ghc/compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcRnDriver (
   8 #ifdef GHCI
   9         mkExportEnv, getModuleContents, tcRnStmt,
  10         tcRnGetInfo, GetInfoResult,
  11         tcRnExpr, tcRnType,
  12 #endif
  13         tcRnModule,
  14         tcTopSrcDecls,
  15         tcRnExtCore
  16     ) where
  17
  18 #include "HsVersions.h"
  19
  20 import IO
  21 #ifdef GHCI
  22 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  23 #endif
  24
  25 import DynFlags         ( DynFlag(..), DynFlags(..), dopt, GhcMode(..) )
  26 import StaticFlags      ( opt_PprStyle_Debug )
  27 import Packages         ( moduleToPackageConfig, mkPackageId, package,
  28                           isHomeModule )
  29 import HsSyn            ( HsModule(..), HsExtCore(..), HsGroup(..), LHsDecl, SpliceDecl(..), HsBind(..),
  30                           nlHsApp, nlHsVar, pprLHsBinds )
  31 import RdrHsSyn         ( findSplice )
  32
  33 import PrelNames        ( runMainIOName, rootMainName, mAIN,
  34                           main_RDR_Unqual )
  35 import RdrName          ( RdrName, mkRdrUnqual, emptyGlobalRdrEnv,
  36                           plusGlobalRdrEnv )
  37 import TcHsSyn          ( zonkTopDecls )
  38 import TcExpr           ( tcInferRho )
  39 import TcRnMonad
  40 import TcType           ( tidyTopType, tcEqType, mkTyVarTys, substTyWith )
  41 import Inst             ( showLIE )
  42 import InstEnv          ( extendInstEnvList )
  43 import TcBinds          ( tcTopBinds, tcHsBootSigs )
  44 import TcDefaults       ( tcDefaults )
  45 import TcEnv            ( tcExtendGlobalValEnv )
  46 import TcRules          ( tcRules )
  47 import TcForeign        ( tcForeignImports, tcForeignExports )
  48 import TcInstDcls       ( tcInstDecls1, tcInstDecls2 )
  49 import TcIface          ( tcExtCoreBindings )
  50 import TcSimplify       ( tcSimplifyTop )
  51 import TcTyClsDecls     ( tcTyAndClassDecls )
  52 import LoadIface        ( loadOrphanModules, loadHiBootInterface )
  53 import RnNames          ( importsFromLocalDecls, rnImports, exportsFromAvail,
  54                           reportUnusedNames, reportDeprecations )
  55 import RnEnv            ( lookupSrcOcc_maybe )
  56 import RnSource         ( rnSrcDecls, rnTyClDecls, checkModDeprec )
  57 import PprCore          ( pprIdRules, pprCoreBindings )
  58 import CoreSyn          ( IdCoreRule, bindersOfBinds )
  59 import DataCon          ( dataConWrapId )
  60 import ErrUtils         ( Messages, mkDumpDoc, showPass )
  61 import Id               ( mkExportedLocalId, isLocalId, idName, idType )
  62 import Var              ( Var )
  63 import VarEnv           ( varEnvElts )
  64 import Module           ( Module, ModuleEnv, mkModule, moduleEnvElts, lookupModuleEnv )
  65 import OccName          ( mkVarOcc )
  66 import Name             ( Name, isExternalName, getSrcLoc, getOccName, isWiredInName )
  67 import NameSet
  68 import TyCon            ( tyConHasGenerics, isSynTyCon, getSynTyConDefn, tyConKind )
  69 import SrcLoc           ( srcLocSpan, Located(..), noLoc )
  70 import DriverPhases     ( HscSource(..), isHsBoot )
  71 import HscTypes         ( ModGuts(..), HscEnv(..), ExternalPackageState(..),
  72                           IsBootInterface, noDependencies,
  73                           Deprecs( NoDeprecs ), plusDeprecs,
  74                           ForeignStubs(NoStubs), TyThing(..),
  75                           TypeEnv, lookupTypeEnv, hptInstances, lookupType,
  76                           extendTypeEnvWithIds, typeEnvIds, typeEnvTyCons,
  77                           emptyFixityEnv
  78                         )
  79 import Outputable
  80
  81 #ifdef GHCI
  82 import HsSyn            ( HsStmtContext(..), Stmt(..), HsExpr(..), HsBindGroup(..),
  83                           LStmt, LHsExpr, LHsType, mkMatchGroup,
  84                           collectStmtsBinders, mkSimpleMatch,
  85                           nlLetStmt, nlExprStmt, nlBindStmt, nlResultStmt, nlVarPat )
  86 import RdrName          ( GlobalRdrEnv, mkGlobalRdrEnv, GlobalRdrElt(..),
  87                           Provenance(..), ImportSpec(..),
  88                           lookupLocalRdrEnv, extendLocalRdrEnv )
  89 import RnSource         ( addTcgDUs )
  90 import TcHsSyn          ( mkHsLet, zonkTopLExpr, zonkTopBndrs )
  91 import TcHsType         ( kcHsType )
  92 import TcExpr           ( tcCheckRho )
  93 import TcIface          ( loadImportedInsts )
  94 import TcMType          ( zonkTcType, zonkQuantifiedTyVar )
  95 import TcUnify          ( unifyTyConApp )
  96 import TcMatches        ( tcStmtsAndThen, TcStmtCtxt(..) )
  97 import TcSimplify       ( tcSimplifyInteractive, tcSimplifyInfer )
  98 import TcType           ( Type, mkForAllTys, mkFunTys, mkTyConApp, tyVarsOfType,
  99                           isUnLiftedType, tyClsNamesOfDFunHead )
 100 import TcEnv            ( tcLookupTyCon, tcLookupId, tcLookupGlobal )
 101 import RnTypes          ( rnLHsType )
 102 import Inst             ( tcStdSyntaxName, tcGetInstEnvs )
 103 import InstEnv          ( DFunId, classInstances, instEnvElts )
 104 import RnExpr           ( rnStmts, rnLExpr )
 105 import RnNames          ( exportsToAvails )
 106 import LoadIface        ( loadSrcInterface, ifaceInstGates )
 107 import IfaceSyn         ( IfaceDecl(..), IfaceClassOp(..), IfaceConDecl(..),
 108                           IfaceExtName(..), IfaceConDecls(..), IfaceInst(..),
 109                           tyThingToIfaceDecl, dfunToIfaceInst )
 110 import IfaceType        ( IfaceTyCon(..), IfaceType, toIfaceType,
 111                           interactiveExtNameFun, isLocalIfaceExtName )
 112 import IfaceEnv         ( lookupOrig )
 113 import RnEnv            ( lookupOccRn, dataTcOccs, lookupFixityRn )
 114 import Id               ( Id, isImplicitId, setIdType, globalIdDetails )
 115 import MkId             ( unsafeCoerceId )
 116 import DataCon          ( dataConTyCon )
 117 import TyCon            ( tyConName )
 118 import TysWiredIn       ( mkListTy, unitTy )
 119 import IdInfo           ( GlobalIdDetails(..) )
 120 import SrcLoc           ( interactiveSrcLoc, unLoc )
 121 import Kind             ( Kind )
 122 import Var              ( globaliseId )
 123 import Name             ( nameOccName )
 124 import OccName          ( occNameUserString )
 125 import NameEnv          ( delListFromNameEnv )
 126 import PrelNames        ( iNTERACTIVE, ioTyConName, printName, monadNames, itName, returnIOName )
 127 import HscTypes         ( InteractiveContext(..), HomeModInfo(..), typeEnvElts, typeEnvClasses,
 128                           availNames, availName, ModIface(..), icPrintUnqual,
 129                           ModDetails(..), Dependencies(..) )
 130 import BasicTypes       ( RecFlag(..), Fixity )
 131 import Bag              ( unitBag )
 132 import ListSetOps       ( removeDups )
 133 import Panic            ( ghcError, GhcException(..) )
 134 import SrcLoc           ( SrcLoc )
 135 #endif
 136
 137 import FastString       ( mkFastString )
 138 import Util             ( sortLe )
 139 import Bag              ( unionBags, snocBag )
 140
 141 import Maybe            ( isJust )
 142 \end{code}
 143
 144
 145
 146 %************************************************************************
 147 %*                                                                      *
 148         Typecheck and rename a module
 149 %*                                                                      *
 150 %************************************************************************
 151
 152
 153 \begin{code}
 154 tcRnModule :: HscEnv
 155            -> HscSource
 156            -> Located (HsModule RdrName)
 157            -> IO (Messages, Maybe TcGblEnv)
 158
 159 tcRnModule hsc_env hsc_src (L loc (HsModule maybe_mod export_ies
 160                                 import_decls local_decls mod_deprec))
 161  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 162
 163    let { this_mod = case maybe_mod of
 164                         Nothing  -> mAIN          -- 'module M where' is omitted
 165                         Just (L _ mod) -> mod } ; -- The normal case
 166
 167    initTc hsc_env hsc_src this_mod $
 168    setSrcSpan loc $
 169    do {
 170         checkForPackageModule (hsc_dflags hsc_env) this_mod;
 171
 172                 -- Deal with imports; sets tcg_rdr_env, tcg_imports
 173         (rdr_env, imports) <- rnImports import_decls ;
 174
 175         let { dep_mods :: ModuleEnv (Module, IsBootInterface)
 176             ; dep_mods = imp_dep_mods imports
 177
 178             ; is_dep_mod :: Module -> Bool
 179             ; is_dep_mod mod = case lookupModuleEnv dep_mods mod of
 180                                 Nothing           -> False
 181                                 Just (_, is_boot) -> not is_boot
 182             ; home_insts = hptInstances hsc_env is_dep_mod
 183             } ;
 184
 185                 -- Record boot-file info in the EPS, so that it's
 186                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 187                 -- and any other incrementally-performed imports
 188         updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 189
 190                 -- Update the gbl env
 191         updGblEnv ( \ gbl ->
 192                 gbl { tcg_rdr_env  = rdr_env,
 193                       tcg_inst_env = extendInstEnvList (tcg_inst_env gbl) home_insts,
 194                       tcg_imports  = tcg_imports gbl `plusImportAvails` imports })
 195                 $ do {
 196
 197         traceRn (text "rn1" <+> ppr (imp_dep_mods imports)) ;
 198                 -- Fail if there are any errors so far
 199                 -- The error printing (if needed) takes advantage
 200                 -- of the tcg_env we have now set
 201         failIfErrsM ;
 202
 203                 -- Load any orphan-module interfaces, so that
 204                 -- their rules and instance decls will be found
 205         loadOrphanModules (imp_orphs imports) ;
 206
 207         traceRn (text "rn1a") ;
 208                 -- Rename and type check the declarations
 209         tcg_env <- if isHsBoot hsc_src then
 210                         tcRnHsBootDecls local_decls
 211                    else
 212                         tcRnSrcDecls local_decls ;
 213         setGblEnv tcg_env               $ do {
 214
 215         traceRn (text "rn3") ;
 216
 217                 -- Report the use of any deprecated things
 218                 -- We do this before processsing the export list so
 219                 -- that we don't bleat about re-exporting a deprecated
 220                 -- thing (especially via 'module Foo' export item)
 221                 -- Only uses in the body of the module are complained about
 222         reportDeprecations tcg_env ;
 223
 224                 -- Process the export list
 225         exports <- exportsFromAvail (isJust maybe_mod) export_ies ;
 226
 227                 -- Check whether the entire module is deprecated
 228                 -- This happens only once per module
 229         let { mod_deprecs = checkModDeprec mod_deprec } ;
 230
 231                 -- Add exports and deprecations to envt
 232         let { final_env  = tcg_env { tcg_exports = exports,
 233                                      tcg_dus = tcg_dus tcg_env `plusDU` usesOnly exports,
 234                                      tcg_deprecs = tcg_deprecs tcg_env `plusDeprecs`
 235                                                    mod_deprecs }
 236                 -- A module deprecation over-rides the earlier ones
 237              } ;
 238
 239                 -- Report unused names
 240         reportUnusedNames export_ies final_env ;
 241
 242                 -- Dump output and return
 243         tcDump final_env ;
 244         return final_env
 245     }}}}
 246
 247 -- This is really a sanity check that the user has given -package-name
 248 -- if necessary.  -package-name is only necessary when the package database
 249 -- already contains the current package, because then we can't tell
 250 -- whether a given module is in the current package or not, without knowing
 251 -- the name of the current package.
 252 checkForPackageModule dflags this_mod
 253   | not (isHomeModule dflags this_mod),
 254     Just (pkg,_) <- moduleToPackageConfig dflags this_mod =
 255         let
 256                 ppr_pkg = ppr (mkPackageId (package pkg))
 257         in
 258         addErr (ptext SLIT("Module") <+> quotes (ppr this_mod) <+>
 259                 ptext SLIT("is a member of package") <+>  ppr_pkg <> char '.' $$
 260                 ptext SLIT("To compile this module, please use -ignore-package") <+> ppr_pkg <> char '.')
 261   | otherwise = return ()
 262 \end{code}
 263
 264
 265 %************************************************************************
 266 %*                                                                      *
 267         Type-checking external-core modules
 268 %*                                                                      *
 269 %************************************************************************
 270
 271 \begin{code}
 272 tcRnExtCore :: HscEnv
 273             -> HsExtCore RdrName
 274             -> IO (Messages, Maybe ModGuts)
 275         -- Nothing => some error occurred
 276
 277 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 278         -- The decls are IfaceDecls; all names are original names
 279  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 280
 281    initTc hsc_env ExtCoreFile this_mod $ do {
 282
 283    let { ldecls  = map noLoc decls } ;
 284
 285         -- Deal with the type declarations; first bring their stuff
 286         -- into scope, then rname them, then type check them
 287    (rdr_env, imports) <- importsFromLocalDecls (mkFakeGroup ldecls) ;
 288
 289    updGblEnv (\gbl -> gbl { tcg_rdr_env = rdr_env `plusGlobalRdrEnv` tcg_rdr_env gbl,
 290                             tcg_imports = imports `plusImportAvails` tcg_imports gbl })
 291                   $ do {
 292
 293    rn_decls <- rnTyClDecls ldecls ;
 294    failIfErrsM ;
 295
 296         -- Dump trace of renaming part
 297    rnDump (ppr rn_decls) ;
 298
 299         -- Typecheck them all together so that
 300         -- any mutually recursive types are done right
 301    tcg_env <- checkNoErrs (tcTyAndClassDecls [{- no boot names -}] rn_decls) ;
 302         -- Make the new type env available to stuff slurped from interface files
 303
 304    setGblEnv tcg_env $ do {
 305
 306         -- Now the core bindings
 307    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 308
 309         -- Wrap up
 310    let {
 311         bndrs      = bindersOfBinds core_binds ;
 312         my_exports = mkNameSet (map idName bndrs) ;
 313                 -- ToDo: export the data types also?
 314
 315         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 316
 317         mod_guts = ModGuts {    mg_module   = this_mod,
 318                                 mg_boot     = False,
 319                                 mg_usages   = [],               -- ToDo: compute usage
 320                                 mg_dir_imps = [],               -- ??
 321                                 mg_deps     = noDependencies,   -- ??
 322                                 mg_exports  = my_exports,
 323                                 mg_types    = final_type_env,
 324                                 mg_insts    = tcg_insts tcg_env,
 325                                 mg_rules    = [],
 326                                 mg_binds    = core_binds,
 327
 328                                 -- Stubs
 329                                 mg_rdr_env  = emptyGlobalRdrEnv,
 330                                 mg_fix_env  = emptyFixityEnv,
 331                                 mg_deprecs  = NoDeprecs,
 332                                 mg_foreign  = NoStubs
 333                     } } ;
 334
 335    tcCoreDump mod_guts ;
 336
 337    return mod_guts
 338    }}}}
 339
 340 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 341   = HsGroup {   hs_tyclds = decls,      -- This is the one we want
 342                 hs_valds = [], hs_fords = [],
 343                 hs_instds = [], hs_fixds = [], hs_depds = [],
 344                 hs_ruleds = [], hs_defds = [] }
 345 \end{code}
 346
 347
 348 %************************************************************************
 349 %*                                                                      *
 350         Type-checking the top level of a module
 351 %*                                                                      *
 352 %************************************************************************
 353
 354 \begin{code}
 355 tcRnSrcDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 356         -- Returns the variables free in the decls
 357         -- Reason: solely to report unused imports and bindings
 358 tcRnSrcDecls decls
 359  = do {         -- Load the hi-boot interface for this module, if any
 360                 -- We do this now so that the boot_names can be passed
 361                 -- to tcTyAndClassDecls, because the boot_names are
 362                 -- automatically considered to be loop breakers
 363         boot_names <- loadHiBootInterface ;
 364
 365                 -- Do all the declarations
 366         (tc_envs, lie) <- getLIE (tc_rn_src_decls boot_names decls) ;
 367
 368              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 369              -- How could there be ambiguous ones?  They can only arise if a
 370              -- top-level decl falls under the monomorphism
 371              -- restriction, and no subsequent decl instantiates its
 372              -- type.  (Usually, ambiguous type variables are resolved
 373              -- during the generalisation step.)
 374         traceTc (text "Tc8") ;
 375         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 376                 -- Setting the global env exposes the instances to tcSimplifyTop
 377                 -- Setting the local env exposes the local Ids to tcSimplifyTop,
 378                 -- so that we get better error messages (monomorphism restriction)
 379
 380             -- Backsubstitution.  This must be done last.
 381             -- Even tcSimplifyTop may do some unification.
 382         traceTc (text "Tc9") ;
 383         let { (tcg_env, _) = tc_envs ;
 384               TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 385                          tcg_rules = rules, tcg_fords = fords } = tcg_env } ;
 386
 387         (bind_ids, binds', fords', rules') <- zonkTopDecls (binds `unionBags` inst_binds)
 388                                                            rules fords ;
 389
 390         let { final_type_env = extendTypeEnvWithIds type_env bind_ids } ;
 391
 392         -- Compre the hi-boot iface (if any) with the real thing
 393         checkHiBootIface final_type_env boot_names ;
 394
 395         -- Make the new type env available to stuff slurped from interface files
 396         writeMutVar (tcg_type_env_var tcg_env) final_type_env ;
 397
 398         return (tcg_env { tcg_type_env = final_type_env,
 399                           tcg_binds = binds', tcg_rules = rules', tcg_fords = fords' })
 400    }
 401
 402 tc_rn_src_decls :: [Name] -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 403 -- Loops around dealing with each top level inter-splice group
 404 -- in turn, until it's dealt with the entire module
 405 tc_rn_src_decls boot_names ds
 406  = do { let { (first_group, group_tail) = findSplice ds } ;
 407                 -- If ds is [] we get ([], Nothing)
 408
 409         -- Type check the decls up to, but not including, the first splice
 410         tc_envs@(tcg_env,tcl_env) <- tcRnGroup boot_names first_group ;
 411
 412         -- Bale out if errors; for example, error recovery when checking
 413         -- the RHS of 'main' can mean that 'main' is not in the envt for
 414         -- the subsequent checkMain test
 415         failIfErrsM ;
 416
 417         setEnvs tc_envs $
 418
 419         -- If there is no splice, we're nearly done
 420         case group_tail of {
 421            Nothing -> do {      -- Last thing: check for `main'
 422                            tcg_env <- checkMain ;
 423                            return (tcg_env, tcl_env)
 424                       } ;
 425
 426         -- If there's a splice, we must carry on
 427            Just (SpliceDecl splice_expr, rest_ds) -> do {
 428 #ifndef GHCI
 429         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 430 #else
 431
 432         -- Rename the splice expression, and get its supporting decls
 433         (rn_splice_expr, splice_fvs) <- rnLExpr splice_expr ;
 434         failIfErrsM ;   -- Don't typecheck if renaming failed
 435
 436         -- Execute the splice
 437         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 438
 439         -- Glue them on the front of the remaining decls and loop
 440         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 441         tc_rn_src_decls boot_names (spliced_decls ++ rest_ds)
 442 #endif /* GHCI */
 443     }}}
 444 \end{code}
 445
 446 %************************************************************************
 447 %*                                                                      *
 448         Compiling hs-boot source files, and
 449         comparing the hi-boot interface with the real thing
 450 %*                                                                      *
 451 %************************************************************************
 452
 453 \begin{code}
 454 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 455 tcRnHsBootDecls decls
 456    = do { let { (first_group, group_tail) = findSplice decls }
 457
 458         ; case group_tail of
 459              Just stuff -> spliceInHsBootErr stuff
 460              Nothing    -> return ()
 461
 462                 -- Rename the declarations
 463         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 464         ; setGblEnv tcg_env $ do {
 465
 466         -- Todo: check no foreign decls, no rules, no default decls
 467
 468                 -- Typecheck type/class decls
 469         ; traceTc (text "Tc2")
 470         ; let tycl_decls = hs_tyclds rn_group
 471         ; tcg_env <- checkNoErrs (tcTyAndClassDecls [{- no boot_names -}] tycl_decls)
 472         ; setGblEnv tcg_env     $ do {
 473
 474                 -- Typecheck instance decls
 475         ; traceTc (text "Tc3")
 476         ; (tcg_env, inst_infos, _binds) <- tcInstDecls1 tycl_decls (hs_instds rn_group)
 477         ; setGblEnv tcg_env     $ do {
 478
 479                 -- Typecheck value declarations
 480         ; traceTc (text "Tc5")
 481         ; new_ids <- tcHsBootSigs (hs_valds rn_group)
 482
 483                 -- Wrap up
 484                 -- No simplification or zonking to do
 485         ; traceTc (text "Tc7a")
 486         ; gbl_env <- getGblEnv
 487
 488         ; let { final_type_env = extendTypeEnvWithIds (tcg_type_env gbl_env) new_ids }
 489         ; return (gbl_env { tcg_type_env = final_type_env })
 490    }}}}
 491
 492 spliceInHsBootErr (SpliceDecl (L loc _), _)
 493   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 494 \end{code}
 495
 496 In both one-shot mode and GHCi mode, hi-boot interfaces are demand-loaded
 497 into the External Package Table.  Once we've typechecked the body of the
 498 module, we want to compare what we've found (gathered in a TypeEnv) with
 499 the hi-boot stuff in the EPT.  We do so here, using the export list of
 500 the hi-boot interface as our checklist.
 501
 502 \begin{code}
 503 checkHiBootIface :: TypeEnv -> [Name] -> TcM ()
 504 -- Compare the hi-boot file for this module (if there is one)
 505 -- with the type environment we've just come up with
 506 -- In the common case where there is no hi-boot file, the list
 507 -- of boot_names is empty.
 508 checkHiBootIface env boot_names
 509   = mapM_ (check_one env) boot_names
 510
 511 ----------------
 512 check_one local_env name
 513   | isWiredInName name  -- No checking for wired-in names.  In particular, 'error'
 514   = return ()           -- is handled by a rather gross hack (see comments in GHC.Err.hs-boot)
 515   | otherwise
 516   = do  { (eps,hpt)  <- getEpsAndHpt
 517
 518                 -- Look up the hi-boot one;
 519                 -- it should jolly well be there (else GHC bug)
 520        ; case lookupType hpt (eps_PTE eps) name of {
 521             Nothing -> pprPanic "checkHiBootIface" (ppr name) ;
 522             Just boot_thing ->
 523
 524                 -- Look it up in the local type env
 525                 -- It should be there, but it's a programmer error if not
 526          case lookupTypeEnv local_env name of
 527            Nothing         -> addErrTc (missingBootThing boot_thing)
 528            Just real_thing -> check_thing boot_thing real_thing
 529     } }
 530
 531 ----------------
 532 check_thing (ATyCon boot_tc) (ATyCon real_tc)
 533   | isSynTyCon boot_tc && isSynTyCon real_tc,
 534     defn1 `tcEqType` substTyWith tvs2 (mkTyVarTys tvs1) defn2
 535   = return ()
 536
 537   | tyConKind boot_tc == tyConKind real_tc
 538   = return ()
 539   where
 540     (tvs1, defn1) = getSynTyConDefn boot_tc
 541     (tvs2, defn2) = getSynTyConDefn boot_tc
 542
 543 check_thing (AnId boot_id) (AnId real_id)
 544   | idType boot_id `tcEqType` idType real_id
 545   = return ()
 546
 547 check_thing (ADataCon dc1) (ADataCon dc2)
 548   | idType (dataConWrapId dc1) `tcEqType` idType (dataConWrapId dc2)
 549   = return ()
 550
 551         -- Can't declare a class in a hi-boot file
 552
 553 check_thing boot_thing real_thing       -- Default case; failure
 554   = addErrAt (srcLocSpan (getSrcLoc real_thing))
 555              (bootMisMatch real_thing)
 556
 557 ----------------
 558 missingBootThing thing
 559   = ppr thing <+> ptext SLIT("is defined in the hs-boot file, but not in the module")
 560 bootMisMatch thing
 561   = ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file")
 562 \end{code}
 563
 564
 565 %************************************************************************
 566 %*                                                                      *
 567         Type-checking the top level of a module
 568 %*                                                                      *
 569 %************************************************************************
 570
 571 tcRnGroup takes a bunch of top-level source-code declarations, and
 572  * renames them
 573  * gets supporting declarations from interface files
 574  * typechecks them
 575  * zonks them
 576  * and augments the TcGblEnv with the results
 577
 578 In Template Haskell it may be called repeatedly for each group of
 579 declarations.  It expects there to be an incoming TcGblEnv in the
 580 monad; it augments it and returns the new TcGblEnv.
 581
 582 \begin{code}
 583 tcRnGroup :: [Name] -> HsGroup RdrName -> TcM (TcGblEnv, TcLclEnv)
 584         -- Returns the variables free in the decls, for unused-binding reporting
 585 tcRnGroup boot_names decls
 586  = do {         -- Rename the declarations
 587         (tcg_env, rn_decls) <- rnTopSrcDecls decls ;
 588         setGblEnv tcg_env $ do {
 589
 590                 -- Typecheck the declarations
 591         tcTopSrcDecls boot_names rn_decls
 592   }}
 593
 594 ------------------------------------------------
 595 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 596 rnTopSrcDecls group
 597  = do {         -- Bring top level binders into scope
 598         (rdr_env, imports) <- importsFromLocalDecls group ;
 599         updGblEnv (\gbl -> gbl { tcg_rdr_env = rdr_env `plusGlobalRdrEnv` tcg_rdr_env gbl,
 600                                  tcg_imports = imports `plusImportAvails` tcg_imports gbl })
 601                   $ do {
 602
 603         traceRn (ptext SLIT("rnTopSrcDecls") <+> ppr rdr_env) ;
 604         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 605
 606                 -- Rename the source decls
 607         (tcg_env, rn_decls) <- rnSrcDecls group ;
 608         failIfErrsM ;
 609
 610                 -- Dump trace of renaming part
 611         rnDump (ppr rn_decls) ;
 612
 613         return (tcg_env, rn_decls)
 614    }}
 615
 616 ------------------------------------------------
 617 tcTopSrcDecls :: [Name] -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 618 tcTopSrcDecls boot_names
 619         (HsGroup { hs_tyclds = tycl_decls,
 620                    hs_instds = inst_decls,
 621                    hs_fords  = foreign_decls,
 622                    hs_defds  = default_decls,
 623                    hs_ruleds = rule_decls,
 624                    hs_valds  = val_binds })
 625  = do {         -- Type-check the type and class decls, and all imported decls
 626                 -- The latter come in via tycl_decls
 627         traceTc (text "Tc2") ;
 628
 629         tcg_env <- checkNoErrs (tcTyAndClassDecls boot_names tycl_decls) ;
 630         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 631         -- an error we'd better stop now, to avoid a cascade
 632
 633         -- Make these type and class decls available to stuff slurped from interface files
 634         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 635
 636
 637         setGblEnv tcg_env       $ do {
 638                 -- Source-language instances, including derivings,
 639                 -- and import the supporting declarations
 640         traceTc (text "Tc3") ;
 641         (tcg_env, inst_infos, deriv_binds) <- tcInstDecls1 tycl_decls inst_decls ;
 642         setGblEnv tcg_env       $ do {
 643
 644                 -- Foreign import declarations next.  No zonking necessary
 645                 -- here; we can tuck them straight into the global environment.
 646         traceTc (text "Tc4") ;
 647         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 648         tcExtendGlobalValEnv fi_ids     $ do {
 649
 650                 -- Default declarations
 651         traceTc (text "Tc4a") ;
 652         default_tys <- tcDefaults default_decls ;
 653         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 654
 655                 -- Value declarations next
 656                 -- We also typecheck any extra binds that came out
 657                 -- of the "deriving" process (deriv_binds)
 658         traceTc (text "Tc5") ;
 659         (tc_val_binds, lcl_env) <- tcTopBinds (val_binds ++ deriv_binds) ;
 660         setLclTypeEnv lcl_env   $ do {
 661
 662                 -- Second pass over class and instance declarations,
 663         traceTc (text "Tc6") ;
 664         (tcl_env, inst_binds) <- tcInstDecls2 tycl_decls inst_infos ;
 665         showLIE (text "after instDecls2") ;
 666
 667                 -- Foreign exports
 668                 -- They need to be zonked, so we return them
 669         traceTc (text "Tc7") ;
 670         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 671
 672                 -- Rules
 673         rules <- tcRules rule_decls ;
 674
 675                 -- Wrap up
 676         traceTc (text "Tc7a") ;
 677         tcg_env <- getGblEnv ;
 678         let { all_binds = tc_val_binds   `unionBags`
 679                           inst_binds     `unionBags`
 680                           foe_binds  ;
 681
 682                 -- Extend the GblEnv with the (as yet un-zonked)
 683                 -- bindings, rules, foreign decls
 684               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 685                                     tcg_rules = tcg_rules tcg_env ++ rules,
 686                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 687         return (tcg_env', lcl_env)
 688     }}}}}}
 689 \end{code}
 690
 691
 692 %************************************************************************
 693 %*                                                                      *
 694         Checking for 'main'
 695 %*                                                                      *
 696 %************************************************************************
 697
 698 \begin{code}
 699 checkMain
 700   = do { ghci_mode <- getGhciMode ;
 701          tcg_env   <- getGblEnv ;
 702          dflags    <- getDOpts ;
 703          let { main_mod = case mainModIs dflags of {
 704                                 Just mod -> mkModule mod ;
 705                                 Nothing  -> mAIN } ;
 706                main_fn  = case mainFunIs dflags of {
 707                                 Just fn -> mkRdrUnqual (mkVarOcc (mkFastString fn)) ;
 708                                 Nothing -> main_RDR_Unqual } } ;
 709
 710          check_main ghci_mode tcg_env main_mod main_fn
 711     }
 712
 713
 714 check_main ghci_mode tcg_env main_mod main_fn
 715      -- If we are in module Main, check that 'main' is defined.
 716      -- It may be imported from another module!
 717      --
 718      --
 719      -- Blimey: a whole page of code to do this...
 720  | mod /= main_mod
 721  = return tcg_env
 722
 723  | otherwise
 724  = addErrCtxt mainCtxt                  $
 725    do   { mb_main <- lookupSrcOcc_maybe main_fn
 726                 -- Check that 'main' is in scope
 727                 -- It might be imported from another module!
 728         ; case mb_main of {
 729              Nothing -> do { complain_no_main
 730                            ; return tcg_env } ;
 731              Just main_name -> do
 732         { let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 733                         -- :Main.main :: IO () = runMainIO main
 734
 735         ; (main_expr, ty) <- setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 736                              tcInferRho rhs
 737
 738         ; let { root_main_id = mkExportedLocalId rootMainName ty ;
 739                 main_bind    = noLoc (VarBind root_main_id main_expr) }
 740
 741         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 742                                         `snocBag` main_bind,
 743                             tcg_dus   = tcg_dus tcg_env
 744                                         `plusDU` usesOnly (unitFV main_name)
 745                         -- Record the use of 'main', so that we don't
 746                         -- complain about it being defined but not used
 747                  })
 748     }}}
 749   where
 750     mod = tcg_mod tcg_env
 751
 752     complain_no_main | ghci_mode == Interactive = return ()
 753                      | otherwise                = failWithTc noMainMsg
 754         -- In interactive mode, don't worry about the absence of 'main'
 755         -- In other modes, fail altogether, so that we don't go on
 756         -- and complain a second time when processing the export list.
 757
 758     mainCtxt  = ptext SLIT("When checking the type of the main function") <+> quotes (ppr main_fn)
 759     noMainMsg = ptext SLIT("The main function") <+> quotes (ppr main_fn)
 760                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 761 \end{code}
 762
 763
 764 %*********************************************************
 765 %*                                                       *
 766                 GHCi stuff
 767 %*                                                       *
 768 %*********************************************************
 769
 770 \begin{code}
 771 #ifdef GHCI
 772 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 773 setInteractiveContext hsc_env icxt thing_inside
 774   = let
 775         -- Initialise the tcg_inst_env with instances
 776         -- from all home modules.  This mimics the more selective
 777         -- call to hptInstances in tcRnModule
 778         dfuns = hptInstances hsc_env (\mod -> True)
 779     in
 780     updGblEnv (\env -> env {
 781         tcg_rdr_env  = ic_rn_gbl_env icxt,
 782         tcg_type_env = ic_type_env   icxt,
 783         tcg_inst_env = extendInstEnvList (tcg_inst_env env) dfuns }) $
 784
 785     updLclEnv (\env -> env { tcl_rdr = ic_rn_local_env icxt })  $
 786
 787     do  { traceTc (text "setIC" <+> ppr (ic_type_env icxt))
 788         ; thing_inside }
 789 \end{code}
 790
 791
 792 \begin{code}
 793 tcRnStmt :: HscEnv
 794          -> InteractiveContext
 795          -> LStmt RdrName
 796          -> IO (Maybe (InteractiveContext, [Name], LHsExpr Id))
 797                 -- The returned [Name] is the same as the input except for
 798                 -- ExprStmt, in which case the returned [Name] is [itName]
 799                 --
 800                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 801                 -- a list of the bound values, coerced to ().
 802
 803 tcRnStmt hsc_env ictxt rdr_stmt
 804   = initTcPrintErrors hsc_env iNTERACTIVE $
 805     setInteractiveContext hsc_env ictxt $ do {
 806
 807     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 808     ([rn_stmt], fvs) <- rnStmts DoExpr [rdr_stmt] ;
 809     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 810     failIfErrsM ;
 811
 812     -- The real work is done here
 813     (bound_ids, tc_expr) <- tcUserStmt rn_stmt ;
 814
 815     traceTc (text "tcs 1") ;
 816     let {       -- (a) Make all the bound ids "global" ids, now that
 817                 --     they're notionally top-level bindings.  This is
 818                 --     important: otherwise when we come to compile an expression
 819                 --     using these ids later, the byte code generator will consider
 820                 --     the occurrences to be free rather than global.
 821                 --
 822                 -- (b) Tidy their types; this is important, because :info may
 823                 --     ask to look at them, and :info expects the things it looks
 824                 --     up to have tidy types
 825         global_ids = map globaliseAndTidy bound_ids ;
 826
 827                 -- Update the interactive context
 828         rn_env   = ic_rn_local_env ictxt ;
 829         type_env = ic_type_env ictxt ;
 830
 831         bound_names = map idName global_ids ;
 832         new_rn_env  = extendLocalRdrEnv rn_env bound_names ;
 833
 834                 -- Remove any shadowed bindings from the type_env;
 835                 -- they are inaccessible but might, I suppose, cause
 836                 -- a space leak if we leave them there
 837         shadowed = [ n | name <- bound_names,
 838                          let rdr_name = mkRdrUnqual (nameOccName name),
 839                          Just n <- [lookupLocalRdrEnv rn_env rdr_name] ] ;
 840
 841         filtered_type_env = delListFromNameEnv type_env shadowed ;
 842         new_type_env = extendTypeEnvWithIds filtered_type_env global_ids ;
 843
 844         new_ic = ictxt { ic_rn_local_env = new_rn_env,
 845                          ic_type_env     = new_type_env }
 846     } ;
 847
 848     dumpOptTcRn Opt_D_dump_tc
 849         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 850                text "Typechecked expr" <+> ppr tc_expr]) ;
 851
 852     returnM (new_ic, bound_names, tc_expr)
 853     }
 854
 855 globaliseAndTidy :: Id -> Id
 856 globaliseAndTidy id
 857 -- Give the Id a Global Name, and tidy its type
 858   = setIdType (globaliseId VanillaGlobal id) tidy_type
 859   where
 860     tidy_type = tidyTopType (idType id)
 861 \end{code}
 862
 863 Here is the grand plan, implemented in tcUserStmt
 864
 865         What you type                   The IO [HValue] that hscStmt returns
 866         -------------                   ------------------------------------
 867         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 868                                         bindings: [x,y,...]
 869
 870         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 871                                         bindings: [x,y,...]
 872
 873         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 874           [NB: result not printed]      bindings: [it]
 875
 876         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 877           result showable)              bindings: [it]
 878
 879         expr (of non-IO type,
 880           result not showable)  ==>     error
 881
 882
 883 \begin{code}
 884 ---------------------------
 885 tcUserStmt :: LStmt Name -> TcM ([Id], LHsExpr Id)
 886 tcUserStmt (L _ (ExprStmt expr _))
 887   = newUnique           `thenM` \ uniq ->
 888     let
 889         fresh_it = itName uniq
 890         the_bind = noLoc $ FunBind (noLoc fresh_it) False
 891                              (mkMatchGroup [mkSimpleMatch [] expr])
 892     in
 893     tryTcLIE_ (do {     -- Try this if the other fails
 894                 traceTc (text "tcs 1b") ;
 895                 tc_stmts [
 896                     nlLetStmt [HsBindGroup (unitBag the_bind) [] NonRecursive],
 897                     nlExprStmt (nlHsApp (nlHsVar printName)
 898                                               (nlHsVar fresh_it))
 899         ] })
 900           (do {         -- Try this first
 901                 traceTc (text "tcs 1a") ;
 902                 tc_stmts [nlBindStmt (nlVarPat fresh_it) expr] })
 903
 904 tcUserStmt stmt = tc_stmts [stmt]
 905
 906 ---------------------------
 907 tc_stmts stmts
 908  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
 909         let {
 910             ret_ty    = mkListTy unitTy ;
 911             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
 912
 913             names = map unLoc (collectStmtsBinders stmts) ;
 914
 915             stmt_ctxt = SC { sc_what = DoExpr,
 916                              sc_rhs  = infer_rhs,
 917                              sc_body = check_body,
 918                              sc_ty   = ret_ty } ;
 919
 920             infer_rhs rhs   = do { (rhs', rhs_ty) <- tcInferRho rhs
 921                                  ; [pat_ty] <- unifyTyConApp ioTyCon rhs_ty
 922                                  ; return (rhs', pat_ty) } ;
 923             check_body body = tcCheckRho body io_ret_ty ;
 924
 925                 -- mk_return builds the expression
 926                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
 927                 --
 928                 -- Despite the inconvenience of building the type applications etc,
 929                 -- this *has* to be done in type-annotated post-typecheck form
 930                 -- because we are going to return a list of *polymorphic* values
 931                 -- coerced to type (). If we built a *source* stmt
 932                 --      return [coerce x, ..., coerce z]
 933                 -- then the type checker would instantiate x..z, and we wouldn't
 934                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
 935                 -- if they were overloaded, since they aren't applied to anything.)
 936             mk_return ret_id ids = nlHsApp (noLoc $ TyApp (nlHsVar ret_id) [ret_ty])
 937                                            (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
 938             mk_item id = nlHsApp (noLoc $ TyApp (nlHsVar unsafeCoerceId) [idType id, unitTy])
 939                                (nlHsVar id) ;
 940
 941             io_ty = mkTyConApp ioTyCon []
 942          } ;
 943
 944         -- OK, we're ready to typecheck the stmts
 945         traceTc (text "tcs 2") ;
 946         ((ids, tc_expr), lie) <- getLIE $ do {
 947             (ids, tc_stmts) <- tcStmtsAndThen combine stmt_ctxt stmts   $
 948                         do {
 949                             -- Look up the names right in the middle,
 950                             -- where they will all be in scope
 951                             ids <- mappM tcLookupId names ;
 952                             ret_id <- tcLookupId returnIOName ;         -- return @ IO
 953                             return (ids, [nlResultStmt (mk_return ret_id ids)]) } ;
 954
 955             io_ids <- mappM (tcStdSyntaxName DoOrigin io_ty) monadNames ;
 956             return (ids, noLoc (HsDo DoExpr tc_stmts io_ids io_ret_ty))
 957         } ;
 958
 959         -- Simplify the context right here, so that we fail
 960         -- if there aren't enough instances.  Notably, when we see
 961         --              e
 962         -- we use recoverTc_ to try     it <- e
 963         -- and then                     let it = e
 964         -- It's the simplify step that rejects the first.
 965         traceTc (text "tcs 3") ;
 966         const_binds <- tcSimplifyInteractive lie ;
 967
 968         -- Build result expression and zonk it
 969         let { expr = mkHsLet const_binds tc_expr } ;
 970         zonked_expr <- zonkTopLExpr expr ;
 971         zonked_ids  <- zonkTopBndrs ids ;
 972
 973         -- None of the Ids should be of unboxed type, because we
 974         -- cast them all to HValues in the end!
 975         mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
 976
 977         return (zonked_ids, zonked_expr)
 978         }
 979   where
 980     combine stmt (ids, stmts) = (ids, stmt:stmts)
 981     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
 982                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
 983 \end{code}
 984
 985
 986 tcRnExpr just finds the type of an expression
 987
 988 \begin{code}
 989 tcRnExpr :: HscEnv
 990          -> InteractiveContext
 991          -> LHsExpr RdrName
 992          -> IO (Maybe Type)
 993 tcRnExpr hsc_env ictxt rdr_expr
 994   = initTcPrintErrors hsc_env iNTERACTIVE $
 995     setInteractiveContext hsc_env ictxt $ do {
 996
 997     (rn_expr, fvs) <- rnLExpr rdr_expr ;
 998     failIfErrsM ;
 999
1000         -- Now typecheck the expression;
1001         -- it might have a rank-2 type (e.g. :t runST)
1002     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1003     ((qtvs, _, dict_ids), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1004     tcSimplifyInteractive lie_top ;
1005     qtvs' <- mappM zonkQuantifiedTyVar qtvs ;
1006
1007     let { all_expr_ty = mkForAllTys qtvs' $
1008                         mkFunTys (map idType dict_ids)  $
1009                         res_ty } ;
1010     zonkTcType all_expr_ty
1011     }
1012   where
1013     smpl_doc = ptext SLIT("main expression")
1014 \end{code}
1015
1016 tcRnType just finds the kind of a type
1017
1018 \begin{code}
1019 tcRnType :: HscEnv
1020          -> InteractiveContext
1021          -> LHsType RdrName
1022          -> IO (Maybe Kind)
1023 tcRnType hsc_env ictxt rdr_type
1024   = initTcPrintErrors hsc_env iNTERACTIVE $
1025     setInteractiveContext hsc_env ictxt $ do {
1026
1027     rn_type <- rnLHsType doc rdr_type ;
1028     failIfErrsM ;
1029
1030         -- Now kind-check the type
1031     (ty', kind) <- kcHsType rn_type ;
1032     return kind
1033     }
1034   where
1035     doc = ptext SLIT("In GHCi input")
1036
1037 #endif /* GHCi */
1038 \end{code}
1039
1040
1041 %************************************************************************
1042 %*                                                                      *
1043         More GHCi stuff, to do with browsing and getting info
1044 %*                                                                      *
1045 %************************************************************************
1046
1047 \begin{code}
1048 #ifdef GHCI
1049 mkExportEnv :: HscEnv -> [Module]       -- Expose these modules' exports only
1050             -> IO GlobalRdrEnv
1051 mkExportEnv hsc_env exports
1052   = do  { mb_envs <- initTcPrintErrors hsc_env iNTERACTIVE $
1053                      mappM getModuleExports exports
1054         ; case mb_envs of
1055              Just envs -> return (foldr plusGlobalRdrEnv emptyGlobalRdrEnv envs)
1056              Nothing   -> return emptyGlobalRdrEnv
1057                              -- Some error; initTc will have printed it
1058     }
1059
1060 getModuleExports :: Module -> TcM GlobalRdrEnv
1061 getModuleExports mod
1062   = do  { iface <- load_iface mod
1063         ; loadOrphanModules (dep_orphs (mi_deps iface))
1064                         -- Load any orphan-module interfaces,
1065                         -- so their instances are visible
1066         ; names <- exportsToAvails (mi_exports iface)
1067         ; let { gres =  [ GRE  { gre_name = name, gre_prov = vanillaProv mod }
1068                         | name <- nameSetToList names ] }
1069         ; returnM (mkGlobalRdrEnv gres) }
1070
1071 vanillaProv :: Module -> Provenance
1072 -- We're building a GlobalRdrEnv as if the user imported
1073 -- all the specified modules into the global interactive module
1074 vanillaProv mod = Imported [ImportSpec mod mod False
1075                              (srcLocSpan interactiveSrcLoc)] False
1076 \end{code}
1077
1078 \begin{code}
1079 getModuleContents
1080   :: HscEnv
1081   -> Module                     -- Module to inspect
1082   -> Bool                       -- Grab just the exports, or the whole toplev
1083   -> IO (Maybe [IfaceDecl])
1084
1085 getModuleContents hsc_env mod exports_only
1086  = initTcPrintErrors hsc_env iNTERACTIVE (get_mod_contents exports_only)
1087  where
1088    get_mod_contents exports_only
1089       | not exports_only  -- We want the whole top-level type env
1090                           -- so it had better be a home module
1091       = do { hpt <- getHpt
1092            ; case lookupModuleEnv hpt mod of
1093                Just mod_info -> return (map (toIfaceDecl ext_nm) $
1094                                         filter wantToSee $
1095                                         typeEnvElts $
1096                                         md_types (hm_details mod_info))
1097                Nothing -> ghcError (ProgramError (showSDoc (noRdrEnvErr mod)))
1098                           -- This is a system error; the module should be in the HPT
1099            }
1100
1101       | otherwise               -- Want the exports only
1102       = do { iface <- load_iface mod
1103            ; mappM get_decl [ (mod,avail) | (mod, avails) <- mi_exports iface
1104                                           , avail <- avails ]
1105         }
1106
1107    get_decl (mod, avail)
1108         = do { main_name <- lookupOrig mod (availName avail)
1109              ; thing     <- tcLookupGlobal main_name
1110              ; return (filter_decl (availNames avail) (toIfaceDecl ext_nm thing)) }
1111
1112    ext_nm = interactiveExtNameFun (icPrintUnqual (hsc_IC hsc_env))
1113
1114 ---------------------
1115 filter_decl occs decl@(IfaceClass {ifSigs = sigs})
1116   = decl { ifSigs = filter (keep_sig occs) sigs }
1117 filter_decl occs decl@(IfaceData {ifCons = IfDataTyCon th cons})
1118   = decl { ifCons = IfDataTyCon th (filter (keep_con occs) cons) }
1119 filter_decl occs decl@(IfaceData {ifCons = IfNewTyCon con})
1120   | keep_con occs con = decl
1121   | otherwise         = decl {ifCons = IfAbstractTyCon} -- Hmm?
1122 filter_decl occs decl
1123   = decl
1124
1125 keep_sig occs (IfaceClassOp occ _ _) = occ `elem` occs
1126 keep_con occs con                    = ifConOcc con `elem` occs
1127
1128 wantToSee (AnId id)    = not (isImplicitId id)
1129 wantToSee (ADataCon _) = False  -- They'll come via their TyCon
1130 wantToSee _            = True
1131
1132 ---------------------
1133 load_iface mod = loadSrcInterface doc mod False {- Not boot iface -}
1134                where
1135                  doc = ptext SLIT("context for compiling statements")
1136
1137 ---------------------
1138 noRdrEnvErr mod = ptext SLIT("No top-level environment available for module")
1139                   <+> quotes (ppr mod)
1140 \end{code}
1141
1142 \begin{code}
1143 type GetInfoResult = (String, IfaceDecl, Fixity, SrcLoc,
1144                               [(IfaceType,SrcLoc)]      -- Instances
1145                      )
1146
1147 tcRnGetInfo :: HscEnv
1148             -> InteractiveContext
1149             -> RdrName
1150             -> IO (Maybe [GetInfoResult])
1151
1152 -- Used to implemnent :info in GHCi
1153 --
1154 -- Look up a RdrName and return all the TyThings it might be
1155 -- A capitalised RdrName is given to us in the DataName namespace,
1156 -- but we want to treat it as *both* a data constructor
1157 -- *and* as a type or class constructor;
1158 -- hence the call to dataTcOccs, and we return up to two results
1159 tcRnGetInfo hsc_env ictxt rdr_name
1160   = initTcPrintErrors hsc_env iNTERACTIVE $
1161     setInteractiveContext hsc_env ictxt $ do {
1162
1163         -- If the identifier is a constructor (begins with an
1164         -- upper-case letter), then we need to consider both
1165         -- constructor and type class identifiers.
1166     let { rdr_names = dataTcOccs rdr_name } ;
1167
1168         -- results :: [(Messages, Maybe Name)]
1169     results <- mapM (tryTc . lookupOccRn) rdr_names ;
1170
1171     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1172         -- The successful lookups will be (Just name)
1173     let { (warns_s, good_names) = unzip [ (msgs, name)
1174                                         | (msgs, Just name) <- results] ;
1175           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1176
1177         -- Fail if nothing good happened, else add warnings
1178     if null good_names then
1179                 -- No lookup succeeded, so
1180                 -- pick the first error message and report it
1181                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1182                 --       while the other is "X is not in scope",
1183                 --       we definitely want the former; but we might pick the latter
1184         do { addMessages (head errs_s) ; failM }
1185       else                      -- Add deprecation warnings
1186         mapM_ addMessages warns_s ;
1187
1188         -- And lookup up the entities, avoiding duplicates, which arise
1189         -- because constructors and record selectors are represented by
1190         -- their parent declaration
1191     let { do_one name = do { thing  <- tcLookupGlobal name
1192                            ; fixity <- lookupFixityRn name
1193                            ; dfuns  <- lookupInsts ext_nm thing
1194                            ; return (str, toIfaceDecl ext_nm thing, fixity,
1195                                      getSrcLoc thing,
1196                                      [(toIfaceType ext_nm (idType dfun), getSrcLoc dfun) | dfun <- dfuns]
1197                              ) }
1198                 where
1199                         -- str is the the naked occurrence name
1200                         -- after stripping off qualification and parens (+)
1201                   str = occNameUserString (nameOccName name)
1202         } ;
1203
1204                 -- For the SrcLoc, the 'thing' has better info than
1205                 -- the 'name' because getting the former forced the
1206                 -- declaration to be loaded into the cache
1207
1208     results <- mapM do_one good_names ;
1209     return (fst (removeDups cmp results))
1210     }
1211   where
1212     cmp (_,d1,_,_,_) (_,d2,_,_,_) = ifName d1 `compare` ifName d2
1213     ext_nm = interactiveExtNameFun (icPrintUnqual ictxt)
1214
1215
1216 lookupInsts :: (Name -> IfaceExtName) -> TyThing -> TcM [DFunId]
1217 -- Filter the instances by the ones whose tycons (or clases resp)
1218 -- are in scope unqualified.  Otherwise we list a whole lot too many!
1219 lookupInsts ext_nm (AClass cls)
1220   = do  { loadImportedInsts cls []      -- [] means load all instances for cls
1221         ; inst_envs <- tcGetInstEnvs
1222         ; return [ dfun
1223                  | (_,_,dfun) <- classInstances inst_envs cls
1224                  , let (_, tycons) = ifaceInstGates (ifInstHead (dfunToIfaceInst ext_nm dfun))
1225                         -- Rather an indirect/inefficient test, but there we go
1226                  , all print_tycon_unqual tycons ] }
1227   where
1228     print_tycon_unqual (IfaceTc nm) = isLocalIfaceExtName nm
1229     print_tycon_unqual other            = True  -- Int etc
1230
1231
1232 lookupInsts ext_nm (ATyCon tc)
1233   = do  { eps <- getEps -- Load all instances for all classes that are
1234                         -- in the type environment (which are all the ones
1235                         -- we've seen in any interface file so far)
1236         ; mapM_ (\c -> loadImportedInsts c [])
1237                 (typeEnvClasses (eps_PTE eps))
1238         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1239         ; return [ dfun
1240                  | (_, _, dfun) <- instEnvElts home_ie ++ instEnvElts pkg_ie
1241                  , relevant dfun
1242                  , let (cls, _) = ifaceInstGates (ifInstHead (dfunToIfaceInst ext_nm dfun))
1243                  , isLocalIfaceExtName cls ]  }
1244   where
1245     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1246     tc_name     = tyConName tc
1247
1248 lookupInsts ext_nm other = return []
1249
1250
1251 toIfaceDecl :: (Name -> IfaceExtName) -> TyThing -> IfaceDecl
1252 toIfaceDecl ext_nm thing
1253   = tyThingToIfaceDecl True             -- Discard IdInfo
1254                        emptyNameSet     -- Show data cons
1255                        ext_nm (munge thing)
1256   where
1257         -- munge transforms a thing to its "parent" thing
1258     munge (ADataCon dc) = ATyCon (dataConTyCon dc)
1259     munge (AnId id) = case globalIdDetails id of
1260                         RecordSelId tc lbl -> ATyCon tc
1261                         ClassOpId cls      -> AClass cls
1262                         other              -> AnId id
1263     munge other_thing = other_thing
1264 #endif /* GHCI */
1265 \end{code}
1266
1267 %************************************************************************
1268 %*                                                                      *
1269                 Degugging output
1270 %*                                                                      *
1271 %************************************************************************
1272
1273 \begin{code}
1274 rnDump :: SDoc -> TcRn ()
1275 -- Dump, with a banner, if -ddump-rn
1276 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1277
1278 tcDump :: TcGblEnv -> TcRn ()
1279 tcDump env
1280  = do { dflags <- getDOpts ;
1281
1282         -- Dump short output if -ddump-types or -ddump-tc
1283         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1284             (dumpTcRn short_dump) ;
1285
1286         -- Dump bindings if -ddump-tc
1287         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1288    }
1289   where
1290     short_dump = pprTcGblEnv env
1291     full_dump  = pprLHsBinds (tcg_binds env)
1292         -- NB: foreign x-d's have undefined's in their types;
1293         --     hence can't show the tc_fords
1294
1295 tcCoreDump mod_guts
1296  = do { dflags <- getDOpts ;
1297         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1298             (dumpTcRn (pprModGuts mod_guts)) ;
1299
1300         -- Dump bindings if -ddump-tc
1301         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1302   where
1303     full_dump = pprCoreBindings (mg_binds mod_guts)
1304
1305 -- It's unpleasant having both pprModGuts and pprModDetails here
1306 pprTcGblEnv :: TcGblEnv -> SDoc
1307 pprTcGblEnv (TcGblEnv { tcg_type_env = type_env,
1308                         tcg_insts    = dfun_ids,
1309                         tcg_rules    = rules,
1310                         tcg_imports  = imports })
1311   = vcat [ ppr_types dfun_ids type_env
1312          , ppr_insts dfun_ids
1313          , vcat (map ppr rules)
1314          , ppr_gen_tycons (typeEnvTyCons type_env)
1315          , ptext SLIT("Dependent modules:") <+> ppr (moduleEnvElts (imp_dep_mods imports))
1316          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1317
1318 pprModGuts :: ModGuts -> SDoc
1319 pprModGuts (ModGuts { mg_types = type_env,
1320                       mg_rules = rules })
1321   = vcat [ ppr_types [] type_env,
1322            ppr_rules rules ]
1323
1324
1325 ppr_types :: [Var] -> TypeEnv -> SDoc
1326 ppr_types dfun_ids type_env
1327   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1328   where
1329     ids = [id | id <- typeEnvIds type_env, want_sig id]
1330     want_sig id | opt_PprStyle_Debug = True
1331                 | otherwise          = isLocalId id &&
1332                                        isExternalName (idName id) &&
1333                                        not (id `elem` dfun_ids)
1334         -- isLocalId ignores data constructors, records selectors etc.
1335         -- The isExternalName ignores local dictionary and method bindings
1336         -- that the type checker has invented.  Top-level user-defined things
1337         -- have External names.
1338
1339 ppr_insts :: [Var] -> SDoc
1340 ppr_insts []       = empty
1341 ppr_insts dfun_ids = text "INSTANCES" $$ nest 4 (ppr_sigs dfun_ids)
1342
1343 ppr_sigs :: [Var] -> SDoc
1344 ppr_sigs ids
1345         -- Print type signatures; sort by OccName
1346   = vcat (map ppr_sig (sortLe le_sig ids))
1347   where
1348     le_sig id1 id2 = getOccName id1 <= getOccName id2
1349     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1350
1351 ppr_rules :: [IdCoreRule] -> SDoc
1352 ppr_rules [] = empty
1353 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1354                       nest 4 (pprIdRules rs),
1355                       ptext SLIT("#-}")]
1356
1357 ppr_gen_tycons []  = empty
1358 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1359                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1360 \end{code}