ghc/compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcRnDriver (
   8 #ifdef GHCI
   9         getModuleContents, tcRnStmt,
  10         tcRnGetInfo, GetInfoResult,
  11         tcRnExpr, tcRnType,
  12         tcRnLookupRdrName,
  13         getModuleExports,
  14 #endif
  15         tcRnModule,
  16         tcTopSrcDecls,
  17         tcRnExtCore
  18     ) where
  19
  20 #include "HsVersions.h"
  21
  22 import IO
  23 #ifdef GHCI
  24 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  25 #endif
  26
  27 import DynFlags         ( DynFlag(..), DynFlags(..), dopt, GhcMode(..) )
  28 import StaticFlags      ( opt_PprStyle_Debug )
  29 import Packages         ( moduleToPackageConfig, mkPackageId, package,
  30                           isHomeModule )
  31 import HsSyn            ( HsModule(..), HsExtCore(..), HsGroup(..), LHsDecl,
  32                           SpliceDecl(..), HsBind(..), LHsBinds,
  33                           emptyGroup, appendGroups,
  34                           nlHsApp, nlHsVar, pprLHsBinds )
  35 import RdrHsSyn         ( findSplice )
  36
  37 import PrelNames        ( runMainIOName, rootMainName, mAIN,
  38                           main_RDR_Unqual )
  39 import RdrName          ( RdrName, mkRdrUnqual, emptyGlobalRdrEnv )
  40 import TcHsSyn          ( zonkTopDecls )
  41 import TcExpr           ( tcInferRho )
  42 import TcRnMonad
  43 import TcType           ( tidyTopType, tcEqType, mkTyVarTys, substTyWith )
  44 import Inst             ( showLIE )
  45 import InstEnv          ( extendInstEnvList, Instance, pprInstances, instanceDFunId )
  46 import TcBinds          ( tcTopBinds, tcHsBootSigs )
  47 import TcDefaults       ( tcDefaults )
  48 import TcEnv            ( tcExtendGlobalValEnv, iDFunId )
  49 import TcRules          ( tcRules )
  50 import TcForeign        ( tcForeignImports, tcForeignExports )
  51 import TcInstDcls       ( tcInstDecls1, tcInstDecls2 )
  52 import TcIface          ( tcExtCoreBindings, tcHiBootIface )
  53 import TcSimplify       ( tcSimplifyTop )
  54 import TcTyClsDecls     ( tcTyAndClassDecls )
  55 import LoadIface        ( loadOrphanModules )
  56 import RnNames          ( importsFromLocalDecls, rnImports, exportsFromAvail,
  57                           reportUnusedNames, reportDeprecations )
  58 import RnEnv            ( lookupSrcOcc_maybe )
  59 import RnSource         ( rnSrcDecls, rnTyClDecls, checkModDeprec )
  60 import PprCore          ( pprRules, pprCoreBindings )
  61 import CoreSyn          ( CoreRule, bindersOfBinds )
  62 import DataCon          ( dataConWrapId )
  63 import ErrUtils         ( Messages, mkDumpDoc, showPass )
  64 import Id               ( Id, mkExportedLocalId, isLocalId, idName, idType )
  65 import Var              ( Var )
  66 import Module           ( Module, ModuleEnv, mkModule, moduleEnvElts, elemModuleEnv )
  67 import OccName          ( mkVarOcc )
  68 import Name             ( Name, NamedThing(..), isExternalName, getSrcLoc, isWiredInName )
  69 import NameSet
  70 import TyCon            ( tyConHasGenerics, isSynTyCon, getSynTyConDefn, tyConKind )
  71 import SrcLoc           ( srcLocSpan, Located(..), noLoc )
  72 import DriverPhases     ( HscSource(..), isHsBoot )
  73 import HscTypes         ( ModGuts(..), ModDetails(..), emptyModDetails,
  74                           HscEnv(..), ExternalPackageState(..),
  75                           IsBootInterface, noDependencies,
  76                           Deprecs( NoDeprecs ), plusDeprecs,
  77                           ForeignStubs(NoStubs), TyThing(..),
  78                           TypeEnv, lookupTypeEnv, hptInstances,
  79                           extendTypeEnvWithIds, typeEnvIds, typeEnvTyCons, typeEnvElts,
  80                           emptyFixityEnv
  81                         )
  82 import Outputable
  83
  84 #ifdef GHCI
  85 import HsSyn            ( HsStmtContext(..), Stmt(..), HsExpr(..), HsBindGroup(..),
  86                           LStmt, LHsExpr, LHsType, mkMatchGroup,
  87                           collectLStmtsBinders, mkSimpleMatch, nlVarPat,
  88                           placeHolderType, noSyntaxExpr )
  89 import RdrName          ( GlobalRdrElt(..), globalRdrEnvElts,
  90                           unQualOK, lookupLocalRdrEnv, extendLocalRdrEnv )
  91 import RnSource         ( addTcgDUs )
  92 import TcHsSyn          ( mkHsLet, zonkTopLExpr, zonkTopBndrs )
  93 import TcHsType         ( kcHsType )
  94 import TcMType          ( zonkTcType, zonkQuantifiedTyVar )
  95 import TcMatches        ( tcStmts, tcDoStmt )
  96 import TcSimplify       ( tcSimplifyInteractive, tcSimplifyInfer )
  97 import TcType           ( Type, mkForAllTys, mkFunTys, mkTyConApp, tyVarsOfType,
  98                           isUnLiftedType, tyClsNamesOfDFunHead, tyClsNamesOfType )
  99 import TcEnv            ( tcLookupTyCon, tcLookupId, tcLookupGlobal )
 100 import RnTypes          ( rnLHsType )
 101 import Inst             ( tcGetInstEnvs )
 102 import InstEnv          ( classInstances, instEnvElts )
 103 import RnExpr           ( rnStmts, rnLExpr )
 104 import LoadIface        ( loadSrcInterface, loadSysInterface )
 105 import IfaceSyn         ( IfaceDecl(..), IfaceClassOp(..), IfaceConDecl(..),
 106                           IfaceExtName(..), IfaceConDecls(..),
 107                           tyThingToIfaceDecl )
 108 import IfaceType        ( IfaceType, toIfaceType,
 109                           interactiveExtNameFun )
 110 import IfaceEnv         ( lookupOrig, ifaceExportNames )
 111 import Module           ( lookupModuleEnv, moduleSetElts, mkModuleSet )
 112 import RnEnv            ( lookupOccRn, dataTcOccs, lookupFixityRn )
 113 import Id               ( isImplicitId, setIdType, globalIdDetails )
 114 import MkId             ( unsafeCoerceId )
 115 import DataCon          ( dataConTyCon )
 116 import TyCon            ( tyConName )
 117 import TysWiredIn       ( mkListTy, unitTy )
 118 import IdInfo           ( GlobalIdDetails(..) )
 119 import SrcLoc           ( unLoc )
 120 import Kind             ( Kind )
 121 import Var              ( globaliseId )
 122 import Name             ( nameOccName, nameModule, isBuiltInSyntax, nameParent_maybe )
 123 import OccName          ( occNameUserString, isTcOcc )
 124 import NameEnv          ( delListFromNameEnv )
 125 import PrelNames        ( iNTERACTIVE, ioTyConName, printName, itName,
 126                           bindIOName, thenIOName, returnIOName )
 127 import HscTypes         ( InteractiveContext(..), HomeModInfo(..),
 128                           availNames, availName, ModIface(..), icPrintUnqual,
 129                           Dependencies(..) )
 130 import BasicTypes       ( RecFlag(..), Fixity )
 131 import Panic            ( ghcError, GhcException(..) )
 132 import SrcLoc           ( SrcLoc )
 133 #endif
 134
 135 import FastString       ( mkFastString )
 136 import Util             ( sortLe )
 137 import Bag              ( unionBags, snocBag, emptyBag, unitBag, unionManyBags )
 138
 139 import Maybe            ( isJust )
 140 \end{code}
 141
 142
 143
 144 %************************************************************************
 145 %*                                                                      *
 146         Typecheck and rename a module
 147 %*                                                                      *
 148 %************************************************************************
 149
 150
 151 \begin{code}
 152 tcRnModule :: HscEnv
 153            -> HscSource
 154            -> Bool              -- True <=> save renamed syntax
 155            -> Located (HsModule RdrName)
 156            -> IO (Messages, Maybe TcGblEnv)
 157
 158 tcRnModule hsc_env hsc_src save_rn_decls
 159          (L loc (HsModule maybe_mod export_ies
 160                           import_decls local_decls mod_deprec))
 161  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 162
 163    let { this_mod = case maybe_mod of
 164                         Nothing  -> mAIN          -- 'module M where' is omitted
 165                         Just (L _ mod) -> mod } ; -- The normal case
 166
 167    initTc hsc_env hsc_src this_mod $
 168    setSrcSpan loc $
 169    do {
 170         checkForPackageModule (hsc_dflags hsc_env) this_mod;
 171
 172                 -- Deal with imports; sets tcg_rdr_env, tcg_imports
 173         (rdr_env, imports) <- rnImports import_decls ;
 174
 175         let { dep_mods :: ModuleEnv (Module, IsBootInterface)
 176             ; dep_mods = imp_dep_mods imports
 177
 178                 -- We want instance declarations from all home-package
 179                 -- modules below this one, including boot modules, except
 180                 -- ourselves.  The 'except ourselves' is so that we don't
 181                 -- get the instances from this module's hs-boot file
 182             ; want_instances :: Module -> Bool
 183             ; want_instances mod = mod `elemModuleEnv` dep_mods
 184                                    && mod /= this_mod
 185             ; home_insts = hptInstances hsc_env want_instances
 186             } ;
 187
 188                 -- Record boot-file info in the EPS, so that it's
 189                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 190                 -- and any other incrementally-performed imports
 191         updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 192
 193                 -- Update the gbl env
 194         updGblEnv ( \ gbl ->
 195                 gbl { tcg_rdr_env  = rdr_env,
 196                       tcg_inst_env = extendInstEnvList (tcg_inst_env gbl) home_insts,
 197                       tcg_imports  = tcg_imports gbl `plusImportAvails` imports,
 198                       tcg_rn_decls = if save_rn_decls then
 199                                         Just emptyGroup
 200                                      else
 201                                         Nothing })
 202                 $ do {
 203
 204         traceRn (text "rn1" <+> ppr (imp_dep_mods imports)) ;
 205                 -- Fail if there are any errors so far
 206                 -- The error printing (if needed) takes advantage
 207                 -- of the tcg_env we have now set
 208         failIfErrsM ;
 209
 210                 -- Load any orphan-module interfaces, so that
 211                 -- their rules and instance decls will be found
 212         loadOrphanModules (imp_orphs imports) ;
 213
 214         traceRn (text "rn1a") ;
 215                 -- Rename and type check the declarations
 216         tcg_env <- if isHsBoot hsc_src then
 217                         tcRnHsBootDecls local_decls
 218                    else
 219                         tcRnSrcDecls local_decls ;
 220         setGblEnv tcg_env               $ do {
 221
 222         traceRn (text "rn3") ;
 223
 224                 -- Report the use of any deprecated things
 225                 -- We do this before processsing the export list so
 226                 -- that we don't bleat about re-exporting a deprecated
 227                 -- thing (especially via 'module Foo' export item)
 228                 -- Only uses in the body of the module are complained about
 229         reportDeprecations tcg_env ;
 230
 231                 -- Process the export list
 232         exports <- exportsFromAvail (isJust maybe_mod) export_ies ;
 233
 234                 -- Check whether the entire module is deprecated
 235                 -- This happens only once per module
 236         let { mod_deprecs = checkModDeprec mod_deprec } ;
 237
 238                 -- Add exports and deprecations to envt
 239         let { final_env  = tcg_env { tcg_exports = exports,
 240                                      tcg_dus = tcg_dus tcg_env `plusDU` usesOnly exports,
 241                                      tcg_deprecs = tcg_deprecs tcg_env `plusDeprecs`
 242                                                    mod_deprecs }
 243                 -- A module deprecation over-rides the earlier ones
 244              } ;
 245
 246                 -- Report unused names
 247         reportUnusedNames export_ies final_env ;
 248
 249                 -- Dump output and return
 250         tcDump final_env ;
 251         return final_env
 252     }}}}
 253
 254 -- This is really a sanity check that the user has given -package-name
 255 -- if necessary.  -package-name is only necessary when the package database
 256 -- already contains the current package, because then we can't tell
 257 -- whether a given module is in the current package or not, without knowing
 258 -- the name of the current package.
 259 checkForPackageModule dflags this_mod
 260   | not (isHomeModule dflags this_mod),
 261     Just (pkg,_) <- moduleToPackageConfig dflags this_mod =
 262         let
 263                 ppr_pkg = ppr (mkPackageId (package pkg))
 264         in
 265         addErr (ptext SLIT("Module") <+> quotes (ppr this_mod) <+>
 266                 ptext SLIT("is a member of package") <+>  ppr_pkg <> char '.' $$
 267                 ptext SLIT("To compile this module, please use -ignore-package") <+> ppr_pkg <> char '.')
 268   | otherwise = return ()
 269 \end{code}
 270
 271
 272 %************************************************************************
 273 %*                                                                      *
 274         Type-checking external-core modules
 275 %*                                                                      *
 276 %************************************************************************
 277
 278 \begin{code}
 279 tcRnExtCore :: HscEnv
 280             -> HsExtCore RdrName
 281             -> IO (Messages, Maybe ModGuts)
 282         -- Nothing => some error occurred
 283
 284 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 285         -- The decls are IfaceDecls; all names are original names
 286  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 287
 288    initTc hsc_env ExtCoreFile this_mod $ do {
 289
 290    let { ldecls  = map noLoc decls } ;
 291
 292         -- Deal with the type declarations; first bring their stuff
 293         -- into scope, then rname them, then type check them
 294    tcg_env  <- importsFromLocalDecls (mkFakeGroup ldecls) ;
 295
 296    setGblEnv tcg_env $ do {
 297
 298    rn_decls <- rnTyClDecls ldecls ;
 299    failIfErrsM ;
 300
 301         -- Dump trace of renaming part
 302    rnDump (ppr rn_decls) ;
 303
 304         -- Typecheck them all together so that
 305         -- any mutually recursive types are done right
 306    tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails rn_decls) ;
 307         -- Make the new type env available to stuff slurped from interface files
 308
 309    setGblEnv tcg_env $ do {
 310
 311         -- Now the core bindings
 312    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 313
 314         -- Wrap up
 315    let {
 316         bndrs      = bindersOfBinds core_binds ;
 317         my_exports = mkNameSet (map idName bndrs) ;
 318                 -- ToDo: export the data types also?
 319
 320         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 321
 322         mod_guts = ModGuts {    mg_module   = this_mod,
 323                                 mg_boot     = False,
 324                                 mg_usages   = [],               -- ToDo: compute usage
 325                                 mg_dir_imps = [],               -- ??
 326                                 mg_deps     = noDependencies,   -- ??
 327                                 mg_exports  = my_exports,
 328                                 mg_types    = final_type_env,
 329                                 mg_insts    = tcg_insts tcg_env,
 330                                 mg_rules    = [],
 331                                 mg_binds    = core_binds,
 332
 333                                 -- Stubs
 334                                 mg_rdr_env  = emptyGlobalRdrEnv,
 335                                 mg_fix_env  = emptyFixityEnv,
 336                                 mg_deprecs  = NoDeprecs,
 337                                 mg_foreign  = NoStubs
 338                     } } ;
 339
 340    tcCoreDump mod_guts ;
 341
 342    return mod_guts
 343    }}}}
 344
 345 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 346   = HsGroup {   hs_tyclds = decls,      -- This is the one we want
 347                 hs_valds = [], hs_fords = [],
 348                 hs_instds = [], hs_fixds = [], hs_depds = [],
 349                 hs_ruleds = [], hs_defds = [] }
 350 \end{code}
 351
 352
 353 %************************************************************************
 354 %*                                                                      *
 355         Type-checking the top level of a module
 356 %*                                                                      *
 357 %************************************************************************
 358
 359 \begin{code}
 360 tcRnSrcDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 361         -- Returns the variables free in the decls
 362         -- Reason: solely to report unused imports and bindings
 363 tcRnSrcDecls decls
 364  = do {         -- Load the hi-boot interface for this module, if any
 365                 -- We do this now so that the boot_names can be passed
 366                 -- to tcTyAndClassDecls, because the boot_names are
 367                 -- automatically considered to be loop breakers
 368         mod <- getModule ;
 369         boot_iface <- tcHiBootIface mod ;
 370
 371                 -- Do all the declarations
 372         (tc_envs, lie) <- getLIE (tc_rn_src_decls boot_iface decls) ;
 373
 374              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 375              -- How could there be ambiguous ones?  They can only arise if a
 376              -- top-level decl falls under the monomorphism
 377              -- restriction, and no subsequent decl instantiates its
 378              -- type.  (Usually, ambiguous type variables are resolved
 379              -- during the generalisation step.)
 380         traceTc (text "Tc8") ;
 381         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 382                 -- Setting the global env exposes the instances to tcSimplifyTop
 383                 -- Setting the local env exposes the local Ids to tcSimplifyTop,
 384                 -- so that we get better error messages (monomorphism restriction)
 385
 386             -- Backsubstitution.  This must be done last.
 387             -- Even tcSimplifyTop may do some unification.
 388         traceTc (text "Tc9") ;
 389         let { (tcg_env, _) = tc_envs ;
 390               TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 391                          tcg_rules = rules, tcg_fords = fords } = tcg_env } ;
 392
 393         (bind_ids, binds', fords', rules') <- zonkTopDecls (binds `unionBags` inst_binds)
 394                                                            rules fords ;
 395
 396         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 397             ; tcg_env' = tcg_env { tcg_type_env = final_type_env,
 398                                    tcg_binds = binds',
 399                                    tcg_rules = rules',
 400                                    tcg_fords = fords' } } ;
 401
 402         -- Make the new type env available to stuff slurped from interface files
 403         writeMutVar (tcg_type_env_var tcg_env) final_type_env ;
 404
 405         -- Compare the hi-boot iface (if any) with the real thing
 406         dfun_binds <- checkHiBootIface tcg_env' boot_iface ;
 407
 408         return (tcg_env' { tcg_binds = tcg_binds tcg_env' `unionBags` dfun_binds })
 409    }
 410
 411 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 412 -- Loops around dealing with each top level inter-splice group
 413 -- in turn, until it's dealt with the entire module
 414 tc_rn_src_decls boot_details ds
 415  = do { let { (first_group, group_tail) = findSplice ds } ;
 416                 -- If ds is [] we get ([], Nothing)
 417
 418         -- Type check the decls up to, but not including, the first splice
 419         tc_envs@(tcg_env,tcl_env) <- tcRnGroup boot_details first_group ;
 420
 421         -- Bale out if errors; for example, error recovery when checking
 422         -- the RHS of 'main' can mean that 'main' is not in the envt for
 423         -- the subsequent checkMain test
 424         failIfErrsM ;
 425
 426         setEnvs tc_envs $
 427
 428         -- If there is no splice, we're nearly done
 429         case group_tail of {
 430            Nothing -> do {      -- Last thing: check for `main'
 431                            tcg_env <- checkMain ;
 432                            return (tcg_env, tcl_env)
 433                       } ;
 434
 435         -- If there's a splice, we must carry on
 436            Just (SpliceDecl splice_expr, rest_ds) -> do {
 437 #ifndef GHCI
 438         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 439 #else
 440
 441         -- Rename the splice expression, and get its supporting decls
 442         (rn_splice_expr, splice_fvs) <- rnLExpr splice_expr ;
 443         failIfErrsM ;   -- Don't typecheck if renaming failed
 444
 445         -- Execute the splice
 446         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 447
 448         -- Glue them on the front of the remaining decls and loop
 449         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 450         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 451 #endif /* GHCI */
 452     }}}
 453 \end{code}
 454
 455 %************************************************************************
 456 %*                                                                      *
 457         Compiling hs-boot source files, and
 458         comparing the hi-boot interface with the real thing
 459 %*                                                                      *
 460 %************************************************************************
 461
 462 \begin{code}
 463 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 464 tcRnHsBootDecls decls
 465    = do { let { (first_group, group_tail) = findSplice decls }
 466
 467         ; case group_tail of
 468              Just stuff -> spliceInHsBootErr stuff
 469              Nothing    -> return ()
 470
 471                 -- Rename the declarations
 472         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 473         ; setGblEnv tcg_env $ do {
 474
 475         -- Todo: check no foreign decls, no rules, no default decls
 476
 477                 -- Typecheck type/class decls
 478         ; traceTc (text "Tc2")
 479         ; let tycl_decls = hs_tyclds rn_group
 480         ; tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails tycl_decls)
 481         ; setGblEnv tcg_env     $ do {
 482
 483                 -- Typecheck instance decls
 484         ; traceTc (text "Tc3")
 485         ; (tcg_env, inst_infos, _binds) <- tcInstDecls1 tycl_decls (hs_instds rn_group)
 486         ; setGblEnv tcg_env     $ do {
 487
 488                 -- Typecheck value declarations
 489         ; traceTc (text "Tc5")
 490         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 491
 492                 -- Wrap up
 493                 -- No simplification or zonking to do
 494         ; traceTc (text "Tc7a")
 495         ; gbl_env <- getGblEnv
 496
 497                 -- Make the final type-env
 498                 -- Include the dfun_ids so that their type sigs get
 499                 -- are written into the interface file
 500         ; let { type_env0 = tcg_type_env gbl_env
 501               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 502               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 503               ; dfun_ids = map iDFunId inst_infos }
 504         ; return (gbl_env { tcg_type_env = type_env2 })
 505    }}}}
 506
 507 spliceInHsBootErr (SpliceDecl (L loc _), _)
 508   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 509 \end{code}
 510
 511 Once we've typechecked the body of the module, we want to compare what
 512 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 513
 514 \begin{code}
 515 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM (LHsBinds Id)
 516 -- Compare the hi-boot file for this module (if there is one)
 517 -- with the type environment we've just come up with
 518 -- In the common case where there is no hi-boot file, the list
 519 -- of boot_names is empty.
 520 --
 521 -- The bindings we return give bindings for the dfuns defined in the
 522 -- hs-boot file, such as        $fbEqT = $fEqT
 523
 524 checkHiBootIface
 525         (TcGblEnv { tcg_insts = local_insts, tcg_type_env = local_type_env })
 526         (ModDetails { md_insts = boot_insts, md_types = boot_type_env })
 527   = do  { mapM_ check_one (typeEnvElts boot_type_env)
 528         ; dfun_binds <- mapM check_inst boot_insts
 529         ; return (unionManyBags dfun_binds) }
 530   where
 531     check_one boot_thing
 532       | no_check name
 533       = return ()
 534       | otherwise
 535       = case lookupTypeEnv local_type_env name of
 536           Nothing         -> addErrTc (missingBootThing boot_thing)
 537           Just real_thing -> check_thing boot_thing real_thing
 538       where
 539         name = getName boot_thing
 540
 541     no_check name = isWiredInName name  -- No checking for wired-in names.  In particular,
 542                                         -- 'error' is handled by a rather gross hack
 543                                         -- (see comments in GHC.Err.hs-boot)
 544                   || name `elem` dfun_names
 545     dfun_names = map getName boot_insts
 546
 547     check_inst boot_inst
 548         = case [dfun | inst <- local_insts,
 549                        let dfun = instanceDFunId inst,
 550                        idType dfun `tcEqType` boot_inst_ty ] of
 551             [] -> do { addErrTc (instMisMatch boot_inst); return emptyBag }
 552             (dfun:_) -> return (unitBag $ noLoc $ VarBind local_boot_dfun (nlHsVar dfun))
 553         where
 554           boot_dfun = instanceDFunId boot_inst
 555           boot_inst_ty = idType boot_dfun
 556           local_boot_dfun = mkExportedLocalId (idName boot_dfun) boot_inst_ty
 557
 558 ----------------
 559 check_thing (ATyCon boot_tc) (ATyCon real_tc)
 560   | isSynTyCon boot_tc && isSynTyCon real_tc,
 561     defn1 `tcEqType` substTyWith tvs2 (mkTyVarTys tvs1) defn2
 562   = return ()
 563
 564   | tyConKind boot_tc == tyConKind real_tc
 565   = return ()
 566   where
 567     (tvs1, defn1) = getSynTyConDefn boot_tc
 568     (tvs2, defn2) = getSynTyConDefn boot_tc
 569
 570 check_thing (AnId boot_id) (AnId real_id)
 571   | idType boot_id `tcEqType` idType real_id
 572   = return ()
 573
 574 check_thing (ADataCon dc1) (ADataCon dc2)
 575   | idType (dataConWrapId dc1) `tcEqType` idType (dataConWrapId dc2)
 576   = return ()
 577
 578         -- Can't declare a class in a hi-boot file
 579
 580 check_thing boot_thing real_thing       -- Default case; failure
 581   = addErrAt (srcLocSpan (getSrcLoc real_thing))
 582              (bootMisMatch real_thing)
 583
 584 ----------------
 585 missingBootThing thing
 586   = ppr thing <+> ptext SLIT("is defined in the hs-boot file, but not in the module")
 587 bootMisMatch thing
 588   = ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file")
 589 instMisMatch inst
 590   = hang (ppr inst)
 591        2 (ptext SLIT("is defined in the hs-boot file, but not in the module"))
 592 \end{code}
 593
 594
 595 %************************************************************************
 596 %*                                                                      *
 597         Type-checking the top level of a module
 598 %*                                                                      *
 599 %************************************************************************
 600
 601 tcRnGroup takes a bunch of top-level source-code declarations, and
 602  * renames them
 603  * gets supporting declarations from interface files
 604  * typechecks them
 605  * zonks them
 606  * and augments the TcGblEnv with the results
 607
 608 In Template Haskell it may be called repeatedly for each group of
 609 declarations.  It expects there to be an incoming TcGblEnv in the
 610 monad; it augments it and returns the new TcGblEnv.
 611
 612 \begin{code}
 613 tcRnGroup :: ModDetails -> HsGroup RdrName -> TcM (TcGblEnv, TcLclEnv)
 614         -- Returns the variables free in the decls, for unused-binding reporting
 615 tcRnGroup boot_details decls
 616  = do {         -- Rename the declarations
 617         (tcg_env, rn_decls) <- rnTopSrcDecls decls ;
 618         setGblEnv tcg_env $ do {
 619
 620                 -- Typecheck the declarations
 621         tcTopSrcDecls boot_details rn_decls
 622   }}
 623
 624 ------------------------------------------------
 625 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 626 rnTopSrcDecls group
 627  = do {         -- Bring top level binders into scope
 628         tcg_env <- importsFromLocalDecls group ;
 629         setGblEnv tcg_env $ do {
 630
 631         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 632
 633                 -- Rename the source decls
 634         (tcg_env, rn_decls) <- rnSrcDecls group ;
 635         failIfErrsM ;
 636
 637                 -- save the renamed syntax, if we want it
 638         let { tcg_env'
 639                 | Just grp <- tcg_rn_decls tcg_env
 640                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 641                 | otherwise
 642                    = tcg_env };
 643
 644                 -- Dump trace of renaming part
 645         rnDump (ppr rn_decls) ;
 646
 647         return (tcg_env', rn_decls)
 648    }}
 649
 650 ------------------------------------------------
 651 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 652 tcTopSrcDecls boot_details
 653         (HsGroup { hs_tyclds = tycl_decls,
 654                    hs_instds = inst_decls,
 655                    hs_fords  = foreign_decls,
 656                    hs_defds  = default_decls,
 657                    hs_ruleds = rule_decls,
 658                    hs_valds  = val_binds })
 659  = do {         -- Type-check the type and class decls, and all imported decls
 660                 -- The latter come in via tycl_decls
 661         traceTc (text "Tc2") ;
 662
 663         tcg_env <- checkNoErrs (tcTyAndClassDecls boot_details tycl_decls) ;
 664         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 665         -- an error we'd better stop now, to avoid a cascade
 666
 667         -- Make these type and class decls available to stuff slurped from interface files
 668         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 669
 670
 671         setGblEnv tcg_env       $ do {
 672                 -- Source-language instances, including derivings,
 673                 -- and import the supporting declarations
 674         traceTc (text "Tc3") ;
 675         (tcg_env, inst_infos, deriv_binds) <- tcInstDecls1 tycl_decls inst_decls ;
 676         setGblEnv tcg_env       $ do {
 677
 678                 -- Foreign import declarations next.  No zonking necessary
 679                 -- here; we can tuck them straight into the global environment.
 680         traceTc (text "Tc4") ;
 681         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 682         tcExtendGlobalValEnv fi_ids     $ do {
 683
 684                 -- Default declarations
 685         traceTc (text "Tc4a") ;
 686         default_tys <- tcDefaults default_decls ;
 687         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 688
 689                 -- Value declarations next
 690                 -- We also typecheck any extra binds that came out
 691                 -- of the "deriving" process (deriv_binds)
 692         traceTc (text "Tc5") ;
 693         (tc_val_binds, tcl_env) <- tcTopBinds (val_binds ++ deriv_binds) ;
 694         setLclTypeEnv tcl_env   $ do {
 695
 696                 -- Second pass over class and instance declarations,
 697         traceTc (text "Tc6") ;
 698         (inst_binds, tcl_env) <- tcInstDecls2 tycl_decls inst_infos ;
 699         showLIE (text "after instDecls2") ;
 700
 701                 -- Foreign exports
 702                 -- They need to be zonked, so we return them
 703         traceTc (text "Tc7") ;
 704         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 705
 706                 -- Rules
 707         rules <- tcRules rule_decls ;
 708
 709                 -- Wrap up
 710         traceTc (text "Tc7a") ;
 711         tcg_env <- getGblEnv ;
 712         let { all_binds = tc_val_binds   `unionBags`
 713                           inst_binds     `unionBags`
 714                           foe_binds  ;
 715
 716                 -- Extend the GblEnv with the (as yet un-zonked)
 717                 -- bindings, rules, foreign decls
 718               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 719                                     tcg_rules = tcg_rules tcg_env ++ rules,
 720                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 721         return (tcg_env', tcl_env)
 722     }}}}}}
 723 \end{code}
 724
 725
 726 %************************************************************************
 727 %*                                                                      *
 728         Checking for 'main'
 729 %*                                                                      *
 730 %************************************************************************
 731
 732 \begin{code}
 733 checkMain
 734   = do { ghci_mode <- getGhciMode ;
 735          tcg_env   <- getGblEnv ;
 736          dflags    <- getDOpts ;
 737          let { main_mod = case mainModIs dflags of {
 738                                 Just mod -> mkModule mod ;
 739                                 Nothing  -> mAIN } ;
 740                main_fn  = case mainFunIs dflags of {
 741                                 Just fn -> mkRdrUnqual (mkVarOcc (mkFastString fn)) ;
 742                                 Nothing -> main_RDR_Unqual } } ;
 743
 744          check_main ghci_mode tcg_env main_mod main_fn
 745     }
 746
 747
 748 check_main ghci_mode tcg_env main_mod main_fn
 749      -- If we are in module Main, check that 'main' is defined.
 750      -- It may be imported from another module!
 751      --
 752      --
 753      -- Blimey: a whole page of code to do this...
 754  | mod /= main_mod
 755  = return tcg_env
 756
 757  | otherwise
 758  = addErrCtxt mainCtxt                  $
 759    do   { mb_main <- lookupSrcOcc_maybe main_fn
 760                 -- Check that 'main' is in scope
 761                 -- It might be imported from another module!
 762         ; case mb_main of {
 763              Nothing -> do { complain_no_main
 764                            ; return tcg_env } ;
 765              Just main_name -> do
 766         { let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 767                         -- :Main.main :: IO () = runMainIO main
 768
 769         ; (main_expr, ty) <- setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 770                              tcInferRho rhs
 771
 772         ; let { root_main_id = mkExportedLocalId rootMainName ty ;
 773                 main_bind    = noLoc (VarBind root_main_id main_expr) }
 774
 775         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 776                                         `snocBag` main_bind,
 777                             tcg_dus   = tcg_dus tcg_env
 778                                         `plusDU` usesOnly (unitFV main_name)
 779                         -- Record the use of 'main', so that we don't
 780                         -- complain about it being defined but not used
 781                  })
 782     }}}
 783   where
 784     mod = tcg_mod tcg_env
 785
 786     complain_no_main | ghci_mode == Interactive = return ()
 787                      | otherwise                = failWithTc noMainMsg
 788         -- In interactive mode, don't worry about the absence of 'main'
 789         -- In other modes, fail altogether, so that we don't go on
 790         -- and complain a second time when processing the export list.
 791
 792     mainCtxt  = ptext SLIT("When checking the type of the main function") <+> quotes (ppr main_fn)
 793     noMainMsg = ptext SLIT("The main function") <+> quotes (ppr main_fn)
 794                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 795 \end{code}
 796
 797 %*********************************************************
 798 %*                                                       *
 799                 GHCi stuff
 800 %*                                                       *
 801 %*********************************************************
 802
 803 \begin{code}
 804 #ifdef GHCI
 805 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 806 setInteractiveContext hsc_env icxt thing_inside
 807   = let
 808         -- Initialise the tcg_inst_env with instances
 809         -- from all home modules.  This mimics the more selective
 810         -- call to hptInstances in tcRnModule
 811         dfuns = hptInstances hsc_env (\mod -> True)
 812     in
 813     updGblEnv (\env -> env {
 814         tcg_rdr_env  = ic_rn_gbl_env icxt,
 815         tcg_type_env = ic_type_env   icxt,
 816         tcg_inst_env = extendInstEnvList (tcg_inst_env env) dfuns }) $
 817
 818     updLclEnv (\env -> env { tcl_rdr = ic_rn_local_env icxt })  $
 819
 820     do  { traceTc (text "setIC" <+> ppr (ic_type_env icxt))
 821         ; thing_inside }
 822 \end{code}
 823
 824
 825 \begin{code}
 826 tcRnStmt :: HscEnv
 827          -> InteractiveContext
 828          -> LStmt RdrName
 829          -> IO (Maybe (InteractiveContext, [Name], LHsExpr Id))
 830                 -- The returned [Name] is the same as the input except for
 831                 -- ExprStmt, in which case the returned [Name] is [itName]
 832                 --
 833                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 834                 -- a list of the bound values, coerced to ().
 835
 836 tcRnStmt hsc_env ictxt rdr_stmt
 837   = initTcPrintErrors hsc_env iNTERACTIVE $
 838     setInteractiveContext hsc_env ictxt $ do {
 839
 840     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 841     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 842     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 843     failIfErrsM ;
 844
 845     -- The real work is done here
 846     (bound_ids, tc_expr) <- tcUserStmt rn_stmt ;
 847
 848     traceTc (text "tcs 1") ;
 849     let {       -- (a) Make all the bound ids "global" ids, now that
 850                 --     they're notionally top-level bindings.  This is
 851                 --     important: otherwise when we come to compile an expression
 852                 --     using these ids later, the byte code generator will consider
 853                 --     the occurrences to be free rather than global.
 854                 --
 855                 -- (b) Tidy their types; this is important, because :info may
 856                 --     ask to look at them, and :info expects the things it looks
 857                 --     up to have tidy types
 858         global_ids = map globaliseAndTidy bound_ids ;
 859
 860                 -- Update the interactive context
 861         rn_env   = ic_rn_local_env ictxt ;
 862         type_env = ic_type_env ictxt ;
 863
 864         bound_names = map idName global_ids ;
 865         new_rn_env  = extendLocalRdrEnv rn_env bound_names ;
 866
 867                 -- Remove any shadowed bindings from the type_env;
 868                 -- they are inaccessible but might, I suppose, cause
 869                 -- a space leak if we leave them there
 870         shadowed = [ n | name <- bound_names,
 871                          let rdr_name = mkRdrUnqual (nameOccName name),
 872                          Just n <- [lookupLocalRdrEnv rn_env rdr_name] ] ;
 873
 874         filtered_type_env = delListFromNameEnv type_env shadowed ;
 875         new_type_env = extendTypeEnvWithIds filtered_type_env global_ids ;
 876
 877         new_ic = ictxt { ic_rn_local_env = new_rn_env,
 878                          ic_type_env     = new_type_env }
 879     } ;
 880
 881     dumpOptTcRn Opt_D_dump_tc
 882         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 883                text "Typechecked expr" <+> ppr tc_expr]) ;
 884
 885     returnM (new_ic, bound_names, tc_expr)
 886     }
 887
 888 globaliseAndTidy :: Id -> Id
 889 globaliseAndTidy id
 890 -- Give the Id a Global Name, and tidy its type
 891   = setIdType (globaliseId VanillaGlobal id) tidy_type
 892   where
 893     tidy_type = tidyTopType (idType id)
 894 \end{code}
 895
 896 Here is the grand plan, implemented in tcUserStmt
 897
 898         What you type                   The IO [HValue] that hscStmt returns
 899         -------------                   ------------------------------------
 900         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 901                                         bindings: [x,y,...]
 902
 903         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 904                                         bindings: [x,y,...]
 905
 906         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 907           [NB: result not printed]      bindings: [it]
 908
 909         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 910           result showable)              bindings: [it]
 911
 912         expr (of non-IO type,
 913           result not showable)  ==>     error
 914
 915
 916 \begin{code}
 917 ---------------------------
 918 tcUserStmt :: LStmt Name -> TcM ([Id], LHsExpr Id)
 919 tcUserStmt (L loc (ExprStmt expr _ _))
 920   = newUnique           `thenM` \ uniq ->
 921     let
 922         fresh_it = itName uniq
 923         the_bind = noLoc $ FunBind (noLoc fresh_it) False
 924                              (mkMatchGroup [mkSimpleMatch [] expr])
 925     in
 926     tryTcLIE_ (do {     -- Try this if the other fails
 927                 traceTc (text "tcs 1b") ;
 928                 tc_stmts (map (L loc) [
 929                     LetStmt [HsBindGroup (unitBag the_bind) [] NonRecursive],
 930                     ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
 931                              (HsVar thenIOName) placeHolderType
 932         ]) })
 933           (do {         -- Try this first
 934                 traceTc (text "tcs 1a") ;
 935                 tc_stmts [L loc (BindStmt (nlVarPat fresh_it) expr
 936                                           (HsVar bindIOName) noSyntaxExpr) ] })
 937
 938 tcUserStmt stmt = tc_stmts [stmt]
 939
 940 ---------------------------
 941 tc_stmts :: [LStmt Name] -> TcM ([Id], LHsExpr Id)
 942 tc_stmts stmts
 943  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
 944         let {
 945             ret_ty    = mkListTy unitTy ;
 946             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
 947
 948             names = map unLoc (collectLStmtsBinders stmts) ;
 949
 950                 -- mk_return builds the expression
 951                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
 952                 --
 953                 -- Despite the inconvenience of building the type applications etc,
 954                 -- this *has* to be done in type-annotated post-typecheck form
 955                 -- because we are going to return a list of *polymorphic* values
 956                 -- coerced to type (). If we built a *source* stmt
 957                 --      return [coerce x, ..., coerce z]
 958                 -- then the type checker would instantiate x..z, and we wouldn't
 959                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
 960                 -- if they were overloaded, since they aren't applied to anything.)
 961             mk_return ret_id ids = nlHsApp (noLoc $ TyApp (nlHsVar ret_id) [ret_ty])
 962                                            (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
 963             mk_item id = nlHsApp (noLoc $ TyApp (nlHsVar unsafeCoerceId) [idType id, unitTy])
 964                                (nlHsVar id) ;
 965
 966             io_ty = mkTyConApp ioTyCon []
 967          } ;
 968
 969         -- OK, we're ready to typecheck the stmts
 970         traceTc (text "tcs 2") ;
 971         ((ids, tc_expr), lie) <- getLIE $ do {
 972                 (tc_stmts, ids) <- tcStmts DoExpr (tcDoStmt io_ty io_ret_ty) stmts $
 973                                 do {
 974                                     -- Look up the names right in the middle,
 975                                     -- where they will all be in scope
 976                                     ids <- mappM tcLookupId names ;
 977                                     return ids } ;
 978
 979             ret_id <- tcLookupId returnIOName ;         -- return @ IO
 980             return (ids, noLoc (HsDo DoExpr tc_stmts (mk_return ret_id ids) io_ret_ty))
 981         } ;
 982
 983         -- Simplify the context right here, so that we fail
 984         -- if there aren't enough instances.  Notably, when we see
 985         --              e
 986         -- we use recoverTc_ to try     it <- e
 987         -- and then                     let it = e
 988         -- It's the simplify step that rejects the first.
 989         traceTc (text "tcs 3") ;
 990         const_binds <- tcSimplifyInteractive lie ;
 991
 992         -- Build result expression and zonk it
 993         let { expr = mkHsLet const_binds tc_expr } ;
 994         zonked_expr <- zonkTopLExpr expr ;
 995         zonked_ids  <- zonkTopBndrs ids ;
 996
 997         -- None of the Ids should be of unboxed type, because we
 998         -- cast them all to HValues in the end!
 999         mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
1000
1001         return (zonked_ids, zonked_expr)
1002         }
1003   where
1004     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
1005                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
1006 \end{code}
1007
1008
1009 tcRnExpr just finds the type of an expression
1010
1011 \begin{code}
1012 tcRnExpr :: HscEnv
1013          -> InteractiveContext
1014          -> LHsExpr RdrName
1015          -> IO (Maybe Type)
1016 tcRnExpr hsc_env ictxt rdr_expr
1017   = initTcPrintErrors hsc_env iNTERACTIVE $
1018     setInteractiveContext hsc_env ictxt $ do {
1019
1020     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1021     failIfErrsM ;
1022
1023         -- Now typecheck the expression;
1024         -- it might have a rank-2 type (e.g. :t runST)
1025     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1026     ((qtvs, _, dict_ids), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1027     tcSimplifyInteractive lie_top ;
1028     qtvs' <- mappM zonkQuantifiedTyVar qtvs ;
1029
1030     let { all_expr_ty = mkForAllTys qtvs' $
1031                         mkFunTys (map idType dict_ids)  $
1032                         res_ty } ;
1033     zonkTcType all_expr_ty
1034     }
1035   where
1036     smpl_doc = ptext SLIT("main expression")
1037 \end{code}
1038
1039 tcRnType just finds the kind of a type
1040
1041 \begin{code}
1042 tcRnType :: HscEnv
1043          -> InteractiveContext
1044          -> LHsType RdrName
1045          -> IO (Maybe Kind)
1046 tcRnType hsc_env ictxt rdr_type
1047   = initTcPrintErrors hsc_env iNTERACTIVE $
1048     setInteractiveContext hsc_env ictxt $ do {
1049
1050     rn_type <- rnLHsType doc rdr_type ;
1051     failIfErrsM ;
1052
1053         -- Now kind-check the type
1054     (ty', kind) <- kcHsType rn_type ;
1055     return kind
1056     }
1057   where
1058     doc = ptext SLIT("In GHCi input")
1059
1060 #endif /* GHCi */
1061 \end{code}
1062
1063
1064 %************************************************************************
1065 %*                                                                      *
1066         More GHCi stuff, to do with browsing and getting info
1067 %*                                                                      *
1068 %************************************************************************
1069
1070 \begin{code}
1071 #ifdef GHCI
1072 getModuleExports :: HscEnv -> Module -> IO (Maybe NameSet)
1073 getModuleExports hsc_env mod
1074   = initTcPrintErrors hsc_env iNTERACTIVE (tcGetModuleExports mod)
1075
1076 tcGetModuleExports :: Module -> TcM NameSet
1077 tcGetModuleExports mod = do
1078   iface <- load_iface mod
1079   loadOrphanModules (dep_orphs (mi_deps iface))
1080                 -- Load any orphan-module interfaces,
1081                 -- so their instances are visible
1082   ifaceExportNames (mi_exports iface)
1083 \end{code}
1084
1085 \begin{code}
1086 getModuleContents
1087   :: HscEnv
1088   -> Module                     -- Module to inspect
1089   -> Bool                       -- Grab just the exports, or the whole toplev
1090   -> IO (Maybe [IfaceDecl])
1091
1092 getModuleContents hsc_env mod exports_only
1093  = initTcPrintErrors hsc_env iNTERACTIVE (get_mod_contents exports_only)
1094  where
1095    get_mod_contents exports_only
1096       | not exports_only  -- We want the whole top-level type env
1097                           -- so it had better be a home module
1098       = do { hpt <- getHpt
1099            ; case lookupModuleEnv hpt mod of
1100                Just mod_info -> return (map (toIfaceDecl ext_nm) $
1101                                         filter wantToSee $
1102                                         typeEnvElts $
1103                                         md_types (hm_details mod_info))
1104                Nothing -> ghcError (ProgramError (showSDoc (noRdrEnvErr mod)))
1105                           -- This is a system error; the module should be in the HPT
1106            }
1107
1108       | otherwise               -- Want the exports only
1109       = do { iface <- load_iface mod
1110            ; mappM get_decl [ (mod,avail) | (mod, avails) <- mi_exports iface
1111                                           , avail <- avails ]
1112         }
1113
1114    get_decl (mod, avail)
1115         = do { main_name <- lookupOrig mod (availName avail)
1116              ; thing     <- tcLookupGlobal main_name
1117              ; return (filter_decl (availNames avail) (toIfaceDecl ext_nm thing)) }
1118
1119    ext_nm = interactiveExtNameFun (icPrintUnqual (hsc_IC hsc_env))
1120
1121 ---------------------
1122 filter_decl occs decl@(IfaceClass {ifSigs = sigs})
1123   = decl { ifSigs = filter (keep_sig occs) sigs }
1124 filter_decl occs decl@(IfaceData {ifCons = IfDataTyCon cons})
1125   = decl { ifCons = IfDataTyCon (filter (keep_con occs) cons) }
1126 filter_decl occs decl@(IfaceData {ifCons = IfNewTyCon con})
1127   | keep_con occs con = decl
1128   | otherwise         = decl {ifCons = IfAbstractTyCon} -- Hmm?
1129 filter_decl occs decl
1130   = decl
1131
1132 keep_sig occs (IfaceClassOp occ _ _) = occ `elem` occs
1133 keep_con occs con                    = ifConOcc con `elem` occs
1134
1135 wantToSee (AnId id)    = not (isImplicitId id)
1136 wantToSee (ADataCon _) = False  -- They'll come via their TyCon
1137 wantToSee _            = True
1138
1139 ---------------------
1140 load_iface mod = loadSrcInterface doc mod False {- Not boot iface -}
1141                where
1142                  doc = ptext SLIT("context for compiling statements")
1143
1144 ---------------------
1145 noRdrEnvErr mod = ptext SLIT("No top-level environment available for module")
1146                   <+> quotes (ppr mod)
1147 \end{code}
1148
1149 \begin{code}
1150 type GetInfoResult = (String, IfaceDecl, Fixity, SrcLoc,
1151                               [(IfaceType,SrcLoc)]      -- Instances
1152                      )
1153
1154 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Maybe [Name])
1155
1156 tcRnLookupRdrName hsc_env rdr_name
1157   = initTcPrintErrors hsc_env iNTERACTIVE $
1158     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1159     lookup_rdr_name rdr_name
1160
1161
1162 lookup_rdr_name rdr_name = do {
1163         -- If the identifier is a constructor (begins with an
1164         -- upper-case letter), then we need to consider both
1165         -- constructor and type class identifiers.
1166     let { rdr_names = dataTcOccs rdr_name } ;
1167
1168         -- results :: [(Messages, Maybe Name)]
1169     results <- mapM (tryTc . lookupOccRn) rdr_names ;
1170
1171     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1172         -- The successful lookups will be (Just name)
1173     let { (warns_s, good_names) = unzip [ (msgs, name)
1174                                         | (msgs, Just name) <- results] ;
1175           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1176
1177         -- Fail if nothing good happened, else add warnings
1178     if null good_names then
1179                 -- No lookup succeeded, so
1180                 -- pick the first error message and report it
1181                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1182                 --       while the other is "X is not in scope",
1183                 --       we definitely want the former; but we might pick the latter
1184         do { addMessages (head errs_s) ; failM }
1185       else                      -- Add deprecation warnings
1186         mapM_ addMessages warns_s ;
1187
1188     return good_names
1189  }
1190
1191
1192 tcRnGetInfo :: HscEnv
1193             -> InteractiveContext
1194             -> RdrName
1195             -> IO (Maybe [GetInfoResult])
1196
1197 -- Used to implemnent :info in GHCi
1198 --
1199 -- Look up a RdrName and return all the TyThings it might be
1200 -- A capitalised RdrName is given to us in the DataName namespace,
1201 -- but we want to treat it as *both* a data constructor
1202 --  *and* as a type or class constructor;
1203 -- hence the call to dataTcOccs, and we return up to two results
1204 tcRnGetInfo hsc_env ictxt rdr_name
1205   = initTcPrintErrors hsc_env iNTERACTIVE $
1206     setInteractiveContext hsc_env ictxt $ do {
1207
1208         -- Load the interface for all unqualified types and classes
1209         -- That way we will find all the instance declarations
1210         -- (Packages have not orphan modules, and we assume that
1211         --  in the home package all relevant modules are loaded.)
1212     loadUnqualIfaces ictxt ;
1213
1214     good_names <- lookup_rdr_name rdr_name ;
1215
1216         -- And lookup up the entities, avoiding duplicates, which arise
1217         -- because constructors and record selectors are represented by
1218         -- their parent declaration
1219     let { do_one name = do { thing  <- tcLookupGlobal name
1220                            ; fixity <- lookupFixityRn name
1221                            ; ispecs <- lookupInsts print_unqual thing
1222                            ; return (str, toIfaceDecl ext_nm thing, fixity,
1223                                      getSrcLoc thing,
1224                                      [(toIfaceType ext_nm (idType dfun), getSrcLoc dfun)
1225                                      | dfun <- map instanceDFunId ispecs ]
1226                              ) }
1227                 where
1228                         -- str is the the naked occurrence name
1229                         -- after stripping off qualification and parens (+)
1230                   str = occNameUserString (nameOccName name)
1231
1232         ; parent_is_there n
1233                 | Just p <- nameParent_maybe n = p `elem` good_names
1234                 | otherwise                    = False
1235         } ;
1236
1237         -- For the SrcLoc, the 'thing' has better info than
1238         -- the 'name' because getting the former forced the
1239         -- declaration to be loaded into the cache
1240
1241     mapM do_one (filter (not . parent_is_there) good_names)
1242         -- Filter out names whose parent is also there
1243         -- Good example is '[]', which is both a type and data constructor
1244         -- in the same type
1245     }
1246   where
1247     ext_nm = interactiveExtNameFun print_unqual
1248     print_unqual = icPrintUnqual ictxt
1249
1250 lookupInsts :: PrintUnqualified -> TyThing -> TcM [Instance]
1251 -- Filter the instances by the ones whose tycons (or clases resp)
1252 -- are in scope unqualified.  Otherwise we list a whole lot too many!
1253 lookupInsts print_unqual (AClass cls)
1254   = do  { inst_envs <- tcGetInstEnvs
1255         ; return [ ispec
1256                  | ispec <- classInstances inst_envs cls
1257                  , plausibleDFun print_unqual (instanceDFunId ispec) ] }
1258
1259 lookupInsts print_unqual (ATyCon tc)
1260   = do  { eps <- getEps -- Load all instances for all classes that are
1261                         -- in the type environment (which are all the ones
1262                         -- we've seen in any interface file so far)
1263         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1264         ; return [ ispec
1265                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1266                  , let dfun = instanceDFunId ispec
1267                  , relevant dfun
1268                  , plausibleDFun print_unqual dfun ] }
1269   where
1270     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1271     tc_name     = tyConName tc
1272
1273 lookupInsts print_unqual other = return []
1274
1275 plausibleDFun print_unqual dfun -- Dfun involving only names that print unqualified
1276   = all ok (nameSetToList (tyClsNamesOfType (idType dfun)))
1277   where
1278     ok name | isBuiltInSyntax name = True
1279             | isExternalName name  = print_unqual (nameModule name) (nameOccName name)
1280             | otherwise            = True
1281
1282 toIfaceDecl :: (Name -> IfaceExtName) -> TyThing -> IfaceDecl
1283 toIfaceDecl ext_nm thing
1284   = tyThingToIfaceDecl ext_nm (munge thing)
1285   where
1286         -- munge transforms a thing to its "parent" thing
1287     munge (ADataCon dc) = ATyCon (dataConTyCon dc)
1288     munge (AnId id) = case globalIdDetails id of
1289                         RecordSelId tc lbl -> ATyCon tc
1290                         ClassOpId cls      -> AClass cls
1291                         other              -> AnId id
1292     munge other_thing = other_thing
1293
1294 loadUnqualIfaces :: InteractiveContext -> TcM ()
1295 -- Load the home module for everything that is in scope unqualified
1296 -- This is so that we can accurately report the instances for
1297 -- something
1298 loadUnqualIfaces ictxt
1299   = initIfaceTcRn $
1300     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1301   where
1302     unqual_mods = [ nameModule name
1303                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1304                     let name = gre_name gre,
1305                     isTcOcc (nameOccName name),  -- Types and classes only
1306                     unQualOK gre ]               -- In scope unqualified
1307     doc = ptext SLIT("Need interface for module whose export(s) are in scope unqualified")
1308 #endif /* GHCI */
1309 \end{code}
1310
1311 %************************************************************************
1312 %*                                                                      *
1313                 Degugging output
1314 %*                                                                      *
1315 %************************************************************************
1316
1317 \begin{code}
1318 rnDump :: SDoc -> TcRn ()
1319 -- Dump, with a banner, if -ddump-rn
1320 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1321
1322 tcDump :: TcGblEnv -> TcRn ()
1323 tcDump env
1324  = do { dflags <- getDOpts ;
1325
1326         -- Dump short output if -ddump-types or -ddump-tc
1327         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1328             (dumpTcRn short_dump) ;
1329
1330         -- Dump bindings if -ddump-tc
1331         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1332    }
1333   where
1334     short_dump = pprTcGblEnv env
1335     full_dump  = pprLHsBinds (tcg_binds env)
1336         -- NB: foreign x-d's have undefined's in their types;
1337         --     hence can't show the tc_fords
1338
1339 tcCoreDump mod_guts
1340  = do { dflags <- getDOpts ;
1341         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1342             (dumpTcRn (pprModGuts mod_guts)) ;
1343
1344         -- Dump bindings if -ddump-tc
1345         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1346   where
1347     full_dump = pprCoreBindings (mg_binds mod_guts)
1348
1349 -- It's unpleasant having both pprModGuts and pprModDetails here
1350 pprTcGblEnv :: TcGblEnv -> SDoc
1351 pprTcGblEnv (TcGblEnv { tcg_type_env = type_env,
1352                         tcg_insts    = dfun_ids,
1353                         tcg_rules    = rules,
1354                         tcg_imports  = imports })
1355   = vcat [ ppr_types dfun_ids type_env
1356          , ppr_insts dfun_ids
1357          , vcat (map ppr rules)
1358          , ppr_gen_tycons (typeEnvTyCons type_env)
1359          , ptext SLIT("Dependent modules:") <+> ppr (moduleEnvElts (imp_dep_mods imports))
1360          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1361
1362 pprModGuts :: ModGuts -> SDoc
1363 pprModGuts (ModGuts { mg_types = type_env,
1364                       mg_rules = rules })
1365   = vcat [ ppr_types [] type_env,
1366            ppr_rules rules ]
1367
1368
1369 ppr_types :: [Instance] -> TypeEnv -> SDoc
1370 ppr_types ispecs type_env
1371   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1372   where
1373     dfun_ids = map instanceDFunId ispecs
1374     ids = [id | id <- typeEnvIds type_env, want_sig id]
1375     want_sig id | opt_PprStyle_Debug = True
1376                 | otherwise          = isLocalId id &&
1377                                        isExternalName (idName id) &&
1378                                        not (id `elem` dfun_ids)
1379         -- isLocalId ignores data constructors, records selectors etc.
1380         -- The isExternalName ignores local dictionary and method bindings
1381         -- that the type checker has invented.  Top-level user-defined things
1382         -- have External names.
1383
1384 ppr_insts :: [Instance] -> SDoc
1385 ppr_insts []     = empty
1386 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1387
1388 ppr_sigs :: [Var] -> SDoc
1389 ppr_sigs ids
1390         -- Print type signatures; sort by OccName
1391   = vcat (map ppr_sig (sortLe le_sig ids))
1392   where
1393     le_sig id1 id2 = getOccName id1 <= getOccName id2
1394     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1395
1396 ppr_rules :: [CoreRule] -> SDoc
1397 ppr_rules [] = empty
1398 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1399                       nest 4 (pprRules rs),
1400                       ptext SLIT("#-}")]
1401
1402 ppr_gen_tycons []  = empty
1403 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1404                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1405 \end{code}