ghc/rts/gmp/mpn/sparc32/v8/submul_1.S

   1 ! SPARC v8 __mpn_submul_1 -- Multiply a limb vector with a limb and
   2 ! subtract the result from a second limb vector.
   3
   4 ! Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
   5
   6 ! This file is part of the GNU MP Library.
   7
   8 ! The GNU MP Library is free software; you can redistribute it and/or modify
   9 ! it under the terms of the GNU Library General Public License as published by
  10 ! the Free Software Foundation; either version 2 of the License, or (at your
  11 ! option) any later version.
  12
  13 ! The GNU MP Library is distributed in the hope that it will be useful, but
  14 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  16 ! License for more details.
  17
  18 ! You should have received a copy of the GNU Library General Public License
  19 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 ! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 ! MA 02111-1307, USA.
  22
  23
  24 ! INPUT PARAMETERS
  25 ! res_ptr       o0
  26 ! s1_ptr        o1
  27 ! size          o2
  28 ! s2_limb       o3
  29
  30 #include "sysdep.h"
  31
  32 .text
  33         .align 4
  34         .global C_SYMBOL_NAME(__mpn_submul_1)
  35 C_SYMBOL_NAME(__mpn_submul_1):
  36         sub     %g0,%o2,%o2             ! negate ...
  37         sll     %o2,2,%o2               ! ... and scale size
  38         sub     %o1,%o2,%o1             ! o1 is offset s1_ptr
  39         sub     %o0,%o2,%g1             ! g1 is offset res_ptr
  40
  41         mov     0,%o0                   ! clear cy_limb
  42
  43 Loop:   ld      [%o1+%o2],%o4
  44         ld      [%g1+%o2],%g2
  45         umul    %o4,%o3,%o5
  46         rd      %y,%g3
  47         addcc   %o5,%o0,%o5
  48         addx    %g3,0,%o0
  49         subcc   %g2,%o5,%g2
  50         addx    %o0,0,%o0
  51         st      %g2,[%g1+%o2]
  52
  53         addcc   %o2,4,%o2
  54         bne     Loop
  55          nop
  56
  57         retl
  58          nop