ghc/compiler/typecheck/TcPat.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcPat]{Typechecking patterns}
   5
   6 \begin{code}
   7 module TcPat ( tcPat, tcPatBndr_NoSigs, badFieldCon, polyPatSig ) where
   8
   9 #include "HsVersions.h"
  10
  11 import {-# SOURCE #-}   TcExpr( tcExpr )
  12
  13 import HsSyn            ( InPat(..), OutPat(..), HsLit(..), HsExpr(..), Sig(..) )
  14 import RnHsSyn          ( RenamedPat )
  15 import TcHsSyn          ( TcPat, TcId )
  16
  17 import TcMonad
  18 import Inst             ( Inst, OverloadedLit(..), InstOrigin(..),
  19                           emptyLIE, plusLIE, LIE,
  20                           newMethod, newOverloadedLit,
  21                           newDicts, instToIdBndr
  22                         )
  23 import Name             ( Name, getOccName, getSrcLoc )
  24 import FieldLabel       ( fieldLabelName )
  25 import TcEnv            ( tcLookupValue,
  26                           tcLookupValueByKey, newLocalId, badCon
  27                         )
  28 import TcType           ( TcType, TcTyVar, tcInstTyVars )
  29 import TcMonoType       ( tcHsType )
  30 import TcUnify          ( unifyTauTy, unifyListTy,
  31                           unifyTupleTy, unifyUnboxedTupleTy
  32                         )
  33
  34 import Bag              ( Bag )
  35 import CmdLineOpts      ( opt_IrrefutableTuples )
  36 import DataCon          ( DataCon, dataConSig, dataConFieldLabels, dataConSourceArity )
  37 import Id               ( Id, idType, isDataConId_maybe )
  38 import Type             ( Type, isTauTy, mkTyConApp )
  39 import Subst            ( substTy, substTheta )
  40 import TysPrim          ( charPrimTy, intPrimTy, floatPrimTy,
  41                           doublePrimTy, addrPrimTy
  42                         )
  43 import TysWiredIn       ( charTy, stringTy, intTy )
  44 import SrcLoc           ( SrcLoc )
  45 import Unique           ( eqClassOpKey, geClassOpKey, minusClassOpKey )
  46 import Bag
  47 import Util             ( zipEqual )
  48 import Outputable
  49 \end{code}
  50
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection{Variable patterns}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 \begin{code}
  59 -- This is the right function to pass to tcPat when there are no signatures
  60 tcPatBndr_NoSigs binder_name pat_ty
  61   =     -- Need to make a new, monomorphic, Id
  62         -- The binder_name is already being used for the polymorphic Id
  63      newLocalId (getOccName binder_name) pat_ty loc     `thenNF_Tc` \ bndr_id ->
  64      returnTc bndr_id
  65  where
  66    loc = getSrcLoc binder_name
  67 \end{code}
  68
  69
  70 %************************************************************************
  71 %*                                                                      *
  72 \subsection{Typechecking patterns}
  73 %*                                                                      *
  74 %************************************************************************
  75
  76 \begin{code}
  77 tcPat :: (Name -> TcType -> TcM s TcId) -- How to construct a suitable (monomorphic)
  78                                         -- Id for variables found in the pattern
  79                                         -- The TcType is the expected type, see note below
  80       -> RenamedPat
  81
  82       -> TcType         -- Expected type derived from the context
  83                         --      In the case of a function with a rank-2 signature,
  84                         --      this type might be a forall type.
  85                         --      INVARIANT: if it is, the foralls will always be visible,
  86                         --      not hidden inside a mutable type variable
  87
  88       -> TcM s (TcPat,
  89                 LIE,                    -- Required by n+k and literal pats
  90                 Bag TcTyVar,    -- TyVars bound by the pattern
  91                                         --      These are just the existentially-bound ones.
  92                                         --      Any tyvars bound by *type signatures* in the
  93                                         --      patterns are brought into scope before we begin.
  94                 Bag (Name, TcId),       -- Ids bound by the pattern, along with the Name under
  95                                         --      which it occurs in the pattern
  96                                         --      The two aren't the same because we conjure up a new
  97                                         --      local name for each variable.
  98                 LIE)                    -- Dicts or methods [see below] bound by the pattern
  99                                         --      from existential constructor patterns
 100 \end{code}
 101
 102
 103 %************************************************************************
 104 %*                                                                      *
 105 \subsection{Variables, wildcards, lazy pats, as-pats}
 106 %*                                                                      *
 107 %************************************************************************
 108
 109 \begin{code}
 110 tcPat tc_bndr (VarPatIn name) pat_ty
 111   = tc_bndr name pat_ty         `thenTc` \ bndr_id ->
 112     returnTc (VarPat bndr_id, emptyLIE, emptyBag, unitBag (name, bndr_id), emptyLIE)
 113
 114 tcPat tc_bndr (LazyPatIn pat) pat_ty
 115   = tcPat tc_bndr pat pat_ty            `thenTc` \ (pat', lie_req, tvs, ids, lie_avail) ->
 116     returnTc (LazyPat pat', lie_req, tvs, ids, lie_avail)
 117
 118 tcPat tc_bndr pat_in@(AsPatIn name pat) pat_ty
 119   = tc_bndr name pat_ty                 `thenTc` \ bndr_id ->
 120     tcPat tc_bndr pat pat_ty            `thenTc` \ (pat', lie_req, tvs, ids, lie_avail) ->
 121     tcAddErrCtxt (patCtxt pat_in)       $
 122     returnTc (AsPat bndr_id pat', lie_req,
 123               tvs, (name, bndr_id) `consBag` ids, lie_avail)
 124
 125 tcPat tc_bndr WildPatIn pat_ty
 126   = returnTc (WildPat pat_ty, emptyLIE, emptyBag, emptyBag, emptyLIE)
 127
 128 tcPat tc_bndr (NegPatIn pat) pat_ty
 129   = tcPat tc_bndr (negate_lit pat) pat_ty
 130   where
 131     negate_lit (LitPatIn (HsInt  i))       = LitPatIn (HsInt  (-i))
 132     negate_lit (LitPatIn (HsIntPrim i))    = LitPatIn (HsIntPrim (-i))
 133     negate_lit (LitPatIn (HsFrac f))       = LitPatIn (HsFrac (-f))
 134     negate_lit (LitPatIn (HsFloatPrim f))  = LitPatIn (HsFloatPrim (-f))
 135     negate_lit (LitPatIn (HsDoublePrim f)) = LitPatIn (HsDoublePrim (-f))
 136     negate_lit _                           = panic "TcPat:negate_pat"
 137
 138 tcPat tc_bndr (ParPatIn parend_pat) pat_ty
 139   = tcPat tc_bndr parend_pat pat_ty
 140
 141 tcPat tc_bndr (SigPatIn pat sig) pat_ty
 142   = tcHsType sig                                        `thenTc` \ sig_ty ->
 143
 144         -- Check that the signature isn't a polymorphic one, which
 145         -- we don't permit (at present, anyway)
 146     checkTc (isTauTy sig_ty) (polyPatSig sig_ty)        `thenTc_`
 147
 148     unifyTauTy pat_ty sig_ty    `thenTc_`
 149     tcPat tc_bndr pat sig_ty
 150 \end{code}
 151
 152 %************************************************************************
 153 %*                                                                      *
 154 \subsection{Explicit lists and tuples}
 155 %*                                                                      *
 156 %************************************************************************
 157
 158 \begin{code}
 159 tcPat tc_bndr pat_in@(ListPatIn pats) pat_ty
 160   = tcAddErrCtxt (patCtxt pat_in)               $
 161     unifyListTy pat_ty                          `thenTc` \ elem_ty ->
 162     tcPats tc_bndr pats (repeat elem_ty)        `thenTc` \ (pats', lie_req, tvs, ids, lie_avail) ->
 163     returnTc (ListPat elem_ty pats', lie_req, tvs, ids, lie_avail)
 164
 165 tcPat tc_bndr pat_in@(TuplePatIn pats boxed) pat_ty
 166   = tcAddErrCtxt (patCtxt pat_in)       $
 167
 168     (if boxed
 169      then unifyTupleTy        arity pat_ty
 170      else unifyUnboxedTupleTy arity pat_ty)     `thenTc` \ arg_tys ->
 171
 172     tcPats tc_bndr pats arg_tys                         `thenTc` \ (pats', lie_req, tvs, ids, lie_avail) ->
 173
 174         -- possibly do the "make all tuple-pats irrefutable" test:
 175     let
 176         unmangled_result = TuplePat pats' boxed
 177
 178         -- Under flag control turn a pattern (x,y,z) into ~(x,y,z)
 179         -- so that we can experiment with lazy tuple-matching.
 180         -- This is a pretty odd place to make the switch, but
 181         -- it was easy to do.
 182
 183         possibly_mangled_result
 184           | opt_IrrefutableTuples && boxed = LazyPat unmangled_result
 185           | otherwise                      = unmangled_result
 186     in
 187     returnTc (possibly_mangled_result, lie_req, tvs, ids, lie_avail)
 188   where
 189     arity = length pats
 190 \end{code}
 191
 192 %************************************************************************
 193 %*                                                                      *
 194 \subsection{Other constructors}
 195 %*                                                                      *
 196
 197 %************************************************************************
 198
 199 \begin{code}
 200 tcPat tc_bndr pat@(ConPatIn name arg_pats) pat_ty
 201   = tcConPat tc_bndr pat name arg_pats pat_ty
 202
 203 tcPat tc_bndr pat@(ConOpPatIn pat1 op _ pat2) pat_ty
 204   = tcConPat tc_bndr pat op [pat1, pat2] pat_ty
 205 \end{code}
 206
 207
 208 %************************************************************************
 209 %*                                                                      *
 210 \subsection{Records}
 211 %*                                                                      *
 212 %************************************************************************
 213
 214 \begin{code}
 215 tcPat tc_bndr pat@(RecPatIn name rpats) pat_ty
 216   = tcAddErrCtxt (patCtxt pat)  $
 217
 218         -- Check the constructor itself
 219     tcConstructor pat name pat_ty       `thenTc` \ (data_con, ex_tvs, dicts, lie_avail1, arg_tys) ->
 220     let
 221         field_tys = zipEqual "tcPat"
 222                              (map fieldLabelName (dataConFieldLabels data_con))
 223                              arg_tys
 224     in
 225
 226         -- Check the fields
 227     tc_fields field_tys rpats           `thenTc` \ (rpats', lie_req, tvs, ids, lie_avail2) ->
 228
 229     returnTc (RecPat data_con pat_ty ex_tvs dicts rpats',
 230               lie_req,
 231               listToBag ex_tvs `unionBags` tvs,
 232               ids,
 233               lie_avail1 `plusLIE` lie_avail2)
 234
 235   where
 236     tc_fields field_tys []
 237       = returnTc ([], emptyLIE, emptyBag, emptyBag, emptyLIE)
 238
 239     tc_fields field_tys ((field_label, rhs_pat, pun_flag) : rpats)
 240       | null matching_fields
 241       = addErrTc (badFieldCon name field_label)         `thenNF_Tc_`
 242         tc_fields field_tys rpats
 243
 244       | otherwise
 245       = ASSERT( null extras )
 246         tc_fields field_tys rpats       `thenTc` \ (rpats', lie_req1, tvs1, ids1, lie_avail1) ->
 247
 248         tcLookupValue field_label       `thenNF_Tc` \ sel_id ->
 249         tcPat tc_bndr rhs_pat rhs_ty    `thenTc` \ (rhs_pat', lie_req2, tvs2, ids2, lie_avail2) ->
 250
 251         returnTc ((sel_id, rhs_pat', pun_flag) : rpats',
 252                   lie_req1 `plusLIE` lie_req2,
 253                   tvs1 `unionBags` tvs2,
 254                   ids1 `unionBags` ids2,
 255                   lie_avail1 `plusLIE` lie_avail2)
 256       where
 257         matching_fields   = [ty | (f,ty) <- field_tys, f == field_label]
 258         (rhs_ty : extras) = matching_fields
 259 \end{code}
 260
 261 %************************************************************************
 262 %*                                                                      *
 263 \subsection{Non-overloaded literals}
 264 %*                                                                      *
 265 %************************************************************************
 266
 267 \begin{code}
 268 tcPat tc_bndr (LitPatIn lit@(HsChar _))       pat_ty = tcSimpleLitPat lit charTy       pat_ty
 269 tcPat tc_bndr (LitPatIn lit@(HsIntPrim _))    pat_ty = tcSimpleLitPat lit intPrimTy    pat_ty
 270 tcPat tc_bndr (LitPatIn lit@(HsCharPrim _))   pat_ty = tcSimpleLitPat lit charPrimTy   pat_ty
 271 tcPat tc_bndr (LitPatIn lit@(HsStringPrim _)) pat_ty = tcSimpleLitPat lit addrPrimTy   pat_ty
 272 tcPat tc_bndr (LitPatIn lit@(HsFloatPrim _))  pat_ty = tcSimpleLitPat lit floatPrimTy  pat_ty
 273 tcPat tc_bndr (LitPatIn lit@(HsDoublePrim _)) pat_ty = tcSimpleLitPat lit doublePrimTy pat_ty
 274
 275 tcPat tc_bndr (LitPatIn lit@(HsLitLit s))     pat_ty = tcSimpleLitPat lit intTy pat_ty
 276         -- This one looks weird!
 277 \end{code}
 278
 279 %************************************************************************
 280 %*                                                                      *
 281 \subsection{Overloaded patterns: int literals and \tr{n+k} patterns}
 282 %*                                                                      *
 283 %************************************************************************
 284
 285 \begin{code}
 286 tcPat tc_bndr pat@(LitPatIn lit@(HsString str)) pat_ty
 287   = unifyTauTy pat_ty stringTy                  `thenTc_`
 288     tcLookupValueByKey eqClassOpKey             `thenNF_Tc` \ sel_id ->
 289     newMethod (PatOrigin pat) sel_id [stringTy] `thenNF_Tc` \ (lie, eq_id) ->
 290     let
 291         comp_op = HsApp (HsVar eq_id) (HsLitOut lit stringTy)
 292     in
 293     returnTc (NPat lit stringTy comp_op, lie, emptyBag, emptyBag, emptyLIE)
 294
 295
 296 tcPat tc_bndr pat@(LitPatIn lit@(HsInt i)) pat_ty
 297   = tcOverloadedLitPat pat lit (OverloadedIntegral i) pat_ty
 298
 299 tcPat tc_bndr pat@(LitPatIn lit@(HsFrac f)) pat_ty
 300   = tcOverloadedLitPat pat lit (OverloadedFractional f) pat_ty
 301
 302
 303 tcPat tc_bndr pat@(NPlusKPatIn name lit@(HsInt i)) pat_ty
 304   = tc_bndr name pat_ty                         `thenTc` \ bndr_id ->
 305     tcLookupValueByKey geClassOpKey             `thenNF_Tc` \ ge_sel_id ->
 306     tcLookupValueByKey minusClassOpKey          `thenNF_Tc` \ minus_sel_id ->
 307
 308     newOverloadedLit origin
 309                      (OverloadedIntegral i) pat_ty      `thenNF_Tc` \ (over_lit_expr, lie1) ->
 310
 311     newMethod origin ge_sel_id    [pat_ty]      `thenNF_Tc` \ (lie2, ge_id) ->
 312     newMethod origin minus_sel_id [pat_ty]      `thenNF_Tc` \ (lie3, minus_id) ->
 313
 314     returnTc (NPlusKPat bndr_id lit pat_ty
 315                         (SectionR (HsVar ge_id) over_lit_expr)
 316                         (SectionR (HsVar minus_id) over_lit_expr),
 317               lie1 `plusLIE` lie2 `plusLIE` lie3,
 318               emptyBag, unitBag (name, bndr_id), emptyLIE)
 319   where
 320     origin = PatOrigin pat
 321
 322 tcPat tc_bndr (NPlusKPatIn pat other) pat_ty
 323   = panic "TcPat:NPlusKPat: not an HsInt literal"
 324 \end{code}
 325
 326 %************************************************************************
 327 %*                                                                      *
 328 \subsection{Lists of patterns}
 329 %*                                                                      *
 330 %************************************************************************
 331
 332 Helper functions
 333
 334 \begin{code}
 335 tcPats :: (Name -> TcType -> TcM s TcId)        -- How to deal with variables
 336        -> [RenamedPat] -> [TcType]              -- Excess 'expected types' discarded
 337        -> TcM s ([TcPat],
 338                  LIE,                           -- Required by n+k and literal pats
 339                  Bag TcTyVar,
 340                  Bag (Name, TcId),      -- Ids bound by the pattern
 341                  LIE)                           -- Dicts bound by the pattern
 342
 343 tcPats tc_bndr [] tys = returnTc ([], emptyLIE, emptyBag, emptyBag, emptyLIE)
 344
 345 tcPats tc_bndr (ty:tys) (pat:pats)
 346   = tcPat tc_bndr ty pat                `thenTc` \ (pat',  lie_req1, tvs1, ids1, lie_avail1) ->
 347     tcPats tc_bndr tys pats     `thenTc` \ (pats', lie_req2, tvs2, ids2, lie_avail2) ->
 348
 349     returnTc (pat':pats', lie_req1 `plusLIE` lie_req2,
 350               tvs1 `unionBags` tvs2, ids1 `unionBags` ids2,
 351               lie_avail1 `plusLIE` lie_avail2)
 352 \end{code}
 353
 354 ------------------------------------------------------
 355 \begin{code}
 356 tcSimpleLitPat lit lit_ty pat_ty
 357   = unifyTauTy pat_ty lit_ty    `thenTc_`
 358     returnTc (LitPat lit lit_ty, emptyLIE, emptyBag, emptyBag, emptyLIE)
 359
 360
 361 tcOverloadedLitPat pat lit over_lit pat_ty
 362   = newOverloadedLit (PatOrigin pat) over_lit pat_ty    `thenNF_Tc` \ (over_lit_expr, lie1) ->
 363     tcLookupValueByKey eqClassOpKey                     `thenNF_Tc` \ eq_sel_id ->
 364     newMethod origin eq_sel_id [pat_ty]                 `thenNF_Tc` \ (lie2, eq_id) ->
 365
 366     returnTc (NPat lit pat_ty (HsApp (HsVar eq_id)
 367                                      over_lit_expr),
 368               lie1 `plusLIE` lie2,
 369               emptyBag, emptyBag, emptyLIE)
 370   where
 371     origin = PatOrigin pat
 372 \end{code}
 373
 374 ------------------------------------------------------
 375 \begin{code}
 376 tcConstructor pat con_name pat_ty
 377   =     -- Check that it's a constructor
 378     tcLookupValue con_name              `thenNF_Tc` \ con_id ->
 379     case isDataConId_maybe con_id of {
 380         Nothing -> failWithTc (badCon con_id);
 381         Just data_con ->
 382
 383         -- Instantiate it
 384     let
 385         (tvs, theta, ex_tvs, ex_theta, arg_tys, tycon) = dataConSig data_con
 386              -- Ignore the theta; overloaded constructors only
 387              -- behave differently when called, not when used for
 388              -- matching.
 389     in
 390     tcInstTyVars (ex_tvs ++ tvs)        `thenNF_Tc` \ (all_tvs', ty_args', tenv) ->
 391     let
 392         ex_theta' = substTheta tenv ex_theta
 393         arg_tys'  = map (substTy tenv) arg_tys
 394
 395         n_ex_tvs  = length ex_tvs
 396         ex_tvs'   = take n_ex_tvs all_tvs'
 397         result_ty = mkTyConApp tycon (drop n_ex_tvs ty_args')
 398     in
 399     newDicts (PatOrigin pat) ex_theta'  `thenNF_Tc` \ (lie_avail, dicts) ->
 400
 401         -- Check overall type matches
 402     unifyTauTy pat_ty result_ty         `thenTc_`
 403
 404     returnTc (data_con, ex_tvs', dicts, lie_avail, arg_tys')
 405     }
 406 \end{code}
 407
 408 ------------------------------------------------------
 409 \begin{code}
 410 tcConPat tc_bndr pat con_name arg_pats pat_ty
 411   = tcAddErrCtxt (patCtxt pat)  $
 412
 413         -- Check the constructor itself
 414     tcConstructor pat con_name pat_ty   `thenTc` \ (data_con, ex_tvs', dicts, lie_avail1, arg_tys') ->
 415
 416         -- Check correct arity
 417     let
 418         con_arity  = dataConSourceArity data_con
 419         no_of_args = length arg_pats
 420     in
 421     checkTc (con_arity == no_of_args)
 422             (arityErr "Constructor" data_con con_arity no_of_args)      `thenTc_`
 423
 424         -- Check arguments
 425     tcPats tc_bndr arg_pats arg_tys'    `thenTc` \ (arg_pats', lie_req, tvs, ids, lie_avail2) ->
 426
 427     returnTc (ConPat data_con pat_ty ex_tvs' dicts arg_pats',
 428               lie_req,
 429               listToBag ex_tvs' `unionBags` tvs,
 430               ids,
 431               lie_avail1 `plusLIE` lie_avail2)
 432 \end{code}
 433
 434
 435 %************************************************************************
 436 %*                                                                      *
 437 \subsection{Errors and contexts}
 438 %*                                                                      *
 439 %************************************************************************
 440
 441 \begin{code}
 442 patCtxt pat = hang (ptext SLIT("In the pattern:"))
 443                  4 (ppr pat)
 444
 445 recordLabel field_label
 446   = hang (hcat [ptext SLIT("When matching record field"), ppr field_label])
 447          4 (hcat [ptext SLIT("with its immediately enclosing constructor")])
 448
 449 recordRhs field_label pat
 450   = hang (ptext SLIT("In the record field pattern"))
 451          4 (sep [ppr field_label, char '=', ppr pat])
 452
 453 badFieldCon :: Name -> Name -> SDoc
 454 badFieldCon con field
 455   = hsep [ptext SLIT("Constructor") <+> quotes (ppr con),
 456           ptext SLIT("does not have field"), quotes (ppr field)]
 457
 458 polyPatSig :: TcType -> SDoc
 459 polyPatSig sig_ty
 460   = hang (ptext SLIT("Polymorphic type signature in pattern"))
 461          4 (ppr sig_ty)
 462 \end{code}
 463