+
+dnl ** Obtain the value of a C constant.
+dnl The value will be `(-1)' if the constant is undefined.
+dnl
+dnl This is set up so that the argument can be a shell variable.
+dnl
+AC_DEFUN(FPTOOLS_CHECK_CCONST,
+[
+eval "def_name=CCONST_$1"
+eval "cv_name=ac_cv_cconst_$1"
+AC_MSG_CHECKING(value of $1)
+AC_CACHE_VAL($cv_name,
+[AC_TRY_RUN([#include <stdio.h>
+#include <errno.h>
+main()
+{
+ FILE *f=fopen("conftestval", "w");
+ if (!f) exit(1);
+ fprintf(f, "%d\n", $1);
+ exit(0);
+}],
+eval "$cv_name=`cat conftestval`",
+eval "$cv_name=-1",
+eval "$cv_name=-1")])dnl
+eval "fptools_check_cconst_result=`echo '$'{$cv_name}`"
+AC_MSG_RESULT($fptools_check_cconst_result)
+AC_DEFINE_UNQUOTED($def_name, $fptools_check_cconst_result)
+unset fptools_check_cconst_result
+])
+
+dnl ** Invoke AC_CHECK_CCONST on each argument (which have to separate with
+dnl spaces)
+dnl
+AC_DEFUN(FPTOOLS_CHECK_CCONSTS,
+[for ac_const_name in $1
+do
+FPTOOLS_CHECK_CCONST($ac_const_name)dnl
+done
+])
+
+
+dnl *** Can we open files in binary mode? ***
+dnl
+AC_DEFUN(FPTOOLS_O_BINARY,
+[
+AC_REQUIRE([AC_PROG_CC])
+AC_MSG_CHECKING(whether we can open files in binary mode)
+AC_CACHE_VAL(fptools_cv_have_o_binary,
+[
+AC_LANG_SAVE
+AC_LANG_C
+AC_TRY_COMPILE(,
+[#ifdef HAVE_FCNTL_H
+#include <fcntl.h>
+#endif
+int x = O_BINARY;],
+fptools_cv_have_o_binary=yes,
+fptools_cv_have_o_binary=no)
+AC_LANG_RESTORE
+])
+AC_MSG_RESULT($fptools_cv_have_o_binary)
+if test "$fptools_cv_have_o_binary" = yes; then
+AC_DEFINE(HAVE_O_BINARY)
+fi
+])
+
+dnl *** Which one comes first, .text or .data? ***
+dnl
+AC_DEFUN(FPTOOLS_CODE_BEFORE_DATA,
+[AC_CACHE_CHECK([if code section appears before data], fptools_cv_code_bef_data,
+[AC_TRY_RUN([
+int f() { return 1; }
+int i;
+int main() { return ((char*)&f > (char*)&i); }
+
+],
+fptools_cv_code_bef_data=yes, fptools_cv_code_bef_data=no,false)])
+if test "$fptools_cv_code_bef_data" = yes; then
+ AC_DEFINE(CODE_BEFORE_DATA)
+fi
+])
+
+dnl *** Helper function **
+dnl
+AC_DEFUN(FPTOOLS_IN_SCOPE,
+[AC_TRY_LINK([extern char* $1;],[return (int)&$2], $3=yes, $3=no)
+])
+
+dnl *** What's the end-of-text-section marker called? ***
+dnl
+AC_DEFUN([FPTOOLS_END_TEXT_SECTION],
+[AC_CACHE_CHECK([for end of text section marker],
+ [fptools_cv_end_of_text],
+ [fptools_cv_end_of_text=""
+ not_done=1
+ for i in data_start _data_start etext _etext __etext; do
+ FPTOOLS_IN_SCOPE($i,$i,fptools_end_of_text)
+ if test "$fptools_end_of_text" = yes; then
+ fptools_cv_end_of_text=$i
+ not_done=0
+ break
+ fi
+ done
+ if test "$not_done" = 1; then
+ FPTOOLS_IN_SCOPE(etext asm("etext"),etext,fptools_end_of_text)
+ if test "$fptools_end_of_text" = yes; then
+ fptools_cv_end_of_text="etext"
+ fi
+ fi])
+ if test -n "$fptools_cv_end_of_text"; then
+ AC_DEFINE_UNQUOTED([TEXT_SECTION_END_MARKER], $fptools_cv_end_of_text)
+ else
+ AC_DEFINE_UNQUOTED([TEXT_SECTION_END_MARKER], dunno_end_of_text)
+ fi
+ AC_CACHE_CHECK([for end of text section marker declaration],
+ [fptools_cv_end_of_text_decl],
+ [fptools_cv_end_of_text_decl=""
+ not_done=1
+ for i in data_start _data_start etext _etext __etext; do
+ FPTOOLS_IN_SCOPE($i,$i,fptools_end_of_text_decl)
+ if test "$fptools_end_of_text_decl" = yes; then
+ fptools_cv_end_of_text_decl=$i
+ not_done=0
+ break
+ fi
+ done
+ if test "$not_done" = 1; then
+ FPTOOLS_IN_SCOPE(etext asm("etext"),etext,fptools_end_of_text_decl)
+ if test "$fptools_end_of_text_decl" = yes; then
+ fptools_cv_end_of_text_decl="etext asm(\"etext\")"
+ fi
+ fi])
+ if test -n "$fptools_cv_end_of_text_decl"; then
+ AC_DEFINE_UNQUOTED([TEXT_SECTION_END_MARKER_DECL], $fptools_cv_end_of_text_decl)
+ else
+ AC_DEFINE_UNQUOTED([TEXT_SECTION_END_MARKER_DECL], dunno_end_of_text_decl)
+ fi
+])
+
+dnl *** What's the end-of-data-section marker called? ***
+dnl
+AC_DEFUN([FPTOOLS_END_DATA_SECTION],
+[AC_CACHE_CHECK([for end of data section marker],
+ [fptools_cv_end_of_data],
+ [fptools_cv_end_of_data=""
+ not_done=1
+ for i in end _end __end; do
+ FPTOOLS_IN_SCOPE($i,$i,fptools_end_of_data)
+ if test "$fptools_end_of_data" = yes; then
+ fptools_cv_end_of_data=$i
+ not_done=0
+ break
+ fi
+ done
+ if test "$not_done" = 1; then
+ FPTOOLS_IN_SCOPE(end asm("end"),end,fptools_end_of_data)
+ if test "$fptools_end_of_data" = yes; then
+ fptools_cv_end_of_data="end"
+ fi
+ fi])
+ if test -n "$fptools_cv_end_of_data"; then
+ AC_DEFINE_UNQUOTED([DATA_SECTION_END_MARKER], $fptools_cv_end_of_data)
+ else
+ AC_DEFINE_UNQUOTED([DATA_SECTION_END_MARKER], dunno_end_of_data)
+ fi
+ AC_CACHE_CHECK([for end of data section marker declaration],
+ [fptools_cv_end_of_data_decl],
+ [fptools_cv_end_of_data_decl=""
+ not_done=1
+ for i in end _end __end; do
+ FPTOOLS_IN_SCOPE($i,$i,fptools_end_of_data_decl)
+ if test "$fptools_end_of_data_decl" = yes; then
+ fptools_cv_end_of_data_decl=$i
+ not_done=0
+ break
+ fi
+ done
+ if test "$not_done" = 1; then
+ FPTOOLS_IN_SCOPE(end asm("end"),end,fptools_end_of_data_decl)
+ if test "$fptools_end_of_data_decl" = yes; then
+ fptools_cv_end_of_data_decl="end asm(\"end\")"
+ fi
+ fi])
+ if test -n "$fptools_cv_end_of_data_decl"; then
+ AC_DEFINE_UNQUOTED([DATA_SECTION_END_MARKER_DECL], $fptools_cv_end_of_data_decl)
+ else
+ AC_DEFINE_UNQUOTED([DATA_SECTION_END_MARKER_DECL], dunno_end_of_data_decl)
+ fi
+])
+
+
+dnl Based on AC_TRY_LINK - run iftrue if links cleanly with no warning
+
+dnl FPTOOLS_TRY_LINK_NOWARN(flags,main?,iftrue,iffalse)
+
+AC_DEFUN(FPTOOLS_TRY_LINK_NOWARN,
+[
+ac_save_LIBS="$LIBS"
+LIBS=[$1];
+cat > conftest.$ac_ext <<EOF
+dnl This sometimes fails to find confdefs.h, for some reason.
+dnl [#]line __oline__ "[$]0"
+[#]line __oline__ "configure"
+#include "confdefs.h"
+[$2]
+int t() { return 0; }
+EOF
+if AC_TRY_EVAL(ac_link); then
+ ifelse([$3], , :, [
+ LIBS="$ac_save_LIBS"
+ rm -rf conftest*
+ $3])
+ ifelse([$4], , , [else
+ LIBS="$ac_save_LIBS"
+ rm -rf conftest*
+ $4
+])dnl
+fi
+rm -f conftest*
+]
+)
+
+dnl Loosely based on AC_CHECK_LIB in acgeneral.m4 in autoconf distribution
+
+dnl FPTOOLS_CHECK_FLAG_NOWARN(NAME, FLAG, CODE, iftrue, iffalse)
+
+AC_DEFUN(FPTOOLS_CHECK_FLAG_NOWARN,
+[AC_MSG_CHECKING([for $1])
+ AC_CACHE_VAL(ac_cv_flag_$1,
+ [FPTOOLS_TRY_LINK_NOWARN("$2", [main() { $3; exit(0); } ],
+ eval "ac_cv_flag_$1=yes",
+ eval "ac_cv_flag_$1=no"
+ )]
+ )
+if eval "test \"`echo '$ac_cv_flag_'$1`\" = yes"; then
+ AC_MSG_RESULT(yes)
+ LIBS="$2 $LIBS"
+ $4
+else
+ AC_MSG_RESULT(no)
+ $5
+fi
+])
+
+dnl FPTOOLS_CHECK_LIB_NOWARN(LIBRARY, FUNCTION)
+
+AC_DEFUN(FPTOOLS_CHECK_LIB_NOWARN,
+[FPTOOLS_CHECK_FLAG_NOWARN([function_$2],[],[extern char $2(); $2();],
+[changequote(, )dnl
+ ac_tr_lib=HAVE_LIB`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
+ changequote([, ])dnl
+ AC_DEFINE_UNQUOTED($ac_tr_lib)
+],
+[FPTOOLS_CHECK_FLAG_NOWARN([library_$1],[-l$1],[extern char $2(); $2();],
+[changequote(, )dnl
+ ac_tr_lib=HAVE_LIB`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
+ changequote([, ])dnl
+ AC_DEFINE_UNQUOTED($ac_tr_lib)
+],
+[]
+)])]
+)
+
+dnl check for prototypes
+dnl
+AC_DEFUN([AC_C_PROTOTYPES],
+[AC_CACHE_CHECK([prototypes], ac_cv_prototypes,
+[AC_TRY_COMPILE([
+void foo(int);
+void foo(i)
+int i; {
+return;
+}
+],
+[int i;],
+ac_cv_prototypes=yes,
+ac_cv_prototypes=no)])
+if test "$ac_cv_prototypes" = yes; then
+AC_DEFINE([HAVE_PROTOTYPES])
+fi
+])
+
+dnl ** Check which CATALOG file we have to use with DocBook SGML.
+dnl
+dnl FPTOOLS_DOCBOOK_CATALOG(VARIABLE, JADE, STYLESHEET, CATALOGS-TO-CHECK-FOR)
+dnl
+dnl If any of the catalogs given in CATALOGS-TO-CHECK-FOR works on this
+dnl platform, let VARIABLE refer to this catalog; otherwise, VARIABLE
+dnl is set to "no". JADE is the jade executable and STYLESHEET
+dnl a DocBook style sheet.
+dnl
+AC_DEFUN(FPTOOLS_DOCBOOK_CATALOG,
+[AC_CACHE_CHECK([for DocBook CATALOG], fptools_cv_sgml_catalog,
+[
+cat > conftest.sgml << EOF
+<!DOCTYPE Article PUBLIC "-//OASIS//DTD DocBook V3.1//EN">
+<Article>
+<ArtHeader>
+<Title>Test</Title>
+<Author><OtherName>Test</OtherName></Author>
+<Address>Test</Address>
+<PubDate>Test</PubDate>
+</ArtHeader>
+<Sect1><Title>Test</Title>
+<Para>
+Test.
+</Para>
+</Sect1>
+</Article>
+EOF
+fptools_cv_sgml_catalog=no
+for fptools_catalog in $4; do
+ ac_try="$2 -t rtf -d $3#print -c $fptools_catalog conftest.sgml"
+ if AC_TRY_EVAL(ac_try); then
+ fptools_cv_sgml_catalog=[$]fptools_catalog
+ break
+ fi
+done
+])
+rm -rf conftest*
+if test $fptools_cv_sgml_catalog != "no"; then
+ $1=$fptools_cv_sgml_catalog
+fi
+])
+
+dnl ######################################################################
+dnl FPTOOLS_SEARCH_LIBS(INCLUDES, FUNCTION, SEARCH-LIBS [, ACTION-IF-FOUND
+dnl [, ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
+dnl Search for a library defining FUNC, if it's not already available.
+dnl This is almost the same as AC_SEARCH_LIBS, but the INCLUDES can be
+dnl specified.
+dnl ######################################################################
+
+AC_DEFUN(FPTOOLS_SEARCH_LIBS,
+[AC_PREREQ([2.13])
+AC_CACHE_CHECK([for library containing $2], [ac_cv_search_$2],
+[ac_func_search_save_LIBS="$LIBS"
+ac_cv_search_$2="no"
+AC_TRY_LINK([$1], [$2()], [ac_cv_search_$2="none required"])
+test "$ac_cv_search_$2" = "no" && for i in $3; do
+LIBS="-l$i $6 $ac_func_search_save_LIBS"
+AC_TRY_LINK([$1], [$2()],
+[ac_cv_search_$2="-l$i"
+break])
+done
+LIBS="$ac_func_search_save_LIBS"])
+if test "$ac_cv_search_$2" != "no"; then
+ test "$ac_cv_search_$2" = "none required" || LIBS="$ac_cv_search_$2 $LIBS"
+ $4
+else :
+ $5
+fi])
+
+dnl ####################### -*- Mode: M4 -*- ###########################
+dnl Copyright (C) 98, 1999 Matthew D. Langston <langston@SLAC.Stanford.EDU>
+dnl
+dnl This file is free software; you can redistribute it and/or modify it
+dnl under the terms of the GNU General Public License as published by
+dnl the Free Software Foundation; either version 2 of the License, or
+dnl (at your option) any later version.
+dnl
+dnl This file is distributed in the hope that it will be useful, but
+dnl WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+dnl General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU General Public License
+dnl along with this file; if not, write to:
+dnl
+dnl Free Software Foundation, Inc.
+dnl Suite 330
+dnl 59 Temple Place
+dnl Boston, MA 02111-1307, USA.
+dnl ####################################################################
+
+
+dnl @synopsis FPTOOLS_CHECK_LIBM
+dnl
+dnl Search for math library (typically -lm).
+dnl
+dnl The variable LIBM (which is not an output variable by default) is
+dnl set to a value which is suitable for use in a Makefile (for example,
+dnl in make's LOADLIBES macro) provided you AC_SUBST it first.
+dnl
+dnl @author Matthew D. Langston <langston@SLAC.Stanford.EDU>
+
+# FPTOOLS_CHECK_LIBM - check for math library
+AC_DEFUN(FPTOOLS_CHECK_LIBM,
+[AC_REQUIRE([AC_CANONICAL_HOST])dnl
+LIBM=
+case "$host" in
+*-*-beos* | *-*-macosx*)
+ # These system don't have libm
+ ;;
+*-ncr-sysv4.3*)
+ AC_CHECK_LIB(mw, _mwvalidcheckl, LIBM="-lmw")
+ AC_CHECK_LIB(m, main, LIBM="$LIBM -lm")
+ ;;
+*)
+ AC_CHECK_LIB(m, main, LIBM="-lm")
+ ;;
+esac
+])
+
+dnl ######################################################################
+dnl NOTE: Because of portability issues between different autoconf
+dnl versions the AC_HELP_STRING macro has been removed from FPTOOLS_HAVE_OPENGL.
+dnl Furthermore, caching has been completely rewritten.
+dnl ######################################################################
+
+dnl ########################### -*- Mode: M4 -*- #######################
+dnl Copyright (C) 98, 1999 Matthew D. Langston <langston@SLAC.Stanford.EDU>
+dnl
+dnl This file is free software; you can redistribute it and/or modify it
+dnl under the terms of the GNU General Public License as published by
+dnl the Free Software Foundation; either version 2 of the License, or
+dnl (at your option) any later version.
+dnl
+dnl This file is distributed in the hope that it will be useful, but
+dnl WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+dnl General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU General Public License
+dnl along with this file; if not, write to:
+dnl
+dnl Free Software Foundation, Inc.
+dnl Suite 330
+dnl 59 Temple Place
+dnl Boston, MA 02111-1307, USA.
+dnl ####################################################################
+
+dnl @synopsis FPTOOLS_HAVE_OPENGL
+dnl
+dnl Search for OpenGL. We search first for Mesa (a GPL'ed version of
+dnl OpenGL) before a vendor's version of OpenGL, unless we were
+dnl specifically asked not to with `--with-Mesa=no' or `--without-Mesa'.
+dnl
+dnl The four "standard" OpenGL libraries are searched for: "-lGL",
+dnl "-lGLU", "-lGLX" (or "-lMesaGL", "-lMesaGLU" as the case may be) and
+dnl "-lglut".
+dnl
+dnl All of the libraries that are found (since "-lglut" or "-lGLX" might
+dnl be missing) are added to the shell output variable "GL_LIBS", along
+dnl with any other libraries that are necessary to successfully link an
+dnl OpenGL application (e.g. the X11 libraries). Care has been taken to
+dnl make sure that all of the libraries in "GL_LIBS" are listed in the
+dnl proper order.
+dnl
+dnl Additionally, the shell output variable "GL_CFLAGS" is set to any
+dnl flags (e.g. "-I" flags) that are necessary to successfully compile
+dnl an OpenGL application.
+dnl
+dnl The following shell variable (which are not output variables) are
+dnl also set to either "yes" or "no" (depending on which libraries were
+dnl found) to help you determine exactly what was found.
+dnl
+dnl have_GL
+dnl have_GLU
+dnl have_GLX
+dnl have_glut
+dnl
+dnl A complete little toy "Automake `make distcheck'" package of how to
+dnl use this macro is available at:
+dnl
+dnl ftp://ftp.slac.stanford.edu/users/langston/autoconf/ac_opengl-0.01.tar.gz
+dnl
+dnl Please note that as the ac_opengl macro and the toy example evolves,
+dnl the version number increases, so you may have to adjust the above
+dnl URL accordingly.
+dnl
+dnl @author Matthew D. Langston <langston@SLAC.Stanford.EDU>
+
+AC_DEFUN(FPTOOLS_HAVE_OPENGL,
+[
+ AC_REQUIRE([AC_PROG_CC])
+ AC_REQUIRE([AC_PATH_X])
+ AC_REQUIRE([AC_PATH_XTRA])
+ AC_REQUIRE([FPTOOLS_CHECK_LIBM])
+
+dnl Check for Mesa first, unless we were asked not to.
+dnl AC_HELP_STRING([--with-Mesa],
+dnl [Prefer the Mesa library over a vendors native OpenGL library (default=yes)],
+dnl with_Mesa_help_string)
+dnl AC_ARG_ENABLE(Mesa, $with_Mesa_help_string, use_Mesa=$enableval, use_Mesa=yes)
+ AC_ARG_ENABLE(Mesa, [ --with-Mesa Prefer the Mesa library over a vendors native OpenGL library (default=yes)], use_Mesa=$enableval, use_Mesa=yes)
+
+ if test x"$use_Mesa" = xyes; then
+ GL_search_list="MesaGL GL opengl32"
+ GLU_search_list="MesaGLU GLU glu32"
+ GLX_search_list="MesaGLX GLX"
+ else
+ GL_search_list="GL opengl32 MesaGL"
+ GLU_search_list="GLU glu32 MesaGLU"
+ GLX_search_list="GLX MesaGLX"
+ fi
+
+ AC_LANG_SAVE
+ AC_LANG_C
+
+dnl If we are running under X11 then add in the appropriate libraries.
+ if ! test x"$no_x" = xyes; then
+dnl Add everything we need to compile and link X programs to GL_CFLAGS
+dnl and GL_X_LIBS.
+ GL_CFLAGS="$X_CFLAGS"
+ GL_X_LIBS="$X_PRE_LIBS $X_LIBS -lX11 -lXext -lXmu -lXt -lXi $X_EXTRA_LIBS $LIBM"
+ fi
+ GL_save_CPPFLAGS="$CPPFLAGS"
+ CPPFLAGS="$GL_CFLAGS"
+
+ GL_save_LIBS="$LIBS"
+ LIBS="$GL_X_LIBS"
+
+ FPTOOLS_SEARCH_LIBS([#include <GL/gl.h>], glEnd, $GL_search_list, have_GL=yes, have_GL=no)
+ FPTOOLS_SEARCH_LIBS([#include <GL/glu.h>], gluNewQuadric, $GLU_search_list, have_GLU=yes, have_GLU=no)
+ FPTOOLS_SEARCH_LIBS([#include <GL/glx.h>], glXChooseVisual, $GLX_search_list, have_GLX=yes, have_GLX=no)
+ FPTOOLS_SEARCH_LIBS([#include <GL/glut.h>], glutMainLoop, glut glut32, have_glut=yes, have_glut=no)
+
+ if test -n "$LIBS"; then
+ GL_LIBS="$LIBS"
+ else
+ GL_LIBS=
+ GL_CFLAGS=
+ fi
+
+ AC_CACHE_CHECK([OpenGL flags], mdl_cv_gl_cflags, [mdl_cv_gl_cflags="$GL_CFLAGS"])
+ GL_CFLAGS="$mdl_cv_gl_cflags"
+ AC_SUBST(GL_CFLAGS)
+ AC_CACHE_CHECK([OpenGL libs], mdl_cv_gl_libs, [mdl_cv_gl_libs="$GL_LIBS"])
+ GL_LIBS="$mdl_cv_gl_libs"
+ AC_SUBST(GL_LIBS)
+
+dnl Reset GL_X_LIBS regardless, since it was just a temporary variable
+dnl and we don't want to be global namespace polluters.
+ GL_X_LIBS=
+
+ LIBS="$GL_save_LIBS"
+ CPPFLAGS="$GL_save_CPPFLAGS"
+
+ AC_LANG_RESTORE
+])
+
+# LocalWords: fi
+
+dnl
+dnl acspecific.m4's defn of AC_PROG_LEX is a bit too permissive, as it
+dnl defaults to 'lex' if 'flex' isn't found (without checking whether
+dnl 'lex' is actually present along the user's PATH).
+dnl
+AC_DEFUN(AC_PROG_LEX_STRICT,
+[AC_CHECK_PROG(LEX, flex, flex)
+if test -z "$LEX"
+then
+ AC_CHECK_PROG(LEX,lex,lex)
+ test -z "$LEX" && AC_MSG_ERROR(['lex' or 'flex' is required to compile GHC.])
+fi
+])
+
+dnl
+dnl Check to see whether CC (gcc) supports a particular option.
+dnl
+AC_DEFUN(FPTOOLS_CC_FLAG,
+[
+AC_CACHE_CHECK([whether $CC accepts $1], [ac_cv_cc_$2],
+[save_CFLAGS="$CFLAGS"
+ CFLAGS="$CFLAGS $1"
+ AC_LANG_C
+ AC_TRY_COMPILE(,[int main(){return(0);}],
+ [ac_cv_cc_$2=yes],
+ [ac_cv_cc_$2=no])
+ CFLAGS="$save_CFLAGS"
+])
+if test "$ac_cv_cc_$2"x = "yesx"; then
+ $2=$extra_flag;
+else
+ $2=$extra_flag;
+fi;
+])