ghc/compiler/types/PprType.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[PprType]{Printing Types, TyVars, Classes, TyCons}
   5
   6 \begin{code}
   7 module PprType(
   8         pprKind, pprParendKind,
   9         pprType, pprParendType,
  10         pprSourceType, pprPred, pprTheta, pprClassPred,
  11         pprTyVarBndr, pprTyVarBndrs,
  12
  13         -- Junk
  14         getTyDescription, showTypeCategory
  15  ) where
  16
  17 #include "HsVersions.h"
  18
  19 -- friends:
  20 -- (PprType can see all the representations it's trying to print)
  21 import TypeRep          ( Type(..), TyNote(..),
  22                           Kind, liftedTypeKind ) -- friend
  23 import Type             ( SourceType(..), eqKind )
  24 import TcType           ( ThetaType, PredType,
  25                           tcSplitSigmaTy, isPredTy, isDictTy,
  26                           tcSplitTyConApp_maybe, tcSplitFunTy_maybe
  27                         )
  28 import Var              ( TyVar, tyVarKind )
  29 import Class            ( Class )
  30 import TyCon            ( TyCon, isPrimTyCon, isTupleTyCon, tupleTyConBoxity,
  31                           maybeTyConSingleCon, isEnumerationTyCon,
  32                           tyConArity, tyConName
  33                         )
  34
  35 -- others:
  36 import CmdLineOpts      ( opt_PprStyle_RawTypes )
  37 import Maybes           ( maybeToBool )
  38 import Name             ( getOccString, getOccName )
  39 import OccName          ( occNameUserString )
  40 import Outputable
  41 import Unique           ( Uniquable(..) )
  42 import Util             ( lengthIs )
  43 import BasicTypes       ( IPName(..), tupleParens, ipNameName )
  44 import PrelNames                -- quite a few *Keys
  45 \end{code}
  46
  47 %************************************************************************
  48 %*                                                                      *
  49 \subsection{The external interface}
  50 %*                                                                      *
  51 %************************************************************************
  52
  53 @pprType@ is the standard @Type@ printer; the overloaded @ppr@ function is
  54 defined to use this.  @pprParendType@ is the same, except it puts
  55 parens around the type, except for the atomic cases.  @pprParendType@
  56 works just by setting the initial context precedence very high.
  57
  58 \begin{code}
  59 pprType, pprParendType :: Type -> SDoc
  60 pprType       ty = ppr_ty tOP_PREC   ty
  61 pprParendType ty = ppr_ty tYCON_PREC ty
  62
  63 pprKind, pprParendKind :: Kind -> SDoc
  64 pprKind       = pprType
  65 pprParendKind = pprParendType
  66
  67 pprPred :: PredType -> SDoc
  68 pprPred = pprSourceType
  69
  70 pprSourceType :: SourceType -> SDoc
  71 pprSourceType (ClassP clas tys) = pprClassPred clas tys
  72 pprSourceType (IParam n ty)     = hsep [ppr n, dcolon, ppr ty]
  73 pprSourceType (NType tc tys)    = ppr tc <+> hsep (map pprParendType tys)
  74
  75 pprClassPred :: Class -> [Type] -> SDoc
  76 pprClassPred clas tys = ppr clas <+> hsep (map pprParendType tys)
  77
  78 pprTheta :: ThetaType -> SDoc
  79 pprTheta theta = parens (hsep (punctuate comma (map pprPred theta)))
  80
  81 instance Outputable Type where
  82     ppr ty = pprType ty
  83
  84 instance Outputable SourceType where
  85     ppr = pprPred
  86
  87 instance Outputable name => Outputable (IPName name) where
  88     ppr (Dupable n) = char '?' <> ppr n -- Ordinary implicit parameters
  89     ppr (Linear  n) = char '%' <> ppr n -- Splittable implicit parameters
  90 \end{code}
  91
  92
  93 %************************************************************************
  94 %*                                                                      *
  95 \subsection{Pretty printing}
  96 %*                                                                      *
  97 %************************************************************************
  98
  99 Precedence
 100 ~~~~~~~~~~
 101 @ppr_ty@ takes an @Int@ that is the precedence of the context.
 102 The precedence levels are:
 103 \begin{description}
 104 \item[tOP_PREC]   No parens required.
 105 \item[fUN_PREC]   Left hand argument of a function arrow.
 106 \item[tYCON_PREC] Argument of a type constructor.
 107 \end{description}
 108
 109
 110 \begin{code}
 111 tOP_PREC    = (0 :: Int)  -- type   in ParseIface.y
 112 fUN_PREC    = (1 :: Int)  -- btype  in ParseIface.y
 113 tYCON_PREC  = (2 :: Int)  -- atype  in ParseIface.y
 114
 115 maybeParen ctxt_prec inner_prec pretty
 116   | ctxt_prec < inner_prec = pretty
 117   | otherwise              = parens pretty
 118 \end{code}
 119
 120 \begin{code}
 121 ppr_ty :: Int -> Type -> SDoc
 122 ppr_ty ctxt_prec (TyVarTy tyvar)
 123   = ppr tyvar
 124
 125 ppr_ty ctxt_prec ty@(TyConApp tycon tys)
 126         -- KIND CASE; it's of the form (Type x)
 127   | tycon `hasKey` typeConKey,
 128     [ty] <- tys
 129   =     -- For kinds, print (Type x) as just x if x is a
 130         --      type constructor (must be Boxed, Unboxed, AnyBox)
 131         -- Otherwise print as (Type x)
 132     case ty of
 133         TyConApp bx [] -> ppr (getOccName bx)   -- Always unqualified
 134         other          -> maybeParen ctxt_prec tYCON_PREC
 135                                      (ppr tycon <+> ppr_ty tYCON_PREC ty)
 136
 137         -- USAGE CASE
 138   | (tycon `hasKey` usOnceTyConKey || tycon `hasKey` usManyTyConKey),
 139     null tys
 140   =     -- For usages (! and .), always print bare OccName, without pkg/mod/uniq
 141     ppr (getOccName (tyConName tycon))
 142
 143         -- TUPLE CASE (boxed and unboxed)
 144   |  isTupleTyCon tycon,
 145       tys `lengthIs` tyConArity tycon   -- No magic if partially applied
 146   = tupleParens (tupleTyConBoxity tycon)
 147                 (sep (punctuate comma (map (ppr_ty tOP_PREC) tys)))
 148
 149         -- LIST CASE
 150   | tycon `hasKey` listTyConKey,
 151     [ty] <- tys
 152   = brackets (ppr_ty tOP_PREC ty)
 153
 154         -- GENERAL CASE
 155   | otherwise
 156   = ppr_tc_app ctxt_prec tycon tys
 157
 158
 159 ppr_ty ctxt_prec ty@(ForAllTy _ _)
 160   = getPprStyle $ \ sty ->
 161     maybeParen ctxt_prec fUN_PREC $
 162     sep [ ptext SLIT("forall") <+> pp_tyvars sty <> ptext SLIT("."),
 163           ppr_theta theta,
 164           ppr_ty tOP_PREC tau
 165     ]
 166  where
 167     (tyvars, theta, tau) = tcSplitSigmaTy ty
 168     pp_tyvars sty        = sep (map pprTyVarBndr tyvars)
 169
 170     ppr_theta []     = empty
 171     ppr_theta theta  = pprTheta theta <+> ptext SLIT("=>")
 172
 173
 174 ppr_ty ctxt_prec (FunTy ty1 ty2)
 175   -- we don't want to lose usage annotations or synonyms,
 176   -- so we mustn't use splitFunTys here.
 177   = maybeParen ctxt_prec fUN_PREC $
 178     sep [ ppr_ty fUN_PREC ty1
 179         , ptext arrow <+> ppr_ty tOP_PREC ty2
 180         ]
 181   where arrow | isPredTy ty1 = SLIT("=>")
 182               | otherwise    = SLIT("->")
 183
 184 ppr_ty ctxt_prec (AppTy ty1 ty2)
 185   = maybeParen ctxt_prec tYCON_PREC $
 186     ppr_ty fUN_PREC ty1 <+> ppr_ty tYCON_PREC ty2
 187
 188 ppr_ty ctxt_prec (NoteTy (SynNote ty) expansion)
 189   = ppr_ty ctxt_prec ty
 190 --  = ppr_ty ctxt_prec expansion -- if we don't want to see syntys
 191
 192 ppr_ty ctxt_prec (NoteTy (FTVNote _) ty) = ppr_ty ctxt_prec ty
 193
 194 ppr_ty ctxt_prec (SourceTy (NType tc tys)) = ppr_tc_app ctxt_prec tc tys
 195 ppr_ty ctxt_prec (SourceTy pred)           = braces (pprPred pred)
 196
 197 ppr_tc_app ctxt_prec tc []  = ppr tc
 198 ppr_tc_app ctxt_prec tc tys = maybeParen ctxt_prec tYCON_PREC
 199                                          (sep [ppr tc, nest 4 (sep (map (ppr_ty tYCON_PREC) tys))])
 200 \end{code}
 201
 202
 203 %************************************************************************
 204 %*                                                                      *
 205 \subsection[TyVar]{@TyVar@}
 206 %*                                                                      *
 207 %************************************************************************
 208
 209 We print type-variable binders with their kinds in interface files,
 210 and when in debug mode.
 211
 212 \begin{code}
 213 pprTyVarBndr :: TyVar -> SDoc
 214 pprTyVarBndr tyvar
 215   = getPprStyle $ \ sty ->
 216     if (ifaceStyle sty  && not (kind `eqKind` liftedTypeKind)) || debugStyle sty then
 217         hsep [ppr tyvar, dcolon, pprParendKind kind]
 218                 -- See comments with ppDcolon in PprCore.lhs
 219     else
 220         ppr tyvar
 221   where
 222     kind = tyVarKind tyvar
 223
 224 pprTyVarBndrs tyvars = hsep (map pprTyVarBndr tyvars)
 225 \end{code}
 226
 227
 228 %************************************************************************
 229 %*                                                                      *
 230 \subsection{Mumbo jumbo}
 231 %*                                                                      *
 232 %************************************************************************
 233
 234 Grab a name for the type. This is used to determine the type
 235 description for profiling.
 236
 237 \begin{code}
 238 getTyDescription :: Type -> String
 239
 240 getTyDescription ty
 241   = case (tcSplitSigmaTy ty) of { (_, _, tau_ty) ->
 242     case tau_ty of
 243       TyVarTy _              -> "*"
 244       AppTy fun _            -> getTyDescription fun
 245       FunTy _ res            -> '-' : '>' : fun_result res
 246       TyConApp tycon _       -> occNameUserString (getOccName tycon)
 247       NoteTy (FTVNote _) ty  -> getTyDescription ty
 248       NoteTy (SynNote ty1) _ -> getTyDescription ty1
 249       SourceTy sty           -> getSourceTyDescription sty
 250       ForAllTy _ ty          -> getTyDescription ty
 251     }
 252   where
 253     fun_result (FunTy _ res) = '>' : fun_result res
 254     fun_result other         = getTyDescription other
 255
 256 getSourceTyDescription (ClassP cl tys) = getOccString cl
 257 getSourceTyDescription (NType  tc tys) = getOccString tc
 258 getSourceTyDescription (IParam ip ty)  = getOccString (ipNameName ip)
 259 \end{code}
 260
 261
 262 \begin{code}
 263 showTypeCategory :: Type -> Char
 264   {-
 265         {C,I,F,D}   char, int, float, double
 266         T           tuple
 267         S           other single-constructor type
 268         {c,i,f,d}   unboxed ditto
 269         t           *unpacked* tuple
 270         s           *unpacked" single-cons...
 271
 272         v           void#
 273         a           primitive array
 274
 275         E           enumeration type
 276         +           dictionary, unless it's a ...
 277         L           List
 278         >           function
 279         M           other (multi-constructor) data-con type
 280         .           other type
 281         -           reserved for others to mark as "uninteresting"
 282     -}
 283 showTypeCategory ty
 284   = if isDictTy ty
 285     then '+'
 286     else
 287       case tcSplitTyConApp_maybe ty of
 288         Nothing -> if maybeToBool (tcSplitFunTy_maybe ty)
 289                    then '>'
 290                    else '.'
 291
 292         Just (tycon, _) ->
 293           let utc = getUnique tycon in
 294           if      utc == charDataConKey    then 'C'
 295           else if utc == intDataConKey     then 'I'
 296           else if utc == floatDataConKey   then 'F'
 297           else if utc == doubleDataConKey  then 'D'
 298           else if utc == smallIntegerDataConKey ||
 299                   utc == largeIntegerDataConKey   then 'J'
 300           else if utc == charPrimTyConKey  then 'c'
 301           else if (utc == intPrimTyConKey || utc == wordPrimTyConKey
 302                 || utc == addrPrimTyConKey)                then 'i'
 303           else if utc  == floatPrimTyConKey                then 'f'
 304           else if utc  == doublePrimTyConKey               then 'd'
 305           else if isPrimTyCon tycon {- array, we hope -}   then 'A'     -- Bogus
 306           else if isEnumerationTyCon tycon                 then 'E'
 307           else if isTupleTyCon tycon                       then 'T'
 308           else if maybeToBool (maybeTyConSingleCon tycon)  then 'S'
 309           else if utc == listTyConKey                      then 'L'
 310           else 'M' -- oh, well...
 311 \end{code}