ghc/rts/gmp/mpn/sparc64/lshift.s

   1 ! SPARC v9 __mpn_lshift --
   2
   3 ! Copyright (C) 1996 Free Software Foundation, Inc.
   4
   5 ! This file is part of the GNU MP Library.
   6
   7 ! The GNU MP Library is free software; you can redistribute it and/or modify
   8 ! it under the terms of the GNU Library General Public License as published by
   9 ! the Free Software Foundation; either version 2 of the License, or (at your
  10 ! option) any later version.
  11
  12 ! The GNU MP Library is distributed in the hope that it will be useful, but
  13 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  15 ! License for more details.
  16
  17 ! You should have received a copy of the GNU Library General Public License
  18 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 ! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20 ! MA 02111-1307, USA.
  21
  22
  23 ! INPUT PARAMETERS
  24 ! res_ptr       %o0
  25 ! src_ptr       %o1
  26 ! size          %o2
  27 ! cnt           %o3
  28
  29 .section        ".text"
  30         .align 4
  31         .global __mpn_lshift
  32         .type    __mpn_lshift,#function
  33         .proc   04
  34 __mpn_lshift:
  35         sllx    %o2,3,%g1
  36         add     %o1,%g1,%o1     ! make %o1 point at end of src
  37         ldx     [%o1-8],%g2     ! load first limb
  38         sub     %g0,%o3,%o5     ! negate shift count
  39         add     %o0,%g1,%o0     ! make %o0 point at end of res
  40         add     %o2,-1,%o2
  41         and     %o2,4-1,%g4     ! number of limbs in first loop
  42         srlx    %g2,%o5,%g1     ! compute function result
  43         brz,pn  %g4,.L0         ! if multiple of 4 limbs, skip first loop
  44         stx     %g1,[%sp+80]
  45
  46         sub     %o2,%g4,%o2     ! adjust count for main loop
  47
  48 .Loop0: ldx     [%o1-16],%g3
  49         add     %o0,-8,%o0
  50         add     %o1,-8,%o1
  51         add     %g4,-1,%g4
  52         sllx    %g2,%o3,%o4
  53         srlx    %g3,%o5,%g1
  54         mov     %g3,%g2
  55         or      %o4,%g1,%o4
  56         brnz,pt %g4,.Loop0
  57          stx    %o4,[%o0+0]
  58
  59 .L0:    brz,pn  %o2,.Lend
  60          nop
  61
  62 .Loop:  ldx     [%o1-16],%g3
  63         add     %o0,-32,%o0
  64         add     %o2,-4,%o2
  65         sllx    %g2,%o3,%o4
  66         srlx    %g3,%o5,%g1
  67
  68         ldx     [%o1-24],%g2
  69         sllx    %g3,%o3,%g4
  70         or      %o4,%g1,%o4
  71         stx     %o4,[%o0+24]
  72         srlx    %g2,%o5,%g1
  73
  74         ldx     [%o1-32],%g3
  75         sllx    %g2,%o3,%o4
  76         or      %g4,%g1,%g4
  77         stx     %g4,[%o0+16]
  78         srlx    %g3,%o5,%g1
  79
  80         ldx     [%o1-40],%g2
  81         sllx    %g3,%o3,%g4
  82         or      %o4,%g1,%o4
  83         stx     %o4,[%o0+8]
  84         srlx    %g2,%o5,%g1
  85
  86         add     %o1,-32,%o1
  87         or      %g4,%g1,%g4
  88         brnz,pt %o2,.Loop
  89          stx    %g4,[%o0+0]
  90
  91 .Lend:  sllx    %g2,%o3,%g2
  92         stx     %g2,[%o0-8]
  93         retl
  94         ldx     [%sp+80],%o0
  95 .LLfe1:
  96         .size    __mpn_lshift,.LLfe1-__mpn_lshift