ghc/lib/std/PrelNum.lhs

   1 % ------------------------------------------------------------------------------
   2 % $Id: PrelNum.lhs,v 1.35 2001/02/22 13:17:59 simonpj Exp $
   3 %
   4 % (c) The University of Glasgow, 1994-2000
   5 %
   6
   7 \section[PrelNum]{Module @PrelNum@}
   8
   9 The class
  10
  11         Num
  12
  13 and the type
  14
  15         Integer
  16
  17
  18 \begin{code}
  19 {-# OPTIONS -fno-implicit-prelude #-}
  20
  21 module PrelNum where
  22
  23 import {-# SOURCE #-} PrelErr
  24 import PrelBase
  25 import PrelList
  26 import PrelEnum
  27 import PrelShow
  28
  29 infixl 7  *
  30 infixl 6  +, -
  31
  32 default ()              -- Double isn't available yet,
  33                         -- and we shouldn't be using defaults anyway
  34 \end{code}
  35
  36 %*********************************************************
  37 %*                                                      *
  38 \subsection{Standard numeric class}
  39 %*                                                      *
  40 %*********************************************************
  41
  42 \begin{code}
  43 class  (Eq a, Show a) => Num a  where
  44     (+), (-), (*)       :: a -> a -> a
  45     negate              :: a -> a
  46     abs, signum         :: a -> a
  47     fromInteger         :: Integer -> a
  48
  49     x - y               = x + negate y
  50     negate x            = 0 - x
  51
  52 fromInt :: Num a => Int -> a
  53 -- For backward compatibility
  54 fromInt (I# i#) = fromInteger (S# i#)
  55 \end{code}
  56
  57 A few small numeric functions
  58
  59 \begin{code}
  60 subtract        :: (Num a) => a -> a -> a
  61 {-# INLINE subtract #-}
  62 subtract x y    =  y - x
  63
  64 ord_0 :: Num a => a
  65 ord_0 = fromInt (ord '0')
  66 \end{code}
  67
  68
  69 %*********************************************************
  70 %*                                                      *
  71 \subsection{Instances for @Int@}
  72 %*                                                      *
  73 %*********************************************************
  74
  75 \begin{code}
  76 instance  Num Int  where
  77     (+)    x y =  plusInt x y
  78     (-)    x y =  minusInt x y
  79     negate x   =  negateInt x
  80     (*)    x y =  timesInt x y
  81     abs    n   = if n `geInt` 0 then n else (negateInt n)
  82
  83     signum n | n `ltInt` 0 = negateInt 1
  84              | n `eqInt` 0 = 0
  85              | otherwise   = 1
  86
  87     fromInteger n = integer2Int n
  88 \end{code}
  89
  90
  91 \begin{code}
  92 -- These can't go in PrelBase with the defn of Int, because
  93 -- we don't have pairs defined at that time!
  94
  95 quotRemInt :: Int -> Int -> (Int, Int)
  96 a@(I# _) `quotRemInt` b@(I# _) = (a `quotInt` b, a `remInt` b)
  97     -- OK, so I made it a little stricter.  Shoot me.  (WDP 94/10)
  98
  99 divModInt ::  Int -> Int -> (Int, Int)
 100 divModInt x@(I# _) y@(I# _) = (x `divInt` y, x `modInt` y)
 101     -- Stricter.  Sorry if you don't like it.  (WDP 94/10)
 102 \end{code}
 103
 104
 105 %*********************************************************
 106 %*                                                      *
 107 \subsection{The @Integer@ type}
 108 %*                                                      *
 109 %*********************************************************
 110
 111 \begin{code}
 112 data Integer
 113    = S# Int#                            -- small integers
 114    | J# Int# ByteArray#                 -- large integers
 115 \end{code}
 116
 117 Convenient boxed Integer PrimOps.
 118
 119 \begin{code}
 120 zeroInteger :: Integer
 121 zeroInteger = S# 0#
 122
 123 int2Integer :: Int -> Integer
 124 {-# INLINE int2Integer #-}
 125 int2Integer (I# i) = S# i
 126
 127 integer2Int :: Integer -> Int
 128 integer2Int (S# i)   = I# i
 129 integer2Int (J# s d) = case (integer2Int# s d) of { n# -> I# n# }
 130
 131 toBig (S# i)     = case int2Integer# i of { (# s, d #) -> J# s d }
 132 toBig i@(J# _ _) = i
 133 \end{code}
 134
 135
 136 %*********************************************************
 137 %*                                                      *
 138 \subsection{Dividing @Integers@}
 139 %*                                                      *
 140 %*********************************************************
 141
 142 \begin{code}
 143 quotRemInteger :: Integer -> Integer -> (Integer, Integer)
 144 quotRemInteger a@(S# (-2147483648#)) b = quotRemInteger (toBig a) b
 145 quotRemInteger (S# i) (S# j)
 146   = case quotRemInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j )
 147 quotRemInteger i1@(J# _ _) i2@(S# _) = quotRemInteger i1 (toBig i2)
 148 quotRemInteger i1@(S# _) i2@(J# _ _) = quotRemInteger (toBig i1) i2
 149 quotRemInteger (J# s1 d1) (J# s2 d2)
 150   = case (quotRemInteger# s1 d1 s2 d2) of
 151           (# s3, d3, s4, d4 #)
 152             -> (J# s3 d3, J# s4 d4)
 153
 154 divModInteger a@(S# (-2147483648#)) b = divModInteger (toBig a) b
 155 divModInteger (S# i) (S# j)
 156   = case divModInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j)
 157 divModInteger i1@(J# _ _) i2@(S# _) = divModInteger i1 (toBig i2)
 158 divModInteger i1@(S# _) i2@(J# _ _) = divModInteger (toBig i1) i2
 159 divModInteger (J# s1 d1) (J# s2 d2)
 160   = case (divModInteger# s1 d1 s2 d2) of
 161           (# s3, d3, s4, d4 #)
 162             -> (J# s3 d3, J# s4 d4)
 163
 164 remInteger :: Integer -> Integer -> Integer
 165 remInteger ia 0
 166   = error "Prelude.Integral.rem{Integer}: divide by 0"
 167 remInteger a@(S# (-2147483648#)) b = remInteger (toBig a) b
 168 remInteger (S# a) (S# b) = S# (remInt# a b)
 169 {- Special case doesn't work, because a 1-element J# has the range
 170    -(2^32-1) -- 2^32-1, whereas S# has the range -2^31 -- (2^31-1)
 171 remInteger ia@(S# a) (J# sb b)
 172   | sb ==# 1#  = S# (remInt# a (word2Int# (integer2Word# sb b)))
 173   | sb ==# -1# = S# (remInt# a (0# -# (word2Int# (integer2Word# sb b))))
 174   | 0# <# sb   = ia
 175   | otherwise  = S# (0# -# a)
 176 -}
 177 remInteger ia@(S# _) ib@(J# _ _) = remInteger (toBig ia) ib
 178 remInteger (J# sa a) (S# b)
 179   = case int2Integer# b of { (# sb, b #) ->
 180     case remInteger# sa a sb b of { (# sr, r #) ->
 181     S# (sr *# (word2Int# (integer2Word# sr r))) }}
 182 remInteger (J# sa a) (J# sb b)
 183   = case remInteger# sa a sb b of (# sr, r #) -> J# sr r
 184
 185 quotInteger :: Integer -> Integer -> Integer
 186 quotInteger ia 0
 187   = error "Prelude.Integral.quot{Integer}: divide by 0"
 188 quotInteger a@(S# (-2147483648#)) b = quotInteger (toBig a) b
 189 quotInteger (S# a) (S# b) = S# (quotInt# a b)
 190 {- Special case disabled, see remInteger above
 191 quotInteger (S# a) (J# sb b)
 192   | sb ==# 1#  = S# (quotInt# a (word2Int# (integer2Word# sb b)))
 193   | sb ==# -1# = S# (quotInt# a (0# -# (word2Int# (integer2Word# sb b))))
 194   | otherwise  = zeroInteger
 195 -}
 196 quotInteger ia@(S# _) ib@(J# _ _) = quotInteger (toBig ia) ib
 197 quotInteger (J# sa a) (S# b)
 198   = case int2Integer# b of { (# sb, b #) ->
 199     case quotInteger# sa a sb b of (# sq, q #) -> J# sq q }
 200 quotInteger (J# sa a) (J# sb b)
 201   = case quotInteger# sa a sb b of (# sg, g #) -> J# sg g
 202 \end{code}
 203
 204
 205
 206 \begin{code}
 207 gcdInteger :: Integer -> Integer -> Integer
 208 -- SUP: Do we really need the first two cases?
 209 gcdInteger a@(S# (-2147483648#)) b = gcdInteger (toBig a) b
 210 gcdInteger a b@(S# (-2147483648#)) = gcdInteger a (toBig b)
 211 gcdInteger (S# a) (S# b) = case gcdInt (I# a) (I# b) of { I# c -> S# c }
 212 gcdInteger ia@(S# 0#) ib@(J# 0# _) = error "PrelNum.gcdInteger: gcd 0 0 is undefined"
 213 gcdInteger ia@(S# a)  ib@(J# sb b)
 214   | a  ==# 0#  = abs ib
 215   | sb ==# 0#  = abs ia
 216   | otherwise  = S# (gcdIntegerInt# absSb b absA)
 217        where absA  = if a  <# 0# then negateInt# a  else a
 218              absSb = if sb <# 0# then negateInt# sb else sb
 219 gcdInteger ia@(J# _ _) ib@(S# _) = gcdInteger ib ia
 220 gcdInteger (J# 0# _) (J# 0# _) = error "PrelNum.gcdInteger: gcd 0 0 is undefined"
 221 gcdInteger (J# sa a) (J# sb b)
 222   = case gcdInteger# sa a sb b of (# sg, g #) -> J# sg g
 223
 224 lcmInteger :: Integer -> Integer -> Integer
 225 lcmInteger a 0
 226   = zeroInteger
 227 lcmInteger 0 b
 228   = zeroInteger
 229 lcmInteger a b
 230   = (divExact aa (gcdInteger aa ab)) * ab
 231   where aa = abs a
 232         ab = abs b
 233
 234 divExact :: Integer -> Integer -> Integer
 235 divExact a@(S# (-2147483648#)) b = divExact (toBig a) b
 236 divExact (S# a) (S# b) = S# (quotInt# a b)
 237 divExact (S# a) (J# sb b)
 238   = S# (quotInt# a (sb *# (word2Int# (integer2Word# sb b))))
 239 divExact (J# sa a) (S# b)
 240   = case int2Integer# b of
 241      (# sb, b #) -> case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 242 divExact (J# sa a) (J# sb b)
 243   = case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 244 \end{code}
 245
 246
 247 %*********************************************************
 248 %*                                                      *
 249 \subsection{The @Integer@ instances for @Eq@, @Ord@}
 250 %*                                                      *
 251 %*********************************************************
 252
 253 \begin{code}
 254 instance  Eq Integer  where
 255     (S# i)     ==  (S# j)     = i ==# j
 256     (S# i)     ==  (J# s d)   = cmpIntegerInt# s d i ==# 0#
 257     (J# s d)   ==  (S# i)     = cmpIntegerInt# s d i ==# 0#
 258     (J# s1 d1) ==  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ==# 0#
 259
 260     (S# i)     /=  (S# j)     = i /=# j
 261     (S# i)     /=  (J# s d)   = cmpIntegerInt# s d i /=# 0#
 262     (J# s d)   /=  (S# i)     = cmpIntegerInt# s d i /=# 0#
 263     (J# s1 d1) /=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) /=# 0#
 264
 265 ------------------------------------------------------------------------
 266 instance  Ord Integer  where
 267     (S# i)     <=  (S# j)     = i <=# j
 268     (J# s d)   <=  (S# i)     = cmpIntegerInt# s d i <=# 0#
 269     (S# i)     <=  (J# s d)   = cmpIntegerInt# s d i >=# 0#
 270     (J# s1 d1) <=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <=# 0#
 271
 272     (S# i)     >   (S# j)     = i ># j
 273     (J# s d)   >   (S# i)     = cmpIntegerInt# s d i ># 0#
 274     (S# i)     >   (J# s d)   = cmpIntegerInt# s d i <# 0#
 275     (J# s1 d1) >   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ># 0#
 276
 277     (S# i)     <   (S# j)     = i <# j
 278     (J# s d)   <   (S# i)     = cmpIntegerInt# s d i <# 0#
 279     (S# i)     <   (J# s d)   = cmpIntegerInt# s d i ># 0#
 280     (J# s1 d1) <   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <# 0#
 281
 282     (S# i)     >=  (S# j)     = i >=# j
 283     (J# s d)   >=  (S# i)     = cmpIntegerInt# s d i >=# 0#
 284     (S# i)     >=  (J# s d)   = cmpIntegerInt# s d i <=# 0#
 285     (J# s1 d1) >=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) >=# 0#
 286
 287     compare (S# i)  (S# j)
 288        | i ==# j = EQ
 289        | i <=# j = LT
 290        | otherwise = GT
 291     compare (J# s d) (S# i)
 292        = case cmpIntegerInt# s d i of { res# ->
 293          if res# <# 0# then LT else
 294          if res# ># 0# then GT else EQ
 295          }
 296     compare (S# i) (J# s d)
 297        = case cmpIntegerInt# s d i of { res# ->
 298          if res# ># 0# then LT else
 299          if res# <# 0# then GT else EQ
 300          }
 301     compare (J# s1 d1) (J# s2 d2)
 302        = case cmpInteger# s1 d1 s2 d2 of { res# ->
 303          if res# <# 0# then LT else
 304          if res# ># 0# then GT else EQ
 305          }
 306 \end{code}
 307
 308
 309 %*********************************************************
 310 %*                                                      *
 311 \subsection{The @Integer@ instances for @Num@}
 312 %*                                                      *
 313 %*********************************************************
 314
 315 \begin{code}
 316 instance  Num Integer  where
 317     (+) = plusInteger
 318     (-) = minusInteger
 319     (*) = timesInteger
 320     negate         = negateInteger
 321     fromInteger x  =  x
 322
 323     -- ORIG: abs n = if n >= 0 then n else -n
 324     abs (S# (-2147483648#)) = 2147483648
 325     abs (S# i) = case abs (I# i) of I# j -> S# j
 326     abs n@(J# s d) = if (s >=# 0#) then n else J# (negateInt# s) d
 327
 328     signum (S# i) = case signum (I# i) of I# j -> S# j
 329     signum (J# s d)
 330       = let
 331             cmp = cmpIntegerInt# s d 0#
 332         in
 333         if      cmp >#  0# then S# 1#
 334         else if cmp ==# 0# then S# 0#
 335         else                    S# (negateInt# 1#)
 336
 337 plusInteger i1@(S# i) i2@(S# j)  = case addIntC# i j of { (# r, c #) ->
 338                                    if c ==# 0# then S# r
 339                                    else toBig i1 + toBig i2 }
 340 plusInteger i1@(J# _ _) i2@(S# _) = i1 + toBig i2
 341 plusInteger i1@(S# _) i2@(J# _ _) = toBig i1 + i2
 342 plusInteger (J# s1 d1) (J# s2 d2) = case plusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 343
 344 minusInteger i1@(S# i) i2@(S# j)   = case subIntC# i j of { (# r, c #) ->
 345                                      if c ==# 0# then S# r
 346                                      else toBig i1 - toBig i2 }
 347 minusInteger i1@(J# _ _) i2@(S# _) = i1 - toBig i2
 348 minusInteger i1@(S# _) i2@(J# _ _) = toBig i1 - i2
 349 minusInteger (J# s1 d1) (J# s2 d2) = case minusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 350
 351 timesInteger i1@(S# i) i2@(S# j)   = case mulIntC# i j of { (# r, c #) ->
 352                                      if c ==# 0# then S# r
 353                                      else toBig i1 * toBig i2 }
 354 timesInteger i1@(J# _ _) i2@(S# _) = i1 * toBig i2
 355 timesInteger i1@(S# _) i2@(J# _ _) = toBig i1 * i2
 356 timesInteger (J# s1 d1) (J# s2 d2) = case timesInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 357
 358 negateInteger (S# (-2147483648#)) = 2147483648
 359 negateInteger (S# i)              = S# (negateInt# i)
 360 negateInteger (J# s d)            = J# (negateInt# s) d
 361 \end{code}
 362
 363
 364 %*********************************************************
 365 %*                                                      *
 366 \subsection{The @Integer@ instance for @Enum@}
 367 %*                                                      *
 368 %*********************************************************
 369
 370 \begin{code}
 371 instance  Enum Integer  where
 372     succ x               = x + 1
 373     pred x               = x - 1
 374     toEnum n             = int2Integer n
 375     fromEnum n           = integer2Int n
 376
 377     {-# INLINE enumFrom #-}
 378     {-# INLINE enumFromThen #-}
 379     {-# INLINE enumFromTo #-}
 380     {-# INLINE enumFromThenTo #-}
 381     enumFrom x             = efdInteger  x 1
 382     enumFromThen x y       = efdInteger  x (y-x)
 383     enumFromTo x lim       = efdtInteger x 1     lim
 384     enumFromThenTo x y lim = efdtInteger x (y-x) lim
 385
 386
 387 efdInteger  = enumDeltaIntegerList
 388 efdtInteger = enumDeltaToIntegerList
 389
 390 {-# RULES
 391 "efdInteger"            forall x y.  efdInteger x y         = build (\c _ -> enumDeltaIntegerFB c x y)
 392 "efdtInteger"           forall x y l.efdtInteger x y l      = build (\c n -> enumDeltaToIntegerFB c n x y l)
 393 "enumDeltaInteger"      enumDeltaIntegerFB   (:)    = enumDeltaIntegerList
 394 "enumDeltaToInteger"    enumDeltaToIntegerFB (:) [] = enumDeltaToIntegerList
 395  #-}
 396
 397 enumDeltaIntegerFB :: (Integer -> b -> b) -> Integer -> Integer -> b
 398 enumDeltaIntegerFB c x d = x `c` enumDeltaIntegerFB c (x+d) d
 399
 400 enumDeltaIntegerList :: Integer -> Integer -> [Integer]
 401 enumDeltaIntegerList x d = x : enumDeltaIntegerList (x+d) d
 402
 403 enumDeltaToIntegerFB c n x delta lim
 404   | delta >= 0 = up_fb c n x delta lim
 405   | otherwise  = dn_fb c n x delta lim
 406
 407 enumDeltaToIntegerList x delta lim
 408   | delta >= 0 = up_list x delta lim
 409   | otherwise  = dn_list x delta lim
 410
 411 up_fb c n x delta lim = go (x::Integer)
 412                       where
 413                         go x | x > lim   = n
 414                              | otherwise = x `c` go (x+delta)
 415 dn_fb c n x delta lim = go (x::Integer)
 416                       where
 417                         go x | x < lim   = n
 418                              | otherwise = x `c` go (x+delta)
 419
 420 up_list x delta lim = go (x::Integer)
 421                     where
 422                         go x | x > lim   = []
 423                              | otherwise = x : go (x+delta)
 424 dn_list x delta lim = go (x::Integer)
 425                     where
 426                         go x | x < lim   = []
 427                              | otherwise = x : go (x+delta)
 428
 429 \end{code}
 430
 431
 432 %*********************************************************
 433 %*                                                      *
 434 \subsection{The @Integer@ instances for @Show@}
 435 %*                                                      *
 436 %*********************************************************
 437
 438 \begin{code}
 439 instance  Show Integer  where
 440     showsPrec   x = showSignedInteger x
 441     showList = showList__ (showsPrec 0)
 442
 443 showSignedInteger :: Int -> Integer -> ShowS
 444 showSignedInteger p n r
 445   | n < 0 && p > 6 = '(':jtos n (')':r)
 446   | otherwise      = jtos n r
 447
 448 jtos :: Integer -> String -> String
 449 jtos i rs
 450  | i < 0     = '-' : jtos' (-i) rs
 451  | otherwise = jtos' i rs
 452  where
 453   jtos' :: Integer -> String -> String
 454   jtos' n cs
 455    | n < 10    = chr (fromInteger n + (ord_0::Int)) : cs
 456    | otherwise = jtos' q (chr (integer2Int r + (ord_0::Int)) : cs)
 457     where
 458      (q,r) = n `quotRemInteger` 10
 459 \end{code}