ghc/compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcRnDriver (
   8 #ifdef GHCI
   9         mkExportEnv, getModuleContents, tcRnStmt,
  10         tcRnGetInfo, GetInfoResult,
  11         tcRnExpr, tcRnType,
  12         tcRnLookupRdrName,
  13         getModuleExports,
  14 #endif
  15         tcRnModule,
  16         tcTopSrcDecls,
  17         tcRnExtCore
  18     ) where
  19
  20 #include "HsVersions.h"
  21
  22 import IO
  23 #ifdef GHCI
  24 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  25 #endif
  26
  27 import DynFlags         ( DynFlag(..), DynFlags(..), dopt, GhcMode(..) )
  28 import StaticFlags      ( opt_PprStyle_Debug )
  29 import Packages         ( moduleToPackageConfig, mkPackageId, package,
  30                           isHomeModule )
  31 import HsSyn            ( HsModule(..), HsExtCore(..), HsGroup(..), LHsDecl,
  32                           SpliceDecl(..), HsBind(..), LHsBinds,
  33                           emptyGroup, appendGroups,
  34                           nlHsApp, nlHsVar, pprLHsBinds )
  35 import RdrHsSyn         ( findSplice )
  36
  37 import PrelNames        ( runMainIOName, rootMainName, mAIN,
  38                           main_RDR_Unqual )
  39 import RdrName          ( RdrName, mkRdrUnqual, emptyGlobalRdrEnv )
  40 import TcHsSyn          ( zonkTopDecls )
  41 import TcExpr           ( tcInferRho )
  42 import TcRnMonad
  43 import TcType           ( tidyTopType, tcEqType, mkTyVarTys, substTyWith )
  44 import Inst             ( showLIE )
  45 import InstEnv          ( extendInstEnvList, Instance, pprInstances, instanceDFunId )
  46 import TcBinds          ( tcTopBinds, tcHsBootSigs )
  47 import TcDefaults       ( tcDefaults )
  48 import TcEnv            ( tcExtendGlobalValEnv, iDFunId )
  49 import TcRules          ( tcRules )
  50 import TcForeign        ( tcForeignImports, tcForeignExports )
  51 import TcInstDcls       ( tcInstDecls1, tcInstDecls2 )
  52 import TcIface          ( tcExtCoreBindings, tcHiBootIface )
  53 import TcSimplify       ( tcSimplifyTop )
  54 import TcTyClsDecls     ( tcTyAndClassDecls )
  55 import LoadIface        ( loadOrphanModules )
  56 import RnNames          ( importsFromLocalDecls, rnImports, exportsFromAvail,
  57                           reportUnusedNames, reportDeprecations )
  58 import RnEnv            ( lookupSrcOcc_maybe )
  59 import RnSource         ( rnSrcDecls, rnTyClDecls, checkModDeprec )
  60 import PprCore          ( pprRules, pprCoreBindings )
  61 import CoreSyn          ( CoreRule, bindersOfBinds )
  62 import DataCon          ( dataConWrapId )
  63 import ErrUtils         ( Messages, mkDumpDoc, showPass )
  64 import Id               ( Id, mkExportedLocalId, isLocalId, idName, idType )
  65 import Var              ( Var )
  66 import Module           ( Module, ModuleEnv, mkModule, moduleEnvElts, elemModuleEnv )
  67 import OccName          ( mkVarOcc )
  68 import Name             ( Name, NamedThing(..), isExternalName, getSrcLoc, isWiredInName )
  69 import NameSet
  70 import TyCon            ( tyConHasGenerics, isSynTyCon, getSynTyConDefn, tyConKind )
  71 import SrcLoc           ( srcLocSpan, Located(..), noLoc )
  72 import DriverPhases     ( HscSource(..), isHsBoot )
  73 import HscTypes         ( ModGuts(..), ModDetails(..), emptyModDetails,
  74                           HscEnv(..), ExternalPackageState(..),
  75                           IsBootInterface, noDependencies,
  76                           Deprecs( NoDeprecs ), plusDeprecs,
  77                           ForeignStubs(NoStubs), TyThing(..),
  78                           TypeEnv, lookupTypeEnv, hptInstances,
  79                           extendTypeEnvWithIds, typeEnvIds, typeEnvTyCons, typeEnvElts,
  80                           emptyFixityEnv
  81                         )
  82 import Outputable
  83
  84 #ifdef GHCI
  85 import HsSyn            ( HsStmtContext(..), Stmt(..), HsExpr(..), HsBindGroup(..),
  86                           LStmt, LHsExpr, LHsType, mkMatchGroup,
  87                           collectLStmtsBinders, mkSimpleMatch, nlVarPat,
  88                           placeHolderType, noSyntaxExpr )
  89 import RdrName          ( GlobalRdrEnv, mkGlobalRdrEnv, GlobalRdrElt(..),
  90                           Provenance(..), ImportSpec(..), globalRdrEnvElts,
  91                           unQualOK, lookupLocalRdrEnv, extendLocalRdrEnv,
  92                           plusGlobalRdrEnv )
  93 import RnSource         ( addTcgDUs )
  94 import TcHsSyn          ( mkHsLet, zonkTopLExpr, zonkTopBndrs )
  95 import TcHsType         ( kcHsType )
  96 import TcMType          ( zonkTcType, zonkQuantifiedTyVar )
  97 import TcMatches        ( tcStmts, tcDoStmt )
  98 import TcSimplify       ( tcSimplifyInteractive, tcSimplifyInfer )
  99 import TcType           ( Type, mkForAllTys, mkFunTys, mkTyConApp, tyVarsOfType,
 100                           isUnLiftedType, tyClsNamesOfDFunHead, tyClsNamesOfType )
 101 import TcEnv            ( tcLookupTyCon, tcLookupId, tcLookupGlobal )
 102 import RnTypes          ( rnLHsType )
 103 import Inst             ( tcGetInstEnvs )
 104 import InstEnv          ( classInstances, instEnvElts )
 105 import RnExpr           ( rnStmts, rnLExpr )
 106 import LoadIface        ( loadSrcInterface, loadSysInterface )
 107 import IfaceSyn         ( IfaceDecl(..), IfaceClassOp(..), IfaceConDecl(..),
 108                           IfaceExtName(..), IfaceConDecls(..),
 109                           tyThingToIfaceDecl )
 110 import IfaceType        ( IfaceType, toIfaceType,
 111                           interactiveExtNameFun )
 112 import IfaceEnv         ( lookupOrig, ifaceExportNames )
 113 import Module           ( lookupModuleEnv, moduleSetElts, mkModuleSet )
 114 import RnEnv            ( lookupOccRn, dataTcOccs, lookupFixityRn )
 115 import Id               ( isImplicitId, setIdType, globalIdDetails )
 116 import MkId             ( unsafeCoerceId )
 117 import DataCon          ( dataConTyCon )
 118 import TyCon            ( tyConName )
 119 import TysWiredIn       ( mkListTy, unitTy )
 120 import IdInfo           ( GlobalIdDetails(..) )
 121 import SrcLoc           ( interactiveSrcLoc, unLoc )
 122 import Kind             ( Kind )
 123 import Var              ( globaliseId )
 124 import Name             ( nameOccName, nameModule )
 125 import OccName          ( occNameUserString, isTcOcc )
 126 import NameEnv          ( delListFromNameEnv )
 127 import PrelNames        ( iNTERACTIVE, ioTyConName, printName, itName,
 128                           bindIOName, thenIOName, returnIOName )
 129 import HscTypes         ( InteractiveContext(..), HomeModInfo(..),
 130                           availNames, availName, ModIface(..), icPrintUnqual,
 131                           Dependencies(..) )
 132 import BasicTypes       ( RecFlag(..), Fixity )
 133 import ListSetOps       ( removeDups )
 134 import Panic            ( ghcError, GhcException(..) )
 135 import SrcLoc           ( SrcLoc )
 136 #endif
 137
 138 import FastString       ( mkFastString )
 139 import Util             ( sortLe )
 140 import Bag              ( unionBags, snocBag, emptyBag, unitBag, unionManyBags )
 141
 142 import Maybe            ( isJust )
 143 \end{code}
 144
 145
 146
 147 %************************************************************************
 148 %*                                                                      *
 149         Typecheck and rename a module
 150 %*                                                                      *
 151 %************************************************************************
 152
 153
 154 \begin{code}
 155 tcRnModule :: HscEnv
 156            -> HscSource
 157            -> Bool              -- True <=> save renamed syntax
 158            -> Located (HsModule RdrName)
 159            -> IO (Messages, Maybe TcGblEnv)
 160
 161 tcRnModule hsc_env hsc_src save_rn_decls
 162          (L loc (HsModule maybe_mod export_ies
 163                           import_decls local_decls mod_deprec))
 164  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 165
 166    let { this_mod = case maybe_mod of
 167                         Nothing  -> mAIN          -- 'module M where' is omitted
 168                         Just (L _ mod) -> mod } ; -- The normal case
 169
 170    initTc hsc_env hsc_src this_mod $
 171    setSrcSpan loc $
 172    do {
 173         checkForPackageModule (hsc_dflags hsc_env) this_mod;
 174
 175                 -- Deal with imports; sets tcg_rdr_env, tcg_imports
 176         (rdr_env, imports) <- rnImports import_decls ;
 177
 178         let { dep_mods :: ModuleEnv (Module, IsBootInterface)
 179             ; dep_mods = imp_dep_mods imports
 180
 181                 -- We want instance declarations from all home-package
 182                 -- modules below this one, including boot modules, except
 183                 -- ourselves.  The 'except ourselves' is so that we don't
 184                 -- get the instances from this module's hs-boot file
 185             ; want_instances :: Module -> Bool
 186             ; want_instances mod = mod `elemModuleEnv` dep_mods
 187                                    && mod /= this_mod
 188             ; home_insts = hptInstances hsc_env want_instances
 189             } ;
 190
 191                 -- Record boot-file info in the EPS, so that it's
 192                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 193                 -- and any other incrementally-performed imports
 194         updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 195
 196                 -- Update the gbl env
 197         updGblEnv ( \ gbl ->
 198                 gbl { tcg_rdr_env  = rdr_env,
 199                       tcg_inst_env = extendInstEnvList (tcg_inst_env gbl) home_insts,
 200                       tcg_imports  = tcg_imports gbl `plusImportAvails` imports,
 201                       tcg_rn_decls = if save_rn_decls then
 202                                         Just emptyGroup
 203                                      else
 204                                         Nothing })
 205                 $ do {
 206
 207         traceRn (text "rn1" <+> ppr (imp_dep_mods imports)) ;
 208                 -- Fail if there are any errors so far
 209                 -- The error printing (if needed) takes advantage
 210                 -- of the tcg_env we have now set
 211         failIfErrsM ;
 212
 213                 -- Load any orphan-module interfaces, so that
 214                 -- their rules and instance decls will be found
 215         loadOrphanModules (imp_orphs imports) ;
 216
 217         traceRn (text "rn1a") ;
 218                 -- Rename and type check the declarations
 219         tcg_env <- if isHsBoot hsc_src then
 220                         tcRnHsBootDecls local_decls
 221                    else
 222                         tcRnSrcDecls local_decls ;
 223         setGblEnv tcg_env               $ do {
 224
 225         traceRn (text "rn3") ;
 226
 227                 -- Report the use of any deprecated things
 228                 -- We do this before processsing the export list so
 229                 -- that we don't bleat about re-exporting a deprecated
 230                 -- thing (especially via 'module Foo' export item)
 231                 -- Only uses in the body of the module are complained about
 232         reportDeprecations tcg_env ;
 233
 234                 -- Process the export list
 235         exports <- exportsFromAvail (isJust maybe_mod) export_ies ;
 236
 237                 -- Check whether the entire module is deprecated
 238                 -- This happens only once per module
 239         let { mod_deprecs = checkModDeprec mod_deprec } ;
 240
 241                 -- Add exports and deprecations to envt
 242         let { final_env  = tcg_env { tcg_exports = exports,
 243                                      tcg_dus = tcg_dus tcg_env `plusDU` usesOnly exports,
 244                                      tcg_deprecs = tcg_deprecs tcg_env `plusDeprecs`
 245                                                    mod_deprecs }
 246                 -- A module deprecation over-rides the earlier ones
 247              } ;
 248
 249                 -- Report unused names
 250         reportUnusedNames export_ies final_env ;
 251
 252                 -- Dump output and return
 253         tcDump final_env ;
 254         return final_env
 255     }}}}
 256
 257 -- This is really a sanity check that the user has given -package-name
 258 -- if necessary.  -package-name is only necessary when the package database
 259 -- already contains the current package, because then we can't tell
 260 -- whether a given module is in the current package or not, without knowing
 261 -- the name of the current package.
 262 checkForPackageModule dflags this_mod
 263   | not (isHomeModule dflags this_mod),
 264     Just (pkg,_) <- moduleToPackageConfig dflags this_mod =
 265         let
 266                 ppr_pkg = ppr (mkPackageId (package pkg))
 267         in
 268         addErr (ptext SLIT("Module") <+> quotes (ppr this_mod) <+>
 269                 ptext SLIT("is a member of package") <+>  ppr_pkg <> char '.' $$
 270                 ptext SLIT("To compile this module, please use -ignore-package") <+> ppr_pkg <> char '.')
 271   | otherwise = return ()
 272 \end{code}
 273
 274
 275 %************************************************************************
 276 %*                                                                      *
 277         Type-checking external-core modules
 278 %*                                                                      *
 279 %************************************************************************
 280
 281 \begin{code}
 282 tcRnExtCore :: HscEnv
 283             -> HsExtCore RdrName
 284             -> IO (Messages, Maybe ModGuts)
 285         -- Nothing => some error occurred
 286
 287 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 288         -- The decls are IfaceDecls; all names are original names
 289  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 290
 291    initTc hsc_env ExtCoreFile this_mod $ do {
 292
 293    let { ldecls  = map noLoc decls } ;
 294
 295         -- Deal with the type declarations; first bring their stuff
 296         -- into scope, then rname them, then type check them
 297    tcg_env  <- importsFromLocalDecls (mkFakeGroup ldecls) ;
 298
 299    setGblEnv tcg_env $ do {
 300
 301    rn_decls <- rnTyClDecls ldecls ;
 302    failIfErrsM ;
 303
 304         -- Dump trace of renaming part
 305    rnDump (ppr rn_decls) ;
 306
 307         -- Typecheck them all together so that
 308         -- any mutually recursive types are done right
 309    tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails rn_decls) ;
 310         -- Make the new type env available to stuff slurped from interface files
 311
 312    setGblEnv tcg_env $ do {
 313
 314         -- Now the core bindings
 315    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 316
 317         -- Wrap up
 318    let {
 319         bndrs      = bindersOfBinds core_binds ;
 320         my_exports = mkNameSet (map idName bndrs) ;
 321                 -- ToDo: export the data types also?
 322
 323         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 324
 325         mod_guts = ModGuts {    mg_module   = this_mod,
 326                                 mg_boot     = False,
 327                                 mg_usages   = [],               -- ToDo: compute usage
 328                                 mg_dir_imps = [],               -- ??
 329                                 mg_deps     = noDependencies,   -- ??
 330                                 mg_exports  = my_exports,
 331                                 mg_types    = final_type_env,
 332                                 mg_insts    = tcg_insts tcg_env,
 333                                 mg_rules    = [],
 334                                 mg_binds    = core_binds,
 335
 336                                 -- Stubs
 337                                 mg_rdr_env  = emptyGlobalRdrEnv,
 338                                 mg_fix_env  = emptyFixityEnv,
 339                                 mg_deprecs  = NoDeprecs,
 340                                 mg_foreign  = NoStubs
 341                     } } ;
 342
 343    tcCoreDump mod_guts ;
 344
 345    return mod_guts
 346    }}}}
 347
 348 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 349   = HsGroup {   hs_tyclds = decls,      -- This is the one we want
 350                 hs_valds = [], hs_fords = [],
 351                 hs_instds = [], hs_fixds = [], hs_depds = [],
 352                 hs_ruleds = [], hs_defds = [] }
 353 \end{code}
 354
 355
 356 %************************************************************************
 357 %*                                                                      *
 358         Type-checking the top level of a module
 359 %*                                                                      *
 360 %************************************************************************
 361
 362 \begin{code}
 363 tcRnSrcDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 364         -- Returns the variables free in the decls
 365         -- Reason: solely to report unused imports and bindings
 366 tcRnSrcDecls decls
 367  = do {         -- Load the hi-boot interface for this module, if any
 368                 -- We do this now so that the boot_names can be passed
 369                 -- to tcTyAndClassDecls, because the boot_names are
 370                 -- automatically considered to be loop breakers
 371         mod <- getModule ;
 372         boot_iface <- tcHiBootIface mod ;
 373
 374                 -- Do all the declarations
 375         (tc_envs, lie) <- getLIE (tc_rn_src_decls boot_iface decls) ;
 376
 377              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 378              -- How could there be ambiguous ones?  They can only arise if a
 379              -- top-level decl falls under the monomorphism
 380              -- restriction, and no subsequent decl instantiates its
 381              -- type.  (Usually, ambiguous type variables are resolved
 382              -- during the generalisation step.)
 383         traceTc (text "Tc8") ;
 384         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 385                 -- Setting the global env exposes the instances to tcSimplifyTop
 386                 -- Setting the local env exposes the local Ids to tcSimplifyTop,
 387                 -- so that we get better error messages (monomorphism restriction)
 388
 389             -- Backsubstitution.  This must be done last.
 390             -- Even tcSimplifyTop may do some unification.
 391         traceTc (text "Tc9") ;
 392         let { (tcg_env, _) = tc_envs ;
 393               TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 394                          tcg_rules = rules, tcg_fords = fords } = tcg_env } ;
 395
 396         (bind_ids, binds', fords', rules') <- zonkTopDecls (binds `unionBags` inst_binds)
 397                                                            rules fords ;
 398
 399         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 400             ; tcg_env' = tcg_env { tcg_type_env = final_type_env,
 401                                    tcg_binds = binds',
 402                                    tcg_rules = rules',
 403                                    tcg_fords = fords' } } ;
 404
 405         -- Make the new type env available to stuff slurped from interface files
 406         writeMutVar (tcg_type_env_var tcg_env) final_type_env ;
 407
 408         -- Compare the hi-boot iface (if any) with the real thing
 409         dfun_binds <- checkHiBootIface tcg_env' boot_iface ;
 410
 411         return (tcg_env' { tcg_binds = tcg_binds tcg_env' `unionBags` dfun_binds })
 412    }
 413
 414 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 415 -- Loops around dealing with each top level inter-splice group
 416 -- in turn, until it's dealt with the entire module
 417 tc_rn_src_decls boot_details ds
 418  = do { let { (first_group, group_tail) = findSplice ds } ;
 419                 -- If ds is [] we get ([], Nothing)
 420
 421         -- Type check the decls up to, but not including, the first splice
 422         tc_envs@(tcg_env,tcl_env) <- tcRnGroup boot_details first_group ;
 423
 424         -- Bale out if errors; for example, error recovery when checking
 425         -- the RHS of 'main' can mean that 'main' is not in the envt for
 426         -- the subsequent checkMain test
 427         failIfErrsM ;
 428
 429         setEnvs tc_envs $
 430
 431         -- If there is no splice, we're nearly done
 432         case group_tail of {
 433            Nothing -> do {      -- Last thing: check for `main'
 434                            tcg_env <- checkMain ;
 435                            return (tcg_env, tcl_env)
 436                       } ;
 437
 438         -- If there's a splice, we must carry on
 439            Just (SpliceDecl splice_expr, rest_ds) -> do {
 440 #ifndef GHCI
 441         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 442 #else
 443
 444         -- Rename the splice expression, and get its supporting decls
 445         (rn_splice_expr, splice_fvs) <- rnLExpr splice_expr ;
 446         failIfErrsM ;   -- Don't typecheck if renaming failed
 447
 448         -- Execute the splice
 449         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 450
 451         -- Glue them on the front of the remaining decls and loop
 452         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 453         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 454 #endif /* GHCI */
 455     }}}
 456 \end{code}
 457
 458 %************************************************************************
 459 %*                                                                      *
 460         Compiling hs-boot source files, and
 461         comparing the hi-boot interface with the real thing
 462 %*                                                                      *
 463 %************************************************************************
 464
 465 \begin{code}
 466 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 467 tcRnHsBootDecls decls
 468    = do { let { (first_group, group_tail) = findSplice decls }
 469
 470         ; case group_tail of
 471              Just stuff -> spliceInHsBootErr stuff
 472              Nothing    -> return ()
 473
 474                 -- Rename the declarations
 475         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 476         ; setGblEnv tcg_env $ do {
 477
 478         -- Todo: check no foreign decls, no rules, no default decls
 479
 480                 -- Typecheck type/class decls
 481         ; traceTc (text "Tc2")
 482         ; let tycl_decls = hs_tyclds rn_group
 483         ; tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails tycl_decls)
 484         ; setGblEnv tcg_env     $ do {
 485
 486                 -- Typecheck instance decls
 487         ; traceTc (text "Tc3")
 488         ; (tcg_env, inst_infos, _binds) <- tcInstDecls1 tycl_decls (hs_instds rn_group)
 489         ; setGblEnv tcg_env     $ do {
 490
 491                 -- Typecheck value declarations
 492         ; traceTc (text "Tc5")
 493         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 494
 495                 -- Wrap up
 496                 -- No simplification or zonking to do
 497         ; traceTc (text "Tc7a")
 498         ; gbl_env <- getGblEnv
 499
 500                 -- Make the final type-env
 501                 -- Include the dfun_ids so that their type sigs get
 502                 -- are written into the interface file
 503         ; let { type_env0 = tcg_type_env gbl_env
 504               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 505               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 506               ; dfun_ids = map iDFunId inst_infos }
 507         ; return (gbl_env { tcg_type_env = type_env2 })
 508    }}}}
 509
 510 spliceInHsBootErr (SpliceDecl (L loc _), _)
 511   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 512 \end{code}
 513
 514 Once we've typechecked the body of the module, we want to compare what
 515 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 516
 517 \begin{code}
 518 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM (LHsBinds Id)
 519 -- Compare the hi-boot file for this module (if there is one)
 520 -- with the type environment we've just come up with
 521 -- In the common case where there is no hi-boot file, the list
 522 -- of boot_names is empty.
 523 --
 524 -- The bindings we return give bindings for the dfuns defined in the
 525 -- hs-boot file, such as        $fbEqT = $fEqT
 526
 527 checkHiBootIface
 528         (TcGblEnv { tcg_insts = local_insts, tcg_type_env = local_type_env })
 529         (ModDetails { md_insts = boot_insts, md_types = boot_type_env })
 530   = do  { mapM_ check_one (typeEnvElts boot_type_env)
 531         ; dfun_binds <- mapM check_inst boot_insts
 532         ; return (unionManyBags dfun_binds) }
 533   where
 534     check_one boot_thing
 535       | no_check name
 536       = return ()
 537       | otherwise
 538       = case lookupTypeEnv local_type_env name of
 539           Nothing         -> addErrTc (missingBootThing boot_thing)
 540           Just real_thing -> check_thing boot_thing real_thing
 541       where
 542         name = getName boot_thing
 543
 544     no_check name = isWiredInName name  -- No checking for wired-in names.  In particular,
 545                                         -- 'error' is handled by a rather gross hack
 546                                         -- (see comments in GHC.Err.hs-boot)
 547                   || name `elem` dfun_names
 548     dfun_names = map getName boot_insts
 549
 550     check_inst boot_inst
 551         = case [dfun | inst <- local_insts,
 552                        let dfun = instanceDFunId inst,
 553                        idType dfun `tcEqType` boot_inst_ty ] of
 554             [] -> do { addErrTc (instMisMatch boot_inst); return emptyBag }
 555             (dfun:_) -> return (unitBag $ noLoc $ VarBind local_boot_dfun (nlHsVar dfun))
 556         where
 557           boot_dfun = instanceDFunId boot_inst
 558           boot_inst_ty = idType boot_dfun
 559           local_boot_dfun = mkExportedLocalId (idName boot_dfun) boot_inst_ty
 560
 561 ----------------
 562 check_thing (ATyCon boot_tc) (ATyCon real_tc)
 563   | isSynTyCon boot_tc && isSynTyCon real_tc,
 564     defn1 `tcEqType` substTyWith tvs2 (mkTyVarTys tvs1) defn2
 565   = return ()
 566
 567   | tyConKind boot_tc == tyConKind real_tc
 568   = return ()
 569   where
 570     (tvs1, defn1) = getSynTyConDefn boot_tc
 571     (tvs2, defn2) = getSynTyConDefn boot_tc
 572
 573 check_thing (AnId boot_id) (AnId real_id)
 574   | idType boot_id `tcEqType` idType real_id
 575   = return ()
 576
 577 check_thing (ADataCon dc1) (ADataCon dc2)
 578   | idType (dataConWrapId dc1) `tcEqType` idType (dataConWrapId dc2)
 579   = return ()
 580
 581         -- Can't declare a class in a hi-boot file
 582
 583 check_thing boot_thing real_thing       -- Default case; failure
 584   = addErrAt (srcLocSpan (getSrcLoc real_thing))
 585              (bootMisMatch real_thing)
 586
 587 ----------------
 588 missingBootThing thing
 589   = ppr thing <+> ptext SLIT("is defined in the hs-boot file, but not in the module")
 590 bootMisMatch thing
 591   = ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file")
 592 instMisMatch inst
 593   = hang (ppr inst)
 594        2 (ptext SLIT("is defined in the hs-boot file, but not in the module"))
 595 \end{code}
 596
 597
 598 %************************************************************************
 599 %*                                                                      *
 600         Type-checking the top level of a module
 601 %*                                                                      *
 602 %************************************************************************
 603
 604 tcRnGroup takes a bunch of top-level source-code declarations, and
 605  * renames them
 606  * gets supporting declarations from interface files
 607  * typechecks them
 608  * zonks them
 609  * and augments the TcGblEnv with the results
 610
 611 In Template Haskell it may be called repeatedly for each group of
 612 declarations.  It expects there to be an incoming TcGblEnv in the
 613 monad; it augments it and returns the new TcGblEnv.
 614
 615 \begin{code}
 616 tcRnGroup :: ModDetails -> HsGroup RdrName -> TcM (TcGblEnv, TcLclEnv)
 617         -- Returns the variables free in the decls, for unused-binding reporting
 618 tcRnGroup boot_details decls
 619  = do {         -- Rename the declarations
 620         (tcg_env, rn_decls) <- rnTopSrcDecls decls ;
 621         setGblEnv tcg_env $ do {
 622
 623                 -- Typecheck the declarations
 624         tcTopSrcDecls boot_details rn_decls
 625   }}
 626
 627 ------------------------------------------------
 628 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 629 rnTopSrcDecls group
 630  = do {         -- Bring top level binders into scope
 631         tcg_env <- importsFromLocalDecls group ;
 632         setGblEnv tcg_env $ do {
 633
 634         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 635
 636                 -- Rename the source decls
 637         (tcg_env, rn_decls) <- rnSrcDecls group ;
 638         failIfErrsM ;
 639
 640                 -- save the renamed syntax, if we want it
 641         let { tcg_env'
 642                 | Just grp <- tcg_rn_decls tcg_env
 643                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 644                 | otherwise
 645                    = tcg_env };
 646
 647                 -- Dump trace of renaming part
 648         rnDump (ppr rn_decls) ;
 649
 650         return (tcg_env', rn_decls)
 651    }}
 652
 653 ------------------------------------------------
 654 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 655 tcTopSrcDecls boot_details
 656         (HsGroup { hs_tyclds = tycl_decls,
 657                    hs_instds = inst_decls,
 658                    hs_fords  = foreign_decls,
 659                    hs_defds  = default_decls,
 660                    hs_ruleds = rule_decls,
 661                    hs_valds  = val_binds })
 662  = do {         -- Type-check the type and class decls, and all imported decls
 663                 -- The latter come in via tycl_decls
 664         traceTc (text "Tc2") ;
 665
 666         tcg_env <- checkNoErrs (tcTyAndClassDecls boot_details tycl_decls) ;
 667         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 668         -- an error we'd better stop now, to avoid a cascade
 669
 670         -- Make these type and class decls available to stuff slurped from interface files
 671         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 672
 673
 674         setGblEnv tcg_env       $ do {
 675                 -- Source-language instances, including derivings,
 676                 -- and import the supporting declarations
 677         traceTc (text "Tc3") ;
 678         (tcg_env, inst_infos, deriv_binds) <- tcInstDecls1 tycl_decls inst_decls ;
 679         setGblEnv tcg_env       $ do {
 680
 681                 -- Foreign import declarations next.  No zonking necessary
 682                 -- here; we can tuck them straight into the global environment.
 683         traceTc (text "Tc4") ;
 684         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 685         tcExtendGlobalValEnv fi_ids     $ do {
 686
 687                 -- Default declarations
 688         traceTc (text "Tc4a") ;
 689         default_tys <- tcDefaults default_decls ;
 690         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 691
 692                 -- Value declarations next
 693                 -- We also typecheck any extra binds that came out
 694                 -- of the "deriving" process (deriv_binds)
 695         traceTc (text "Tc5") ;
 696         (tc_val_binds, lcl_env) <- tcTopBinds (val_binds ++ deriv_binds) ;
 697         setLclTypeEnv lcl_env   $ do {
 698
 699                 -- Second pass over class and instance declarations,
 700         traceTc (text "Tc6") ;
 701         (tcl_env, inst_binds) <- tcInstDecls2 tycl_decls inst_infos ;
 702         showLIE (text "after instDecls2") ;
 703
 704                 -- Foreign exports
 705                 -- They need to be zonked, so we return them
 706         traceTc (text "Tc7") ;
 707         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 708
 709                 -- Rules
 710         rules <- tcRules rule_decls ;
 711
 712                 -- Wrap up
 713         traceTc (text "Tc7a") ;
 714         tcg_env <- getGblEnv ;
 715         let { all_binds = tc_val_binds   `unionBags`
 716                           inst_binds     `unionBags`
 717                           foe_binds  ;
 718
 719                 -- Extend the GblEnv with the (as yet un-zonked)
 720                 -- bindings, rules, foreign decls
 721               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 722                                     tcg_rules = tcg_rules tcg_env ++ rules,
 723                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 724         return (tcg_env', lcl_env)
 725     }}}}}}
 726 \end{code}
 727
 728
 729 %************************************************************************
 730 %*                                                                      *
 731         Checking for 'main'
 732 %*                                                                      *
 733 %************************************************************************
 734
 735 \begin{code}
 736 checkMain
 737   = do { ghci_mode <- getGhciMode ;
 738          tcg_env   <- getGblEnv ;
 739          dflags    <- getDOpts ;
 740          let { main_mod = case mainModIs dflags of {
 741                                 Just mod -> mkModule mod ;
 742                                 Nothing  -> mAIN } ;
 743                main_fn  = case mainFunIs dflags of {
 744                                 Just fn -> mkRdrUnqual (mkVarOcc (mkFastString fn)) ;
 745                                 Nothing -> main_RDR_Unqual } } ;
 746
 747          check_main ghci_mode tcg_env main_mod main_fn
 748     }
 749
 750
 751 check_main ghci_mode tcg_env main_mod main_fn
 752      -- If we are in module Main, check that 'main' is defined.
 753      -- It may be imported from another module!
 754      --
 755      --
 756      -- Blimey: a whole page of code to do this...
 757  | mod /= main_mod
 758  = return tcg_env
 759
 760  | otherwise
 761  = addErrCtxt mainCtxt                  $
 762    do   { mb_main <- lookupSrcOcc_maybe main_fn
 763                 -- Check that 'main' is in scope
 764                 -- It might be imported from another module!
 765         ; case mb_main of {
 766              Nothing -> do { complain_no_main
 767                            ; return tcg_env } ;
 768              Just main_name -> do
 769         { let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 770                         -- :Main.main :: IO () = runMainIO main
 771
 772         ; (main_expr, ty) <- setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 773                              tcInferRho rhs
 774
 775         ; let { root_main_id = mkExportedLocalId rootMainName ty ;
 776                 main_bind    = noLoc (VarBind root_main_id main_expr) }
 777
 778         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 779                                         `snocBag` main_bind,
 780                             tcg_dus   = tcg_dus tcg_env
 781                                         `plusDU` usesOnly (unitFV main_name)
 782                         -- Record the use of 'main', so that we don't
 783                         -- complain about it being defined but not used
 784                  })
 785     }}}
 786   where
 787     mod = tcg_mod tcg_env
 788
 789     complain_no_main | ghci_mode == Interactive = return ()
 790                      | otherwise                = failWithTc noMainMsg
 791         -- In interactive mode, don't worry about the absence of 'main'
 792         -- In other modes, fail altogether, so that we don't go on
 793         -- and complain a second time when processing the export list.
 794
 795     mainCtxt  = ptext SLIT("When checking the type of the main function") <+> quotes (ppr main_fn)
 796     noMainMsg = ptext SLIT("The main function") <+> quotes (ppr main_fn)
 797                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 798 \end{code}
 799
 800 %*********************************************************
 801 %*                                                       *
 802                 GHCi stuff
 803 %*                                                       *
 804 %*********************************************************
 805
 806 \begin{code}
 807 #ifdef GHCI
 808 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 809 setInteractiveContext hsc_env icxt thing_inside
 810   = let
 811         -- Initialise the tcg_inst_env with instances
 812         -- from all home modules.  This mimics the more selective
 813         -- call to hptInstances in tcRnModule
 814         dfuns = hptInstances hsc_env (\mod -> True)
 815     in
 816     updGblEnv (\env -> env {
 817         tcg_rdr_env  = ic_rn_gbl_env icxt,
 818         tcg_type_env = ic_type_env   icxt,
 819         tcg_inst_env = extendInstEnvList (tcg_inst_env env) dfuns }) $
 820
 821     updLclEnv (\env -> env { tcl_rdr = ic_rn_local_env icxt })  $
 822
 823     do  { traceTc (text "setIC" <+> ppr (ic_type_env icxt))
 824         ; thing_inside }
 825 \end{code}
 826
 827
 828 \begin{code}
 829 tcRnStmt :: HscEnv
 830          -> InteractiveContext
 831          -> LStmt RdrName
 832          -> IO (Maybe (InteractiveContext, [Name], LHsExpr Id))
 833                 -- The returned [Name] is the same as the input except for
 834                 -- ExprStmt, in which case the returned [Name] is [itName]
 835                 --
 836                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 837                 -- a list of the bound values, coerced to ().
 838
 839 tcRnStmt hsc_env ictxt rdr_stmt
 840   = initTcPrintErrors hsc_env iNTERACTIVE $
 841     setInteractiveContext hsc_env ictxt $ do {
 842
 843     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 844     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 845     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 846     failIfErrsM ;
 847
 848     -- The real work is done here
 849     (bound_ids, tc_expr) <- tcUserStmt rn_stmt ;
 850
 851     traceTc (text "tcs 1") ;
 852     let {       -- (a) Make all the bound ids "global" ids, now that
 853                 --     they're notionally top-level bindings.  This is
 854                 --     important: otherwise when we come to compile an expression
 855                 --     using these ids later, the byte code generator will consider
 856                 --     the occurrences to be free rather than global.
 857                 --
 858                 -- (b) Tidy their types; this is important, because :info may
 859                 --     ask to look at them, and :info expects the things it looks
 860                 --     up to have tidy types
 861         global_ids = map globaliseAndTidy bound_ids ;
 862
 863                 -- Update the interactive context
 864         rn_env   = ic_rn_local_env ictxt ;
 865         type_env = ic_type_env ictxt ;
 866
 867         bound_names = map idName global_ids ;
 868         new_rn_env  = extendLocalRdrEnv rn_env bound_names ;
 869
 870                 -- Remove any shadowed bindings from the type_env;
 871                 -- they are inaccessible but might, I suppose, cause
 872                 -- a space leak if we leave them there
 873         shadowed = [ n | name <- bound_names,
 874                          let rdr_name = mkRdrUnqual (nameOccName name),
 875                          Just n <- [lookupLocalRdrEnv rn_env rdr_name] ] ;
 876
 877         filtered_type_env = delListFromNameEnv type_env shadowed ;
 878         new_type_env = extendTypeEnvWithIds filtered_type_env global_ids ;
 879
 880         new_ic = ictxt { ic_rn_local_env = new_rn_env,
 881                          ic_type_env     = new_type_env }
 882     } ;
 883
 884     dumpOptTcRn Opt_D_dump_tc
 885         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 886                text "Typechecked expr" <+> ppr tc_expr]) ;
 887
 888     returnM (new_ic, bound_names, tc_expr)
 889     }
 890
 891 globaliseAndTidy :: Id -> Id
 892 globaliseAndTidy id
 893 -- Give the Id a Global Name, and tidy its type
 894   = setIdType (globaliseId VanillaGlobal id) tidy_type
 895   where
 896     tidy_type = tidyTopType (idType id)
 897 \end{code}
 898
 899 Here is the grand plan, implemented in tcUserStmt
 900
 901         What you type                   The IO [HValue] that hscStmt returns
 902         -------------                   ------------------------------------
 903         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 904                                         bindings: [x,y,...]
 905
 906         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 907                                         bindings: [x,y,...]
 908
 909         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 910           [NB: result not printed]      bindings: [it]
 911
 912         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 913           result showable)              bindings: [it]
 914
 915         expr (of non-IO type,
 916           result not showable)  ==>     error
 917
 918
 919 \begin{code}
 920 ---------------------------
 921 tcUserStmt :: LStmt Name -> TcM ([Id], LHsExpr Id)
 922 tcUserStmt (L loc (ExprStmt expr _ _))
 923   = newUnique           `thenM` \ uniq ->
 924     let
 925         fresh_it = itName uniq
 926         the_bind = noLoc $ FunBind (noLoc fresh_it) False
 927                              (mkMatchGroup [mkSimpleMatch [] expr])
 928     in
 929     tryTcLIE_ (do {     -- Try this if the other fails
 930                 traceTc (text "tcs 1b") ;
 931                 tc_stmts (map (L loc) [
 932                     LetStmt [HsBindGroup (unitBag the_bind) [] NonRecursive],
 933                     ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
 934                              (HsVar thenIOName) placeHolderType
 935         ]) })
 936           (do {         -- Try this first
 937                 traceTc (text "tcs 1a") ;
 938                 tc_stmts [L loc (BindStmt (nlVarPat fresh_it) expr
 939                                           (HsVar bindIOName) noSyntaxExpr) ] })
 940
 941 tcUserStmt stmt = tc_stmts [stmt]
 942
 943 ---------------------------
 944 tc_stmts :: [LStmt Name] -> TcM ([Id], LHsExpr Id)
 945 tc_stmts stmts
 946  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
 947         let {
 948             ret_ty    = mkListTy unitTy ;
 949             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
 950
 951             names = map unLoc (collectLStmtsBinders stmts) ;
 952
 953                 -- mk_return builds the expression
 954                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
 955                 --
 956                 -- Despite the inconvenience of building the type applications etc,
 957                 -- this *has* to be done in type-annotated post-typecheck form
 958                 -- because we are going to return a list of *polymorphic* values
 959                 -- coerced to type (). If we built a *source* stmt
 960                 --      return [coerce x, ..., coerce z]
 961                 -- then the type checker would instantiate x..z, and we wouldn't
 962                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
 963                 -- if they were overloaded, since they aren't applied to anything.)
 964             mk_return ret_id ids = nlHsApp (noLoc $ TyApp (nlHsVar ret_id) [ret_ty])
 965                                            (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
 966             mk_item id = nlHsApp (noLoc $ TyApp (nlHsVar unsafeCoerceId) [idType id, unitTy])
 967                                (nlHsVar id) ;
 968
 969             io_ty = mkTyConApp ioTyCon []
 970          } ;
 971
 972         -- OK, we're ready to typecheck the stmts
 973         traceTc (text "tcs 2") ;
 974         ((ids, tc_expr), lie) <- getLIE $ do {
 975                 (tc_stmts, ids) <- tcStmts DoExpr (tcDoStmt io_ty io_ret_ty) stmts $
 976                                 do {
 977                                     -- Look up the names right in the middle,
 978                                     -- where they will all be in scope
 979                                     ids <- mappM tcLookupId names ;
 980                                     return ids } ;
 981
 982             ret_id <- tcLookupId returnIOName ;         -- return @ IO
 983             return (ids, noLoc (HsDo DoExpr tc_stmts (mk_return ret_id ids) io_ret_ty))
 984         } ;
 985
 986         -- Simplify the context right here, so that we fail
 987         -- if there aren't enough instances.  Notably, when we see
 988         --              e
 989         -- we use recoverTc_ to try     it <- e
 990         -- and then                     let it = e
 991         -- It's the simplify step that rejects the first.
 992         traceTc (text "tcs 3") ;
 993         const_binds <- tcSimplifyInteractive lie ;
 994
 995         -- Build result expression and zonk it
 996         let { expr = mkHsLet const_binds tc_expr } ;
 997         zonked_expr <- zonkTopLExpr expr ;
 998         zonked_ids  <- zonkTopBndrs ids ;
 999
1000         -- None of the Ids should be of unboxed type, because we
1001         -- cast them all to HValues in the end!
1002         mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
1003
1004         return (zonked_ids, zonked_expr)
1005         }
1006   where
1007     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
1008                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
1009 \end{code}
1010
1011
1012 tcRnExpr just finds the type of an expression
1013
1014 \begin{code}
1015 tcRnExpr :: HscEnv
1016          -> InteractiveContext
1017          -> LHsExpr RdrName
1018          -> IO (Maybe Type)
1019 tcRnExpr hsc_env ictxt rdr_expr
1020   = initTcPrintErrors hsc_env iNTERACTIVE $
1021     setInteractiveContext hsc_env ictxt $ do {
1022
1023     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1024     failIfErrsM ;
1025
1026         -- Now typecheck the expression;
1027         -- it might have a rank-2 type (e.g. :t runST)
1028     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1029     ((qtvs, _, dict_ids), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1030     tcSimplifyInteractive lie_top ;
1031     qtvs' <- mappM zonkQuantifiedTyVar qtvs ;
1032
1033     let { all_expr_ty = mkForAllTys qtvs' $
1034                         mkFunTys (map idType dict_ids)  $
1035                         res_ty } ;
1036     zonkTcType all_expr_ty
1037     }
1038   where
1039     smpl_doc = ptext SLIT("main expression")
1040 \end{code}
1041
1042 tcRnType just finds the kind of a type
1043
1044 \begin{code}
1045 tcRnType :: HscEnv
1046          -> InteractiveContext
1047          -> LHsType RdrName
1048          -> IO (Maybe Kind)
1049 tcRnType hsc_env ictxt rdr_type
1050   = initTcPrintErrors hsc_env iNTERACTIVE $
1051     setInteractiveContext hsc_env ictxt $ do {
1052
1053     rn_type <- rnLHsType doc rdr_type ;
1054     failIfErrsM ;
1055
1056         -- Now kind-check the type
1057     (ty', kind) <- kcHsType rn_type ;
1058     return kind
1059     }
1060   where
1061     doc = ptext SLIT("In GHCi input")
1062
1063 #endif /* GHCi */
1064 \end{code}
1065
1066
1067 %************************************************************************
1068 %*                                                                      *
1069         More GHCi stuff, to do with browsing and getting info
1070 %*                                                                      *
1071 %************************************************************************
1072
1073 \begin{code}
1074 #ifdef GHCI
1075 getModuleExports :: HscEnv -> Module -> IO (Maybe NameSet)
1076 getModuleExports hsc_env mod
1077   = initTcPrintErrors hsc_env iNTERACTIVE (tcGetModuleExports mod)
1078
1079 tcGetModuleExports :: Module -> TcM NameSet
1080 tcGetModuleExports mod = do
1081   iface <- load_iface mod
1082   loadOrphanModules (dep_orphs (mi_deps iface))
1083                 -- Load any orphan-module interfaces,
1084                 -- so their instances are visible
1085   ifaceExportNames (mi_exports iface)
1086
1087 mkExportEnv :: HscEnv -> [Module]       -- Expose these modules' exports only
1088             -> IO GlobalRdrEnv
1089 mkExportEnv hsc_env exports
1090   = do  { mb_envs <- initTcPrintErrors hsc_env iNTERACTIVE $
1091                      mappM getModuleExportRdrEnv exports
1092         ; case mb_envs of
1093              Just envs -> return (foldr plusGlobalRdrEnv emptyGlobalRdrEnv envs)
1094              Nothing   -> return emptyGlobalRdrEnv
1095                              -- Some error; initTc will have printed it
1096     }
1097
1098 getModuleExportRdrEnv :: Module -> TcM GlobalRdrEnv
1099 getModuleExportRdrEnv mod = do
1100   names <- tcGetModuleExports mod
1101   let gres =  [ GRE  { gre_name = name, gre_prov = vanillaProv mod }
1102               | name <- nameSetToList names ]
1103   returnM (mkGlobalRdrEnv gres)
1104
1105 vanillaProv :: Module -> Provenance
1106 -- We're building a GlobalRdrEnv as if the user imported
1107 -- all the specified modules into the global interactive module
1108 vanillaProv mod = Imported [ImportSpec { is_mod = mod, is_as = mod,
1109                                          is_qual = False, is_explicit = False,
1110                                          is_loc = srcLocSpan interactiveSrcLoc }]
1111
1112 \end{code}
1113
1114 \begin{code}
1115 getModuleContents
1116   :: HscEnv
1117   -> Module                     -- Module to inspect
1118   -> Bool                       -- Grab just the exports, or the whole toplev
1119   -> IO (Maybe [IfaceDecl])
1120
1121 getModuleContents hsc_env mod exports_only
1122  = initTcPrintErrors hsc_env iNTERACTIVE (get_mod_contents exports_only)
1123  where
1124    get_mod_contents exports_only
1125       | not exports_only  -- We want the whole top-level type env
1126                           -- so it had better be a home module
1127       = do { hpt <- getHpt
1128            ; case lookupModuleEnv hpt mod of
1129                Just mod_info -> return (map (toIfaceDecl ext_nm) $
1130                                         filter wantToSee $
1131                                         typeEnvElts $
1132                                         md_types (hm_details mod_info))
1133                Nothing -> ghcError (ProgramError (showSDoc (noRdrEnvErr mod)))
1134                           -- This is a system error; the module should be in the HPT
1135            }
1136
1137       | otherwise               -- Want the exports only
1138       = do { iface <- load_iface mod
1139            ; mappM get_decl [ (mod,avail) | (mod, avails) <- mi_exports iface
1140                                           , avail <- avails ]
1141         }
1142
1143    get_decl (mod, avail)
1144         = do { main_name <- lookupOrig mod (availName avail)
1145              ; thing     <- tcLookupGlobal main_name
1146              ; return (filter_decl (availNames avail) (toIfaceDecl ext_nm thing)) }
1147
1148    ext_nm = interactiveExtNameFun (icPrintUnqual (hsc_IC hsc_env))
1149
1150 ---------------------
1151 filter_decl occs decl@(IfaceClass {ifSigs = sigs})
1152   = decl { ifSigs = filter (keep_sig occs) sigs }
1153 filter_decl occs decl@(IfaceData {ifCons = IfDataTyCon cons})
1154   = decl { ifCons = IfDataTyCon (filter (keep_con occs) cons) }
1155 filter_decl occs decl@(IfaceData {ifCons = IfNewTyCon con})
1156   | keep_con occs con = decl
1157   | otherwise         = decl {ifCons = IfAbstractTyCon} -- Hmm?
1158 filter_decl occs decl
1159   = decl
1160
1161 keep_sig occs (IfaceClassOp occ _ _) = occ `elem` occs
1162 keep_con occs con                    = ifConOcc con `elem` occs
1163
1164 wantToSee (AnId id)    = not (isImplicitId id)
1165 wantToSee (ADataCon _) = False  -- They'll come via their TyCon
1166 wantToSee _            = True
1167
1168 ---------------------
1169 load_iface mod = loadSrcInterface doc mod False {- Not boot iface -}
1170                where
1171                  doc = ptext SLIT("context for compiling statements")
1172
1173 ---------------------
1174 noRdrEnvErr mod = ptext SLIT("No top-level environment available for module")
1175                   <+> quotes (ppr mod)
1176 \end{code}
1177
1178 \begin{code}
1179 type GetInfoResult = (String, IfaceDecl, Fixity, SrcLoc,
1180                               [(IfaceType,SrcLoc)]      -- Instances
1181                      )
1182
1183 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Maybe [Name])
1184
1185 tcRnLookupRdrName hsc_env rdr_name
1186   = initTcPrintErrors hsc_env iNTERACTIVE $
1187     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1188     lookup_rdr_name rdr_name
1189
1190
1191 lookup_rdr_name rdr_name = do {
1192         -- If the identifier is a constructor (begins with an
1193         -- upper-case letter), then we need to consider both
1194         -- constructor and type class identifiers.
1195     let { rdr_names = dataTcOccs rdr_name } ;
1196
1197         -- results :: [(Messages, Maybe Name)]
1198     results <- mapM (tryTc . lookupOccRn) rdr_names ;
1199
1200     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1201         -- The successful lookups will be (Just name)
1202     let { (warns_s, good_names) = unzip [ (msgs, name)
1203                                         | (msgs, Just name) <- results] ;
1204           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1205
1206         -- Fail if nothing good happened, else add warnings
1207     if null good_names then
1208                 -- No lookup succeeded, so
1209                 -- pick the first error message and report it
1210                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1211                 --       while the other is "X is not in scope",
1212                 --       we definitely want the former; but we might pick the latter
1213         do { addMessages (head errs_s) ; failM }
1214       else                      -- Add deprecation warnings
1215         mapM_ addMessages warns_s ;
1216
1217     return good_names
1218  }
1219
1220
1221 tcRnGetInfo :: HscEnv
1222             -> InteractiveContext
1223             -> RdrName
1224             -> IO (Maybe [GetInfoResult])
1225
1226 -- Used to implemnent :info in GHCi
1227 --
1228 -- Look up a RdrName and return all the TyThings it might be
1229 -- A capitalised RdrName is given to us in the DataName namespace,
1230 -- but we want to treat it as *both* a data constructor
1231 --  *and* as a type or class constructor;
1232 -- hence the call to dataTcOccs, and we return up to two results
1233 tcRnGetInfo hsc_env ictxt rdr_name
1234   = initTcPrintErrors hsc_env iNTERACTIVE $
1235     setInteractiveContext hsc_env ictxt $ do {
1236
1237         -- Load the interface for all unqualified types and classes
1238         -- That way we will find all the instance declarations
1239         -- (Packages have not orphan modules, and we assume that
1240         --  in the home package all relevant modules are loaded.)
1241     loadUnqualIfaces ictxt ;
1242
1243     good_names <- lookup_rdr_name rdr_name ;
1244
1245         -- And lookup up the entities, avoiding duplicates, which arise
1246         -- because constructors and record selectors are represented by
1247         -- their parent declaration
1248     let { do_one name = do { thing  <- tcLookupGlobal name
1249                            ; fixity <- lookupFixityRn name
1250                            ; ispecs <- lookupInsts print_unqual thing
1251                            ; return (str, toIfaceDecl ext_nm thing, fixity,
1252                                      getSrcLoc thing,
1253                                      [(toIfaceType ext_nm (idType dfun), getSrcLoc dfun)
1254                                      | dfun <- map instanceDFunId ispecs ]
1255                              ) }
1256                 where
1257                         -- str is the the naked occurrence name
1258                         -- after stripping off qualification and parens (+)
1259                   str = occNameUserString (nameOccName name)
1260         } ;
1261
1262                 -- For the SrcLoc, the 'thing' has better info than
1263                 -- the 'name' because getting the former forced the
1264                 -- declaration to be loaded into the cache
1265
1266     results <- mapM do_one good_names ;
1267     return (fst (removeDups cmp results))
1268     }
1269   where
1270     cmp (_,d1,_,_,_) (_,d2,_,_,_) = ifName d1 `compare` ifName d2
1271     ext_nm = interactiveExtNameFun print_unqual
1272     print_unqual = icPrintUnqual ictxt
1273
1274 lookupInsts :: PrintUnqualified -> TyThing -> TcM [Instance]
1275 -- Filter the instances by the ones whose tycons (or clases resp)
1276 -- are in scope unqualified.  Otherwise we list a whole lot too many!
1277 lookupInsts print_unqual (AClass cls)
1278   = do  { inst_envs <- tcGetInstEnvs
1279         ; return [ ispec
1280                  | ispec <- classInstances inst_envs cls
1281                  , plausibleDFun print_unqual (instanceDFunId ispec) ] }
1282
1283 lookupInsts print_unqual (ATyCon tc)
1284   = do  { eps <- getEps -- Load all instances for all classes that are
1285                         -- in the type environment (which are all the ones
1286                         -- we've seen in any interface file so far)
1287         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1288         ; return [ ispec
1289                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1290                  , let dfun = instanceDFunId ispec
1291                  , relevant dfun
1292                  , plausibleDFun print_unqual dfun ] }
1293   where
1294     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1295     tc_name     = tyConName tc
1296
1297 lookupInsts print_unqual other = return []
1298
1299 plausibleDFun print_unqual dfun -- Dfun involving only names that print unqualified
1300   = all ok (nameSetToList (tyClsNamesOfType (idType dfun)))
1301   where
1302     ok name | isExternalName name = print_unqual (nameModule name) (nameOccName name)
1303             | otherwise           = True
1304
1305 toIfaceDecl :: (Name -> IfaceExtName) -> TyThing -> IfaceDecl
1306 toIfaceDecl ext_nm thing
1307   = tyThingToIfaceDecl ext_nm (munge thing)
1308   where
1309         -- munge transforms a thing to its "parent" thing
1310     munge (ADataCon dc) = ATyCon (dataConTyCon dc)
1311     munge (AnId id) = case globalIdDetails id of
1312                         RecordSelId tc lbl -> ATyCon tc
1313                         ClassOpId cls      -> AClass cls
1314                         other              -> AnId id
1315     munge other_thing = other_thing
1316
1317 loadUnqualIfaces :: InteractiveContext -> TcM ()
1318 -- Load the home module for everything that is in scope unqualified
1319 -- This is so that we can accurately report the instances for
1320 -- something
1321 loadUnqualIfaces ictxt
1322   = initIfaceTcRn $
1323     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1324   where
1325     unqual_mods = [ nameModule name
1326                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1327                     let name = gre_name gre,
1328                     isTcOcc (nameOccName name),  -- Types and classes only
1329                     unQualOK gre ]               -- In scope unqualified
1330     doc = ptext SLIT("Need interface for module whose export(s) are in scope unqualified")
1331 #endif /* GHCI */
1332 \end{code}
1333
1334 %************************************************************************
1335 %*                                                                      *
1336                 Degugging output
1337 %*                                                                      *
1338 %************************************************************************
1339
1340 \begin{code}
1341 rnDump :: SDoc -> TcRn ()
1342 -- Dump, with a banner, if -ddump-rn
1343 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1344
1345 tcDump :: TcGblEnv -> TcRn ()
1346 tcDump env
1347  = do { dflags <- getDOpts ;
1348
1349         -- Dump short output if -ddump-types or -ddump-tc
1350         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1351             (dumpTcRn short_dump) ;
1352
1353         -- Dump bindings if -ddump-tc
1354         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1355    }
1356   where
1357     short_dump = pprTcGblEnv env
1358     full_dump  = pprLHsBinds (tcg_binds env)
1359         -- NB: foreign x-d's have undefined's in their types;
1360         --     hence can't show the tc_fords
1361
1362 tcCoreDump mod_guts
1363  = do { dflags <- getDOpts ;
1364         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1365             (dumpTcRn (pprModGuts mod_guts)) ;
1366
1367         -- Dump bindings if -ddump-tc
1368         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1369   where
1370     full_dump = pprCoreBindings (mg_binds mod_guts)
1371
1372 -- It's unpleasant having both pprModGuts and pprModDetails here
1373 pprTcGblEnv :: TcGblEnv -> SDoc
1374 pprTcGblEnv (TcGblEnv { tcg_type_env = type_env,
1375                         tcg_insts    = dfun_ids,
1376                         tcg_rules    = rules,
1377                         tcg_imports  = imports })
1378   = vcat [ ppr_types dfun_ids type_env
1379          , ppr_insts dfun_ids
1380          , vcat (map ppr rules)
1381          , ppr_gen_tycons (typeEnvTyCons type_env)
1382          , ptext SLIT("Dependent modules:") <+> ppr (moduleEnvElts (imp_dep_mods imports))
1383          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1384
1385 pprModGuts :: ModGuts -> SDoc
1386 pprModGuts (ModGuts { mg_types = type_env,
1387                       mg_rules = rules })
1388   = vcat [ ppr_types [] type_env,
1389            ppr_rules rules ]
1390
1391
1392 ppr_types :: [Instance] -> TypeEnv -> SDoc
1393 ppr_types ispecs type_env
1394   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1395   where
1396     dfun_ids = map instanceDFunId ispecs
1397     ids = [id | id <- typeEnvIds type_env, want_sig id]
1398     want_sig id | opt_PprStyle_Debug = True
1399                 | otherwise          = isLocalId id &&
1400                                        isExternalName (idName id) &&
1401                                        not (id `elem` dfun_ids)
1402         -- isLocalId ignores data constructors, records selectors etc.
1403         -- The isExternalName ignores local dictionary and method bindings
1404         -- that the type checker has invented.  Top-level user-defined things
1405         -- have External names.
1406
1407 ppr_insts :: [Instance] -> SDoc
1408 ppr_insts []     = empty
1409 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1410
1411 ppr_sigs :: [Var] -> SDoc
1412 ppr_sigs ids
1413         -- Print type signatures; sort by OccName
1414   = vcat (map ppr_sig (sortLe le_sig ids))
1415   where
1416     le_sig id1 id2 = getOccName id1 <= getOccName id2
1417     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1418
1419 ppr_rules :: [CoreRule] -> SDoc
1420 ppr_rules [] = empty
1421 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1422                       nest 4 (pprRules rs),
1423                       ptext SLIT("#-}")]
1424
1425 ppr_gen_tycons []  = empty
1426 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1427                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1428 \end{code}