ghc/lib/std/Monad.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1994-1999
   3 %
   4 \section[Monad]{Module @Monad@}
   5
   6 \begin{code}
   7 {-# OPTIONS -fno-implicit-prelude #-}
   8
   9 module Monad
  10     ( MonadPlus (   -- class context: Monad
  11           mzero     -- :: (MonadPlus m) => m a
  12         , mplus     -- :: (MonadPlus m) => m a -> m a -> m a
  13         )
  14     , join          -- :: (Monad m) => m (m a) -> m a
  15     , guard         -- :: (Monad m) => Bool -> m ()
  16     , when          -- :: (Monad m) => Bool -> m () -> m ()
  17     , unless        -- :: (Monad m) => Bool -> m () -> m ()
  18     , ap            -- :: (Monad m) => (m (a -> b)) -> (m a) -> m b
  19     , msum          -- :: (MonadPlus m) => [m a] -> m a
  20     , filterM       -- :: (Monad m) => (a -> m Bool) -> [m a] -> m [a]
  21     , mapAndUnzipM  -- :: (Monad m) => (a -> m (b,c)) -> [a] -> m ([b], [c])
  22     , zipWithM      -- :: (Monad m) => (a -> b -> m c) -> [a] -> [b] -> m [c]
  23     , zipWithM_     -- :: (Monad m) => (a -> b -> m c) -> [a] -> [b] -> m ()
  24     , foldM         -- :: (Monad m) => (a -> b -> m a) -> a -> [b] -> m a
  25
  26     , liftM         -- :: (Monad m) => (a -> b) -> (m a -> m b)
  27     , liftM2        -- :: (Monad m) => (a -> b -> c) -> (m a -> m b -> m c)
  28     , liftM3        -- :: ...
  29     , liftM4        -- :: ...
  30     , liftM5        -- :: ...
  31
  32     , Monad((>>=), (>>), return, fail)
  33     , Functor(fmap)
  34
  35     , mapM          -- :: (Monad m) => (a -> m b) -> [a] -> m [b]
  36     , mapM_         -- :: (Monad m) => (a -> m b) -> [a] -> m ()
  37     , sequence      -- :: (Monad m) => [m a] -> m [a]
  38     , sequence_     -- :: (Monad m) => [m a] -> m ()
  39     , (=<<)         -- :: (Monad m) => (a -> m b) -> m a -> m b
  40     ) where
  41
  42 import PrelList
  43 import PrelTup
  44 import PrelBase
  45 import PrelMaybe ( Maybe(..) )
  46 \end{code}
  47
  48 %*********************************************************
  49 %*                                                      *
  50 \subsection{Monadic classes: @MonadPlus@}
  51 %*                                                      *
  52 %*********************************************************
  53
  54
  55 \begin{code}
  56 class Monad m => MonadPlus m where
  57   mzero :: m a
  58   mplus :: m a -> m a -> m a
  59
  60 instance MonadPlus [] where
  61    mzero = []
  62    mplus = (++)
  63
  64 instance MonadPlus Maybe where
  65    mzero = Nothing
  66
  67    Nothing `mplus` ys  = ys
  68    xs      `mplus` _ys = xs
  69 \end{code}
  70
  71
  72 %*********************************************************
  73 %*                                                      *
  74 \subsection{Functions mandated by the Prelude}
  75 %*                                                      *
  76 %*********************************************************
  77
  78 \begin{code}
  79 sequence       :: Monad m => [m a] -> m [a]
  80 sequence []     = return []
  81 sequence (m:ms) = do { x <- m; xs <- sequence ms; return (x:xs) }
  82
  83 sequence_        :: Monad m => [m a] -> m ()
  84 sequence_        =  foldr (>>) (return ())
  85
  86 mapM            :: Monad m => (a -> m b) -> [a] -> m [b]
  87 mapM f as       =  sequence (map f as)
  88
  89 mapM_           :: Monad m => (a -> m b) -> [a] -> m ()
  90 mapM_ f as      =  sequence_ (map f as)
  91
  92 guard           :: MonadPlus m => Bool -> m ()
  93 guard pred
  94  | pred      = return ()
  95  | otherwise = mzero
  96
  97 -- This subsumes the list-based filter function.
  98
  99 filterM         :: (Monad m) => ( a -> m Bool ) -> [a] -> m [a]
 100 filterM _predM []     = return []
 101 filterM  predM (x:xs) = do
 102    flg <- predM x
 103    ys  <- filterM predM xs
 104    return (if flg then x:ys else ys)
 105
 106 -- This subsumes the list-based concat function.
 107
 108 msum        :: MonadPlus m => [m a] -> m a
 109 msum        =  foldr mplus mzero
 110
 111 {-# SPECIALISE (=<<) :: (a -> [b]) -> [a] -> [b] #-}
 112 (=<<)           :: Monad m => (a -> m b) -> m a -> m b
 113 f =<< x         = x >>= f
 114 \end{code}
 115
 116
 117 %*********************************************************
 118 %*                                                      *
 119 \subsection{Other monad functions}
 120 %*                                                      *
 121 %*********************************************************
 122
 123 \begin{code}
 124 join             :: (Monad m) => m (m a) -> m a
 125 join x           = x >>= id
 126
 127 mapAndUnzipM     :: (Monad m) => (a -> m (b,c)) -> [a] -> m ([b], [c])
 128 mapAndUnzipM f xs = sequence (map f xs) >>= return . unzip
 129
 130 zipWithM         :: (Monad m) => (a -> b -> m c) -> [a] -> [b] -> m [c]
 131 zipWithM f xs ys = sequence (zipWith f xs ys)
 132
 133 zipWithM_ :: (Monad m) => (a -> b -> m c) -> [a] -> [b] -> m ()
 134 zipWithM_ f xs ys = sequence_ (zipWith f xs ys)
 135
 136 foldM            :: (Monad m) => (a -> b -> m a) -> a -> [b] -> m a
 137 foldM _ a []     = return a
 138 foldM f a (x:xs) = f a x >>= \fax -> foldM f fax xs
 139
 140 unless           :: (Monad m) => Bool -> m () -> m ()
 141 unless p s       =  if p then return () else s
 142
 143 when             :: (Monad m) => Bool -> m () -> m ()
 144 when p s         =  if p then s else return ()
 145
 146 ap :: (Monad m) => m (a->b) -> m a -> m b
 147 ap = liftM2 ($)
 148
 149 liftM   :: (Monad m) => (a1 -> r) -> m a1 -> m r
 150 liftM2  :: (Monad m) => (a1 -> a2 -> r) -> m a1 -> m a2 -> m r
 151 liftM3  :: (Monad m) => (a1 -> a2 -> a3 -> r) -> m a1 -> m a2 -> m a3 -> m r
 152 liftM4  :: (Monad m) => (a1 -> a2 -> a3 -> a4 -> r) -> m a1 -> m a2 -> m a3 -> m a4 -> m r
 153 liftM5  :: (Monad m) => (a1 -> a2 -> a3 -> a4 -> a5 -> r) -> m a1 -> m a2 -> m a3 -> m a4 -> m a5 -> m r
 154
 155 liftM f m1              = do { x1 <- m1; return (f x1) }
 156 liftM2 f m1 m2          = do { x1 <- m1; x2 <- m2; return (f x1 x2) }
 157 liftM3 f m1 m2 m3       = do { x1 <- m1; x2 <- m2; x3 <- m3; return (f x1 x2 x3) }
 158 liftM4 f m1 m2 m3 m4    = do { x1 <- m1; x2 <- m2; x3 <- m3; x4 <- m4; return (f x1 x2 x3 x4) }
 159 liftM5 f m1 m2 m3 m4 m5 = do { x1 <- m1; x2 <- m2; x3 <- m3; x4 <- m4; x5 <- m5; return (f x1 x2 x3 x4 x5) }
 160
 161 \end{code}