ghc/compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[TcTyClsDecls]{Typecheck type and class declarations}
   5
   6 \begin{code}
   7 module TcTyClsDecls (
   8         tcTyAndClassDecls
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..),  HsConDetails(..), HsTyVarBndr(..),
  14                           ConDecl(..),   Sig(..), , NewOrData(..),
  15                           tyClDeclTyVars, isSynDecl,
  16                           LTyClDecl, tcdName, hsTyVarName, LHsTyVarBndr
  17                         )
  18 import HsTypes          ( HsBang(..), getBangStrictness )
  19 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
  20 import HscTypes         ( implicitTyThings, ModDetails )
  21 import BuildTyCl        ( buildClass, buildAlgTyCon, buildSynTyCon, buildDataCon,
  22                           mkDataTyConRhs, mkNewTyConRhs )
  23 import TcRnMonad
  24 import TcEnv            ( TyThing(..),
  25                           tcLookupLocated, tcLookupLocatedGlobal,
  26                           tcExtendGlobalEnv, tcExtendKindEnv, tcExtendKindEnvTvs,
  27                           tcExtendRecEnv, tcLookupTyVar )
  28 import TcTyDecls        ( calcTyConArgVrcs, calcRecFlags, calcClassCycles, calcSynCycles )
  29 import TcClassDcl       ( tcClassSigs, tcAddDeclCtxt )
  30 import TcHsType         ( kcHsTyVars, kcHsLiftedSigType, kcHsType,
  31                           kcHsContext, tcTyVarBndrs, tcHsKindedType, tcHsKindedContext,
  32                           kcHsSigType, tcHsBangType, tcLHsConSig, tcDataKindSig )
  33 import TcMType          ( newKindVar, checkValidTheta, checkValidType, checkFreeness,
  34                           UserTypeCtxt(..), SourceTyCtxt(..) )
  35 import TcType           ( TcKind, TcType, tyVarsOfType,
  36                           mkArrowKind, liftedTypeKind, mkTyVarTys, tcEqTypes,
  37                           tcSplitSigmaTy, tcEqType )
  38 import Type             ( splitTyConApp_maybe, pprThetaArrow, pprParendType )
  39 import Kind             ( mkArrowKinds, splitKindFunTys )
  40 import Generics         ( validGenericMethodType, canDoGenerics )
  41 import Class            ( Class, className, classTyCon, DefMeth(..), classBigSig, classTyVars )
  42 import TyCon            ( TyCon, ArgVrcs, AlgTyConRhs( AbstractTyCon ),
  43                           tyConDataCons, mkForeignTyCon, isProductTyCon, isRecursiveTyCon,
  44                           tyConStupidTheta, getSynTyConDefn, isSynTyCon, tyConName )
  45 import DataCon          ( DataCon, dataConWrapId, dataConName, dataConSig,
  46                           dataConFieldLabels, dataConOrigArgTys, dataConTyCon )
  47 import Type             ( zipTopTvSubst, substTys )
  48 import Var              ( TyVar, idType, idName )
  49 import VarSet           ( elemVarSet )
  50 import Name             ( Name )
  51 import Outputable
  52 import Util             ( zipLazy, isSingleton, notNull, sortLe )
  53 import List             ( partition )
  54 import SrcLoc           ( Located(..), unLoc, getLoc )
  55 import ListSetOps       ( equivClasses )
  56 import Digraph          ( SCC(..) )
  57 import DynFlags         ( DynFlag( Opt_GlasgowExts, Opt_Generics,
  58                                         Opt_UnboxStrictFields ) )
  59 \end{code}
  60
  61
  62 %************************************************************************
  63 %*                                                                      *
  64 \subsection{Type checking for type and class declarations}
  65 %*                                                                      *
  66 %************************************************************************
  67
  68 Dealing with a group
  69 ~~~~~~~~~~~~~~~~~~~~
  70 Consider a mutually-recursive group, binding
  71 a type constructor T and a class C.
  72
  73 Step 1:         getInitialKind
  74         Construct a KindEnv by binding T and C to a kind variable
  75
  76 Step 2:         kcTyClDecl
  77         In that environment, do a kind check
  78
  79 Step 3: Zonk the kinds
  80
  81 Step 4:         buildTyConOrClass
  82         Construct an environment binding T to a TyCon and C to a Class.
  83         a) Their kinds comes from zonking the relevant kind variable
  84         b) Their arity (for synonyms) comes direct from the decl
  85         c) The funcional dependencies come from the decl
  86         d) The rest comes a knot-tied binding of T and C, returned from Step 4
  87         e) The variances of the tycons in the group is calculated from
  88                 the knot-tied stuff
  89
  90 Step 5:         tcTyClDecl1
  91         In this environment, walk over the decls, constructing the TyCons and Classes.
  92         This uses in a strict way items (a)-(c) above, which is why they must
  93         be constructed in Step 4. Feed the results back to Step 4.
  94         For this step, pass the is-recursive flag as the wimp-out flag
  95         to tcTyClDecl1.
  96
  97
  98 Step 6:         Extend environment
  99         We extend the type environment with bindings not only for the TyCons and Classes,
 100         but also for their "implicit Ids" like data constructors and class selectors
 101
 102 Step 7:         checkValidTyCl
 103         For a recursive group only, check all the decls again, just
 104         to check all the side conditions on validity.  We could not
 105         do this before because we were in a mutually recursive knot.
 106
 107
 108 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 109 @TyThing@s.  @rec_vrcs@ is a finite map from @Name@s to @ArgVrcs@s.
 110
 111 \begin{code}
 112 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
 113                    -> TcM TcGblEnv      -- Input env extended by types and classes
 114                                         -- and their implicit Ids,DataCons
 115 tcTyAndClassDecls boot_details decls
 116   = do  {       -- First check for cyclic type synonysm or classes
 117                 -- See notes with checkCycleErrs
 118           checkCycleErrs decls
 119         ; mod <- getModule
 120         ; traceTc (text "tcTyAndCl" <+> ppr mod)
 121         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(rec_syn_tycons, rec_alg_tyclss) ->
 122           do    { let { -- Calculate variances and rec-flag
 123                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc) decls }
 124
 125                         -- Extend the global env with the knot-tied results
 126                         -- for data types and classes
 127                         --
 128                         -- We must populate the environment with the loop-tied T's right
 129                         -- away, because the kind checker may "fault in" some type
 130                         -- constructors that recursively mention T
 131                 ; let { gbl_things = mkGlobalThings alg_decls rec_alg_tyclss }
 132                 ; tcExtendRecEnv gbl_things $ do
 133
 134                         -- Kind-check the declarations
 135                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
 136
 137                 ; let { calc_vrcs = calcTyConArgVrcs (rec_syn_tycons ++ rec_alg_tyclss)
 138                       ; calc_rec  = calcRecFlags boot_details rec_alg_tyclss
 139                       ; tc_decl   = addLocM (tcTyClDecl calc_vrcs calc_rec) }
 140                         -- Type-check the type synonyms, and extend the envt
 141                 ; syn_tycons <- tcSynDecls calc_vrcs kc_syn_decls
 142                 ; tcExtendGlobalEnv syn_tycons $ do
 143
 144                         -- Type-check the data types and classes
 145                 { alg_tyclss <- mappM tc_decl kc_alg_decls
 146                 ; return (syn_tycons, alg_tyclss)
 147             }}})
 148         -- Finished with knot-tying now
 149         -- Extend the environment with the finished things
 150         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
 151
 152         -- Perform the validity check
 153         { traceTc (text "ready for validity check")
 154         ; mappM_ (addLocM checkValidTyCl) decls
 155         ; traceTc (text "done")
 156
 157         -- Add the implicit things;
 158         -- we want them in the environment because
 159         -- they may be mentioned in interface files
 160         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
 161         ; traceTc ((text "Adding" <+> ppr alg_tyclss) $$ (text "and" <+> ppr implicit_things))
 162         ; tcExtendGlobalEnv implicit_things getGblEnv
 163     }}
 164
 165 mkGlobalThings :: [LTyClDecl Name]      -- The decls
 166                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
 167                -> [(Name,TyThing)]
 168 -- Driven by the Decls, and treating the TyThings lazily
 169 -- make a TypeEnv for the new things
 170 mkGlobalThings decls things
 171   = map mk_thing (decls `zipLazy` things)
 172   where
 173     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
 174          = (name, AClass cl)
 175     mk_thing (L _ decl, ~(ATyCon tc))
 176          = (tcdName decl, ATyCon tc)
 177 \end{code}
 178
 179
 180 %************************************************************************
 181 %*                                                                      *
 182                 Kind checking
 183 %*                                                                      *
 184 %************************************************************************
 185
 186 We need to kind check all types in the mutually recursive group
 187 before we know the kind of the type variables.  For example:
 188
 189 class C a where
 190    op :: D b => a -> b -> b
 191
 192 class D c where
 193    bop :: (Monad c) => ...
 194
 195 Here, the kind of the locally-polymorphic type variable "b"
 196 depends on *all the uses of class D*.  For example, the use of
 197 Monad c in bop's type signature means that D must have kind Type->Type.
 198
 199 However type synonyms work differently.  They can have kinds which don't
 200 just involve (->) and *:
 201         type R = Int#           -- Kind #
 202         type S a = Array# a     -- Kind * -> #
 203         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
 204 So we must infer their kinds from their right-hand sides *first* and then
 205 use them, whereas for the mutually recursive data types D we bring into
 206 scope kind bindings D -> k, where k is a kind variable, and do inference.
 207
 208 \begin{code}
 209 kcTyClDecls syn_decls alg_decls
 210   = do  {       -- First extend the kind env with each data
 211                 -- type and class, mapping them to a type variable
 212           alg_kinds <- mappM getInitialKind alg_decls
 213         ; tcExtendKindEnv alg_kinds $ do
 214
 215                 -- Now kind-check the type synonyms, in dependency order
 216                 -- We do these differently to data type and classes,
 217                 -- because a type synonym can be an unboxed type
 218                 --      type Foo = Int#
 219                 -- and a kind variable can't unify with UnboxedTypeKind
 220                 -- So we infer their kinds in dependency order
 221         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
 222         ; tcExtendKindEnv syn_kinds $  do
 223
 224                 -- Now kind-check the data type and class declarations,
 225                 -- returning kind-annotated decls
 226         { kc_alg_decls <- mappM (wrapLocM kcTyClDecl) alg_decls
 227
 228         ; return (kc_syn_decls, kc_alg_decls) }}}
 229
 230 ------------------------------------------------------------------------
 231 getInitialKind :: LTyClDecl Name -> TcM (Name, TcKind)
 232 -- Only for data type and class declarations
 233 -- Get as much info as possible from the data or class decl,
 234 -- so as to maximise usefulness of error messages
 235 getInitialKind (L _ decl)
 236   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
 237         ; res_kind  <- mk_res_kind decl
 238         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
 239   where
 240     mk_arg_kind (UserTyVar _)        = newKindVar
 241     mk_arg_kind (KindedTyVar _ kind) = return kind
 242
 243     mk_res_kind (TyData { tcdKindSig = Just kind }) = return kind
 244         -- On GADT-style declarations we allow a kind signature
 245         --      data T :: *->* where { ... }
 246     mk_res_kind other = return liftedTypeKind
 247
 248
 249 ----------------
 250 kcSynDecls :: [SCC (LTyClDecl Name)]
 251            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
 252                    [(Name,TcKind)])     -- Kind bindings
 253 kcSynDecls []
 254   = return ([], [])
 255 kcSynDecls (group : groups)
 256   = do  { (decl,  nk)  <- kcSynDecl group
 257         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
 258         ; return (decl:decls, nk:nks) }
 259
 260 ----------------
 261 kcSynDecl :: SCC (LTyClDecl Name)
 262            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
 263                    (Name,TcKind))       -- Kind bindings
 264 kcSynDecl (AcyclicSCC ldecl@(L loc decl))
 265   = tcAddDeclCtxt decl  $
 266     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
 267     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl))
 268                         <+> brackets (ppr k_tvs))
 269        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
 270        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
 271        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
 272        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
 273                  (unLoc (tcdLName decl), tc_kind)) })
 274
 275 kcSynDecl (CyclicSCC decls)
 276   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
 277                                         -- of out-of-scope tycons
 278
 279 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
 280
 281 ------------------------------------------------------------------------
 282 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
 283         -- Not used for type synonyms (see kcSynDecl)
 284
 285 kcTyClDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
 286   = kcTyClDeclBody decl $ \ tvs' ->
 287     do  { ctxt' <- kcHsContext ctxt
 288         ; cons' <- mappM (wrapLocM kc_con_decl) cons
 289         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdCons = cons'}) }
 290   where
 291     kc_con_decl (ConDecl name ex_tvs ex_ctxt details)
 292       = kcHsTyVars ex_tvs               $ \ ex_tvs' ->
 293         do { ex_ctxt' <- kcHsContext ex_ctxt
 294            ; details' <- kc_con_details details
 295            ; return (ConDecl name ex_tvs' ex_ctxt' details')}
 296     kc_con_decl (GadtDecl name ty)
 297         = do { ty' <- kcHsSigType ty
 298              ; traceTc (text "kc_con_decl" <+> ppr name <+> ppr ty')
 299              ; return (GadtDecl name ty') }
 300
 301     kc_con_details (PrefixCon btys)
 302         = do { btys' <- mappM kc_larg_ty btys ; return (PrefixCon btys') }
 303     kc_con_details (InfixCon bty1 bty2)
 304         = do { bty1' <- kc_larg_ty bty1; bty2' <- kc_larg_ty bty2; return (InfixCon bty1' bty2') }
 305     kc_con_details (RecCon fields)
 306         = do { fields' <- mappM kc_field fields; return (RecCon fields') }
 307
 308     kc_field (fld, bty) = do { bty' <- kc_larg_ty bty ; return (fld, bty') }
 309
 310     kc_larg_ty bty = case new_or_data of
 311                         DataType -> kcHsSigType bty
 312                         NewType  -> kcHsLiftedSigType bty
 313         -- Can't allow an unlifted type for newtypes, because we're effectively
 314         -- going to remove the constructor while coercing it to a lifted type.
 315         -- And newtypes can't be bang'd
 316
 317 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt,  tcdSigs = sigs})
 318   = kcTyClDeclBody decl $ \ tvs' ->
 319     do  { ctxt' <- kcHsContext ctxt
 320         ; sigs' <- mappM (wrapLocM kc_sig) sigs
 321         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs'}) }
 322   where
 323     kc_sig (Sig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
 324                                 ; return (Sig nm op_ty') }
 325     kc_sig other_sig          = return other_sig
 326
 327 kcTyClDecl decl@(ForeignType {})
 328   = return decl
 329
 330 kcTyClDeclBody :: TyClDecl Name
 331                -> ([LHsTyVarBndr Name] -> TcM a)
 332                -> TcM a
 333 -- getInitialKind has made a suitably-shaped kind for the type or class
 334 -- Unpack it, and attribute those kinds to the type variables
 335 -- Extend the env with bindings for the tyvars, taken from
 336 -- the kind of the tycon/class.  Give it to the thing inside, and
 337  -- check the result kind matches
 338 kcTyClDeclBody decl thing_inside
 339   = tcAddDeclCtxt decl          $
 340     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 341         ; let tc_kind    = case tc_ty_thing of { AThing k -> k }
 342               (kinds, _) = splitKindFunTys tc_kind
 343               hs_tvs     = tcdTyVars decl
 344               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
 345                            [ L loc (KindedTyVar (hsTyVarName tv) k)
 346                            | (L loc tv, k) <- zip hs_tvs kinds]
 347         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
 348 \end{code}
 349
 350
 351 %************************************************************************
 352 %*                                                                      *
 353 \subsection{Type checking}
 354 %*                                                                      *
 355 %************************************************************************
 356
 357 \begin{code}
 358 tcSynDecls :: (Name -> ArgVrcs) -> [LTyClDecl Name] -> TcM [TyThing]
 359 tcSynDecls calc_vrcs [] = return []
 360 tcSynDecls calc_vrcs (decl : decls)
 361   = do { syn_tc <- addLocM (tcSynDecl calc_vrcs) decl
 362        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls calc_vrcs decls)
 363        ; return (syn_tc : syn_tcs) }
 364
 365 tcSynDecl calc_vrcs
 366   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
 367   = tcTyVarBndrs tvs            $ \ tvs' -> do
 368     { traceTc (text "tcd1" <+> ppr tc_name)
 369     ; rhs_ty' <- tcHsKindedType rhs_ty
 370     ; return (ATyCon (buildSynTyCon tc_name tvs' rhs_ty' (calc_vrcs tc_name))) }
 371
 372 --------------------
 373 tcTyClDecl :: (Name -> ArgVrcs) -> (Name -> RecFlag)
 374            -> TyClDecl Name -> TcM TyThing
 375
 376 tcTyClDecl calc_vrcs calc_isrec decl
 377   = tcAddDeclCtxt decl (tcTyClDecl1 calc_vrcs calc_isrec decl)
 378
 379 tcTyClDecl1 calc_vrcs calc_isrec
 380   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 381            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
 382   = tcTyVarBndrs tvs    $ \ tvs' -> do
 383   { extra_tvs <- tcDataKindSig mb_ksig
 384   ; let final_tvs = tvs' ++ extra_tvs
 385   ; stupid_theta <- tcHsKindedContext ctxt
 386   ; want_generic <- doptM Opt_Generics
 387   ; unbox_strict <- doptM Opt_UnboxStrictFields
 388   ; gla_exts     <- doptM Opt_GlasgowExts
 389   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
 390
 391         -- Check that we don't use GADT syntax in H98 world
 392   ; checkTc (gla_exts || h98_syntax) (badGadtDecl tc_name)
 393
 394         -- Check that there's at least one condecl,
 395         -- or else we're reading an interface file, or -fglasgow-exts
 396   ; checkTc (not (null cons) || gla_exts || is_boot)
 397             (emptyConDeclsErr tc_name)
 398
 399   ; tycon <- fixM (\ tycon -> do
 400         { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data
 401                                                  tycon final_tvs))
 402                              cons
 403         ; let tc_rhs
 404                 | null cons && is_boot  -- In a hs-boot file, empty cons means
 405                 = AbstractTyCon         -- "don't know"; hence Abstract
 406                 | otherwise
 407                 = case new_or_data of
 408                         DataType -> mkDataTyConRhs data_cons
 409                         NewType  -> ASSERT( isSingleton data_cons )
 410                                     mkNewTyConRhs tycon (head data_cons)
 411         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs arg_vrcs is_rec
 412                         (want_generic && canDoGenerics data_cons)
 413         })
 414   ; return (ATyCon tycon)
 415   }
 416   where
 417     arg_vrcs = calc_vrcs tc_name
 418     is_rec   = calc_isrec tc_name
 419     h98_syntax = case cons of   -- All constructors have same shape
 420                         L _ (GadtDecl {}) : _ -> False
 421                         other -> True
 422
 423 tcTyClDecl1 calc_vrcs calc_isrec
 424   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs,
 425               tcdCtxt = ctxt, tcdMeths = meths,
 426               tcdFDs = fundeps, tcdSigs = sigs} )
 427   = tcTyVarBndrs tvs            $ \ tvs' -> do
 428   { ctxt' <- tcHsKindedContext ctxt
 429   ; fds' <- mappM (addLocM tc_fundep) fundeps
 430   ; sig_stuff <- tcClassSigs class_name sigs meths
 431   ; clas <- fixM (\ clas ->
 432                 let     -- This little knot is just so we can get
 433                         -- hold of the name of the class TyCon, which we
 434                         -- need to look up its recursiveness and variance
 435                     tycon_name = tyConName (classTyCon clas)
 436                     tc_isrec = calc_isrec tycon_name
 437                     tc_vrcs  = calc_vrcs  tycon_name
 438                 in
 439                 buildClass class_name tvs' ctxt' fds'
 440                            sig_stuff tc_isrec tc_vrcs)
 441   ; return (AClass clas) }
 442   where
 443     tc_fundep (tvs1, tvs2) = do { tvs1' <- mappM tcLookupTyVar tvs1 ;
 444                                 ; tvs2' <- mappM tcLookupTyVar tvs2 ;
 445                                 ; return (tvs1', tvs2') }
 446
 447
 448 tcTyClDecl1 calc_vrcs calc_isrec
 449   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
 450   = returnM (ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0 []))
 451
 452 -----------------------------------
 453 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
 454           -> NewOrData -> TyCon -> [TyVar]
 455           -> ConDecl Name -> TcM DataCon
 456
 457 tcConDecl unbox_strict NewType tycon tc_tvs     -- Newtypes
 458           (ConDecl name ex_tvs ex_ctxt details)
 459   = ASSERT( null ex_tvs && null (unLoc ex_ctxt) )
 460     do  { let tc_datacon field_lbls arg_ty
 461                 = do { arg_ty' <- tcHsKindedType arg_ty -- No bang on newtype
 462                      ; buildDataCon (unLoc name) False {- Prefix -}
 463                                     True {- Vanilla -} [NotMarkedStrict]
 464                                     (map unLoc field_lbls)
 465                                     tc_tvs [] [arg_ty']
 466                                     tycon (mkTyVarTys tc_tvs) }
 467         ; case details of
 468             PrefixCon [arg_ty] -> tc_datacon [] arg_ty
 469             RecCon [(field_lbl, arg_ty)] -> tc_datacon [field_lbl] arg_ty }
 470
 471 tcConDecl unbox_strict DataType tycon tc_tvs    -- Ordinary data types
 472           (ConDecl name ex_tvs ex_ctxt details)
 473   = tcTyVarBndrs ex_tvs         $ \ ex_tvs' -> do
 474     { ex_ctxt' <- tcHsKindedContext ex_ctxt
 475     ; let
 476         is_vanilla = null ex_tvs && null (unLoc ex_ctxt)
 477                 -- Vanilla iff no ex_tvs and no context
 478                 -- Must check the context too because of
 479                 -- implicit params; e.g.
 480                 --  data T = (?x::Int) => MkT Int
 481
 482         tc_datacon is_infix field_lbls btys
 483           = do { let { bangs = map getBangStrictness btys }
 484                ; arg_tys <- mappM tcHsBangType btys
 485                ; buildDataCon (unLoc name) is_infix is_vanilla
 486                     (argStrictness unbox_strict tycon bangs arg_tys)
 487                     (map unLoc field_lbls)
 488                     (tc_tvs ++ ex_tvs')
 489                     ex_ctxt'
 490                     arg_tys
 491                     tycon (mkTyVarTys tc_tvs) }
 492     ; case details of
 493         PrefixCon btys     -> tc_datacon False [] btys
 494         InfixCon bty1 bty2 -> tc_datacon True [] [bty1,bty2]
 495         RecCon fields      -> do { checkTc (null ex_tvs) (exRecConErr name)
 496                 -- It's ok to have an implicit-parameter context
 497                 -- for the data constructor, provided it binds
 498                 -- no type variables
 499                                  ; let { (field_names, btys) = unzip fields }
 500                                  ; tc_datacon False field_names btys } }
 501
 502 tcConDecl unbox_strict DataType tycon tc_tvs    -- GADTs
 503           decl@(GadtDecl name con_ty)
 504   = do  { traceTc (text "tcConDecl"  <+> ppr name)
 505         ; (tvs, theta, bangs, arg_tys, data_tc, res_tys) <- tcLHsConSig con_ty
 506
 507         ; traceTc (text "tcConDecl1"  <+> ppr name)
 508         ; let   -- Now dis-assemble the type, and check its form
 509               is_vanilla = null theta && mkTyVarTys tvs `tcEqTypes` res_tys
 510
 511                 -- Vanilla datacons guarantee to use the same
 512                 -- type variables as the parent tycon
 513               (tvs', arg_tys', res_tys')
 514                   | is_vanilla = (tc_tvs, substTys subst arg_tys, substTys subst res_tys)
 515                   | otherwise  = (tvs, arg_tys, res_tys)
 516               subst = zipTopTvSubst tvs (mkTyVarTys tc_tvs)
 517
 518         ; traceTc (text "tcConDecl3"  <+> ppr name)
 519         ; buildDataCon (unLoc name) False {- Not infix -} is_vanilla
 520                        (argStrictness unbox_strict tycon bangs arg_tys)
 521                        [{- No field labels -}]
 522                        tvs' theta arg_tys' data_tc res_tys' }
 523                 -- NB:  we put data_tc, the type constructor gotten from the constructor
 524                 --      type signature into the data constructor; that way checkValidDataCon
 525                 --      can complain if it's wrong.
 526
 527 -------------------
 528 argStrictness :: Bool           -- True <=> -funbox-strict_fields
 529               -> TyCon -> [HsBang]
 530               -> [TcType] -> [StrictnessMark]
 531 argStrictness unbox_strict tycon bangs arg_tys
 532  = ASSERT( length bangs == length arg_tys )
 533    zipWith (chooseBoxingStrategy unbox_strict tycon) arg_tys bangs
 534
 535 -- We attempt to unbox/unpack a strict field when either:
 536 --   (i)  The field is marked '!!', or
 537 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
 538
 539 chooseBoxingStrategy :: Bool -> TyCon -> TcType -> HsBang -> StrictnessMark
 540 chooseBoxingStrategy unbox_strict_fields tycon arg_ty bang
 541   = case bang of
 542         HsNoBang                                    -> NotMarkedStrict
 543         HsStrict | unbox_strict_fields && can_unbox -> MarkedUnboxed
 544         HsUnbox  | can_unbox                        -> MarkedUnboxed
 545         other                                       -> MarkedStrict
 546   where
 547     can_unbox = case splitTyConApp_maybe arg_ty of
 548                    Nothing             -> False
 549                    Just (arg_tycon, _) -> not (isRecursiveTyCon tycon) &&
 550                                           isProductTyCon arg_tycon
 551 \end{code}
 552
 553 %************************************************************************
 554 %*                                                                      *
 555 \subsection{Dependency analysis}
 556 %*                                                                      *
 557 %************************************************************************
 558
 559 Validity checking is done once the mutually-recursive knot has been
 560 tied, so we can look at things freely.
 561
 562 \begin{code}
 563 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
 564 checkCycleErrs tyclss
 565   | null cls_cycles
 566   = return ()
 567   | otherwise
 568   = do  { mappM_ recClsErr cls_cycles
 569         ; failM }       -- Give up now, because later checkValidTyCl
 570                         -- will loop if the synonym is recursive
 571   where
 572     cls_cycles = calcClassCycles tyclss
 573
 574 checkValidTyCl :: TyClDecl Name -> TcM ()
 575 -- We do the validity check over declarations, rather than TyThings
 576 -- only so that we can add a nice context with tcAddDeclCtxt
 577 checkValidTyCl decl
 578   = tcAddDeclCtxt decl $
 579     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
 580         ; traceTc (text "Validity of" <+> ppr thing)
 581         ; case thing of
 582             ATyCon tc -> checkValidTyCon tc
 583             AClass cl -> checkValidClass cl
 584         ; traceTc (text "Done validity of" <+> ppr thing)
 585         }
 586
 587 -------------------------
 588 checkValidTyCon :: TyCon -> TcM ()
 589 checkValidTyCon tc
 590   | isSynTyCon tc
 591   = checkValidType syn_ctxt syn_rhs
 592   | otherwise
 593   =     -- Check the context on the data decl
 594     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)     `thenM_`
 595
 596         -- Check arg types of data constructors
 597     mappM_ (checkValidDataCon tc) data_cons                     `thenM_`
 598
 599         -- Check that fields with the same name share a type
 600     mappM_ check_fields groups
 601
 602   where
 603     syn_ctxt     = TySynCtxt name
 604     name         = tyConName tc
 605     (_, syn_rhs) = getSynTyConDefn tc
 606     data_cons    = tyConDataCons tc
 607
 608     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
 609     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
 610     get_fields con = dataConFieldLabels con `zip` dataConOrigArgTys con
 611         -- dataConFieldLabels may return the empty list, which is fine
 612
 613     check_fields fields@((first_field_label, field_ty) : other_fields)
 614         -- These fields all have the same name, but are from
 615         -- different constructors in the data type
 616         =       -- Check that all the fields in the group have the same type
 617                 -- NB: this check assumes that all the constructors of a given
 618                 -- data type use the same type variables
 619           checkTc (all (tcEqType field_ty . snd) other_fields)
 620                   (fieldTypeMisMatch first_field_label)
 621
 622 -------------------------------
 623 checkValidDataCon :: TyCon -> DataCon -> TcM ()
 624 checkValidDataCon tc con
 625   = addErrCtxt (dataConCtxt con) $
 626     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
 627         ; checkValidType ctxt (idType (dataConWrapId con)) }
 628
 629                 -- This checks the argument types and
 630                 -- ambiguity of the existential context (if any)
 631                 --
 632                 -- Note [Sept 04] Now that tvs is all the tvs, this
 633                 -- test doesn't actually check anything
 634 --      ; checkFreeness tvs ex_theta }
 635   where
 636     ctxt = ConArgCtxt (dataConName con)
 637 --    (tvs, ex_theta, _, _, _) = dataConSig con
 638
 639
 640 -------------------------------
 641 checkValidClass :: Class -> TcM ()
 642 checkValidClass cls
 643   = do  {       -- CHECK ARITY 1 FOR HASKELL 1.4
 644           gla_exts <- doptM Opt_GlasgowExts
 645
 646         -- Check that the class is unary, unless GlaExs
 647         ; checkTc (notNull tyvars) (nullaryClassErr cls)
 648         ; checkTc (gla_exts || unary) (classArityErr cls)
 649
 650         -- Check the super-classes
 651         ; checkValidTheta (ClassSCCtxt (className cls)) theta
 652
 653         -- Check the class operations
 654         ; mappM_ check_op op_stuff
 655
 656         -- Check that if the class has generic methods, then the
 657         -- class has only one parameter.  We can't do generic
 658         -- multi-parameter type classes!
 659         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
 660         }
 661   where
 662     (tyvars, theta, _, op_stuff) = classBigSig cls
 663     unary       = isSingleton tyvars
 664     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
 665
 666     check_op (sel_id, dm)
 667       = addErrCtxt (classOpCtxt sel_id tau) $ do
 668         { checkValidTheta SigmaCtxt (tail theta)
 669                 -- The 'tail' removes the initial (C a) from the
 670                 -- class itself, leaving just the method type
 671
 672         ; checkValidType (FunSigCtxt op_name) tau
 673
 674                 -- Check that the type mentions at least one of
 675                 -- the class type variables
 676         ; checkTc (any (`elemVarSet` tyVarsOfType tau) tyvars)
 677                   (noClassTyVarErr cls sel_id)
 678
 679                 -- Check that for a generic method, the type of
 680                 -- the method is sufficiently simple
 681         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
 682                   (badGenericMethodType op_name op_ty)
 683         }
 684         where
 685           op_name = idName sel_id
 686           op_ty   = idType sel_id
 687           (_,theta,tau) = tcSplitSigmaTy op_ty
 688
 689
 690
 691 ---------------------------------------------------------------------
 692 fieldTypeMisMatch field_name
 693   = sep [ptext SLIT("Different constructors give different types for field"), quotes (ppr field_name)]
 694
 695 dataConCtxt con = sep [ptext SLIT("When checking the data constructor:"),
 696                        nest 2 (ex_part <+> pprThetaArrow ex_theta <+> ppr con <+> arg_part)]
 697   where
 698     (ex_tvs, ex_theta, arg_tys, _, _) = dataConSig con
 699     ex_part | null ex_tvs = empty
 700             | otherwise   = ptext SLIT("forall") <+> hsep (map ppr ex_tvs) <> dot
 701         -- The 'ex_theta' part could be non-empty, if the user (bogusly) wrote
 702         --      data T a = Eq a => T a a
 703         -- So we make sure to print it
 704
 705     fields = dataConFieldLabels con
 706     arg_part | null fields = sep (map pprParendType arg_tys)
 707              | otherwise   = braces (sep (punctuate comma
 708                              [ ppr n <+> dcolon <+> ppr ty
 709                              | (n,ty) <- fields `zip` arg_tys]))
 710
 711 classOpCtxt sel_id tau = sep [ptext SLIT("When checking the class method:"),
 712                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
 713
 714 nullaryClassErr cls
 715   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
 716
 717 classArityErr cls
 718   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
 719           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
 720
 721 noClassTyVarErr clas op
 722   = sep [ptext SLIT("The class method") <+> quotes (ppr op),
 723          ptext SLIT("mentions none of the type variables of the class") <+>
 724                 ppr clas <+> hsep (map ppr (classTyVars clas))]
 725
 726 genericMultiParamErr clas
 727   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 728     ptext SLIT("cannot have generic methods")
 729
 730 badGenericMethodType op op_ty
 731   = hang (ptext SLIT("Generic method type is too complex"))
 732        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 733                 ptext SLIT("You can only use type variables, arrows, lists, and tuples")])
 734
 735 recSynErr syn_decls
 736   = setSrcSpan (getLoc (head sorted_decls)) $
 737     addErr (sep [ptext SLIT("Cycle in type synonym declarations:"),
 738                  nest 2 (vcat (map ppr_decl sorted_decls))])
 739   where
 740     sorted_decls = sortLocated syn_decls
 741     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
 742
 743 recClsErr cls_decls
 744   = setSrcSpan (getLoc (head sorted_decls)) $
 745     addErr (sep [ptext SLIT("Cycle in class declarations (via superclasses):"),
 746                  nest 2 (vcat (map ppr_decl sorted_decls))])
 747   where
 748     sorted_decls = sortLocated cls_decls
 749     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
 750
 751 sortLocated :: [Located a] -> [Located a]
 752 sortLocated things = sortLe le things
 753   where
 754     le (L l1 _) (L l2 _) = l1 <= l2
 755
 756 exRecConErr name
 757   = ptext SLIT("Can't combine named fields with locally-quantified type variables or context")
 758     $$
 759     (ptext SLIT("In the declaration of data constructor") <+> ppr name)
 760
 761 badDataConTyCon data_con
 762   = hang (ptext SLIT("Data constructor") <+> quotes (ppr data_con) <+>
 763                 ptext SLIT("returns type") <+> quotes (ppr (dataConTyCon data_con)))
 764        2 (ptext SLIT("instead of its parent type"))
 765
 766 badGadtDecl tc_name
 767   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
 768          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow GADTs")) ]
 769
 770 emptyConDeclsErr tycon
 771   = sep [quotes (ppr tycon) <+> ptext SLIT("has no constructors"),
 772          nest 4 (ptext SLIT("(-fglasgow-exts permits this)"))]
 773 \end{code}