ghc/compiler/utils/IOEnv.hs

   1 -- (c) The University of Glasgow 2002
   2 --
   3 -- The IO Monad with an environment
   4 --
   5
   6 module IOEnv (
   7         IOEnv,  -- Instance of Monad
   8
   9         -- Standard combinators, specialised
  10         returnM, thenM, thenM_, failM,
  11         mappM, mappM_, mapSndM, sequenceM, sequenceM_,
  12         foldlM,
  13         mapAndUnzipM, mapAndUnzip3M,
  14         checkM, ifM, zipWithM, zipWithM_,
  15
  16         -- Getting at the environment
  17         getEnv, setEnv, updEnv,
  18
  19         runIOEnv, unsafeInterleaveM,
  20         tryM, fixM,
  21
  22         -- I/O operations
  23         ioToIOEnv,
  24         IORef, newMutVar, readMutVar, writeMutVar, updMutVar
  25   ) where
  26 #include "HsVersions.h"
  27
  28 import Panic            ( tryJust )
  29 import DATA_IOREF       ( IORef, newIORef, readIORef, writeIORef )
  30 import UNSAFE_IO        ( unsafeInterleaveIO )
  31 import FIX_IO           ( fixIO )
  32 import EXCEPTION        ( Exception(..) )
  33 import IO               ( isUserError )
  34
  35
  36 ----------------------------------------------------------------------
  37 --              Defining the monad type
  38 ----------------------------------------------------------------------
  39
  40
  41 newtype IOEnv env a = IOEnv (env -> IO a)
  42 unIOEnv (IOEnv m) = m
  43
  44 instance Monad (IOEnv m) where
  45   (>>=)  = thenM
  46   (>>)   = thenM_
  47   return = returnM
  48   fail s = failM        -- Ignore the string
  49
  50 returnM :: a -> IOEnv env a
  51 returnM a = IOEnv (\ env -> return a)
  52
  53 thenM :: IOEnv env a -> (a -> IOEnv env b) -> IOEnv env b
  54 thenM (IOEnv m) f = IOEnv (\ env -> do { r <- m env ;
  55                                        unIOEnv (f r) env })
  56
  57 thenM_ :: IOEnv env a -> IOEnv env b -> IOEnv env b
  58 thenM_ (IOEnv m) f = IOEnv (\ env -> do { m env ; unIOEnv f env })
  59
  60 failM :: IOEnv env a
  61 failM = IOEnv (\ env -> ioError (userError "IOEnv failure"))
  62
  63
  64
  65 ----------------------------------------------------------------------
  66 --      Fundmantal combinators specific to the monad
  67 ----------------------------------------------------------------------
  68
  69
  70 ---------------------------
  71 runIOEnv :: env -> IOEnv env a -> IO a
  72 runIOEnv env (IOEnv m) = m env
  73
  74
  75 ---------------------------
  76 {-# NOINLINE fixM #-}
  77   -- Aargh!  Not inlining fixTc alleviates a space leak problem.
  78   -- Normally fixTc is used with a lazy tuple match: if the optimiser is
  79   -- shown the definition of fixTc, it occasionally transforms the code
  80   -- in such a way that the code generator doesn't spot the selector
  81   -- thunks.  Sigh.
  82
  83 fixM :: (a -> IOEnv env a) -> IOEnv env a
  84 fixM f = IOEnv (\ env -> fixIO (\ r -> unIOEnv (f r) env))
  85
  86
  87 ---------------------------
  88 tryM :: IOEnv env r -> IOEnv env (Either Exception r)
  89 -- Reflect exception into IOEnv envonad
  90 tryM (IOEnv thing) = IOEnv (\ env -> tryJust tc_errors (thing env))
  91   where
  92 #if __GLASGOW_HASKELL__ > 504 || __GLASGOW_HASKELL__ < 500
  93         tc_errors e@(IOException ioe) | isUserError ioe = Just e
  94 #elif __GLASGOW_HASKELL__ == 502
  95         tc_errors e@(UserError _) = Just e
  96 #else
  97         tc_errors e@(IOException ioe) | isUserError e = Just e
  98 #endif
  99         tc_errors _other = Nothing
 100         -- type checker failures show up as UserErrors only
 101
 102
 103 ---------------------------
 104 unsafeInterleaveM :: IOEnv env a -> IOEnv env a
 105 unsafeInterleaveM (IOEnv m) = IOEnv (\ env -> unsafeInterleaveIO (m env))
 106
 107
 108 ----------------------------------------------------------------------
 109 --      Accessing input/output
 110 ----------------------------------------------------------------------
 111
 112 ioToIOEnv :: IO a -> IOEnv env a
 113 ioToIOEnv io = IOEnv (\ env -> io)
 114
 115 newMutVar :: a -> IOEnv env (IORef a)
 116 newMutVar val = IOEnv (\ env -> newIORef val)
 117
 118 writeMutVar :: IORef a -> a -> IOEnv env ()
 119 writeMutVar var val = IOEnv (\ env -> writeIORef var val)
 120
 121 readMutVar :: IORef a -> IOEnv env a
 122 readMutVar var = IOEnv (\ env -> readIORef var)
 123
 124 updMutVar :: IORef a -> (a->a) -> IOEnv env ()
 125 updMutVar var upd_fn = IOEnv (\ env -> do { v <- readIORef var; writeIORef var (upd_fn v) })
 126
 127
 128 ----------------------------------------------------------------------
 129 --      Accessing the environment
 130 ----------------------------------------------------------------------
 131
 132 getEnv :: IOEnv env env
 133 {-# INLINE getEnv #-}
 134 getEnv = IOEnv (\ env -> return env)
 135
 136 setEnv :: env' -> IOEnv env' a -> IOEnv env a
 137 {-# INLINE setEnv #-}
 138 setEnv new_env (IOEnv m) = IOEnv (\ env -> m new_env)
 139
 140 updEnv :: (env -> env') -> IOEnv env' a -> IOEnv env a
 141 {-# INLINE updEnv #-}
 142 updEnv upd (IOEnv m) = IOEnv (\ env -> m (upd env))
 143
 144
 145 ----------------------------------------------------------------------
 146 --      Standard combinators, but specialised for this monad
 147 --                      (for efficiency)
 148 ----------------------------------------------------------------------
 149
 150 mappM         :: (a -> IOEnv env b) -> [a] -> IOEnv env [b]
 151 mappM_        :: (a -> IOEnv env b) -> [a] -> IOEnv env ()
 152 mapSndM       :: (b -> IOEnv env c) -> [(a,b)] -> IOEnv env [(a,c)]
 153         -- Funny names to avoid clash with Prelude
 154 sequenceM     :: [IOEnv env a] -> IOEnv env [a]
 155 sequenceM_    :: [IOEnv env a] -> IOEnv env ()
 156 foldlM        :: (a -> b -> IOEnv env a)  -> a -> [b] -> IOEnv env a
 157 mapAndUnzipM  :: (a -> IOEnv env (b,c))   -> [a] -> IOEnv env ([b],[c])
 158 mapAndUnzip3M :: (a -> IOEnv env (b,c,d)) -> [a] -> IOEnv env ([b],[c],[d])
 159 checkM        :: Bool -> IOEnv env () -> IOEnv env ()   -- Perform arg if bool is False
 160 ifM           :: Bool -> IOEnv env () -> IOEnv env ()   -- Perform arg if bool is True
 161
 162 mappM f []     = return []
 163 mappM f (x:xs) = do { r <- f x; rs <- mappM f xs; return (r:rs) }
 164
 165 mapSndM f []     = return []
 166 mapSndM f ((a,b):xs) = do { c <- f b; rs <- mapSndM f xs; return ((a,c):rs) }
 167
 168 mappM_ f []     = return ()
 169 mappM_ f (x:xs) = f x >> mappM_ f xs
 170
 171 zipWithM :: (a -> b -> IOEnv env c) -> [a] -> [b] -> IOEnv env [c]
 172 zipWithM f [] bs = return []
 173 zipWithM f as [] = return []
 174 zipWithM f (a:as) (b:bs) = do { r <- f a b; rs <- zipWithM f as bs; return (r:rs) }
 175
 176 zipWithM_ :: (a -> b -> IOEnv env c) -> [a] -> [b] -> IOEnv env ()
 177 zipWithM_ f [] bs = return ()
 178 zipWithM_ f as [] = return ()
 179 zipWithM_ f (a:as) (b:bs) = do { f a b; zipWithM_ f as bs }
 180
 181 sequenceM [] = return []
 182 sequenceM (x:xs) = do { r <- x; rs <- sequenceM xs; return (r:rs) }
 183
 184 sequenceM_ []     = return ()
 185 sequenceM_ (x:xs) = do { x; sequenceM_ xs }
 186
 187 foldlM k z [] = return z
 188 foldlM k z (x:xs) = do { r <- k z x; foldlM k r xs }
 189
 190 mapAndUnzipM f []     = return ([],[])
 191 mapAndUnzipM f (x:xs) = do { (r,s) <- f x;
 192                              (rs,ss) <- mapAndUnzipM f xs;
 193                              return (r:rs, s:ss) }
 194
 195 mapAndUnzip3M f []     = return ([],[], [])
 196 mapAndUnzip3M f (x:xs) = do { (r,s,t) <- f x;
 197                               (rs,ss,ts) <- mapAndUnzip3M f xs;
 198                               return (r:rs, s:ss, t:ts) }
 199
 200 checkM True  err = return ()
 201 checkM False err = err
 202
 203 ifM True  do_it = do_it
 204 ifM False do_it = return ()