+# FP_CHECK_WIN32
+# --------------
+# If Windows is the target platform (e.g. MinGW/MSYS or Cygwin with
+# -mno-cygwin), the variable "is_win32" is set to "yes", otherwise (e.g. *nix
+# systems or plain Cygwin) it is set to "no".
+AC_DEFUN([FP_CHECK_WIN32],
+[AC_CACHE_CHECK([for Windows environment], [fp_cv_is_win32],
+ [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
+#if !_WIN32
+ syntax error;
+#endif
+])], [fp_cv_is_win32=yes], [fp_cv_is_win32=no])])
+is_win32="$fp_cv_is_win32"[]dnl
+])# FP_CHECK_WIN32
+
+
+# FP_PATH_X
+# ---------
+# Same as AC_PATH_X, but works even for broken Cygwins which try to include the
+# non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
+AC_DEFUN([FP_PATH_X],
+[AC_REQUIRE([FP_CHECK_WIN32])
+if test x"$is_win32" = xyes; then
+ no_x=yes
+else
+ AC_PATH_X
+fi
+])# FP_PATH_X
+
+
+# FP_PATH_XTRA
+# ------------
+# Same as AC_PATH_XTRA, but works even for broken Cygwins which try to include
+# the non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
+AC_DEFUN([FP_PATH_XTRA],
+[AC_REQUIRE([FP_CHECK_WIN32])
+if test x"$is_win32" = xyes; then
+ no_x=yes
+else
+ AC_PATH_XTRA
+fi
+])# FP_PATH_XTRA
+
+
+# FP_CHECK_GL_HELPER(LIBNAME, LIBS, INCLUDES, FUNCTION-BODY)
+# ----------------------------------------------------------
+# Try each library in LIBS to successfully link INCLUDES plus FUNCTION-BODY,
+# setting LIBNAME_CFLAGS and LIBNAME_LIBS to the corresponding values. Sets
+# no_LIBNAME to "yes" if no suitable library was found. (LIBNAME_CFLAGS0
+# contains the value of LIBNAME_CFLAGS without CPPFLAGS, and LIBNAME_LIBS0
+# contains the value of LIBNAME_LIBS without LDFLAGS, but these are only
+# used internally.)
+AC_DEFUN([FP_CHECK_GL_HELPER],
+[AC_CACHE_CHECK([for $1 library], [fp_cv_check_$1_lib],
+ [fp_cv_check_$1_lib="no"
+ fp_save_CPPFLAGS="$CPPFLAGS"
+ CPPFLAGS="$CPPFLAGS ${$1_CFLAGS}"
+ fp_save_LIBS="$LIBS"
+ for fp_try_lib in $2; do
+ # transform "-lfoo" to "foo.lib" when using cl
+ if test x"$CC" = xcl; then
+ fp_try_lib=`echo $fp_try_lib | sed -e 's/^-l//' -e 's/$/.lib/'`
+ fi
+ LIBS="$fp_try_lib ${$1_LIBS} $fp_save_LIBS"
+ AC_TRY_LINK([$3], [$4], [fp_cv_check_$1_lib="$fp_try_lib ${$1_LIBS}"; break])
+ done
+ LIBS="$fp_save_LIBS"
+ CPPFLAGS="$fp_save_CPPFLAGS"])
+
+ if test x"$fp_cv_check_$1_lib" = xno; then
+ no_$1=yes
+ $1_CFLAGS=
+ $1_LIBS=
+ else
+ $1_CFLAGS0="${$1_CFLAGS}"
+ $1_CFLAGS="$CPPFLAGS ${$1_CFLAGS0}"
+ $1_LIBS0="$fp_cv_check_$1_lib"
+ $1_LIBS="$LDFLAGS ${$1_LIBS0}"
+ fi
+])# FP_CHECK_GL_HELPER
+
+
+# FP_CHECK_GL
+# -----------
+AC_DEFUN([FP_CHECK_GL],
+[AC_REQUIRE([FP_PATH_X])
+AC_REQUIRE([AC_CANONICAL_SYSTEM])
+
+AC_ARG_ENABLE([hopengl],
+ [AC_HELP_STRING([--enable-hopengl],
+ [build a Haskell binding for OpenGL (GL/GLU). On Mac OS X, use
+ --enable-hopengl=x11 to use X11 instead of the "native" libraries.
+ (default=no)])],
+ [enable_opengl=$enableval], [enable_opengl=no])
+
+if test x"$enable_opengl" = xno; then
+ no_GL=yes
+else
+ use_quartz_opengl=no
+ case $target_os in
+ darwin*)
+ if test x"$enable_opengl" != xx11; then
+ AC_DEFINE([USE_QUARTZ_OPENGL], [1],
+ [Define to 1 if native OpenGL should be used on Mac OS X])
+ use_quartz_opengl=yes
+ fi
+ ;;
+ esac
+
+ if test x"$use_quartz_opengl" != xyes; then
+ AC_CHECK_LIB([m], [atan], [GL_LIBS="-lm $GL_LIBS"])
+
+ if test x"$no_x" != xyes; then
+ test -n "$x_includes" && GL_CFLAGS="-I$x_includes $GL_CFLAGS"
+ test -n "$x_libraries" && GL_LIBS="-L$x_libraries -lX11 $GL_LIBS"
+ fi
+
+ FP_CHECK_GL_HELPER([GL], [-lGL -lopengl32], [@%:@include <GL/gl.h>], [glEnd()])
+
+ if test x"$no_GL" != xyes; then
+ # Ugly: To get wglGetProcAddress on Windows, we have to link with
+ # opengl32.dll, too, even when we are using Cygwin with X11.
+ case "$GL_LIBS" in
+ *-lopengl32*|*opengl32.lib*) ;;
+ *) fp_save_LIBS="$LIBS"
+ LIBS="$LIBS -lopengl32"
+ AC_TRY_LINK([@%:@include <GL/gl.h>], [glEnd()],
+ [GL_LIBS="$GL_LIBS -lopengl32"; GL_LIBS0="$GL_LIBS0 -lopengl32"])
+ LIBS="$fp_save_LIBS"
+ ;;
+ esac
+ fi
+ fi
+fi
+
+AC_SUBST([GL_CFLAGS])
+AC_SUBST([GL_LIBS])
+])# FP_CHECK_GL
+
+
+# FP_CHECK_GLU
+# ------------
+AC_DEFUN([FP_CHECK_GLU],
+[AC_REQUIRE([FP_CHECK_GL])dnl
+GLU_CFLAGS="$GL_CFLAGS0"
+GLU_LIBS="$GL_LIBS0"
+
+if test x"$enable_opengl" = xno; then
+ no_GLU=yes
+elif test x"$use_quartz_opengl" != xyes; then
+ FP_CHECK_GL_HELPER([GLU], [-lglu32 -lGLU], [@%:@include <GL/glu.h>], [gluNewQuadric()])
+fi
+
+AC_SUBST([GLU_CFLAGS])
+AC_SUBST([GLU_LIBS])
+])# FP_CHECK_GLU
+
+
+# FP_CHECK_GLUT
+# -------------
+AC_DEFUN([FP_CHECK_GLUT],
+[AC_REQUIRE([FP_CHECK_GLU])
+FP_PATH_XTRA
+
+if test x"$enable_opengl" = xno; then
+ no_GLUT=yes
+elif test x"$use_quartz_opengl" != xyes; then
+ GLUT_CFLAGS="$GLU_CFLAGS0"
+ GLUT_LIBS="$GLU_LIBS0"
+
+ if test x"$no_x" != xyes; then
+ GLUT_LIBS="$X_PRE_LIBS -lXmu -lXi $X_EXTRA_LIBS $GLUT_LIBS"
+ fi
+
+ AC_CHECK_HEADERS([windows.h GL/glut.h])
+ # Note 1: On Cygwin with X11, GL/GLU functions use the "normal" calling
+ # convention, but GLUT functions use stdcall. To get this right, it is
+ # necessary to include <windows.h> first.
+ # Note 2: MinGW/MSYS comes without a GLUT header, so we use Cygwin's one in
+ # that case.
+ FP_CHECK_GL_HELPER([GLUT], [-lglut32 -lglut], [
+#if HAVE_WINDOWS_H
+#include <windows.h>
+#endif
+#if HAVE_GL_GLUT_H
+#include <GL/glut.h>
+#else
+#include "glut_local.h"
+#endif
+ ], [glutMainLoop()])
+fi
+
+AC_SUBST([GLUT_CFLAGS])
+AC_SUBST([GLUT_LIBS])
+])# FP_CHECK_GLUT
+
+
+dnl @synopsis FP_EMPTY_STRUCTS
+dnl
+dnl Check whether empty structs is accepted by CC.
+dnl
+AC_DEFUN(FP_EMPTY_STRUCTS,
+[AC_CACHE_CHECK(empty struct support, fptools_cv_empty_structs,
+[AC_TRY_COMPILE([
+typedef struct { /*empty*/ } StgFoo;
+],
+[int i;],
+fptools_cv_empty_structs=yes,
+fptools_cv_empty_structs=no)])
+if test "$fptools_cv_empty_structs" = yes; then
+AC_DEFINE([SUPPORTS_EMPTY_STRUCTS], [1], [Define to 1 if C compiler supports declaration of empty structure types.])
+fi
+])
+
+
+dnl @synopsis FP_READDIR_EOF_ERRNO
+dnl
+dnl Check what readdir() sets 'errno' to upon reaching
+dnl end of directory; not setting it is the correct thing to do,
+dnl but mingw based versions have set it to ENOENT until recently
+dnl (summer 2004).
+dnl
+dnl
+AC_DEFUN(FP_READDIR_EOF_ERRNO,
+[AC_CACHE_CHECK([what readdir sets errno to upon EOF], fptools_cv_readdir_eof_errno,
+[AC_TRY_RUN([#include <dirent.h>
+#include <stdio.h>
+#include <errno.h>
+int
+main(argc, argv)
+int argc;
+char **argv;
+{
+ FILE *f=fopen("conftestval", "w");
+#if defined(__MINGW32__)
+ int fd = mkdir("testdir");
+#else
+ int fd = mkdir("testdir", 0666);
+#endif
+ DIR* dp;
+ struct dirent* de;
+ int err = 0;
+
+ if (!f) return 1;
+ if (fd == -1) {
+ fprintf(stderr,"unable to create directory; quitting.\n");
+ return 1;
+ }
+ close(fd);
+ dp = opendir("testdir");
+ if (!dp) {
+ fprintf(stderr,"unable to browse directory; quitting.\n");
+ rmdir("testdir");
+ return 1;
+ }
+
+ /* the assumption here is that readdir() will only return NULL
+ * due to reaching the end of the directory.
+ */
+ while (de = readdir(dp)) {
+ ;
+ }
+ err = errno;
+ fprintf(f,"%d", err);
+ fclose(f);
+ closedir(de);
+ rmdir("testdir");
+ return 0;
+}],fptools_cv_readdir_eof_errno=`cat conftestval`, fptools_cv_readdir_eof_errno=bogus, fptools_cv_readdir_eof_errno=0)])
+dnl the cross value is somewhat bogus.
+AC_DEFINE([READDIR_ERRNO_EOF], [$fptools_cv_readdir_eof_errno], [readdir() sets errno to this upon EOF])
+])
+
+dnl @synopsis FP_DIRENT_FLAT_LAYOUT
+dnl
+dnl Check whether 'struct dirent' (in dirent.h) has d_name defined
+dnl as being the final field in a struct, or a pointer to somewhere
+dnl else. The former is the standardly thing to do, but mingw defns
+dnl have for the longest time gone for the latter. They no longer do,
+dnl hence the need to configure test for this.
+dnl
+dnl
+AC_DEFUN(FP_DIRENT_FLAT_LAYOUT,
+[AC_CACHE_CHECK([if struct dirent layout is flat], fptools_cv_dirent_flat_layout,
+[AC_TRY_RUN([#include <dirent.h>
+#include <stdio.h>
+#include <string.h>
+int
+main(argc, argv)
+int argc;
+char **argv;
+{
+ struct dirent de;
+ /*
+ * Check whether d_name is defined as
+ * struct dirent { .... ; char d_name[..]; }
+ * or
+ * struct dirent { .... ; char* d_name; }
+ *
+ * Returns 0 if the former.
+ */
+ memset(&de,0,sizeof(struct dirent));
+ return ((int)de.d_name == 0);
+}],fptools_cv_dirent_flat_layout=yes, fptools_cv_dirent_flat_layout=no, fptools_cv_dirent_flat_layout=yes)])
+dnl the cross value is somewhat bogus.
+if test "$fptools_cv_dirent_flat_layout" = yes; then
+AC_DEFINE([STRUCT_DIRENT_FLAT_LAYOUT], [1], [Define to 1 if struct dirent is a flat structure])
+fi
+])
+
+