ghc/compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[TcTyClsDecls]{Typecheck type and class declarations}
   5
   6 \begin{code}
   7 module TcTyClsDecls (
   8         tcTyAndClassDecls
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( HsDecl(..), TyClDecl(..),
  14                           HsType(..), HsTyVarBndr,
  15                           ConDecl(..), ConDetails(..),
  16                           Sig(..), HsPred(..), HsTupCon(..),
  17                           tyClDeclName, hsTyVarNames, isClassDecl, isSynDecl, isClassOpSig, getBangType
  18                         )
  19 import RnHsSyn          ( RenamedHsDecl, RenamedTyClDecl, listTyCon_name )
  20 import BasicTypes       ( RecFlag(..), NewOrData(..) )
  21
  22 import TcMonad
  23 import TcEnv            ( ValueEnv, TyThing(..), TyThingDetails(..), tyThingKind,
  24                           tcExtendTypeEnv, tcExtendKindEnv, tcLookupTy
  25                         )
  26 import TcTyDecls        ( tcTyDecl1, kcConDetails, mkNewTyConRep )
  27 import TcClassDcl       ( tcClassDecl1 )
  28 import TcMonoType       ( kcHsTyVars, kcHsType, kcHsBoxedSigType, kcHsContext, mkTyClTyVars )
  29 import TcType           ( TcKind, newKindVar, zonkKindEnv )
  30
  31 import TcUnify          ( unifyKind )
  32 import TcInstDcls       ( tcAddDeclCtxt )
  33 import Type             ( Kind, mkArrowKind, boxedTypeKind, zipFunTys )
  34 import Variance         ( calcTyConArgVrcs )
  35 import Class            ( Class, mkClass, classTyCon )
  36 import TyCon            ( TyCon, ArgVrcs, AlgTyConFlavour(..), mkSynTyCon, mkAlgTyConRep, mkClassTyCon )
  37 import DataCon          ( isNullaryDataCon )
  38 import Var              ( varName )
  39 import FiniteMap
  40 import Digraph          ( stronglyConnComp, SCC(..) )
  41 import Name             ( Name, NamedThing(..), NameEnv, getSrcLoc, isTvOcc, nameOccName,
  42                           mkNameEnv, lookupNameEnv_NF
  43                         )
  44 import Outputable
  45 import Maybes           ( mapMaybe, catMaybes )
  46 import UniqSet          ( emptyUniqSet, unitUniqSet, unionUniqSets,
  47                           unionManyUniqSets, uniqSetToList )
  48 import ErrUtils         ( Message )
  49 import Unique           ( Unique, Uniquable(..) )
  50 import HsDecls          ( fromClassDeclNameList )
  51 import Generics         ( mkTyConGenInfo )
  52 \end{code}
  53
  54
  55 %************************************************************************
  56 %*                                                                      *
  57 \subsection{Type checking for type and class declarations}
  58 %*                                                                      *
  59 %************************************************************************
  60
  61 The main function
  62 ~~~~~~~~~~~~~~~~~
  63 \begin{code}
  64 tcTyAndClassDecls :: ValueEnv           -- Knot tying stuff
  65                   -> [RenamedHsDecl]
  66                   -> TcM s TcEnv
  67
  68 tcTyAndClassDecls unf_env decls
  69   = sortByDependency decls              `thenTc` \ groups ->
  70     tcGroups unf_env groups
  71
  72 tcGroups unf_env []
  73   = tcGetEnv    `thenNF_Tc` \ env ->
  74     returnTc env
  75
  76 tcGroups unf_env (group:groups)
  77   = tcGroup unf_env group       `thenTc` \ env ->
  78     tcSetEnv env                        $
  79     tcGroups unf_env groups
  80 \end{code}
  81
  82 Dealing with a group
  83 ~~~~~~~~~~~~~~~~~~~~
  84 Consider a mutually-recursive group, binding
  85 a type constructor T and a class C.
  86
  87 Step 1:         getInitialKind
  88         Construct a KindEnv by binding T and C to a kind variable
  89
  90 Step 2:         kcTyClDecl
  91         In that environment, do a kind check
  92
  93 Step 3: Zonk the kinds
  94
  95 Step 4:         buildTyConOrClass
  96         Construct an environment binding T to a TyCon and C to a Class.
  97         a) Their kinds comes from zonking the relevant kind variable
  98         b) Their arity (for synonyms) comes direct from the decl
  99         c) The funcional dependencies come from the decl
 100         d) The rest comes a knot-tied binding of T and C, returned from Step 4
 101         e) The variances of the tycons in the group is calculated from
 102                 the knot-tied stuff
 103
 104 Step 5:         tcTyClDecl1
 105         In this environment, walk over the decls, constructing the TyCons and Classes.
 106         This uses in a strict way items (a)-(c) above, which is why they must
 107         be constructed in Step 4.
 108         Feed the results back to Step 4.
 109
 110 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 111 @TyThing@s.  @rec_vrcs@ is a finite map from @Name@s to @ArgVrcs@s.
 112
 113 \begin{code}
 114 tcGroup :: ValueEnv -> SCC RenamedTyClDecl -> TcM s TcEnv
 115 tcGroup unf_env scc
 116   =     -- Step 1
 117     mapNF_Tc getInitialKind decls                               `thenNF_Tc` \ initial_kinds ->
 118
 119         -- Step 2
 120     tcExtendKindEnv initial_kinds (mapTc kcTyClDecl decls)      `thenTc_`
 121
 122         -- Step 3
 123     zonkKindEnv initial_kinds                   `thenNF_Tc` \ final_kinds ->
 124
 125         -- Tie the knot
 126     fixTc ( \ ~(rec_details_list,  _) ->
 127                 -- Step 4
 128         let
 129             kind_env    = mkNameEnv final_kinds
 130             rec_details = mkNameEnv rec_details_list
 131
 132             tyclss, all_tyclss :: [(Name, TyThing)]
 133             tyclss = map (buildTyConOrClass is_rec kind_env rec_vrcs rec_details) decls
 134
 135                 -- Add the tycons that come from the classes
 136                 -- We want them in the environment because
 137                 -- they are mentioned in interface files
 138             all_tyclss  = [ (getName tycon, ATyCon tycon) | (_, AClass clas) <- tyclss,
 139                                                             let tycon = classTyCon clas
 140                           ] ++ tyclss
 141
 142                 -- Calculate variances, and (yes!) feed back into buildTyConOrClass.
 143             rec_vrcs    = calcTyConArgVrcs [tc | (_, ATyCon tc) <- all_tyclss]
 144         in
 145                 -- Step 5
 146         tcExtendTypeEnv all_tyclss              $
 147         mapTc (tcTyClDecl1 unf_env) decls       `thenTc` \ tycls_details ->
 148         tcGetEnv                                `thenNF_Tc` \ env ->
 149         returnTc (tycls_details, env)
 150     )                                           `thenTc` \ (_, env) ->
 151     returnTc env
 152   where
 153     is_rec = case scc of
 154                 AcyclicSCC _ -> NonRecursive
 155                 CyclicSCC _  -> Recursive
 156
 157     decls = case scc of
 158                 AcyclicSCC decl -> [decl]
 159                 CyclicSCC decls -> decls
 160
 161 tcTyClDecl1 unf_env decl
 162   = tcAddDeclCtxt decl                  $
 163     if isClassDecl decl then
 164         tcClassDecl1 unf_env decl
 165     else
 166         tcTyDecl1 decl
 167 \end{code}
 168
 169
 170 %************************************************************************
 171 %*                                                                      *
 172 \subsection{Step 1: Initial environment}
 173 %*                                                                      *
 174 %************************************************************************
 175
 176 \begin{code}
 177 getInitialKind :: RenamedTyClDecl -> NF_TcM s (Name, TcKind)
 178 getInitialKind (TySynonym name tyvars _ _)
 179  = kcHsTyVars tyvars    `thenNF_Tc` \ arg_kinds ->
 180    newKindVar           `thenNF_Tc` \ result_kind  ->
 181    returnNF_Tc (name, mk_kind arg_kinds result_kind)
 182
 183 getInitialKind (TyData _ _ name tyvars _ _ _ _ _ _ _)
 184  = kcHsTyVars tyvars    `thenNF_Tc` \ arg_kinds ->
 185    returnNF_Tc (name, mk_kind arg_kinds boxedTypeKind)
 186
 187 getInitialKind (ClassDecl _ name tyvars _ _ _ _ _ _ )
 188  = kcHsTyVars tyvars    `thenNF_Tc` \ arg_kinds ->
 189    returnNF_Tc (name, mk_kind arg_kinds boxedTypeKind)
 190
 191 mk_kind tvs_w_kinds res_kind = foldr (mkArrowKind . snd) res_kind tvs_w_kinds
 192 \end{code}
 193
 194
 195 %************************************************************************
 196 %*                                                                      *
 197 \subsection{Step 2: Kind checking}
 198 %*                                                                      *
 199 %************************************************************************
 200
 201 We need to kind check all types in the mutually recursive group
 202 before we know the kind of the type variables.  For example:
 203
 204 class C a where
 205    op :: D b => a -> b -> b
 206
 207 class D c where
 208    bop :: (Monad c) => ...
 209
 210 Here, the kind of the locally-polymorphic type variable "b"
 211 depends on *all the uses of class D*.  For example, the use of
 212 Monad c in bop's type signature means that D must have kind Type->Type.
 213
 214 \begin{code}
 215 kcTyClDecl :: RenamedTyClDecl -> TcM s ()
 216
 217 kcTyClDecl decl@(TySynonym tycon_name hs_tyvars rhs loc)
 218   = tcAddDeclCtxt decl                  $
 219     kcTyClDeclBody tycon_name hs_tyvars $ \ result_kind ->
 220     kcHsType rhs                        `thenTc` \ rhs_kind ->
 221     unifyKind result_kind rhs_kind
 222
 223 kcTyClDecl decl@(TyData _ context tycon_name hs_tyvars con_decls _ _ _ loc _ _)
 224   = tcAddDeclCtxt decl                  $
 225     kcTyClDeclBody tycon_name hs_tyvars $ \ result_kind ->
 226     kcHsContext context                 `thenTc_`
 227     mapTc_ kc_con_decl con_decls
 228   where
 229     kc_con_decl (ConDecl _ _ ex_tvs ex_ctxt details loc)
 230       = tcAddSrcLoc loc                 $
 231         kcHsTyVars ex_tvs               `thenNF_Tc` \ kind_env ->
 232         tcExtendKindEnv kind_env        $
 233         kcConDetails ex_ctxt details
 234
 235 kcTyClDecl decl@(ClassDecl context class_name
 236                            hs_tyvars fundeps class_sigs
 237                            _ _ _ loc)
 238   = tcAddDeclCtxt decl                  $
 239     kcTyClDeclBody class_name hs_tyvars $ \ result_kind ->
 240     kcHsContext context                 `thenTc_`
 241     mapTc_ kc_sig (filter isClassOpSig class_sigs)
 242   where
 243     kc_sig (ClassOpSig _ _ op_ty loc) = tcAddSrcLoc loc (kcHsBoxedSigType op_ty)
 244
 245 kcTyClDeclBody :: Name -> [HsTyVarBndr Name]    -- Kind of the tycon/cls and its tyvars
 246                -> (Kind -> TcM s a)             -- Thing inside
 247                -> TcM s a
 248 -- Extend the env with bindings for the tyvars, taken from
 249 -- the kind of the tycon/class.  Give it to the thing inside, and
 250 -- check the result kind matches
 251 kcTyClDeclBody tc_name hs_tyvars thing_inside
 252   = tcLookupTy tc_name          `thenNF_Tc` \ tc ->
 253     let
 254         (tyvars_w_kinds, result_kind) = zipFunTys (hsTyVarNames hs_tyvars) (tyThingKind tc)
 255     in
 256     tcExtendKindEnv tyvars_w_kinds (thing_inside result_kind)
 257 \end{code}
 258
 259
 260 %************************************************************************
 261 %*                                                                      *
 262 \subsection{Step 4: Building the tycon/class}
 263 %*                                                                      *
 264 %************************************************************************
 265
 266 \begin{code}
 267 buildTyConOrClass
 268         :: RecFlag -> NameEnv Kind
 269         -> FiniteMap TyCon ArgVrcs -> NameEnv TyThingDetails
 270         -> RenamedTyClDecl -> (Name, TyThing)
 271         -- Can't fail; the only reason it's in the monad
 272         -- is so it can zonk the kinds
 273
 274 buildTyConOrClass is_rec kenv rec_vrcs rec_details
 275                   (TySynonym tycon_name tyvar_names rhs src_loc)
 276   = (tycon_name, ATyCon tycon)
 277   where
 278         tycon = mkSynTyCon tycon_name tycon_kind arity tyvars rhs_ty argvrcs
 279         tycon_kind          = lookupNameEnv_NF kenv tycon_name
 280         arity               = length tyvar_names
 281         tyvars              = mkTyClTyVars tycon_kind tyvar_names
 282         SynTyDetails rhs_ty = lookupNameEnv_NF rec_details tycon_name
 283         argvrcs             = lookupWithDefaultFM rec_vrcs bogusVrcs tycon
 284
 285 buildTyConOrClass is_rec kenv rec_vrcs  rec_details
 286                   (TyData data_or_new context tycon_name tyvar_names _ nconstrs _ _ src_loc name1 name2)
 287   = (tycon_name, ATyCon tycon)
 288   where
 289         tycon = mkAlgTyConRep tycon_name tycon_kind tyvars ctxt argvrcs
 290                            data_cons nconstrs
 291                            derived_classes
 292                            flavour is_rec gen_info
 293         gen_info = mkTyConGenInfo tycon name1 name2
 294
 295         DataTyDetails ctxt data_cons derived_classes = lookupNameEnv_NF rec_details tycon_name
 296
 297         tycon_kind = lookupNameEnv_NF kenv tycon_name
 298         tyvars     = mkTyClTyVars tycon_kind tyvar_names
 299         argvrcs    = lookupWithDefaultFM rec_vrcs bogusVrcs tycon
 300
 301         flavour = case data_or_new of
 302                         NewType -> NewTyCon (mkNewTyConRep tycon)
 303                         DataType | all isNullaryDataCon data_cons -> EnumTyCon
 304                                  | otherwise                      -> DataTyCon
 305
 306 buildTyConOrClass is_rec kenv rec_vrcs  rec_details
 307                   (ClassDecl context class_name
 308                              tyvar_names fundeps class_sigs def_methods pragmas
 309                              name_list src_loc)
 310   = (class_name, AClass clas)
 311   where
 312         (tycon_name, _, _, _) = fromClassDeclNameList name_list
 313         clas = mkClass class_name tyvars fds
 314                        sc_theta sc_sel_ids op_items
 315                        tycon
 316
 317         tycon = mkClassTyCon tycon_name class_kind tyvars
 318                              argvrcs dict_con
 319                              clas               -- Yes!  It's a dictionary
 320                              flavour
 321
 322         ClassDetails sc_theta sc_sel_ids op_items dict_con = lookupNameEnv_NF rec_details class_name
 323
 324         class_kind = lookupNameEnv_NF kenv class_name
 325         tyvars     = mkTyClTyVars class_kind tyvar_names
 326         argvrcs    = lookupWithDefaultFM rec_vrcs bogusVrcs tycon
 327         n_fields   = length sc_sel_ids + length op_items
 328
 329         flavour | n_fields == 1 = NewTyCon (mkNewTyConRep tycon)
 330                 | otherwise     = DataTyCon
 331
 332         -- We can find the functional dependencies right away,
 333         -- and it is vital to do so. Why?  Because in the next pass
 334         -- we check for ambiguity in all the type signatures, and we
 335         -- need the functional dependcies to be done by then
 336         fds        = [(map lookup xs, map lookup ys) | (xs,ys) <- fundeps]
 337         tyvar_env  = mkNameEnv [(varName tv, tv) | tv <- tyvars]
 338         lookup     = lookupNameEnv_NF tyvar_env
 339
 340 bogusVrcs = panic "Bogus tycon arg variances"
 341 \end{code}
 342
 343
 344 %************************************************************************
 345 %*                                                                      *
 346 \subsection{Dependency analysis}
 347 %*                                                                      *
 348 %************************************************************************
 349
 350 Dependency analysis
 351 ~~~~~~~~~~~~~~~~~~~
 352 \begin{code}
 353 sortByDependency :: [RenamedHsDecl] -> TcM s [SCC RenamedTyClDecl]
 354 sortByDependency decls
 355   = let         -- CHECK FOR CLASS CYCLES
 356         cls_sccs   = stronglyConnComp (mapMaybe mk_cls_edges tycl_decls)
 357         cls_cycles = [ decls | CyclicSCC decls <- cls_sccs]
 358     in
 359     checkTc (null cls_cycles) (classCycleErr cls_cycles)        `thenTc_`
 360
 361     let         -- CHECK FOR SYNONYM CYCLES
 362         syn_sccs   = stronglyConnComp (filter is_syn_decl edges)
 363         syn_cycles = [ decls | CyclicSCC decls <- syn_sccs]
 364
 365     in
 366     checkTc (null syn_cycles) (typeCycleErr syn_cycles)         `thenTc_`
 367
 368         -- DO THE MAIN DEPENDENCY ANALYSIS
 369     let
 370         decl_sccs  = stronglyConnComp edges
 371     in
 372     returnTc decl_sccs
 373   where
 374     tycl_decls = [d | TyClD d <- decls]
 375     edges      = map mk_edges tycl_decls
 376
 377     is_syn_decl (d, _, _) = isSynDecl d
 378 \end{code}
 379
 380 Edges in Type/Class decls
 381 ~~~~~~~~~~~~~~~~~~~~~~~~~
 382
 383 \begin{code}
 384 ----------------------------------------------------
 385 -- mk_cls_edges looks only at the context of class decls
 386 -- Its used when we are figuring out if there's a cycle in the
 387 -- superclass hierarchy
 388
 389 mk_cls_edges :: RenamedTyClDecl -> Maybe (RenamedTyClDecl, Unique, [Unique])
 390
 391 mk_cls_edges decl@(ClassDecl ctxt name _ _ _ _ _ _ _)
 392   = Just (decl, getUnique name, map getUnique (catMaybes (map get_clas ctxt)))
 393 mk_cls_edges other_decl
 394   = Nothing
 395
 396 ----------------------------------------------------
 397 mk_edges :: RenamedTyClDecl -> (RenamedTyClDecl, Unique, [Unique])
 398
 399 mk_edges decl@(TyData _ ctxt name _ condecls _ derivs _ _ _ _)
 400   = (decl, getUnique name, uniqSetToList (get_ctxt ctxt `unionUniqSets`
 401                                          get_cons condecls `unionUniqSets`
 402                                          get_deriv derivs))
 403
 404 mk_edges decl@(TySynonym name _ rhs _)
 405   = (decl, getUnique name, uniqSetToList (get_ty rhs))
 406
 407 mk_edges decl@(ClassDecl ctxt name _ _ sigs _ _ _ _)
 408   = (decl, getUnique name, uniqSetToList (get_ctxt ctxt `unionUniqSets`
 409                                          get_sigs sigs))
 410
 411
 412 ----------------------------------------------------
 413 get_ctxt ctxt = unionManyUniqSets (map set_name (catMaybes (map get_clas ctxt)))
 414 get_clas (HsPClass clas _) = Just clas
 415 get_clas _                 = Nothing
 416
 417 ----------------------------------------------------
 418 get_deriv Nothing     = emptyUniqSet
 419 get_deriv (Just clss) = unionManyUniqSets (map set_name clss)
 420
 421 ----------------------------------------------------
 422 get_cons cons = unionManyUniqSets (map get_con cons)
 423
 424 ----------------------------------------------------
 425 get_con (ConDecl _ _ _ ctxt details _)
 426   = get_ctxt ctxt `unionUniqSets` get_con_details details
 427
 428 ----------------------------------------------------
 429 get_con_details (VanillaCon btys)    = unionManyUniqSets (map get_bty btys)
 430 get_con_details (InfixCon bty1 bty2) = unionUniqSets (get_bty bty1) (get_bty bty2)
 431 get_con_details (RecCon nbtys)       = unionManyUniqSets (map (get_bty.snd) nbtys)
 432
 433 ----------------------------------------------------
 434 get_bty bty = get_ty (getBangType bty)
 435
 436 ----------------------------------------------------
 437 get_ty (HsTyVar name) | isTvOcc (nameOccName name) = emptyUniqSet
 438                       | otherwise                  = set_name name
 439 get_ty (HsAppTy ty1 ty2)              = unionUniqSets (get_ty ty1) (get_ty ty2)
 440 get_ty (HsFunTy ty1 ty2)              = unionUniqSets (get_ty ty1) (get_ty ty2)
 441 get_ty (HsListTy ty)                  = set_name listTyCon_name `unionUniqSets` get_ty ty
 442 get_ty (HsTupleTy (HsTupCon n _) tys) = set_name n `unionUniqSets` get_tys tys
 443 get_ty (HsUsgTy _ ty)                 = get_ty ty
 444 get_ty (HsUsgForAllTy _ ty)           = get_ty ty
 445 get_ty (HsForAllTy _ ctxt mty)        = get_ctxt ctxt `unionUniqSets` get_ty mty
 446 get_ty (HsPredTy (HsPClass name _))   = set_name name
 447 get_ty (HsPredTy (HsPIParam _ _))     = emptyUniqSet    -- I think
 448
 449 ----------------------------------------------------
 450 get_tys tys = unionManyUniqSets (map get_ty tys)
 451
 452 ----------------------------------------------------
 453 get_sigs sigs
 454   = unionManyUniqSets (map get_sig sigs)
 455   where
 456     get_sig (ClassOpSig _ _ ty _) = get_ty ty
 457     get_sig (FixSig _)            = emptyUniqSet
 458     get_sig other = panic "TcTyClsDecls:get_sig"
 459
 460 ----------------------------------------------------
 461 set_name name = unitUniqSet (getUnique name)
 462 \end{code}
 463
 464
 465 %************************************************************************
 466 %*                                                                      *
 467 \subsection{Error management
 468 %*                                                                      *
 469 %************************************************************************
 470
 471 \begin{code}
 472 typeCycleErr, classCycleErr :: [[RenamedTyClDecl]] -> Message
 473
 474 typeCycleErr syn_cycles
 475   = vcat (map (pp_cycle "Cycle in type declarations:") syn_cycles)
 476
 477 classCycleErr cls_cycles
 478   = vcat (map (pp_cycle "Cycle in class declarations:") cls_cycles)
 479
 480 pp_cycle str decls
 481   = hang (text str)
 482          4 (vcat (map pp_decl decls))
 483   where
 484     pp_decl decl
 485       = hsep [quotes (ppr name), ptext SLIT("at"), ppr (getSrcLoc name)]
 486      where
 487         name = tyClDeclName decl
 488
 489 \end{code}