ghc/lib/std/PrelNum.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1994-1996
   3 %
   4
   5 \section[PrelNum]{Module @PrelNum@}
   6
   7 The class
   8
   9         Num
  10
  11 and the type
  12
  13         Integer
  14
  15
  16 \begin{code}
  17 {-# OPTIONS -fno-implicit-prelude #-}
  18
  19 module PrelNum where
  20
  21 import {-# SOURCE #-} PrelErr
  22 import PrelBase
  23 import PrelList
  24 import PrelEnum
  25 import PrelShow
  26
  27 infixl 7  *
  28 infixl 6  +, -
  29
  30 default ()              -- Double isn't available yet,
  31                         -- and we shouldn't be using defaults anyway
  32 \end{code}
  33
  34 %*********************************************************
  35 %*                                                      *
  36 \subsection{Standard numeric class}
  37 %*                                                      *
  38 %*********************************************************
  39
  40 \begin{code}
  41 class  (Eq a, Show a) => Num a  where
  42     (+), (-), (*)       :: a -> a -> a
  43     negate              :: a -> a
  44     abs, signum         :: a -> a
  45     fromInteger         :: Integer -> a
  46     fromInt             :: Int -> a -- partain: Glasgow extension
  47
  48     x - y               = x + negate y
  49     negate x            = 0 - x
  50     fromInt (I# i#)     = fromInteger (S# i#)
  51                                         -- Go via the standard class-op if the
  52                                         -- non-standard one ain't provided
  53 \end{code}
  54
  55 A few small numeric functions
  56
  57 \begin{code}
  58 subtract        :: (Num a) => a -> a -> a
  59 {-# INLINE subtract #-}
  60 subtract x y    =  y - x
  61
  62 ord_0 :: Num a => a
  63 ord_0 = fromInt (ord '0')
  64 \end{code}
  65
  66
  67 %*********************************************************
  68 %*                                                      *
  69 \subsection{Instances for @Int@}
  70 %*                                                      *
  71 %*********************************************************
  72
  73 \begin{code}
  74 instance  Num Int  where
  75     (+)    x y =  plusInt x y
  76     (-)    x y =  minusInt x y
  77     negate x   =  negateInt x
  78     (*)    x y =  timesInt x y
  79     abs    n   = if n `geInt` 0 then n else (negateInt n)
  80
  81     signum n | n `ltInt` 0 = negateInt 1
  82              | n `eqInt` 0 = 0
  83              | otherwise   = 1
  84
  85     fromInteger n = integer2Int n
  86     fromInt n     = n
  87 \end{code}
  88
  89
  90 \begin{code}
  91 -- These can't go in PrelBase with the defn of Int, because
  92 -- we don't have pairs defined at that time!
  93
  94 quotRemInt :: Int -> Int -> (Int, Int)
  95 a@(I# _) `quotRemInt` b@(I# _) = (a `quotInt` b, a `remInt` b)
  96     -- OK, so I made it a little stricter.  Shoot me.  (WDP 94/10)
  97
  98 divModInt ::  Int -> Int -> (Int, Int)
  99 divModInt x@(I# _) y@(I# _) = (x `divInt` y, x `modInt` y)
 100     -- Stricter.  Sorry if you don't like it.  (WDP 94/10)
 101 \end{code}
 102
 103
 104 %*********************************************************
 105 %*                                                      *
 106 \subsection{The @Integer@ type}
 107 %*                                                      *
 108 %*********************************************************
 109
 110 \begin{code}
 111 data Integer
 112    = S# Int#                            -- small integers
 113    | J# Int# ByteArray#                 -- large integers
 114 \end{code}
 115
 116 Convenient boxed Integer PrimOps.
 117
 118 \begin{code}
 119 zeroInteger :: Integer
 120 zeroInteger = S# 0#
 121
 122 int2Integer :: Int -> Integer
 123 {-# INLINE int2Integer #-}
 124 int2Integer (I# i) = S# i
 125
 126 integer2Int :: Integer -> Int
 127 integer2Int (S# i)   = I# i
 128 integer2Int (J# s d) = case (integer2Int# s d) of { n# -> I# n# }
 129
 130 addr2Integer :: Addr# -> Integer
 131 {-# INLINE addr2Integer #-}
 132 addr2Integer x = case addr2Integer# x of (# s, d #) -> J# s d
 133
 134 toBig (S# i)     = case int2Integer# i of { (# s, d #) -> J# s d }
 135 toBig i@(J# _ _) = i
 136 \end{code}
 137
 138
 139 %*********************************************************
 140 %*                                                      *
 141 \subsection{Dividing @Integers@}
 142 %*                                                      *
 143 %*********************************************************
 144
 145 \begin{code}
 146 quotRemInteger :: Integer -> Integer -> (Integer, Integer)
 147 quotRemInteger a@(S# (-2147483648#)) b = quotRemInteger (toBig a) b
 148 quotRemInteger (S# i) (S# j)
 149   = case quotRemInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j )
 150 quotRemInteger i1@(J# _ _) i2@(S# _) = quotRemInteger i1 (toBig i2)
 151 quotRemInteger i1@(S# _) i2@(J# _ _) = quotRemInteger (toBig i1) i2
 152 quotRemInteger (J# s1 d1) (J# s2 d2)
 153   = case (quotRemInteger# s1 d1 s2 d2) of
 154           (# s3, d3, s4, d4 #)
 155             -> (J# s3 d3, J# s4 d4)
 156
 157 divModInteger a@(S# (-2147483648#)) b = divModInteger (toBig a) b
 158 divModInteger (S# i) (S# j)
 159   = case divModInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j)
 160 divModInteger i1@(J# _ _) i2@(S# _) = divModInteger i1 (toBig i2)
 161 divModInteger i1@(S# _) i2@(J# _ _) = divModInteger (toBig i1) i2
 162 divModInteger (J# s1 d1) (J# s2 d2)
 163   = case (divModInteger# s1 d1 s2 d2) of
 164           (# s3, d3, s4, d4 #)
 165             -> (J# s3 d3, J# s4 d4)
 166
 167 remInteger :: Integer -> Integer -> Integer
 168 remInteger ia 0
 169   = error "Prelude.Integral.rem{Integer}: divide by 0"
 170 remInteger a@(S# (-2147483648#)) b = remInteger (toBig a) b
 171 remInteger (S# a) (S# b) = S# (remInt# a b)
 172 remInteger ia@(S# a) (J# sb b)
 173   | sb ==# 1#  = S# (remInt# a (word2Int# (integer2Word# sb b)))
 174   | sb ==# -1# = S# (remInt# a (0# -# (word2Int# (integer2Word# sb b))))
 175   | 0# <# sb   = ia
 176   | otherwise  = S# (0# -# a)
 177 remInteger (J# sa a) (S# b)
 178   = case int2Integer# b of { (# sb, b #) ->
 179     case remInteger# sa a sb b of { (# sr, r #) ->
 180     S# (sr *# (word2Int# (integer2Word# sr r))) }}
 181 remInteger (J# sa a) (J# sb b)
 182   = case remInteger# sa a sb b of (# sr, r #) -> J# sr r
 183
 184 quotInteger :: Integer -> Integer -> Integer
 185 quotInteger ia 0
 186   = error "Prelude.Integral.quot{Integer}: divide by 0"
 187 quotInteger a@(S# (-2147483648#)) b = quotInteger (toBig a) b
 188 quotInteger (S# a) (S# b) = S# (quotInt# a b)
 189 quotInteger (S# a) (J# sb b)
 190   | sb ==# 1#  = S# (quotInt# a (word2Int# (integer2Word# sb b)))
 191   | sb ==# -1# = S# (quotInt# a (0# -# (word2Int# (integer2Word# sb b))))
 192   | otherwise  = zeroInteger
 193 quotInteger (J# sa a) (S# b)
 194   = case int2Integer# b of { (# sb, b #) ->
 195     case quotInteger# sa a sb b of (# sq, q #) -> J# sq q }
 196 quotInteger (J# sa a) (J# sb b)
 197   = case quotInteger# sa a sb b of (# sg, g #) -> J# sg g
 198 \end{code}
 199
 200
 201
 202 \begin{code}
 203 gcdInteger :: Integer -> Integer -> Integer
 204 gcdInteger a@(S# (-2147483648#)) b = gcdInteger (toBig a) b
 205 gcdInteger a b@(S# (-2147483648#)) = gcdInteger a (toBig b)
 206 gcdInteger (S# a) (S# b) = S# (gcdInt# a b)
 207 gcdInteger ia@(S# a) ib@(J# sb b)
 208   | a  ==# 0#  = abs ib
 209   | sb ==# 0#  = abs ia
 210   | otherwise  = S# (gcdIntegerInt# sb b a)
 211 gcdInteger ia@(J# sa a) ib@(S# b)
 212   | sa ==# 0#  = abs ib
 213   | b ==# 0#   = abs ia
 214   | otherwise  = S# (gcdIntegerInt# sa a b)
 215 gcdInteger (J# sa a) (J# sb b)
 216   = case gcdInteger# sa a sb b of (# sg, g #) -> J# sg g
 217
 218 lcmInteger :: Integer -> Integer -> Integer
 219 lcmInteger a 0
 220   = zeroInteger
 221 lcmInteger 0 b
 222   = zeroInteger
 223 lcmInteger a b
 224   = (divExact aa (gcdInteger aa ab)) * ab
 225   where aa = abs a
 226         ab = abs b
 227
 228 divExact :: Integer -> Integer -> Integer
 229 divExact a@(S# (-2147483648#)) b = divExact (toBig a) b
 230 divExact (S# a) (S# b) = S# (quotInt# a b)
 231 divExact (S# a) (J# sb b)
 232   = S# (quotInt# a (sb *# (word2Int# (integer2Word# sb b))))
 233 divExact (J# sa a) (S# b)
 234   = case int2Integer# b of
 235      (# sb, b #) -> case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 236 divExact (J# sa a) (J# sb b)
 237   = case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 238 \end{code}
 239
 240
 241 %*********************************************************
 242 %*                                                      *
 243 \subsection{The @Integer@ instances for @Eq@, @Ord@}
 244 %*                                                      *
 245 %*********************************************************
 246
 247 \begin{code}
 248 instance  Eq Integer  where
 249     (S# i)     ==  (S# j)     = i ==# j
 250     (S# i)     ==  (J# s d)   = cmpIntegerInt# s d i ==# 0#
 251     (J# s d)   ==  (S# i)     = cmpIntegerInt# s d i ==# 0#
 252     (J# s1 d1) ==  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ==# 0#
 253
 254     (S# i)     /=  (S# j)     = i /=# j
 255     (S# i)     /=  (J# s d)   = cmpIntegerInt# s d i /=# 0#
 256     (J# s d)   /=  (S# i)     = cmpIntegerInt# s d i /=# 0#
 257     (J# s1 d1) /=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) /=# 0#
 258
 259 ------------------------------------------------------------------------
 260 instance  Ord Integer  where
 261     (S# i)     <=  (S# j)     = i <=# j
 262     (J# s d)   <=  (S# i)     = cmpIntegerInt# s d i <=# 0#
 263     (S# i)     <=  (J# s d)   = cmpIntegerInt# s d i >=# 0#
 264     (J# s1 d1) <=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <=# 0#
 265
 266     (S# i)     >   (S# j)     = i ># j
 267     (J# s d)   >   (S# i)     = cmpIntegerInt# s d i ># 0#
 268     (S# i)     >   (J# s d)   = cmpIntegerInt# s d i <# 0#
 269     (J# s1 d1) >   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ># 0#
 270
 271     (S# i)     <   (S# j)     = i <# j
 272     (J# s d)   <   (S# i)     = cmpIntegerInt# s d i <# 0#
 273     (S# i)     <   (J# s d)   = cmpIntegerInt# s d i ># 0#
 274     (J# s1 d1) <   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <# 0#
 275
 276     (S# i)     >=  (S# j)     = i >=# j
 277     (J# s d)   >=  (S# i)     = cmpIntegerInt# s d i >=# 0#
 278     (S# i)     >=  (J# s d)   = cmpIntegerInt# s d i <=# 0#
 279     (J# s1 d1) >=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) >=# 0#
 280
 281     compare (S# i)  (S# j)
 282        | i ==# j = EQ
 283        | i <=# j = LT
 284        | otherwise = GT
 285     compare (J# s d) (S# i)
 286        = case cmpIntegerInt# s d i of { res# ->
 287          if res# <# 0# then LT else
 288          if res# ># 0# then GT else EQ
 289          }
 290     compare (S# i) (J# s d)
 291        = case cmpIntegerInt# s d i of { res# ->
 292          if res# ># 0# then LT else
 293          if res# <# 0# then GT else EQ
 294          }
 295     compare (J# s1 d1) (J# s2 d2)
 296        = case cmpInteger# s1 d1 s2 d2 of { res# ->
 297          if res# <# 0# then LT else
 298          if res# ># 0# then GT else EQ
 299          }
 300 \end{code}
 301
 302
 303 %*********************************************************
 304 %*                                                      *
 305 \subsection{The @Integer@ instances for @Num@}
 306 %*                                                      *
 307 %*********************************************************
 308
 309 \begin{code}
 310 instance  Num Integer  where
 311     (+) i1@(S# i) i2@(S# j)
 312         = case addIntC# i j of { (# r, c #) ->
 313           if c ==# 0# then S# r
 314           else toBig i1 + toBig i2 }
 315     (+) i1@(J# _ _) i2@(S# _)   = i1 + toBig i2
 316     (+) i1@(S# _) i2@(J# _ _)   = toBig i1 + i2
 317     (+) (J# s1 d1) (J# s2 d2)
 318       = case plusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 319
 320     (-) i1@(S# i) i2@(S# j)
 321         = case subIntC# i j of { (# r, c #) ->
 322           if c ==# 0# then S# r
 323           else toBig i1 - toBig i2 }
 324     (-) i1@(J# _ _) i2@(S# _)   = i1 - toBig i2
 325     (-) i1@(S# _) i2@(J# _ _)   = toBig i1 - i2
 326     (-) (J# s1 d1) (J# s2 d2)
 327       = case minusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 328
 329     (*) i1@(S# i) i2@(S# j)
 330         = case mulIntC# i j of { (# r, c #) ->
 331           if c ==# 0# then S# r
 332           else toBig i1 * toBig i2 }
 333     (*) i1@(J# _ _) i2@(S# _)   = i1 * toBig i2
 334     (*) i1@(S# _) i2@(J# _ _)   = toBig i1 * i2
 335     (*) (J# s1 d1) (J# s2 d2)
 336       = case timesInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 337
 338     negate (S# (-2147483648#)) = 2147483648
 339     negate (S# i) = S# (negateInt# i)
 340     negate (J# s d) = J# (negateInt# s) d
 341
 342     -- ORIG: abs n = if n >= 0 then n else -n
 343
 344     abs (S# (-2147483648#)) = 2147483648
 345     abs (S# i) = case abs (I# i) of I# j -> S# j
 346     abs n@(J# s d) = if (s >=# 0#) then n else J# (negateInt# s) d
 347
 348     signum (S# i) = case signum (I# i) of I# j -> S# j
 349     signum (J# s d)
 350       = let
 351             cmp = cmpIntegerInt# s d 0#
 352         in
 353         if      cmp >#  0# then S# 1#
 354         else if cmp ==# 0# then S# 0#
 355         else                    S# (negateInt# 1#)
 356
 357     fromInteger x       =  x
 358
 359     fromInt (I# i)      =  S# i
 360 \end{code}
 361
 362
 363 %*********************************************************
 364 %*                                                      *
 365 \subsection{The @Integer@ instance for @Enum@}
 366 %*                                                      *
 367 %*********************************************************
 368
 369 \begin{code}
 370 instance  Enum Integer  where
 371     succ x               = x + 1
 372     pred x               = x - 1
 373     toEnum n             = int2Integer n
 374     fromEnum n           = integer2Int n
 375
 376     {-# INLINE enumFrom #-}
 377     {-# INLINE enumFromThen #-}
 378     {-# INLINE enumFromTo #-}
 379     {-# INLINE enumFromThenTo #-}
 380     enumFrom x             = build (\c _ -> enumDeltaIntegerFB   c   x 1)
 381     enumFromThen x y       = build (\c _ -> enumDeltaIntegerFB   c   x (y-x))
 382     enumFromTo x lim       = build (\c n -> enumDeltaToIntegerFB c n x 1     lim)
 383     enumFromThenTo x y lim = build (\c n -> enumDeltaToIntegerFB c n x (y-x) lim)
 384
 385 enumDeltaIntegerFB :: (Integer -> b -> b) -> Integer -> Integer -> b
 386 enumDeltaIntegerFB c x d = x `c` enumDeltaIntegerFB c (x+d) d
 387
 388 enumDeltaIntegerList :: Integer -> Integer -> [Integer]
 389 enumDeltaIntegerList x d = x : enumDeltaIntegerList (x+d) d
 390
 391 enumDeltaToIntegerFB c n x delta lim
 392   | delta >= 0 = up_fb c n x delta lim
 393   | otherwise  = dn_fb c n x delta lim
 394
 395 enumDeltaToIntegerList x delta lim
 396   | delta >= 0 = up_list x delta lim
 397   | otherwise  = dn_list x delta lim
 398
 399 up_fb c n x delta lim = go (x::Integer)
 400                       where
 401                         go x | x > lim   = n
 402                              | otherwise = x `c` go (x+delta)
 403 dn_fb c n x delta lim = go (x::Integer)
 404                       where
 405                         go x | x < lim   = n
 406                              | otherwise = x `c` go (x+delta)
 407
 408 up_list x delta lim = go (x::Integer)
 409                     where
 410                         go x | x > lim   = []
 411                              | otherwise = x : go (x+delta)
 412 dn_list x delta lim = go (x::Integer)
 413                     where
 414                         go x | x < lim   = []
 415                              | otherwise = x : go (x+delta)
 416
 417 {-# RULES
 418 "enumDeltaInteger"      enumDeltaIntegerFB   (:)    = enumDeltaIntegerList
 419 "enumDeltaToInteger"    enumDeltaToIntegerFB (:) [] = enumDeltaToIntegerList
 420  #-}
 421 \end{code}
 422
 423
 424 %*********************************************************
 425 %*                                                      *
 426 \subsection{The @Integer@ instances for @Show@}
 427 %*                                                      *
 428 %*********************************************************
 429
 430 \begin{code}
 431 instance  Show Integer  where
 432     showsPrec   x = showSignedInteger x
 433     showList = showList__ (showsPrec 0)
 434
 435 showSignedInteger :: Int -> Integer -> ShowS
 436 showSignedInteger p n r
 437   | n < 0 && p > 6 = '(':jtos n (')':r)
 438   | otherwise      = jtos n r
 439
 440 jtos :: Integer -> String -> String
 441 jtos i rs
 442  | i < 0     = '-' : jtos' (-i) rs
 443  | otherwise = jtos' i rs
 444  where
 445   jtos' :: Integer -> String -> String
 446   jtos' n cs
 447    | n < 10    = chr (fromInteger n + (ord_0::Int)) : cs
 448    | otherwise = jtos' q (chr (integer2Int r + (ord_0::Int)) : cs)
 449     where
 450      (q,r) = n `quotRemInteger` 10
 451 \end{code}