ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes
   5   ) where
   6
   7 #include "HsVersions.h"
   8
   9 import HsSyn            ( MonoBinds(..) )
  10 import HscTypes         ( HscEnv(..), PersistentCompilerState(..),
  11                           emptyFixityEnv, emptyGlobalRdrEnv, TyThing,
  12                           ExternalPackageState(..), HomePackageTable,
  13                           ModDetails(..), HomeModInfo(..), Deprecations(..),
  14                           GlobalRdrEnv, LocalRdrEnv, NameCache, FixityEnv,
  15                           GhciMode, lookupType, unQualInScope )
  16 import TcRnTypes
  17 import Module           ( Module, moduleName, unitModuleEnv, foldModuleEnv )
  18 import Name             ( Name, isInternalName )
  19 import Type             ( Type )
  20 import NameEnv          ( extendNameEnvList )
  21 import InstEnv          ( InstEnv, extendInstEnv )
  22 import TysWiredIn       ( integerTy, doubleTy )
  23
  24 import VarSet           ( emptyVarSet )
  25 import VarEnv           ( TidyEnv, emptyTidyEnv )
  26 import RdrName          ( emptyRdrEnv )
  27 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  28                           addShortErrLocLine, addShortWarnLocLine, printErrorsAndWarnings )
  29 import SrcLoc           ( SrcLoc, noSrcLoc )
  30 import NameEnv          ( emptyNameEnv )
  31 import Bag              ( emptyBag )
  32 import Outputable
  33 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  34 import Unique           ( Unique )
  35 import CmdLineOpts      ( DynFlags, DynFlag(..), dopt, opt_PprStyle_Debug )
  36 import BasicTypes       ( FixitySig )
  37 import Bag              ( snocBag, unionBags )
  38
  39 import Maybe            ( isJust )
  40 import IO               ( stderr )
  41 import DATA_IOREF       ( newIORef, readIORef )
  42 \end{code}
  43
  44 %************************************************************************
  45 %*                                                                      *
  46         Standard combinators, but specialised for this monad
  47                         (for efficiency)
  48 %*                                                                      *
  49 6%************************************************************************
  50
  51 \begin{code}
  52 mappM         :: (a -> TcRn m b) -> [a] -> TcRn m [b]
  53 mappM_        :: (a -> TcRn m b) -> [a] -> TcRn m ()
  54         -- Funny names to avoid clash with Prelude
  55 sequenceM     :: [TcRn m a] -> TcRn m [a]
  56 foldlM        :: (a -> b -> TcRn m a)  -> a -> [b] -> TcRn m a
  57 mapAndUnzipM  :: (a -> TcRn m (b,c))   -> [a] -> TcRn m ([b],[c])
  58 mapAndUnzip3M :: (a -> TcRn m (b,c,d)) -> [a] -> TcRn m ([b],[c],[d])
  59 checkM        :: Bool -> TcRn m () -> TcRn m () -- Perform arg if bool is False
  60 ifM           :: Bool -> TcRn m () -> TcRn m () -- Perform arg if bool is True
  61
  62 mappM f []     = return []
  63 mappM f (x:xs) = do { r <- f x; rs <- mappM f xs; return (r:rs) }
  64
  65 mappM_ f []     = return ()
  66 mappM_ f (x:xs) = f x >> mappM_ f xs
  67
  68 sequenceM [] = return []
  69 sequenceM (x:xs) = do { r <- x; rs <- sequenceM xs; return (r:rs) }
  70
  71 foldlM k z [] = return z
  72 foldlM k z (x:xs) = do { r <- k z x; foldlM k r xs }
  73
  74 mapAndUnzipM f []     = return ([],[])
  75 mapAndUnzipM f (x:xs) = do { (r,s) <- f x;
  76                              (rs,ss) <- mapAndUnzipM f xs;
  77                              return (r:rs, s:ss) }
  78
  79 mapAndUnzip3M f []     = return ([],[], [])
  80 mapAndUnzip3M f (x:xs) = do { (r,s,t) <- f x;
  81                               (rs,ss,ts) <- mapAndUnzip3M f xs;
  82                               return (r:rs, s:ss, t:ts) }
  83
  84 checkM True  err = return ()
  85 checkM False err = err
  86
  87 ifM True  do_it = do_it
  88 ifM False do_it = return ()
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94                         initTc
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 \begin{code}
  99 initTc :: HscEnv -> PersistentCompilerState
 100        -> Module
 101        -> TcM r
 102        -> IO (PersistentCompilerState, Maybe r)
 103                 -- Nothing => error thrown by the thing inside
 104                 -- (error messages should have been printed already)
 105
 106 initTc  (HscEnv { hsc_mode   = ghci_mode,
 107                   hsc_HPT    = hpt,
 108                   hsc_dflags = dflags })
 109         pcs mod do_this
 110  = do { us       <- mkSplitUniqSupply 'a' ;
 111         us_var   <- newIORef us ;
 112         errs_var <- newIORef (emptyBag, emptyBag) ;
 113         tvs_var  <- newIORef emptyVarSet ;
 114         usg_var  <- newIORef emptyUsages ;
 115         nc_var   <- newIORef (pcs_nc pcs) ;
 116         eps_var  <- newIORef eps ;
 117
 118         let {
 119              env = Env { env_top = top_env,
 120                          env_gbl = gbl_env,
 121                          env_lcl = lcl_env,
 122                          env_loc = noSrcLoc } ;
 123
 124              top_env = TopEnv {
 125                 top_mode   = ghci_mode,
 126                 top_dflags = dflags,
 127                 top_eps    = eps_var,
 128                 top_hpt    = hpt,
 129                 top_nc     = nc_var,
 130                 top_us     = us_var,
 131                 top_errs   = errs_var } ;
 132
 133              gbl_env = TcGblEnv {
 134                 tcg_mod      = mod,
 135                 tcg_usages   = usg_var,
 136                 tcg_rdr_env  = emptyGlobalRdrEnv,
 137                 tcg_fix_env  = emptyFixityEnv,
 138                 tcg_default  = defaultDefaultTys,
 139                 tcg_type_env = emptyNameEnv,
 140                 tcg_ist      = mkImpTypeEnv eps hpt,
 141                 tcg_inst_env = mkImpInstEnv dflags eps hpt,
 142                 tcg_exports  = [],
 143                 tcg_imports  = init_imports,
 144                 tcg_binds    = EmptyMonoBinds,
 145                 tcg_deprecs  = NoDeprecs,
 146                 tcg_insts    = [],
 147                 tcg_rules    = [],
 148                 tcg_fords    = [] } ;
 149
 150              lcl_env = TcLclEnv {
 151                 tcl_ctxt   = [],
 152                 tcl_level  = topStage,
 153                 tcl_env    = emptyNameEnv,
 154                 tcl_tyvars = tvs_var,
 155                 tcl_lie    = panic "initTc:LIE" } ;
 156                         -- LIE only valid inside a getLIE
 157              } ;
 158
 159         -- OK, here's the business end!
 160         maybe_res <- catch (do { res  <- runTcRn env do_this ;
 161                                  return (Just res) })
 162                            (\_ -> return Nothing) ;
 163
 164         -- Print any error messages
 165         msgs <- readIORef errs_var ;
 166         printErrorsAndWarnings msgs ;
 167
 168         -- Get final PCS and return
 169         eps' <- readIORef eps_var ;
 170         nc'  <- readIORef nc_var ;
 171         let { pcs' = PCS { pcs_EPS = eps', pcs_nc = nc' } ;
 172               final_res | errorsFound dflags msgs = Nothing
 173                         | otherwise               = maybe_res } ;
 174
 175         return (pcs', final_res)
 176     }
 177   where
 178     eps = pcs_EPS pcs
 179
 180     init_imports = emptyImportAvails { imp_qual = unitModuleEnv mod emptyAvailEnv }
 181         -- Initialise tcg_imports with an empty set of bindings for
 182         -- this module, so that if we see 'module M' in the export
 183         -- list, and there are no bindings in M, we don't bleat
 184         -- "unknown module M".
 185
 186 defaultDefaultTys :: [Type]
 187 defaultDefaultTys = [integerTy, doubleTy]
 188
 189 mkImpInstEnv :: DynFlags -> ExternalPackageState -> HomePackageTable -> InstEnv
 190 mkImpInstEnv dflags eps hpt
 191   = foldModuleEnv (add . md_insts . hm_details)
 192                   (eps_inst_env eps)
 193                   hpt
 194   where
 195           -- We shouldn't get instance conflict errors from
 196           -- the package and home type envs
 197     add dfuns inst_env = WARN( not (null errs), vcat (map snd errs) ) inst_env'
 198                        where
 199                          (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 200
 201 -- mkImpTypeEnv makes the imported symbol table
 202 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 203              -> Name -> Maybe TyThing
 204 mkImpTypeEnv pcs hpt = lookup
 205   where
 206     pte = eps_PTE pcs
 207     lookup name | isInternalName name = Nothing
 208                 | otherwise           = lookupType hpt pte name
 209 \end{code}
 210
 211
 212 %************************************************************************
 213 %*                                                                      *
 214                 Simple accessors
 215 %*                                                                      *
 216 %************************************************************************
 217
 218 \begin{code}
 219 getTopEnv :: TcRn m TopEnv
 220 getTopEnv = do { env <- getEnv; return (env_top env) }
 221
 222 getGblEnv :: TcRn m TcGblEnv
 223 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 224
 225 updGblEnv :: (TcGblEnv -> TcGblEnv) -> TcRn m a -> TcRn m a
 226 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 227                           env { env_gbl = upd gbl })
 228
 229 setGblEnv :: TcGblEnv -> TcRn m a -> TcRn m a
 230 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 231
 232 getLclEnv :: TcRn m m
 233 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 234
 235 updLclEnv :: (m -> m) -> TcRn m a -> TcRn m a
 236 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 237                           env { env_lcl = upd lcl })
 238
 239 setLclEnv :: m -> TcRn m a -> TcRn n a
 240 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 241 \end{code}
 242
 243 Command-line flags
 244
 245 \begin{code}
 246 getDOpts :: TcRn m DynFlags
 247 getDOpts = do { env <- getTopEnv; return (top_dflags env) }
 248
 249 doptM :: DynFlag -> TcRn m Bool
 250 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 251
 252 ifOptM :: DynFlag -> TcRn m () -> TcRn m ()     -- Do it flag is true
 253 ifOptM flag thing_inside = do { b <- doptM flag;
 254                                 if b then thing_inside else return () }
 255
 256 getGhciMode :: TcRn m GhciMode
 257 getGhciMode = do { env <- getTopEnv; return (top_mode env) }
 258 \end{code}
 259
 260 \begin{code}
 261 getSrcLocM :: TcRn m SrcLoc
 262         -- Avoid clash with Name.getSrcLoc
 263 getSrcLocM = do { env <- getEnv; return (env_loc env) }
 264
 265 addSrcLoc :: SrcLoc -> TcRn m a -> TcRn m a
 266 addSrcLoc loc = updEnv (\env -> env { env_loc = loc })
 267 \end{code}
 268
 269 \begin{code}
 270 getEps :: TcRn m ExternalPackageState
 271 getEps = do { env <- getTopEnv; readMutVar (top_eps env) }
 272
 273 setEps :: ExternalPackageState -> TcRn m ()
 274 setEps eps = do { env <- getTopEnv; writeMutVar (top_eps env) eps }
 275
 276 getHpt :: TcRn m HomePackageTable
 277 getHpt = do { env <- getTopEnv; return (top_hpt env) }
 278
 279 getModule :: TcRn m Module
 280 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 281
 282 getGlobalRdrEnv :: TcRn m GlobalRdrEnv
 283 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 284
 285 getImports :: TcRn m ImportAvails
 286 getImports = do { env <- getGblEnv; return (tcg_imports env) }
 287
 288 getFixityEnv :: TcRn m FixityEnv
 289 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 290
 291 extendFixityEnv :: [(Name,FixitySig Name)] -> RnM a -> RnM a
 292 extendFixityEnv new_bit
 293   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 294                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 295
 296 getDefaultTys :: TcRn m [Type]
 297 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 298 \end{code}
 299
 300 \begin{code}
 301 getUsageVar :: TcRn m (TcRef EntityUsage)
 302 getUsageVar = do { env <- getGblEnv; return (tcg_usages env) }
 303
 304 getUsages :: TcRn m EntityUsage
 305 getUsages = do { usg_var <- getUsageVar; readMutVar usg_var }
 306
 307 updUsages :: (EntityUsage -> EntityUsage) -> TcRn m ()
 308 updUsages upd = do { usg_var <- getUsageVar ;
 309                      usg <- readMutVar usg_var ;
 310                      writeMutVar usg_var (upd usg) }
 311 \end{code}
 312
 313
 314 %************************************************************************
 315 %*                                                                      *
 316                 Error management
 317 %*                                                                      *
 318 %************************************************************************
 319
 320 \begin{code}
 321 getErrsVar :: TcRn m (TcRef Messages)
 322 getErrsVar = do { env <- getTopEnv; return (top_errs env) }
 323
 324 setErrsVar :: TcRef Messages -> TcRn m a -> TcRn m a
 325 setErrsVar v = updEnv (\ env@(Env { env_top = top_env }) ->
 326                          env { env_top = top_env { top_errs = v }})
 327
 328 addErr :: Message -> TcRn m ()
 329 addErr msg = do { loc <- getSrcLocM ; addErrAt loc msg }
 330
 331 addErrAt :: SrcLoc -> Message -> TcRn m ()
 332 addErrAt loc msg
 333  = do {  errs_var <- getErrsVar ;
 334          rdr_env <- getGlobalRdrEnv ;
 335          let { err = addShortErrLocLine loc (unQualInScope rdr_env) msg } ;
 336          (warns, errs) <- readMutVar errs_var ;
 337          writeMutVar errs_var (warns, errs `snocBag` err) }
 338
 339 addErrs :: [(SrcLoc,Message)] -> TcRn m ()
 340 addErrs msgs = mappM_ add msgs
 341              where
 342                add (loc,msg) = addErrAt loc msg
 343
 344 addWarn :: Message -> TcRn m ()
 345 addWarn msg
 346   = do { errs_var <- getErrsVar ;
 347          loc <- getSrcLocM ;
 348          rdr_env <- getGlobalRdrEnv ;
 349          let { warn = addShortWarnLocLine loc (unQualInScope rdr_env) msg } ;
 350          (warns, errs) <- readMutVar errs_var ;
 351          writeMutVar errs_var (warns `snocBag` warn, errs) }
 352
 353 checkErr :: Bool -> Message -> TcRn m ()
 354 -- Add the error if the bool is False
 355 checkErr ok msg = checkM ok (addErr msg)
 356
 357 warnIf :: Bool -> Message -> TcRn m ()
 358 warnIf True  msg = addWarn msg
 359 warnIf False msg = return ()
 360
 361 addMessages :: Messages -> TcRn m ()
 362 addMessages (m_warns, m_errs)
 363   = do { errs_var <- getErrsVar ;
 364          (warns, errs) <- readMutVar errs_var ;
 365          writeMutVar errs_var (warns `unionBags` m_warns,
 366                                errs  `unionBags` m_errs) }
 367 \end{code}
 368
 369
 370 \begin{code}
 371 recoverM :: TcRn m r    -- Recovery action; do this if the main one fails
 372          -> TcRn m r    -- Main action: do this first
 373          -> TcRn m r
 374 recoverM recover thing
 375   = do { mb_res <- tryM thing ;
 376          case mb_res of
 377            Left exn  -> recover
 378            Right res -> returnM res }
 379
 380 tryTc :: TcRn m a -> TcRn m (Messages, Maybe a)
 381     -- (tryTc m) executes m, and returns
 382     --  Just r,  if m succeeds (returning r) and caused no errors
 383     --  Nothing, if m fails, or caused errors
 384     -- It also returns all the errors accumulated by m
 385     --  (even in the Just case, there might be warnings)
 386     --
 387     -- It always succeeds (never raises an exception)
 388 tryTc m
 389  = do { errs_var <- newMutVar emptyMessages ;
 390
 391         mb_r <- tryM (setErrsVar errs_var m) ;
 392
 393         new_errs <- readMutVar errs_var ;
 394
 395         dflags <- getDOpts ;
 396
 397         return (new_errs,
 398                 case mb_r of
 399                   Left exn                              -> Nothing
 400                   Right r | errorsFound dflags new_errs -> Nothing
 401                           | otherwise                   -> Just r)
 402    }
 403
 404 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 405 -- Just like tryTc, except that it ensures that the LIE
 406 -- for the thing is propagated only if there are no errors
 407 -- Hence it's restricted to the type-check monad
 408 tryTcLIE thing_inside
 409   = do { ((errs, mb_r), lie) <- getLIE (tryTc thing_inside) ;
 410          ifM (isJust mb_r) (extendLIEs lie) ;
 411          return (errs, mb_r) }
 412
 413 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 414 -- (tryM_ r m) tries m; if it succeeds it returns it,
 415 -- otherwise it returns r.  Any error messages added by m are discarded,
 416 -- whether or not m succeeds.
 417 tryTcLIE_ recover main
 418   = do { (_msgs, mb_res) <- tryTcLIE main ;
 419          case mb_res of
 420            Just res -> return res
 421            Nothing  -> recover }
 422
 423 checkNoErrs :: TcM r -> TcM r
 424 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 425 -- If m fails then (checkNoErrsTc m) fails.
 426 -- If m succeeds, it checks whether m generated any errors messages
 427 --      (it might have recovered internally)
 428 --      If so, it fails too.
 429 -- Regardless, any errors generated by m are propagated to the enclosing context.
 430 checkNoErrs main
 431   = do { (msgs, mb_res) <- tryTcLIE main ;
 432          addMessages msgs ;
 433          case mb_res of
 434            Just r  -> return r
 435            Nothing -> failM
 436    }
 437
 438 ifErrsM :: TcRn m r -> TcRn m r -> TcRn m r
 439 --      ifErrsM bale_out main
 440 -- does 'bale_out' if there are errors in errors collection
 441 -- otherwise does 'main'
 442 ifErrsM bale_out normal
 443  = do { errs_var <- getErrsVar ;
 444         msgs <- readMutVar errs_var ;
 445         dflags <- getDOpts ;
 446         if errorsFound dflags msgs then
 447            bale_out
 448         else
 449            normal }
 450
 451 failIfErrsM :: TcRn m ()
 452 -- Useful to avoid error cascades
 453 failIfErrsM = ifErrsM failM (return ())
 454 \end{code}
 455
 456 \begin{code}
 457 forkM :: SDoc -> TcM a -> TcM (Maybe a)
 458 -- Run thing_inside in an interleaved thread.  It gets a separate
 459 --      * errs_var, and
 460 --      * unique supply,
 461 -- but everything else is shared, so this is DANGEROUS.
 462 --
 463 -- It returns Nothing if the computation fails
 464 --
 465 -- It's used for lazily type-checking interface
 466 -- signatures, which is pretty benign
 467
 468 forkM doc thing_inside
 469  = do { us <- newUniqueSupply ;
 470         unsafeInterleaveM $
 471         do { us_var <- newMutVar us ;
 472              (msgs, mb_res) <- tryTcLIE (setUsVar us_var thing_inside) ;
 473              case mb_res of
 474                 Just r  -> return (Just r)
 475                 Nothing -> do {
 476                     -- Bleat about errors in the forked thread
 477                     ioToTcRn (do { printErrs (hdr_doc defaultErrStyle) ;
 478                                    printErrorsAndWarnings msgs }) ;
 479                     return Nothing }
 480         }}
 481   where
 482     hdr_doc = text "forkM failed:" <+> doc
 483 \end{code}
 484
 485
 486 %************************************************************************
 487 %*                                                                      *
 488                 Unique supply
 489 %*                                                                      *
 490 %************************************************************************
 491
 492 \begin{code}
 493 getUsVar :: TcRn m (TcRef UniqSupply)
 494 getUsVar = do { env <- getTopEnv; return (top_us env) }
 495
 496 setUsVar :: TcRef UniqSupply -> TcRn m a -> TcRn m a
 497 setUsVar v = updEnv (\ env@(Env { env_top = top_env }) ->
 498                        env { env_top = top_env { top_us = v }})
 499
 500 newUnique :: TcRn m Unique
 501 newUnique = do { us <- newUniqueSupply ;
 502                  return (uniqFromSupply us) }
 503
 504 newUniqueSupply :: TcRn m UniqSupply
 505 newUniqueSupply
 506  = do { u_var <- getUsVar ;
 507         us <- readMutVar u_var ;
 508         let { (us1, us2) = splitUniqSupply us } ;
 509         writeMutVar u_var us1 ;
 510         return us2 }
 511 \end{code}
 512
 513
 514 \begin{code}
 515 getNameCache :: TcRn m NameCache
 516 getNameCache = do { TopEnv { top_nc = nc_var } <- getTopEnv;
 517                     readMutVar nc_var }
 518
 519 setNameCache :: NameCache -> TcRn m ()
 520 setNameCache nc = do { TopEnv { top_nc = nc_var } <- getTopEnv;
 521                        writeMutVar nc_var nc }
 522 \end{code}
 523
 524
 525 %************************************************************************
 526 %*                                                                      *
 527                 Debugging
 528 %*                                                                      *
 529 %************************************************************************
 530
 531 \begin{code}
 532 traceTc, traceRn :: SDoc -> TcRn a ()
 533 traceRn      = dumpOptTcRn Opt_D_dump_rn_trace
 534 traceTc      = dumpOptTcRn Opt_D_dump_tc_trace
 535 traceSplice  = dumpOptTcRn Opt_D_dump_splices
 536 traceHiDiffs = dumpOptTcRn Opt_D_dump_hi_diffs
 537
 538 dumpOptTcRn :: DynFlag -> SDoc -> TcRn a ()
 539 dumpOptTcRn flag doc = ifOptM flag (dumpTcRn doc)
 540
 541 dumpTcRn :: SDoc -> TcRn a ()
 542 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 543                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 544 \end{code}
 545
 546
 547 %************************************************************************
 548 %*                                                                      *
 549         Context management and error message generation
 550                     for the type checker
 551 %*                                                                      *
 552 %************************************************************************
 553
 554 \begin{code}
 555 setErrCtxtM, addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 556 setErrCtxtM msg = updCtxt (\ msgs -> [msg])
 557 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 558
 559 setErrCtxt, addErrCtxt :: Message -> TcM a -> TcM a
 560 setErrCtxt msg = setErrCtxtM (\env -> returnM (env, msg))
 561 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 562
 563 popErrCtxt :: TcM a -> TcM a
 564 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 565
 566 getErrCtxt :: TcM ErrCtxt
 567 getErrCtxt = do { env <- getLclEnv ; return (tcl_ctxt env) }
 568
 569 -- Helper function for the above
 570 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 571 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 572                            env { tcl_ctxt = upd ctxt })
 573
 574 getInstLoc :: InstOrigin -> TcM InstLoc
 575 getInstLoc origin
 576   = do { loc <- getSrcLocM ; env <- getLclEnv ;
 577          return (InstLoc origin loc (tcl_ctxt env)) }
 578
 579 addInstCtxt :: InstLoc -> TcM a -> TcM a
 580 -- Add the SrcLoc and context from the first Inst in the list
 581 --      (they all have similar locations)
 582 addInstCtxt (InstLoc _ src_loc ctxt) thing_inside
 583   = addSrcLoc src_loc (updCtxt (\ old_ctxt -> ctxt) thing_inside)
 584 \end{code}
 585
 586     The addErrTc functions add an error message, but do not cause failure.
 587     The 'M' variants pass a TidyEnv that has already been used to
 588     tidy up the message; we then use it to tidy the context messages
 589
 590 \begin{code}
 591 addErrTc :: Message -> TcM ()
 592 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 593
 594 addErrsTc :: [Message] -> TcM ()
 595 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 596
 597 addErrTcM :: (TidyEnv, Message) -> TcM ()
 598 addErrTcM (tidy_env, err_msg)
 599   = do { ctxt <- getErrCtxt ;
 600          loc  <- getSrcLocM ;
 601          add_err_tcm tidy_env err_msg loc ctxt }
 602 \end{code}
 603
 604 The failWith functions add an error message and cause failure
 605
 606 \begin{code}
 607 failWithTc :: Message -> TcM a               -- Add an error message and fail
 608 failWithTc err_msg
 609   = addErrTc err_msg >> failM
 610
 611 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 612 failWithTcM local_and_msg
 613   = addErrTcM local_and_msg >> failM
 614
 615 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 616 checkTc True  err = returnM ()
 617 checkTc False err = failWithTc err
 618 \end{code}
 619
 620         Warnings have no 'M' variant, nor failure
 621
 622 \begin{code}
 623 addWarnTc :: Message -> TcM ()
 624 addWarnTc msg
 625  = do { ctxt <- getErrCtxt ;
 626         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 627         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 628
 629 warnTc :: Bool -> Message -> TcM ()
 630 warnTc warn_if_true warn_msg
 631   | warn_if_true = addWarnTc warn_msg
 632   | otherwise    = return ()
 633 \end{code}
 634
 635         Helper functions
 636
 637 \begin{code}
 638 add_err_tcm tidy_env err_msg loc ctxt
 639  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 640         addErrAt loc (vcat (err_msg : ctxt_to_use ctxt_msgs)) }
 641
 642 do_ctxt tidy_env []
 643  = return []
 644 do_ctxt tidy_env (c:cs)
 645  = do { (tidy_env', m) <- c tidy_env  ;
 646         ms             <- do_ctxt tidy_env' cs  ;
 647         return (m:ms) }
 648
 649 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 650                  | otherwise          = take 3 ctxt
 651 \end{code}
 652
 653 %************************************************************************
 654 %*                                                                      *
 655              Other stuff specific to type checker
 656 %*                                                                      *
 657 %************************************************************************
 658
 659 \begin{code}
 660 getLIEVar :: TcM (TcRef LIE)
 661 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 662
 663 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 664 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 665
 666 getLIE :: TcM a -> TcM (a, [Inst])
 667 -- (getLIE m) runs m, and returns the type constraints it generates
 668 getLIE thing_inside
 669   = do { lie_var <- newMutVar emptyLIE ;
 670          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 671                           thing_inside ;
 672          lie <- readMutVar lie_var ;
 673          return (res, lieToList lie) }
 674
 675 extendLIE :: Inst -> TcM ()
 676 extendLIE inst
 677   = do { lie_var <- getLIEVar ;
 678          lie <- readMutVar lie_var ;
 679          writeMutVar lie_var (inst `consLIE` lie) }
 680
 681 extendLIEs :: [Inst] -> TcM ()
 682 extendLIEs []
 683   = returnM ()
 684 extendLIEs insts
 685   = do { lie_var <- getLIEVar ;
 686          lie <- readMutVar lie_var ;
 687          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 688 \end{code}
 689
 690
 691 \begin{code}
 692 getStage :: TcM Stage
 693 getStage = do { env <- getLclEnv; return (tcl_level env) }
 694
 695 setStage :: Stage -> TcM a -> TcM a
 696 setStage s = updLclEnv (\ env -> env { tcl_level = s })
 697
 698 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 699 -- Set the local type envt, but do *not* disturb other fields,
 700 -- notably the lie_var
 701 setLclTypeEnv lcl_env thing_inside
 702   = updLclEnv upd thing_inside
 703   where
 704     upd env = env { tcl_env = tcl_env lcl_env,
 705                     tcl_tyvars = tcl_tyvars lcl_env }
 706 \end{code}
 707
 708
 709 %************************************************************************
 710 %*                                                                      *
 711              Stuff for the renamer's local env
 712 %*                                                                      *
 713 %************************************************************************
 714
 715 \begin{code}
 716 initRn :: RnMode -> RnM a -> TcRn m a
 717 initRn mode thing_inside
 718  = do { env <- getGblEnv ;
 719         let { lcl_env = RnLclEnv {
 720                              rn_mode = mode,
 721                              rn_lenv = emptyRdrEnv }} ;
 722         setLclEnv lcl_env thing_inside }
 723 \end{code}
 724
 725 \begin{code}
 726 getLocalRdrEnv :: RnM LocalRdrEnv
 727 getLocalRdrEnv = do { env <- getLclEnv; return (rn_lenv env) }
 728
 729 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 730 setLocalRdrEnv rdr_env thing_inside
 731   = updLclEnv (\env -> env {rn_lenv = rdr_env}) thing_inside
 732
 733 getModeRn :: RnM RnMode
 734 getModeRn = do { env <- getLclEnv; return (rn_mode env) }
 735 \end{code}
 736