ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes
   5   ) where
   6
   7 #include "HsVersions.h"
   8
   9 import HsSyn            ( MonoBinds(..) )
  10 import HscTypes         ( HscEnv(..), PersistentCompilerState(..),
  11                           emptyFixityEnv, emptyGlobalRdrEnv, TyThing,
  12                           ExternalPackageState(..), HomePackageTable,
  13                           ModDetails(..), HomeModInfo(..), Deprecations(..),
  14                           GlobalRdrEnv, LocalRdrEnv, NameCache, FixityEnv,
  15                           GhciMode, lookupType, unQualInScope )
  16 import TcRnTypes
  17 import Module           ( Module, foldModuleEnv )
  18 import Name             ( Name, isInternalName )
  19 import Type             ( Type )
  20 import NameEnv          ( extendNameEnvList )
  21 import InstEnv          ( InstEnv, extendInstEnv )
  22 import TysWiredIn       ( integerTy, doubleTy )
  23
  24 import VarSet           ( emptyVarSet )
  25 import VarEnv           ( TidyEnv, emptyTidyEnv )
  26 import RdrName          ( emptyRdrEnv )
  27 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  28                           addShortErrLocLine, addShortWarnLocLine, printErrorsAndWarnings )
  29 import SrcLoc           ( SrcLoc, noSrcLoc )
  30 import NameEnv          ( emptyNameEnv )
  31 import Bag              ( emptyBag )
  32 import Outputable
  33 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  34 import Unique           ( Unique )
  35 import CmdLineOpts      ( DynFlags, DynFlag(..), dopt, opt_PprStyle_Debug )
  36 import BasicTypes       ( FixitySig )
  37 import Bag              ( snocBag, unionBags )
  38
  39 import Maybe            ( isJust )
  40 import IO               ( stderr )
  41 import DATA_IOREF       ( newIORef, readIORef )
  42 \end{code}
  43
  44 %************************************************************************
  45 %*                                                                      *
  46         Standard combinators, but specialised for this monad
  47                         (for efficiency)
  48 %*                                                                      *
  49 6%************************************************************************
  50
  51 \begin{code}
  52 mappM         :: (a -> TcRn m b) -> [a] -> TcRn m [b]
  53 mappM_        :: (a -> TcRn m b) -> [a] -> TcRn m ()
  54         -- Funny names to avoid clash with Prelude
  55 sequenceM     :: [TcRn m a] -> TcRn m [a]
  56 foldlM        :: (a -> b -> TcRn m a)  -> a -> [b] -> TcRn m a
  57 mapAndUnzipM  :: (a -> TcRn m (b,c))   -> [a] -> TcRn m ([b],[c])
  58 mapAndUnzip3M :: (a -> TcRn m (b,c,d)) -> [a] -> TcRn m ([b],[c],[d])
  59 checkM        :: Bool -> TcRn m () -> TcRn m () -- Perform arg if bool is False
  60 ifM           :: Bool -> TcRn m () -> TcRn m () -- Perform arg if bool is True
  61
  62 mappM f []     = return []
  63 mappM f (x:xs) = do { r <- f x; rs <- mappM f xs; return (r:rs) }
  64
  65 mappM_ f []     = return ()
  66 mappM_ f (x:xs) = f x >> mappM_ f xs
  67
  68 sequenceM [] = return []
  69 sequenceM (x:xs) = do { r <- x; rs <- sequenceM xs; return (r:rs) }
  70
  71 foldlM k z [] = return z
  72 foldlM k z (x:xs) = do { r <- k z x; foldlM k r xs }
  73
  74 mapAndUnzipM f []     = return ([],[])
  75 mapAndUnzipM f (x:xs) = do { (r,s) <- f x;
  76                              (rs,ss) <- mapAndUnzipM f xs;
  77                              return (r:rs, s:ss) }
  78
  79 mapAndUnzip3M f []     = return ([],[], [])
  80 mapAndUnzip3M f (x:xs) = do { (r,s,t) <- f x;
  81                               (rs,ss,ts) <- mapAndUnzip3M f xs;
  82                               return (r:rs, s:ss, t:ts) }
  83
  84 checkM True  err = return ()
  85 checkM False err = err
  86
  87 ifM True  do_it = do_it
  88 ifM False do_it = return ()
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94                         initTc
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 \begin{code}
  99 initTc :: HscEnv -> PersistentCompilerState
 100        -> Module
 101        -> TcM r
 102        -> IO (PersistentCompilerState, Maybe r)
 103                 -- Nothing => error thrown by the thing inside
 104                 -- (error messages should have been printed already)
 105
 106 initTc  (HscEnv { hsc_mode   = ghci_mode,
 107                   hsc_HPT    = hpt,
 108                   hsc_dflags = dflags })
 109         pcs mod do_this
 110  = do { us       <- mkSplitUniqSupply 'a' ;
 111         us_var   <- newIORef us ;
 112         errs_var <- newIORef (emptyBag, emptyBag) ;
 113         tvs_var  <- newIORef emptyVarSet ;
 114         usg_var  <- newIORef emptyUsages ;
 115         nc_var   <- newIORef (pcs_nc pcs) ;
 116         eps_var  <- newIORef eps ;
 117
 118         let {
 119              env = Env { env_top = top_env,
 120                          env_gbl = gbl_env,
 121                          env_lcl = lcl_env,
 122                          env_loc = noSrcLoc } ;
 123
 124              top_env = TopEnv {
 125                 top_mode   = ghci_mode,
 126                 top_dflags = dflags,
 127                 top_eps    = eps_var,
 128                 top_hpt    = hpt,
 129                 top_nc     = nc_var,
 130                 top_us     = us_var,
 131                 top_errs   = errs_var } ;
 132
 133              gbl_env = TcGblEnv {
 134                 tcg_mod      = mod,
 135                 tcg_usages   = usg_var,
 136                 tcg_rdr_env  = emptyGlobalRdrEnv,
 137                 tcg_fix_env  = emptyFixityEnv,
 138                 tcg_default  = defaultDefaultTys,
 139                 tcg_type_env = emptyNameEnv,
 140                 tcg_ist      = mkImpTypeEnv eps hpt,
 141                 tcg_inst_env = mkImpInstEnv dflags eps hpt,
 142                 tcg_exports  = [],
 143                 tcg_imports  = emptyImportAvails,
 144                 tcg_binds    = EmptyMonoBinds,
 145                 tcg_deprecs  = NoDeprecs,
 146                 tcg_insts    = [],
 147                 tcg_rules    = [],
 148                 tcg_fords    = [] } ;
 149
 150              lcl_env = TcLclEnv {
 151                 tcl_ctxt   = [],
 152                 tcl_level  = topStage,
 153                 tcl_env    = emptyNameEnv,
 154                 tcl_tyvars = tvs_var,
 155                 tcl_lie    = panic "initTc:LIE" } ;
 156                         -- LIE only valid inside a getLIE
 157              } ;
 158
 159         -- OK, here's the business end!
 160         maybe_res <- catch (do { res  <- runTcRn env do_this ;
 161                                  return (Just res) })
 162                            (\_ -> return Nothing) ;
 163
 164         -- Print any error messages
 165         msgs <- readIORef errs_var ;
 166         printErrorsAndWarnings msgs ;
 167
 168         -- Get final PCS and return
 169         eps' <- readIORef eps_var ;
 170         nc'  <- readIORef nc_var ;
 171         let { pcs' = PCS { pcs_EPS = eps', pcs_nc = nc' } ;
 172               final_res | errorsFound msgs = Nothing
 173                         | otherwise        = maybe_res } ;
 174
 175         return (pcs', final_res)
 176     }
 177   where
 178     eps = pcs_EPS pcs
 179
 180 defaultDefaultTys :: [Type]
 181 defaultDefaultTys = [integerTy, doubleTy]
 182
 183 mkImpInstEnv :: DynFlags -> ExternalPackageState -> HomePackageTable -> InstEnv
 184 mkImpInstEnv dflags eps hpt
 185   = foldModuleEnv (add . md_insts . hm_details)
 186                   (eps_inst_env eps)
 187                   hpt
 188   where
 189           -- We shouldn't get instance conflict errors from
 190           -- the package and home type envs
 191     add dfuns inst_env = WARN( not (null errs), vcat (map snd errs) ) inst_env'
 192                        where
 193                          (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 194
 195 -- mkImpTypeEnv makes the imported symbol table
 196 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 197              -> Name -> Maybe TyThing
 198 mkImpTypeEnv pcs hpt = lookup
 199   where
 200     pte = eps_PTE pcs
 201     lookup name | isInternalName name = Nothing
 202                 | otherwise           = lookupType hpt pte name
 203 \end{code}
 204
 205
 206 %************************************************************************
 207 %*                                                                      *
 208                 Simple accessors
 209 %*                                                                      *
 210 %************************************************************************
 211
 212 \begin{code}
 213 getTopEnv :: TcRn m TopEnv
 214 getTopEnv = do { env <- getEnv; return (env_top env) }
 215
 216 getGblEnv :: TcRn m TcGblEnv
 217 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 218
 219 updGblEnv :: (TcGblEnv -> TcGblEnv) -> TcRn m a -> TcRn m a
 220 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 221                           env { env_gbl = upd gbl })
 222
 223 setGblEnv :: TcGblEnv -> TcRn m a -> TcRn m a
 224 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 225
 226 getLclEnv :: TcRn m m
 227 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 228
 229 updLclEnv :: (m -> m) -> TcRn m a -> TcRn m a
 230 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 231                           env { env_lcl = upd lcl })
 232
 233 setLclEnv :: m -> TcRn m a -> TcRn n a
 234 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 235 \end{code}
 236
 237 Command-line flags
 238
 239 \begin{code}
 240 getDOpts :: TcRn m DynFlags
 241 getDOpts = do { env <- getTopEnv; return (top_dflags env) }
 242
 243 doptM :: DynFlag -> TcRn m Bool
 244 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 245
 246 ifOptM :: DynFlag -> TcRn m () -> TcRn m ()     -- Do it flag is true
 247 ifOptM flag thing_inside = do { b <- doptM flag;
 248                                 if b then thing_inside else return () }
 249
 250 getGhciMode :: TcRn m GhciMode
 251 getGhciMode = do { env <- getTopEnv; return (top_mode env) }
 252 \end{code}
 253
 254 \begin{code}
 255 getSrcLocM :: TcRn m SrcLoc
 256         -- Avoid clash with Name.getSrcLoc
 257 getSrcLocM = do { env <- getEnv; return (env_loc env) }
 258
 259 addSrcLoc :: SrcLoc -> TcRn m a -> TcRn m a
 260 addSrcLoc loc = updEnv (\env -> env { env_loc = loc })
 261 \end{code}
 262
 263 \begin{code}
 264 getEps :: TcRn m ExternalPackageState
 265 getEps = do { env <- getTopEnv; readMutVar (top_eps env) }
 266
 267 setEps :: ExternalPackageState -> TcRn m ()
 268 setEps eps = do { env <- getTopEnv; writeMutVar (top_eps env) eps }
 269
 270 getHpt :: TcRn m HomePackageTable
 271 getHpt = do { env <- getTopEnv; return (top_hpt env) }
 272
 273 getModule :: TcRn m Module
 274 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 275
 276 getGlobalRdrEnv :: TcRn m GlobalRdrEnv
 277 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 278
 279 getFixityEnv :: TcRn m FixityEnv
 280 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 281
 282 extendFixityEnv :: [(Name,FixitySig Name)] -> RnM a -> RnM a
 283 extendFixityEnv new_bit
 284   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 285                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 286
 287 getDefaultTys :: TcRn m [Type]
 288 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 289 \end{code}
 290
 291 \begin{code}
 292 getUsageVar :: TcRn m (TcRef Usages)
 293 getUsageVar = do { env <- getGblEnv; return (tcg_usages env) }
 294
 295 getUsages :: TcRn m Usages
 296 getUsages = do { usg_var <- getUsageVar; readMutVar usg_var }
 297
 298 updUsages :: (Usages -> Usages) -> TcRn m ()
 299 updUsages upd = do { usg_var <- getUsageVar ;
 300                      usg <- readMutVar usg_var ;
 301                      writeMutVar usg_var (upd usg) }
 302 \end{code}
 303
 304
 305 %************************************************************************
 306 %*                                                                      *
 307                 Error management
 308 %*                                                                      *
 309 %************************************************************************
 310
 311 \begin{code}
 312 getErrsVar :: TcRn m (TcRef Messages)
 313 getErrsVar = do { env <- getTopEnv; return (top_errs env) }
 314
 315 setErrsVar :: TcRef Messages -> TcRn m a -> TcRn m a
 316 setErrsVar v = updEnv (\ env@(Env { env_top = top_env }) ->
 317                          env { env_top = top_env { top_errs = v }})
 318
 319 addErr :: Message -> TcRn m ()
 320 addErr msg = do { loc <- getSrcLocM ; addErrAt loc msg }
 321
 322 addErrAt :: SrcLoc -> Message -> TcRn m ()
 323 addErrAt loc msg
 324  = do {  errs_var <- getErrsVar ;
 325          rdr_env <- getGlobalRdrEnv ;
 326          let { err = addShortErrLocLine loc (unQualInScope rdr_env) msg } ;
 327          (warns, errs) <- readMutVar errs_var ;
 328          writeMutVar errs_var (warns, errs `snocBag` err) }
 329
 330 addErrs :: [(SrcLoc,Message)] -> TcRn m ()
 331 addErrs msgs = mappM_ add msgs
 332              where
 333                add (loc,msg) = addErrAt loc msg
 334
 335 addWarn :: Message -> TcRn m ()
 336 addWarn msg
 337   = do { errs_var <- getErrsVar ;
 338          loc <- getSrcLocM ;
 339          rdr_env <- getGlobalRdrEnv ;
 340          let { warn = addShortWarnLocLine loc (unQualInScope rdr_env) msg } ;
 341          (warns, errs) <- readMutVar errs_var ;
 342          writeMutVar errs_var (warns `snocBag` warn, errs) }
 343
 344 checkErr :: Bool -> Message -> TcRn m ()
 345 -- Add the error if the bool is False
 346 checkErr ok msg = checkM ok (addErr msg)
 347
 348 warnIf :: Bool -> Message -> TcRn m ()
 349 warnIf True  msg = addWarn msg
 350 warnIf False msg = return ()
 351
 352 addMessages :: Messages -> TcRn m ()
 353 addMessages (m_warns, m_errs)
 354   = do { errs_var <- getErrsVar ;
 355          (warns, errs) <- readMutVar errs_var ;
 356          writeMutVar errs_var (warns `unionBags` m_warns,
 357                                errs  `unionBags` m_errs) }
 358
 359 checkGHCI :: Message -> TcRn m ()       -- Check that GHCI is on
 360                                         -- otherwise add the error message
 361 #ifdef GHCI
 362 checkGHCI m = returnM ()
 363 #else
 364 checkGHCI m = addErr m
 365 #endif
 366 \end{code}
 367
 368
 369 \begin{code}
 370 recoverM :: TcRn m r    -- Recovery action; do this if the main one fails
 371          -> TcRn m r    -- Main action: do this first
 372          -> TcRn m r
 373 recoverM recover thing
 374   = do { mb_res <- tryM thing ;
 375          case mb_res of
 376            Left exn  -> recover
 377            Right res -> returnM res }
 378
 379 tryTc :: TcRn m a -> TcRn m (Messages, Maybe a)
 380     -- (tryTc m) executes m, and returns
 381     --  Just r,  if m succeeds (returning r) and caused no errors
 382     --  Nothing, if m fails, or caused errors
 383     -- It also returns all the errors accumulated by m
 384     --  (even in the Just case, there might be warnings)
 385     --
 386     -- It always succeeds (never raises an exception)
 387 tryTc m
 388  = do { errs_var <- newMutVar emptyMessages ;
 389
 390         mb_r <- tryM (setErrsVar errs_var m) ;
 391
 392         new_errs <- readMutVar errs_var ;
 393
 394         return (new_errs,
 395                 case mb_r of
 396                   Left exn                       -> Nothing
 397                   Right r | errorsFound new_errs -> Nothing
 398                           | otherwise            -> Just r)
 399    }
 400
 401 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 402 -- Just like tryTc, except that it ensures that the LIE
 403 -- for the thing is propagated only if there are no errors
 404 -- Hence it's restricted to the type-check monad
 405 tryTcLIE thing_inside
 406   = do { ((errs, mb_r), lie) <- getLIE (tryTc thing_inside) ;
 407          ifM (isJust mb_r) (extendLIEs lie) ;
 408          return (errs, mb_r) }
 409
 410 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 411 -- (tryM_ r m) tries m; if it succeeds it returns it,
 412 -- otherwise it returns r.  Any error messages added by m are discarded,
 413 -- whether or not m succeeds.
 414 tryTcLIE_ recover main
 415   = do { (_msgs, mb_res) <- tryTcLIE main ;
 416          case mb_res of
 417            Just res -> return res
 418            Nothing  -> recover }
 419
 420 checkNoErrs :: TcM r -> TcM r
 421 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 422 -- If m fails then (checkNoErrsTc m) fails.
 423 -- If m succeeds, it checks whether m generated any errors messages
 424 --      (it might have recovered internally)
 425 --      If so, it fails too.
 426 -- Regardless, any errors generated by m are propagated to the enclosing context.
 427 checkNoErrs main
 428   = do { (msgs, mb_res) <- tryTcLIE main ;
 429          addMessages msgs ;
 430          case mb_res of
 431            Just r  -> return r
 432            Nothing -> failM
 433    }
 434
 435 ifErrsM :: TcRn m r -> TcRn m r -> TcRn m r
 436 --      ifErrsM bale_out main
 437 -- does 'bale_out' if there are errors in errors collection
 438 -- otherwise does 'main'
 439 ifErrsM bale_out normal
 440  = do { errs_var <- getErrsVar ;
 441         msgs <- readMutVar errs_var ;
 442         if errorsFound msgs then
 443            bale_out
 444         else
 445            normal }
 446
 447 failIfErrsM :: TcRn m ()
 448 -- Useful to avoid error cascades
 449 failIfErrsM = ifErrsM failM (return ())
 450 \end{code}
 451
 452 \begin{code}
 453 forkM :: SDoc -> TcM a -> TcM (Maybe a)
 454 -- Run thing_inside in an interleaved thread.  It gets a separate
 455 --      * errs_var, and
 456 --      * unique supply,
 457 -- but everything else is shared, so this is DANGEROUS.
 458 --
 459 -- It returns Nothing if the computation fails
 460 --
 461 -- It's used for lazily type-checking interface
 462 -- signatures, which is pretty benign
 463
 464 forkM doc thing_inside
 465  = do { us <- newUniqueSupply ;
 466         unsafeInterleaveM $
 467         do { us_var <- newMutVar us ;
 468              (msgs, mb_res) <- tryTcLIE (setUsVar us_var thing_inside) ;
 469              case mb_res of
 470                 Just r  -> return (Just r)
 471                 Nothing -> do {
 472                     -- Bleat about errors in the forked thread
 473                     ioToTcRn (do { printErrs (hdr_doc defaultErrStyle) ;
 474                                    printErrorsAndWarnings msgs }) ;
 475                     return Nothing }
 476         }}
 477   where
 478     hdr_doc = text "forkM failed:" <+> doc
 479 \end{code}
 480
 481
 482 %************************************************************************
 483 %*                                                                      *
 484                 Unique supply
 485 %*                                                                      *
 486 %************************************************************************
 487
 488 \begin{code}
 489 getUsVar :: TcRn m (TcRef UniqSupply)
 490 getUsVar = do { env <- getTopEnv; return (top_us env) }
 491
 492 setUsVar :: TcRef UniqSupply -> TcRn m a -> TcRn m a
 493 setUsVar v = updEnv (\ env@(Env { env_top = top_env }) ->
 494                        env { env_top = top_env { top_us = v }})
 495
 496 newUnique :: TcRn m Unique
 497 newUnique = do { us <- newUniqueSupply ;
 498                  return (uniqFromSupply us) }
 499
 500 newUniqueSupply :: TcRn m UniqSupply
 501 newUniqueSupply
 502  = do { u_var <- getUsVar ;
 503         us <- readMutVar u_var ;
 504         let { (us1, us2) = splitUniqSupply us } ;
 505         writeMutVar u_var us1 ;
 506         return us2 }
 507 \end{code}
 508
 509
 510 \begin{code}
 511 getNameCache :: TcRn m NameCache
 512 getNameCache = do { TopEnv { top_nc = nc_var } <- getTopEnv;
 513                     readMutVar nc_var }
 514
 515 setNameCache :: NameCache -> TcRn m ()
 516 setNameCache nc = do { TopEnv { top_nc = nc_var } <- getTopEnv;
 517                        writeMutVar nc_var nc }
 518 \end{code}
 519
 520
 521 %************************************************************************
 522 %*                                                                      *
 523                 Debugging
 524 %*                                                                      *
 525 %************************************************************************
 526
 527 \begin{code}
 528 traceTc, traceRn :: SDoc -> TcRn a ()
 529 traceRn      = dumpOptTcRn Opt_D_dump_rn_trace
 530 traceTc      = dumpOptTcRn Opt_D_dump_tc_trace
 531 traceSplice  = dumpOptTcRn Opt_D_dump_splices
 532 traceHiDiffs = dumpOptTcRn Opt_D_dump_hi_diffs
 533
 534 dumpOptTcRn :: DynFlag -> SDoc -> TcRn a ()
 535 dumpOptTcRn flag doc = ifOptM flag (dumpTcRn doc)
 536
 537 dumpTcRn :: SDoc -> TcRn a ()
 538 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 539                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 540 \end{code}
 541
 542
 543 %************************************************************************
 544 %*                                                                      *
 545         Context management and error message generation
 546                     for the type checker
 547 %*                                                                      *
 548 %************************************************************************
 549
 550 \begin{code}
 551 setErrCtxtM, addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 552 setErrCtxtM msg = updCtxt (\ msgs -> [msg])
 553 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 554
 555 setErrCtxt, addErrCtxt :: Message -> TcM a -> TcM a
 556 setErrCtxt msg = setErrCtxtM (\env -> returnM (env, msg))
 557 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 558
 559 popErrCtxt :: TcM a -> TcM a
 560 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 561
 562 getErrCtxt :: TcM ErrCtxt
 563 getErrCtxt = do { env <- getLclEnv ; return (tcl_ctxt env) }
 564
 565 -- Helper function for the above
 566 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 567 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 568                            env { tcl_ctxt = upd ctxt })
 569
 570 getInstLoc :: InstOrigin -> TcM InstLoc
 571 getInstLoc origin
 572   = do { loc <- getSrcLocM ; env <- getLclEnv ;
 573          return (origin, loc, (tcl_ctxt env)) }
 574 \end{code}
 575
 576     The addErrTc functions add an error message, but do not cause failure.
 577     The 'M' variants pass a TidyEnv that has already been used to
 578     tidy up the message; we then use it to tidy the context messages
 579
 580 \begin{code}
 581 addErrTc :: Message -> TcM ()
 582 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 583
 584 addErrsTc :: [Message] -> TcM ()
 585 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 586
 587 addErrTcM :: (TidyEnv, Message) -> TcM ()
 588 addErrTcM (tidy_env, err_msg)
 589   = do { ctxt <- getErrCtxt ;
 590          loc  <- getSrcLocM ;
 591          add_err_tcm tidy_env err_msg loc ctxt }
 592
 593 addInstErrTcM :: InstLoc -> (TidyEnv, Message) -> TcM ()
 594 addInstErrTcM inst_loc@(_, loc, ctxt) (tidy_env, err_msg)
 595   = add_err_tcm tidy_env err_msg loc full_ctxt
 596   where
 597     full_ctxt = (\env -> returnM (env, pprInstLoc inst_loc)) : ctxt
 598 \end{code}
 599
 600 The failWith functions add an error message and cause failure
 601
 602 \begin{code}
 603 failWithTc :: Message -> TcM a               -- Add an error message and fail
 604 failWithTc err_msg
 605   = addErrTc err_msg >> failM
 606
 607 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 608 failWithTcM local_and_msg
 609   = addErrTcM local_and_msg >> failM
 610
 611 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 612 checkTc True  err = returnM ()
 613 checkTc False err = failWithTc err
 614 \end{code}
 615
 616         Warnings have no 'M' variant, nor failure
 617
 618 \begin{code}
 619 addWarnTc :: Message -> TcM ()
 620 addWarnTc msg
 621  = do { ctxt <- getErrCtxt ;
 622         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 623         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 624
 625 warnTc :: Bool -> Message -> TcM ()
 626 warnTc warn_if_true warn_msg
 627   | warn_if_true = addWarnTc warn_msg
 628   | otherwise    = return ()
 629 \end{code}
 630
 631         Helper functions
 632
 633 \begin{code}
 634 add_err_tcm tidy_env err_msg loc ctxt
 635  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 636         addErrAt loc (vcat (err_msg : ctxt_to_use ctxt_msgs)) }
 637
 638 do_ctxt tidy_env []
 639  = return []
 640 do_ctxt tidy_env (c:cs)
 641  = do { (tidy_env', m) <- c tidy_env  ;
 642         ms             <- do_ctxt tidy_env' cs  ;
 643         return (m:ms) }
 644
 645 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 646                  | otherwise          = take 3 ctxt
 647 \end{code}
 648
 649 %************************************************************************
 650 %*                                                                      *
 651              Other stuff specific to type checker
 652 %*                                                                      *
 653 %************************************************************************
 654
 655 \begin{code}
 656 getLIEVar :: TcM (TcRef LIE)
 657 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 658
 659 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 660 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 661
 662 getLIE :: TcM a -> TcM (a, [Inst])
 663 -- (getLIE m) runs m, and returns the type constraints it generates
 664 getLIE thing_inside
 665   = do { lie_var <- newMutVar emptyLIE ;
 666          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 667                           thing_inside ;
 668          lie <- readMutVar lie_var ;
 669          return (res, lieToList lie) }
 670
 671 extendLIE :: Inst -> TcM ()
 672 extendLIE inst
 673   = do { lie_var <- getLIEVar ;
 674          lie <- readMutVar lie_var ;
 675          writeMutVar lie_var (inst `consLIE` lie) }
 676
 677 extendLIEs :: [Inst] -> TcM ()
 678 extendLIEs []
 679   = returnM ()
 680 extendLIEs insts
 681   = do { lie_var <- getLIEVar ;
 682          lie <- readMutVar lie_var ;
 683          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 684 \end{code}
 685
 686
 687 \begin{code}
 688 getStage :: TcM Stage
 689 getStage = do { env <- getLclEnv; return (tcl_level env) }
 690
 691 setStage :: Stage -> TcM a -> TcM a
 692 setStage s = updLclEnv (\ env -> env { tcl_level = s })
 693
 694 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 695 -- Set the local type envt, but do *not* disturb other fields,
 696 -- notably the lie_var
 697 setLclTypeEnv lcl_env thing_inside
 698   = updLclEnv upd thing_inside
 699   where
 700     upd env = env { tcl_env = tcl_env lcl_env,
 701                     tcl_tyvars = tcl_tyvars lcl_env }
 702 \end{code}
 703
 704
 705 %************************************************************************
 706 %*                                                                      *
 707              Stuff for the renamer's local env
 708 %*                                                                      *
 709 %************************************************************************
 710
 711 \begin{code}
 712 initRn :: RnMode -> RnM a -> TcRn m a
 713 initRn mode thing_inside
 714  = do { env <- getGblEnv ;
 715         let { lcl_env = RnLclEnv {
 716                              rn_mode = mode,
 717                              rn_lenv = emptyRdrEnv }} ;
 718         setLclEnv lcl_env thing_inside }
 719 \end{code}
 720
 721 \begin{code}
 722 getLocalRdrEnv :: RnM LocalRdrEnv
 723 getLocalRdrEnv = do { env <- getLclEnv; return (rn_lenv env) }
 724
 725 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 726 setLocalRdrEnv rdr_env thing_inside
 727   = updLclEnv (\env -> env {rn_lenv = rdr_env}) thing_inside
 728
 729 getModeRn :: RnM RnMode
 730 getModeRn = do { env <- getLclEnv; return (rn_mode env) }
 731 \end{code}
 732