ghc/compiler/types/PprType.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[PprType]{Printing Types, TyVars, Classes, TyCons}
   5
   6 \begin{code}
   7 module PprType(
   8         pprKind, pprParendKind,
   9         pprType, pprParendType,
  10         pprConstraint, pprTheta,
  11         pprTyVarBndr, pprTyVarBndrs,
  12
  13         -- Junk
  14         getTyDescription, showTypeCategory
  15  ) where
  16
  17 #include "HsVersions.h"
  18
  19 -- friends:
  20 -- (PprType can see all the representations it's trying to print)
  21 import Type             ( Type(..), TyNote(..), Kind, ThetaType, UsageAnn(..),
  22                           splitDictTy_maybe,
  23                           splitForAllTys, splitSigmaTy, splitRhoTy,
  24                           isDictTy, splitTyConApp_maybe, splitFunTy_maybe,
  25                           boxedTypeKind
  26                         )
  27 import Var              ( TyVar, tyVarKind,
  28                           tyVarName, setTyVarName
  29                         )
  30 import VarEnv
  31 import TyCon            ( TyCon, isPrimTyCon, isTupleTyCon, isUnboxedTupleTyCon,
  32                           maybeTyConSingleCon, isEnumerationTyCon,
  33                           tyConArity, tyConUnique
  34                         )
  35 import Class            ( Class )
  36
  37 -- others:
  38 import Maybes           ( maybeToBool )
  39 import Name             ( getOccString, NamedThing(..) )
  40 import Outputable
  41 import PprEnv
  42 import Unique           ( Uniquable(..) )
  43 import Unique           -- quite a few *Keys
  44 import Util
  45 \end{code}
  46
  47 %************************************************************************
  48 %*                                                                      *
  49 \subsection{The external interface}
  50 %*                                                                      *
  51 %************************************************************************
  52
  53 @pprType@ is the standard @Type@ printer; the overloaded @ppr@ function is
  54 defined to use this.  @pprParendType@ is the same, except it puts
  55 parens around the type, except for the atomic cases.  @pprParendType@
  56 works just by setting the initial context precedence very high.
  57
  58 \begin{code}
  59 pprType, pprParendType :: Type -> SDoc
  60 pprType       ty = ppr_ty pprTyEnv tOP_PREC   ty
  61 pprParendType ty = ppr_ty pprTyEnv tYCON_PREC ty
  62
  63 pprKind, pprParendKind :: Kind -> SDoc
  64 pprKind       = pprType
  65 pprParendKind = pprParendType
  66
  67 pprConstraint :: Class -> [Type] -> SDoc
  68 pprConstraint clas tys = ppr clas <+> hsep (map (pprParendType) tys)
  69
  70 pprTheta :: ThetaType -> SDoc
  71 pprTheta theta = parens (hsep (punctuate comma (map ppr_dict theta)))
  72                where
  73                  ppr_dict (c,tys) = pprConstraint c tys
  74
  75 instance Outputable Type where
  76     ppr ty = pprType ty
  77 \end{code}
  78
  79
  80 %************************************************************************
  81 %*                                                                      *
  82 \subsection{Pretty printing}
  83 %*                                                                      *
  84 %************************************************************************
  85
  86 Precedence
  87 ~~~~~~~~~~
  88 @ppr_ty@ takes an @Int@ that is the precedence of the context.
  89 The precedence levels are:
  90 \begin{description}
  91 \item[tOP_PREC]   No parens required.
  92 \item[fUN_PREC]   Left hand argument of a function arrow.
  93 \item[tYCON_PREC] Argument of a type constructor.
  94 \end{description}
  95
  96
  97 \begin{code}
  98 tOP_PREC    = (0 :: Int)
  99 fUN_PREC    = (1 :: Int)
 100 tYCON_PREC  = (2 :: Int)
 101
 102 maybeParen ctxt_prec inner_prec pretty
 103   | ctxt_prec < inner_prec = pretty
 104   | otherwise              = parens pretty
 105 \end{code}
 106
 107 \begin{code}
 108 ppr_ty :: PprEnv TyVar -> Int -> Type -> SDoc
 109 ppr_ty env ctxt_prec (TyVarTy tyvar)
 110   = pTyVarO env tyvar
 111
 112 ppr_ty env ctxt_prec ty@(TyConApp tycon tys)
 113         -- KIND CASE; it's of the form (Type x)
 114   | tycon_uniq == typeConKey && n_tys == 1
 115   =     -- For kinds, print (Type x) as just x if x is a
 116         --      type constructor (must be Boxed, Unboxed, AnyBox)
 117         -- Otherwise print as (Type x)
 118     case ty1 of
 119         TyConApp bx [] -> ppr bx
 120         other          -> maybeParen ctxt_prec tYCON_PREC
 121                                      (sep [ppr tycon, nest 4 tys_w_spaces])
 122
 123
 124         -- TUPLE CASE (boxed and unboxed)
 125   |  isTupleTyCon tycon
 126   && length tys == tyConArity tycon     -- no magic if partially applied
 127   = parens tys_w_commas
 128
 129   |  isUnboxedTupleTyCon tycon
 130   && length tys == tyConArity tycon     -- no magic if partially applied
 131   = parens (char '#' <+> tys_w_commas <+> char '#')
 132
 133         -- LIST CASE
 134   | tycon_uniq == listTyConKey && n_tys == 1
 135   = brackets (ppr_ty env tOP_PREC ty1)
 136
 137         -- DICTIONARY CASE, prints {C a}
 138         -- This means that instance decls come out looking right in interfaces
 139         -- and that in turn means they get "gated" correctly when being slurped in
 140   | maybeToBool maybe_dict
 141   = braces (ppr_dict env tYCON_PREC ctys)
 142
 143         -- NO-ARGUMENT CASE (=> no parens)
 144   | null tys
 145   = ppr tycon
 146
 147         -- GENERAL CASE
 148   | otherwise
 149   = maybeParen ctxt_prec tYCON_PREC (sep [ppr tycon, nest 4 tys_w_spaces])
 150
 151   where
 152     tycon_uniq = tyConUnique tycon
 153     n_tys      = length tys
 154     (ty1:_)    = tys
 155     Just ctys  = maybe_dict
 156     maybe_dict = splitDictTy_maybe ty   -- Checks class and arity
 157     tys_w_commas = sep (punctuate comma (map (ppr_ty env tOP_PREC) tys))
 158     tys_w_spaces = sep (map (ppr_ty env tYCON_PREC) tys)
 159
 160
 161
 162 ppr_ty env ctxt_prec ty@(ForAllTy _ _)
 163   = getPprStyle $ \ sty ->
 164     maybeParen ctxt_prec fUN_PREC $
 165     if ifaceStyle sty then
 166        sep [ ptext SLIT("__forall") <+> brackets pp_tyvars <+> ptext SLIT("=>"), pp_body ]
 167     else
 168        sep [ ptext SLIT("forall") <+> pp_tyvars <> ptext SLIT("."), pp_body ]
 169   where
 170     (tyvars, body_ty) = splitForAllTys ty  -- don't treat theta specially any more (KSW 1999-04)
 171
 172     pp_tyvars = hsep (map (pBndr env LambdaBind) tyvars)
 173     pp_body   = ppr_ty env tOP_PREC body_ty
 174
 175
 176 ppr_ty env ctxt_prec (FunTy ty1 ty2)
 177   = maybeParen ctxt_prec fUN_PREC (sep (ppr_ty env fUN_PREC ty1 : pp_rest ty2))
 178   -- we don't want to lose usage annotations or synonyms,
 179   -- so we mustn't use splitFunTys here.
 180   where
 181     pp_rest (FunTy ty1 ty2) = pp_codom ty1 : pp_rest ty2
 182     pp_rest ty              = [pp_codom ty]
 183     pp_codom ty             = ptext SLIT("->") <+> ppr_ty env fUN_PREC ty
 184
 185 ppr_ty env ctxt_prec (AppTy ty1 ty2)
 186   = maybeParen ctxt_prec tYCON_PREC $
 187     ppr_ty env tOP_PREC ty1 <+> ppr_ty env tYCON_PREC ty2
 188
 189 ppr_ty env ctxt_prec (NoteTy (SynNote ty) expansion)
 190   = ppr_ty env ctxt_prec ty
 191 --  = ppr_ty env ctxt_prec expansion -- if we don't want to see syntys
 192
 193 ppr_ty env ctxt_prec (NoteTy (FTVNote _) ty) = ppr_ty env ctxt_prec ty
 194
 195 ppr_ty env ctxt_prec (NoteTy (UsgNote u) ty)
 196   = maybeParen ctxt_prec tYCON_PREC $
 197     ppr u <+> ppr_ty env tYCON_PREC ty
 198
 199 ppr_theta env []    = empty
 200 ppr_theta env theta = braces (hsep (punctuate comma (map (ppr_dict env tOP_PREC) theta)))
 201
 202 ppr_dict env ctxt (clas, tys) = ppr clas <+>
 203                                 hsep (map (ppr_ty env tYCON_PREC) tys)
 204 \end{code}
 205
 206 \begin{code}
 207 pprTyEnv = initPprEnv b b (Just ppr) b (Just (\site -> pprTyVarBndr)) b
 208   where
 209     b = panic "PprType:init_ppr_env"
 210 \end{code}
 211
 212 \begin{code}
 213 instance Outputable UsageAnn where
 214   ppr UsOnce     = ptext SLIT("__o")
 215   ppr UsMany     = ptext SLIT("__m")
 216   ppr (UsVar uv) = ptext SLIT("__uv") <> ppr uv
 217 \end{code}
 218
 219 %************************************************************************
 220 %*                                                                      *
 221 \subsection[TyVar]{@TyVar@}
 222 %*                                                                      *
 223 %************************************************************************
 224
 225 We print type-variable binders with their kinds in interface files,
 226 and when in debug mode.
 227
 228 \begin{code}
 229 pprTyVarBndr tyvar
 230   = getPprStyle $ \ sty ->
 231     if (ifaceStyle sty || debugStyle sty) && kind /= boxedTypeKind then
 232         hsep [ppr tyvar, dcolon, pprParendKind kind]
 233                 -- See comments with ppDcolon in PprCore.lhs
 234     else
 235         ppr tyvar
 236   where
 237     kind = tyVarKind tyvar
 238
 239 pprTyVarBndrs tyvars = hsep (map pprTyVarBndr tyvars)
 240 \end{code}
 241
 242
 243 %************************************************************************
 244 %*                                                                      *
 245 \subsection{Mumbo jumbo}
 246 %*                                                                      *
 247 %************************************************************************
 248
 249 Grab a name for the type. This is used to determine the type
 250 description for profiling.
 251
 252 \begin{code}
 253 getTyDescription :: Type -> String
 254
 255 getTyDescription ty
 256   = case (splitSigmaTy ty) of { (_, _, tau_ty) ->
 257     case tau_ty of
 258       TyVarTy _        -> "*"
 259       AppTy fun _      -> getTyDescription fun
 260       FunTy _ res      -> '-' : '>' : fun_result res
 261       TyConApp tycon _ -> getOccString tycon
 262       NoteTy (FTVNote _) ty  -> getTyDescription ty
 263       NoteTy (SynNote ty1) _ -> getTyDescription ty1
 264       NoteTy (UsgNote _) ty  -> getTyDescription ty
 265       ForAllTy _ ty    -> getTyDescription ty
 266     }
 267   where
 268     fun_result (FunTy _ res) = '>' : fun_result res
 269     fun_result other         = getTyDescription other
 270 \end{code}
 271
 272
 273 \begin{code}
 274 showTypeCategory :: Type -> Char
 275   {-
 276         {C,I,F,D}   char, int, float, double
 277         T           tuple
 278         S           other single-constructor type
 279         {c,i,f,d}   unboxed ditto
 280         t           *unpacked* tuple
 281         s           *unpacked" single-cons...
 282
 283         v           void#
 284         a           primitive array
 285
 286         E           enumeration type
 287         +           dictionary, unless it's a ...
 288         L           List
 289         >           function
 290         M           other (multi-constructor) data-con type
 291         .           other type
 292         -           reserved for others to mark as "uninteresting"
 293     -}
 294 showTypeCategory ty
 295   = if isDictTy ty
 296     then '+'
 297     else
 298       case splitTyConApp_maybe ty of
 299         Nothing -> if maybeToBool (splitFunTy_maybe ty)
 300                    then '>'
 301                    else '.'
 302
 303         Just (tycon, _) ->
 304           let utc = getUnique tycon in
 305           if      utc == charDataConKey    then 'C'
 306           else if utc == intDataConKey     then 'I'
 307           else if utc == floatDataConKey   then 'F'
 308           else if utc == doubleDataConKey  then 'D'
 309           else if utc == smallIntegerDataConKey ||
 310                   utc == largeIntegerDataConKey   then 'J'
 311           else if utc == charPrimTyConKey  then 'c'
 312           else if (utc == intPrimTyConKey || utc == wordPrimTyConKey
 313                 || utc == addrPrimTyConKey)                then 'i'
 314           else if utc  == floatPrimTyConKey                then 'f'
 315           else if utc  == doublePrimTyConKey               then 'd'
 316           else if isPrimTyCon tycon {- array, we hope -}   then 'A'
 317           else if isEnumerationTyCon tycon                 then 'E'
 318           else if isTupleTyCon tycon                       then 'T'
 319           else if maybeToBool (maybeTyConSingleCon tycon)  then 'S'
 320           else if utc == listTyConKey                      then 'L'
 321           else 'M' -- oh, well...
 322 \end{code}