ghc/rts/gmp/mpn/sparc64/rshift.s

   1 ! SPARC v9 __mpn_rshift --
   2
   3 ! Copyright (C) 1996 Free Software Foundation, Inc.
   4
   5 ! This file is part of the GNU MP Library.
   6
   7 ! The GNU MP Library is free software; you can redistribute it and/or modify
   8 ! it under the terms of the GNU Library General Public License as published by
   9 ! the Free Software Foundation; either version 2 of the License, or (at your
  10 ! option) any later version.
  11
  12 ! The GNU MP Library is distributed in the hope that it will be useful, but
  13 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  15 ! License for more details.
  16
  17 ! You should have received a copy of the GNU Library General Public License
  18 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 ! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20 ! MA 02111-1307, USA.
  21
  22
  23 ! INPUT PARAMETERS
  24 ! res_ptr       %o0
  25 ! src_ptr       %o1
  26 ! size          %o2
  27 ! cnt           %o3
  28
  29 .section        ".text"
  30         .align  4
  31         .global __mpn_rshift
  32         .type   __mpn_rshift,#function
  33         .proc   04
  34 __mpn_rshift:
  35         ldx     [%o1],%g2       ! load first limb
  36         sub     %g0,%o3,%o5     ! negate shift count
  37         add     %o2,-1,%o2
  38         and     %o2,4-1,%g4     ! number of limbs in first loop
  39         sllx    %g2,%o5,%g1     ! compute function result
  40         brz,pn  %g4,.L0         ! if multiple of 4 limbs, skip first loop
  41         stx     %g1,[%sp+80]
  42
  43         sub     %o2,%g4,%o2     ! adjust count for main loop
  44
  45 .Loop0: ldx     [%o1+8],%g3
  46         add     %o0,8,%o0
  47         add     %o1,8,%o1
  48         add     %g4,-1,%g4
  49         srlx    %g2,%o3,%o4
  50         sllx    %g3,%o5,%g1
  51         mov     %g3,%g2
  52         or      %o4,%g1,%o4
  53         brnz,pt %g4,.Loop0
  54          stx    %o4,[%o0-8]
  55
  56 .L0:    brz,pn  %o2,.Lend
  57          nop
  58
  59 .Loop:  ldx     [%o1+8],%g3
  60         add     %o0,32,%o0
  61         add     %o2,-4,%o2
  62         srlx    %g2,%o3,%o4
  63         sllx    %g3,%o5,%g1
  64
  65         ldx     [%o1+16],%g2
  66         srlx    %g3,%o3,%g4
  67         or      %o4,%g1,%o4
  68         stx     %o4,[%o0-32]
  69         sllx    %g2,%o5,%g1
  70
  71         ldx     [%o1+24],%g3
  72         srlx    %g2,%o3,%o4
  73         or      %g4,%g1,%g4
  74         stx     %g4,[%o0-24]
  75         sllx    %g3,%o5,%g1
  76
  77         ldx     [%o1+32],%g2
  78         srlx    %g3,%o3,%g4
  79         or      %o4,%g1,%o4
  80         stx     %o4,[%o0-16]
  81         sllx    %g2,%o5,%g1
  82
  83         add     %o1,32,%o1
  84         or      %g4,%g1,%g4
  85         brnz    %o2,.Loop
  86          stx    %g4,[%o0-8]
  87
  88 .Lend:  srlx    %g2,%o3,%g2
  89         stx     %g2,[%o0-0]
  90         retl
  91         ldx     [%sp+80],%o0
  92 .LLfe1:
  93         .size   __mpn_rshift,.LLfe1-__mpn_rshift