ghc/compiler/typecheck/TcUnify.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[Unify]{Unifier}
   5
   6 The unifier is now squarely in the typechecker monad (because of the
   7 updatable substitution).
   8
   9 \begin{code}
  10 module TcUnify ( unifyTauTy, unifyTauTyList, unifyTauTyLists,
  11                  unifyFunTy, unifyListTy, unifyTupleTy,
  12                  unifyKind, unifyKinds, unifyOpenTypeKind
  13  ) where
  14
  15 #include "HsVersions.h"
  16
  17 -- friends:
  18 import TcMonad
  19 import TypeRep  ( Type(..), PredType(..) )  -- friend
  20 import Type     ( unboxedTypeKind, boxedTypeKind, openTypeKind,
  21                   typeCon, openKindCon, hasMoreBoxityInfo,
  22                   tyVarsOfType, typeKind,
  23                   mkFunTy, splitFunTy_maybe, splitTyConApp_maybe,
  24                   isNotUsgTy, splitAppTy_maybe, mkTyConApp,
  25                   tidyOpenType, tidyOpenTypes, tidyTyVar
  26                 )
  27 import TyCon    ( TyCon, isTupleTyCon, tupleTyConBoxity, tyConArity )
  28 import Var      ( tyVarKind, varName, isSigTyVar )
  29 import VarSet   ( varSetElems )
  30 import TcType   ( TcType, TcTauType, TcTyVar, TcKind, newBoxityVar,
  31                   newTyVarTy, newTyVarTys, tcGetTyVar, tcPutTyVar, zonkTcType
  32                 )
  33 import Name     ( isSystemName )
  34
  35 -- others:
  36 import BasicTypes ( Arity, Boxity, isBoxed )
  37 import TysWiredIn ( listTyCon, mkListTy, mkTupleTy )
  38 import Outputable
  39 \end{code}
  40
  41
  42 %************************************************************************
  43 %*                                                                      *
  44 \subsection{The Kind variants}
  45 %*                                                                      *
  46 %************************************************************************
  47
  48 \begin{code}
  49 unifyKind :: TcKind                 -- Expected
  50           -> TcKind                 -- Actual
  51           -> TcM ()
  52 unifyKind k1 k2
  53   = tcAddErrCtxtM (unifyCtxt "kind" k1 k2) $
  54     uTys k1 k1 k2 k2
  55
  56 unifyKinds :: [TcKind] -> [TcKind] -> TcM ()
  57 unifyKinds []       []       = returnTc ()
  58 unifyKinds (k1:ks1) (k2:ks2) = unifyKind k1 k2  `thenTc_`
  59                                unifyKinds ks1 ks2
  60 unifyKinds _ _ = panic "unifyKinds: length mis-match"
  61 \end{code}
  62
  63 \begin{code}
  64 unifyOpenTypeKind :: TcKind -> TcM ()
  65 -- Ensures that the argument kind is of the form (Type bx)
  66 -- for some boxity bx
  67
  68 unifyOpenTypeKind ty@(TyVarTy tyvar)
  69   = tcGetTyVar tyvar    `thenNF_Tc` \ maybe_ty ->
  70     case maybe_ty of
  71         Just ty' -> unifyOpenTypeKind ty'
  72         other    -> unify_open_kind_help ty
  73
  74 unifyOpenTypeKind ty
  75   = case splitTyConApp_maybe ty of
  76         Just (tycon, [_]) | tycon == typeCon -> returnTc ()
  77         other                                -> unify_open_kind_help ty
  78
  79 unify_open_kind_help ty -- Revert to ordinary unification
  80   = newBoxityVar        `thenNF_Tc` \ boxity ->
  81     unifyKind ty (mkTyConApp typeCon [boxity])
  82 \end{code}
  83
  84
  85 %************************************************************************
  86 %*                                                                      *
  87 \subsection[Unify-exported]{Exported unification functions}
  88 %*                                                                      *
  89 %************************************************************************
  90
  91 The exported functions are all defined as versions of some
  92 non-exported generic functions.
  93
  94 Unify two @TauType@s.  Dead straightforward.
  95
  96 \begin{code}
  97 unifyTauTy :: TcTauType -> TcTauType -> TcM ()
  98 unifyTauTy ty1 ty2      -- ty1 expected, ty2 inferred
  99   = tcAddErrCtxtM (unifyCtxt "type" ty1 ty2) $
 100     uTys ty1 ty1 ty2 ty2
 101 \end{code}
 102
 103 @unifyTauTyList@ unifies corresponding elements of two lists of
 104 @TauType@s.  It uses @uTys@ to do the real work.  The lists should be
 105 of equal length.  We charge down the list explicitly so that we can
 106 complain if their lengths differ.
 107
 108 \begin{code}
 109 unifyTauTyLists :: [TcTauType] -> [TcTauType] ->  TcM ()
 110 unifyTauTyLists []           []         = returnTc ()
 111 unifyTauTyLists (ty1:tys1) (ty2:tys2) = uTys ty1 ty1 ty2 ty2   `thenTc_`
 112                                         unifyTauTyLists tys1 tys2
 113 unifyTauTyLists ty1s ty2s = panic "Unify.unifyTauTyLists: mismatched type lists!"
 114 \end{code}
 115
 116 @unifyTauTyList@ takes a single list of @TauType@s and unifies them
 117 all together.  It is used, for example, when typechecking explicit
 118 lists, when all the elts should be of the same type.
 119
 120 \begin{code}
 121 unifyTauTyList :: [TcTauType] -> TcM ()
 122 unifyTauTyList []                = returnTc ()
 123 unifyTauTyList [ty]              = returnTc ()
 124 unifyTauTyList (ty1:tys@(ty2:_)) = unifyTauTy ty1 ty2   `thenTc_`
 125                                    unifyTauTyList tys
 126 \end{code}
 127
 128 %************************************************************************
 129 %*                                                                      *
 130 \subsection[Unify-uTys]{@uTys@: getting down to business}
 131 %*                                                                      *
 132 %************************************************************************
 133
 134 @uTys@ is the heart of the unifier.  Each arg happens twice, because
 135 we want to report errors in terms of synomyms if poss.  The first of
 136 the pair is used in error messages only; it is always the same as the
 137 second, except that if the first is a synonym then the second may be a
 138 de-synonym'd version.  This way we get better error messages.
 139
 140 We call the first one \tr{ps_ty1}, \tr{ps_ty2} for ``possible synomym''.
 141
 142 \begin{code}
 143 uTys :: TcTauType -> TcTauType  -- Error reporting ty1 and real ty1
 144                                 -- ty1 is the *expected* type
 145
 146      -> TcTauType -> TcTauType  -- Error reporting ty2 and real ty2
 147                                 -- ty2 is the *actual* type
 148      -> TcM ()
 149
 150         -- Always expand synonyms (see notes at end)
 151         -- (this also throws away FTVs and usage annots)
 152 uTys ps_ty1 (NoteTy _ ty1) ps_ty2 ty2 = uTys ps_ty1 ty1 ps_ty2 ty2
 153 uTys ps_ty1 ty1 ps_ty2 (NoteTy _ ty2) = uTys ps_ty1 ty1 ps_ty2 ty2
 154
 155         -- Variables; go for uVar
 156 uTys ps_ty1 (TyVarTy tyvar1) ps_ty2 ty2 = uVar False tyvar1 ps_ty2 ty2
 157 uTys ps_ty1 ty1 ps_ty2 (TyVarTy tyvar2) = uVar True  tyvar2 ps_ty1 ty1
 158                                         -- "True" means args swapped
 159
 160         -- Predicates
 161 uTys _ (PredTy (IParam n1 t1)) _ (PredTy (IParam n2 t2))
 162   | n1 == n2 = uTys t1 t1 t2 t2
 163 uTys _ (PredTy (Class c1 tys1)) _ (PredTy (Class c2 tys2))
 164   | c1 == c2 = unifyTauTyLists tys1 tys2
 165
 166         -- Functions; just check the two parts
 167 uTys _ (FunTy fun1 arg1) _ (FunTy fun2 arg2)
 168   = uTys fun1 fun1 fun2 fun2    `thenTc_`    uTys arg1 arg1 arg2 arg2
 169
 170         -- Type constructors must match
 171 uTys ps_ty1 (TyConApp con1 tys1) ps_ty2 (TyConApp con2 tys2)
 172   | con1 == con2 && length tys1 == length tys2
 173   = unifyTauTyLists tys1 tys2
 174
 175   | con1 == openKindCon
 176         -- When we are doing kind checking, we might match a kind '?'
 177         -- against a kind '*' or '#'.  Notably, CCallable :: ? -> *, and
 178         -- (CCallable Int) and (CCallable Int#) are both OK
 179   = unifyOpenTypeKind ps_ty2
 180
 181         -- Applications need a bit of care!
 182         -- They can match FunTy and TyConApp, so use splitAppTy_maybe
 183         -- NB: we've already dealt with type variables and Notes,
 184         -- so if one type is an App the other one jolly well better be too
 185 uTys ps_ty1 (AppTy s1 t1) ps_ty2 ty2
 186   = case splitAppTy_maybe ty2 of
 187         Just (s2,t2) -> uTys s1 s1 s2 s2        `thenTc_`    uTys t1 t1 t2 t2
 188         Nothing      -> unifyMisMatch ps_ty1 ps_ty2
 189
 190         -- Now the same, but the other way round
 191         -- Don't swap the types, because the error messages get worse
 192 uTys ps_ty1 ty1 ps_ty2 (AppTy s2 t2)
 193   = case splitAppTy_maybe ty1 of
 194         Just (s1,t1) -> uTys s1 s1 s2 s2        `thenTc_`    uTys t1 t1 t2 t2
 195         Nothing      -> unifyMisMatch ps_ty1 ps_ty2
 196
 197         -- Not expecting for-alls in unification
 198         -- ... but the error message from the unifyMisMatch more informative
 199         -- than a panic message!
 200
 201         -- Anything else fails
 202 uTys ps_ty1 ty1 ps_ty2 ty2  = unifyMisMatch ps_ty1 ps_ty2
 203 \end{code}
 204
 205 Notes on synonyms
 206 ~~~~~~~~~~~~~~~~~
 207 If you are tempted to make a short cut on synonyms, as in this
 208 pseudocode...
 209
 210 \begin{verbatim}
 211 uTys (SynTy con1 args1 ty1) (SynTy con2 args2 ty2)
 212   = if (con1 == con2) then
 213         -- Good news!  Same synonym constructors, so we can shortcut
 214         -- by unifying their arguments and ignoring their expansions.
 215         unifyTauTypeLists args1 args2
 216     else
 217         -- Never mind.  Just expand them and try again
 218         uTys ty1 ty2
 219 \end{verbatim}
 220
 221 then THINK AGAIN.  Here is the whole story, as detected and reported
 222 by Chris Okasaki \tr{<Chris_Okasaki@loch.mess.cs.cmu.edu>}:
 223 \begin{quotation}
 224 Here's a test program that should detect the problem:
 225
 226 \begin{verbatim}
 227         type Bogus a = Int
 228         x = (1 :: Bogus Char) :: Bogus Bool
 229 \end{verbatim}
 230
 231 The problem with [the attempted shortcut code] is that
 232 \begin{verbatim}
 233         con1 == con2
 234 \end{verbatim}
 235 is not a sufficient condition to be able to use the shortcut!
 236 You also need to know that the type synonym actually USES all
 237 its arguments.  For example, consider the following type synonym
 238 which does not use all its arguments.
 239 \begin{verbatim}
 240         type Bogus a = Int
 241 \end{verbatim}
 242
 243 If you ever tried unifying, say, \tr{Bogus Char} with \tr{Bogus Bool},
 244 the unifier would blithely try to unify \tr{Char} with \tr{Bool} and
 245 would fail, even though the expanded forms (both \tr{Int}) should
 246 match.
 247
 248 Similarly, unifying \tr{Bogus Char} with \tr{Bogus t} would
 249 unnecessarily bind \tr{t} to \tr{Char}.
 250
 251 ... You could explicitly test for the problem synonyms and mark them
 252 somehow as needing expansion, perhaps also issuing a warning to the
 253 user.
 254 \end{quotation}
 255
 256
 257 %************************************************************************
 258 %*                                                                      *
 259 \subsection[Unify-uVar]{@uVar@: unifying with a type variable}
 260 %*                                                                      *
 261 %************************************************************************
 262
 263 @uVar@ is called when at least one of the types being unified is a
 264 variable.  It does {\em not} assume that the variable is a fixed point
 265 of the substitution; rather, notice that @uVar@ (defined below) nips
 266 back into @uTys@ if it turns out that the variable is already bound.
 267
 268 \begin{code}
 269 uVar :: Bool            -- False => tyvar is the "expected"
 270                         -- True  => ty    is the "expected" thing
 271      -> TcTyVar
 272      -> TcTauType -> TcTauType  -- printing and real versions
 273      -> TcM ()
 274
 275 uVar swapped tv1 ps_ty2 ty2
 276   = tcGetTyVar tv1      `thenNF_Tc` \ maybe_ty1 ->
 277     case maybe_ty1 of
 278         Just ty1 | swapped   -> uTys ps_ty2 ty2 ty1 ty1 -- Swap back
 279                  | otherwise -> uTys ty1 ty1 ps_ty2 ty2 -- Same order
 280         other       -> uUnboundVar swapped tv1 maybe_ty1 ps_ty2 ty2
 281
 282         -- Expand synonyms; ignore FTVs; ignore usage annots
 283 uUnboundVar swapped tv1 maybe_ty1 ps_ty2 (NoteTy _ ty2)
 284   = uUnboundVar swapped tv1 maybe_ty1 ps_ty2 ty2
 285
 286
 287         -- The both-type-variable case
 288 uUnboundVar swapped tv1 maybe_ty1 ps_ty2 ty2@(TyVarTy tv2)
 289
 290         -- Same type variable => no-op
 291   | tv1 == tv2
 292   = returnTc ()
 293
 294         -- Distinct type variables
 295         -- ASSERT maybe_ty1 /= Just
 296   | otherwise
 297   = tcGetTyVar tv2      `thenNF_Tc` \ maybe_ty2 ->
 298     case maybe_ty2 of
 299         Just ty2' -> uUnboundVar swapped tv1 maybe_ty1 ty2' ty2'
 300
 301         Nothing | update_tv2
 302
 303                 -> WARN( not (k1 `hasMoreBoxityInfo` k2), (ppr tv1 <+> ppr k1) $$ (ppr tv2 <+> ppr k2) )
 304                    tcPutTyVar tv2 (TyVarTy tv1)         `thenNF_Tc_`
 305                    returnTc ()
 306                 |  otherwise
 307
 308                 -> WARN( not (k2 `hasMoreBoxityInfo` k1), (ppr tv2 <+> ppr k2) $$ (ppr tv1 <+> ppr k1) )
 309                    (ASSERT( isNotUsgTy ps_ty2 )
 310                     tcPutTyVar tv1 ps_ty2               `thenNF_Tc_`
 311                     returnTc ())
 312   where
 313     k1 = tyVarKind tv1
 314     k2 = tyVarKind tv2
 315     update_tv2 = (k2 == openTypeKind) || (k1 /= openTypeKind && nicer_to_update_tv2)
 316                         -- Try to get rid of open type variables as soon as poss
 317
 318     nicer_to_update_tv2 =  isSigTyVar tv1
 319                                 -- Don't unify a signature type variable if poss
 320                         || isSystemName (varName tv2)
 321                                 -- Try to update sys-y type variables in preference to sig-y ones
 322
 323         -- Second one isn't a type variable
 324 uUnboundVar swapped tv1 maybe_ty1 ps_ty2 non_var_ty2
 325   = checkKinds swapped tv1 non_var_ty2                  `thenTc_`
 326     occur_check non_var_ty2                             `thenTc_`
 327     ASSERT( isNotUsgTy ps_ty2 )
 328     checkTcM (not (isSigTyVar tv1))
 329              (failWithTcM (unifyWithSigErr tv1 ps_ty2)) `thenTc_`
 330
 331     warnTc (not (typeKind non_var_ty2 `hasMoreBoxityInfo` tyVarKind tv1))
 332            ((ppr tv1 <+> ppr (tyVarKind tv1)) $$
 333              (ppr non_var_ty2 <+> ppr (typeKind non_var_ty2)))          `thenNF_Tc_`
 334
 335     tcPutTyVar tv1 non_var_ty2                          `thenNF_Tc_`
 336         -- This used to say "ps_ty2" instead of "non_var_ty2"
 337
 338         -- But that led to an infinite loop in the type checker!
 339         -- Consider
 340         --      type A a = ()
 341         --
 342         --      f :: (A a -> a -> ()) -> ()
 343         --      f = \ _ -> ()
 344         --
 345         --      x :: ()
 346         --      x = f (\ x p -> p x)
 347         --
 348         -- Here, we try to match "t" with "A t", and succeed
 349         -- because the unifier looks through synonyms.  The occurs
 350         -- check doesn't kick in because we are "really" binding "t" to "()",
 351         -- but we *actually* bind "t" to "A t" if we store ps_ty2.
 352         -- That leads the typechecker into an infinite loop later.
 353
 354     returnTc ()
 355   where
 356     occur_check ty = mapTc occur_check_tv (varSetElems (tyVarsOfType ty))       `thenTc_`
 357                      returnTc ()
 358
 359     occur_check_tv tv2
 360        | tv1 == tv2             -- Same tyvar; fail
 361        = zonkTcType ps_ty2      `thenNF_Tc` \ zonked_ty2 ->
 362          failWithTcM (unifyOccurCheck tv1 zonked_ty2)
 363
 364        | otherwise              -- A different tyvar
 365        = tcGetTyVar tv2 `thenNF_Tc` \ maybe_ty2 ->
 366          case maybe_ty2 of
 367                 Just ty2' -> occur_check ty2'
 368                 other     -> returnTc ()
 369
 370 checkKinds swapped tv1 ty2
 371 -- We're about to unify a type variable tv1 with a non-tyvar-type ty2.
 372 -- We need to check that we don't unify a boxed type variable with an
 373 -- unboxed type: e.g.  (id 3#) is illegal
 374   | tk1 == boxedTypeKind && tk2 == unboxedTypeKind
 375   = tcAddErrCtxtM (unifyKindCtxt swapped tv1 ty2)       $
 376     unifyMisMatch k1 k2
 377   | otherwise
 378   = returnTc ()
 379   where
 380     (k1,k2) | swapped   = (tk2,tk1)
 381             | otherwise = (tk1,tk2)
 382     tk1 = tyVarKind tv1
 383     tk2 = typeKind ty2
 384 \end{code}
 385
 386
 387 %************************************************************************
 388 %*                                                                      *
 389 \subsection[Unify-fun]{@unifyFunTy@}
 390 %*                                                                      *
 391 %************************************************************************
 392
 393 @unifyFunTy@ is used to avoid the fruitless creation of type variables.
 394
 395 \begin{code}
 396 unifyFunTy :: TcType                            -- Fail if ty isn't a function type
 397            -> TcM (TcType, TcType)      -- otherwise return arg and result types
 398
 399 unifyFunTy ty@(TyVarTy tyvar)
 400   = tcGetTyVar tyvar    `thenNF_Tc` \ maybe_ty ->
 401     case maybe_ty of
 402         Just ty' -> unifyFunTy ty'
 403         other       -> unify_fun_ty_help ty
 404
 405 unifyFunTy ty
 406   = case splitFunTy_maybe ty of
 407         Just arg_and_res -> returnTc arg_and_res
 408         Nothing          -> unify_fun_ty_help ty
 409
 410 unify_fun_ty_help ty    -- Special cases failed, so revert to ordinary unification
 411   = newTyVarTy openTypeKind     `thenNF_Tc` \ arg ->
 412     newTyVarTy openTypeKind     `thenNF_Tc` \ res ->
 413     unifyTauTy ty (mkFunTy arg res)     `thenTc_`
 414     returnTc (arg,res)
 415 \end{code}
 416
 417 \begin{code}
 418 unifyListTy :: TcType              -- expected list type
 419             -> TcM TcType      -- list element type
 420
 421 unifyListTy ty@(TyVarTy tyvar)
 422   = tcGetTyVar tyvar    `thenNF_Tc` \ maybe_ty ->
 423     case maybe_ty of
 424         Just ty' -> unifyListTy ty'
 425         other       -> unify_list_ty_help ty
 426
 427 unifyListTy ty
 428   = case splitTyConApp_maybe ty of
 429         Just (tycon, [arg_ty]) | tycon == listTyCon -> returnTc arg_ty
 430         other                                       -> unify_list_ty_help ty
 431
 432 unify_list_ty_help ty   -- Revert to ordinary unification
 433   = newTyVarTy boxedTypeKind            `thenNF_Tc` \ elt_ty ->
 434     unifyTauTy ty (mkListTy elt_ty)     `thenTc_`
 435     returnTc elt_ty
 436 \end{code}
 437
 438 \begin{code}
 439 unifyTupleTy :: Boxity -> Arity -> TcType -> TcM [TcType]
 440 unifyTupleTy boxity arity ty@(TyVarTy tyvar)
 441   = tcGetTyVar tyvar    `thenNF_Tc` \ maybe_ty ->
 442     case maybe_ty of
 443         Just ty' -> unifyTupleTy boxity arity ty'
 444         other    -> unify_tuple_ty_help boxity arity ty
 445
 446 unifyTupleTy boxity arity ty
 447   = case splitTyConApp_maybe ty of
 448         Just (tycon, arg_tys)
 449                 |  isTupleTyCon tycon
 450                 && tyConArity tycon == arity
 451                 && tupleTyConBoxity tycon == boxity
 452                 -> returnTc arg_tys
 453         other -> unify_tuple_ty_help boxity arity ty
 454
 455 unify_tuple_ty_help boxity arity ty
 456   = newTyVarTys arity kind                              `thenNF_Tc` \ arg_tys ->
 457     unifyTauTy ty (mkTupleTy boxity arity arg_tys)      `thenTc_`
 458     returnTc arg_tys
 459   where
 460     kind | isBoxed boxity = boxedTypeKind
 461          | otherwise      = openTypeKind
 462 \end{code}
 463
 464
 465 %************************************************************************
 466 %*                                                                      *
 467 \subsection[Unify-context]{Errors and contexts}
 468 %*                                                                      *
 469 %************************************************************************
 470
 471 Errors
 472 ~~~~~~
 473
 474 \begin{code}
 475 unifyCtxt s ty1 ty2 tidy_env    -- ty1 expected, ty2 inferred
 476   = zonkTcType ty1      `thenNF_Tc` \ ty1' ->
 477     zonkTcType ty2      `thenNF_Tc` \ ty2' ->
 478     returnNF_Tc (err ty1' ty2')
 479   where
 480     err ty1 ty2 = (env1,
 481                    nest 4
 482                         (vcat [
 483                            text "Expected" <+> text s <> colon <+> ppr tidy_ty1,
 484                            text "Inferred" <+> text s <> colon <+> ppr tidy_ty2
 485                         ]))
 486                   where
 487                     (env1, [tidy_ty1,tidy_ty2]) = tidyOpenTypes tidy_env [ty1,ty2]
 488
 489 unifyKindCtxt swapped tv1 ty2 tidy_env  -- not swapped => tv1 expected, ty2 inferred
 490         -- tv1 is zonked already
 491   = zonkTcType ty2      `thenNF_Tc` \ ty2' ->
 492     returnNF_Tc (err ty2')
 493   where
 494     err ty2 = (env2, ptext SLIT("When matching types") <+>
 495                      sep [quotes pp_expected, ptext SLIT("and"), quotes pp_actual])
 496             where
 497               (pp_expected, pp_actual) | swapped   = (pp2, pp1)
 498                                        | otherwise = (pp1, pp2)
 499               (env1, tv1') = tidyTyVar tidy_env tv1
 500               (env2, ty2') = tidyOpenType  env1 ty2
 501               pp1 = ppr tv1'
 502               pp2 = ppr ty2'
 503
 504 unifyMisMatch ty1 ty2
 505   = zonkTcType ty1      `thenNF_Tc` \ ty1' ->
 506     zonkTcType ty2      `thenNF_Tc` \ ty2' ->
 507     let
 508         (env, [tidy_ty1, tidy_ty2]) = tidyOpenTypes emptyTidyEnv [ty1',ty2']
 509         msg = hang (ptext SLIT("Couldn't match"))
 510                    4 (sep [quotes (ppr tidy_ty1),
 511                            ptext SLIT("against"),
 512                            quotes (ppr tidy_ty2)])
 513     in
 514     failWithTcM (env, msg)
 515
 516 unifyWithSigErr tyvar ty
 517   = (env2, hang (ptext SLIT("Cannot unify the type-signature variable") <+> quotes (ppr tidy_tyvar))
 518               4 (ptext SLIT("with the type") <+> quotes (ppr tidy_ty)))
 519   where
 520     (env1, tidy_tyvar) = tidyTyVar emptyTidyEnv tyvar
 521     (env2, tidy_ty)    = tidyOpenType  env1     ty
 522
 523 unifyOccurCheck tyvar ty
 524   = (env2, hang (ptext SLIT("Occurs check: cannot construct the infinite type:"))
 525               4 (sep [ppr tidy_tyvar, char '=', ppr tidy_ty]))
 526   where
 527     (env1, tidy_tyvar) = tidyTyVar emptyTidyEnv tyvar
 528     (env2, tidy_ty)    = tidyOpenType  env1     ty
 529 \end{code}
 530