ghc/compiler/types/PprType.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[PprType]{Printing Types, TyVars, Classes, TyCons}
   5
   6 \begin{code}
   7 module PprType(
   8         pprKind, pprParendKind,
   9         pprType, pprParendType,
  10         pprConstraint, pprTheta,
  11         pprTyVarBndr, pprTyVarBndrs,
  12
  13         -- Junk
  14         getTyDescription, showTypeCategory
  15  ) where
  16
  17 #include "HsVersions.h"
  18
  19 -- friends:
  20 -- (PprType can see all the representations it's trying to print)
  21 import Type             ( Type(..), TyNote(..), Kind, ThetaType,
  22                           splitFunTys, splitDictTy_maybe,
  23                           splitForAllTys, splitSigmaTy, splitRhoTy,
  24                           isDictTy, splitTyConApp_maybe, splitFunTy_maybe,
  25                           boxedTypeKind
  26                         )
  27 import Var              ( TyVar, tyVarKind,
  28                           tyVarName, setTyVarName
  29                         )
  30 import VarEnv
  31 import TyCon            ( TyCon, isPrimTyCon, isTupleTyCon, isUnboxedTupleTyCon,
  32                           maybeTyConSingleCon, isEnumerationTyCon,
  33                           tyConArity, tyConUnique
  34                         )
  35 import Class            ( Class )
  36
  37 -- others:
  38 import Maybes           ( maybeToBool )
  39 import Name             ( getOccString, NamedThing(..) )
  40 import Outputable
  41 import PprEnv
  42 import Unique           ( Uniquable(..) )
  43 import Unique           -- quite a few *Keys
  44 import Util
  45 \end{code}
  46
  47 %************************************************************************
  48 %*                                                                      *
  49 \subsection{The external interface}
  50 %*                                                                      *
  51 %************************************************************************
  52
  53 @pprType@ is the standard @Type@ printer; the overloaded @ppr@ function is
  54 defined to use this.  @pprParendType@ is the same, except it puts
  55 parens around the type, except for the atomic cases.  @pprParendType@
  56 works just by setting the initial context precedence very high.
  57
  58 \begin{code}
  59 pprType, pprParendType :: Type -> SDoc
  60 pprType       ty = ppr_ty pprTyEnv tOP_PREC   ty
  61 pprParendType ty = ppr_ty pprTyEnv tYCON_PREC ty
  62
  63 pprKind, pprParendKind :: Kind -> SDoc
  64 pprKind       = pprType
  65 pprParendKind = pprParendType
  66
  67 pprConstraint :: Class -> [Type] -> SDoc
  68 pprConstraint clas tys = ppr clas <+> hsep (map (pprParendType) tys)
  69
  70 pprTheta :: ThetaType -> SDoc
  71 pprTheta theta = parens (hsep (punctuate comma (map ppr_dict theta)))
  72                where
  73                  ppr_dict (c,tys) = pprConstraint c tys
  74
  75 instance Outputable Type where
  76     ppr ty = pprType ty
  77 \end{code}
  78
  79
  80 %************************************************************************
  81 %*                                                                      *
  82 \subsection{Pretty printing}
  83 %*                                                                      *
  84 %************************************************************************
  85
  86 Precedence
  87 ~~~~~~~~~~
  88 @ppr_ty@ takes an @Int@ that is the precedence of the context.
  89 The precedence levels are:
  90 \begin{description}
  91 \item[tOP_PREC]   No parens required.
  92 \item[fUN_PREC]   Left hand argument of a function arrow.
  93 \item[tYCON_PREC] Argument of a type constructor.
  94 \end{description}
  95
  96
  97 \begin{code}
  98 tOP_PREC    = (0 :: Int)
  99 fUN_PREC    = (1 :: Int)
 100 tYCON_PREC  = (2 :: Int)
 101
 102 maybeParen ctxt_prec inner_prec pretty
 103   | ctxt_prec < inner_prec = pretty
 104   | otherwise              = parens pretty
 105 \end{code}
 106
 107 \begin{code}
 108 ppr_ty :: PprEnv TyVar -> Int -> Type -> SDoc
 109 ppr_ty env ctxt_prec (TyVarTy tyvar)
 110   = pTyVarO env tyvar
 111
 112 ppr_ty env ctxt_prec ty@(TyConApp tycon tys)
 113         -- KIND CASE; it's of the form (Type x)
 114   | tycon_uniq == typeConKey && n_tys == 1
 115   =     -- For kinds, print (Type x) as just x if x is a
 116         --      type constructor (must be Boxed, Unboxed, AnyBox)
 117         -- Otherwise print as (Type x)
 118     case ty1 of
 119         TyConApp bx [] -> ppr bx
 120         other          -> maybeParen ctxt_prec tYCON_PREC
 121                                      (ppr tycon <+> tys_w_spaces)
 122
 123
 124         -- TUPLE CASE (boxed and unboxed)
 125   |  isTupleTyCon tycon
 126   && length tys == tyConArity tycon     -- no magic if partially applied
 127   = parens tys_w_commas
 128
 129   |  isUnboxedTupleTyCon tycon
 130   && length tys == tyConArity tycon     -- no magic if partially applied
 131   = parens (char '#' <+> tys_w_commas <+> char '#')
 132
 133         -- LIST CASE
 134   | tycon_uniq == listTyConKey && n_tys == 1
 135   = brackets (ppr_ty env tOP_PREC ty1)
 136
 137         -- DICTIONARY CASE, prints {C a}
 138         -- This means that instance decls come out looking right in interfaces
 139         -- and that in turn means they get "gated" correctly when being slurped in
 140   | maybeToBool maybe_dict
 141   = braces (ppr_dict env tYCON_PREC ctys)
 142
 143         -- NO-ARGUMENT CASE (=> no parens)
 144   | null tys
 145   = ppr tycon
 146
 147         -- GENERAL CASE
 148   | otherwise
 149   = maybeParen ctxt_prec tYCON_PREC (hsep [ppr tycon, tys_w_spaces])
 150
 151   where
 152     tycon_uniq = tyConUnique tycon
 153     n_tys      = length tys
 154     (ty1:_)    = tys
 155     Just ctys  = maybe_dict
 156     maybe_dict = splitDictTy_maybe ty   -- Checks class and arity
 157     tys_w_commas = sep (punctuate comma (map (ppr_ty env tOP_PREC) tys))
 158     tys_w_spaces = hsep (map (ppr_ty env tYCON_PREC) tys)
 159
 160
 161
 162 ppr_ty env ctxt_prec ty@(ForAllTy _ _)
 163   = getPprStyle $ \ sty ->
 164     maybeParen ctxt_prec fUN_PREC $
 165     if ifaceStyle sty then
 166        sep [ ptext SLIT("__forall") <+> brackets pp_tyvars, pp_ctxt, pp_body ]
 167     else
 168        sep [ ptext SLIT("forall") <+> pp_tyvars <> ptext SLIT("."), pp_maybe_ctxt, pp_body ]
 169   where
 170     (tyvars, rho_ty) = splitForAllTys ty
 171     (theta, body_ty) = splitRhoTy rho_ty
 172
 173     pp_tyvars = hsep (map (pBndr env LambdaBind) tyvars)
 174     pp_body   = ppr_ty env tOP_PREC body_ty
 175
 176     pp_maybe_ctxt | null theta = empty
 177                   | otherwise  = pp_ctxt
 178
 179     pp_ctxt = ppr_theta env theta <+> ptext SLIT("=>")
 180
 181
 182 ppr_ty env ctxt_prec (FunTy ty1 ty2)
 183     -- We fiddle the precedences passed to left/right branches,
 184     -- so that right associativity comes out nicely...
 185   = maybeParen ctxt_prec fUN_PREC (sep (ppr_ty env fUN_PREC ty1 : pp_rest))
 186   where
 187     (arg_tys, result_ty) = splitFunTys ty2
 188     pp_rest = [ ptext SLIT("-> ") <> ppr_ty env fUN_PREC ty | ty <- arg_tys ++ [result_ty] ]
 189
 190 ppr_ty env ctxt_prec (AppTy ty1 ty2)
 191   = maybeParen ctxt_prec tYCON_PREC $
 192     ppr_ty env tOP_PREC ty1 <+> ppr_ty env tYCON_PREC ty2
 193
 194 ppr_ty env ctxt_prec (NoteTy (SynNote ty) expansion)
 195   = ppr_ty env ctxt_prec ty
 196
 197 ppr_ty env ctxt_prec (NoteTy (FTVNote _) ty) = ppr_ty env ctxt_prec ty
 198
 199 ppr_theta env []    = empty
 200 ppr_theta env theta = braces (hsep (punctuate comma (map (ppr_dict env tOP_PREC) theta)))
 201
 202 ppr_dict env ctxt (clas, tys) = ppr clas <+>
 203                                 hsep (map (ppr_ty env tYCON_PREC) tys)
 204 \end{code}
 205
 206 \begin{code}
 207 pprTyEnv = initPprEnv b b (Just ppr) b (Just (\site -> pprTyVarBndr)) b
 208   where
 209     b = panic "PprType:init_ppr_env"
 210 \end{code}
 211
 212 %************************************************************************
 213 %*                                                                      *
 214 \subsection[TyVar]{@TyVar@}
 215 %*                                                                      *
 216 %************************************************************************
 217
 218 We print type-variable binders with their kinds in interface files,
 219 and when in debug mode.
 220
 221 \begin{code}
 222 pprTyVarBndr tyvar
 223   = getPprStyle $ \ sty ->
 224     if (ifaceStyle sty || debugStyle sty) && kind /= boxedTypeKind then
 225         hsep [ppr tyvar, dcolon, pprParendKind kind]
 226                 -- See comments with ppDcolon in PprCore.lhs
 227     else
 228         ppr tyvar
 229   where
 230     kind = tyVarKind tyvar
 231
 232 pprTyVarBndrs tyvars = hsep (map pprTyVarBndr tyvars)
 233 \end{code}
 234
 235
 236 %************************************************************************
 237 %*                                                                      *
 238 \subsection{Mumbo jumbo}
 239 %*                                                                      *
 240 %************************************************************************
 241
 242 Grab a name for the type. This is used to determine the type
 243 description for profiling.
 244
 245 \begin{code}
 246 getTyDescription :: Type -> String
 247
 248 getTyDescription ty
 249   = case (splitSigmaTy ty) of { (_, _, tau_ty) ->
 250     case tau_ty of
 251       TyVarTy _        -> "*"
 252       AppTy fun _      -> getTyDescription fun
 253       FunTy _ res      -> '-' : '>' : fun_result res
 254       TyConApp tycon _ -> getOccString tycon
 255       NoteTy (FTVNote _) ty  -> getTyDescription ty
 256       NoteTy (SynNote ty1) _ -> getTyDescription ty1
 257       ForAllTy _ ty    -> getTyDescription ty
 258     }
 259   where
 260     fun_result (FunTy _ res) = '>' : fun_result res
 261     fun_result other         = getTyDescription other
 262 \end{code}
 263
 264
 265 \begin{code}
 266 showTypeCategory :: Type -> Char
 267   {-
 268         {C,I,F,D}   char, int, float, double
 269         T           tuple
 270         S           other single-constructor type
 271         {c,i,f,d}   unboxed ditto
 272         t           *unpacked* tuple
 273         s           *unpacked" single-cons...
 274
 275         v           void#
 276         a           primitive array
 277
 278         E           enumeration type
 279         +           dictionary, unless it's a ...
 280         L           List
 281         >           function
 282         M           other (multi-constructor) data-con type
 283         .           other type
 284         -           reserved for others to mark as "uninteresting"
 285     -}
 286 showTypeCategory ty
 287   = if isDictTy ty
 288     then '+'
 289     else
 290       case splitTyConApp_maybe ty of
 291         Nothing -> if maybeToBool (splitFunTy_maybe ty)
 292                    then '>'
 293                    else '.'
 294
 295         Just (tycon, _) ->
 296           let utc = getUnique tycon in
 297           if      utc == charDataConKey    then 'C'
 298           else if utc == intDataConKey     then 'I'
 299           else if utc == floatDataConKey   then 'F'
 300           else if utc == doubleDataConKey  then 'D'
 301           else if utc == integerDataConKey then 'J'
 302           else if utc == charPrimTyConKey  then 'c'
 303           else if (utc == intPrimTyConKey || utc == wordPrimTyConKey
 304                 || utc == addrPrimTyConKey)                then 'i'
 305           else if utc  == floatPrimTyConKey                then 'f'
 306           else if utc  == doublePrimTyConKey               then 'd'
 307           else if isPrimTyCon tycon {- array, we hope -}   then 'A'
 308           else if isEnumerationTyCon tycon                 then 'E'
 309           else if isTupleTyCon tycon                       then 'T'
 310           else if maybeToBool (maybeTyConSingleCon tycon)  then 'S'
 311           else if utc == listTyConKey                      then 'L'
 312           else 'M' -- oh, well...
 313 \end{code}