ghc/compiler/types/Unify.lhs

   1 \begin{code}
   2 module Unify (
   3         -- Matching and unification
   4         matchTys, matchTyX, tcMatchPreds, MatchEnv(..),
   5
   6         unifyTys, unifyTysX,
   7
   8         tcRefineTys, tcMatchTys, coreRefineTys,
   9
  10         -- Re-export
  11         MaybeErr(..)
  12    ) where
  13
  14 #include "HsVersions.h"
  15
  16 import Var              ( Var, TyVar, tyVarKind )
  17 import VarEnv
  18 import VarSet
  19 import Kind             ( isSubKind )
  20 import Type             ( typeKind, tyVarsOfType, tyVarsOfTypes, tyVarsOfTheta,
  21                           TvSubstEnv, TvSubst(..), substTy, tcEqTypeX )
  22 import TypeRep          ( Type(..), PredType(..), funTyCon )
  23 import Util             ( snocView )
  24 import ErrUtils         ( Message )
  25 import Outputable
  26 import Maybes
  27 \end{code}
  28
  29
  30 %************************************************************************
  31 %*                                                                      *
  32                 Matching
  33 %*                                                                      *
  34 %************************************************************************
  35
  36
  37 Matching is much tricker than you might think.
  38
  39 1. The substitution we generate binds the *template type variables*
  40    which are given to us explicitly.
  41
  42 2. We want to match in the presence of foralls;
  43         e.g     (forall a. t1) ~ (forall b. t2)
  44
  45    That is what the RnEnv2 is for; it does the alpha-renaming
  46    that makes it as if a and b were the same variable.
  47    Initialising the RnEnv2, so that it can generate a fresh
  48    binder when necessary, entails knowing the free variables of
  49    both types.
  50
  51 3. We must be careful not to bind a template type variable to a
  52    locally bound variable.  E.g.
  53         (forall a. x) ~ (forall b. b)
  54    where x is the template type variable.  Then we do not want to
  55    bind x to a/b!  This is a kind of occurs check.
  56    The necessary locals accumulate in the RnEnv2.
  57
  58
  59 \begin{code}
  60 data MatchEnv
  61   = ME  { me_tmpls :: VarSet    -- Template tyvars
  62         , me_env   :: RnEnv2    -- Renaming envt for nested foralls
  63         }                       --   In-scope set includes template tyvars
  64
  65 matchTys :: TyVarSet            -- Template tyvars
  66          -> [Type]              -- Template
  67          -> [Type]              -- Target
  68          -> Maybe TvSubstEnv    -- One-shot; in principle the template
  69                                 -- variables could be free in the target
  70
  71 matchTys tmpls tys1 tys2
  72   = match_tys (ME { me_tmpls = tmpls, me_env = mkRnEnv2 in_scope_tyvars})
  73               emptyTvSubstEnv
  74               tys1 tys2
  75   where
  76     in_scope_tyvars = mkInScopeSet (tmpls `unionVarSet` tyVarsOfTypes tys2)
  77         -- We're assuming that all the interesting
  78         -- tyvars in tys1 are in tmpls
  79
  80 tcMatchPreds
  81         :: [TyVar]                      -- Bind these
  82         -> [PredType] -> [PredType]
  83         -> Maybe TvSubstEnv
  84 tcMatchPreds tmpls ps1 ps2
  85   = match_list (match_pred menv) emptyTvSubstEnv ps1 ps2
  86   where
  87     menv = ME { me_tmpls = mkVarSet tmpls, me_env = mkRnEnv2 in_scope_tyvars }
  88     in_scope_tyvars = mkInScopeSet (tyVarsOfTheta ps1 `unionVarSet` tyVarsOfTheta ps2)
  89
  90 matchTyX :: MatchEnv
  91          -> TvSubstEnv          -- Substitution to extend
  92          -> Type                -- Template
  93          -> Type                -- Target
  94          -> Maybe TvSubstEnv
  95
  96 matchTyX menv subst ty1 ty2 = match menv subst ty1 ty2  -- Rename for export
  97 \end{code}
  98
  99 Now the internals of matching
 100
 101 \begin{code}
 102 match :: MatchEnv       -- For the ost part this is pushed downwards
 103       -> TvSubstEnv     -- Substitution so far:
 104                         --   Domain is subset of template tyvars
 105                         --   Free vars of range is subset of
 106                         --      in-scope set of the RnEnv2
 107       -> Type -> Type   -- Template and target respectively
 108       -> Maybe TvSubstEnv
 109 -- This matcher works on source types; that is,
 110 -- it respects NewTypes and PredType
 111
 112 match menv subst (NoteTy _ ty1) ty2 = match menv subst ty1 ty2
 113 match menv subst ty1 (NoteTy _ ty2) = match menv subst ty1 ty2
 114
 115 match menv subst (TyVarTy tv1) ty2
 116   | tv1 `elemVarSet` me_tmpls menv
 117   = case lookupVarEnv subst tv1' of
 118         Nothing | any (inRnEnvR rn_env) (varSetElems (tyVarsOfType ty2))
 119                 -> Nothing      -- Occurs check
 120                 | otherwise
 121                 -> Just (extendVarEnv subst tv1 ty2)
 122
 123         Just ty1' | tcEqTypeX (nukeRnEnvL rn_env) ty1' ty2
 124                 -- ty1 has no locally-bound variables, hence nukeRnEnvL
 125                 -- Note tcEqType...we are doing source-type matching here
 126                   -> Just subst
 127
 128         other -> Nothing
 129
 130    | otherwise  -- tv1 is not a template tyvar
 131    = case ty2 of
 132         TyVarTy tv2 | tv1' == rnOccR rn_env tv2 -> Just subst
 133         other                                   -> Nothing
 134   where
 135     rn_env = me_env menv
 136     tv1' = rnOccL rn_env tv1
 137
 138 match menv subst (ForAllTy tv1 ty1) (ForAllTy tv2 ty2)
 139   = match menv' subst ty1 ty2
 140   where         -- Use the magic of rnBndr2 to go under the binders
 141     menv' = menv { me_env = rnBndr2 (me_env menv) tv1 tv2 }
 142
 143 match menv subst (PredTy p1) (PredTy p2)
 144   = match_pred menv subst p1 p2
 145 match menv subst (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 146   | tc1 == tc2 = match_tys menv subst tys1 tys2
 147 match menv subst (FunTy ty1a ty1b) (FunTy ty2a ty2b)
 148   = do { subst' <- match menv subst ty1a ty2a
 149        ; match menv subst' ty1b ty2b }
 150 match menv subst (AppTy ty1a ty1b) ty2
 151   | Just (ty2a, ty2b) <- repSplitAppTy_maybe ty2
 152   = do { subst' <- match menv subst ty1a ty2a
 153        ; match menv subst' ty1b ty2b }
 154
 155 match menv subst ty1 ty2
 156   = Nothing
 157
 158 --------------
 159 match_tys menv subst tys1 tys2 = match_list (match menv) subst tys1 tys2
 160
 161 --------------
 162 match_list :: (TvSubstEnv -> a -> a -> Maybe TvSubstEnv)
 163            -> TvSubstEnv -> [a] -> [a] -> Maybe TvSubstEnv
 164 match_list fn subst []         []         = Just subst
 165 match_list fn subst (ty1:tys1) (ty2:tys2) = do  { subst' <- fn subst ty1 ty2
 166                                                 ; match_list fn subst' tys1 tys2 }
 167 match_list fn subst tys1       tys2       = Nothing
 168
 169 --------------
 170 match_pred menv subst (ClassP c1 tys1) (ClassP c2 tys2)
 171   | c1 == c2 = match_tys menv subst tys1 tys2
 172 match_pred menv subst (IParam n1 t1) (IParam n2 t2)
 173   | n1 == n2 = match menv subst t1 t2
 174 match_pred menv subst p1 p2 = Nothing
 175 \end{code}
 176
 177
 178 %************************************************************************
 179 %*                                                                      *
 180                 The workhorse
 181 %*                                                                      *
 182 %************************************************************************
 183
 184 \begin{code}
 185 tcRefineTys, tcMatchTys
 186         :: [TyVar]                      -- Try to unify these
 187         -> TvSubstEnv                   -- Not idempotent
 188         -> [Type] -> [Type]
 189         -> MaybeErr Message TvSubstEnv  -- Not idempotent
 190 -- This one is used by the type checker.  Neither the input nor result
 191 -- substitition is idempotent
 192 tcRefineTys ex_tvs subst tys1 tys2
 193   = initUM (tryToBind (mkVarSet ex_tvs)) (unify_tys subst tys1 tys2)
 194
 195 tcMatchTys ex_tvs subst tys1 tys2
 196   = initUM (bindOnly (mkVarSet ex_tvs)) (unify_tys subst tys1 tys2)
 197
 198 ----------------------------
 199 coreRefineTys :: [TyVar]        -- Try to unify these
 200               -> TvSubst        -- A full-blown apply-once substitition
 201               -> Type           -- A fixed point of the incoming substitution
 202               -> Type
 203               -> Maybe TvSubstEnv       -- In-scope set is unaffected
 204 -- Used by Core Lint and the simplifier.  Takes a full apply-once substitution.
 205 -- The incoming substitution's in-scope set should mention all the variables free
 206 -- in the incoming types
 207 coreRefineTys ex_tvs subst@(TvSubst in_scope orig_env) ty1 ty2
 208   = maybeErrToMaybe $ initUM (tryToBind (mkVarSet ex_tvs)) $
 209     do  {       -- Apply the input substitution; nothing int ty2
 210           let ty1' = substTy subst ty1
 211                 -- Run the unifier, starting with an empty env
 212         ; extra_env <- unify emptyTvSubstEnv ty1' ty2
 213
 214                 -- Find the fixed point of the resulting non-idempotent
 215                 -- substitution, and apply it to the
 216         ; let extra_subst     = TvSubst in_scope extra_env_fixpt
 217               extra_env_fixpt = mapVarEnv (substTy extra_subst) extra_env
 218               orig_env'       = mapVarEnv (substTy extra_subst) orig_env
 219         ; return (orig_env' `plusVarEnv` extra_env_fixpt) }
 220
 221
 222 ----------------------------
 223 unifyTys :: TyVarSet -> [Type] -> [Type] -> Maybe TvSubstEnv
 224 unifyTys bind_these tys1 tys2
 225   = maybeErrToMaybe $ initUM (bindOnly bind_these) $
 226     unify_tys emptyTvSubstEnv tys1 tys2
 227
 228 unifyTysX :: TyVarSet -> TvSubstEnv -> [Type] -> [Type] -> Maybe TvSubstEnv
 229 unifyTysX bind_these subst tys1 tys2
 230   = maybeErrToMaybe $ initUM (bindOnly bind_these) $
 231     unify_tys subst tys1 tys2
 232
 233 ----------------------------
 234 tryToBind, bindOnly :: TyVarSet -> TyVar -> BindFlag
 235 tryToBind tv_set tv | tv `elemVarSet` tv_set = BindMe
 236                     | otherwise              = AvoidMe
 237
 238 bindOnly tv_set tv | tv `elemVarSet` tv_set = BindMe
 239                    | otherwise              = DontBindMe
 240
 241 emptyTvSubstEnv :: TvSubstEnv
 242 emptyTvSubstEnv = emptyVarEnv
 243 \end{code}
 244
 245
 246 %************************************************************************
 247 %*                                                                      *
 248                 The workhorse
 249 %*                                                                      *
 250 %************************************************************************
 251
 252 \begin{code}
 253 unify :: TvSubstEnv             -- An existing substitution to extend
 254       -> Type -> Type           -- Types to be unified
 255       -> UM TvSubstEnv          -- Just the extended substitution,
 256                                 -- Nothing if unification failed
 257 -- We do not require the incoming substitution to be idempotent,
 258 -- nor guarantee that the outgoing one is.  That's fixed up by
 259 -- the wrappers.
 260
 261 unify subst ty1 ty2 = -- pprTrace "unify" (ppr subst <+> pprParendType ty1 <+> pprParendType ty2) $
 262                         unify_ subst ty1 ty2
 263
 264 -- in unify_, any NewTcApps/Preds should be taken at face value
 265 unify_ subst (TyVarTy tv1) ty2  = uVar False subst tv1 ty2
 266 unify_ subst ty1 (TyVarTy tv2)  = uVar True  subst tv2 ty1
 267
 268 unify_ subst (NoteTy _ ty1) ty2  = unify subst ty1 ty2
 269 unify_ subst ty1 (NoteTy _ ty2)  = unify subst ty1 ty2
 270
 271 unify_ subst (PredTy p1) (PredTy p2) = unify_pred subst p1 p2
 272
 273 unify_ subst t1@(TyConApp tyc1 tys1) t2@(TyConApp tyc2 tys2)
 274   | tyc1 == tyc2 = unify_tys subst tys1 tys2
 275
 276 unify_ subst (FunTy ty1a ty1b) (FunTy ty2a ty2b)
 277   = do { subst' <- unify subst ty1a ty2a
 278        ; unify subst' ty1b ty2b }
 279
 280         -- Applications need a bit of care!
 281         -- They can match FunTy and TyConApp, so use splitAppTy_maybe
 282         -- NB: we've already dealt with type variables and Notes,
 283         -- so if one type is an App the other one jolly well better be too
 284 unify_ subst (AppTy ty1a ty1b) ty2
 285   | Just (ty2a, ty2b) <- repSplitAppTy_maybe ty2
 286   = do  { subst' <- unify subst ty1a ty2a
 287         ; unify subst' ty1b ty2b }
 288
 289 unify_ subst ty1 (AppTy ty2a ty2b)
 290   | Just (ty1a, ty1b) <- repSplitAppTy_maybe ty1
 291   = do  { subst' <- unify subst ty1a ty2a
 292         ; unify subst' ty1b ty2b }
 293
 294 unify_ subst ty1 ty2 = failWith (misMatch ty1 ty2)
 295
 296 ------------------------------
 297 unify_pred subst (ClassP c1 tys1) (ClassP c2 tys2)
 298   | c1 == c2 = unify_tys subst tys1 tys2
 299 unify_pred subst (IParam n1 t1) (IParam n2 t2)
 300   | n1 == n2 = unify subst t1 t2
 301 unify_pred subst p1 p2 = failWith (misMatch (PredTy p1) (PredTy p2))
 302
 303 ------------------------------
 304 unify_tys = unifyList unify
 305
 306 unifyList :: Outputable a
 307           => (TvSubstEnv -> a -> a -> UM TvSubstEnv)
 308           -> TvSubstEnv -> [a] -> [a] -> UM TvSubstEnv
 309 unifyList unifier subst orig_xs orig_ys
 310   = go subst orig_xs orig_ys
 311   where
 312     go subst []     []     = return subst
 313     go subst (x:xs) (y:ys) = do { subst' <- unifier subst x y
 314                                 ; go subst' xs ys }
 315     go subst _      _      = failWith (lengthMisMatch orig_xs orig_ys)
 316
 317 ------------------------------
 318 uVar :: Bool            -- Swapped
 319      -> TvSubstEnv      -- An existing substitution to extend
 320      -> TyVar           -- Type variable to be unified
 321      -> Type            -- with this type
 322      -> UM TvSubstEnv
 323
 324 uVar swap subst tv1 ty
 325  = -- check to see whether tv1 is refined
 326    case (lookupVarEnv subst tv1) of
 327      -- yes, call back into unify'
 328      Just ty' | swap      -> unify subst ty ty'
 329               | otherwise -> unify subst ty' ty
 330      -- No, continue
 331      Nothing          -> uUnrefined subst tv1 ty
 332
 333
 334 uUnrefined :: TvSubstEnv          -- An existing substitution to extend
 335            -> TyVar               -- Type variable to be unified
 336            -> Type                -- with this type
 337            -> UM TvSubstEnv
 338
 339 -- We know that tv1 isn't refined
 340 uUnrefined subst tv1 ty2@(TyVarTy tv2)
 341   | tv1 == tv2    -- Same, do nothing
 342   = return subst
 343
 344     -- Check to see whether tv2 is refined
 345   | Just ty' <- lookupVarEnv subst tv2
 346   = uUnrefined subst tv1 ty'
 347
 348   -- So both are unrefined; next, see if the kinds force the direction
 349   | k1 == k2    -- Can update either; so check the bind-flags
 350   = do  { b1 <- tvBindFlag tv1
 351         ; b2 <- tvBindFlag tv2
 352         ; case (b1,b2) of
 353             (DontBindMe, DontBindMe) -> failWith (misMatch ty1 ty2)
 354             (DontBindMe, _)          -> bindTv subst tv2 ty1
 355             (BindMe, _)              -> bindTv subst tv1 ty2
 356             (AvoidMe, BindMe)        -> bindTv subst tv2 ty1
 357             (AvoidMe, _)             -> bindTv subst tv1 ty2
 358         }
 359
 360   | k1 `isSubKind` k2   -- Must update tv2
 361   = do  { b2 <- tvBindFlag tv2
 362         ; case b2 of
 363             DontBindMe -> failWith (misMatch ty1 ty2)
 364             other      -> bindTv subst tv2 ty1
 365         }
 366
 367   | k2 `isSubKind` k1   -- Must update tv1
 368   = do  { b1 <- tvBindFlag tv1
 369         ; case b1 of
 370             DontBindMe -> failWith (misMatch ty1 ty2)
 371             other      -> bindTv subst tv1 ty2
 372         }
 373
 374   | otherwise = failWith (kindMisMatch tv1 ty2)
 375   where
 376     ty1 = TyVarTy tv1
 377     k1 = tyVarKind tv1
 378     k2 = tyVarKind tv2
 379
 380 uUnrefined subst tv1 ty2        -- ty2 is not a type variable
 381         -- Do occurs check...
 382   | tv1 `elemVarSet` substTvSet subst (tyVarsOfType ty2)
 383   = failWith (occursCheck tv1 ty2)
 384         -- And a kind check...
 385   | k2 `isSubKind` k1
 386   = do  { b1 <- tvBindFlag tv1
 387         ; case b1 of            -- And  check that tv1 is bindable
 388             DontBindMe -> failWith (misMatch ty1 ty2)
 389             other      -> bindTv subst tv1 ty2
 390         }
 391   | otherwise
 392   = pprTrace "kind" (ppr tv1 <+> ppr k1 $$ ppr ty2 <+> ppr k2) $
 393     failWith (kindMisMatch tv1 ty2)
 394   where
 395     ty1 = TyVarTy tv1
 396     k1 = tyVarKind tv1
 397     k2 = typeKind ty2
 398
 399 substTvSet :: TvSubstEnv -> TyVarSet -> TyVarSet
 400 -- Apply the non-idempotent substitution to a set of type variables,
 401 -- remembering that the substitution isn't necessarily idempotent
 402 substTvSet subst tvs
 403   = foldVarSet (unionVarSet . get) emptyVarSet tvs
 404   where
 405     get tv = case lookupVarEnv subst tv of
 406                 Nothing -> unitVarSet tv
 407                 Just ty -> substTvSet subst (tyVarsOfType ty)
 408
 409 bindTv subst tv ty = return (extendVarEnv subst tv ty)
 410 \end{code}
 411
 412 %************************************************************************
 413 %*                                                                      *
 414                 Unification monad
 415 %*                                                                      *
 416 %************************************************************************
 417
 418 \begin{code}
 419 data BindFlag = BindMe | AvoidMe | DontBindMe
 420
 421 newtype UM a = UM { unUM :: (TyVar -> BindFlag)
 422                          -> MaybeErr Message a }
 423
 424 instance Monad UM where
 425   return a = UM (\tvs -> Succeeded a)
 426   fail s   = UM (\tvs -> Failed (text s))
 427   m >>= k  = UM (\tvs -> case unUM m tvs of
 428                            Failed err -> Failed err
 429                            Succeeded v  -> unUM (k v) tvs)
 430
 431 initUM :: (TyVar -> BindFlag) -> UM a -> MaybeErr Message a
 432 initUM badtvs um = unUM um badtvs
 433
 434 tvBindFlag :: TyVar -> UM BindFlag
 435 tvBindFlag tv = UM (\tv_fn -> Succeeded (tv_fn tv))
 436
 437 failWith :: Message -> UM a
 438 failWith msg = UM (\tv_fn -> Failed msg)
 439
 440 maybeErrToMaybe :: MaybeErr fail succ -> Maybe succ
 441 maybeErrToMaybe (Succeeded a) = Just a
 442 maybeErrToMaybe (Failed m)    = Nothing
 443
 444 ------------------------------
 445 repSplitAppTy_maybe :: Type -> Maybe (Type,Type)
 446 -- Like Type.splitAppTy_maybe, but any coreView stuff is already done
 447 repSplitAppTy_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
 448 repSplitAppTy_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
 449 repSplitAppTy_maybe (TyConApp tc tys) = case snocView tys of
 450                                                 Just (tys', ty') -> Just (TyConApp tc tys', ty')
 451                                                 Nothing          -> Nothing
 452 repSplitAppTy_maybe other = Nothing
 453 \end{code}
 454
 455
 456 %************************************************************************
 457 %*                                                                      *
 458                 Error reporting
 459         We go to a lot more trouble to tidy the types
 460         in TcUnify.  Maybe we'll end up having to do that
 461         here too, but I'll leave it for now.
 462 %*                                                                      *
 463 %************************************************************************
 464
 465 \begin{code}
 466 misMatch t1 t2
 467   = ptext SLIT("Can't match types") <+> quotes (ppr t1) <+>
 468     ptext SLIT("and") <+> quotes (ppr t2)
 469
 470 lengthMisMatch tys1 tys2
 471   = sep [ptext SLIT("Can't match unequal length lists"),
 472          nest 2 (ppr tys1), nest 2 (ppr tys2) ]
 473
 474 kindMisMatch tv1 t2
 475   = vcat [ptext SLIT("Can't match kinds") <+> quotes (ppr (tyVarKind tv1)) <+>
 476             ptext SLIT("and") <+> quotes (ppr (typeKind t2)),
 477           ptext SLIT("when matching") <+> quotes (ppr tv1) <+>
 478                 ptext SLIT("with") <+> quotes (ppr t2)]
 479
 480 occursCheck tv ty
 481   = hang (ptext SLIT("Can't construct the infinite type"))
 482        2 (ppr tv <+> equals <+> ppr ty)
 483 \end{code}