ghc/compiler/types/PprType.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[PprType]{Printing Types, TyVars, Classes, TyCons}
   5
   6 \begin{code}
   7 module PprType(
   8         pprKind, pprParendKind,
   9         pprType, pprParendType,
  10         pprSourceType, pprPred, pprTheta, pprClassPred,
  11         pprTyVarBndr, pprTyVarBndrs,
  12
  13         -- Junk
  14         getTyDescription, showTypeCategory
  15  ) where
  16
  17 #include "HsVersions.h"
  18
  19 -- friends:
  20 -- (PprType can see all the representations it's trying to print)
  21 import TypeRep          ( Type(..), TyNote(..),
  22                           Kind, liftedTypeKind ) -- friend
  23 import Type             ( SourceType(..), isUTyVar, eqKind )
  24 import TcType           ( ThetaType, PredType,
  25                           tcSplitSigmaTy, isPredTy, isDictTy,
  26                           tcSplitTyConApp_maybe, tcSplitFunTy_maybe
  27                         )
  28 import Var              ( TyVar, tyVarKind )
  29 import Class            ( Class )
  30 import TyCon            ( TyCon, isPrimTyCon, isTupleTyCon, tupleTyConBoxity,
  31                           maybeTyConSingleCon, isEnumerationTyCon,
  32                           tyConArity, tyConName
  33                         )
  34
  35 -- others:
  36 import CmdLineOpts      ( opt_PprStyle_RawTypes )
  37 import Maybes           ( maybeToBool )
  38 import Name             ( getOccString, getOccName )
  39 import OccName          ( occNameUserString )
  40 import Outputable
  41 import Unique           ( Uniquable(..) )
  42 import Util             ( lengthIs )
  43 import BasicTypes       ( IPName(..), tupleParens, ipNameName )
  44 import PrelNames                -- quite a few *Keys
  45 \end{code}
  46
  47 %************************************************************************
  48 %*                                                                      *
  49 \subsection{The external interface}
  50 %*                                                                      *
  51 %************************************************************************
  52
  53 @pprType@ is the standard @Type@ printer; the overloaded @ppr@ function is
  54 defined to use this.  @pprParendType@ is the same, except it puts
  55 parens around the type, except for the atomic cases.  @pprParendType@
  56 works just by setting the initial context precedence very high.
  57
  58 \begin{code}
  59 pprType, pprParendType :: Type -> SDoc
  60 pprType       ty = ppr_ty tOP_PREC   ty
  61 pprParendType ty = ppr_ty tYCON_PREC ty
  62
  63 pprKind, pprParendKind :: Kind -> SDoc
  64 pprKind       = pprType
  65 pprParendKind = pprParendType
  66
  67 pprPred :: PredType -> SDoc
  68 pprPred = pprSourceType
  69
  70 pprSourceType :: SourceType -> SDoc
  71 pprSourceType (ClassP clas tys) = pprClassPred clas tys
  72 pprSourceType (IParam n ty)     = hsep [ppr n, dcolon, ppr ty]
  73 pprSourceType (NType tc tys)    = ppr tc <+> hsep (map pprParendType tys)
  74
  75 pprClassPred :: Class -> [Type] -> SDoc
  76 pprClassPred clas tys = ppr clas <+> hsep (map pprParendType tys)
  77
  78 pprTheta :: ThetaType -> SDoc
  79 pprTheta theta = parens (hsep (punctuate comma (map pprPred theta)))
  80
  81 instance Outputable Type where
  82     ppr ty = pprType ty
  83
  84 instance Outputable SourceType where
  85     ppr = pprPred
  86
  87 instance Outputable name => Outputable (IPName name) where
  88     ppr (Dupable n) = char '?' <> ppr n -- Ordinary implicit parameters
  89     ppr (Linear  n) = char '%' <> ppr n -- Splittable implicit parameters
  90 \end{code}
  91
  92
  93 %************************************************************************
  94 %*                                                                      *
  95 \subsection{Pretty printing}
  96 %*                                                                      *
  97 %************************************************************************
  98
  99 Precedence
 100 ~~~~~~~~~~
 101 @ppr_ty@ takes an @Int@ that is the precedence of the context.
 102 The precedence levels are:
 103 \begin{description}
 104 \item[tOP_PREC]   No parens required.
 105 \item[fUN_PREC]   Left hand argument of a function arrow.
 106 \item[tYCON_PREC] Argument of a type constructor.
 107 \end{description}
 108
 109
 110 \begin{code}
 111 tOP_PREC    = (0 :: Int)  -- type   in ParseIface.y
 112 fUN_PREC    = (1 :: Int)  -- btype  in ParseIface.y
 113 tYCON_PREC  = (2 :: Int)  -- atype  in ParseIface.y
 114
 115 maybeParen ctxt_prec inner_prec pretty
 116   | ctxt_prec < inner_prec = pretty
 117   | otherwise              = parens pretty
 118 \end{code}
 119
 120 \begin{code}
 121 ppr_ty :: Int -> Type -> SDoc
 122 ppr_ty ctxt_prec (TyVarTy tyvar)
 123   = ppr tyvar
 124
 125 ppr_ty ctxt_prec ty@(TyConApp tycon tys)
 126         -- KIND CASE; it's of the form (Type x)
 127   | tycon `hasKey` typeConKey,
 128     [ty] <- tys
 129   =     -- For kinds, print (Type x) as just x if x is a
 130         --      type constructor (must be Boxed, Unboxed, AnyBox)
 131         -- Otherwise print as (Type x)
 132     case ty of
 133         TyConApp bx [] -> ppr (getOccName bx)   -- Always unqualified
 134         other          -> maybeParen ctxt_prec tYCON_PREC
 135                                      (ppr tycon <+> ppr_ty tYCON_PREC ty)
 136
 137         -- USAGE CASE
 138   | (tycon `hasKey` usOnceTyConKey || tycon `hasKey` usManyTyConKey),
 139     null tys
 140   =     -- For usages (! and .), always print bare OccName, without pkg/mod/uniq
 141     ppr (getOccName (tyConName tycon))
 142
 143         -- TUPLE CASE (boxed and unboxed)
 144   |  isTupleTyCon tycon,
 145       tys `lengthIs` tyConArity tycon   -- No magic if partially applied
 146   = tupleParens (tupleTyConBoxity tycon)
 147                 (sep (punctuate comma (map (ppr_ty tOP_PREC) tys)))
 148
 149         -- LIST CASE
 150   | tycon `hasKey` listTyConKey,
 151     [ty] <- tys
 152   = brackets (ppr_ty tOP_PREC ty)
 153
 154         -- GENERAL CASE
 155   | otherwise
 156   = ppr_tc_app ctxt_prec tycon tys
 157
 158
 159 ppr_ty ctxt_prec ty@(ForAllTy _ _)
 160   = getPprStyle $ \ sty ->
 161     maybeParen ctxt_prec fUN_PREC $
 162     sep [ ptext SLIT("forall") <+> pp_tyvars sty <> ptext SLIT("."),
 163           ppr_theta theta,
 164           ppr_ty tOP_PREC tau
 165     ]
 166  where
 167     (tyvars, theta, tau) = tcSplitSigmaTy ty
 168
 169     pp_tyvars sty = sep (map pprTyVarBndr some_tyvars)
 170       where
 171         some_tyvars | userStyle sty && not opt_PprStyle_RawTypes
 172                     = filter (not . isUTyVar) tyvars  -- hide uvars from user
 173                     | otherwise
 174                     = tyvars
 175
 176     ppr_theta []     = empty
 177     ppr_theta theta  = pprTheta theta <+> ptext SLIT("=>")
 178
 179
 180 ppr_ty ctxt_prec (FunTy ty1 ty2)
 181   -- we don't want to lose usage annotations or synonyms,
 182   -- so we mustn't use splitFunTys here.
 183   = maybeParen ctxt_prec fUN_PREC $
 184     sep [ ppr_ty fUN_PREC ty1
 185         , ptext arrow <+> ppr_ty tOP_PREC ty2
 186         ]
 187   where arrow | isPredTy ty1 = SLIT("=>")
 188               | otherwise    = SLIT("->")
 189
 190 ppr_ty ctxt_prec (AppTy ty1 ty2)
 191   = maybeParen ctxt_prec tYCON_PREC $
 192     ppr_ty fUN_PREC ty1 <+> ppr_ty tYCON_PREC ty2
 193
 194 ppr_ty ctxt_prec (UsageTy u ty)
 195   = maybeParen ctxt_prec tYCON_PREC $
 196     ptext SLIT("__u") <+> ppr_ty tYCON_PREC u
 197                       <+> ppr_ty tYCON_PREC ty
 198     -- fUN_PREC would be logical for u, but it yields a reduce/reduce conflict with AppTy
 199
 200 ppr_ty ctxt_prec (NoteTy (SynNote ty) expansion)
 201   = ppr_ty ctxt_prec ty
 202 --  = ppr_ty ctxt_prec expansion -- if we don't want to see syntys
 203
 204 ppr_ty ctxt_prec (NoteTy (FTVNote _) ty) = ppr_ty ctxt_prec ty
 205
 206 ppr_ty ctxt_prec (SourceTy (NType tc tys)) = ppr_tc_app ctxt_prec tc tys
 207 ppr_ty ctxt_prec (SourceTy pred)           = braces (pprPred pred)
 208
 209 ppr_tc_app ctxt_prec tc []  = ppr tc
 210 ppr_tc_app ctxt_prec tc tys = maybeParen ctxt_prec tYCON_PREC
 211                                          (sep [ppr tc, nest 4 (sep (map (ppr_ty tYCON_PREC) tys))])
 212 \end{code}
 213
 214
 215 %************************************************************************
 216 %*                                                                      *
 217 \subsection[TyVar]{@TyVar@}
 218 %*                                                                      *
 219 %************************************************************************
 220
 221 We print type-variable binders with their kinds in interface files,
 222 and when in debug mode.
 223
 224 \begin{code}
 225 pprTyVarBndr :: TyVar -> SDoc
 226 pprTyVarBndr tyvar
 227   = getPprStyle $ \ sty ->
 228     if (ifaceStyle sty  && not (kind `eqKind` liftedTypeKind)) || debugStyle sty then
 229         hsep [ppr tyvar, dcolon, pprParendKind kind]
 230                 -- See comments with ppDcolon in PprCore.lhs
 231     else
 232         ppr tyvar
 233   where
 234     kind = tyVarKind tyvar
 235
 236 pprTyVarBndrs tyvars = hsep (map pprTyVarBndr tyvars)
 237 \end{code}
 238
 239
 240 %************************************************************************
 241 %*                                                                      *
 242 \subsection{Mumbo jumbo}
 243 %*                                                                      *
 244 %************************************************************************
 245
 246 Grab a name for the type. This is used to determine the type
 247 description for profiling.
 248
 249 \begin{code}
 250 getTyDescription :: Type -> String
 251
 252 getTyDescription ty
 253   = case (tcSplitSigmaTy ty) of { (_, _, tau_ty) ->
 254     case tau_ty of
 255       TyVarTy _              -> "*"
 256       AppTy fun _            -> getTyDescription fun
 257       FunTy _ res            -> '-' : '>' : fun_result res
 258       TyConApp tycon _       -> occNameUserString (getOccName tycon)
 259       NoteTy (FTVNote _) ty  -> getTyDescription ty
 260       NoteTy (SynNote ty1) _ -> getTyDescription ty1
 261       SourceTy sty           -> getSourceTyDescription sty
 262       ForAllTy _ ty          -> getTyDescription ty
 263     }
 264   where
 265     fun_result (FunTy _ res) = '>' : fun_result res
 266     fun_result other         = getTyDescription other
 267
 268 getSourceTyDescription (ClassP cl tys) = getOccString cl
 269 getSourceTyDescription (NType  tc tys) = getOccString tc
 270 getSourceTyDescription (IParam ip ty)  = getOccString (ipNameName ip)
 271 \end{code}
 272
 273
 274 \begin{code}
 275 showTypeCategory :: Type -> Char
 276   {-
 277         {C,I,F,D}   char, int, float, double
 278         T           tuple
 279         S           other single-constructor type
 280         {c,i,f,d}   unboxed ditto
 281         t           *unpacked* tuple
 282         s           *unpacked" single-cons...
 283
 284         v           void#
 285         a           primitive array
 286
 287         E           enumeration type
 288         +           dictionary, unless it's a ...
 289         L           List
 290         >           function
 291         M           other (multi-constructor) data-con type
 292         .           other type
 293         -           reserved for others to mark as "uninteresting"
 294     -}
 295 showTypeCategory ty
 296   = if isDictTy ty
 297     then '+'
 298     else
 299       case tcSplitTyConApp_maybe ty of
 300         Nothing -> if maybeToBool (tcSplitFunTy_maybe ty)
 301                    then '>'
 302                    else '.'
 303
 304         Just (tycon, _) ->
 305           let utc = getUnique tycon in
 306           if      utc == charDataConKey    then 'C'
 307           else if utc == intDataConKey     then 'I'
 308           else if utc == floatDataConKey   then 'F'
 309           else if utc == doubleDataConKey  then 'D'
 310           else if utc == smallIntegerDataConKey ||
 311                   utc == largeIntegerDataConKey   then 'J'
 312           else if utc == charPrimTyConKey  then 'c'
 313           else if (utc == intPrimTyConKey || utc == wordPrimTyConKey
 314                 || utc == addrPrimTyConKey)                then 'i'
 315           else if utc  == floatPrimTyConKey                then 'f'
 316           else if utc  == doublePrimTyConKey               then 'd'
 317           else if isPrimTyCon tycon {- array, we hope -}   then 'A'     -- Bogus
 318           else if isEnumerationTyCon tycon                 then 'E'
 319           else if isTupleTyCon tycon                       then 'T'
 320           else if maybeToBool (maybeTyConSingleCon tycon)  then 'S'
 321           else if utc == listTyConKey                      then 'L'
 322           else 'M' -- oh, well...
 323 \end{code}