ghc/lib/std/Monad.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1994-1999
   3 %
   4 \section[Monad]{Module @Monad@}
   5
   6 \begin{code}
   7 {-# OPTIONS -fno-implicit-prelude #-}
   8
   9 module Monad
  10     ( MonadPlus (   -- class context: Monad
  11           mzero     -- :: (MonadPlus m) => m a
  12         , mplus     -- :: (MonadPlus m) => m a -> m a -> m a
  13         )
  14     , join          -- :: (Monad m) => m (m a) -> m a
  15     , guard         -- :: (Monad m) => Bool -> m ()
  16     , when          -- :: (Monad m) => Bool -> m () -> m ()
  17     , unless        -- :: (Monad m) => Bool -> m () -> m ()
  18     , ap            -- :: (Monad m) => (m (a -> b)) -> (m a) -> m b
  19     , msum          -- :: (MonadPlus m) => [m a] -> m a
  20     , filterM       -- :: (Monad m) => (a -> m Bool) -> [m a] -> m [a]
  21     , mapAndUnzipM  -- :: (Monad m) => (a -> m (b,c)) -> [a] -> m ([b], [c])
  22     , zipWithM      -- :: (Monad m) => (a -> b -> m c) -> [a] -> [b] -> m [c]
  23     , zipWithM_     -- :: (Monad m) => (a -> b -> m c) -> [a] -> [b] -> m ()
  24     , foldM         -- :: (Monad m) => (a -> b -> m a) -> a -> [b] -> m a
  25
  26     , liftM         -- :: (Monad m) => (a -> b) -> (m a -> m b)
  27     , liftM2        -- :: (Monad m) => (a -> b -> c) -> (m a -> m b -> m c)
  28     , liftM3        -- :: ...
  29     , liftM4        -- :: ...
  30     , liftM5        -- :: ...
  31
  32     , Monad((>>=), (>>), return, fail)
  33     , Functor(fmap)
  34
  35     , mapM          -- :: (Monad m) => (a -> m b) -> [a] -> m [b]
  36     , mapM_         -- :: (Monad m) => (a -> m b) -> [a] -> m ()
  37     , sequence      -- :: (Monad m) => [m a] -> m [a]
  38     , sequence_     -- :: (Monad m) => [m a] -> m ()
  39     , (=<<)         -- :: (Monad m) => (a -> m b) -> m a -> m b
  40     ) where
  41
  42 #ifndef __HUGS__
  43 import PrelList
  44 import PrelTup
  45 import PrelBase
  46 import PrelMaybe ( Maybe(..) )
  47
  48 infixr 1 =<<
  49 #endif
  50 \end{code}
  51
  52 %*********************************************************
  53 %*                                                      *
  54 \subsection{Monadic classes: @MonadPlus@}
  55 %*                                                      *
  56 %*********************************************************
  57
  58
  59 \begin{code}
  60 class Monad m => MonadPlus m where
  61   mzero :: m a
  62   mplus :: m a -> m a -> m a
  63
  64 instance MonadPlus [] where
  65    mzero = []
  66    mplus = (++)
  67
  68 instance MonadPlus Maybe where
  69    mzero = Nothing
  70
  71    Nothing `mplus` ys  = ys
  72    xs      `mplus` _ys = xs
  73 \end{code}
  74
  75
  76 %*********************************************************
  77 %*                                                      *
  78 \subsection{Functions mandated by the Prelude}
  79 %*                                                      *
  80 %*********************************************************
  81
  82 \begin{code}
  83 #ifdef __HUGS__
  84 -- These functions are defined in the Prelude.
  85 -- sequence       :: Monad m => [m a] -> m [a]
  86 -- sequence_        :: Monad m => [m a] -> m ()
  87 -- mapM            :: Monad m => (a -> m b) -> [a] -> m [b]
  88 -- mapM_           :: Monad m => (a -> m b) -> [a] -> m ()
  89 #else
  90 sequence       :: Monad m => [m a] -> m [a]
  91 sequence []     = return []
  92 sequence (m:ms) = do { x <- m; xs <- sequence ms; return (x:xs) }
  93
  94 sequence_        :: Monad m => [m a] -> m ()
  95 {-# INLINE sequence_ #-}
  96 sequence_        =  foldr (>>) (return ())
  97
  98 mapM            :: Monad m => (a -> m b) -> [a] -> m [b]
  99 {-# INLINE mapM #-}
 100 mapM f as       =  sequence (map f as)
 101
 102 mapM_           :: Monad m => (a -> m b) -> [a] -> m ()
 103 {-# INLINE mapM_ #-}
 104 mapM_ f as      =  sequence_ (map f as)
 105 #endif
 106
 107 guard           :: MonadPlus m => Bool -> m ()
 108 guard pred
 109  | pred      = return ()
 110  | otherwise = mzero
 111
 112 -- This subsumes the list-based filter function.
 113
 114 filterM         :: (Monad m) => ( a -> m Bool ) -> [a] -> m [a]
 115 filterM _predM []     = return []
 116 filterM  predM (x:xs) = do
 117    flg <- predM x
 118    ys  <- filterM predM xs
 119    return (if flg then x:ys else ys)
 120
 121 -- This subsumes the list-based concat function.
 122
 123 msum        :: MonadPlus m => [m a] -> m a
 124 {-# INLINE msum #-}
 125 msum        =  foldr mplus mzero
 126
 127 #ifdef __HUGS__
 128 -- This function is defined in the Prelude.
 129 --(=<<)           :: Monad m => (a -> m b) -> m a -> m b
 130 #else
 131 {-# SPECIALISE (=<<) :: (a -> [b]) -> [a] -> [b] #-}
 132 (=<<)           :: Monad m => (a -> m b) -> m a -> m b
 133 f =<< x         = x >>= f
 134 #endif
 135 \end{code}
 136
 137
 138 %*********************************************************
 139 %*                                                      *
 140 \subsection{Other monad functions}
 141 %*                                                      *
 142 %*********************************************************
 143
 144 \begin{code}
 145 join             :: (Monad m) => m (m a) -> m a
 146 join x           = x >>= id
 147
 148 mapAndUnzipM     :: (Monad m) => (a -> m (b,c)) -> [a] -> m ([b], [c])
 149 mapAndUnzipM f xs = sequence (map f xs) >>= return . unzip
 150
 151 zipWithM         :: (Monad m) => (a -> b -> m c) -> [a] -> [b] -> m [c]
 152 zipWithM f xs ys = sequence (zipWith f xs ys)
 153
 154 zipWithM_ :: (Monad m) => (a -> b -> m c) -> [a] -> [b] -> m ()
 155 zipWithM_ f xs ys = sequence_ (zipWith f xs ys)
 156
 157 foldM            :: (Monad m) => (a -> b -> m a) -> a -> [b] -> m a
 158 foldM _ a []     = return a
 159 foldM f a (x:xs) = f a x >>= \fax -> foldM f fax xs
 160
 161 unless           :: (Monad m) => Bool -> m () -> m ()
 162 unless p s       =  if p then return () else s
 163
 164 when             :: (Monad m) => Bool -> m () -> m ()
 165 when p s         =  if p then s else return ()
 166
 167 ap :: (Monad m) => m (a->b) -> m a -> m b
 168 ap = liftM2 ($)
 169
 170 liftM   :: (Monad m) => (a1 -> r) -> m a1 -> m r
 171 liftM2  :: (Monad m) => (a1 -> a2 -> r) -> m a1 -> m a2 -> m r
 172 liftM3  :: (Monad m) => (a1 -> a2 -> a3 -> r) -> m a1 -> m a2 -> m a3 -> m r
 173 liftM4  :: (Monad m) => (a1 -> a2 -> a3 -> a4 -> r) -> m a1 -> m a2 -> m a3 -> m a4 -> m r
 174 liftM5  :: (Monad m) => (a1 -> a2 -> a3 -> a4 -> a5 -> r) -> m a1 -> m a2 -> m a3 -> m a4 -> m a5 -> m r
 175
 176 liftM f m1              = do { x1 <- m1; return (f x1) }
 177 liftM2 f m1 m2          = do { x1 <- m1; x2 <- m2; return (f x1 x2) }
 178 liftM3 f m1 m2 m3       = do { x1 <- m1; x2 <- m2; x3 <- m3; return (f x1 x2 x3) }
 179 liftM4 f m1 m2 m3 m4    = do { x1 <- m1; x2 <- m2; x3 <- m3; x4 <- m4; return (f x1 x2 x3 x4) }
 180 liftM5 f m1 m2 m3 m4 m5 = do { x1 <- m1; x2 <- m2; x3 <- m3; x4 <- m4; x5 <- m5; return (f x1 x2 x3 x4 x5) }
 181
 182 \end{code}