ghc/compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[TcTyClsDecls]{Typecheck type and class declarations}
   5
   6 \begin{code}
   7 module TcTyClsDecls (
   8         tcTyAndClassDecls
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..),  HsConDetails(..), HsTyVarBndr(..),
  14                           ConDecl(..),   Sig(..), , NewOrData(..),
  15                           tyClDeclTyVars, isSynDecl, LConDecl,
  16                           LTyClDecl, tcdName, LHsTyVarBndr, LHsContext
  17                         )
  18 import HsTypes          ( HsBang(..), getBangStrictness )
  19 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
  20 import HscTypes         ( implicitTyThings )
  21 import BuildTyCl        ( buildClass, buildAlgTyCon, buildSynTyCon, buildDataCon,
  22                           mkDataTyConRhs, mkNewTyConRhs )
  23 import TcRnMonad
  24 import TcEnv            ( TcTyThing(..), TyThing(..),
  25                           tcLookupLocated, tcLookupLocatedGlobal,
  26                           tcExtendGlobalEnv, tcExtendKindEnv,
  27                           tcExtendRecEnv, tcLookupTyVar )
  28 import TcTyDecls        ( calcTyConArgVrcs, calcRecFlags, calcClassCycles, calcSynCycles )
  29 import TcClassDcl       ( tcClassSigs, tcAddDeclCtxt )
  30 import TcHsType         ( kcHsTyVars, kcHsLiftedSigType, kcHsType,
  31                           kcHsContext, tcTyVarBndrs, tcHsKindedType, tcHsKindedContext,
  32                           kcHsSigType, tcHsBangType, tcLHsConSig )
  33 import TcMType          ( newKindVar, checkValidTheta, checkValidType, checkFreeness,
  34                           UserTypeCtxt(..), SourceTyCtxt(..) )
  35 import TcUnify          ( unifyKind )
  36 import TcType           ( TcKind, ThetaType, TcType, tyVarsOfType,
  37                           mkArrowKind, liftedTypeKind, mkTyVarTys, tcEqTypes,
  38                           tcSplitSigmaTy, tcEqType )
  39 import Type             ( splitTyConApp_maybe, pprThetaArrow, pprParendType )
  40 import Generics         ( validGenericMethodType, canDoGenerics )
  41 import Class            ( Class, className, classTyCon, DefMeth(..), classBigSig, classTyVars )
  42 import TyCon            ( TyCon, ArgVrcs,
  43                           tyConDataCons, mkForeignTyCon, isProductTyCon, isRecursiveTyCon,
  44                           tyConStupidTheta, getSynTyConDefn, tyConDataCons, isSynTyCon, tyConName )
  45 import DataCon          ( DataCon, dataConWrapId, dataConName, dataConSig,
  46                           dataConFieldLabels, dataConOrigArgTys, dataConTyCon )
  47 import Type             ( zipTopTvSubst, substTys )
  48 import Var              ( TyVar, idType, idName )
  49 import VarSet           ( elemVarSet )
  50 import Name             ( Name )
  51 import Outputable
  52 import Util             ( zipLazy, isSingleton, notNull, sortLe )
  53 import List             ( partition )
  54 import SrcLoc           ( Located(..), unLoc, getLoc )
  55 import ListSetOps       ( equivClasses )
  56 import Digraph          ( SCC(..) )
  57 import CmdLineOpts      ( DynFlag( Opt_GlasgowExts, Opt_Generics, Opt_UnboxStrictFields ) )
  58 \end{code}
  59
  60
  61 %************************************************************************
  62 %*                                                                      *
  63 \subsection{Type checking for type and class declarations}
  64 %*                                                                      *
  65 %************************************************************************
  66
  67 Dealing with a group
  68 ~~~~~~~~~~~~~~~~~~~~
  69 Consider a mutually-recursive group, binding
  70 a type constructor T and a class C.
  71
  72 Step 1:         getInitialKind
  73         Construct a KindEnv by binding T and C to a kind variable
  74
  75 Step 2:         kcTyClDecl
  76         In that environment, do a kind check
  77
  78 Step 3: Zonk the kinds
  79
  80 Step 4:         buildTyConOrClass
  81         Construct an environment binding T to a TyCon and C to a Class.
  82         a) Their kinds comes from zonking the relevant kind variable
  83         b) Their arity (for synonyms) comes direct from the decl
  84         c) The funcional dependencies come from the decl
  85         d) The rest comes a knot-tied binding of T and C, returned from Step 4
  86         e) The variances of the tycons in the group is calculated from
  87                 the knot-tied stuff
  88
  89 Step 5:         tcTyClDecl1
  90         In this environment, walk over the decls, constructing the TyCons and Classes.
  91         This uses in a strict way items (a)-(c) above, which is why they must
  92         be constructed in Step 4. Feed the results back to Step 4.
  93         For this step, pass the is-recursive flag as the wimp-out flag
  94         to tcTyClDecl1.
  95
  96
  97 Step 6:         Extend environment
  98         We extend the type environment with bindings not only for the TyCons and Classes,
  99         but also for their "implicit Ids" like data constructors and class selectors
 100
 101 Step 7:         checkValidTyCl
 102         For a recursive group only, check all the decls again, just
 103         to check all the side conditions on validity.  We could not
 104         do this before because we were in a mutually recursive knot.
 105
 106
 107 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 108 @TyThing@s.  @rec_vrcs@ is a finite map from @Name@s to @ArgVrcs@s.
 109
 110 \begin{code}
 111 tcTyAndClassDecls :: [Name] -> [LTyClDecl Name]
 112                    -> TcM TcGblEnv      -- Input env extended by types and classes
 113                                         -- and their implicit Ids,DataCons
 114 tcTyAndClassDecls boot_names decls
 115   = do  {       -- First check for cyclic type synonysm or classes
 116                 -- See notes with checkCycleErrs
 117           checkCycleErrs decls
 118
 119         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(rec_syn_tycons, rec_alg_tyclss) ->
 120           do    { let { -- Calculate variances and rec-flag
 121                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc) decls }
 122
 123                         -- Extend the global env with the knot-tied results
 124                         -- for data types and classes
 125                         --
 126                         -- We must populate the environment with the loop-tied T's right
 127                         -- away, because the kind checker may "fault in" some type
 128                         -- constructors that recursively mention T
 129                 ; let { gbl_things = mkGlobalThings alg_decls rec_alg_tyclss }
 130                 ; tcExtendRecEnv gbl_things $ do
 131
 132                         -- Kind-check the declarations
 133                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
 134
 135                 ; let { calc_vrcs = calcTyConArgVrcs (rec_syn_tycons ++ rec_alg_tyclss)
 136                       ; calc_rec  = calcRecFlags boot_names rec_alg_tyclss
 137                       ; tc_decl   = addLocM (tcTyClDecl calc_vrcs calc_rec) }
 138                         -- Type-check the type synonyms, and extend the envt
 139                 ; syn_tycons <- tcSynDecls calc_vrcs kc_syn_decls
 140                 ; tcExtendGlobalEnv syn_tycons $ do
 141
 142                         -- Type-check the data types and classes
 143                 { alg_tyclss <- mappM tc_decl kc_alg_decls
 144                 ; return (syn_tycons, alg_tyclss)
 145             }}})
 146         -- Finished with knot-tying now
 147         -- Extend the environment with the finished things
 148         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
 149
 150         -- Perform the validity check
 151         { traceTc (text "ready for validity check")
 152         ; mappM_ (addLocM checkValidTyCl) decls
 153         ; traceTc (text "done")
 154
 155         -- Add the implicit things;
 156         -- we want them in the environment because
 157         -- they may be mentioned in interface files
 158         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
 159         ; traceTc ((text "Adding" <+> ppr alg_tyclss) $$ (text "and" <+> ppr implicit_things))
 160         ; tcExtendGlobalEnv implicit_things getGblEnv
 161     }}
 162
 163 mkGlobalThings :: [LTyClDecl Name]      -- The decls
 164                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
 165                -> [(Name,TyThing)]
 166 -- Driven by the Decls, and treating the TyThings lazily
 167 -- make a TypeEnv for the new things
 168 mkGlobalThings decls things
 169   = map mk_thing (decls `zipLazy` things)
 170   where
 171     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
 172          = (name, AClass cl)
 173     mk_thing (L _ decl, ~(ATyCon tc))
 174          = (tcdName decl, ATyCon tc)
 175 \end{code}
 176
 177
 178 %************************************************************************
 179 %*                                                                      *
 180                 Kind checking
 181 %*                                                                      *
 182 %************************************************************************
 183
 184 We need to kind check all types in the mutually recursive group
 185 before we know the kind of the type variables.  For example:
 186
 187 class C a where
 188    op :: D b => a -> b -> b
 189
 190 class D c where
 191    bop :: (Monad c) => ...
 192
 193 Here, the kind of the locally-polymorphic type variable "b"
 194 depends on *all the uses of class D*.  For example, the use of
 195 Monad c in bop's type signature means that D must have kind Type->Type.
 196
 197 However type synonyms work differently.  They can have kinds which don't
 198 just involve (->) and *:
 199         type R = Int#           -- Kind #
 200         type S a = Array# a     -- Kind * -> #
 201         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
 202 So we must infer their kinds from their right-hand sides *first* and then
 203 use them, whereas for the mutually recursive data types D we bring into
 204 scope kind bindings D -> k, where k is a kind variable, and do inference.
 205
 206 \begin{code}
 207 kcTyClDecls syn_decls alg_decls
 208   = do  {       -- First extend the kind env with each data
 209                 -- type and class, mapping them to a type variable
 210           alg_kinds <- mappM getInitialKind alg_decls
 211         ; tcExtendKindEnv alg_kinds $ do
 212
 213                 -- Now kind-check the type synonyms, in dependency order
 214                 -- We do these differently to data type and classes,
 215                 -- because a type synonym can be an unboxed type
 216                 --      type Foo = Int#
 217                 -- and a kind variable can't unify with UnboxedTypeKind
 218                 -- So we infer their kinds in dependency order
 219         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
 220         ; tcExtendKindEnv syn_kinds $  do
 221
 222                 -- Now kind-check the data type and class declarations,
 223                 -- returning kind-annotated decls
 224         { kc_alg_decls <- mappM (wrapLocM kcTyClDecl) alg_decls
 225
 226         ; return (kc_syn_decls, kc_alg_decls) }}}
 227
 228 ------------------------------------------------------------------------
 229 getInitialKind :: LTyClDecl Name -> TcM (Name, TcKind)
 230
 231 getInitialKind decl
 232  = newKindVar                   `thenM` \ kind  ->
 233    returnM (unLoc (tcdLName (unLoc decl)), kind)
 234
 235 ----------------
 236 kcSynDecls :: [SCC (LTyClDecl Name)]
 237            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
 238                    [(Name,TcKind)])     -- Kind bindings
 239 kcSynDecls []
 240   = return ([], [])
 241 kcSynDecls (group : groups)
 242   = do  { (decl,  nk)  <- kcSynDecl group
 243         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
 244         ; return (decl:decls, nk:nks) }
 245
 246 ----------------
 247 kcSynDecl :: SCC (LTyClDecl Name)
 248            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
 249                    (Name,TcKind))       -- Kind bindings
 250 kcSynDecl (AcyclicSCC ldecl@(L loc decl))
 251   = tcAddDeclCtxt decl  $
 252     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
 253     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl))
 254                         <+> brackets (ppr k_tvs))
 255        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
 256        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
 257        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
 258        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
 259                  (unLoc (tcdLName decl), tc_kind)) })
 260
 261 kcSynDecl (CyclicSCC decls)
 262   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
 263                                         -- of out-of-scope tycons
 264
 265 ------------------------------------------------------------------------
 266 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
 267         -- Not used for type synonyms (see kcSynDecl)
 268
 269 kcTyClDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
 270   = kcTyClDeclBody decl $ \ tvs' ->
 271     do  { ctxt' <- kcHsContext ctxt
 272         ; cons' <- mappM (wrapLocM kc_con_decl) cons
 273         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdCons = cons'}) }
 274   where
 275     kc_con_decl (ConDecl name ex_tvs ex_ctxt details)
 276       = kcHsTyVars ex_tvs               $ \ ex_tvs' ->
 277         do { ex_ctxt' <- kcHsContext ex_ctxt
 278            ; details' <- kc_con_details details
 279            ; return (ConDecl name ex_tvs' ex_ctxt' details')}
 280     kc_con_decl (GadtDecl name ty)
 281         = do { ty' <- kcHsSigType ty
 282              ; return (GadtDecl name ty') }
 283
 284     kc_con_details (PrefixCon btys)
 285         = do { btys' <- mappM kc_larg_ty btys ; return (PrefixCon btys') }
 286     kc_con_details (InfixCon bty1 bty2)
 287         = do { bty1' <- kc_larg_ty bty1; bty2' <- kc_larg_ty bty2; return (InfixCon bty1' bty2') }
 288     kc_con_details (RecCon fields)
 289         = do { fields' <- mappM kc_field fields; return (RecCon fields') }
 290
 291     kc_field (fld, bty) = do { bty' <- kc_larg_ty bty ; return (fld, bty') }
 292
 293     kc_larg_ty bty = case new_or_data of
 294                         DataType -> kcHsSigType bty
 295                         NewType  -> kcHsLiftedSigType bty
 296         -- Can't allow an unlifted type for newtypes, because we're effectively
 297         -- going to remove the constructor while coercing it to a lifted type.
 298         -- And newtypes can't be bang'd
 299
 300 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt,  tcdSigs = sigs})
 301   = kcTyClDeclBody decl $ \ tvs' ->
 302     do  { ctxt' <- kcHsContext ctxt
 303         ; sigs' <- mappM (wrapLocM kc_sig) sigs
 304         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs'}) }
 305   where
 306     kc_sig (Sig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
 307                                 ; return (Sig nm op_ty') }
 308     kc_sig other_sig          = return other_sig
 309
 310 kcTyClDecl decl@(ForeignType {})
 311   = return decl
 312
 313 kcTyClDeclBody :: TyClDecl Name
 314                -> ([LHsTyVarBndr Name] -> TcM a)
 315                -> TcM a
 316   -- Extend the env with bindings for the tyvars, taken from
 317   -- the kind of the tycon/class.  Give it to the thing inside, and
 318   -- check the result kind matches
 319 kcTyClDeclBody decl thing_inside
 320   = tcAddDeclCtxt decl          $
 321     kcHsTyVars (tyClDeclTyVars decl)    $ \ kinded_tvs ->
 322     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 323         ; let tc_kind = case tc_ty_thing of { AThing k -> k }
 324         ; unifyKind tc_kind (foldr (mkArrowKind . kindedTyVarKind)
 325                                    (result_kind decl)
 326                                    kinded_tvs)
 327         ; thing_inside kinded_tvs }
 328   where
 329     result_kind (TyData { tcdKindSig = Just kind }) = kind
 330     result_kind other                              = liftedTypeKind
 331         -- On GADT-style declarations we allow a kind signature
 332         --      data T :: *->* where { ... }
 333
 334 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
 335 \end{code}
 336
 337
 338 %************************************************************************
 339 %*                                                                      *
 340 \subsection{Type checking}
 341 %*                                                                      *
 342 %************************************************************************
 343
 344 \begin{code}
 345 tcSynDecls :: (Name -> ArgVrcs) -> [LTyClDecl Name] -> TcM [TyThing]
 346 tcSynDecls calc_vrcs [] = return []
 347 tcSynDecls calc_vrcs (decl : decls)
 348   = do { syn_tc <- addLocM (tcSynDecl calc_vrcs) decl
 349        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls calc_vrcs decls)
 350        ; return (syn_tc : syn_tcs) }
 351
 352 tcSynDecl calc_vrcs
 353   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
 354   = tcTyVarBndrs tvs            $ \ tvs' -> do
 355     { traceTc (text "tcd1" <+> ppr tc_name)
 356     ; rhs_ty' <- tcHsKindedType rhs_ty
 357     ; return (ATyCon (buildSynTyCon tc_name tvs' rhs_ty' (calc_vrcs tc_name))) }
 358
 359 --------------------
 360 tcTyClDecl :: (Name -> ArgVrcs) -> (Name -> RecFlag)
 361            -> TyClDecl Name -> TcM TyThing
 362
 363 tcTyClDecl calc_vrcs calc_isrec decl
 364   = tcAddDeclCtxt decl (tcTyClDecl1 calc_vrcs calc_isrec decl)
 365
 366 tcTyClDecl1 calc_vrcs calc_isrec
 367   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 368            tcdLName = L _ tc_name, tcdCons = cons})
 369   = tcTyVarBndrs tvs            $ \ tvs' -> do
 370   { stupid_theta <- tcStupidTheta ctxt cons
 371   ; want_generic <- doptM Opt_Generics
 372   ; tycon <- fixM (\ tycon -> do
 373         { unbox_strict <- doptM Opt_UnboxStrictFields
 374         ; data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data tycon tvs')) cons
 375         ; let tc_rhs = case new_or_data of
 376                         DataType -> mkDataTyConRhs stupid_theta data_cons
 377                         NewType  -> ASSERT( isSingleton data_cons )
 378                                     mkNewTyConRhs tycon (head data_cons)
 379         ; buildAlgTyCon tc_name tvs' tc_rhs arg_vrcs is_rec
 380                         (want_generic && canDoGenerics data_cons)
 381         })
 382   ; return (ATyCon tycon)
 383   }
 384   where
 385     arg_vrcs = calc_vrcs tc_name
 386     is_rec   = calc_isrec tc_name
 387
 388 tcTyClDecl1 calc_vrcs calc_isrec
 389   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs,
 390               tcdCtxt = ctxt, tcdMeths = meths,
 391               tcdFDs = fundeps, tcdSigs = sigs} )
 392   = tcTyVarBndrs tvs            $ \ tvs' -> do
 393   { ctxt' <- tcHsKindedContext ctxt
 394   ; fds' <- mappM (addLocM tc_fundep) fundeps
 395   ; sig_stuff <- tcClassSigs class_name sigs meths
 396   ; clas <- fixM (\ clas ->
 397                 let     -- This little knot is just so we can get
 398                         -- hold of the name of the class TyCon, which we
 399                         -- need to look up its recursiveness and variance
 400                     tycon_name = tyConName (classTyCon clas)
 401                     tc_isrec = calc_isrec tycon_name
 402                     tc_vrcs  = calc_vrcs  tycon_name
 403                 in
 404                 buildClass class_name tvs' ctxt' fds'
 405                            sig_stuff tc_isrec tc_vrcs)
 406   ; return (AClass clas) }
 407   where
 408     tc_fundep (tvs1, tvs2) = do { tvs1' <- mappM tcLookupTyVar tvs1 ;
 409                                 ; tvs2' <- mappM tcLookupTyVar tvs2 ;
 410                                 ; return (tvs1', tvs2') }
 411
 412
 413 tcTyClDecl1 calc_vrcs calc_isrec
 414   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
 415   = returnM (ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0 []))
 416
 417 -----------------------------------
 418 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
 419           -> NewOrData -> TyCon -> [TyVar]
 420           -> ConDecl Name -> TcM DataCon
 421
 422 tcConDecl unbox_strict NewType tycon tc_tvs     -- Newtypes
 423           (ConDecl name ex_tvs ex_ctxt details)
 424   = ASSERT( null ex_tvs && null (unLoc ex_ctxt) )
 425     do  { let tc_datacon field_lbls arg_ty
 426                 = do { arg_ty' <- tcHsKindedType arg_ty -- No bang on newtype
 427                      ; buildDataCon (unLoc name) False {- Prefix -}
 428                                     True {- Vanilla -} [NotMarkedStrict]
 429                                     (map unLoc field_lbls)
 430                                     tc_tvs [] [arg_ty']
 431                                     tycon (mkTyVarTys tc_tvs) }
 432         ; case details of
 433             PrefixCon [arg_ty] -> tc_datacon [] arg_ty
 434             RecCon [(field_lbl, arg_ty)] -> tc_datacon [field_lbl] arg_ty }
 435
 436 tcConDecl unbox_strict DataType tycon tc_tvs    -- Ordinary data types
 437           (ConDecl name ex_tvs ex_ctxt details)
 438   = tcTyVarBndrs ex_tvs         $ \ ex_tvs' -> do
 439     { ex_ctxt' <- tcHsKindedContext ex_ctxt
 440     ; let
 441         is_vanilla = null ex_tvs && null (unLoc ex_ctxt)
 442                 -- Vanilla iff no ex_tvs and no context
 443
 444         tc_datacon is_infix field_lbls btys
 445           = do { let { bangs = map getBangStrictness btys }
 446                ; arg_tys <- mappM tcHsBangType btys
 447                ; buildDataCon (unLoc name) is_infix is_vanilla
 448                     (argStrictness unbox_strict tycon bangs arg_tys)
 449                     (map unLoc field_lbls)
 450                     (tc_tvs ++ ex_tvs')
 451                     ex_ctxt'
 452                     arg_tys
 453                     tycon (mkTyVarTys tc_tvs) }
 454     ; case details of
 455         PrefixCon btys     -> tc_datacon False [] btys
 456         InfixCon bty1 bty2 -> tc_datacon True [] [bty1,bty2]
 457         RecCon fields      -> do { checkTc is_vanilla (exRecConErr name)
 458                                  ; let { (field_names, btys) = unzip fields }
 459                                  ; tc_datacon False field_names btys } }
 460
 461 tcConDecl unbox_strict DataType tycon tc_tvs    -- GADTs
 462           decl@(GadtDecl name con_ty)
 463   = do  { traceTc (text "tcConDecl"  <+> ppr name)
 464         ; (tvs, theta, bangs, arg_tys, tc, res_tys) <- tcLHsConSig con_ty
 465
 466         ; traceTc (text "tcConDecl1"  <+> ppr name)
 467         ; let   -- Now dis-assemble the type, and check its form
 468               is_vanilla = null theta && mkTyVarTys tvs `tcEqTypes` res_tys
 469
 470                 -- Vanilla datacons guarantee to use the same
 471                 -- type variables as the parent tycon
 472               (tvs', arg_tys', res_tys')
 473                   | is_vanilla = (tc_tvs, substTys subst arg_tys, substTys subst res_tys)
 474                   | otherwise  = (tvs, arg_tys, res_tys)
 475               subst = zipTopTvSubst tvs (mkTyVarTys tc_tvs)
 476
 477         ; traceTc (text "tcConDecl3"  <+> ppr name)
 478         ; buildDataCon (unLoc name) False {- Not infix -} is_vanilla
 479                        (argStrictness unbox_strict tycon bangs arg_tys)
 480                        [{- No field labels -}]
 481                        tvs' theta arg_tys' tycon res_tys' }
 482
 483 -------------------
 484 tcStupidTheta :: LHsContext Name -> [LConDecl Name] -> TcM (Maybe ThetaType)
 485 -- For GADTs we don't allow a context on the data declaration
 486 -- whereas for standard Haskell style data declarations, we do
 487 tcStupidTheta ctxt (L _ (ConDecl _ _ _ _) : _)
 488   = do { theta <- tcHsKindedContext ctxt; return (Just theta) }
 489 tcStupidTheta ctxt other        -- Includes an empty constructor list
 490   = ASSERT( null (unLoc ctxt) ) return Nothing
 491
 492 -------------------
 493 argStrictness :: Bool           -- True <=> -funbox-strict_fields
 494               -> TyCon -> [HsBang]
 495               -> [TcType] -> [StrictnessMark]
 496 argStrictness unbox_strict tycon bangs arg_tys
 497  = ASSERT( length bangs == length arg_tys )
 498    zipWith (chooseBoxingStrategy unbox_strict tycon) arg_tys bangs
 499
 500 -- We attempt to unbox/unpack a strict field when either:
 501 --   (i)  The field is marked '!!', or
 502 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
 503
 504 chooseBoxingStrategy :: Bool -> TyCon -> TcType -> HsBang -> StrictnessMark
 505 chooseBoxingStrategy unbox_strict_fields tycon arg_ty bang
 506   = case bang of
 507         HsNoBang                                    -> NotMarkedStrict
 508         HsStrict | unbox_strict_fields && can_unbox -> MarkedUnboxed
 509         HsUnbox  | can_unbox                        -> MarkedUnboxed
 510         other                                       -> MarkedStrict
 511   where
 512     can_unbox = case splitTyConApp_maybe arg_ty of
 513                    Nothing             -> False
 514                    Just (arg_tycon, _) -> not (isRecursiveTyCon tycon) &&
 515                                           isProductTyCon arg_tycon
 516 \end{code}
 517
 518 %************************************************************************
 519 %*                                                                      *
 520 \subsection{Dependency analysis}
 521 %*                                                                      *
 522 %************************************************************************
 523
 524 Validity checking is done once the mutually-recursive knot has been
 525 tied, so we can look at things freely.
 526
 527 \begin{code}
 528 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
 529 checkCycleErrs tyclss
 530   | null cls_cycles
 531   = return ()
 532   | otherwise
 533   = do  { mappM_ recClsErr cls_cycles
 534         ; failM }       -- Give up now, because later checkValidTyCl
 535                         -- will loop if the synonym is recursive
 536   where
 537     cls_cycles = calcClassCycles tyclss
 538
 539 checkValidTyCl :: TyClDecl Name -> TcM ()
 540 -- We do the validity check over declarations, rather than TyThings
 541 -- only so that we can add a nice context with tcAddDeclCtxt
 542 checkValidTyCl decl
 543   = tcAddDeclCtxt decl $
 544     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
 545         ; traceTc (text "Validity of" <+> ppr thing)
 546         ; case thing of
 547             ATyCon tc -> checkValidTyCon tc
 548             AClass cl -> checkValidClass cl
 549         ; traceTc (text "Done validity of" <+> ppr thing)
 550         }
 551
 552 -------------------------
 553 checkValidTyCon :: TyCon -> TcM ()
 554 checkValidTyCon tc
 555   | isSynTyCon tc
 556   = checkValidType syn_ctxt syn_rhs
 557   | otherwise
 558   =     -- Check the context on the data decl
 559     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)     `thenM_`
 560
 561         -- Check arg types of data constructors
 562     mappM_ (checkValidDataCon tc) data_cons                     `thenM_`
 563
 564         -- Check that fields with the same name share a type
 565     mappM_ check_fields groups
 566
 567   where
 568     syn_ctxt     = TySynCtxt name
 569     name         = tyConName tc
 570     (_, syn_rhs) = getSynTyConDefn tc
 571     data_cons    = tyConDataCons tc
 572
 573     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
 574     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
 575     get_fields con = dataConFieldLabels con `zip` dataConOrigArgTys con
 576         -- dataConFieldLabels may return the empty list, which is fine
 577
 578     check_fields fields@((first_field_label, field_ty) : other_fields)
 579         -- These fields all have the same name, but are from
 580         -- different constructors in the data type
 581         =       -- Check that all the fields in the group have the same type
 582                 -- NB: this check assumes that all the constructors of a given
 583                 -- data type use the same type variables
 584           checkTc (all (tcEqType field_ty . snd) other_fields)
 585                   (fieldTypeMisMatch first_field_label)
 586
 587 -------------------------------
 588 checkValidDataCon :: TyCon -> DataCon -> TcM ()
 589 checkValidDataCon tc con
 590   = addErrCtxt (dataConCtxt con) $
 591     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
 592         ; checkValidType ctxt (idType (dataConWrapId con)) }
 593
 594                 -- This checks the argument types and
 595                 -- ambiguity of the existential context (if any)
 596                 --
 597                 -- Note [Sept 04] Now that tvs is all the tvs, this
 598                 -- test doesn't actually check anything
 599 --      ; checkFreeness tvs ex_theta }
 600   where
 601     ctxt = ConArgCtxt (dataConName con)
 602     (tvs, ex_theta, _, _, _) = dataConSig con
 603
 604
 605 -------------------------------
 606 checkValidClass :: Class -> TcM ()
 607 checkValidClass cls
 608   = do  {       -- CHECK ARITY 1 FOR HASKELL 1.4
 609           gla_exts <- doptM Opt_GlasgowExts
 610
 611         -- Check that the class is unary, unless GlaExs
 612         ; checkTc (notNull tyvars) (nullaryClassErr cls)
 613         ; checkTc (gla_exts || unary) (classArityErr cls)
 614
 615         -- Check the super-classes
 616         ; checkValidTheta (ClassSCCtxt (className cls)) theta
 617
 618         -- Check the class operations
 619         ; mappM_ check_op op_stuff
 620
 621         -- Check that if the class has generic methods, then the
 622         -- class has only one parameter.  We can't do generic
 623         -- multi-parameter type classes!
 624         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
 625         }
 626   where
 627     (tyvars, theta, _, op_stuff) = classBigSig cls
 628     unary       = isSingleton tyvars
 629     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
 630
 631     check_op (sel_id, dm)
 632       = addErrCtxt (classOpCtxt sel_id tau) $ do
 633         { checkValidTheta SigmaCtxt (tail theta)
 634                 -- The 'tail' removes the initial (C a) from the
 635                 -- class itself, leaving just the method type
 636
 637         ; checkValidType (FunSigCtxt op_name) tau
 638
 639                 -- Check that the type mentions at least one of
 640                 -- the class type variables
 641         ; checkTc (any (`elemVarSet` tyVarsOfType tau) tyvars)
 642                   (noClassTyVarErr cls sel_id)
 643
 644                 -- Check that for a generic method, the type of
 645                 -- the method is sufficiently simple
 646         ; checkTc (dm /= GenDefMeth || validGenericMethodType op_ty)
 647                   (badGenericMethodType op_name op_ty)
 648         }
 649         where
 650           op_name = idName sel_id
 651           op_ty   = idType sel_id
 652           (_,theta,tau) = tcSplitSigmaTy op_ty
 653
 654
 655
 656 ---------------------------------------------------------------------
 657 fieldTypeMisMatch field_name
 658   = sep [ptext SLIT("Different constructors give different types for field"), quotes (ppr field_name)]
 659
 660 dataConCtxt con = sep [ptext SLIT("When checking the data constructor:"),
 661                        nest 2 (ex_part <+> pprThetaArrow ex_theta <+> ppr con <+> arg_part)]
 662   where
 663     (ex_tvs, ex_theta, arg_tys, _, _) = dataConSig con
 664     ex_part | null ex_tvs = empty
 665             | otherwise   = ptext SLIT("forall") <+> hsep (map ppr ex_tvs) <> dot
 666         -- The 'ex_theta' part could be non-empty, if the user (bogusly) wrote
 667         --      data T a = Eq a => T a a
 668         -- So we make sure to print it
 669
 670     fields = dataConFieldLabels con
 671     arg_part | null fields = sep (map pprParendType arg_tys)
 672              | otherwise   = braces (sep (punctuate comma
 673                              [ ppr n <+> dcolon <+> ppr ty
 674                              | (n,ty) <- fields `zip` arg_tys]))
 675
 676 classOpCtxt sel_id tau = sep [ptext SLIT("When checking the class method:"),
 677                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
 678
 679 nullaryClassErr cls
 680   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
 681
 682 classArityErr cls
 683   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
 684           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
 685
 686 noClassTyVarErr clas op
 687   = sep [ptext SLIT("The class method") <+> quotes (ppr op),
 688          ptext SLIT("mentions none of the type variables of the class") <+>
 689                 ppr clas <+> hsep (map ppr (classTyVars clas))]
 690
 691 genericMultiParamErr clas
 692   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 693     ptext SLIT("cannot have generic methods")
 694
 695 badGenericMethodType op op_ty
 696   = hang (ptext SLIT("Generic method type is too complex"))
 697        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 698                 ptext SLIT("You can only use type variables, arrows, and tuples")])
 699
 700 recSynErr syn_decls
 701   = setSrcSpan (getLoc (head sorted_decls)) $
 702     addErr (sep [ptext SLIT("Cycle in type synonym declarations:"),
 703                  nest 2 (vcat (map ppr_decl sorted_decls))])
 704   where
 705     sorted_decls = sortLocated syn_decls
 706     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
 707
 708 recClsErr cls_decls
 709   = setSrcSpan (getLoc (head sorted_decls)) $
 710     addErr (sep [ptext SLIT("Cycle in class declarations (via superclasses):"),
 711                  nest 2 (vcat (map ppr_decl sorted_decls))])
 712   where
 713     sorted_decls = sortLocated cls_decls
 714     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
 715
 716 sortLocated :: [Located a] -> [Located a]
 717 sortLocated things = sortLe le things
 718   where
 719     le (L l1 _) (L l2 _) = l1 <= l2
 720
 721 exRecConErr name
 722   = ptext SLIT("Can't combine named fields with locally-quantified type variables or context")
 723     $$
 724     (ptext SLIT("In the declaration of data constructor") <+> ppr name)
 725
 726 badDataConTyCon data_con
 727   = hang (ptext SLIT("Data constructor does not return its parent type:"))
 728        2 (ppr data_con)
 729 \end{code}