ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes
   5   ) where
   6
   7 #include "HsVersions.h"
   8
   9 import HsSyn            ( MonoBinds(..) )
  10 import HscTypes         ( HscEnv(..), PersistentCompilerState(..),
  11                           emptyFixityEnv, emptyGlobalRdrEnv, TyThing,
  12                           ExternalPackageState(..), HomePackageTable,
  13                           ModDetails(..), HomeModInfo(..), Deprecations(..),
  14                           GlobalRdrEnv, LocalRdrEnv, NameCache, FixityEnv,
  15                           GhciMode, lookupType, unQualInScope )
  16 import TcRnTypes
  17 import Module           ( Module, moduleName, foldModuleEnv )
  18 import Name             ( Name, isInternalName )
  19 import Type             ( Type )
  20 import NameEnv          ( extendNameEnvList )
  21 import InstEnv          ( InstEnv, extendInstEnv )
  22 import TysWiredIn       ( integerTy, doubleTy )
  23
  24 import VarSet           ( emptyVarSet )
  25 import VarEnv           ( TidyEnv, emptyTidyEnv )
  26 import RdrName          ( emptyRdrEnv )
  27 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  28                           addShortErrLocLine, addShortWarnLocLine, printErrorsAndWarnings )
  29 import SrcLoc           ( SrcLoc, noSrcLoc )
  30 import NameEnv          ( emptyNameEnv )
  31 import Bag              ( emptyBag )
  32 import Outputable
  33 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  34 import Unique           ( Unique )
  35 import CmdLineOpts      ( DynFlags, DynFlag(..), dopt, opt_PprStyle_Debug )
  36 import BasicTypes       ( FixitySig )
  37 import Bag              ( snocBag, unionBags )
  38
  39 import Maybe            ( isJust )
  40 import IO               ( stderr )
  41 import DATA_IOREF       ( newIORef, readIORef )
  42 \end{code}
  43
  44 %************************************************************************
  45 %*                                                                      *
  46         Standard combinators, but specialised for this monad
  47                         (for efficiency)
  48 %*                                                                      *
  49 6%************************************************************************
  50
  51 \begin{code}
  52 mappM         :: (a -> TcRn m b) -> [a] -> TcRn m [b]
  53 mappM_        :: (a -> TcRn m b) -> [a] -> TcRn m ()
  54         -- Funny names to avoid clash with Prelude
  55 sequenceM     :: [TcRn m a] -> TcRn m [a]
  56 foldlM        :: (a -> b -> TcRn m a)  -> a -> [b] -> TcRn m a
  57 mapAndUnzipM  :: (a -> TcRn m (b,c))   -> [a] -> TcRn m ([b],[c])
  58 mapAndUnzip3M :: (a -> TcRn m (b,c,d)) -> [a] -> TcRn m ([b],[c],[d])
  59 checkM        :: Bool -> TcRn m () -> TcRn m () -- Perform arg if bool is False
  60 ifM           :: Bool -> TcRn m () -> TcRn m () -- Perform arg if bool is True
  61
  62 mappM f []     = return []
  63 mappM f (x:xs) = do { r <- f x; rs <- mappM f xs; return (r:rs) }
  64
  65 mappM_ f []     = return ()
  66 mappM_ f (x:xs) = f x >> mappM_ f xs
  67
  68 sequenceM [] = return []
  69 sequenceM (x:xs) = do { r <- x; rs <- sequenceM xs; return (r:rs) }
  70
  71 foldlM k z [] = return z
  72 foldlM k z (x:xs) = do { r <- k z x; foldlM k r xs }
  73
  74 mapAndUnzipM f []     = return ([],[])
  75 mapAndUnzipM f (x:xs) = do { (r,s) <- f x;
  76                              (rs,ss) <- mapAndUnzipM f xs;
  77                              return (r:rs, s:ss) }
  78
  79 mapAndUnzip3M f []     = return ([],[], [])
  80 mapAndUnzip3M f (x:xs) = do { (r,s,t) <- f x;
  81                               (rs,ss,ts) <- mapAndUnzip3M f xs;
  82                               return (r:rs, s:ss, t:ts) }
  83
  84 checkM True  err = return ()
  85 checkM False err = err
  86
  87 ifM True  do_it = do_it
  88 ifM False do_it = return ()
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94                         initTc
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 \begin{code}
  99 initTc :: HscEnv -> PersistentCompilerState
 100        -> Module
 101        -> TcM r
 102        -> IO (PersistentCompilerState, Maybe r)
 103                 -- Nothing => error thrown by the thing inside
 104                 -- (error messages should have been printed already)
 105
 106 initTc  (HscEnv { hsc_mode   = ghci_mode,
 107                   hsc_HPT    = hpt,
 108                   hsc_dflags = dflags })
 109         pcs mod do_this
 110  = do { us       <- mkSplitUniqSupply 'a' ;
 111         us_var   <- newIORef us ;
 112         errs_var <- newIORef (emptyBag, emptyBag) ;
 113         tvs_var  <- newIORef emptyVarSet ;
 114         usg_var  <- newIORef emptyUsages ;
 115         nc_var   <- newIORef (pcs_nc pcs) ;
 116         eps_var  <- newIORef eps ;
 117
 118         let {
 119              env = Env { env_top = top_env,
 120                          env_gbl = gbl_env,
 121                          env_lcl = lcl_env,
 122                          env_loc = noSrcLoc } ;
 123
 124              top_env = TopEnv {
 125                 top_mode   = ghci_mode,
 126                 top_dflags = dflags,
 127                 top_eps    = eps_var,
 128                 top_hpt    = hpt,
 129                 top_nc     = nc_var,
 130                 top_us     = us_var,
 131                 top_errs   = errs_var } ;
 132
 133              gbl_env = TcGblEnv {
 134                 tcg_mod      = mod,
 135                 tcg_usages   = usg_var,
 136                 tcg_rdr_env  = emptyGlobalRdrEnv,
 137                 tcg_fix_env  = emptyFixityEnv,
 138                 tcg_default  = defaultDefaultTys,
 139                 tcg_type_env = emptyNameEnv,
 140                 tcg_ist      = mkImpTypeEnv eps hpt,
 141                 tcg_inst_env = mkImpInstEnv dflags eps hpt,
 142                 tcg_exports  = [],
 143                 tcg_imports  = init_imports,
 144                 tcg_binds    = EmptyMonoBinds,
 145                 tcg_deprecs  = NoDeprecs,
 146                 tcg_insts    = [],
 147                 tcg_rules    = [],
 148                 tcg_fords    = [] } ;
 149
 150              lcl_env = TcLclEnv {
 151                 tcl_ctxt   = [],
 152                 tcl_level  = topStage,
 153                 tcl_env    = emptyNameEnv,
 154                 tcl_tyvars = tvs_var,
 155                 tcl_lie    = panic "initTc:LIE" } ;
 156                         -- LIE only valid inside a getLIE
 157              } ;
 158
 159         -- OK, here's the business end!
 160         maybe_res <- catch (do { res  <- runTcRn env do_this ;
 161                                  return (Just res) })
 162                            (\_ -> return Nothing) ;
 163
 164         -- Print any error messages
 165         msgs <- readIORef errs_var ;
 166         printErrorsAndWarnings msgs ;
 167
 168         -- Get final PCS and return
 169         eps' <- readIORef eps_var ;
 170         nc'  <- readIORef nc_var ;
 171         let { pcs' = PCS { pcs_EPS = eps', pcs_nc = nc' } ;
 172               final_res | errorsFound msgs = Nothing
 173                         | otherwise        = maybe_res } ;
 174
 175         return (pcs', final_res)
 176     }
 177   where
 178     eps = pcs_EPS pcs
 179
 180     init_imports = mkImportAvails (moduleName mod) True []
 181         -- Initialise tcg_imports with an empty set of bindings for
 182         -- this module, so that if we see 'module M' in the export
 183         -- list, and there are no bindings in M, we don't bleat
 184         -- "unknown module M".
 185
 186
 187 defaultDefaultTys :: [Type]
 188 defaultDefaultTys = [integerTy, doubleTy]
 189
 190 mkImpInstEnv :: DynFlags -> ExternalPackageState -> HomePackageTable -> InstEnv
 191 mkImpInstEnv dflags eps hpt
 192   = foldModuleEnv (add . md_insts . hm_details)
 193                   (eps_inst_env eps)
 194                   hpt
 195   where
 196           -- We shouldn't get instance conflict errors from
 197           -- the package and home type envs
 198     add dfuns inst_env = WARN( not (null errs), vcat (map snd errs) ) inst_env'
 199                        where
 200                          (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 201
 202 -- mkImpTypeEnv makes the imported symbol table
 203 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 204              -> Name -> Maybe TyThing
 205 mkImpTypeEnv pcs hpt = lookup
 206   where
 207     pte = eps_PTE pcs
 208     lookup name | isInternalName name = Nothing
 209                 | otherwise           = lookupType hpt pte name
 210 \end{code}
 211
 212
 213 %************************************************************************
 214 %*                                                                      *
 215                 Simple accessors
 216 %*                                                                      *
 217 %************************************************************************
 218
 219 \begin{code}
 220 getTopEnv :: TcRn m TopEnv
 221 getTopEnv = do { env <- getEnv; return (env_top env) }
 222
 223 getGblEnv :: TcRn m TcGblEnv
 224 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 225
 226 updGblEnv :: (TcGblEnv -> TcGblEnv) -> TcRn m a -> TcRn m a
 227 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 228                           env { env_gbl = upd gbl })
 229
 230 setGblEnv :: TcGblEnv -> TcRn m a -> TcRn m a
 231 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 232
 233 getLclEnv :: TcRn m m
 234 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 235
 236 updLclEnv :: (m -> m) -> TcRn m a -> TcRn m a
 237 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 238                           env { env_lcl = upd lcl })
 239
 240 setLclEnv :: m -> TcRn m a -> TcRn n a
 241 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 242 \end{code}
 243
 244 Command-line flags
 245
 246 \begin{code}
 247 getDOpts :: TcRn m DynFlags
 248 getDOpts = do { env <- getTopEnv; return (top_dflags env) }
 249
 250 doptM :: DynFlag -> TcRn m Bool
 251 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 252
 253 ifOptM :: DynFlag -> TcRn m () -> TcRn m ()     -- Do it flag is true
 254 ifOptM flag thing_inside = do { b <- doptM flag;
 255                                 if b then thing_inside else return () }
 256
 257 getGhciMode :: TcRn m GhciMode
 258 getGhciMode = do { env <- getTopEnv; return (top_mode env) }
 259 \end{code}
 260
 261 \begin{code}
 262 getSrcLocM :: TcRn m SrcLoc
 263         -- Avoid clash with Name.getSrcLoc
 264 getSrcLocM = do { env <- getEnv; return (env_loc env) }
 265
 266 addSrcLoc :: SrcLoc -> TcRn m a -> TcRn m a
 267 addSrcLoc loc = updEnv (\env -> env { env_loc = loc })
 268 \end{code}
 269
 270 \begin{code}
 271 getEps :: TcRn m ExternalPackageState
 272 getEps = do { env <- getTopEnv; readMutVar (top_eps env) }
 273
 274 setEps :: ExternalPackageState -> TcRn m ()
 275 setEps eps = do { env <- getTopEnv; writeMutVar (top_eps env) eps }
 276
 277 getHpt :: TcRn m HomePackageTable
 278 getHpt = do { env <- getTopEnv; return (top_hpt env) }
 279
 280 getModule :: TcRn m Module
 281 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 282
 283 getGlobalRdrEnv :: TcRn m GlobalRdrEnv
 284 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 285
 286 getFixityEnv :: TcRn m FixityEnv
 287 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 288
 289 extendFixityEnv :: [(Name,FixitySig Name)] -> RnM a -> RnM a
 290 extendFixityEnv new_bit
 291   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 292                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 293
 294 getDefaultTys :: TcRn m [Type]
 295 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 296 \end{code}
 297
 298 \begin{code}
 299 getUsageVar :: TcRn m (TcRef Usages)
 300 getUsageVar = do { env <- getGblEnv; return (tcg_usages env) }
 301
 302 getUsages :: TcRn m Usages
 303 getUsages = do { usg_var <- getUsageVar; readMutVar usg_var }
 304
 305 updUsages :: (Usages -> Usages) -> TcRn m ()
 306 updUsages upd = do { usg_var <- getUsageVar ;
 307                      usg <- readMutVar usg_var ;
 308                      writeMutVar usg_var (upd usg) }
 309 \end{code}
 310
 311
 312 %************************************************************************
 313 %*                                                                      *
 314                 Error management
 315 %*                                                                      *
 316 %************************************************************************
 317
 318 \begin{code}
 319 getErrsVar :: TcRn m (TcRef Messages)
 320 getErrsVar = do { env <- getTopEnv; return (top_errs env) }
 321
 322 setErrsVar :: TcRef Messages -> TcRn m a -> TcRn m a
 323 setErrsVar v = updEnv (\ env@(Env { env_top = top_env }) ->
 324                          env { env_top = top_env { top_errs = v }})
 325
 326 addErr :: Message -> TcRn m ()
 327 addErr msg = do { loc <- getSrcLocM ; addErrAt loc msg }
 328
 329 addErrAt :: SrcLoc -> Message -> TcRn m ()
 330 addErrAt loc msg
 331  = do {  errs_var <- getErrsVar ;
 332          rdr_env <- getGlobalRdrEnv ;
 333          let { err = addShortErrLocLine loc (unQualInScope rdr_env) msg } ;
 334          (warns, errs) <- readMutVar errs_var ;
 335          writeMutVar errs_var (warns, errs `snocBag` err) }
 336
 337 addErrs :: [(SrcLoc,Message)] -> TcRn m ()
 338 addErrs msgs = mappM_ add msgs
 339              where
 340                add (loc,msg) = addErrAt loc msg
 341
 342 addWarn :: Message -> TcRn m ()
 343 addWarn msg
 344   = do { errs_var <- getErrsVar ;
 345          loc <- getSrcLocM ;
 346          rdr_env <- getGlobalRdrEnv ;
 347          let { warn = addShortWarnLocLine loc (unQualInScope rdr_env) msg } ;
 348          (warns, errs) <- readMutVar errs_var ;
 349          writeMutVar errs_var (warns `snocBag` warn, errs) }
 350
 351 checkErr :: Bool -> Message -> TcRn m ()
 352 -- Add the error if the bool is False
 353 checkErr ok msg = checkM ok (addErr msg)
 354
 355 warnIf :: Bool -> Message -> TcRn m ()
 356 warnIf True  msg = addWarn msg
 357 warnIf False msg = return ()
 358
 359 addMessages :: Messages -> TcRn m ()
 360 addMessages (m_warns, m_errs)
 361   = do { errs_var <- getErrsVar ;
 362          (warns, errs) <- readMutVar errs_var ;
 363          writeMutVar errs_var (warns `unionBags` m_warns,
 364                                errs  `unionBags` m_errs) }
 365
 366 checkGHCI :: Message -> TcRn m ()       -- Check that GHCI is on
 367                                         -- otherwise add the error message
 368 #ifdef GHCI
 369 checkGHCI m = returnM ()
 370 #else
 371 checkGHCI m = addErr m
 372 #endif
 373 \end{code}
 374
 375
 376 \begin{code}
 377 recoverM :: TcRn m r    -- Recovery action; do this if the main one fails
 378          -> TcRn m r    -- Main action: do this first
 379          -> TcRn m r
 380 recoverM recover thing
 381   = do { mb_res <- tryM thing ;
 382          case mb_res of
 383            Left exn  -> recover
 384            Right res -> returnM res }
 385
 386 tryTc :: TcRn m a -> TcRn m (Messages, Maybe a)
 387     -- (tryTc m) executes m, and returns
 388     --  Just r,  if m succeeds (returning r) and caused no errors
 389     --  Nothing, if m fails, or caused errors
 390     -- It also returns all the errors accumulated by m
 391     --  (even in the Just case, there might be warnings)
 392     --
 393     -- It always succeeds (never raises an exception)
 394 tryTc m
 395  = do { errs_var <- newMutVar emptyMessages ;
 396
 397         mb_r <- tryM (setErrsVar errs_var m) ;
 398
 399         new_errs <- readMutVar errs_var ;
 400
 401         return (new_errs,
 402                 case mb_r of
 403                   Left exn                       -> Nothing
 404                   Right r | errorsFound new_errs -> Nothing
 405                           | otherwise            -> Just r)
 406    }
 407
 408 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 409 -- Just like tryTc, except that it ensures that the LIE
 410 -- for the thing is propagated only if there are no errors
 411 -- Hence it's restricted to the type-check monad
 412 tryTcLIE thing_inside
 413   = do { ((errs, mb_r), lie) <- getLIE (tryTc thing_inside) ;
 414          ifM (isJust mb_r) (extendLIEs lie) ;
 415          return (errs, mb_r) }
 416
 417 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 418 -- (tryM_ r m) tries m; if it succeeds it returns it,
 419 -- otherwise it returns r.  Any error messages added by m are discarded,
 420 -- whether or not m succeeds.
 421 tryTcLIE_ recover main
 422   = do { (_msgs, mb_res) <- tryTcLIE main ;
 423          case mb_res of
 424            Just res -> return res
 425            Nothing  -> recover }
 426
 427 checkNoErrs :: TcM r -> TcM r
 428 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 429 -- If m fails then (checkNoErrsTc m) fails.
 430 -- If m succeeds, it checks whether m generated any errors messages
 431 --      (it might have recovered internally)
 432 --      If so, it fails too.
 433 -- Regardless, any errors generated by m are propagated to the enclosing context.
 434 checkNoErrs main
 435   = do { (msgs, mb_res) <- tryTcLIE main ;
 436          addMessages msgs ;
 437          case mb_res of
 438            Just r  -> return r
 439            Nothing -> failM
 440    }
 441
 442 ifErrsM :: TcRn m r -> TcRn m r -> TcRn m r
 443 --      ifErrsM bale_out main
 444 -- does 'bale_out' if there are errors in errors collection
 445 -- otherwise does 'main'
 446 ifErrsM bale_out normal
 447  = do { errs_var <- getErrsVar ;
 448         msgs <- readMutVar errs_var ;
 449         if errorsFound msgs then
 450            bale_out
 451         else
 452            normal }
 453
 454 failIfErrsM :: TcRn m ()
 455 -- Useful to avoid error cascades
 456 failIfErrsM = ifErrsM failM (return ())
 457 \end{code}
 458
 459 \begin{code}
 460 forkM :: SDoc -> TcM a -> TcM (Maybe a)
 461 -- Run thing_inside in an interleaved thread.  It gets a separate
 462 --      * errs_var, and
 463 --      * unique supply,
 464 -- but everything else is shared, so this is DANGEROUS.
 465 --
 466 -- It returns Nothing if the computation fails
 467 --
 468 -- It's used for lazily type-checking interface
 469 -- signatures, which is pretty benign
 470
 471 forkM doc thing_inside
 472  = do { us <- newUniqueSupply ;
 473         unsafeInterleaveM $
 474         do { us_var <- newMutVar us ;
 475              (msgs, mb_res) <- tryTcLIE (setUsVar us_var thing_inside) ;
 476              case mb_res of
 477                 Just r  -> return (Just r)
 478                 Nothing -> do {
 479                     -- Bleat about errors in the forked thread
 480                     ioToTcRn (do { printErrs (hdr_doc defaultErrStyle) ;
 481                                    printErrorsAndWarnings msgs }) ;
 482                     return Nothing }
 483         }}
 484   where
 485     hdr_doc = text "forkM failed:" <+> doc
 486 \end{code}
 487
 488
 489 %************************************************************************
 490 %*                                                                      *
 491                 Unique supply
 492 %*                                                                      *
 493 %************************************************************************
 494
 495 \begin{code}
 496 getUsVar :: TcRn m (TcRef UniqSupply)
 497 getUsVar = do { env <- getTopEnv; return (top_us env) }
 498
 499 setUsVar :: TcRef UniqSupply -> TcRn m a -> TcRn m a
 500 setUsVar v = updEnv (\ env@(Env { env_top = top_env }) ->
 501                        env { env_top = top_env { top_us = v }})
 502
 503 newUnique :: TcRn m Unique
 504 newUnique = do { us <- newUniqueSupply ;
 505                  return (uniqFromSupply us) }
 506
 507 newUniqueSupply :: TcRn m UniqSupply
 508 newUniqueSupply
 509  = do { u_var <- getUsVar ;
 510         us <- readMutVar u_var ;
 511         let { (us1, us2) = splitUniqSupply us } ;
 512         writeMutVar u_var us1 ;
 513         return us2 }
 514 \end{code}
 515
 516
 517 \begin{code}
 518 getNameCache :: TcRn m NameCache
 519 getNameCache = do { TopEnv { top_nc = nc_var } <- getTopEnv;
 520                     readMutVar nc_var }
 521
 522 setNameCache :: NameCache -> TcRn m ()
 523 setNameCache nc = do { TopEnv { top_nc = nc_var } <- getTopEnv;
 524                        writeMutVar nc_var nc }
 525 \end{code}
 526
 527
 528 %************************************************************************
 529 %*                                                                      *
 530                 Debugging
 531 %*                                                                      *
 532 %************************************************************************
 533
 534 \begin{code}
 535 traceTc, traceRn :: SDoc -> TcRn a ()
 536 traceRn      = dumpOptTcRn Opt_D_dump_rn_trace
 537 traceTc      = dumpOptTcRn Opt_D_dump_tc_trace
 538 traceSplice  = dumpOptTcRn Opt_D_dump_splices
 539 traceHiDiffs = dumpOptTcRn Opt_D_dump_hi_diffs
 540
 541 dumpOptTcRn :: DynFlag -> SDoc -> TcRn a ()
 542 dumpOptTcRn flag doc = ifOptM flag (dumpTcRn doc)
 543
 544 dumpTcRn :: SDoc -> TcRn a ()
 545 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 546                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 547 \end{code}
 548
 549
 550 %************************************************************************
 551 %*                                                                      *
 552         Context management and error message generation
 553                     for the type checker
 554 %*                                                                      *
 555 %************************************************************************
 556
 557 \begin{code}
 558 setErrCtxtM, addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 559 setErrCtxtM msg = updCtxt (\ msgs -> [msg])
 560 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 561
 562 setErrCtxt, addErrCtxt :: Message -> TcM a -> TcM a
 563 setErrCtxt msg = setErrCtxtM (\env -> returnM (env, msg))
 564 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 565
 566 popErrCtxt :: TcM a -> TcM a
 567 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 568
 569 getErrCtxt :: TcM ErrCtxt
 570 getErrCtxt = do { env <- getLclEnv ; return (tcl_ctxt env) }
 571
 572 -- Helper function for the above
 573 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 574 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 575                            env { tcl_ctxt = upd ctxt })
 576
 577 getInstLoc :: InstOrigin -> TcM InstLoc
 578 getInstLoc origin
 579   = do { loc <- getSrcLocM ; env <- getLclEnv ;
 580          return (origin, loc, (tcl_ctxt env)) }
 581 \end{code}
 582
 583     The addErrTc functions add an error message, but do not cause failure.
 584     The 'M' variants pass a TidyEnv that has already been used to
 585     tidy up the message; we then use it to tidy the context messages
 586
 587 \begin{code}
 588 addErrTc :: Message -> TcM ()
 589 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 590
 591 addErrsTc :: [Message] -> TcM ()
 592 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 593
 594 addErrTcM :: (TidyEnv, Message) -> TcM ()
 595 addErrTcM (tidy_env, err_msg)
 596   = do { ctxt <- getErrCtxt ;
 597          loc  <- getSrcLocM ;
 598          add_err_tcm tidy_env err_msg loc ctxt }
 599
 600 addInstErrTcM :: InstLoc -> (TidyEnv, Message) -> TcM ()
 601 addInstErrTcM inst_loc@(_, loc, ctxt) (tidy_env, err_msg)
 602   = add_err_tcm tidy_env err_msg loc full_ctxt
 603   where
 604     full_ctxt = (\env -> returnM (env, pprInstLoc inst_loc)) : ctxt
 605 \end{code}
 606
 607 The failWith functions add an error message and cause failure
 608
 609 \begin{code}
 610 failWithTc :: Message -> TcM a               -- Add an error message and fail
 611 failWithTc err_msg
 612   = addErrTc err_msg >> failM
 613
 614 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 615 failWithTcM local_and_msg
 616   = addErrTcM local_and_msg >> failM
 617
 618 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 619 checkTc True  err = returnM ()
 620 checkTc False err = failWithTc err
 621 \end{code}
 622
 623         Warnings have no 'M' variant, nor failure
 624
 625 \begin{code}
 626 addWarnTc :: Message -> TcM ()
 627 addWarnTc msg
 628  = do { ctxt <- getErrCtxt ;
 629         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 630         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 631
 632 warnTc :: Bool -> Message -> TcM ()
 633 warnTc warn_if_true warn_msg
 634   | warn_if_true = addWarnTc warn_msg
 635   | otherwise    = return ()
 636 \end{code}
 637
 638         Helper functions
 639
 640 \begin{code}
 641 add_err_tcm tidy_env err_msg loc ctxt
 642  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 643         addErrAt loc (vcat (err_msg : ctxt_to_use ctxt_msgs)) }
 644
 645 do_ctxt tidy_env []
 646  = return []
 647 do_ctxt tidy_env (c:cs)
 648  = do { (tidy_env', m) <- c tidy_env  ;
 649         ms             <- do_ctxt tidy_env' cs  ;
 650         return (m:ms) }
 651
 652 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 653                  | otherwise          = take 3 ctxt
 654 \end{code}
 655
 656 %************************************************************************
 657 %*                                                                      *
 658              Other stuff specific to type checker
 659 %*                                                                      *
 660 %************************************************************************
 661
 662 \begin{code}
 663 getLIEVar :: TcM (TcRef LIE)
 664 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 665
 666 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 667 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 668
 669 getLIE :: TcM a -> TcM (a, [Inst])
 670 -- (getLIE m) runs m, and returns the type constraints it generates
 671 getLIE thing_inside
 672   = do { lie_var <- newMutVar emptyLIE ;
 673          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 674                           thing_inside ;
 675          lie <- readMutVar lie_var ;
 676          return (res, lieToList lie) }
 677
 678 extendLIE :: Inst -> TcM ()
 679 extendLIE inst
 680   = do { lie_var <- getLIEVar ;
 681          lie <- readMutVar lie_var ;
 682          writeMutVar lie_var (inst `consLIE` lie) }
 683
 684 extendLIEs :: [Inst] -> TcM ()
 685 extendLIEs []
 686   = returnM ()
 687 extendLIEs insts
 688   = do { lie_var <- getLIEVar ;
 689          lie <- readMutVar lie_var ;
 690          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 691 \end{code}
 692
 693
 694 \begin{code}
 695 getStage :: TcM Stage
 696 getStage = do { env <- getLclEnv; return (tcl_level env) }
 697
 698 setStage :: Stage -> TcM a -> TcM a
 699 setStage s = updLclEnv (\ env -> env { tcl_level = s })
 700
 701 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 702 -- Set the local type envt, but do *not* disturb other fields,
 703 -- notably the lie_var
 704 setLclTypeEnv lcl_env thing_inside
 705   = updLclEnv upd thing_inside
 706   where
 707     upd env = env { tcl_env = tcl_env lcl_env,
 708                     tcl_tyvars = tcl_tyvars lcl_env }
 709 \end{code}
 710
 711
 712 %************************************************************************
 713 %*                                                                      *
 714              Stuff for the renamer's local env
 715 %*                                                                      *
 716 %************************************************************************
 717
 718 \begin{code}
 719 initRn :: RnMode -> RnM a -> TcRn m a
 720 initRn mode thing_inside
 721  = do { env <- getGblEnv ;
 722         let { lcl_env = RnLclEnv {
 723                              rn_mode = mode,
 724                              rn_lenv = emptyRdrEnv }} ;
 725         setLclEnv lcl_env thing_inside }
 726 \end{code}
 727
 728 \begin{code}
 729 getLocalRdrEnv :: RnM LocalRdrEnv
 730 getLocalRdrEnv = do { env <- getLclEnv; return (rn_lenv env) }
 731
 732 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 733 setLocalRdrEnv rdr_env thing_inside
 734   = updLclEnv (\env -> env {rn_lenv = rdr_env}) thing_inside
 735
 736 getModeRn :: RnM RnMode
 737 getModeRn = do { env <- getLclEnv; return (rn_mode env) }
 738 \end{code}
 739