ghc/rts/gmp/mpn/powerpc32/add_n.s

   1 # PowerPC-32 __mpn_add_n -- Add two limb vectors of equal, non-zero length.
   2
   3 # Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
   4
   5 # This file is part of the GNU MP Library.
   6
   7 # The GNU MP Library is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU Library General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or (at your
  10 # option) any later version.
  11
  12 # The GNU MP Library is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  15 # License for more details.
  16
  17 # You should have received a copy of the GNU Library General Public License
  18 # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 # the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20 # MA 02111-1307, USA.
  21
  22
  23 # INPUT PARAMETERS
  24 # res_ptr       r3
  25 # s1_ptr        r4
  26 # s2_ptr        r5
  27 # size          r6
  28
  29         .toc
  30         .extern __mpn_add_n[DS]
  31         .extern .__mpn_add_n
  32 .csect [PR]
  33         .align 2
  34         .globl __mpn_add_n
  35         .globl .__mpn_add_n
  36         .csect __mpn_add_n[DS]
  37 __mpn_add_n:
  38         .long .__mpn_add_n, TOC[tc0], 0
  39         .csect [PR]
  40 .__mpn_add_n:
  41         mtctr   6               # copy size into CTR
  42         lwz     8,0(4)          # load least significant s1 limb
  43         lwz     0,0(5)          # load least significant s2 limb
  44         addi    3,3,-4          # offset res_ptr, it's updated before used
  45         addc    7,0,8           # add least significant limbs, set cy
  46         bdz     Lend            # If done, skip loop
  47 Loop:   lwzu    8,4(4)          # load s1 limb and update s1_ptr
  48         lwzu    0,4(5)          # load s2 limb and update s2_ptr
  49         stwu    7,4(3)          # store previous limb in load latency slot
  50         adde    7,0,8           # add new limbs with cy, set cy
  51         bdnz    Loop            # decrement CTR and loop back
  52 Lend:   stw     7,4(3)          # store ultimate result limb
  53         li      3,0             # load cy into ...
  54         addze   3,3             # ... return value register
  55         blr