ghc/lib/std/PrelList.lhs

   1 % ------------------------------------------------------------------------------
   2 % $Id: PrelList.lhs,v 1.25 2001/07/31 10:48:02 simonmar Exp $
   3 %
   4 % (c) The University of Glasgow, 1994-2000
   5 %
   6
   7 \section[PrelList]{Module @PrelList@}
   8
   9 The List data type and its operations
  10
  11 \begin{code}
  12 {-# OPTIONS -fno-implicit-prelude #-}
  13
  14 module PrelList (
  15    [] (..),
  16
  17    map, (++), filter, concat,
  18    head, last, tail, init, null, length, (!!),
  19    foldl, foldl1, scanl, scanl1, foldr, foldr1, scanr, scanr1,
  20    iterate, repeat, replicate, cycle,
  21    take, drop, splitAt, takeWhile, dropWhile, span, break,
  22    reverse, and, or,
  23    any, all, elem, notElem, lookup,
  24    maximum, minimum, concatMap,
  25    zip, zip3, zipWith, zipWith3, unzip, unzip3,
  26 #ifdef USE_REPORT_PRELUDE
  27
  28 #else
  29
  30    -- non-standard, but hidden when creating the Prelude
  31    -- export list.
  32    takeUInt_append
  33
  34 #endif
  35
  36  ) where
  37
  38 import {-# SOURCE #-} PrelErr ( error )
  39 import PrelTup
  40 import PrelMaybe
  41 import PrelBase
  42
  43 infixl 9  !!
  44 infix  4 `elem`, `notElem`
  45 \end{code}
  46
  47 %*********************************************************
  48 %*                                                      *
  49 \subsection{List-manipulation functions}
  50 %*                                                      *
  51 %*********************************************************
  52
  53 \begin{code}
  54 -- head and tail extract the first element and remaining elements,
  55 -- respectively, of a list, which must be non-empty.  last and init
  56 -- are the dual functions working from the end of a finite list,
  57 -- rather than the beginning.
  58
  59 head                    :: [a] -> a
  60 head (x:_)              =  x
  61 head []                 =  badHead
  62
  63 badHead = errorEmptyList "head"
  64
  65 -- This rule is useful in cases like
  66 --      head [y | (x,y) <- ps, x==t]
  67 {-# RULES
  68 "head/build"    forall (g::forall b.(Bool->b->b)->b->b) .
  69                 head (build g) = g (\x _ -> x) badHead
  70 "head/augment"  forall xs (g::forall b. (a->b->b) -> b -> b) .
  71                 head (augment g xs) = g (\x _ -> x) (head xs)
  72  #-}
  73
  74 tail                    :: [a] -> [a]
  75 tail (_:xs)             =  xs
  76 tail []                 =  errorEmptyList "tail"
  77
  78 last                    :: [a] -> a
  79 #ifdef USE_REPORT_PRELUDE
  80 last [x]                =  x
  81 last (_:xs)             =  last xs
  82 last []                 =  errorEmptyList "last"
  83 #else
  84 -- eliminate repeated cases
  85 last []                 =  errorEmptyList "last"
  86 last (x:xs)             =  last' x xs
  87   where last' y []     = y
  88         last' _ (y:ys) = last' y ys
  89 #endif
  90
  91 init                    :: [a] -> [a]
  92 #ifdef USE_REPORT_PRELUDE
  93 init [x]                =  []
  94 init (x:xs)             =  x : init xs
  95 init []                 =  errorEmptyList "init"
  96 #else
  97 -- eliminate repeated cases
  98 init []                 =  errorEmptyList "init"
  99 init (x:xs)             =  init' x xs
 100   where init' _ []     = []
 101         init' y (z:zs) = y : init' z zs
 102 #endif
 103
 104 null                    :: [a] -> Bool
 105 null []                 =  True
 106 null (_:_)              =  False
 107
 108 -- length returns the length of a finite list as an Int; it is an instance
 109 -- of the more general genericLength, the result type of which may be
 110 -- any kind of number.
 111 length                  :: [a] -> Int
 112 length l                =  len l 0#
 113   where
 114     len :: [a] -> Int# -> Int
 115     len []     a# = I# a#
 116     len (_:xs) a# = len xs (a# +# 1#)
 117
 118 -- filter, applied to a predicate and a list, returns the list of those
 119 -- elements that satisfy the predicate; i.e.,
 120 -- filter p xs = [ x | x <- xs, p x]
 121 filter :: (a -> Bool) -> [a] -> [a]
 122 filter = filterList
 123
 124 filterFB c p x r | p x       = x `c` r
 125                  | otherwise = r
 126
 127 {-# RULES
 128 "filter"        forall p xs.    filter p xs = build (\c n -> foldr (filterFB c p) n xs)
 129 "filterFB"      forall c p q.   filterFB (filterFB c p) q = filterFB c (\x -> q x && p x)
 130 "filterList"    forall p.       foldr (filterFB (:) p) [] = filterList p
 131  #-}
 132
 133 -- Note the filterFB rule, which has p and q the "wrong way round" in the RHS.
 134 --     filterFB (filterFB c p) q a b
 135 --   = if q a then filterFB c p a b else b
 136 --   = if q a then (if p a then c a b else b) else b
 137 --   = if q a && p a then c a b else b
 138 --   = filterFB c (\x -> q x && p x) a b
 139 -- I originally wrote (\x -> p x && q x), which is wrong, and actually
 140 -- gave rise to a live bug report.  SLPJ.
 141
 142 filterList :: (a -> Bool) -> [a] -> [a]
 143 filterList _pred []    = []
 144 filterList pred (x:xs)
 145   | pred x         = x : filterList pred xs
 146   | otherwise      = filterList pred xs
 147
 148 -- foldl, applied to a binary operator, a starting value (typically the
 149 -- left-identity of the operator), and a list, reduces the list using
 150 -- the binary operator, from left to right:
 151 --  foldl f z [x1, x2, ..., xn] == (...((z `f` x1) `f` x2) `f`...) `f` xn
 152 -- foldl1 is a variant that has no starting value argument, and  thus must
 153 -- be applied to non-empty lists.  scanl is similar to foldl, but returns
 154 -- a list of successive reduced values from the left:
 155 --      scanl f z [x1, x2, ...] == [z, z `f` x1, (z `f` x1) `f` x2, ...]
 156 -- Note that  last (scanl f z xs) == foldl f z xs.
 157 -- scanl1 is similar, again without the starting element:
 158 --      scanl1 f [x1, x2, ...] == [x1, x1 `f` x2, ...]
 159
 160 -- We write foldl as a non-recursive thing, so that it
 161 -- can be inlined, and then (often) strictness-analysed,
 162 -- and hence the classic space leak on foldl (+) 0 xs
 163
 164 foldl        :: (a -> b -> a) -> a -> [b] -> a
 165 foldl f z xs = lgo z xs
 166              where
 167                 lgo z []     =  z
 168                 lgo z (x:xs) = lgo (f z x) xs
 169
 170 foldl1                  :: (a -> a -> a) -> [a] -> a
 171 foldl1 f (x:xs)         =  foldl f x xs
 172 foldl1 _ []             =  errorEmptyList "foldl1"
 173
 174 scanl                   :: (a -> b -> a) -> a -> [b] -> [a]
 175 scanl f q ls            =  q : (case ls of
 176                                 []   -> []
 177                                 x:xs -> scanl f (f q x) xs)
 178
 179 scanl1                  :: (a -> a -> a) -> [a] -> [a]
 180 scanl1 f (x:xs)         =  scanl f x xs
 181 scanl1 _ []             =  errorEmptyList "scanl1"
 182
 183 -- foldr, foldr1, scanr, and scanr1 are the right-to-left duals of the
 184 -- above functions.
 185
 186 foldr1                  :: (a -> a -> a) -> [a] -> a
 187 foldr1 _ [x]            =  x
 188 foldr1 f (x:xs)         =  f x (foldr1 f xs)
 189 foldr1 _ []             =  errorEmptyList "foldr1"
 190
 191 scanr                   :: (a -> b -> b) -> b -> [a] -> [b]
 192 scanr _ q0 []           =  [q0]
 193 scanr f q0 (x:xs)       =  f x q : qs
 194                            where qs@(q:_) = scanr f q0 xs
 195
 196 scanr1                  :: (a -> a -> a) -> [a] -> [a]
 197 scanr1 _  [x]           =  [x]
 198 scanr1 f  (x:xs)        =  f x q : qs
 199                            where qs@(q:_) = scanr1 f xs
 200 scanr1 _ []             =  errorEmptyList "scanr1"
 201
 202 -- iterate f x returns an infinite list of repeated applications of f to x:
 203 -- iterate f x == [x, f x, f (f x), ...]
 204 iterate :: (a -> a) -> a -> [a]
 205 iterate = iterateList
 206
 207 iterateFB c f x = x `c` iterateFB c f (f x)
 208
 209 iterateList f x =  x : iterateList f (f x)
 210
 211 {-# RULES
 212 "iterate"       forall f x.     iterate f x = build (\c _n -> iterateFB c f x)
 213 "iterateFB"                     iterateFB (:) = iterateList
 214  #-}
 215
 216
 217 -- repeat x is an infinite list, with x the value of every element.
 218 repeat :: a -> [a]
 219 repeat = repeatList
 220
 221 repeatFB c x = xs where xs = x `c` xs
 222 repeatList x = xs where xs = x :   xs
 223
 224 {-# RULES
 225 "repeat"        forall x. repeat x      = build (\c _n -> repeatFB c x)
 226 "repeatFB"                repeatFB (:)  = repeatList
 227  #-}
 228
 229 -- replicate n x is a list of length n with x the value of every element
 230 replicate               :: Int -> a -> [a]
 231 replicate n x           =  take n (repeat x)
 232
 233 -- cycle ties a finite list into a circular one, or equivalently,
 234 -- the infinite repetition of the original list.  It is the identity
 235 -- on infinite lists.
 236
 237 cycle                   :: [a] -> [a]
 238 cycle []                = error "Prelude.cycle: empty list"
 239 cycle xs                = xs' where xs' = xs ++ xs'
 240
 241 -- takeWhile, applied to a predicate p and a list xs, returns the longest
 242 -- prefix (possibly empty) of xs of elements that satisfy p.  dropWhile p xs
 243 -- returns the remaining suffix.  Span p xs is equivalent to
 244 -- (takeWhile p xs, dropWhile p xs), while break p uses the negation of p.
 245
 246 takeWhile               :: (a -> Bool) -> [a] -> [a]
 247 takeWhile _ []          =  []
 248 takeWhile p (x:xs)
 249             | p x       =  x : takeWhile p xs
 250             | otherwise =  []
 251
 252 dropWhile               :: (a -> Bool) -> [a] -> [a]
 253 dropWhile _ []          =  []
 254 dropWhile p xs@(x:xs')
 255             | p x       =  dropWhile p xs'
 256             | otherwise =  xs
 257
 258 -- take n, applied to a list xs, returns the prefix of xs of length n,
 259 -- or xs itself if n > length xs.  drop n xs returns the suffix of xs
 260 -- after the first n elements, or [] if n > length xs.  splitAt n xs
 261 -- is equivalent to (take n xs, drop n xs).
 262 #ifdef USE_REPORT_PRELUDE
 263 take                   :: Int -> [a] -> [a]
 264 take n _      | n <= 0 =  []
 265 take _ []              =  []
 266 take n (x:xs)          =  x : take (n-1) xs
 267
 268 drop                   :: Int -> [a] -> [a]
 269 drop n xs     | n <= 0 =  xs
 270 drop _ []              =  []
 271 drop n (_:xs)          =  drop (n-1) xs
 272
 273 splitAt                  :: Int -> [a] -> ([a],[a])
 274 splitAt n xs             =  (take n xs, drop n xs)
 275
 276 #else /* hack away */
 277 take    :: Int -> [b] -> [b]
 278 take (I# n#) xs = takeUInt n# xs
 279
 280 -- The general code for take, below, checks n <= maxInt
 281 -- No need to check for maxInt overflow when specialised
 282 -- at type Int or Int# since the Int must be <= maxInt
 283
 284 takeUInt :: Int# -> [b] -> [b]
 285 takeUInt n xs
 286   | n >=# 0#  =  take_unsafe_UInt n xs
 287   | otherwise =  []
 288
 289 take_unsafe_UInt :: Int# -> [b] -> [b]
 290 take_unsafe_UInt 0#  _  = []
 291 take_unsafe_UInt m   ls =
 292   case ls of
 293     []     -> []
 294     (x:xs) -> x : take_unsafe_UInt (m -# 1#) xs
 295
 296 takeUInt_append :: Int# -> [b] -> [b] -> [b]
 297 takeUInt_append n xs rs
 298   | n >=# 0#  =  take_unsafe_UInt_append n xs rs
 299   | otherwise =  []
 300
 301 take_unsafe_UInt_append :: Int# -> [b] -> [b] -> [b]
 302 take_unsafe_UInt_append 0#  _ rs  = rs
 303 take_unsafe_UInt_append m  ls rs  =
 304   case ls of
 305     []     -> rs
 306     (x:xs) -> x : take_unsafe_UInt_append (m -# 1#) xs rs
 307
 308 drop            :: Int -> [b] -> [b]
 309 drop (I# n#) ls
 310   | n# <# 0#    = []
 311   | otherwise   = drop# n# ls
 312     where
 313         drop# :: Int# -> [a] -> [a]
 314         drop# 0# xs      = xs
 315         drop# _  xs@[]   = xs
 316         drop# m# (_:xs)  = drop# (m# -# 1#) xs
 317
 318 splitAt :: Int -> [b] -> ([b], [b])
 319 splitAt (I# n#) ls
 320   | n# <# 0#    = ([], ls)
 321   | otherwise   = splitAt# n# ls
 322     where
 323         splitAt# :: Int# -> [a] -> ([a], [a])
 324         splitAt# 0# xs     = ([], xs)
 325         splitAt# _  xs@[]  = (xs, xs)
 326         splitAt# m# (x:xs) = (x:xs', xs'')
 327           where
 328             (xs', xs'') = splitAt# (m# -# 1#) xs
 329
 330 #endif /* USE_REPORT_PRELUDE */
 331
 332 span, break             :: (a -> Bool) -> [a] -> ([a],[a])
 333 span _ xs@[]            =  (xs, xs)
 334 span p xs@(x:xs')
 335          | p x          =  let (ys,zs) = span p xs' in (x:ys,zs)
 336          | otherwise    =  ([],xs)
 337
 338 #ifdef USE_REPORT_PRELUDE
 339 break p                 =  span (not . p)
 340 #else
 341 -- HBC version (stolen)
 342 break _ xs@[]           =  (xs, xs)
 343 break p xs@(x:xs')
 344            | p x        =  ([],xs)
 345            | otherwise  =  let (ys,zs) = break p xs' in (x:ys,zs)
 346 #endif
 347
 348 -- reverse xs returns the elements of xs in reverse order.  xs must be finite.
 349 reverse                 :: [a] -> [a]
 350 #ifdef USE_REPORT_PRELUDE
 351 reverse                 =  foldl (flip (:)) []
 352 #else
 353 reverse l =  rev l []
 354   where
 355     rev []     a = a
 356     rev (x:xs) a = rev xs (x:a)
 357 #endif
 358
 359 -- and returns the conjunction of a Boolean list.  For the result to be
 360 -- True, the list must be finite; False, however, results from a False
 361 -- value at a finite index of a finite or infinite list.  or is the
 362 -- disjunctive dual of and.
 363 and, or                 :: [Bool] -> Bool
 364 #ifdef USE_REPORT_PRELUDE
 365 and                     =  foldr (&&) True
 366 or                      =  foldr (||) False
 367 #else
 368 and []          =  True
 369 and (x:xs)      =  x && and xs
 370 or []           =  False
 371 or (x:xs)       =  x || or xs
 372
 373 {-# RULES
 374 "and/build"     forall (g::forall b.(Bool->b->b)->b->b) .
 375                 and (build g) = g (&&) True
 376 "or/build"      forall (g::forall b.(Bool->b->b)->b->b) .
 377                 or (build g) = g (||) False
 378  #-}
 379 #endif
 380
 381 -- Applied to a predicate and a list, any determines if any element
 382 -- of the list satisfies the predicate.  Similarly, for all.
 383 any, all                :: (a -> Bool) -> [a] -> Bool
 384 #ifdef USE_REPORT_PRELUDE
 385 any p                   =  or . map p
 386 all p                   =  and . map p
 387 #else
 388 any _ []        = False
 389 any p (x:xs)    = p x || any p xs
 390
 391 all _ []        =  True
 392 all p (x:xs)    =  p x && all p xs
 393 {-# RULES
 394 "any/build"     forall p (g::forall b.(a->b->b)->b->b) .
 395                 any p (build g) = g ((||) . p) False
 396 "all/build"     forall p (g::forall b.(a->b->b)->b->b) .
 397                 all p (build g) = g ((&&) . p) True
 398  #-}
 399 #endif
 400
 401 -- elem is the list membership predicate, usually written in infix form,
 402 -- e.g., x `elem` xs.  notElem is the negation.
 403 elem, notElem           :: (Eq a) => a -> [a] -> Bool
 404 #ifdef USE_REPORT_PRELUDE
 405 elem x                  =  any (== x)
 406 notElem x               =  all (/= x)
 407 #else
 408 elem _ []       = False
 409 elem x (y:ys)   = x==y || elem x ys
 410
 411 notElem _ []    =  True
 412 notElem x (y:ys)=  x /= y && notElem x ys
 413 #endif
 414
 415 -- lookup key assocs looks up a key in an association list.
 416 lookup                  :: (Eq a) => a -> [(a,b)] -> Maybe b
 417 lookup _key []          =  Nothing
 418 lookup  key ((x,y):xys)
 419     | key == x          =  Just y
 420     | otherwise         =  lookup key xys
 421
 422
 423 -- maximum and minimum return the maximum or minimum value from a list,
 424 -- which must be non-empty, finite, and of an ordered type.
 425 {-# SPECIALISE maximum :: [Int] -> Int #-}
 426 {-# SPECIALISE minimum :: [Int] -> Int #-}
 427 maximum, minimum        :: (Ord a) => [a] -> a
 428 maximum []              =  errorEmptyList "maximum"
 429 maximum xs              =  foldl1 max xs
 430
 431 minimum []              =  errorEmptyList "minimum"
 432 minimum xs              =  foldl1 min xs
 433
 434 concatMap               :: (a -> [b]) -> [a] -> [b]
 435 concatMap f             =  foldr ((++) . f) []
 436
 437 concat :: [[a]] -> [a]
 438 concat = foldr (++) []
 439
 440 {-# RULES
 441   "concat" forall xs. concat xs = build (\c n -> foldr (\x y -> foldr c y x) n xs)
 442  #-}
 443 \end{code}
 444
 445
 446 \begin{code}
 447 -- List index (subscript) operator, 0-origin
 448 (!!)                    :: [a] -> Int -> a
 449 #ifdef USE_REPORT_PRELUDE
 450 (x:_)  !! 0             =  x
 451 (_:xs) !! n | n > 0     =  xs !! (minusInt n 1)
 452 (_:_)  !! _             =  error "Prelude.(!!): negative index"
 453 []     !! _             =  error "Prelude.(!!): index too large"
 454 #else
 455 -- HBC version (stolen), then unboxified
 456 -- The semantics is not quite the same for error conditions
 457 -- in the more efficient version.
 458 --
 459 xs !! (I# n) | n <# 0#   =  error "Prelude.(!!): negative index\n"
 460              | otherwise =  sub xs n
 461                          where
 462                             sub :: [a] -> Int# -> a
 463                             sub []     _ = error "Prelude.(!!): index too large\n"
 464                             sub (y:ys) n = if n ==# 0#
 465                                            then y
 466                                            else sub ys (n -# 1#)
 467 #endif
 468 \end{code}
 469
 470
 471 %*********************************************************
 472 %*                                                      *
 473 \subsection{The zip family}
 474 %*                                                      *
 475 %*********************************************************
 476
 477 \begin{code}
 478 foldr2 _k z []    _ys    = z
 479 foldr2 _k z _xs   []     = z
 480 foldr2 k z (x:xs) (y:ys) = k x y (foldr2 k z xs ys)
 481
 482 foldr2_left _k  z _x _r []     = z
 483 foldr2_left  k _z  x  r (y:ys) = k x y (r ys)
 484
 485 foldr2_right _k z  _y _r []     = z
 486 foldr2_right  k _z  y  r (x:xs) = k x y (r xs)
 487
 488 -- foldr2 k z xs ys = foldr (foldr2_left k z)  (\_ -> z) xs ys
 489 -- foldr2 k z xs ys = foldr (foldr2_right k z) (\_ -> z) ys xs
 490 {-# RULES
 491 "foldr2/left"   forall k z ys (g::forall b.(a->b->b)->b->b) .
 492                   foldr2 k z (build g) ys = g (foldr2_left  k z) (\_ -> z) ys
 493
 494 "foldr2/right"  forall k z xs (g::forall b.(a->b->b)->b->b) .
 495                   foldr2 k z xs (build g) = g (foldr2_right k z) (\_ -> z) xs
 496  #-}
 497 \end{code}
 498
 499 The foldr2/right rule isn't exactly right, because it changes
 500 the strictness of foldr2 (and thereby zip)
 501
 502 E.g. main = print (null (zip nonobviousNil (build undefined)))
 503           where   nonobviousNil = f 3
 504                   f n = if n == 0 then [] else f (n-1)
 505
 506 I'm going to leave it though.
 507
 508
 509 zip takes two lists and returns a list of corresponding pairs.  If one
 510 input list is short, excess elements of the longer list are discarded.
 511 zip3 takes three lists and returns a list of triples.  Zips for larger
 512 tuples are in the List module.
 513
 514 \begin{code}
 515 ----------------------------------------------
 516 zip :: [a] -> [b] -> [(a,b)]
 517 zip = zipList
 518
 519 zipFB c x y r = (x,y) `c` r
 520
 521
 522 zipList               :: [a] -> [b] -> [(a,b)]
 523 zipList (a:as) (b:bs) = (a,b) : zipList as bs
 524 zipList _      _      = []
 525
 526 {-# RULES
 527 "zip"           forall xs ys. zip xs ys = build (\c n -> foldr2 (zipFB c) n xs ys)
 528 "zipList"       foldr2 (zipFB (:)) []   = zipList
 529  #-}
 530 \end{code}
 531
 532 \begin{code}
 533 ----------------------------------------------
 534 zip3 :: [a] -> [b] -> [c] -> [(a,b,c)]
 535 -- Specification
 536 -- zip3 =  zipWith3 (,,)
 537 zip3 (a:as) (b:bs) (c:cs) = (a,b,c) : zip3 as bs cs
 538 zip3 _      _      _      = []
 539 \end{code}
 540
 541
 542 -- The zipWith family generalises the zip family by zipping with the
 543 -- function given as the first argument, instead of a tupling function.
 544 -- For example, zipWith (+) is applied to two lists to produce the list
 545 -- of corresponding sums.
 546
 547
 548 \begin{code}
 549 ----------------------------------------------
 550 zipWith :: (a->b->c) -> [a]->[b]->[c]
 551 zipWith = zipWithList
 552
 553
 554 zipWithFB c f x y r = (x `f` y) `c` r
 555
 556 zipWithList                 :: (a->b->c) -> [a] -> [b] -> [c]
 557 zipWithList f (a:as) (b:bs) = f a b : zipWithList f as bs
 558 zipWithList _ _      _      = []
 559
 560 {-# RULES
 561 "zipWith"       forall f xs ys. zipWith f xs ys = build (\c n -> foldr2 (zipWithFB c f) n xs ys)
 562 "zipWithList"   forall f.       foldr2 (zipWithFB (:) f) [] = zipWithList f
 563   #-}
 564 \end{code}
 565
 566 \begin{code}
 567 zipWith3                :: (a->b->c->d) -> [a]->[b]->[c]->[d]
 568 zipWith3 z (a:as) (b:bs) (c:cs)
 569                         =  z a b c : zipWith3 z as bs cs
 570 zipWith3 _ _ _ _        =  []
 571
 572 -- unzip transforms a list of pairs into a pair of lists.
 573 unzip    :: [(a,b)] -> ([a],[b])
 574 {-# INLINE unzip #-}
 575 unzip    =  foldr (\(a,b) ~(as,bs) -> (a:as,b:bs)) ([],[])
 576
 577 unzip3   :: [(a,b,c)] -> ([a],[b],[c])
 578 {-# INLINE unzip3 #-}
 579 unzip3   =  foldr (\(a,b,c) ~(as,bs,cs) -> (a:as,b:bs,c:cs))
 580                   ([],[],[])
 581 \end{code}
 582
 583
 584 %*********************************************************
 585 %*                                                      *
 586 \subsection{Error code}
 587 %*                                                      *
 588 %*********************************************************
 589
 590 Common up near identical calls to `error' to reduce the number
 591 constant strings created when compiled:
 592
 593 \begin{code}
 594 errorEmptyList :: String -> a
 595 errorEmptyList fun =
 596   error (prel_list_str ++ fun ++ ": empty list")
 597
 598 prel_list_str :: String
 599 prel_list_str = "Prelude."
 600 \end{code}