ghc/compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcRnDriver (
   8 #ifdef GHCI
   9         tcRnStmt, tcRnExpr, tcRnType,
  10         tcRnLookupRdrName,
  11         tcRnLookupName,
  12         tcRnGetInfo,
  13         getModuleExports,
  14 #endif
  15         tcRnModule,
  16         tcTopSrcDecls,
  17         tcRnExtCore
  18     ) where
  19
  20 #include "HsVersions.h"
  21
  22 import IO
  23 #ifdef GHCI
  24 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  25 #endif
  26
  27 import DynFlags         ( DynFlag(..), DynFlags(..), dopt, GhcMode(..) )
  28 import StaticFlags      ( opt_PprStyle_Debug )
  29 import Packages         ( moduleToPackageConfig, mkPackageId, package,
  30                           isHomeModule )
  31 import HsSyn            ( HsModule(..), HsExtCore(..), HsGroup(..), LHsDecl,
  32                           SpliceDecl(..), HsBind(..), LHsBinds,
  33                           emptyGroup, appendGroups,
  34                           nlHsApp, nlHsVar, pprLHsBinds )
  35 import RdrHsSyn         ( findSplice )
  36
  37 import PrelNames        ( runMainIOName, rootMainName, mAIN,
  38                           main_RDR_Unqual )
  39 import RdrName          ( RdrName, mkRdrUnqual, emptyGlobalRdrEnv )
  40 import TcHsSyn          ( zonkTopDecls )
  41 import TcExpr           ( tcInferRho )
  42 import TcRnMonad
  43 import TcType           ( tidyTopType, tcEqType, mkTyVarTys, substTyWith )
  44 import Inst             ( showLIE )
  45 import InstEnv          ( extendInstEnvList, Instance, pprInstances, instanceDFunId )
  46 import TcBinds          ( tcTopBinds, tcHsBootSigs )
  47 import TcDefaults       ( tcDefaults )
  48 import TcEnv            ( tcExtendGlobalValEnv, iDFunId )
  49 import TcRules          ( tcRules )
  50 import TcForeign        ( tcForeignImports, tcForeignExports )
  51 import TcInstDcls       ( tcInstDecls1, tcInstDecls2 )
  52 import TcIface          ( tcExtCoreBindings, tcHiBootIface )
  53 import TcSimplify       ( tcSimplifyTop )
  54 import TcTyClsDecls     ( tcTyAndClassDecls )
  55 import LoadIface        ( loadOrphanModules )
  56 import RnNames          ( importsFromLocalDecls, rnImports, rnExports,
  57                           reportUnusedNames, reportDeprecations )
  58 import RnEnv            ( lookupSrcOcc_maybe )
  59 import RnSource         ( rnSrcDecls, rnTyClDecls, checkModDeprec )
  60 import PprCore          ( pprRules, pprCoreBindings )
  61 import CoreSyn          ( CoreRule, bindersOfBinds )
  62 import DataCon          ( dataConWrapId )
  63 import ErrUtils         ( Messages, mkDumpDoc, showPass )
  64 import Id               ( Id, mkExportedLocalId, isLocalId, idName, idType )
  65 import Var              ( Var )
  66 import Module           ( Module, ModuleEnv, mkModule, moduleEnvElts, elemModuleEnv )
  67 import OccName          ( mkVarOcc )
  68 import Name             ( Name, NamedThing(..), isExternalName, getSrcLoc, isWiredInName )
  69 import NameSet
  70 import TyCon            ( tyConHasGenerics, isSynTyCon, getSynTyConDefn, tyConKind )
  71 import SrcLoc           ( srcLocSpan, Located(..), noLoc )
  72 import DriverPhases     ( HscSource(..), isHsBoot )
  73 import HscTypes         ( ModGuts(..), ModDetails(..), emptyModDetails,
  74                           HscEnv(..), ExternalPackageState(..),
  75                           IsBootInterface, noDependencies,
  76                           Deprecs( NoDeprecs ), plusDeprecs,
  77                           ForeignStubs(NoStubs), TyThing(..),
  78                           TypeEnv, lookupTypeEnv, hptInstances,
  79                           extendTypeEnvWithIds, typeEnvIds, typeEnvTyCons, typeEnvElts,
  80                           emptyFixityEnv
  81                         )
  82 import Outputable
  83
  84 #ifdef GHCI
  85 import HsSyn            ( HsStmtContext(..), Stmt(..), HsExpr(..), HsBindGroup(..),
  86                           LStmt, LHsExpr, LHsType, mkVarBind,
  87                           collectLStmtsBinders, collectLStmtBinders, nlVarPat,
  88                           placeHolderType, noSyntaxExpr )
  89 import RdrName          ( GlobalRdrElt(..), globalRdrEnvElts,
  90                           unQualOK, lookupLocalRdrEnv, extendLocalRdrEnv )
  91 import RnSource         ( addTcgDUs )
  92 import TcHsSyn          ( mkHsLet, zonkTopLExpr, zonkTopBndrs )
  93 import TcHsType         ( kcHsType )
  94 import TcMType          ( zonkTcType, zonkQuantifiedTyVar )
  95 import TcMatches        ( tcStmts, tcDoStmt )
  96 import TcSimplify       ( tcSimplifyInteractive, tcSimplifyInfer )
  97 import TcType           ( Type, mkForAllTys, mkFunTys, mkTyConApp, tyVarsOfType, isTauTy,
  98                           isUnLiftedType, tyClsNamesOfDFunHead, tyClsNamesOfType, isUnitTy )
  99 import TcEnv            ( tcLookupTyCon, tcLookupId, tcLookupGlobal )
 100 import RnTypes          ( rnLHsType )
 101 import Inst             ( tcGetInstEnvs )
 102 import InstEnv          ( classInstances, instEnvElts )
 103 import RnExpr           ( rnStmts, rnLExpr )
 104 import LoadIface        ( loadSrcInterface, loadSysInterface )
 105 import IfaceEnv         ( ifaceExportNames )
 106 import Module           ( moduleSetElts, mkModuleSet )
 107 import RnEnv            ( lookupOccRn, dataTcOccs, lookupFixityRn )
 108 import Id               ( setIdType )
 109 import MkId             ( unsafeCoerceId )
 110 import TyCon            ( tyConName )
 111 import TysWiredIn       ( mkListTy, unitTy )
 112 import IdInfo           ( GlobalIdDetails(..) )
 113 import Kind             ( Kind )
 114 import Var              ( globaliseId )
 115 import Name             ( nameOccName, nameModule, isBuiltInSyntax )
 116 import OccName          ( isTcOcc )
 117 import NameEnv          ( delListFromNameEnv )
 118 import PrelNames        ( iNTERACTIVE, ioTyConName, printName, itName,
 119                           bindIOName, thenIOName, returnIOName )
 120 import HscTypes         ( InteractiveContext(..),
 121                           ModIface(..), icPrintUnqual,
 122                           Dependencies(..) )
 123 import BasicTypes       ( RecFlag(..), Fixity )
 124 import SrcLoc           ( unLoc, noSrcSpan )
 125 #endif
 126
 127 import FastString       ( mkFastString )
 128 import Util             ( sortLe )
 129 import Bag              ( unionBags, snocBag, emptyBag, unitBag, unionManyBags )
 130
 131 import Maybe            ( isJust )
 132 \end{code}
 133
 134
 135
 136 %************************************************************************
 137 %*                                                                      *
 138         Typecheck and rename a module
 139 %*                                                                      *
 140 %************************************************************************
 141
 142
 143 \begin{code}
 144 tcRnModule :: HscEnv
 145            -> HscSource
 146            -> Bool              -- True <=> save renamed syntax
 147            -> Located (HsModule RdrName)
 148            -> IO (Messages, Maybe TcGblEnv)
 149
 150 tcRnModule hsc_env hsc_src save_rn_decls
 151          (L loc (HsModule maybe_mod export_ies
 152                           import_decls local_decls mod_deprec))
 153  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 154
 155    let { this_mod = case maybe_mod of
 156                         Nothing  -> mAIN          -- 'module M where' is omitted
 157                         Just (L _ mod) -> mod } ; -- The normal case
 158
 159    initTc hsc_env hsc_src this_mod $
 160    setSrcSpan loc $
 161    do {
 162         checkForPackageModule (hsc_dflags hsc_env) this_mod;
 163
 164                 -- Deal with imports; sets tcg_rdr_env, tcg_imports
 165         (rdr_env, imports) <- rnImports import_decls ;
 166
 167         let { dep_mods :: ModuleEnv (Module, IsBootInterface)
 168             ; dep_mods = imp_dep_mods imports
 169
 170                 -- We want instance declarations from all home-package
 171                 -- modules below this one, including boot modules, except
 172                 -- ourselves.  The 'except ourselves' is so that we don't
 173                 -- get the instances from this module's hs-boot file
 174             ; want_instances :: Module -> Bool
 175             ; want_instances mod = mod `elemModuleEnv` dep_mods
 176                                    && mod /= this_mod
 177             ; home_insts = hptInstances hsc_env want_instances
 178             } ;
 179
 180                 -- Record boot-file info in the EPS, so that it's
 181                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 182                 -- and any other incrementally-performed imports
 183         updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 184
 185                 -- Update the gbl env
 186         updGblEnv ( \ gbl ->
 187                 gbl { tcg_rdr_env  = rdr_env,
 188                       tcg_inst_env = extendInstEnvList (tcg_inst_env gbl) home_insts,
 189                       tcg_imports  = tcg_imports gbl `plusImportAvails` imports,
 190                       tcg_rn_decls = if save_rn_decls then
 191                                         Just emptyGroup
 192                                      else
 193                                         Nothing })
 194                 $ do {
 195
 196         traceRn (text "rn1" <+> ppr (imp_dep_mods imports)) ;
 197                 -- Fail if there are any errors so far
 198                 -- The error printing (if needed) takes advantage
 199                 -- of the tcg_env we have now set
 200         failIfErrsM ;
 201
 202                 -- Load any orphan-module interfaces, so that
 203                 -- their rules and instance decls will be found
 204         loadOrphanModules (imp_orphs imports) ;
 205
 206         traceRn (text "rn1a") ;
 207                 -- Rename and type check the declarations
 208         tcg_env <- if isHsBoot hsc_src then
 209                         tcRnHsBootDecls local_decls
 210                    else
 211                         tcRnSrcDecls local_decls ;
 212         setGblEnv tcg_env               $ do {
 213
 214         traceRn (text "rn3") ;
 215
 216                 -- Report the use of any deprecated things
 217                 -- We do this before processsing the export list so
 218                 -- that we don't bleat about re-exporting a deprecated
 219                 -- thing (especially via 'module Foo' export item)
 220                 -- Only uses in the body of the module are complained about
 221         reportDeprecations tcg_env ;
 222
 223                 -- Process the export list
 224         exports <- rnExports (isJust maybe_mod) export_ies ;
 225
 226                 -- Check whether the entire module is deprecated
 227                 -- This happens only once per module
 228         let { mod_deprecs = checkModDeprec mod_deprec } ;
 229
 230                 -- Add exports and deprecations to envt
 231         let { final_env  = tcg_env { tcg_exports = exports,
 232                                      tcg_dus = tcg_dus tcg_env `plusDU` usesOnly exports,
 233                                      tcg_deprecs = tcg_deprecs tcg_env `plusDeprecs`
 234                                                    mod_deprecs }
 235                 -- A module deprecation over-rides the earlier ones
 236              } ;
 237
 238                 -- Report unused names
 239         reportUnusedNames export_ies final_env ;
 240
 241                 -- Dump output and return
 242         tcDump final_env ;
 243         return final_env
 244     }}}}
 245
 246 -- This is really a sanity check that the user has given -package-name
 247 -- if necessary.  -package-name is only necessary when the package database
 248 -- already contains the current package, because then we can't tell
 249 -- whether a given module is in the current package or not, without knowing
 250 -- the name of the current package.
 251 checkForPackageModule dflags this_mod
 252   | not (isHomeModule dflags this_mod),
 253     Just (pkg,_) <- moduleToPackageConfig dflags this_mod =
 254         let
 255                 ppr_pkg = ppr (mkPackageId (package pkg))
 256         in
 257         addErr (ptext SLIT("Module") <+> quotes (ppr this_mod) <+>
 258                 ptext SLIT("is a member of package") <+>  ppr_pkg <> char '.' $$
 259                 ptext SLIT("To compile this module, please use -ignore-package") <+> ppr_pkg <> char '.')
 260   | otherwise = return ()
 261 \end{code}
 262
 263
 264 %************************************************************************
 265 %*                                                                      *
 266         Type-checking external-core modules
 267 %*                                                                      *
 268 %************************************************************************
 269
 270 \begin{code}
 271 tcRnExtCore :: HscEnv
 272             -> HsExtCore RdrName
 273             -> IO (Messages, Maybe ModGuts)
 274         -- Nothing => some error occurred
 275
 276 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 277         -- The decls are IfaceDecls; all names are original names
 278  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 279
 280    initTc hsc_env ExtCoreFile this_mod $ do {
 281
 282    let { ldecls  = map noLoc decls } ;
 283
 284         -- Deal with the type declarations; first bring their stuff
 285         -- into scope, then rname them, then type check them
 286    tcg_env  <- importsFromLocalDecls (mkFakeGroup ldecls) ;
 287
 288    setGblEnv tcg_env $ do {
 289
 290    rn_decls <- rnTyClDecls ldecls ;
 291    failIfErrsM ;
 292
 293         -- Dump trace of renaming part
 294    rnDump (ppr rn_decls) ;
 295
 296         -- Typecheck them all together so that
 297         -- any mutually recursive types are done right
 298    tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails rn_decls) ;
 299         -- Make the new type env available to stuff slurped from interface files
 300
 301    setGblEnv tcg_env $ do {
 302
 303         -- Now the core bindings
 304    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 305
 306         -- Wrap up
 307    let {
 308         bndrs      = bindersOfBinds core_binds ;
 309         my_exports = mkNameSet (map idName bndrs) ;
 310                 -- ToDo: export the data types also?
 311
 312         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 313
 314         mod_guts = ModGuts {    mg_module   = this_mod,
 315                                 mg_boot     = False,
 316                                 mg_usages   = [],               -- ToDo: compute usage
 317                                 mg_dir_imps = [],               -- ??
 318                                 mg_deps     = noDependencies,   -- ??
 319                                 mg_exports  = my_exports,
 320                                 mg_types    = final_type_env,
 321                                 mg_insts    = tcg_insts tcg_env,
 322                                 mg_rules    = [],
 323                                 mg_binds    = core_binds,
 324
 325                                 -- Stubs
 326                                 mg_rdr_env  = emptyGlobalRdrEnv,
 327                                 mg_fix_env  = emptyFixityEnv,
 328                                 mg_deprecs  = NoDeprecs,
 329                                 mg_foreign  = NoStubs
 330                     } } ;
 331
 332    tcCoreDump mod_guts ;
 333
 334    return mod_guts
 335    }}}}
 336
 337 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 338   = HsGroup {   hs_tyclds = decls,      -- This is the one we want
 339                 hs_valds = [], hs_fords = [],
 340                 hs_instds = [], hs_fixds = [], hs_depds = [],
 341                 hs_ruleds = [], hs_defds = [] }
 342 \end{code}
 343
 344
 345 %************************************************************************
 346 %*                                                                      *
 347         Type-checking the top level of a module
 348 %*                                                                      *
 349 %************************************************************************
 350
 351 \begin{code}
 352 tcRnSrcDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 353         -- Returns the variables free in the decls
 354         -- Reason: solely to report unused imports and bindings
 355 tcRnSrcDecls decls
 356  = do {         -- Load the hi-boot interface for this module, if any
 357                 -- We do this now so that the boot_names can be passed
 358                 -- to tcTyAndClassDecls, because the boot_names are
 359                 -- automatically considered to be loop breakers
 360         mod <- getModule ;
 361         boot_iface <- tcHiBootIface mod ;
 362
 363                 -- Do all the declarations
 364         (tc_envs, lie) <- getLIE (tc_rn_src_decls boot_iface decls) ;
 365
 366              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 367              -- How could there be ambiguous ones?  They can only arise if a
 368              -- top-level decl falls under the monomorphism
 369              -- restriction, and no subsequent decl instantiates its
 370              -- type.  (Usually, ambiguous type variables are resolved
 371              -- during the generalisation step.)
 372         traceTc (text "Tc8") ;
 373         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 374                 -- Setting the global env exposes the instances to tcSimplifyTop
 375                 -- Setting the local env exposes the local Ids to tcSimplifyTop,
 376                 -- so that we get better error messages (monomorphism restriction)
 377
 378             -- Backsubstitution.  This must be done last.
 379             -- Even tcSimplifyTop may do some unification.
 380         traceTc (text "Tc9") ;
 381         let { (tcg_env, _) = tc_envs ;
 382               TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 383                          tcg_rules = rules, tcg_fords = fords } = tcg_env } ;
 384
 385         (bind_ids, binds', fords', rules') <- zonkTopDecls (binds `unionBags` inst_binds)
 386                                                            rules fords ;
 387
 388         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 389             ; tcg_env' = tcg_env { tcg_type_env = final_type_env,
 390                                    tcg_binds = binds',
 391                                    tcg_rules = rules',
 392                                    tcg_fords = fords' } } ;
 393
 394         -- Make the new type env available to stuff slurped from interface files
 395         writeMutVar (tcg_type_env_var tcg_env) final_type_env ;
 396
 397         -- Compare the hi-boot iface (if any) with the real thing
 398         dfun_binds <- checkHiBootIface tcg_env' boot_iface ;
 399
 400         return (tcg_env' { tcg_binds = tcg_binds tcg_env' `unionBags` dfun_binds })
 401    }
 402
 403 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 404 -- Loops around dealing with each top level inter-splice group
 405 -- in turn, until it's dealt with the entire module
 406 tc_rn_src_decls boot_details ds
 407  = do { let { (first_group, group_tail) = findSplice ds } ;
 408                 -- If ds is [] we get ([], Nothing)
 409
 410         -- Type check the decls up to, but not including, the first splice
 411         tc_envs@(tcg_env,tcl_env) <- tcRnGroup boot_details first_group ;
 412
 413         -- Bale out if errors; for example, error recovery when checking
 414         -- the RHS of 'main' can mean that 'main' is not in the envt for
 415         -- the subsequent checkMain test
 416         failIfErrsM ;
 417
 418         setEnvs tc_envs $
 419
 420         -- If there is no splice, we're nearly done
 421         case group_tail of {
 422            Nothing -> do {      -- Last thing: check for `main'
 423                            tcg_env <- checkMain ;
 424                            return (tcg_env, tcl_env)
 425                       } ;
 426
 427         -- If there's a splice, we must carry on
 428            Just (SpliceDecl splice_expr, rest_ds) -> do {
 429 #ifndef GHCI
 430         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 431 #else
 432
 433         -- Rename the splice expression, and get its supporting decls
 434         (rn_splice_expr, splice_fvs) <- rnLExpr splice_expr ;
 435         failIfErrsM ;   -- Don't typecheck if renaming failed
 436
 437         -- Execute the splice
 438         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 439
 440         -- Glue them on the front of the remaining decls and loop
 441         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 442         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 443 #endif /* GHCI */
 444     }}}
 445 \end{code}
 446
 447 %************************************************************************
 448 %*                                                                      *
 449         Compiling hs-boot source files, and
 450         comparing the hi-boot interface with the real thing
 451 %*                                                                      *
 452 %************************************************************************
 453
 454 \begin{code}
 455 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 456 tcRnHsBootDecls decls
 457    = do { let { (first_group, group_tail) = findSplice decls }
 458
 459         ; case group_tail of
 460              Just stuff -> spliceInHsBootErr stuff
 461              Nothing    -> return ()
 462
 463                 -- Rename the declarations
 464         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 465         ; setGblEnv tcg_env $ do {
 466
 467         -- Todo: check no foreign decls, no rules, no default decls
 468
 469                 -- Typecheck type/class decls
 470         ; traceTc (text "Tc2")
 471         ; let tycl_decls = hs_tyclds rn_group
 472         ; tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails tycl_decls)
 473         ; setGblEnv tcg_env     $ do {
 474
 475                 -- Typecheck instance decls
 476         ; traceTc (text "Tc3")
 477         ; (tcg_env, inst_infos, _binds) <- tcInstDecls1 tycl_decls (hs_instds rn_group)
 478         ; setGblEnv tcg_env     $ do {
 479
 480                 -- Typecheck value declarations
 481         ; traceTc (text "Tc5")
 482         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 483
 484                 -- Wrap up
 485                 -- No simplification or zonking to do
 486         ; traceTc (text "Tc7a")
 487         ; gbl_env <- getGblEnv
 488
 489                 -- Make the final type-env
 490                 -- Include the dfun_ids so that their type sigs get
 491                 -- are written into the interface file
 492         ; let { type_env0 = tcg_type_env gbl_env
 493               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 494               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 495               ; dfun_ids = map iDFunId inst_infos }
 496         ; return (gbl_env { tcg_type_env = type_env2 })
 497    }}}}
 498
 499 spliceInHsBootErr (SpliceDecl (L loc _), _)
 500   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 501 \end{code}
 502
 503 Once we've typechecked the body of the module, we want to compare what
 504 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 505
 506 \begin{code}
 507 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM (LHsBinds Id)
 508 -- Compare the hi-boot file for this module (if there is one)
 509 -- with the type environment we've just come up with
 510 -- In the common case where there is no hi-boot file, the list
 511 -- of boot_names is empty.
 512 --
 513 -- The bindings we return give bindings for the dfuns defined in the
 514 -- hs-boot file, such as        $fbEqT = $fEqT
 515
 516 checkHiBootIface
 517         (TcGblEnv { tcg_insts = local_insts, tcg_type_env = local_type_env })
 518         (ModDetails { md_insts = boot_insts, md_types = boot_type_env })
 519   = do  { mapM_ check_one (typeEnvElts boot_type_env)
 520         ; dfun_binds <- mapM check_inst boot_insts
 521         ; return (unionManyBags dfun_binds) }
 522   where
 523     check_one boot_thing
 524       | no_check name
 525       = return ()
 526       | otherwise
 527       = case lookupTypeEnv local_type_env name of
 528           Nothing         -> addErrTc (missingBootThing boot_thing)
 529           Just real_thing -> check_thing boot_thing real_thing
 530       where
 531         name = getName boot_thing
 532
 533     no_check name = isWiredInName name  -- No checking for wired-in names.  In particular,
 534                                         -- 'error' is handled by a rather gross hack
 535                                         -- (see comments in GHC.Err.hs-boot)
 536                   || name `elem` dfun_names
 537     dfun_names = map getName boot_insts
 538
 539     check_inst boot_inst
 540         = case [dfun | inst <- local_insts,
 541                        let dfun = instanceDFunId inst,
 542                        idType dfun `tcEqType` boot_inst_ty ] of
 543             [] -> do { addErrTc (instMisMatch boot_inst); return emptyBag }
 544             (dfun:_) -> return (unitBag $ noLoc $ VarBind local_boot_dfun (nlHsVar dfun))
 545         where
 546           boot_dfun = instanceDFunId boot_inst
 547           boot_inst_ty = idType boot_dfun
 548           local_boot_dfun = mkExportedLocalId (idName boot_dfun) boot_inst_ty
 549
 550 ----------------
 551 check_thing (ATyCon boot_tc) (ATyCon real_tc)
 552   | isSynTyCon boot_tc && isSynTyCon real_tc,
 553     defn1 `tcEqType` substTyWith tvs2 (mkTyVarTys tvs1) defn2
 554   = return ()
 555
 556   | tyConKind boot_tc == tyConKind real_tc
 557   = return ()
 558   where
 559     (tvs1, defn1) = getSynTyConDefn boot_tc
 560     (tvs2, defn2) = getSynTyConDefn boot_tc
 561
 562 check_thing (AnId boot_id) (AnId real_id)
 563   | idType boot_id `tcEqType` idType real_id
 564   = return ()
 565
 566 check_thing (ADataCon dc1) (ADataCon dc2)
 567   | idType (dataConWrapId dc1) `tcEqType` idType (dataConWrapId dc2)
 568   = return ()
 569
 570         -- Can't declare a class in a hi-boot file
 571
 572 check_thing boot_thing real_thing       -- Default case; failure
 573   = addErrAt (srcLocSpan (getSrcLoc real_thing))
 574              (bootMisMatch real_thing)
 575
 576 ----------------
 577 missingBootThing thing
 578   = ppr thing <+> ptext SLIT("is defined in the hs-boot file, but not in the module")
 579 bootMisMatch thing
 580   = ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file")
 581 instMisMatch inst
 582   = hang (ppr inst)
 583        2 (ptext SLIT("is defined in the hs-boot file, but not in the module"))
 584 \end{code}
 585
 586
 587 %************************************************************************
 588 %*                                                                      *
 589         Type-checking the top level of a module
 590 %*                                                                      *
 591 %************************************************************************
 592
 593 tcRnGroup takes a bunch of top-level source-code declarations, and
 594  * renames them
 595  * gets supporting declarations from interface files
 596  * typechecks them
 597  * zonks them
 598  * and augments the TcGblEnv with the results
 599
 600 In Template Haskell it may be called repeatedly for each group of
 601 declarations.  It expects there to be an incoming TcGblEnv in the
 602 monad; it augments it and returns the new TcGblEnv.
 603
 604 \begin{code}
 605 tcRnGroup :: ModDetails -> HsGroup RdrName -> TcM (TcGblEnv, TcLclEnv)
 606         -- Returns the variables free in the decls, for unused-binding reporting
 607 tcRnGroup boot_details decls
 608  = do {         -- Rename the declarations
 609         (tcg_env, rn_decls) <- rnTopSrcDecls decls ;
 610         setGblEnv tcg_env $ do {
 611
 612                 -- Typecheck the declarations
 613         tcTopSrcDecls boot_details rn_decls
 614   }}
 615
 616 ------------------------------------------------
 617 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 618 rnTopSrcDecls group
 619  = do {         -- Bring top level binders into scope
 620         tcg_env <- importsFromLocalDecls group ;
 621         setGblEnv tcg_env $ do {
 622
 623         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 624
 625                 -- Rename the source decls
 626         (tcg_env, rn_decls) <- rnSrcDecls group ;
 627         failIfErrsM ;
 628
 629                 -- save the renamed syntax, if we want it
 630         let { tcg_env'
 631                 | Just grp <- tcg_rn_decls tcg_env
 632                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 633                 | otherwise
 634                    = tcg_env };
 635
 636                 -- Dump trace of renaming part
 637         rnDump (ppr rn_decls) ;
 638
 639         return (tcg_env', rn_decls)
 640    }}
 641
 642 ------------------------------------------------
 643 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 644 tcTopSrcDecls boot_details
 645         (HsGroup { hs_tyclds = tycl_decls,
 646                    hs_instds = inst_decls,
 647                    hs_fords  = foreign_decls,
 648                    hs_defds  = default_decls,
 649                    hs_ruleds = rule_decls,
 650                    hs_valds  = val_binds })
 651  = do {         -- Type-check the type and class decls, and all imported decls
 652                 -- The latter come in via tycl_decls
 653         traceTc (text "Tc2") ;
 654
 655         tcg_env <- checkNoErrs (tcTyAndClassDecls boot_details tycl_decls) ;
 656         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 657         -- an error we'd better stop now, to avoid a cascade
 658
 659         -- Make these type and class decls available to stuff slurped from interface files
 660         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 661
 662
 663         setGblEnv tcg_env       $ do {
 664                 -- Source-language instances, including derivings,
 665                 -- and import the supporting declarations
 666         traceTc (text "Tc3") ;
 667         (tcg_env, inst_infos, deriv_binds) <- tcInstDecls1 tycl_decls inst_decls ;
 668         setGblEnv tcg_env       $ do {
 669
 670                 -- Foreign import declarations next.  No zonking necessary
 671                 -- here; we can tuck them straight into the global environment.
 672         traceTc (text "Tc4") ;
 673         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 674         tcExtendGlobalValEnv fi_ids     $ do {
 675
 676                 -- Default declarations
 677         traceTc (text "Tc4a") ;
 678         default_tys <- tcDefaults default_decls ;
 679         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 680
 681                 -- Value declarations next
 682                 -- We also typecheck any extra binds that came out
 683                 -- of the "deriving" process (deriv_binds)
 684         traceTc (text "Tc5") ;
 685         (tc_val_binds, tcl_env) <- tcTopBinds (val_binds ++ deriv_binds) ;
 686         setLclTypeEnv tcl_env   $ do {
 687
 688                 -- Second pass over class and instance declarations,
 689         traceTc (text "Tc6") ;
 690         (inst_binds, tcl_env) <- tcInstDecls2 tycl_decls inst_infos ;
 691         showLIE (text "after instDecls2") ;
 692
 693                 -- Foreign exports
 694                 -- They need to be zonked, so we return them
 695         traceTc (text "Tc7") ;
 696         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 697
 698                 -- Rules
 699         rules <- tcRules rule_decls ;
 700
 701                 -- Wrap up
 702         traceTc (text "Tc7a") ;
 703         tcg_env <- getGblEnv ;
 704         let { all_binds = tc_val_binds   `unionBags`
 705                           inst_binds     `unionBags`
 706                           foe_binds  ;
 707
 708                 -- Extend the GblEnv with the (as yet un-zonked)
 709                 -- bindings, rules, foreign decls
 710               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 711                                     tcg_rules = tcg_rules tcg_env ++ rules,
 712                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 713         return (tcg_env', tcl_env)
 714     }}}}}}
 715 \end{code}
 716
 717
 718 %************************************************************************
 719 %*                                                                      *
 720         Checking for 'main'
 721 %*                                                                      *
 722 %************************************************************************
 723
 724 \begin{code}
 725 checkMain :: TcM TcGblEnv
 726 -- If we are in module Main, check that 'main' is defined.
 727 checkMain
 728   = do { ghci_mode <- getGhciMode ;
 729          tcg_env   <- getGblEnv ;
 730          dflags    <- getDOpts ;
 731          let { main_mod = case mainModIs dflags of {
 732                                 Just mod -> mkModule mod ;
 733                                 Nothing  -> mAIN } ;
 734                main_fn  = case mainFunIs dflags of {
 735                                 Just fn -> mkRdrUnqual (mkVarOcc (mkFastString fn)) ;
 736                                 Nothing -> main_RDR_Unqual } } ;
 737
 738          check_main ghci_mode tcg_env main_mod main_fn
 739     }
 740
 741
 742 check_main ghci_mode tcg_env main_mod main_fn
 743  | mod /= main_mod
 744  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
 745    return tcg_env
 746
 747  | otherwise
 748  = addErrCtxt mainCtxt                  $
 749    do   { mb_main <- lookupSrcOcc_maybe main_fn
 750                 -- Check that 'main' is in scope
 751                 -- It might be imported from another module!
 752         ; case mb_main of {
 753              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
 754                            ; complain_no_main
 755                            ; return tcg_env } ;
 756              Just main_name -> do
 757         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
 758         ; let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 759                         -- :Main.main :: IO () = runMainIO main
 760
 761         ; (main_expr, ty) <- setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 762                              tcInferRho rhs
 763
 764         ; let { root_main_id = mkExportedLocalId rootMainName ty ;
 765                 main_bind    = noLoc (VarBind root_main_id main_expr) }
 766
 767         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 768                                         `snocBag` main_bind,
 769                             tcg_dus   = tcg_dus tcg_env
 770                                         `plusDU` usesOnly (unitFV main_name)
 771                         -- Record the use of 'main', so that we don't
 772                         -- complain about it being defined but not used
 773                  })
 774     }}}
 775   where
 776     mod = tcg_mod tcg_env
 777
 778     complain_no_main | ghci_mode == Interactive = return ()
 779                      | otherwise                = failWithTc noMainMsg
 780         -- In interactive mode, don't worry about the absence of 'main'
 781         -- In other modes, fail altogether, so that we don't go on
 782         -- and complain a second time when processing the export list.
 783
 784     mainCtxt  = ptext SLIT("When checking the type of the main function") <+> quotes (ppr main_fn)
 785     noMainMsg = ptext SLIT("The main function") <+> quotes (ppr main_fn)
 786                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 787 \end{code}
 788
 789 %*********************************************************
 790 %*                                                       *
 791                 GHCi stuff
 792 %*                                                       *
 793 %*********************************************************
 794
 795 \begin{code}
 796 #ifdef GHCI
 797 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 798 setInteractiveContext hsc_env icxt thing_inside
 799   = let
 800         -- Initialise the tcg_inst_env with instances
 801         -- from all home modules.  This mimics the more selective
 802         -- call to hptInstances in tcRnModule
 803         dfuns = hptInstances hsc_env (\mod -> True)
 804     in
 805     updGblEnv (\env -> env {
 806         tcg_rdr_env  = ic_rn_gbl_env icxt,
 807         tcg_type_env = ic_type_env   icxt,
 808         tcg_inst_env = extendInstEnvList (tcg_inst_env env) dfuns }) $
 809
 810     updLclEnv (\env -> env { tcl_rdr = ic_rn_local_env icxt })  $
 811
 812     do  { traceTc (text "setIC" <+> ppr (ic_type_env icxt))
 813         ; thing_inside }
 814 \end{code}
 815
 816
 817 \begin{code}
 818 tcRnStmt :: HscEnv
 819          -> InteractiveContext
 820          -> LStmt RdrName
 821          -> IO (Maybe (InteractiveContext, [Name], LHsExpr Id))
 822                 -- The returned [Name] is the same as the input except for
 823                 -- ExprStmt, in which case the returned [Name] is [itName]
 824                 --
 825                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 826                 -- a list of the bound values, coerced to ().
 827
 828 tcRnStmt hsc_env ictxt rdr_stmt
 829   = initTcPrintErrors hsc_env iNTERACTIVE $
 830     setInteractiveContext hsc_env ictxt $ do {
 831
 832     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 833     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 834     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 835     failIfErrsM ;
 836
 837     -- The real work is done here
 838     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
 839     zonked_expr <- zonkTopLExpr tc_expr ;
 840     zonked_ids  <- zonkTopBndrs bound_ids ;
 841
 842         -- None of the Ids should be of unboxed type, because we
 843         -- cast them all to HValues in the end!
 844     mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
 845
 846     traceTc (text "tcs 1") ;
 847     let {       -- (a) Make all the bound ids "global" ids, now that
 848                 --     they're notionally top-level bindings.  This is
 849                 --     important: otherwise when we come to compile an expression
 850                 --     using these ids later, the byte code generator will consider
 851                 --     the occurrences to be free rather than global.
 852                 --
 853                 -- (b) Tidy their types; this is important, because :info may
 854                 --     ask to look at them, and :info expects the things it looks
 855                 --     up to have tidy types
 856         global_ids = map globaliseAndTidy zonked_ids ;
 857
 858                 -- Update the interactive context
 859         rn_env   = ic_rn_local_env ictxt ;
 860         type_env = ic_type_env ictxt ;
 861
 862         bound_names = map idName global_ids ;
 863         new_rn_env  = extendLocalRdrEnv rn_env bound_names ;
 864
 865                 -- Remove any shadowed bindings from the type_env;
 866                 -- they are inaccessible but might, I suppose, cause
 867                 -- a space leak if we leave them there
 868         shadowed = [ n | name <- bound_names,
 869                          let rdr_name = mkRdrUnqual (nameOccName name),
 870                          Just n <- [lookupLocalRdrEnv rn_env rdr_name] ] ;
 871
 872         filtered_type_env = delListFromNameEnv type_env shadowed ;
 873         new_type_env = extendTypeEnvWithIds filtered_type_env global_ids ;
 874
 875         new_ic = ictxt { ic_rn_local_env = new_rn_env,
 876                          ic_type_env     = new_type_env }
 877     } ;
 878
 879     dumpOptTcRn Opt_D_dump_tc
 880         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 881                text "Typechecked expr" <+> ppr zonked_expr]) ;
 882
 883     returnM (new_ic, bound_names, zonked_expr)
 884     }
 885   where
 886     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
 887                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
 888
 889 globaliseAndTidy :: Id -> Id
 890 globaliseAndTidy id
 891 -- Give the Id a Global Name, and tidy its type
 892   = setIdType (globaliseId VanillaGlobal id) tidy_type
 893   where
 894     tidy_type = tidyTopType (idType id)
 895 \end{code}
 896
 897 Here is the grand plan, implemented in tcUserStmt
 898
 899         What you type                   The IO [HValue] that hscStmt returns
 900         -------------                   ------------------------------------
 901         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 902                                         bindings: [x,y,...]
 903
 904         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 905                                         bindings: [x,y,...]
 906
 907         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 908           [NB: result not printed]      bindings: [it]
 909
 910         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 911           result showable)              bindings: [it]
 912
 913         expr (of non-IO type,
 914           result not showable)  ==>     error
 915
 916
 917 \begin{code}
 918 ---------------------------
 919 type PlanResult = ([Id], LHsExpr Id)
 920 type Plan = TcM PlanResult
 921
 922 runPlans :: [Plan] -> TcM PlanResult
 923 -- Try the plans in order.  If one fails (by raising an exn), try the next.
 924 -- If one succeeds, take it.
 925 runPlans []     = panic "runPlans"
 926 runPlans [p]    = p
 927 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
 928
 929 --------------------
 930 mkPlan :: LStmt Name -> TcM PlanResult
 931 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
 932   = do  { uniq <- newUnique             -- is treated very specially
 933         ; let fresh_it  = itName uniq
 934               the_bind  = mkVarBind noSrcSpan fresh_it expr
 935               let_stmt  = L loc $ LetStmt [HsBindGroup (unitBag the_bind) [] NonRecursive]
 936               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
 937                                            (HsVar bindIOName) noSyntaxExpr
 938               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
 939                                            (HsVar thenIOName) placeHolderType
 940
 941         -- The plans are:
 942         --      [it <- e; print it]     but not if it::()
 943         --      [it <- e]
 944         --      [let it = e; print it]
 945         ; runPlans [    -- Plan A
 946                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
 947                        ; it_ty <- zonkTcType (idType it_id)
 948                        ; ifM (isUnitTy it_ty) failM
 949                        ; return stuff },
 950
 951                         -- Plan B; a naked bind statment
 952                     tcGhciStmts [bind_stmt],
 953
 954                         -- Plan C; check that the let-binding is typeable all by itself.
 955                         -- If not, fail; if so, try to print it.
 956                         -- The two-step process avoids getting two errors: one from
 957                         -- the expression itself, and one from the 'print it' part
 958                         -- This two-step story is very clunky, alas
 959                     do { checkNoErrs (tcGhciStmts [let_stmt])
 960                                 --- checkNoErrs defeats the error recovery of let-bindings
 961                        ; tcGhciStmts [let_stmt, print_it] }
 962           ]}
 963
 964 mkPlan stmt@(L loc (BindStmt {}))
 965   | [L _ v] <- collectLStmtBinders stmt         -- One binder, for a bind stmt
 966   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
 967                                            (HsVar thenIOName) placeHolderType
 968         -- The plans are:
 969         --      [stmt; print v]         but not if v::()
 970         --      [stmt]
 971         ; runPlans [do { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
 972                        ; v_ty <- zonkTcType (idType v_id)
 973                        ; ifM (isUnitTy v_ty || not (isTauTy v_ty)) failM
 974                        ; return stuff },
 975                     tcGhciStmts [stmt]
 976           ]}
 977
 978 mkPlan stmt
 979   = tcGhciStmts [stmt]
 980
 981 ---------------------------
 982 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
 983 tcGhciStmts stmts
 984  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
 985         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
 986         let {
 987             io_ty     = mkTyConApp ioTyCon [] ;
 988             ret_ty    = mkListTy unitTy ;
 989             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
 990
 991             names = map unLoc (collectLStmtsBinders stmts) ;
 992
 993                 -- mk_return builds the expression
 994                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
 995                 --
 996                 -- Despite the inconvenience of building the type applications etc,
 997                 -- this *has* to be done in type-annotated post-typecheck form
 998                 -- because we are going to return a list of *polymorphic* values
 999                 -- coerced to type (). If we built a *source* stmt
1000                 --      return [coerce x, ..., coerce z]
1001                 -- then the type checker would instantiate x..z, and we wouldn't
1002                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1003                 -- if they were overloaded, since they aren't applied to anything.)
1004             mk_return ids = nlHsApp (noLoc $ TyApp (nlHsVar ret_id) [ret_ty])
1005                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1006             mk_item id = nlHsApp (noLoc $ TyApp (nlHsVar unsafeCoerceId) [idType id, unitTy])
1007                                  (nlHsVar id)
1008          } ;
1009
1010         -- OK, we're ready to typecheck the stmts
1011         traceTc (text "tcs 2") ;
1012         ((tc_stmts, ids), lie) <- getLIE $
1013                                   tcStmts DoExpr (tcDoStmt io_ty io_ret_ty) stmts $
1014                                   mappM tcLookupId names ;
1015                                         -- Look up the names right in the middle,
1016                                         -- where they will all be in scope
1017
1018         -- Simplify the context
1019         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1020                 -- checkNoErrs ensures that the plan fails if context redn fails
1021
1022         return (ids, mkHsLet const_binds $
1023                      noLoc (HsDo DoExpr tc_stmts (mk_return ids) io_ret_ty))
1024     }
1025 \end{code}
1026
1027
1028 tcRnExpr just finds the type of an expression
1029
1030 \begin{code}
1031 tcRnExpr :: HscEnv
1032          -> InteractiveContext
1033          -> LHsExpr RdrName
1034          -> IO (Maybe Type)
1035 tcRnExpr hsc_env ictxt rdr_expr
1036   = initTcPrintErrors hsc_env iNTERACTIVE $
1037     setInteractiveContext hsc_env ictxt $ do {
1038
1039     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1040     failIfErrsM ;
1041
1042         -- Now typecheck the expression;
1043         -- it might have a rank-2 type (e.g. :t runST)
1044     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1045     ((qtvs, _, dict_ids), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1046     tcSimplifyInteractive lie_top ;
1047     qtvs' <- mappM zonkQuantifiedTyVar qtvs ;
1048
1049     let { all_expr_ty = mkForAllTys qtvs' $
1050                         mkFunTys (map idType dict_ids)  $
1051                         res_ty } ;
1052     zonkTcType all_expr_ty
1053     }
1054   where
1055     smpl_doc = ptext SLIT("main expression")
1056 \end{code}
1057
1058 tcRnType just finds the kind of a type
1059
1060 \begin{code}
1061 tcRnType :: HscEnv
1062          -> InteractiveContext
1063          -> LHsType RdrName
1064          -> IO (Maybe Kind)
1065 tcRnType hsc_env ictxt rdr_type
1066   = initTcPrintErrors hsc_env iNTERACTIVE $
1067     setInteractiveContext hsc_env ictxt $ do {
1068
1069     rn_type <- rnLHsType doc rdr_type ;
1070     failIfErrsM ;
1071
1072         -- Now kind-check the type
1073     (ty', kind) <- kcHsType rn_type ;
1074     return kind
1075     }
1076   where
1077     doc = ptext SLIT("In GHCi input")
1078
1079 #endif /* GHCi */
1080 \end{code}
1081
1082
1083 %************************************************************************
1084 %*                                                                      *
1085         More GHCi stuff, to do with browsing and getting info
1086 %*                                                                      *
1087 %************************************************************************
1088
1089 \begin{code}
1090 #ifdef GHCI
1091 -- ASSUMES that the module is either in the HomePackageTable or is
1092 -- a package module with an interface on disk.  If neither of these is
1093 -- true, then the result will be an error indicating the interface
1094 -- could not be found.
1095 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe NameSet)
1096 getModuleExports hsc_env mod
1097   = initTc hsc_env HsSrcFile iNTERACTIVE (tcGetModuleExports mod)
1098
1099 tcGetModuleExports :: Module -> TcM NameSet
1100 tcGetModuleExports mod = do
1101   iface <- load_iface mod
1102   loadOrphanModules (dep_orphs (mi_deps iface))
1103                 -- Load any orphan-module interfaces,
1104                 -- so their instances are visible
1105   ifaceExportNames (mi_exports iface)
1106
1107 load_iface mod = loadSrcInterface doc mod False {- Not boot iface -}
1108                where
1109                  doc = ptext SLIT("context for compiling statements")
1110
1111
1112 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Maybe [Name])
1113 tcRnLookupRdrName hsc_env rdr_name
1114   = initTcPrintErrors hsc_env iNTERACTIVE $
1115     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1116     lookup_rdr_name rdr_name
1117
1118 lookup_rdr_name rdr_name = do {
1119         -- If the identifier is a constructor (begins with an
1120         -- upper-case letter), then we need to consider both
1121         -- constructor and type class identifiers.
1122     let { rdr_names = dataTcOccs rdr_name } ;
1123
1124         -- results :: [Either Messages Name]
1125     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1126
1127     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1128         -- The successful lookups will be (Just name)
1129     let { (warns_s, good_names) = unzip [ (msgs, name)
1130                                         | (msgs, Just name) <- results] ;
1131           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1132
1133         -- Fail if nothing good happened, else add warnings
1134     if null good_names then
1135                 -- No lookup succeeded, so
1136                 -- pick the first error message and report it
1137                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1138                 --       while the other is "X is not in scope",
1139                 --       we definitely want the former; but we might pick the latter
1140         do { addMessages (head errs_s) ; failM }
1141       else                      -- Add deprecation warnings
1142         mapM_ addMessages warns_s ;
1143
1144     return good_names
1145  }
1146
1147
1148 tcRnLookupName :: HscEnv -> Name -> IO (Maybe TyThing)
1149 tcRnLookupName hsc_env name
1150   = initTcPrintErrors hsc_env iNTERACTIVE $
1151     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1152     tcLookupGlobal name
1153
1154
1155 tcRnGetInfo :: HscEnv
1156             -> Name
1157             -> IO (Maybe (TyThing, Fixity, [Instance]))
1158
1159 -- Used to implemnent :info in GHCi
1160 --
1161 -- Look up a RdrName and return all the TyThings it might be
1162 -- A capitalised RdrName is given to us in the DataName namespace,
1163 -- but we want to treat it as *both* a data constructor
1164 --  *and* as a type or class constructor;
1165 -- hence the call to dataTcOccs, and we return up to two results
1166 tcRnGetInfo hsc_env name
1167   = initTcPrintErrors hsc_env iNTERACTIVE $
1168     let ictxt = hsc_IC hsc_env in
1169     setInteractiveContext hsc_env ictxt $ do
1170
1171         -- Load the interface for all unqualified types and classes
1172         -- That way we will find all the instance declarations
1173         -- (Packages have not orphan modules, and we assume that
1174         --  in the home package all relevant modules are loaded.)
1175     loadUnqualIfaces ictxt
1176
1177     thing  <- tcLookupGlobal name
1178     fixity <- lookupFixityRn name
1179     ispecs <- lookupInsts (icPrintUnqual ictxt) thing
1180     return (thing, fixity, ispecs)
1181
1182
1183 lookupInsts :: PrintUnqualified -> TyThing -> TcM [Instance]
1184 -- Filter the instances by the ones whose tycons (or clases resp)
1185 -- are in scope unqualified.  Otherwise we list a whole lot too many!
1186 lookupInsts print_unqual (AClass cls)
1187   = do  { inst_envs <- tcGetInstEnvs
1188         ; return [ ispec
1189                  | ispec <- classInstances inst_envs cls
1190                  , plausibleDFun print_unqual (instanceDFunId ispec) ] }
1191
1192 lookupInsts print_unqual (ATyCon tc)
1193   = do  { eps <- getEps -- Load all instances for all classes that are
1194                         -- in the type environment (which are all the ones
1195                         -- we've seen in any interface file so far)
1196         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1197         ; return [ ispec
1198                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1199                  , let dfun = instanceDFunId ispec
1200                  , relevant dfun
1201                  , plausibleDFun print_unqual dfun ] }
1202   where
1203     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1204     tc_name     = tyConName tc
1205
1206 lookupInsts print_unqual other = return []
1207
1208 plausibleDFun print_unqual dfun -- Dfun involving only names that print unqualified
1209   = all ok (nameSetToList (tyClsNamesOfType (idType dfun)))
1210   where
1211     ok name | isBuiltInSyntax name = True
1212             | isExternalName name  = print_unqual (nameModule name) (nameOccName name)
1213             | otherwise            = True
1214
1215 loadUnqualIfaces :: InteractiveContext -> TcM ()
1216 -- Load the home module for everything that is in scope unqualified
1217 -- This is so that we can accurately report the instances for
1218 -- something
1219 loadUnqualIfaces ictxt
1220   = initIfaceTcRn $
1221     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1222   where
1223     unqual_mods = [ nameModule name
1224                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1225                     let name = gre_name gre,
1226                     isTcOcc (nameOccName name),  -- Types and classes only
1227                     unQualOK gre ]               -- In scope unqualified
1228     doc = ptext SLIT("Need interface for module whose export(s) are in scope unqualified")
1229 #endif /* GHCI */
1230 \end{code}
1231
1232 %************************************************************************
1233 %*                                                                      *
1234                 Degugging output
1235 %*                                                                      *
1236 %************************************************************************
1237
1238 \begin{code}
1239 rnDump :: SDoc -> TcRn ()
1240 -- Dump, with a banner, if -ddump-rn
1241 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1242
1243 tcDump :: TcGblEnv -> TcRn ()
1244 tcDump env
1245  = do { dflags <- getDOpts ;
1246
1247         -- Dump short output if -ddump-types or -ddump-tc
1248         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1249             (dumpTcRn short_dump) ;
1250
1251         -- Dump bindings if -ddump-tc
1252         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1253    }
1254   where
1255     short_dump = pprTcGblEnv env
1256     full_dump  = pprLHsBinds (tcg_binds env)
1257         -- NB: foreign x-d's have undefined's in their types;
1258         --     hence can't show the tc_fords
1259
1260 tcCoreDump mod_guts
1261  = do { dflags <- getDOpts ;
1262         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1263             (dumpTcRn (pprModGuts mod_guts)) ;
1264
1265         -- Dump bindings if -ddump-tc
1266         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1267   where
1268     full_dump = pprCoreBindings (mg_binds mod_guts)
1269
1270 -- It's unpleasant having both pprModGuts and pprModDetails here
1271 pprTcGblEnv :: TcGblEnv -> SDoc
1272 pprTcGblEnv (TcGblEnv { tcg_type_env = type_env,
1273                         tcg_insts    = dfun_ids,
1274                         tcg_rules    = rules,
1275                         tcg_imports  = imports })
1276   = vcat [ ppr_types dfun_ids type_env
1277          , ppr_insts dfun_ids
1278          , vcat (map ppr rules)
1279          , ppr_gen_tycons (typeEnvTyCons type_env)
1280          , ptext SLIT("Dependent modules:") <+> ppr (moduleEnvElts (imp_dep_mods imports))
1281          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1282
1283 pprModGuts :: ModGuts -> SDoc
1284 pprModGuts (ModGuts { mg_types = type_env,
1285                       mg_rules = rules })
1286   = vcat [ ppr_types [] type_env,
1287            ppr_rules rules ]
1288
1289
1290 ppr_types :: [Instance] -> TypeEnv -> SDoc
1291 ppr_types ispecs type_env
1292   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1293   where
1294     dfun_ids = map instanceDFunId ispecs
1295     ids = [id | id <- typeEnvIds type_env, want_sig id]
1296     want_sig id | opt_PprStyle_Debug = True
1297                 | otherwise          = isLocalId id &&
1298                                        isExternalName (idName id) &&
1299                                        not (id `elem` dfun_ids)
1300         -- isLocalId ignores data constructors, records selectors etc.
1301         -- The isExternalName ignores local dictionary and method bindings
1302         -- that the type checker has invented.  Top-level user-defined things
1303         -- have External names.
1304
1305 ppr_insts :: [Instance] -> SDoc
1306 ppr_insts []     = empty
1307 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1308
1309 ppr_sigs :: [Var] -> SDoc
1310 ppr_sigs ids
1311         -- Print type signatures; sort by OccName
1312   = vcat (map ppr_sig (sortLe le_sig ids))
1313   where
1314     le_sig id1 id2 = getOccName id1 <= getOccName id2
1315     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1316
1317 ppr_rules :: [CoreRule] -> SDoc
1318 ppr_rules [] = empty
1319 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1320                       nest 4 (pprRules rs),
1321                       ptext SLIT("#-}")]
1322
1323 ppr_gen_tycons []  = empty
1324 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1325                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1326 \end{code}