ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes
   5   ) where
   6
   7 #include "HsVersions.h"
   8
   9 import HsSyn            ( MonoBinds(..) )
  10 import HscTypes         ( HscEnv(..), PersistentCompilerState(..),
  11                           emptyFixityEnv, emptyGlobalRdrEnv, TyThing,
  12                           ExternalPackageState(..), HomePackageTable,
  13                           ModDetails(..), HomeModInfo(..), Deprecations(..),
  14                           GlobalRdrEnv, LocalRdrEnv, NameCache, FixityEnv,
  15                           GhciMode, lookupType, unQualInScope )
  16 import TcRnTypes
  17 import Module           ( Module, foldModuleEnv )
  18 import Name             ( Name, isInternalName )
  19 import Type             ( Type )
  20 import NameEnv          ( extendNameEnvList )
  21 import InstEnv          ( InstEnv, extendInstEnv )
  22 import TysWiredIn       ( integerTy, doubleTy )
  23
  24 import VarSet           ( emptyVarSet )
  25 import VarEnv           ( TidyEnv, emptyTidyEnv )
  26 import RdrName          ( emptyRdrEnv )
  27 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  28                           addShortErrLocLine, addShortWarnLocLine, printErrorsAndWarnings )
  29 import SrcLoc           ( SrcLoc, noSrcLoc )
  30 import NameEnv          ( emptyNameEnv )
  31 import Bag              ( emptyBag )
  32 import Outputable
  33 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  34 import Unique           ( Unique )
  35 import CmdLineOpts      ( DynFlags, DynFlag(..), dopt, opt_PprStyle_Debug )
  36 import BasicTypes       ( FixitySig )
  37 import Bag              ( snocBag, unionBags )
  38
  39 import Maybe            ( isJust )
  40 import IO               ( stderr )
  41 import DATA_IOREF       ( newIORef, readIORef )
  42 \end{code}
  43
  44 %************************************************************************
  45 %*                                                                      *
  46         Standard combinators, but specialised for this monad
  47                         (for efficiency)
  48 %*                                                                      *
  49 6%************************************************************************
  50
  51 \begin{code}
  52 mappM         :: (a -> TcRn m b) -> [a] -> TcRn m [b]
  53 mappM_        :: (a -> TcRn m b) -> [a] -> TcRn m ()
  54         -- Funny names to avoid clash with Prelude
  55 sequenceM     :: [TcRn m a] -> TcRn m [a]
  56 foldlM        :: (a -> b -> TcRn m a)  -> a -> [b] -> TcRn m a
  57 mapAndUnzipM  :: (a -> TcRn m (b,c))   -> [a] -> TcRn m ([b],[c])
  58 mapAndUnzip3M :: (a -> TcRn m (b,c,d)) -> [a] -> TcRn m ([b],[c],[d])
  59 checkM        :: Bool -> TcRn m () -> TcRn m () -- Perform arg if bool is False
  60 ifM           :: Bool -> TcRn m () -> TcRn m () -- Perform arg if bool is True
  61
  62 mappM f []     = return []
  63 mappM f (x:xs) = do { r <- f x; rs <- mappM f xs; return (r:rs) }
  64
  65 mappM_ f []     = return ()
  66 mappM_ f (x:xs) = f x >> mappM_ f xs
  67
  68 sequenceM [] = return []
  69 sequenceM (x:xs) = do { r <- x; rs <- sequenceM xs; return (r:rs) }
  70
  71 foldlM k z [] = return z
  72 foldlM k z (x:xs) = do { r <- k z x; foldlM k r xs }
  73
  74 mapAndUnzipM f []     = return ([],[])
  75 mapAndUnzipM f (x:xs) = do { (r,s) <- f x;
  76                              (rs,ss) <- mapAndUnzipM f xs;
  77                              return (r:rs, s:ss) }
  78
  79 mapAndUnzip3M f []     = return ([],[], [])
  80 mapAndUnzip3M f (x:xs) = do { (r,s,t) <- f x;
  81                               (rs,ss,ts) <- mapAndUnzip3M f xs;
  82                               return (r:rs, s:ss, t:ts) }
  83
  84 checkM True  err = return ()
  85 checkM False err = err
  86
  87 ifM True  do_it = do_it
  88 ifM False do_it = return ()
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94                         initTc
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 \begin{code}
  99 initTc :: HscEnv -> PersistentCompilerState
 100        -> Module
 101        -> TcM r
 102        -> IO (PersistentCompilerState, Maybe r)
 103                 -- Nothing => error thrown by the thing inside
 104                 -- (error messages should have been printed already)
 105
 106 initTc  (HscEnv { hsc_mode   = ghci_mode,
 107                   hsc_HPT    = hpt,
 108                   hsc_dflags = dflags })
 109         pcs mod do_this
 110  = do { us       <- mkSplitUniqSupply 'a' ;
 111         us_var   <- newIORef us ;
 112         errs_var <- newIORef (emptyBag, emptyBag) ;
 113         tvs_var  <- newIORef emptyVarSet ;
 114         usg_var  <- newIORef emptyUsages ;
 115         nc_var   <- newIORef (pcs_nc pcs) ;
 116         eps_var  <- newIORef eps ;
 117
 118         let {
 119              env = Env { env_top = top_env,
 120                          env_gbl = gbl_env,
 121                          env_lcl = lcl_env,
 122                          env_loc = noSrcLoc } ;
 123
 124              top_env = TopEnv {
 125                 top_mode   = ghci_mode,
 126                 top_dflags = dflags,
 127                 top_eps    = eps_var,
 128                 top_hpt    = hpt,
 129                 top_nc     = nc_var,
 130                 top_us     = us_var,
 131                 top_errs   = errs_var } ;
 132
 133              gbl_env = TcGblEnv {
 134                 tcg_mod      = mod,
 135                 tcg_usages   = usg_var,
 136                 tcg_rdr_env  = emptyGlobalRdrEnv,
 137                 tcg_fix_env  = emptyFixityEnv,
 138                 tcg_default  = defaultDefaultTys,
 139                 tcg_type_env = emptyNameEnv,
 140                 tcg_ist      = mkImpTypeEnv eps hpt,
 141                 tcg_inst_env = mkImpInstEnv dflags eps hpt,
 142                 tcg_exports  = [],
 143                 tcg_imports  = emptyImportAvails,
 144                 tcg_binds    = EmptyMonoBinds,
 145                 tcg_deprecs  = NoDeprecs,
 146                 tcg_insts    = [],
 147                 tcg_rules    = [],
 148                 tcg_fords    = [] } ;
 149
 150              lcl_env = TcLclEnv {
 151                 tcl_ctxt   = [],
 152                 tcl_level  = topStage,
 153                 tcl_env    = emptyNameEnv,
 154                 tcl_tyvars = tvs_var,
 155                 tcl_lie    = panic "initTc:LIE" } ;
 156                         -- LIE only valid inside a getLIE
 157              } ;
 158
 159         -- OK, here's the business end!
 160         maybe_res <- catch (do { res  <- runTcRn env do_this ;
 161                                  return (Just res) })
 162                            (\_ -> return Nothing) ;
 163
 164         -- Print any error messages
 165         msgs <- readIORef errs_var ;
 166         printErrorsAndWarnings msgs ;
 167
 168         -- Get final PCS and return
 169         eps' <- readIORef eps_var ;
 170         nc'  <- readIORef nc_var ;
 171         let { pcs' = PCS { pcs_EPS = eps', pcs_nc = nc' } ;
 172               final_res | errorsFound msgs = Nothing
 173                         | otherwise        = maybe_res } ;
 174
 175         return (pcs', final_res)
 176     }
 177   where
 178     eps = pcs_EPS pcs
 179
 180 defaultDefaultTys :: [Type]
 181 defaultDefaultTys = [integerTy, doubleTy]
 182
 183 mkImpInstEnv :: DynFlags -> ExternalPackageState -> HomePackageTable -> InstEnv
 184 mkImpInstEnv dflags eps hpt
 185   = foldModuleEnv (add . md_insts . hm_details)
 186                   (eps_inst_env eps)
 187                   hpt
 188   where
 189           -- We shouldn't get instance conflict errors from
 190           -- the package and home type envs
 191     add dfuns inst_env = WARN( not (null errs), vcat (map snd errs) ) inst_env'
 192                        where
 193                          (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 194
 195 -- mkImpTypeEnv makes the imported symbol table
 196 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 197              -> Name -> Maybe TyThing
 198 mkImpTypeEnv pcs hpt = lookup
 199   where
 200     pte = eps_PTE pcs
 201     lookup name | isInternalName name = Nothing
 202                 | otherwise           = lookupType hpt pte name
 203 \end{code}
 204
 205
 206 %************************************************************************
 207 %*                                                                      *
 208                 Simple accessors
 209 %*                                                                      *
 210 %************************************************************************
 211
 212 \begin{code}
 213 getTopEnv :: TcRn m TopEnv
 214 getTopEnv = do { env <- getEnv; return (env_top env) }
 215
 216 getGblEnv :: TcRn m TcGblEnv
 217 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 218
 219 updGblEnv :: (TcGblEnv -> TcGblEnv) -> TcRn m a -> TcRn m a
 220 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 221                           env { env_gbl = upd gbl })
 222
 223 setGblEnv :: TcGblEnv -> TcRn m a -> TcRn m a
 224 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 225
 226 getLclEnv :: TcRn m m
 227 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 228
 229 updLclEnv :: (m -> m) -> TcRn m a -> TcRn m a
 230 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 231                           env { env_lcl = upd lcl })
 232
 233 setLclEnv :: m -> TcRn m a -> TcRn n a
 234 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 235 \end{code}
 236
 237 Command-line flags
 238
 239 \begin{code}
 240 getDOpts :: TcRn m DynFlags
 241 getDOpts = do { env <- getTopEnv; return (top_dflags env) }
 242
 243 doptM :: DynFlag -> TcRn m Bool
 244 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 245
 246 ifOptM :: DynFlag -> TcRn m () -> TcRn m ()     -- Do it flag is true
 247 ifOptM flag thing_inside = do { b <- doptM flag;
 248                                 if b then thing_inside else return () }
 249
 250 getGhciMode :: TcRn m GhciMode
 251 getGhciMode = do { env <- getTopEnv; return (top_mode env) }
 252 \end{code}
 253
 254 \begin{code}
 255 getSrcLocM :: TcRn m SrcLoc
 256         -- Avoid clash with Name.getSrcLoc
 257 getSrcLocM = do { env <- getEnv; return (env_loc env) }
 258
 259 addSrcLoc :: SrcLoc -> TcRn m a -> TcRn m a
 260 addSrcLoc loc = updEnv (\env -> env { env_loc = loc })
 261 \end{code}
 262
 263 \begin{code}
 264 getEps :: TcRn m ExternalPackageState
 265 getEps = do { env <- getTopEnv; readMutVar (top_eps env) }
 266
 267 setEps :: ExternalPackageState -> TcRn m ()
 268 setEps eps = do { env <- getTopEnv; writeMutVar (top_eps env) eps }
 269
 270 getHpt :: TcRn m HomePackageTable
 271 getHpt = do { env <- getTopEnv; return (top_hpt env) }
 272
 273 getModule :: TcRn m Module
 274 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 275
 276 getGlobalRdrEnv :: TcRn m GlobalRdrEnv
 277 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 278
 279 getFixityEnv :: TcRn m FixityEnv
 280 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 281
 282 extendFixityEnv :: [(Name,FixitySig Name)] -> RnM a -> RnM a
 283 extendFixityEnv new_bit
 284   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 285                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 286
 287 getDefaultTys :: TcRn m [Type]
 288 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 289 \end{code}
 290
 291 \begin{code}
 292 getUsageVar :: TcRn m (TcRef Usages)
 293 getUsageVar = do { env <- getGblEnv; return (tcg_usages env) }
 294
 295 getUsages :: TcRn m Usages
 296 getUsages = do { usg_var <- getUsageVar; readMutVar usg_var }
 297
 298 updUsages :: (Usages -> Usages) -> TcRn m ()
 299 updUsages upd = do { usg_var <- getUsageVar ;
 300                      usg <- readMutVar usg_var ;
 301                      writeMutVar usg_var (upd usg) }
 302 \end{code}
 303
 304
 305 %************************************************************************
 306 %*                                                                      *
 307                 Error management
 308 %*                                                                      *
 309 %************************************************************************
 310
 311 \begin{code}
 312 getErrsVar :: TcRn m (TcRef Messages)
 313 getErrsVar = do { env <- getTopEnv; return (top_errs env) }
 314
 315 setErrsVar :: TcRef Messages -> TcRn m a -> TcRn m a
 316 setErrsVar v = updEnv (\ env@(Env { env_top = top_env }) ->
 317                          env { env_top = top_env { top_errs = v }})
 318
 319 addErr :: Message -> TcRn m ()
 320 addErr msg = do { loc <- getSrcLocM ; add_err loc msg }
 321
 322 add_err :: SrcLoc -> Message -> TcRn m ()
 323 add_err loc msg
 324  = do {  errs_var <- getErrsVar ;
 325          rdr_env <- getGlobalRdrEnv ;
 326          let { err = addShortErrLocLine loc (unQualInScope rdr_env) msg } ;
 327          (warns, errs) <- readMutVar errs_var ;
 328          writeMutVar errs_var (warns, errs `snocBag` err) }
 329
 330 addErrs :: [(SrcLoc,Message)] -> TcRn m ()
 331 addErrs msgs = mappM_ add msgs
 332              where
 333                add (loc,msg) = add_err loc msg
 334
 335 addWarn :: Message -> TcRn m ()
 336 addWarn msg
 337   = do { errs_var <- getErrsVar ;
 338          loc <- getSrcLocM ;
 339          rdr_env <- getGlobalRdrEnv ;
 340          let { warn = addShortWarnLocLine loc (unQualInScope rdr_env) msg } ;
 341          (warns, errs) <- readMutVar errs_var ;
 342          writeMutVar errs_var (warns `snocBag` warn, errs) }
 343
 344 checkErr :: Bool -> Message -> TcRn m ()
 345 -- Add the error if the bool is False
 346 checkErr ok msg = checkM ok (addErr msg)
 347
 348 warnIf :: Bool -> Message -> TcRn m ()
 349 warnIf True  msg = addWarn msg
 350 warnIf False msg = return ()
 351
 352 addMessages :: Messages -> TcRn m ()
 353 addMessages (m_warns, m_errs)
 354   = do { errs_var <- getErrsVar ;
 355          (warns, errs) <- readMutVar errs_var ;
 356          writeMutVar errs_var (warns `unionBags` m_warns,
 357                                errs  `unionBags` m_errs) }
 358
 359 checkGHCI :: Message -> TcRn m ()       -- Check that GHCI is on
 360                                         -- otherwise add the error message
 361 #ifdef GHCI
 362 checkGHCI m = returnM ()
 363 #else
 364 checkGHCI m = addErr m
 365 #endif
 366 \end{code}
 367
 368
 369 \begin{code}
 370 tryM :: TcRn m a -> TcRn m (Messages, Maybe a)
 371     -- (try m) executes m, and returns
 372     --  Just r,  if m succeeds (returning r) and caused no errors
 373     --  Nothing, if m fails, or caused errors
 374     -- It also returns all the errors accumulated by m
 375     --  (even in the Just case, there might be warnings)
 376     --
 377     -- It always succeeds (never raises an exception)
 378 tryM m
 379  = do { errs_var <- newMutVar emptyMessages ;
 380
 381         mb_r <- recoverM (return Nothing)
 382                          (do { r <- setErrsVar errs_var m ;
 383                                     return (Just r) }) ;
 384
 385         new_errs <- readMutVar errs_var ;
 386
 387         return (new_errs,
 388                 case mb_r of
 389                   Nothing                       -> Nothing
 390                   Just r | errorsFound new_errs -> Nothing
 391                          | otherwise            -> Just r)
 392    }
 393
 394 tryTc :: TcM a -> TcM (Messages, Maybe a)
 395 -- Just like tryM, except that it ensures that the LIE
 396 -- for the thing is propagated only if there are no errors
 397 -- Hence it's restricted to the type-check monad
 398 tryTc thing_inside
 399   = do { ((errs, mb_r), lie) <- getLIE (tryM thing_inside) ;
 400          ifM (isJust mb_r) (extendLIEs lie) ;
 401          return (errs, mb_r) }
 402
 403 tryTc_ :: TcM r -> TcM r -> TcM r
 404 -- (tryM_ r m) tries m; if it succeeds it returns it,
 405 -- otherwise it returns r.  Any error messages added by m are discarded,
 406 -- whether or not m succeeds.
 407 tryTc_ recover main
 408   = do { (_msgs, mb_res) <- tryTc main ;
 409          case mb_res of
 410            Just res -> return res
 411            Nothing  -> recover }
 412
 413 checkNoErrs :: TcM r -> TcM r
 414 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 415 -- If m fails then (checkNoErrsTc m) fails.
 416 -- If m succeeds, it checks whether m generated any errors messages
 417 --      (it might have recovered internally)
 418 --      If so, it fails too.
 419 -- Regardless, any errors generated by m are propagated to the enclosing context.
 420 checkNoErrs main
 421   = do { (msgs, mb_res) <- tryTc main ;
 422          addMessages msgs ;
 423          case mb_res of
 424            Just r  -> return r
 425            Nothing -> failM
 426    }
 427
 428 ifErrsM :: TcRn m r -> TcRn m r -> TcRn m r
 429 --      ifErrsM bale_out main
 430 -- does 'bale_out' if there are errors in errors collection
 431 -- otherwise does 'main'
 432 ifErrsM bale_out normal
 433  = do { errs_var <- getErrsVar ;
 434         msgs <- readMutVar errs_var ;
 435         if errorsFound msgs then
 436            bale_out
 437         else
 438            normal }
 439
 440 failIfErrsM :: TcRn m ()
 441 -- Useful to avoid error cascades
 442 failIfErrsM = ifErrsM failM (return ())
 443 \end{code}
 444
 445 \begin{code}
 446 forkM :: SDoc -> TcM a -> TcM (Maybe a)
 447 -- Run thing_inside in an interleaved thread.  It gets a separate
 448 --      * errs_var, and
 449 --      * unique supply,
 450 -- but everything else is shared, so this is DANGEROUS.
 451 --
 452 -- It returns Nothing if the computation fails
 453 --
 454 -- It's used for lazily type-checking interface
 455 -- signatures, which is pretty benign
 456
 457 forkM doc thing_inside
 458  = do { us <- newUniqueSupply ;
 459         unsafeInterleaveM $
 460         do { us_var <- newMutVar us ;
 461              (msgs, mb_res) <- tryTc (setUsVar us_var thing_inside) ;
 462              case mb_res of
 463                 Just r  -> return (Just r)
 464                 Nothing -> do {
 465                     -- Bleat about errors in the forked thread
 466                     ioToTcRn (do { printErrs (hdr_doc defaultErrStyle) ;
 467                                    printErrorsAndWarnings msgs }) ;
 468                     return Nothing }
 469         }}
 470   where
 471     hdr_doc = text "forkM failed:" <+> doc
 472 \end{code}
 473
 474
 475 %************************************************************************
 476 %*                                                                      *
 477                 Unique supply
 478 %*                                                                      *
 479 %************************************************************************
 480
 481 \begin{code}
 482 getUsVar :: TcRn m (TcRef UniqSupply)
 483 getUsVar = do { env <- getTopEnv; return (top_us env) }
 484
 485 setUsVar :: TcRef UniqSupply -> TcRn m a -> TcRn m a
 486 setUsVar v = updEnv (\ env@(Env { env_top = top_env }) ->
 487                        env { env_top = top_env { top_us = v }})
 488
 489 newUnique :: TcRn m Unique
 490 newUnique = do { us <- newUniqueSupply ;
 491                  return (uniqFromSupply us) }
 492
 493 newUniqueSupply :: TcRn m UniqSupply
 494 newUniqueSupply
 495  = do { u_var <- getUsVar ;
 496         us <- readMutVar u_var ;
 497         let { (us1, us2) = splitUniqSupply us } ;
 498         writeMutVar u_var us1 ;
 499         return us2 }
 500 \end{code}
 501
 502
 503 \begin{code}
 504 getNameCache :: TcRn m NameCache
 505 getNameCache = do { TopEnv { top_nc = nc_var } <- getTopEnv;
 506                     readMutVar nc_var }
 507
 508 setNameCache :: NameCache -> TcRn m ()
 509 setNameCache nc = do { TopEnv { top_nc = nc_var } <- getTopEnv;
 510                        writeMutVar nc_var nc }
 511 \end{code}
 512
 513
 514 %************************************************************************
 515 %*                                                                      *
 516                 Debugging
 517 %*                                                                      *
 518 %************************************************************************
 519
 520 \begin{code}
 521 traceTc, traceRn :: SDoc -> TcRn a ()
 522 traceRn      = dumpOptTcRn Opt_D_dump_rn_trace
 523 traceTc      = dumpOptTcRn Opt_D_dump_tc_trace
 524 traceHiDiffs = dumpOptTcRn Opt_D_dump_hi_diffs
 525
 526 dumpOptTcRn :: DynFlag -> SDoc -> TcRn a ()
 527 dumpOptTcRn flag doc = ifOptM flag (dumpTcRn doc)
 528
 529 dumpTcRn :: SDoc -> TcRn a ()
 530 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 531                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 532 \end{code}
 533
 534
 535 %************************************************************************
 536 %*                                                                      *
 537         Context management and error message generation
 538                     for the type checker
 539 %*                                                                      *
 540 %************************************************************************
 541
 542 \begin{code}
 543 setErrCtxtM, addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 544 setErrCtxtM msg = updCtxt (\ msgs -> [msg])
 545 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 546
 547 setErrCtxt, addErrCtxt :: Message -> TcM a -> TcM a
 548 setErrCtxt msg = setErrCtxtM (\env -> returnM (env, msg))
 549 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 550
 551 popErrCtxt :: TcM a -> TcM a
 552 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 553
 554 getErrCtxt :: TcM ErrCtxt
 555 getErrCtxt = do { env <- getLclEnv ; return (tcl_ctxt env) }
 556
 557 -- Helper function for the above
 558 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 559 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 560                            env { tcl_ctxt = upd ctxt })
 561
 562 getInstLoc :: InstOrigin -> TcM InstLoc
 563 getInstLoc origin
 564   = do { loc <- getSrcLocM ; env <- getLclEnv ;
 565          return (origin, loc, (tcl_ctxt env)) }
 566 \end{code}
 567
 568     The addErrTc functions add an error message, but do not cause failure.
 569     The 'M' variants pass a TidyEnv that has already been used to
 570     tidy up the message; we then use it to tidy the context messages
 571
 572 \begin{code}
 573 addErrTc :: Message -> TcM ()
 574 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 575
 576 addErrsTc :: [Message] -> TcM ()
 577 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 578
 579 addErrTcM :: (TidyEnv, Message) -> TcM ()
 580 addErrTcM (tidy_env, err_msg)
 581   = do { ctxt <- getErrCtxt ;
 582          loc  <- getSrcLocM ;
 583          add_err_tcm tidy_env err_msg loc ctxt }
 584
 585 addInstErrTcM :: InstLoc -> (TidyEnv, Message) -> TcM ()
 586 addInstErrTcM inst_loc@(_, loc, ctxt) (tidy_env, err_msg)
 587   = add_err_tcm tidy_env err_msg loc full_ctxt
 588   where
 589     full_ctxt = (\env -> returnM (env, pprInstLoc inst_loc)) : ctxt
 590 \end{code}
 591
 592 The failWith functions add an error message and cause failure
 593
 594 \begin{code}
 595 failWithTc :: Message -> TcM a               -- Add an error message and fail
 596 failWithTc err_msg
 597   = addErrTc err_msg >> failM
 598
 599 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 600 failWithTcM local_and_msg
 601   = addErrTcM local_and_msg >> failM
 602
 603 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 604 checkTc True  err = returnM ()
 605 checkTc False err = failWithTc err
 606 \end{code}
 607
 608         Warnings have no 'M' variant, nor failure
 609
 610 \begin{code}
 611 addWarnTc :: Message -> TcM ()
 612 addWarnTc msg
 613  = do { ctxt <- getErrCtxt ;
 614         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 615         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 616
 617 warnTc :: Bool -> Message -> TcM ()
 618 warnTc warn_if_true warn_msg
 619   | warn_if_true = addWarnTc warn_msg
 620   | otherwise    = return ()
 621 \end{code}
 622
 623         Helper functions
 624
 625 \begin{code}
 626 add_err_tcm tidy_env err_msg loc ctxt
 627  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 628         add_err loc (vcat (err_msg : ctxt_to_use ctxt_msgs)) }
 629
 630 do_ctxt tidy_env []
 631  = return []
 632 do_ctxt tidy_env (c:cs)
 633  = do { (tidy_env', m) <- c tidy_env  ;
 634         ms             <- do_ctxt tidy_env' cs  ;
 635         return (m:ms) }
 636
 637 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 638                  | otherwise          = take 3 ctxt
 639 \end{code}
 640
 641 %************************************************************************
 642 %*                                                                      *
 643              Other stuff specific to type checker
 644 %*                                                                      *
 645 %************************************************************************
 646
 647 \begin{code}
 648 getLIEVar :: TcM (TcRef LIE)
 649 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 650
 651 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 652 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 653
 654 getLIE :: TcM a -> TcM (a, [Inst])
 655 -- (getLIE m) runs m, and returns the type constraints it generates
 656 getLIE thing_inside
 657   = do { lie_var <- newMutVar emptyLIE ;
 658          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 659                           thing_inside ;
 660          lie <- readMutVar lie_var ;
 661          return (res, lieToList lie) }
 662
 663 extendLIE :: Inst -> TcM ()
 664 extendLIE inst
 665   = do { lie_var <- getLIEVar ;
 666          lie <- readMutVar lie_var ;
 667          writeMutVar lie_var (inst `consLIE` lie) }
 668
 669 extendLIEs :: [Inst] -> TcM ()
 670 extendLIEs []
 671   = returnM ()
 672 extendLIEs insts
 673   = do { lie_var <- getLIEVar ;
 674          lie <- readMutVar lie_var ;
 675          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 676 \end{code}
 677
 678
 679 \begin{code}
 680 getStage :: TcM Stage
 681 getStage = do { env <- getLclEnv; return (tcl_level env) }
 682
 683 setStage :: Stage -> TcM a -> TcM a
 684 setStage s = updLclEnv (\ env -> env { tcl_level = s })
 685
 686 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 687 -- Set the local type envt, but do *not* disturb other fields,
 688 -- notably the lie_var
 689 setLclTypeEnv lcl_env thing_inside
 690   = updLclEnv upd thing_inside
 691   where
 692     upd env = env { tcl_env = tcl_env lcl_env,
 693                     tcl_tyvars = tcl_tyvars lcl_env }
 694 \end{code}
 695
 696
 697 %************************************************************************
 698 %*                                                                      *
 699              Stuff for the renamer's local env
 700 %*                                                                      *
 701 %************************************************************************
 702
 703 \begin{code}
 704 initRn :: RnMode -> RnM a -> TcRn m a
 705 initRn mode thing_inside
 706  = do { env <- getGblEnv ;
 707         let { lcl_env = RnLclEnv {
 708                              rn_mode = mode,
 709                              rn_lenv = emptyRdrEnv }} ;
 710         setLclEnv lcl_env thing_inside }
 711 \end{code}
 712
 713 \begin{code}
 714 getLocalRdrEnv :: RnM LocalRdrEnv
 715 getLocalRdrEnv = do { env <- getLclEnv; return (rn_lenv env) }
 716
 717 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 718 setLocalRdrEnv rdr_env thing_inside
 719   = updLclEnv (\env -> env {rn_lenv = rdr_env}) thing_inside
 720
 721 getModeRn :: RnM RnMode
 722 getModeRn = do { env <- getLclEnv; return (rn_mode env) }
 723 \end{code}
 724