ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes
   5   ) where
   6
   7 #include "HsVersions.h"
   8
   9 import HsSyn            ( MonoBinds(..) )
  10 import HscTypes         ( HscEnv(..), PersistentCompilerState(..),
  11                           emptyFixityEnv, emptyGlobalRdrEnv, TyThing,
  12                           ExternalPackageState(..), HomePackageTable,
  13                           ModDetails(..), HomeModInfo(..), Deprecations(..),
  14                           GlobalRdrEnv, LocalRdrEnv, NameCache, FixityEnv,
  15                           GhciMode, lookupType, unQualInScope )
  16 import TcRnTypes
  17 import Module           ( Module, unitModuleEnv, foldModuleEnv )
  18 import Name             ( Name, isInternalName )
  19 import Type             ( Type )
  20 import NameEnv          ( extendNameEnvList )
  21 import InstEnv          ( InstEnv, extendInstEnv )
  22 import TysWiredIn       ( integerTy, doubleTy )
  23
  24 import VarSet           ( emptyVarSet )
  25 import VarEnv           ( TidyEnv, emptyTidyEnv )
  26 import RdrName          ( emptyRdrEnv )
  27 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  28                           addShortErrLocLine, addShortWarnLocLine, printErrorsAndWarnings )
  29 import SrcLoc           ( SrcLoc, noSrcLoc )
  30 import NameEnv          ( emptyNameEnv )
  31 import Bag              ( emptyBag )
  32 import Outputable
  33 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  34 import Unique           ( Unique )
  35 import CmdLineOpts      ( DynFlags, DynFlag(..), dopt, opt_PprStyle_Debug )
  36 import BasicTypes       ( FixitySig )
  37 import Bag              ( snocBag, unionBags )
  38 import Panic            ( showException )
  39
  40 import Maybe            ( isJust )
  41 import IO               ( stderr )
  42 import DATA_IOREF       ( newIORef, readIORef )
  43 import EXCEPTION        ( Exception )
  44 \end{code}
  45
  46 %************************************************************************
  47 %*                                                                      *
  48         Standard combinators, but specialised for this monad
  49                         (for efficiency)
  50 %*                                                                      *
  51 6%************************************************************************
  52
  53 \begin{code}
  54 mappM         :: (a -> TcRn m b) -> [a] -> TcRn m [b]
  55 mappM_        :: (a -> TcRn m b) -> [a] -> TcRn m ()
  56         -- Funny names to avoid clash with Prelude
  57 sequenceM     :: [TcRn m a] -> TcRn m [a]
  58 foldlM        :: (a -> b -> TcRn m a)  -> a -> [b] -> TcRn m a
  59 mapAndUnzipM  :: (a -> TcRn m (b,c))   -> [a] -> TcRn m ([b],[c])
  60 mapAndUnzip3M :: (a -> TcRn m (b,c,d)) -> [a] -> TcRn m ([b],[c],[d])
  61 checkM        :: Bool -> TcRn m () -> TcRn m () -- Perform arg if bool is False
  62 ifM           :: Bool -> TcRn m () -> TcRn m () -- Perform arg if bool is True
  63
  64 mappM f []     = return []
  65 mappM f (x:xs) = do { r <- f x; rs <- mappM f xs; return (r:rs) }
  66
  67 mappM_ f []     = return ()
  68 mappM_ f (x:xs) = f x >> mappM_ f xs
  69
  70 sequenceM [] = return []
  71 sequenceM (x:xs) = do { r <- x; rs <- sequenceM xs; return (r:rs) }
  72
  73 foldlM k z [] = return z
  74 foldlM k z (x:xs) = do { r <- k z x; foldlM k r xs }
  75
  76 mapAndUnzipM f []     = return ([],[])
  77 mapAndUnzipM f (x:xs) = do { (r,s) <- f x;
  78                              (rs,ss) <- mapAndUnzipM f xs;
  79                              return (r:rs, s:ss) }
  80
  81 mapAndUnzip3M f []     = return ([],[], [])
  82 mapAndUnzip3M f (x:xs) = do { (r,s,t) <- f x;
  83                               (rs,ss,ts) <- mapAndUnzip3M f xs;
  84                               return (r:rs, s:ss, t:ts) }
  85
  86 checkM True  err = return ()
  87 checkM False err = err
  88
  89 ifM True  do_it = do_it
  90 ifM False do_it = return ()
  91 \end{code}
  92
  93
  94 %************************************************************************
  95 %*                                                                      *
  96                         initTc
  97 %*                                                                      *
  98 %************************************************************************
  99
 100 \begin{code}
 101 initTc :: HscEnv -> PersistentCompilerState
 102        -> Module
 103        -> TcM r
 104        -> IO (PersistentCompilerState, Maybe r)
 105                 -- Nothing => error thrown by the thing inside
 106                 -- (error messages should have been printed already)
 107
 108 initTc  (HscEnv { hsc_mode   = ghci_mode,
 109                   hsc_HPT    = hpt,
 110                   hsc_dflags = dflags })
 111         pcs mod do_this
 112  = do { us       <- mkSplitUniqSupply 'a' ;
 113         us_var   <- newIORef us ;
 114         errs_var <- newIORef (emptyBag, emptyBag) ;
 115         tvs_var  <- newIORef emptyVarSet ;
 116         usg_var  <- newIORef emptyUsages ;
 117         nc_var   <- newIORef (pcs_nc pcs) ;
 118         eps_var  <- newIORef eps ;
 119         ie_var   <- newIORef (mkImpInstEnv dflags eps hpt) ;
 120
 121         let {
 122              env = Env { env_top = top_env,
 123                          env_gbl = gbl_env,
 124                          env_lcl = lcl_env,
 125                          env_loc = noSrcLoc } ;
 126
 127              top_env = TopEnv {
 128                 top_mode   = ghci_mode,
 129                 top_dflags = dflags,
 130                 top_eps    = eps_var,
 131                 top_hpt    = hpt,
 132                 top_nc     = nc_var,
 133                 top_us     = us_var,
 134                 top_errs   = errs_var } ;
 135
 136              gbl_env = TcGblEnv {
 137                 tcg_mod      = mod,
 138                 tcg_usages   = usg_var,
 139                 tcg_rdr_env  = emptyGlobalRdrEnv,
 140                 tcg_fix_env  = emptyFixityEnv,
 141                 tcg_default  = defaultDefaultTys,
 142                 tcg_type_env = emptyNameEnv,
 143                 tcg_inst_env = ie_var,
 144                 tcg_exports  = [],
 145                 tcg_imports  = init_imports,
 146                 tcg_binds    = EmptyMonoBinds,
 147                 tcg_deprecs  = NoDeprecs,
 148                 tcg_insts    = [],
 149                 tcg_rules    = [],
 150                 tcg_fords    = [] } ;
 151
 152              lcl_env = TcLclEnv {
 153                 tcl_ctxt   = [],
 154                 tcl_level  = topStage,
 155                 tcl_env    = emptyNameEnv,
 156                 tcl_tyvars = tvs_var,
 157                 tcl_lie    = panic "initTc:LIE" } ;
 158                         -- LIE only valid inside a getLIE
 159              } ;
 160
 161         -- OK, here's the business end!
 162         maybe_res <- catch (do { res  <- runTcRn env do_this ;
 163                                  return (Just res) })
 164                            (\_ -> return Nothing) ;
 165
 166         -- Print any error messages
 167         msgs <- readIORef errs_var ;
 168         printErrorsAndWarnings msgs ;
 169
 170         -- Get final PCS and return
 171         eps' <- readIORef eps_var ;
 172         nc'  <- readIORef nc_var ;
 173         let { pcs' = PCS { pcs_EPS = eps', pcs_nc = nc' } ;
 174               final_res | errorsFound dflags msgs = Nothing
 175                         | otherwise               = maybe_res } ;
 176
 177         return (pcs', final_res)
 178     }
 179   where
 180     eps = pcs_EPS pcs
 181
 182     init_imports = emptyImportAvails { imp_qual = unitModuleEnv mod emptyAvailEnv }
 183         -- Initialise tcg_imports with an empty set of bindings for
 184         -- this module, so that if we see 'module M' in the export
 185         -- list, and there are no bindings in M, we don't bleat
 186         -- "unknown module M".
 187
 188 defaultDefaultTys :: [Type]
 189 defaultDefaultTys = [integerTy, doubleTy]
 190
 191 mkImpInstEnv :: DynFlags -> ExternalPackageState -> HomePackageTable -> InstEnv
 192 -- At the moment we (wrongly) build an instance environment from all the
 193 -- modules we have already compiled:
 194 --      (a) eps_inst_env from the external package state
 195 --      (b) all the md_insts in the home package table
 196 -- We should really only get instances from modules below us in the
 197 -- module import tree.
 198 mkImpInstEnv dflags eps hpt
 199   = foldModuleEnv (add . md_insts . hm_details)
 200                   (eps_inst_env eps)
 201                   hpt
 202   where
 203           -- We shouldn't get instance conflict errors from
 204           -- the package and home type envs
 205     add dfuns inst_env = WARN( not (null errs), vcat (map snd errs) ) inst_env'
 206                        where
 207                          (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 208
 209 -- mkImpTypeEnv makes the imported symbol table
 210 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 211              -> Name -> Maybe TyThing
 212 mkImpTypeEnv pcs hpt = lookup
 213   where
 214     pte = eps_PTE pcs
 215     lookup name | isInternalName name = Nothing
 216                 | otherwise           = lookupType hpt pte name
 217 \end{code}
 218
 219
 220 %************************************************************************
 221 %*                                                                      *
 222                 Simple accessors
 223 %*                                                                      *
 224 %************************************************************************
 225
 226 \begin{code}
 227 getTopEnv :: TcRn m TopEnv
 228 getTopEnv = do { env <- getEnv; return (env_top env) }
 229
 230 getGblEnv :: TcRn m TcGblEnv
 231 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 232
 233 updGblEnv :: (TcGblEnv -> TcGblEnv) -> TcRn m a -> TcRn m a
 234 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 235                           env { env_gbl = upd gbl })
 236
 237 setGblEnv :: TcGblEnv -> TcRn m a -> TcRn m a
 238 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 239
 240 getLclEnv :: TcRn m m
 241 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 242
 243 updLclEnv :: (m -> m) -> TcRn m a -> TcRn m a
 244 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 245                           env { env_lcl = upd lcl })
 246
 247 setLclEnv :: m -> TcRn m a -> TcRn n a
 248 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 249
 250 getEnvs :: TcRn m (TcGblEnv, m)
 251 getEnvs = do { env <- getEnv; return (env_gbl env, env_lcl env) }
 252
 253 setEnvs :: (TcGblEnv, m) -> TcRn m a -> TcRn m a
 254 setEnvs (gbl_env, lcl_env) = updEnv (\ env -> env { env_gbl = gbl_env, env_lcl = lcl_env })
 255 \end{code}
 256
 257 Command-line flags
 258
 259 \begin{code}
 260 getDOpts :: TcRn m DynFlags
 261 getDOpts = do { env <- getTopEnv; return (top_dflags env) }
 262
 263 doptM :: DynFlag -> TcRn m Bool
 264 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 265
 266 ifOptM :: DynFlag -> TcRn m () -> TcRn m ()     -- Do it flag is true
 267 ifOptM flag thing_inside = do { b <- doptM flag;
 268                                 if b then thing_inside else return () }
 269
 270 getGhciMode :: TcRn m GhciMode
 271 getGhciMode = do { env <- getTopEnv; return (top_mode env) }
 272 \end{code}
 273
 274 \begin{code}
 275 getSrcLocM :: TcRn m SrcLoc
 276         -- Avoid clash with Name.getSrcLoc
 277 getSrcLocM = do { env <- getEnv; return (env_loc env) }
 278
 279 addSrcLoc :: SrcLoc -> TcRn m a -> TcRn m a
 280 addSrcLoc loc = updEnv (\env -> env { env_loc = loc })
 281 \end{code}
 282
 283 \begin{code}
 284 getEps :: TcRn m ExternalPackageState
 285 getEps = do { env <- getTopEnv; readMutVar (top_eps env) }
 286
 287 setEps :: ExternalPackageState -> TcRn m ()
 288 setEps eps = do { env <- getTopEnv; writeMutVar (top_eps env) eps }
 289
 290 getHpt :: TcRn m HomePackageTable
 291 getHpt = do { env <- getTopEnv; return (top_hpt env) }
 292
 293 getModule :: TcRn m Module
 294 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 295
 296 getGlobalRdrEnv :: TcRn m GlobalRdrEnv
 297 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 298
 299 getImports :: TcRn m ImportAvails
 300 getImports = do { env <- getGblEnv; return (tcg_imports env) }
 301
 302 getFixityEnv :: TcRn m FixityEnv
 303 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 304
 305 extendFixityEnv :: [(Name,FixitySig Name)] -> RnM a -> RnM a
 306 extendFixityEnv new_bit
 307   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 308                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 309
 310 getDefaultTys :: TcRn m [Type]
 311 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 312 \end{code}
 313
 314 \begin{code}
 315 getUsageVar :: TcRn m (TcRef EntityUsage)
 316 getUsageVar = do { env <- getGblEnv; return (tcg_usages env) }
 317
 318 getUsages :: TcRn m EntityUsage
 319 getUsages = do { usg_var <- getUsageVar; readMutVar usg_var }
 320
 321 updUsages :: (EntityUsage -> EntityUsage) -> TcRn m ()
 322 updUsages upd = do { usg_var <- getUsageVar ;
 323                      usg <- readMutVar usg_var ;
 324                      writeMutVar usg_var (upd usg) }
 325 \end{code}
 326
 327
 328 %************************************************************************
 329 %*                                                                      *
 330                 Error management
 331 %*                                                                      *
 332 %************************************************************************
 333
 334 \begin{code}
 335 getErrsVar :: TcRn m (TcRef Messages)
 336 getErrsVar = do { env <- getTopEnv; return (top_errs env) }
 337
 338 setErrsVar :: TcRef Messages -> TcRn m a -> TcRn m a
 339 setErrsVar v = updEnv (\ env@(Env { env_top = top_env }) ->
 340                          env { env_top = top_env { top_errs = v }})
 341
 342 addErr :: Message -> TcRn m ()
 343 addErr msg = do { loc <- getSrcLocM ; addErrAt loc msg }
 344
 345 addErrAt :: SrcLoc -> Message -> TcRn m ()
 346 addErrAt loc msg
 347  = do {  errs_var <- getErrsVar ;
 348          rdr_env <- getGlobalRdrEnv ;
 349          let { err = addShortErrLocLine loc (unQualInScope rdr_env) msg } ;
 350          (warns, errs) <- readMutVar errs_var ;
 351          writeMutVar errs_var (warns, errs `snocBag` err) }
 352
 353 addErrs :: [(SrcLoc,Message)] -> TcRn m ()
 354 addErrs msgs = mappM_ add msgs
 355              where
 356                add (loc,msg) = addErrAt loc msg
 357
 358 addWarn :: Message -> TcRn m ()
 359 addWarn msg
 360   = do { errs_var <- getErrsVar ;
 361          loc <- getSrcLocM ;
 362          rdr_env <- getGlobalRdrEnv ;
 363          let { warn = addShortWarnLocLine loc (unQualInScope rdr_env) msg } ;
 364          (warns, errs) <- readMutVar errs_var ;
 365          writeMutVar errs_var (warns `snocBag` warn, errs) }
 366
 367 checkErr :: Bool -> Message -> TcRn m ()
 368 -- Add the error if the bool is False
 369 checkErr ok msg = checkM ok (addErr msg)
 370
 371 warnIf :: Bool -> Message -> TcRn m ()
 372 warnIf True  msg = addWarn msg
 373 warnIf False msg = return ()
 374
 375 addMessages :: Messages -> TcRn m ()
 376 addMessages (m_warns, m_errs)
 377   = do { errs_var <- getErrsVar ;
 378          (warns, errs) <- readMutVar errs_var ;
 379          writeMutVar errs_var (warns `unionBags` m_warns,
 380                                errs  `unionBags` m_errs) }
 381 \end{code}
 382
 383
 384 \begin{code}
 385 recoverM :: TcRn m r    -- Recovery action; do this if the main one fails
 386          -> TcRn m r    -- Main action: do this first
 387          -> TcRn m r
 388 recoverM recover thing
 389   = do { mb_res <- try_m thing ;
 390          case mb_res of
 391            Left exn  -> recover
 392            Right res -> returnM res }
 393
 394 tryTc :: TcRn m a -> TcRn m (Messages, Maybe a)
 395     -- (tryTc m) executes m, and returns
 396     --  Just r,  if m succeeds (returning r) and caused no errors
 397     --  Nothing, if m fails, or caused errors
 398     -- It also returns all the errors accumulated by m
 399     --  (even in the Just case, there might be warnings)
 400     --
 401     -- It always succeeds (never raises an exception)
 402 tryTc m
 403  = do { errs_var <- newMutVar emptyMessages ;
 404
 405         mb_r <- try_m (setErrsVar errs_var m) ;
 406
 407         new_errs <- readMutVar errs_var ;
 408
 409         dflags <- getDOpts ;
 410
 411         return (new_errs,
 412                 case mb_r of
 413                   Left exn -> Nothing
 414                   Right r | errorsFound dflags new_errs -> Nothing
 415                           | otherwise                   -> Just r)
 416    }
 417
 418 try_m :: TcRn m r -> TcRn m (Either Exception r)
 419 -- Does try_m, with a debug-trace on failure
 420 try_m thing
 421   = do { mb_r <- tryM thing ;
 422          case mb_r of
 423              Left exn -> do { traceTc (exn_msg exn); return mb_r }
 424              Right r  -> return mb_r }
 425   where
 426     exn_msg exn = text "recoverM recovering from" <+> text (showException exn)
 427
 428 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 429 -- Just like tryTc, except that it ensures that the LIE
 430 -- for the thing is propagated only if there are no errors
 431 -- Hence it's restricted to the type-check monad
 432 tryTcLIE thing_inside
 433   = do { ((errs, mb_r), lie) <- getLIE (tryTc thing_inside) ;
 434          ifM (isJust mb_r) (extendLIEs lie) ;
 435          return (errs, mb_r) }
 436
 437 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 438 -- (tryTcLIE_ r m) tries m; if it succeeds it returns it,
 439 -- otherwise it returns r.  Any error messages added by m are discarded,
 440 -- whether or not m succeeds.
 441 tryTcLIE_ recover main
 442   = do { (_msgs, mb_res) <- tryTcLIE main ;
 443          case mb_res of
 444            Just res -> return res
 445            Nothing  -> recover }
 446
 447 checkNoErrs :: TcM r -> TcM r
 448 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 449 -- If m fails then (checkNoErrsTc m) fails.
 450 -- If m succeeds, it checks whether m generated any errors messages
 451 --      (it might have recovered internally)
 452 --      If so, it fails too.
 453 -- Regardless, any errors generated by m are propagated to the enclosing context.
 454 checkNoErrs main
 455   = do { (msgs, mb_res) <- tryTcLIE main ;
 456          addMessages msgs ;
 457          case mb_res of
 458            Just r  -> return r
 459            Nothing -> failM
 460    }
 461
 462 ifErrsM :: TcRn m r -> TcRn m r -> TcRn m r
 463 --      ifErrsM bale_out main
 464 -- does 'bale_out' if there are errors in errors collection
 465 -- otherwise does 'main'
 466 ifErrsM bale_out normal
 467  = do { errs_var <- getErrsVar ;
 468         msgs <- readMutVar errs_var ;
 469         dflags <- getDOpts ;
 470         if errorsFound dflags msgs then
 471            bale_out
 472         else
 473            normal }
 474
 475 failIfErrsM :: TcRn m ()
 476 -- Useful to avoid error cascades
 477 failIfErrsM = ifErrsM failM (return ())
 478 \end{code}
 479
 480 \begin{code}
 481 forkM :: SDoc -> TcM a -> TcM (Maybe a)
 482 -- Run thing_inside in an interleaved thread.  It gets a separate
 483 --      * errs_var, and
 484 --      * unique supply,
 485 --      * LIE var is set to bottom (should never be used)
 486 -- but everything else is shared, so this is DANGEROUS.
 487 --
 488 -- It returns Nothing if the computation fails
 489 --
 490 -- It's used for lazily type-checking interface
 491 -- signatures, which is pretty benign
 492
 493 forkM doc thing_inside
 494  = do { us <- newUniqueSupply ;
 495         unsafeInterleaveM $
 496         do { us_var <- newMutVar us ;
 497              (msgs, mb_res) <- tryTc (setLIEVar (panic "forkM: LIE used") $
 498                                       setUsVar us_var thing_inside) ;
 499              case mb_res of
 500                 Just r  -> return (Just r)
 501                 Nothing -> do {
 502
 503                     -- Bleat about errors in the forked thread, if -ddump-tc-trace is on
 504                     -- Otherwise we silently discard errors. Errors can legitimately
 505                     -- happen when compiling interface signatures (see tcInterfaceSigs)
 506                     ifOptM Opt_D_dump_tc_trace
 507                       (ioToTcRn (do { printErrs (hdr_doc defaultErrStyle) ;
 508                                       printErrorsAndWarnings msgs })) ;
 509
 510                     return Nothing }
 511         }}
 512   where
 513     hdr_doc = text "forkM failed:" <+> doc
 514 \end{code}
 515
 516
 517 %************************************************************************
 518 %*                                                                      *
 519                 Unique supply
 520 %*                                                                      *
 521 %************************************************************************
 522
 523 \begin{code}
 524 getUsVar :: TcRn m (TcRef UniqSupply)
 525 getUsVar = do { env <- getTopEnv; return (top_us env) }
 526
 527 setUsVar :: TcRef UniqSupply -> TcRn m a -> TcRn m a
 528 setUsVar v = updEnv (\ env@(Env { env_top = top_env }) ->
 529                        env { env_top = top_env { top_us = v }})
 530
 531 newUnique :: TcRn m Unique
 532 newUnique = do { us <- newUniqueSupply ;
 533                  return (uniqFromSupply us) }
 534
 535 newUniqueSupply :: TcRn m UniqSupply
 536 newUniqueSupply
 537  = do { u_var <- getUsVar ;
 538         us <- readMutVar u_var ;
 539         let { (us1, us2) = splitUniqSupply us } ;
 540         writeMutVar u_var us1 ;
 541         return us2 }
 542 \end{code}
 543
 544
 545 \begin{code}
 546 getNameCache :: TcRn m NameCache
 547 getNameCache = do { TopEnv { top_nc = nc_var } <- getTopEnv;
 548                     readMutVar nc_var }
 549
 550 setNameCache :: NameCache -> TcRn m ()
 551 setNameCache nc = do { TopEnv { top_nc = nc_var } <- getTopEnv;
 552                        writeMutVar nc_var nc }
 553 \end{code}
 554
 555
 556 %************************************************************************
 557 %*                                                                      *
 558                 Debugging
 559 %*                                                                      *
 560 %************************************************************************
 561
 562 \begin{code}
 563 traceTc, traceRn :: SDoc -> TcRn a ()
 564 traceRn      = dumpOptTcRn Opt_D_dump_rn_trace
 565 traceTc      = dumpOptTcRn Opt_D_dump_tc_trace
 566 traceSplice  = dumpOptTcRn Opt_D_dump_splices
 567 traceHiDiffs = dumpOptTcRn Opt_D_dump_hi_diffs
 568
 569 dumpOptTcRn :: DynFlag -> SDoc -> TcRn a ()
 570 dumpOptTcRn flag doc = ifOptM flag (dumpTcRn doc)
 571
 572 dumpTcRn :: SDoc -> TcRn a ()
 573 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 574                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 575 \end{code}
 576
 577
 578 %************************************************************************
 579 %*                                                                      *
 580         Context management and error message generation
 581                     for the type checker
 582 %*                                                                      *
 583 %************************************************************************
 584
 585 \begin{code}
 586 setErrCtxtM, addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 587 setErrCtxtM msg = updCtxt (\ msgs -> [msg])
 588 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 589
 590 setErrCtxt, addErrCtxt :: Message -> TcM a -> TcM a
 591 setErrCtxt msg = setErrCtxtM (\env -> returnM (env, msg))
 592 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 593
 594 popErrCtxt :: TcM a -> TcM a
 595 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 596
 597 getErrCtxt :: TcM ErrCtxt
 598 getErrCtxt = do { env <- getLclEnv ; return (tcl_ctxt env) }
 599
 600 -- Helper function for the above
 601 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 602 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 603                            env { tcl_ctxt = upd ctxt })
 604
 605 getInstLoc :: InstOrigin -> TcM InstLoc
 606 getInstLoc origin
 607   = do { loc <- getSrcLocM ; env <- getLclEnv ;
 608          return (InstLoc origin loc (tcl_ctxt env)) }
 609
 610 addInstCtxt :: InstLoc -> TcM a -> TcM a
 611 -- Add the SrcLoc and context from the first Inst in the list
 612 --      (they all have similar locations)
 613 addInstCtxt (InstLoc _ src_loc ctxt) thing_inside
 614   = addSrcLoc src_loc (updCtxt (\ old_ctxt -> ctxt) thing_inside)
 615 \end{code}
 616
 617     The addErrTc functions add an error message, but do not cause failure.
 618     The 'M' variants pass a TidyEnv that has already been used to
 619     tidy up the message; we then use it to tidy the context messages
 620
 621 \begin{code}
 622 addErrTc :: Message -> TcM ()
 623 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 624
 625 addErrsTc :: [Message] -> TcM ()
 626 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 627
 628 addErrTcM :: (TidyEnv, Message) -> TcM ()
 629 addErrTcM (tidy_env, err_msg)
 630   = do { ctxt <- getErrCtxt ;
 631          loc  <- getSrcLocM ;
 632          add_err_tcm tidy_env err_msg loc ctxt }
 633 \end{code}
 634
 635 The failWith functions add an error message and cause failure
 636
 637 \begin{code}
 638 failWithTc :: Message -> TcM a               -- Add an error message and fail
 639 failWithTc err_msg
 640   = addErrTc err_msg >> failM
 641
 642 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 643 failWithTcM local_and_msg
 644   = addErrTcM local_and_msg >> failM
 645
 646 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 647 checkTc True  err = returnM ()
 648 checkTc False err = failWithTc err
 649 \end{code}
 650
 651         Warnings have no 'M' variant, nor failure
 652
 653 \begin{code}
 654 addWarnTc :: Message -> TcM ()
 655 addWarnTc msg
 656  = do { ctxt <- getErrCtxt ;
 657         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 658         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 659
 660 warnTc :: Bool -> Message -> TcM ()
 661 warnTc warn_if_true warn_msg
 662   | warn_if_true = addWarnTc warn_msg
 663   | otherwise    = return ()
 664 \end{code}
 665
 666         Helper functions
 667
 668 \begin{code}
 669 add_err_tcm tidy_env err_msg loc ctxt
 670  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 671         addErrAt loc (vcat (err_msg : ctxt_to_use ctxt_msgs)) }
 672
 673 do_ctxt tidy_env []
 674  = return []
 675 do_ctxt tidy_env (c:cs)
 676  = do { (tidy_env', m) <- c tidy_env  ;
 677         ms             <- do_ctxt tidy_env' cs  ;
 678         return (m:ms) }
 679
 680 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 681                  | otherwise          = take 3 ctxt
 682 \end{code}
 683
 684 %************************************************************************
 685 %*                                                                      *
 686              Other stuff specific to type checker
 687 %*                                                                      *
 688 %************************************************************************
 689
 690 \begin{code}
 691 getLIEVar :: TcM (TcRef LIE)
 692 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 693
 694 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 695 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 696
 697 getLIE :: TcM a -> TcM (a, [Inst])
 698 -- (getLIE m) runs m, and returns the type constraints it generates
 699 getLIE thing_inside
 700   = do { lie_var <- newMutVar emptyLIE ;
 701          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 702                           thing_inside ;
 703          lie <- readMutVar lie_var ;
 704          return (res, lieToList lie) }
 705
 706 extendLIE :: Inst -> TcM ()
 707 extendLIE inst
 708   = do { lie_var <- getLIEVar ;
 709          lie <- readMutVar lie_var ;
 710          writeMutVar lie_var (inst `consLIE` lie) }
 711
 712 extendLIEs :: [Inst] -> TcM ()
 713 extendLIEs []
 714   = returnM ()
 715 extendLIEs insts
 716   = do { lie_var <- getLIEVar ;
 717          lie <- readMutVar lie_var ;
 718          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 719 \end{code}
 720
 721
 722 \begin{code}
 723 getStage :: TcM Stage
 724 getStage = do { env <- getLclEnv; return (tcl_level env) }
 725
 726 setStage :: Stage -> TcM a -> TcM a
 727 setStage s = updLclEnv (\ env -> env { tcl_level = s })
 728
 729 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 730 -- Set the local type envt, but do *not* disturb other fields,
 731 -- notably the lie_var
 732 setLclTypeEnv lcl_env thing_inside
 733   = updLclEnv upd thing_inside
 734   where
 735     upd env = env { tcl_env = tcl_env lcl_env,
 736                     tcl_tyvars = tcl_tyvars lcl_env }
 737 \end{code}
 738
 739
 740 %************************************************************************
 741 %*                                                                      *
 742              Stuff for the renamer's local env
 743 %*                                                                      *
 744 %************************************************************************
 745
 746 \begin{code}
 747 initRn :: RnMode -> RnM a -> TcRn m a
 748 initRn mode thing_inside
 749  = do { env <- getGblEnv ;
 750         let { lcl_env = RnLclEnv {
 751                              rn_mode = mode,
 752                              rn_lenv = emptyRdrEnv }} ;
 753         setLclEnv lcl_env thing_inside }
 754 \end{code}
 755
 756 \begin{code}
 757 getLocalRdrEnv :: RnM LocalRdrEnv
 758 getLocalRdrEnv = do { env <- getLclEnv; return (rn_lenv env) }
 759
 760 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 761 setLocalRdrEnv rdr_env thing_inside
 762   = updLclEnv (\env -> env {rn_lenv = rdr_env}) thing_inside
 763
 764 getModeRn :: RnM RnMode
 765 getModeRn = do { env <- getLclEnv; return (rn_mode env) }
 766 \end{code}
 767