ghc/lib/std/Complex.lhs

   1 % -----------------------------------------------------------------------------
   2 % $Id: Complex.lhs,v 1.6 2001/09/19 14:05:01 simonmar Exp $
   3 %
   4 % (c) The University of Glasgow, 1994-2000
   5 %
   6
   7 \section[Complex]{Module @Complex@}
   8
   9 \begin{code}
  10 module Complex
  11         ( Complex((:+))
  12
  13         , realPart      -- :: (RealFloat a) => Complex a -> a
  14         , imagPart      -- :: (RealFloat a) => Complex a -> a
  15         , conjugate     -- :: (RealFloat a) => Complex a -> Complex a
  16         , mkPolar       -- :: (RealFloat a) => a -> a -> Complex a
  17         , cis           -- :: (RealFloat a) => a -> Complex a
  18         , polar         -- :: (RealFloat a) => Complex a -> (a,a)
  19         , magnitude     -- :: (RealFloat a) => Complex a -> a
  20         , phase         -- :: (RealFloat a) => Complex a -> a
  21
  22         -- Complex instances:
  23         --
  24         --  (RealFloat a) => Eq         (Complex a)
  25         --  (RealFloat a) => Read       (Complex a)
  26         --  (RealFloat a) => Show       (Complex a)
  27         --  (RealFloat a) => Num        (Complex a)
  28         --  (RealFloat a) => Fractional (Complex a)
  29         --  (RealFloat a) => Floating   (Complex a)
  30         --
  31         -- Implementation checked wrt. Haskell 98 lib report, 1/99.
  32
  33         )  where
  34
  35 import Prelude
  36
  37 infix  6  :+
  38 \end{code}
  39
  40 %*********************************************************
  41 %*                                                      *
  42 \subsection{The @Complex@ type}
  43 %*                                                      *
  44 %*********************************************************
  45
  46 \begin{code}
  47 data  (RealFloat a)     => Complex a = !a :+ !a  deriving (Eq, Read, Show)
  48 \end{code}
  49
  50
  51 %*********************************************************
  52 %*                                                      *
  53 \subsection{Functions over @Complex@}
  54 %*                                                      *
  55 %*********************************************************
  56
  57 \begin{code}
  58 {-# SPECIALISE realPart :: Complex Double -> Double #-}
  59 {-# SPECIALISE imagPart :: Complex Double -> Double #-}
  60 realPart, imagPart :: (RealFloat a) => Complex a -> a
  61 realPart (x :+ _) =  x
  62 imagPart (_ :+ y) =  y
  63
  64 {-# SPECIALISE conjugate :: Complex Double -> Complex Double #-}
  65 conjugate        :: (RealFloat a) => Complex a -> Complex a
  66 conjugate (x:+y) =  x :+ (-y)
  67
  68 {-# SPECIALISE mkPolar :: Double -> Double -> Complex Double #-}
  69 mkPolar          :: (RealFloat a) => a -> a -> Complex a
  70 mkPolar r theta  =  r * cos theta :+ r * sin theta
  71
  72 {-# SPECIALISE cis :: Double -> Complex Double #-}
  73 cis              :: (RealFloat a) => a -> Complex a
  74 cis theta        =  cos theta :+ sin theta
  75
  76 {-# SPECIALISE polar :: Complex Double -> (Double,Double) #-}
  77 polar            :: (RealFloat a) => Complex a -> (a,a)
  78 polar z          =  (magnitude z, phase z)
  79
  80 {-# SPECIALISE magnitude :: Complex Double -> Double #-}
  81 magnitude :: (RealFloat a) => Complex a -> a
  82 magnitude (x:+y) =  scaleFloat k
  83                      (sqrt ((scaleFloat mk x)^(2::Int) + (scaleFloat mk y)^(2::Int)))
  84                     where k  = max (exponent x) (exponent y)
  85                           mk = - k
  86
  87 {-# SPECIALISE phase :: Complex Double -> Double #-}
  88 phase :: (RealFloat a) => Complex a -> a
  89 phase (0 :+ 0)   = 0            -- SLPJ July 97 from John Peterson
  90 phase (x:+y)     = atan2 y x
  91 \end{code}
  92
  93
  94 %*********************************************************
  95 %*                                                      *
  96 \subsection{Instances of @Complex@}
  97 %*                                                      *
  98 %*********************************************************
  99
 100 \begin{code}
 101 instance  (RealFloat a) => Num (Complex a)  where
 102     {-# SPECIALISE instance Num (Complex Float) #-}
 103     {-# SPECIALISE instance Num (Complex Double) #-}
 104     (x:+y) + (x':+y')   =  (x+x') :+ (y+y')
 105     (x:+y) - (x':+y')   =  (x-x') :+ (y-y')
 106     (x:+y) * (x':+y')   =  (x*x'-y*y') :+ (x*y'+y*x')
 107     negate (x:+y)       =  negate x :+ negate y
 108     abs z               =  magnitude z :+ 0
 109     signum 0            =  0
 110     signum z@(x:+y)     =  x/r :+ y/r  where r = magnitude z
 111     fromInteger n       =  fromInteger n :+ 0
 112
 113 instance  (RealFloat a) => Fractional (Complex a)  where
 114     {-# SPECIALISE instance Fractional (Complex Float) #-}
 115     {-# SPECIALISE instance Fractional (Complex Double) #-}
 116     (x:+y) / (x':+y')   =  (x*x''+y*y'') / d :+ (y*x''-x*y'') / d
 117                            where x'' = scaleFloat k x'
 118                                  y'' = scaleFloat k y'
 119                                  k   = - max (exponent x') (exponent y')
 120                                  d   = x'*x'' + y'*y''
 121
 122     fromRational a      =  fromRational a :+ 0
 123
 124 instance  (RealFloat a) => Floating (Complex a) where
 125     {-# SPECIALISE instance Floating (Complex Float) #-}
 126     {-# SPECIALISE instance Floating (Complex Double) #-}
 127     pi             =  pi :+ 0
 128     exp (x:+y)     =  expx * cos y :+ expx * sin y
 129                       where expx = exp x
 130     log z          =  log (magnitude z) :+ phase z
 131
 132     sqrt 0         =  0
 133     sqrt z@(x:+y)  =  u :+ (if y < 0 then -v else v)
 134                       where (u,v) = if x < 0 then (v',u') else (u',v')
 135                             v'    = abs y / (u'*2)
 136                             u'    = sqrt ((magnitude z + abs x) / 2)
 137
 138     sin (x:+y)     =  sin x * cosh y :+ cos x * sinh y
 139     cos (x:+y)     =  cos x * cosh y :+ (- sin x * sinh y)
 140     tan (x:+y)     =  (sinx*coshy:+cosx*sinhy)/(cosx*coshy:+(-sinx*sinhy))
 141                       where sinx  = sin x
 142                             cosx  = cos x
 143                             sinhy = sinh y
 144                             coshy = cosh y
 145
 146     sinh (x:+y)    =  cos y * sinh x :+ sin  y * cosh x
 147     cosh (x:+y)    =  cos y * cosh x :+ sin y * sinh x
 148     tanh (x:+y)    =  (cosy*sinhx:+siny*coshx)/(cosy*coshx:+siny*sinhx)
 149                       where siny  = sin y
 150                             cosy  = cos y
 151                             sinhx = sinh x
 152                             coshx = cosh x
 153
 154     asin z@(x:+y)  =  y':+(-x')
 155                       where  (x':+y') = log (((-y):+x) + sqrt (1 - z*z))
 156     acos z         =  y'':+(-x'')
 157                       where (x'':+y'') = log (z + ((-y'):+x'))
 158                             (x':+y')   = sqrt (1 - z*z)
 159     atan z@(x:+y)  =  y':+(-x')
 160                       where (x':+y') = log (((1-y):+x) / sqrt (1+z*z))
 161
 162     asinh z        =  log (z + sqrt (1+z*z))
 163     acosh z        =  log (z + (z+1) * sqrt ((z-1)/(z+1)))
 164     atanh z        =  log ((1+z) / sqrt (1-z*z))
 165 \end{code}