ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes,
   5         module IOEnv
   6   ) where
   7
   8 #include "HsVersions.h"
   9
  10 import TcRnTypes        -- Re-export all
  11 import IOEnv            -- Re-export all
  12
  13 import HsSyn            ( emptyLHsBinds )
  14 import HscTypes         ( HscEnv(..), ModGuts(..), ModIface(..),
  15                           TyThing, TypeEnv, emptyTypeEnv, HscSource(..), isHsBoot,
  16                           ExternalPackageState(..), HomePackageTable,
  17                           Deprecs(..), FixityEnv, FixItem,
  18                           lookupType, unQualInScope )
  19 import Module           ( Module, unitModuleEnv )
  20 import RdrName          ( GlobalRdrEnv, emptyGlobalRdrEnv,
  21                           LocalRdrEnv, emptyLocalRdrEnv )
  22 import Name             ( Name, isInternalName )
  23 import Type             ( Type )
  24 import NameEnv          ( extendNameEnvList )
  25 import InstEnv          ( emptyInstEnv )
  26
  27 import VarSet           ( emptyVarSet )
  28 import VarEnv           ( TidyEnv, emptyTidyEnv, emptyVarEnv )
  29 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  30                           mkWarnMsg, printErrorsAndWarnings,
  31                           mkLocMessage, mkLongErrMsg )
  32 import SrcLoc           ( mkGeneralSrcSpan, isGoodSrcSpan, SrcSpan, Located(..) )
  33 import NameEnv          ( emptyNameEnv )
  34 import NameSet          ( NameSet, emptyDUs, emptyNameSet, unionNameSets, addOneToNameSet )
  35 import OccName          ( emptyOccEnv )
  36 import Bag              ( emptyBag )
  37 import Outputable
  38 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  39 import Unique           ( Unique )
  40 import DynFlags         ( DynFlags(..), DynFlag(..), dopt, dopt_set, GhcMode )
  41 import StaticFlags      ( opt_PprStyle_Debug )
  42 import Bag              ( snocBag, unionBags )
  43 import Panic            ( showException )
  44
  45 import Maybe            ( isJust )
  46 import IO               ( stderr )
  47 import DATA_IOREF       ( newIORef, readIORef )
  48 import EXCEPTION        ( Exception )
  49 \end{code}
  50
  51
  52
  53 %************************************************************************
  54 %*                                                                      *
  55                         initTc
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 \begin{code}
  60 ioToTcRn :: IO r -> TcRn r
  61 ioToTcRn = ioToIOEnv
  62 \end{code}
  63
  64 \begin{code}
  65 initTc :: HscEnv
  66        -> HscSource
  67        -> Module
  68        -> TcM r
  69        -> IO (Messages, Maybe r)
  70                 -- Nothing => error thrown by the thing inside
  71                 -- (error messages should have been printed already)
  72
  73 initTc hsc_env hsc_src mod do_this
  74  = do { errs_var     <- newIORef (emptyBag, emptyBag) ;
  75         tvs_var      <- newIORef emptyVarSet ;
  76         type_env_var <- newIORef emptyNameEnv ;
  77         dfuns_var    <- newIORef emptyNameSet ;
  78         keep_var     <- newIORef emptyNameSet ;
  79         th_var       <- newIORef False ;
  80         dfun_n_var   <- newIORef 1 ;
  81
  82         let {
  83              gbl_env = TcGblEnv {
  84                 tcg_mod      = mod,
  85                 tcg_src      = hsc_src,
  86                 tcg_rdr_env  = emptyGlobalRdrEnv,
  87                 tcg_fix_env  = emptyNameEnv,
  88                 tcg_default  = Nothing,
  89                 tcg_type_env = emptyNameEnv,
  90                 tcg_type_env_var = type_env_var,
  91                 tcg_inst_env  = emptyInstEnv,
  92                 tcg_inst_uses = dfuns_var,
  93                 tcg_th_used   = th_var,
  94                 tcg_exports  = emptyNameSet,
  95                 tcg_imports  = init_imports,
  96                 tcg_dus      = emptyDUs,
  97                 tcg_rn_decls = Nothing,
  98                 tcg_binds    = emptyLHsBinds,
  99                 tcg_deprecs  = NoDeprecs,
 100                 tcg_insts    = [],
 101                 tcg_rules    = [],
 102                 tcg_fords    = [],
 103                 tcg_dfun_n   = dfun_n_var,
 104                 tcg_keep     = keep_var
 105              } ;
 106              lcl_env = TcLclEnv {
 107                 tcl_errs       = errs_var,
 108                 tcl_loc        = mkGeneralSrcSpan FSLIT("Top level"),
 109                 tcl_ctxt       = [],
 110                 tcl_rdr        = emptyLocalRdrEnv,
 111                 tcl_th_ctxt    = topStage,
 112                 tcl_arrow_ctxt = NoArrowCtxt,
 113                 tcl_env        = emptyNameEnv,
 114                 tcl_tyvars     = tvs_var,
 115                 tcl_lie        = panic "initTc:LIE",    -- LIE only valid inside a getLIE
 116                 tcl_gadt       = emptyVarEnv
 117              } ;
 118         } ;
 119
 120         -- OK, here's the business end!
 121         maybe_res <- initTcRnIf 'a' hsc_env gbl_env lcl_env $
 122                              do { r <- tryM do_this
 123                                 ; case r of
 124                                     Right res -> return (Just res)
 125                                     Left _    -> return Nothing } ;
 126
 127         -- Collect any error messages
 128         msgs <- readIORef errs_var ;
 129
 130         let { dflags = hsc_dflags hsc_env
 131             ; final_res | errorsFound dflags msgs = Nothing
 132                         | otherwise               = maybe_res } ;
 133
 134         return (msgs, final_res)
 135     }
 136   where
 137     init_imports = emptyImportAvails { imp_env = unitModuleEnv mod emptyNameSet }
 138         -- Initialise tcg_imports with an empty set of bindings for
 139         -- this module, so that if we see 'module M' in the export
 140         -- list, and there are no bindings in M, we don't bleat
 141         -- "unknown module M".
 142
 143 initTcPrintErrors       -- Used from the interactive loop only
 144        :: HscEnv
 145        -> Module
 146        -> TcM r
 147        -> IO (Maybe r)
 148 initTcPrintErrors env mod todo = do
 149   (msgs, res) <- initTc env HsSrcFile mod todo
 150   printErrorsAndWarnings msgs
 151   return res
 152
 153 -- mkImpTypeEnv makes the imported symbol table
 154 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 155              -> Name -> Maybe TyThing
 156 mkImpTypeEnv pcs hpt = lookup
 157   where
 158     pte = eps_PTE pcs
 159     lookup name | isInternalName name = Nothing
 160                 | otherwise           = lookupType hpt pte name
 161 \end{code}
 162
 163
 164 %************************************************************************
 165 %*                                                                      *
 166                 Initialisation
 167 %*                                                                      *
 168 %************************************************************************
 169
 170
 171 \begin{code}
 172 initTcRnIf :: Char              -- Tag for unique supply
 173            -> HscEnv
 174            -> gbl -> lcl
 175            -> TcRnIf gbl lcl a
 176            -> IO a
 177 initTcRnIf uniq_tag hsc_env gbl_env lcl_env thing_inside
 178    = do { us     <- mkSplitUniqSupply uniq_tag ;
 179         ; us_var <- newIORef us ;
 180
 181         ; let { env = Env { env_top = hsc_env,
 182                             env_us  = us_var,
 183                             env_gbl = gbl_env,
 184                             env_lcl = lcl_env } }
 185
 186         ; runIOEnv env thing_inside
 187         }
 188 \end{code}
 189
 190 %************************************************************************
 191 %*                                                                      *
 192                 Simple accessors
 193 %*                                                                      *
 194 %************************************************************************
 195
 196 \begin{code}
 197 getTopEnv :: TcRnIf gbl lcl HscEnv
 198 getTopEnv = do { env <- getEnv; return (env_top env) }
 199
 200 getGblEnv :: TcRnIf gbl lcl gbl
 201 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 202
 203 updGblEnv :: (gbl -> gbl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 204 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 205                           env { env_gbl = upd gbl })
 206
 207 setGblEnv :: gbl -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 208 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 209
 210 getLclEnv :: TcRnIf gbl lcl lcl
 211 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 212
 213 updLclEnv :: (lcl -> lcl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 214 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 215                           env { env_lcl = upd lcl })
 216
 217 setLclEnv :: lcl' -> TcRnIf gbl lcl' a -> TcRnIf gbl lcl a
 218 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 219
 220 getEnvs :: TcRnIf gbl lcl (gbl, lcl)
 221 getEnvs = do { env <- getEnv; return (env_gbl env, env_lcl env) }
 222
 223 setEnvs :: (gbl', lcl') -> TcRnIf gbl' lcl' a -> TcRnIf gbl lcl a
 224 setEnvs (gbl_env, lcl_env) = updEnv (\ env -> env { env_gbl = gbl_env, env_lcl = lcl_env })
 225 \end{code}
 226
 227
 228 Command-line flags
 229
 230 \begin{code}
 231 getDOpts :: TcRnIf gbl lcl DynFlags
 232 getDOpts = do { env <- getTopEnv; return (hsc_dflags env) }
 233
 234 doptM :: DynFlag -> TcRnIf gbl lcl Bool
 235 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 236
 237 setOptM :: DynFlag -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 238 setOptM flag = updEnv (\ env@(Env { env_top = top }) ->
 239                          env { env_top = top { hsc_dflags = dopt_set (hsc_dflags top) flag}} )
 240
 241 ifOptM :: DynFlag -> TcRnIf gbl lcl () -> TcRnIf gbl lcl ()     -- Do it flag is true
 242 ifOptM flag thing_inside = do { b <- doptM flag;
 243                                 if b then thing_inside else return () }
 244
 245 getGhciMode :: TcRnIf gbl lcl GhcMode
 246 getGhciMode = do { env <- getTopEnv; return (ghcMode (hsc_dflags env)) }
 247 \end{code}
 248
 249 \begin{code}
 250 getEpsVar :: TcRnIf gbl lcl (TcRef ExternalPackageState)
 251 getEpsVar = do { env <- getTopEnv; return (hsc_EPS env) }
 252
 253 getEps :: TcRnIf gbl lcl ExternalPackageState
 254 getEps = do { env <- getTopEnv; readMutVar (hsc_EPS env) }
 255
 256 -- Updating the EPS.  This should be an atomic operation.
 257 -- Note the delicate 'seq' which forces the EPS before putting it in the
 258 -- variable.  Otherwise what happens is that we get
 259 --      write eps_var (....(unsafeRead eps_var)....)
 260 -- and if the .... is strict, that's obviously bottom.  By forcing it beforehand
 261 -- we make the unsafeRead happen before we update the variable.
 262
 263 updateEps :: (ExternalPackageState -> (ExternalPackageState, a))
 264           -> TcRnIf gbl lcl a
 265 updateEps upd_fn = do   { traceIf (text "updating EPS")
 266                         ; eps_var <- getEpsVar
 267                         ; eps <- readMutVar eps_var
 268                         ; let { (eps', val) = upd_fn eps }
 269                         ; seq eps' (writeMutVar eps_var eps')
 270                         ; return val }
 271
 272 updateEps_ :: (ExternalPackageState -> ExternalPackageState)
 273            -> TcRnIf gbl lcl ()
 274 updateEps_ upd_fn = do  { traceIf (text "updating EPS_")
 275                         ; eps_var <- getEpsVar
 276                         ; eps <- readMutVar eps_var
 277                         ; let { eps' = upd_fn eps }
 278                         ; seq eps' (writeMutVar eps_var eps') }
 279
 280 getHpt :: TcRnIf gbl lcl HomePackageTable
 281 getHpt = do { env <- getTopEnv; return (hsc_HPT env) }
 282
 283 getEpsAndHpt :: TcRnIf gbl lcl (ExternalPackageState, HomePackageTable)
 284 getEpsAndHpt = do { env <- getTopEnv; eps <- readMutVar (hsc_EPS env)
 285                   ; return (eps, hsc_HPT env) }
 286 \end{code}
 287
 288 %************************************************************************
 289 %*                                                                      *
 290                 Unique supply
 291 %*                                                                      *
 292 %************************************************************************
 293
 294 \begin{code}
 295 newUnique :: TcRnIf gbl lcl Unique
 296 newUnique = do { us <- newUniqueSupply ;
 297                  return (uniqFromSupply us) }
 298
 299 newUniqueSupply :: TcRnIf gbl lcl UniqSupply
 300 newUniqueSupply
 301  = do { env <- getEnv ;
 302         let { u_var = env_us env } ;
 303         us <- readMutVar u_var ;
 304         let { (us1, us2) = splitUniqSupply us } ;
 305         writeMutVar u_var us1 ;
 306         return us2 }
 307 \end{code}
 308
 309
 310 %************************************************************************
 311 %*                                                                      *
 312                 Debugging
 313 %*                                                                      *
 314 %************************************************************************
 315
 316 \begin{code}
 317 traceTc, traceRn :: SDoc -> TcRn ()
 318 traceRn      = dumpOptTcRn Opt_D_dump_rn_trace
 319 traceTc      = dumpOptTcRn Opt_D_dump_tc_trace
 320 traceSplice  = dumpOptTcRn Opt_D_dump_splices
 321
 322
 323 traceIf :: SDoc -> TcRnIf m n ()
 324 traceIf      = dumpOptIf Opt_D_dump_if_trace
 325 traceHiDiffs = dumpOptIf Opt_D_dump_hi_diffs
 326
 327
 328 dumpOptIf :: DynFlag -> SDoc -> TcRnIf m n ()  -- No RdrEnv available, so qualify everything
 329 dumpOptIf flag doc = ifOptM flag $
 330                      ioToIOEnv (printForUser stderr alwaysQualify doc)
 331
 332 dumpOptTcRn :: DynFlag -> SDoc -> TcRn ()
 333 dumpOptTcRn flag doc = ifOptM flag $ do
 334                         { ctxt <- getErrCtxt
 335                         ; loc  <- getSrcSpanM
 336                         ; ctxt_msgs <- do_ctxt emptyTidyEnv ctxt
 337                         ; let real_doc = mkLocMessage loc (vcat (doc : ctxt_to_use ctxt_msgs))
 338                         ; dumpTcRn real_doc }
 339
 340 dumpTcRn :: SDoc -> TcRn ()
 341 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 342                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 343 \end{code}
 344
 345
 346 %************************************************************************
 347 %*                                                                      *
 348                 Typechecker global environment
 349 %*                                                                      *
 350 %************************************************************************
 351
 352 \begin{code}
 353 getModule :: TcRn Module
 354 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 355
 356 tcIsHsBoot :: TcRn Bool
 357 tcIsHsBoot = do { env <- getGblEnv; return (isHsBoot (tcg_src env)) }
 358
 359 getGlobalRdrEnv :: TcRn GlobalRdrEnv
 360 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 361
 362 getImports :: TcRn ImportAvails
 363 getImports = do { env <- getGblEnv; return (tcg_imports env) }
 364
 365 getFixityEnv :: TcRn FixityEnv
 366 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 367
 368 extendFixityEnv :: [(Name,FixItem)] -> RnM a -> RnM a
 369 extendFixityEnv new_bit
 370   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 371                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 372
 373 getDefaultTys :: TcRn (Maybe [Type])
 374 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 375 \end{code}
 376
 377 %************************************************************************
 378 %*                                                                      *
 379                 Error management
 380 %*                                                                      *
 381 %************************************************************************
 382
 383 \begin{code}
 384 getSrcSpanM :: TcRn SrcSpan
 385         -- Avoid clash with Name.getSrcLoc
 386 getSrcSpanM = do { env <- getLclEnv; return (tcl_loc env) }
 387
 388 setSrcSpan :: SrcSpan -> TcRn a -> TcRn a
 389 setSrcSpan loc thing_inside
 390   | isGoodSrcSpan loc = updLclEnv (\env -> env { tcl_loc = loc }) thing_inside
 391   | otherwise         = thing_inside    -- Don't overwrite useful info with useless
 392
 393 addLocM :: (a -> TcM b) -> Located a -> TcM b
 394 addLocM fn (L loc a) = setSrcSpan loc $ fn a
 395
 396 wrapLocM :: (a -> TcM b) -> Located a -> TcM (Located b)
 397 wrapLocM fn (L loc a) = setSrcSpan loc $ do b <- fn a; return (L loc b)
 398
 399 wrapLocFstM :: (a -> TcM (b,c)) -> Located a -> TcM (Located b, c)
 400 wrapLocFstM fn (L loc a) =
 401   setSrcSpan loc $ do
 402     (b,c) <- fn a
 403     return (L loc b, c)
 404
 405 wrapLocSndM :: (a -> TcM (b,c)) -> Located a -> TcM (b, Located c)
 406 wrapLocSndM fn (L loc a) =
 407   setSrcSpan loc $ do
 408     (b,c) <- fn a
 409     return (b, L loc c)
 410 \end{code}
 411
 412
 413 \begin{code}
 414 getErrsVar :: TcRn (TcRef Messages)
 415 getErrsVar = do { env <- getLclEnv; return (tcl_errs env) }
 416
 417 setErrsVar :: TcRef Messages -> TcRn a -> TcRn a
 418 setErrsVar v = updLclEnv (\ env -> env { tcl_errs =  v })
 419
 420 addErr :: Message -> TcRn ()
 421 addErr msg = do { loc <- getSrcSpanM ; addErrAt loc msg }
 422
 423 addLocErr :: Located e -> (e -> Message) -> TcRn ()
 424 addLocErr (L loc e) fn = addErrAt loc (fn e)
 425
 426 addErrAt :: SrcSpan -> Message -> TcRn ()
 427 addErrAt loc msg = addLongErrAt loc msg empty
 428
 429 addLongErrAt :: SrcSpan -> Message -> Message -> TcRn ()
 430 addLongErrAt loc msg extra
 431  = do {  errs_var <- getErrsVar ;
 432          rdr_env <- getGlobalRdrEnv ;
 433          let { err = mkLongErrMsg loc (unQualInScope rdr_env) msg extra } ;
 434          (warns, errs) <- readMutVar errs_var ;
 435          writeMutVar errs_var (warns, errs `snocBag` err) }
 436
 437 addErrs :: [(SrcSpan,Message)] -> TcRn ()
 438 addErrs msgs = mappM_ add msgs
 439              where
 440                add (loc,msg) = addErrAt loc msg
 441
 442 addReport :: Message -> TcRn ()
 443 addReport msg = do loc <- getSrcSpanM; addReportAt loc msg
 444
 445 addReportAt :: SrcSpan -> Message -> TcRn ()
 446 addReportAt loc msg
 447   = do { errs_var <- getErrsVar ;
 448          rdr_env <- getGlobalRdrEnv ;
 449          let { warn = mkWarnMsg loc (unQualInScope rdr_env) msg } ;
 450          (warns, errs) <- readMutVar errs_var ;
 451          writeMutVar errs_var (warns `snocBag` warn, errs) }
 452
 453 addWarn :: Message -> TcRn ()
 454 addWarn msg = addReport (ptext SLIT("Warning:") <+> msg)
 455
 456 addWarnAt :: SrcSpan -> Message -> TcRn ()
 457 addWarnAt loc msg = addReportAt loc (ptext SLIT("Warning:") <+> msg)
 458
 459 addLocWarn :: Located e -> (e -> Message) -> TcRn ()
 460 addLocWarn (L loc e) fn = addReportAt loc (fn e)
 461
 462 checkErr :: Bool -> Message -> TcRn ()
 463 -- Add the error if the bool is False
 464 checkErr ok msg = checkM ok (addErr msg)
 465
 466 warnIf :: Bool -> Message -> TcRn ()
 467 warnIf True  msg = addWarn msg
 468 warnIf False msg = return ()
 469
 470 addMessages :: Messages -> TcRn ()
 471 addMessages (m_warns, m_errs)
 472   = do { errs_var <- getErrsVar ;
 473          (warns, errs) <- readMutVar errs_var ;
 474          writeMutVar errs_var (warns `unionBags` m_warns,
 475                                errs  `unionBags` m_errs) }
 476
 477 discardWarnings :: TcRn a -> TcRn a
 478 -- Ignore warnings inside the thing inside;
 479 -- used to ignore-unused-variable warnings inside derived code
 480 -- With -dppr-debug, the effects is switched off, so you can still see
 481 -- what warnings derived code would give
 482 discardWarnings thing_inside
 483   | opt_PprStyle_Debug = thing_inside
 484   | otherwise
 485   = do  { errs_var <- newMutVar emptyMessages
 486         ; result <- setErrsVar errs_var thing_inside
 487         ; (_warns, errs) <- readMutVar errs_var
 488         ; addMessages (emptyBag, errs)
 489         ; return result }
 490 \end{code}
 491
 492
 493 \begin{code}
 494 try_m :: TcRn r -> TcRn (Either Exception r)
 495 -- Does try_m, with a debug-trace on failure
 496 try_m thing
 497   = do { mb_r <- tryM thing ;
 498          case mb_r of
 499              Left exn -> do { traceTc (exn_msg exn); return mb_r }
 500              Right r  -> return mb_r }
 501   where
 502     exn_msg exn = text "tryTc/recoverM recovering from" <+> text (showException exn)
 503
 504 -----------------------
 505 recoverM :: TcRn r      -- Recovery action; do this if the main one fails
 506          -> TcRn r      -- Main action: do this first
 507          -> TcRn r
 508 -- Errors in 'thing' are retained
 509 recoverM recover thing
 510   = do { mb_res <- try_m thing ;
 511          case mb_res of
 512            Left exn  -> recover
 513            Right res -> returnM res }
 514
 515 -----------------------
 516 tryTc :: TcRn a -> TcRn (Messages, Maybe a)
 517 -- (tryTc m) executes m, and returns
 518 --      Just r,  if m succeeds (returning r)
 519 --      Nothing, if m fails
 520 -- It also returns all the errors and warnings accumulated by m
 521 -- It always succeeds (never raises an exception)
 522 tryTc m
 523  = do { errs_var <- newMutVar emptyMessages ;
 524         res  <- try_m (setErrsVar errs_var m) ;
 525         msgs <- readMutVar errs_var ;
 526         return (msgs, case res of
 527                             Left exn  -> Nothing
 528                             Right val -> Just val)
 529         -- The exception is always the IOEnv built-in
 530         -- in exception; see IOEnv.failM
 531    }
 532
 533 -----------------------
 534 tryTcErrs :: TcRn a -> TcRn (Messages, Maybe a)
 535 -- Run the thing, returning
 536 --      Just r,  if m succceeds with no error messages
 537 --      Nothing, if m fails, or if it succeeds but has error messages
 538 -- Either way, the messages are returned; even in the Just case
 539 -- there might be warnings
 540 tryTcErrs thing
 541   = do  { (msgs, res) <- tryTc thing
 542         ; dflags <- getDOpts
 543         ; let errs_found = errorsFound dflags msgs
 544         ; return (msgs, case res of
 545                           Nothing -> Nothing
 546                           Just val | errs_found -> Nothing
 547                                    | otherwise  -> Just val)
 548         }
 549
 550 -----------------------
 551 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 552 -- Just like tryTcErrs, except that it ensures that the LIE
 553 -- for the thing is propagated only if there are no errors
 554 -- Hence it's restricted to the type-check monad
 555 tryTcLIE thing_inside
 556   = do  { ((msgs, mb_res), lie) <- getLIE (tryTcErrs thing_inside) ;
 557         ; case mb_res of
 558             Nothing  -> return (msgs, Nothing)
 559             Just val -> do { extendLIEs lie; return (msgs, Just val) }
 560         }
 561
 562 -----------------------
 563 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 564 -- (tryTcLIE_ r m) tries m;
 565 --      if m succeeds with no error messages, it's the answer
 566 --      otherwise tryTcLIE_ drops everything from m and tries r instead.
 567 tryTcLIE_ recover main
 568   = do  { (msgs, mb_res) <- tryTcLIE main
 569         ; case mb_res of
 570              Just val -> do { addMessages msgs  -- There might be warnings
 571                              ; return val }
 572              Nothing  -> recover                -- Discard all msgs
 573         }
 574
 575 -----------------------
 576 checkNoErrs :: TcM r -> TcM r
 577 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 578 -- If m fails then (checkNoErrsTc m) fails.
 579 -- If m succeeds, it checks whether m generated any errors messages
 580 --      (it might have recovered internally)
 581 --      If so, it fails too.
 582 -- Regardless, any errors generated by m are propagated to the enclosing context.
 583 checkNoErrs main
 584   = do  { (msgs, mb_res) <- tryTcLIE main
 585         ; addMessages msgs
 586         ; case mb_res of
 587             Nothing   -> failM
 588             Just val -> return val
 589         }
 590
 591 ifErrsM :: TcRn r -> TcRn r -> TcRn r
 592 --      ifErrsM bale_out main
 593 -- does 'bale_out' if there are errors in errors collection
 594 -- otherwise does 'main'
 595 ifErrsM bale_out normal
 596  = do { errs_var <- getErrsVar ;
 597         msgs <- readMutVar errs_var ;
 598         dflags <- getDOpts ;
 599         if errorsFound dflags msgs then
 600            bale_out
 601         else
 602            normal }
 603
 604 failIfErrsM :: TcRn ()
 605 -- Useful to avoid error cascades
 606 failIfErrsM = ifErrsM failM (return ())
 607 \end{code}
 608
 609
 610 %************************************************************************
 611 %*                                                                      *
 612         Context management and error message generation
 613                     for the type checker
 614 %*                                                                      *
 615 %************************************************************************
 616
 617 \begin{code}
 618 getErrCtxt :: TcM ErrCtxt
 619 getErrCtxt = do { env <- getLclEnv; return (tcl_ctxt env) }
 620
 621 setErrCtxt :: ErrCtxt -> TcM a -> TcM a
 622 setErrCtxt ctxt = updLclEnv (\ env -> env { tcl_ctxt = ctxt })
 623
 624 addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 625 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 626
 627 addErrCtxt :: Message -> TcM a -> TcM a
 628 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 629
 630 -- Helper function for the above
 631 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 632 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 633                            env { tcl_ctxt = upd ctxt })
 634
 635 -- Conditionally add an error context
 636 maybeAddErrCtxt :: Maybe Message -> TcM a -> TcM a
 637 maybeAddErrCtxt (Just msg) thing_inside = addErrCtxt msg thing_inside
 638 maybeAddErrCtxt Nothing    thing_inside = thing_inside
 639
 640 popErrCtxt :: TcM a -> TcM a
 641 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 642
 643 getInstLoc :: InstOrigin -> TcM InstLoc
 644 getInstLoc origin
 645   = do { loc <- getSrcSpanM ; env <- getLclEnv ;
 646          return (InstLoc origin loc (tcl_ctxt env)) }
 647
 648 addInstCtxt :: InstLoc -> TcM a -> TcM a
 649 -- Add the SrcSpan and context from the first Inst in the list
 650 --      (they all have similar locations)
 651 addInstCtxt (InstLoc _ src_loc ctxt) thing_inside
 652   = setSrcSpan src_loc (updCtxt (\ old_ctxt -> ctxt) thing_inside)
 653 \end{code}
 654
 655     The addErrTc functions add an error message, but do not cause failure.
 656     The 'M' variants pass a TidyEnv that has already been used to
 657     tidy up the message; we then use it to tidy the context messages
 658
 659 \begin{code}
 660 addErrTc :: Message -> TcM ()
 661 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 662
 663 addErrsTc :: [Message] -> TcM ()
 664 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 665
 666 addErrTcM :: (TidyEnv, Message) -> TcM ()
 667 addErrTcM (tidy_env, err_msg)
 668   = do { ctxt <- getErrCtxt ;
 669          loc  <- getSrcSpanM ;
 670          add_err_tcm tidy_env err_msg loc ctxt }
 671 \end{code}
 672
 673 The failWith functions add an error message and cause failure
 674
 675 \begin{code}
 676 failWithTc :: Message -> TcM a               -- Add an error message and fail
 677 failWithTc err_msg
 678   = addErrTc err_msg >> failM
 679
 680 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 681 failWithTcM local_and_msg
 682   = addErrTcM local_and_msg >> failM
 683
 684 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 685 checkTc True  err = returnM ()
 686 checkTc False err = failWithTc err
 687 \end{code}
 688
 689         Warnings have no 'M' variant, nor failure
 690
 691 \begin{code}
 692 addWarnTc :: Message -> TcM ()
 693 addWarnTc msg
 694  = do { ctxt <- getErrCtxt ;
 695         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 696         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 697
 698 warnTc :: Bool -> Message -> TcM ()
 699 warnTc warn_if_true warn_msg
 700   | warn_if_true = addWarnTc warn_msg
 701   | otherwise    = return ()
 702 \end{code}
 703
 704         Helper functions
 705
 706 \begin{code}
 707 add_err_tcm tidy_env err_msg loc ctxt
 708  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 709         addLongErrAt loc err_msg (vcat (ctxt_to_use ctxt_msgs)) }
 710
 711 do_ctxt tidy_env []
 712  = return []
 713 do_ctxt tidy_env (c:cs)
 714  = do { (tidy_env', m) <- c tidy_env  ;
 715         ms             <- do_ctxt tidy_env' cs  ;
 716         return (m:ms) }
 717
 718 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 719                  | otherwise          = take 3 ctxt
 720 \end{code}
 721
 722 debugTc is useful for monadi debugging code
 723
 724 \begin{code}
 725 debugTc :: TcM () -> TcM ()
 726 #ifdef DEBUG
 727 debugTc thing = thing
 728 #else
 729 debugTc thing = return ()
 730 #endif
 731 \end{code}
 732
 733  %************************************************************************
 734 %*                                                                      *
 735              Type constraints (the so-called LIE)
 736 %*                                                                      *
 737 %************************************************************************
 738
 739 \begin{code}
 740 nextDFunIndex :: TcM Int        -- Get the next dfun index
 741 nextDFunIndex = do { env <- getGblEnv
 742                    ; let dfun_n_var = tcg_dfun_n env
 743                    ; n <- readMutVar dfun_n_var
 744                    ; writeMutVar dfun_n_var (n+1)
 745                    ; return n }
 746
 747 getLIEVar :: TcM (TcRef LIE)
 748 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 749
 750 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 751 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 752
 753 getLIE :: TcM a -> TcM (a, [Inst])
 754 -- (getLIE m) runs m, and returns the type constraints it generates
 755 getLIE thing_inside
 756   = do { lie_var <- newMutVar emptyLIE ;
 757          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 758                           thing_inside ;
 759          lie <- readMutVar lie_var ;
 760          return (res, lieToList lie) }
 761
 762 extendLIE :: Inst -> TcM ()
 763 extendLIE inst
 764   = do { lie_var <- getLIEVar ;
 765          lie <- readMutVar lie_var ;
 766          writeMutVar lie_var (inst `consLIE` lie) }
 767
 768 extendLIEs :: [Inst] -> TcM ()
 769 extendLIEs []
 770   = returnM ()
 771 extendLIEs insts
 772   = do { lie_var <- getLIEVar ;
 773          lie <- readMutVar lie_var ;
 774          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 775 \end{code}
 776
 777 \begin{code}
 778 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 779 -- Set the local type envt, but do *not* disturb other fields,
 780 -- notably the lie_var
 781 setLclTypeEnv lcl_env thing_inside
 782   = updLclEnv upd thing_inside
 783   where
 784     upd env = env { tcl_env = tcl_env lcl_env,
 785                     tcl_tyvars = tcl_tyvars lcl_env }
 786 \end{code}
 787
 788
 789 %************************************************************************
 790 %*                                                                      *
 791              Template Haskell context
 792 %*                                                                      *
 793 %************************************************************************
 794
 795 \begin{code}
 796 recordThUse :: TcM ()
 797 recordThUse = do { env <- getGblEnv; writeMutVar (tcg_th_used env) True }
 798
 799 keepAliveTc :: Name -> TcM ()   -- Record the name in the keep-alive set
 800 keepAliveTc n = do { env <- getGblEnv;
 801                    ; updMutVar (tcg_keep env) (`addOneToNameSet` n) }
 802
 803 keepAliveSetTc :: NameSet -> TcM ()     -- Record the name in the keep-alive set
 804 keepAliveSetTc ns = do { env <- getGblEnv;
 805                        ; updMutVar (tcg_keep env) (`unionNameSets` ns) }
 806
 807 getStage :: TcM ThStage
 808 getStage = do { env <- getLclEnv; return (tcl_th_ctxt env) }
 809
 810 setStage :: ThStage -> TcM a -> TcM a
 811 setStage s = updLclEnv (\ env -> env { tcl_th_ctxt = s })
 812 \end{code}
 813
 814
 815 %************************************************************************
 816 %*                                                                      *
 817              Stuff for the renamer's local env
 818 %*                                                                      *
 819 %************************************************************************
 820
 821 \begin{code}
 822 getLocalRdrEnv :: RnM LocalRdrEnv
 823 getLocalRdrEnv = do { env <- getLclEnv; return (tcl_rdr env) }
 824
 825 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 826 setLocalRdrEnv rdr_env thing_inside
 827   = updLclEnv (\env -> env {tcl_rdr = rdr_env}) thing_inside
 828 \end{code}
 829
 830
 831 %************************************************************************
 832 %*                                                                      *
 833              Stuff for interface decls
 834 %*                                                                      *
 835 %************************************************************************
 836
 837 \begin{code}
 838 mkIfLclEnv :: Module -> SDoc -> IfLclEnv
 839 mkIfLclEnv mod loc = IfLclEnv { if_mod     = mod,
 840                                 if_loc     = loc,
 841                                 if_tv_env  = emptyOccEnv,
 842                                 if_id_env  = emptyOccEnv }
 843
 844 initIfaceTcRn :: IfG a -> TcRn a
 845 initIfaceTcRn thing_inside
 846   = do  { tcg_env <- getGblEnv
 847         ; let { if_env = IfGblEnv { if_rec_types = Just (tcg_mod tcg_env, get_type_env) }
 848               ; get_type_env = readMutVar (tcg_type_env_var tcg_env) }
 849         ; setEnvs (if_env, ()) thing_inside }
 850
 851 initIfaceExtCore :: IfL a -> TcRn a
 852 initIfaceExtCore thing_inside
 853   = do  { tcg_env <- getGblEnv
 854         ; let { mod = tcg_mod tcg_env
 855               ; doc = ptext SLIT("External Core file for") <+> quotes (ppr mod)
 856               ; if_env = IfGblEnv {
 857                         if_rec_types = Just (mod, return (tcg_type_env tcg_env)) }
 858               ; if_lenv = mkIfLclEnv mod doc
 859           }
 860         ; setEnvs (if_env, if_lenv) thing_inside }
 861
 862 initIfaceCheck :: HscEnv -> IfG a -> IO a
 863 -- Used when checking the up-to-date-ness of the old Iface
 864 -- Initialise the environment with no useful info at all
 865 initIfaceCheck hsc_env do_this
 866  = do   { let gbl_env = IfGblEnv { if_rec_types = Nothing }
 867         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 868     }
 869
 870 initIfaceTc :: ModIface
 871             -> (TcRef TypeEnv -> IfL a) -> TcRnIf gbl lcl a
 872 -- Used when type-checking checking an up-to-date interface file
 873 -- No type envt from the current module, but we do know the module dependencies
 874 initIfaceTc iface do_this
 875  = do   { tc_env_var <- newMutVar emptyTypeEnv
 876         ; let { gbl_env = IfGblEnv { if_rec_types = Just (mod, readMutVar tc_env_var) } ;
 877               ; if_lenv = mkIfLclEnv mod doc
 878            }
 879         ; setEnvs (gbl_env, if_lenv) (do_this tc_env_var)
 880     }
 881   where
 882     mod = mi_module iface
 883     doc = ptext SLIT("The interface for") <+> quotes (ppr mod)
 884
 885 initIfaceRules :: HscEnv -> ModGuts -> IfG a -> IO a
 886 -- Used when sucking in new Rules in SimplCore
 887 -- We have available the type envt of the module being compiled, and we must use it
 888 initIfaceRules hsc_env guts do_this
 889  = do   { let {
 890              type_info = (mg_module guts, return (mg_types guts))
 891            ; gbl_env = IfGblEnv { if_rec_types = Just type_info } ;
 892            }
 893
 894         -- Run the thing; any exceptions just bubble out from here
 895         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 896     }
 897
 898 initIfaceLcl :: Module -> SDoc -> IfL a -> IfM lcl a
 899 initIfaceLcl mod loc_doc thing_inside
 900   = setLclEnv (mkIfLclEnv mod loc_doc) thing_inside
 901
 902 getIfModule :: IfL Module
 903 getIfModule = do { env <- getLclEnv; return (if_mod env) }
 904
 905 --------------------
 906 failIfM :: Message -> IfL a
 907 -- The Iface monad doesn't have a place to accumulate errors, so we
 908 -- just fall over fast if one happens; it "shouldnt happen".
 909 -- We use IfL here so that we can get context info out of the local env
 910 failIfM msg
 911   = do  { env <- getLclEnv
 912         ; let full_msg = if_loc env $$ nest 2 msg
 913         ; ioToIOEnv (printErrs (full_msg defaultErrStyle))
 914         ; failM }
 915
 916 --------------------
 917 forkM_maybe :: SDoc -> IfL a -> IfL (Maybe a)
 918 -- Run thing_inside in an interleaved thread.
 919 -- It shares everything with the parent thread, so this is DANGEROUS.
 920 --
 921 -- It returns Nothing if the computation fails
 922 --
 923 -- It's used for lazily type-checking interface
 924 -- signatures, which is pretty benign
 925
 926 forkM_maybe doc thing_inside
 927  = do { unsafeInterleaveM $
 928         do { traceIf (text "Starting fork {" <+> doc)
 929            ; mb_res <- tryM thing_inside ;
 930              case mb_res of
 931                 Right r  -> do  { traceIf (text "} ending fork" <+> doc)
 932                                 ; return (Just r) }
 933                 Left exn -> do {
 934
 935                     -- Bleat about errors in the forked thread, if -ddump-if-trace is on
 936                     -- Otherwise we silently discard errors. Errors can legitimately
 937                     -- happen when compiling interface signatures (see tcInterfaceSigs)
 938                       ifOptM Opt_D_dump_if_trace
 939                              (print_errs (hang (text "forkM failed:" <+> doc)
 940                                              4 (text (show exn))))
 941
 942                     ; traceIf (text "} ending fork (badly)" <+> doc)
 943                     ; return Nothing }
 944         }}
 945   where
 946     print_errs sdoc = ioToIOEnv (printErrs (sdoc defaultErrStyle))
 947
 948 forkM :: SDoc -> IfL a -> IfL a
 949 forkM doc thing_inside
 950  = do   { mb_res <- forkM_maybe doc thing_inside
 951         ; return (case mb_res of
 952                         Nothing -> pprPanic "forkM" doc
 953                         Just r  -> r) }
 954 \end{code}
 955
 956 %************************************************************************
 957 %*                                                                      *
 958              Stuff for GADTs
 959 %*                                                                      *
 960 %************************************************************************
 961
 962 \begin{code}
 963 getTypeRefinement :: TcM GadtRefinement
 964 getTypeRefinement = do { lcl_env <- getLclEnv; return (tcl_gadt lcl_env) }
 965
 966 setTypeRefinement :: GadtRefinement -> TcM a -> TcM a
 967 setTypeRefinement gadt = updLclEnv (\env -> env { tcl_gadt = gadt })
 968 \end{code}