ghc/compiler/types/PprType.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[PprType]{Printing Types, TyVars, Classes, TyCons}
   5
   6 \begin{code}
   7 module PprType(
   8         pprKind, pprParendKind,
   9         pprType, pprParendType,
  10         pprSourceType, pprPred, pprTheta, pprClassPred,
  11         pprTyVarBndr, pprTyVarBndrs,
  12
  13         -- Junk
  14         getTyDescription, showTypeCategory
  15  ) where
  16
  17 #include "HsVersions.h"
  18
  19 -- friends:
  20 -- (PprType can see all the representations it's trying to print)
  21 import TypeRep          ( Type(..), TyNote(..), Kind  ) -- friend
  22 import Type             ( SourceType(..) )
  23 import TcType           ( ThetaType, PredType,
  24                           tcSplitSigmaTy, isPredTy, isDictTy,
  25                           tcSplitTyConApp_maybe, tcSplitFunTy_maybe
  26                         )
  27 import Var              ( TyVar, tyVarKind )
  28 import Class            ( Class )
  29 import TyCon            ( TyCon, isPrimTyCon, isTupleTyCon, tupleTyConBoxity,
  30                           maybeTyConSingleCon, isEnumerationTyCon,
  31                           tyConArity, tyConName
  32                         )
  33
  34 -- others:
  35 import Maybes           ( maybeToBool )
  36 import Name             ( getOccString, getOccName )
  37 import OccName          ( occNameUserString )
  38 import Outputable
  39 import Unique           ( Uniquable(..) )
  40 import Util             ( lengthIs )
  41 import BasicTypes       ( IPName(..), tupleParens, ipNameName )
  42 import PrelNames                -- quite a few *Keys
  43 \end{code}
  44
  45 %************************************************************************
  46 %*                                                                      *
  47 \subsection{The external interface}
  48 %*                                                                      *
  49 %************************************************************************
  50
  51 @pprType@ is the standard @Type@ printer; the overloaded @ppr@ function is
  52 defined to use this.  @pprParendType@ is the same, except it puts
  53 parens around the type, except for the atomic cases.  @pprParendType@
  54 works just by setting the initial context precedence very high.
  55
  56 \begin{code}
  57 pprType, pprParendType :: Type -> SDoc
  58 pprType       ty = ppr_ty tOP_PREC   ty
  59 pprParendType ty = ppr_ty tYCON_PREC ty
  60
  61 pprKind, pprParendKind :: Kind -> SDoc
  62 pprKind       = pprType
  63 pprParendKind = pprParendType
  64
  65 pprPred :: PredType -> SDoc
  66 pprPred = pprSourceType
  67
  68 pprSourceType :: SourceType -> SDoc
  69 pprSourceType (ClassP clas tys) = pprClassPred clas tys
  70 pprSourceType (IParam n ty)     = hsep [ppr n, dcolon, ppr ty]
  71 pprSourceType (NType tc tys)    = ppr tc <+> sep (map pprParendType tys)
  72
  73 pprClassPred :: Class -> [Type] -> SDoc
  74 pprClassPred clas tys = ppr clas <+> sep (map pprParendType tys)
  75
  76 pprTheta :: ThetaType -> SDoc
  77 pprTheta theta = parens (sep (punctuate comma (map pprPred theta)))
  78
  79 instance Outputable Type where
  80     ppr ty = pprType ty
  81
  82 instance Outputable SourceType where
  83     ppr = pprPred
  84
  85 instance Outputable name => Outputable (IPName name) where
  86     ppr (Dupable n) = char '?' <> ppr n -- Ordinary implicit parameters
  87     ppr (Linear  n) = char '%' <> ppr n -- Splittable implicit parameters
  88 \end{code}
  89
  90
  91 %************************************************************************
  92 %*                                                                      *
  93 \subsection{Pretty printing}
  94 %*                                                                      *
  95 %************************************************************************
  96
  97 Precedence
  98 ~~~~~~~~~~
  99 @ppr_ty@ takes an @Int@ that is the precedence of the context.
 100 The precedence levels are:
 101 \begin{description}
 102 \item[tOP_PREC]   No parens required.
 103 \item[fUN_PREC]   Left hand argument of a function arrow.
 104 \item[tYCON_PREC] Argument of a type constructor.
 105 \end{description}
 106
 107
 108 \begin{code}
 109 tOP_PREC    = (0 :: Int)  -- type   in ParseIface.y
 110 fUN_PREC    = (1 :: Int)  -- btype  in ParseIface.y
 111 tYCON_PREC  = (2 :: Int)  -- atype  in ParseIface.y
 112
 113 maybeParen ctxt_prec inner_prec pretty
 114   | ctxt_prec < inner_prec = pretty
 115   | otherwise              = parens pretty
 116 \end{code}
 117
 118 \begin{code}
 119 ppr_ty :: Int -> Type -> SDoc
 120 ppr_ty ctxt_prec (TyVarTy tyvar)
 121   = ppr tyvar
 122
 123 ppr_ty ctxt_prec ty@(TyConApp tycon tys)
 124         -- KIND CASE; it's of the form (Type x)
 125   | tycon `hasKey` typeConKey,
 126     [ty] <- tys
 127   =     -- For kinds, print (Type x) as just x if x is a
 128         --      type constructor (must be Boxed, Unboxed, AnyBox)
 129         -- Otherwise print as (Type x)
 130     case ty of
 131         TyConApp bx [] -> ppr (getOccName bx)   -- Always unqualified
 132         other          -> maybeParen ctxt_prec tYCON_PREC
 133                                      (ppr tycon <+> ppr_ty tYCON_PREC ty)
 134
 135         -- USAGE CASE
 136   | (tycon `hasKey` usOnceTyConKey || tycon `hasKey` usManyTyConKey),
 137     null tys
 138   =     -- For usages (! and .), always print bare OccName, without pkg/mod/uniq
 139     ppr (getOccName (tyConName tycon))
 140
 141         -- TUPLE CASE (boxed and unboxed)
 142   |  isTupleTyCon tycon,
 143       tys `lengthIs` tyConArity tycon   -- No magic if partially applied
 144   = tupleParens (tupleTyConBoxity tycon)
 145                 (sep (punctuate comma (map (ppr_ty tOP_PREC) tys)))
 146
 147         -- LIST CASE
 148   | tycon `hasKey` listTyConKey,
 149     [ty] <- tys
 150   = brackets (ppr_ty tOP_PREC ty)
 151
 152         -- PARALLEL ARRAY CASE
 153   | tycon `hasKey` parrTyConKey,
 154     [ty] <- tys
 155   = pabrackets (ppr_ty tOP_PREC ty)
 156
 157         -- GENERAL CASE
 158   | otherwise
 159   = ppr_tc_app ctxt_prec tycon tys
 160
 161   where
 162     pabrackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 163
 164
 165 ppr_ty ctxt_prec ty@(ForAllTy _ _)
 166   = getPprStyle $ \ sty ->
 167     maybeParen ctxt_prec fUN_PREC $
 168     sep [ ptext SLIT("forall") <+> pp_tyvars sty <> ptext SLIT("."),
 169           ppr_theta theta,
 170           ppr_ty tOP_PREC tau
 171     ]
 172  where
 173     (tyvars, theta, tau) = tcSplitSigmaTy ty
 174     pp_tyvars sty        = sep (map pprTyVarBndr tyvars)
 175
 176     ppr_theta []     = empty
 177     ppr_theta theta  = pprTheta theta <+> ptext SLIT("=>")
 178
 179
 180 ppr_ty ctxt_prec (FunTy ty1 ty2)
 181   -- we don't want to lose usage annotations or synonyms,
 182   -- so we mustn't use splitFunTys here.
 183   = maybeParen ctxt_prec fUN_PREC $
 184     sep [ ppr_ty fUN_PREC ty1
 185         , ptext arrow <+> ppr_ty tOP_PREC ty2
 186         ]
 187   where arrow | isPredTy ty1 = SLIT("=>")
 188               | otherwise    = SLIT("->")
 189
 190 ppr_ty ctxt_prec (AppTy ty1 ty2)
 191   = maybeParen ctxt_prec tYCON_PREC $
 192     ppr_ty fUN_PREC ty1 <+> ppr_ty tYCON_PREC ty2
 193
 194 ppr_ty ctxt_prec (NoteTy (SynNote ty) expansion)
 195   = ppr_ty ctxt_prec ty
 196 --  = ppr_ty ctxt_prec expansion -- if we don't want to see syntys
 197
 198 ppr_ty ctxt_prec (NoteTy (FTVNote _) ty) = ppr_ty ctxt_prec ty
 199
 200 ppr_ty ctxt_prec (SourceTy (NType tc tys)) = ppr_tc_app ctxt_prec tc tys
 201 ppr_ty ctxt_prec (SourceTy pred)           = braces (pprPred pred)
 202
 203 ppr_tc_app ctxt_prec tc []  = ppr tc
 204 ppr_tc_app ctxt_prec tc tys = maybeParen ctxt_prec tYCON_PREC
 205                                          (sep [ppr tc, nest 4 (sep (map (ppr_ty tYCON_PREC) tys))])
 206 \end{code}
 207
 208
 209 %************************************************************************
 210 %*                                                                      *
 211 \subsection[TyVar]{@TyVar@}
 212 %*                                                                      *
 213 %************************************************************************
 214
 215 We print type-variable binders with their kinds in interface files,
 216 and when in debug mode.
 217
 218 \begin{code}
 219 pprTyVarBndr :: TyVar -> SDoc
 220 pprTyVarBndr tyvar
 221   = getPprStyle $ \ sty ->
 222     if debugStyle sty then
 223         hsep [ppr tyvar, dcolon, pprParendKind kind]
 224                 -- See comments with ppDcolon in PprCore.lhs
 225     else
 226         ppr tyvar
 227   where
 228     kind = tyVarKind tyvar
 229
 230 pprTyVarBndrs tyvars = hsep (map pprTyVarBndr tyvars)
 231 \end{code}
 232
 233
 234 %************************************************************************
 235 %*                                                                      *
 236 \subsection{Mumbo jumbo}
 237 %*                                                                      *
 238 %************************************************************************
 239
 240 Grab a name for the type. This is used to determine the type
 241 description for profiling.
 242
 243 \begin{code}
 244 getTyDescription :: Type -> String
 245
 246 getTyDescription ty
 247   = case (tcSplitSigmaTy ty) of { (_, _, tau_ty) ->
 248     case tau_ty of
 249       TyVarTy _              -> "*"
 250       AppTy fun _            -> getTyDescription fun
 251       FunTy _ res            -> '-' : '>' : fun_result res
 252       TyConApp tycon _       -> occNameUserString (getOccName tycon)
 253       NoteTy (FTVNote _) ty  -> getTyDescription ty
 254       NoteTy (SynNote ty1) _ -> getTyDescription ty1
 255       SourceTy sty           -> getSourceTyDescription sty
 256       ForAllTy _ ty          -> getTyDescription ty
 257     }
 258   where
 259     fun_result (FunTy _ res) = '>' : fun_result res
 260     fun_result other         = getTyDescription other
 261
 262 getSourceTyDescription (ClassP cl tys) = getOccString cl
 263 getSourceTyDescription (NType  tc tys) = getOccString tc
 264 getSourceTyDescription (IParam ip ty)  = getOccString (ipNameName ip)
 265 \end{code}
 266
 267
 268 \begin{code}
 269 showTypeCategory :: Type -> Char
 270   {-
 271         {C,I,F,D}   char, int, float, double
 272         T           tuple
 273         S           other single-constructor type
 274         {c,i,f,d}   unboxed ditto
 275         t           *unpacked* tuple
 276         s           *unpacked" single-cons...
 277
 278         v           void#
 279         a           primitive array
 280
 281         E           enumeration type
 282         +           dictionary, unless it's a ...
 283         L           List
 284         >           function
 285         M           other (multi-constructor) data-con type
 286         .           other type
 287         -           reserved for others to mark as "uninteresting"
 288     -}
 289 showTypeCategory ty
 290   = if isDictTy ty
 291     then '+'
 292     else
 293       case tcSplitTyConApp_maybe ty of
 294         Nothing -> if maybeToBool (tcSplitFunTy_maybe ty)
 295                    then '>'
 296                    else '.'
 297
 298         Just (tycon, _) ->
 299           let utc = getUnique tycon in
 300           if      utc == charDataConKey    then 'C'
 301           else if utc == intDataConKey     then 'I'
 302           else if utc == floatDataConKey   then 'F'
 303           else if utc == doubleDataConKey  then 'D'
 304           else if utc == smallIntegerDataConKey ||
 305                   utc == largeIntegerDataConKey   then 'J'
 306           else if utc == charPrimTyConKey  then 'c'
 307           else if (utc == intPrimTyConKey || utc == wordPrimTyConKey
 308                 || utc == addrPrimTyConKey)                then 'i'
 309           else if utc  == floatPrimTyConKey                then 'f'
 310           else if utc  == doublePrimTyConKey               then 'd'
 311           else if isPrimTyCon tycon {- array, we hope -}   then 'A'     -- Bogus
 312           else if isEnumerationTyCon tycon                 then 'E'
 313           else if isTupleTyCon tycon                       then 'T'
 314           else if maybeToBool (maybeTyConSingleCon tycon)  then 'S'
 315           else if utc == listTyConKey                      then 'L'
 316           else 'M' -- oh, well...
 317 \end{code}