aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FPTOOLS_SET_PLATFORM_VARS
   8 # ----------------------------------
   9 # Set the platform variables
  10 AC_DEFUN([FPTOOLS_SET_PLATFORM_VARS],
  11 [
  12     # If no argument was given for a configuration variable, then discard
  13     # the guessed canonical system and use the configuration of the
  14     # bootstrapping ghc. If an argument was given, map it from gnu format
  15     # to ghc format.
  16     #
  17     # For why we do it this way, see: #3637, #1717, #2951
  18     #
  19     # In bindists, we haven't called AC_CANONICAL_{BUILD,HOST,TARGET}
  20     # so this justs uses $bootstrap_target.
  21
  22     if test "$build_alias" = ""
  23     then
  24         if test "$bootstrap_target" != ""
  25         then
  26             build=$bootstrap_target
  27             echo "Build platform inferred as: $build"
  28         else
  29             echo "Can't work out build platform"
  30             exit 1
  31         fi
  32
  33         BuildArch=`echo "$build" | sed 's/-.*//'`
  34         BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
  35         BuildOS=`echo "$build" | sed 's/.*-//'`
  36     else
  37         GHC_CONVERT_CPU([$build_cpu], [BuildArch])
  38         GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
  39         GHC_CONVERT_OS([$build_os], [BuildOS])
  40     fi
  41
  42     if test "$host_alias" = ""
  43     then
  44         if test "$bootstrap_target" != ""
  45         then
  46             host=$bootstrap_target
  47             echo "Host platform inferred as: $host"
  48         else
  49             echo "Can't work out host platform"
  50             exit 1
  51         fi
  52
  53         HostArch=`echo "$host" | sed 's/-.*//'`
  54         HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
  55         HostOS=`echo "$host" | sed 's/.*-//'`
  56     else
  57         GHC_CONVERT_CPU([$host_cpu], [HostArch])
  58         GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
  59         GHC_CONVERT_OS([$host_os], [HostOS])
  60     fi
  61
  62     if test "$target_alias" = ""
  63     then
  64         if test "$bootstrap_target" != ""
  65         then
  66             target=$bootstrap_target
  67             echo "Target platform inferred as: $target"
  68         else
  69             echo "Can't work out target platform"
  70             exit 1
  71         fi
  72
  73         TargetArch=`echo "$target" | sed 's/-.*//'`
  74         TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
  75         TargetOS=`echo "$target" | sed 's/.*-//'`
  76     else
  77         GHC_CONVERT_CPU([$target_cpu], [TargetArch])
  78         GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
  79         GHC_CONVERT_OS([$target_os], [TargetOS])
  80     fi
  81 ])
  82
  83
  84 # FPTOOLS_SET_C_LD_FLAGS
  85 # ----------------------------------
  86 # Set the C, LD and CPP flags for a given platform
  87 # $1 is the platform
  88 # $2 is the name of the CC flags variable
  89 # $3 is the name of the linker flags variable when linking with gcc
  90 # $4 is the name of the linker flags variable when linking with ld
  91 # $5 is the name of the CPP flags variable
  92 AC_DEFUN([FPTOOLS_SET_C_LD_FLAGS],
  93 [
  94     AC_MSG_CHECKING([Setting up $2, $3, $4 and $5])
  95     case $$1 in
  96     i386-apple-darwin)
  97         $2="$$2 -m32"
  98         $3="$$3 -m32"
  99         $4="$$4 -arch i386"
 100         $5="$$5 -m32"
 101         ;;
 102     x86_64-apple-darwin)
 103         $2="$$2 -m64"
 104         $3="$$3 -m64"
 105         $4="$$4 -arch x86_64"
 106         $5="$$5 -m64"
 107         ;;
 108     esac
 109
 110     # If gcc knows about the stack protector, turn it off.
 111     # Otherwise the stack-smash handler gets triggered.
 112     echo 'int main(void) {return 0;}' > conftest.c
 113     if $CC -c conftest.c -fno-stack-protector > /dev/null 2>&1
 114     then
 115         $2="$$2 -fno-stack-protector"
 116     fi
 117     rm -f conftest.c conftest.o
 118     AC_MSG_RESULT([done])
 119 ])
 120
 121
 122 # FP_VISIBILITY_HIDDEN
 123 # ----------------------------------
 124 # Is the visibility hidden attribute supported?
 125 AC_DEFUN([FP_VISIBILITY_HIDDEN],
 126 [
 127     AC_MSG_CHECKING([whether __attribute__((visibility("hidden"))) is supported])
 128     echo '__attribute__((visibility("hidden"))) void foo(void) {}' > conftest.c
 129     if $CC -Wall -Werror -c conftest.c > /dev/null 2>&1
 130     then
 131         AC_MSG_RESULT([yes])
 132         AC_DEFINE(HAS_VISIBILITY_HIDDEN, 1, [Has visibility hidden])
 133     else
 134         AC_MSG_RESULT([no])
 135     fi
 136     rm -f conftest.c conftest.o
 137 ])
 138
 139
 140 # FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 141 # ----------------------------------
 142 # Little endian Arm on Linux with some ABIs has big endian word order
 143 # in doubles. Define FLOAT_WORDS_BIGENDIAN if this is the case.
 144 AC_DEFUN([FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN],
 145   [AC_CACHE_CHECK([whether float word order is big endian], [fptools_cv_float_word_order_bigendian],
 146     [AC_COMPILE_IFELSE(
 147       [AC_LANG_PROGRAM(
 148         [#include <endian.h>],
 149         [#if defined(__FLOAT_WORD_ORDER) && __FLOAT_WORD_ORDER == BIG_ENDIAN
 150              return 0;
 151          #else
 152              not float word order big endian
 153          #endif]
 154       )],
 155       [fptools_cv_float_word_order_bigendian=yes],
 156       [fptools_cv_float_word_order_bigendian=no])
 157     ])
 158   case $fptools_cv_float_word_order_bigendian in
 159       yes)
 160           AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
 161           [Define to 1 if your processor stores words of floats with
 162            the most significant byte first]) ;;
 163   esac
 164 ])
 165
 166
 167 # FP_EVAL_STDERR(COMMAND)
 168 # -----------------------
 169 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
 170 # into the file conftest.err and the exit status in the variable fp_status.
 171 AC_DEFUN([FP_EVAL_STDERR],
 172 [{ (eval $1) 2>conftest.er1
 173   fp_status=$?
 174   grep -v '^ *+' conftest.er1 >conftest.err
 175   rm -f conftest.er1
 176   (exit $fp_status); }[]dnl
 177 ])# FP_EVAL_STDERR
 178
 179
 180 # FP_ARG_WITH_PATH_GNU_PROG
 181 # --------------------
 182 # XXX
 183 #
 184 # $1 = the variable to set
 185 # $2 = the command to look for
 186 #
 187 AC_DEFUN([FP_ARG_WITH_PATH_GNU_PROG],
 188 [
 189 AC_ARG_WITH($2,
 190 [AC_HELP_STRING([--with-$2=ARG],
 191         [Use ARG as the path to $2 [default=autodetect]])],
 192 [
 193     if test "$HostOS" = "mingw32"
 194     then
 195         AC_MSG_WARN([Request to use $withval will be ignored])
 196     else
 197         $1=$withval
 198     fi
 199 ],
 200 [
 201     if test "$HostOS" != "mingw32"
 202     then
 203         AC_PATH_PROG([$1], [$2])
 204         if test -z "$$1"
 205         then
 206             AC_MSG_ERROR([cannot find $2 in your PATH, no idea how to link])
 207         fi
 208     fi
 209 ]
 210 )
 211 ]) # FP_ARG_WITH_PATH_GNU_PROG
 212
 213
 214 # FP_PROG_CONTEXT_DIFF
 215 # --------------------
 216 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
 217 #
 218 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
 219 #
 220 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
 221 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
 222 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
 223 [echo foo > conftest1
 224 echo foo > conftest2
 225 fp_cv_context_diff=no
 226 for fp_var in '-U 1' '-u1' '-C 1' '-c1'
 227 do
 228   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
 229     fp_cv_context_diff="diff $fp_var"
 230     break
 231   fi
 232 done])
 233 if test x"$fp_cv_context_diff" = xno; then
 234    AC_MSG_ERROR([cannot figure out how to do context diffs])
 235 fi
 236 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
 237 ])# FP_PROG_CONTEXT_DIFF
 238
 239
 240 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
 241 # --------------------------------------------------------
 242 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
 243 # compilation. Execute IF-FAILS when unable to determine the value. Works for
 244 # cross-compilation, too.
 245 #
 246 # Implementation note: We are lazy and use an internal autoconf macro, but it
 247 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
 248 # little risk.
 249 AC_DEFUN([FP_COMPUTE_INT],
 250 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
 251 ])# FP_COMPUTE_INT
 252
 253
 254 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
 255 # ------------------------------------------------------------------
 256 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
 257 # given type. Defines ALIGNMENT_TYPE.
 258 AC_DEFUN([FP_CHECK_ALIGNMENT],
 259 [AS_LITERAL_IF(m4_translit([[$1]], [*], [p]), [],
 260                [AC_FATAL([$0: requires literal arguments])])[]dnl
 261 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 262 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 263 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 264 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 265   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 266                  [fp_Cache],
 267                  [AC_INCLUDES_DEFAULT([$3])],
 268                  [AC_MSG_ERROR([cannot compute alignment ($1)
 269 See `config.log' for more details.], [77])])
 270 else
 271   fp_Cache=0
 272 fi])[]dnl
 273 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 274 m4_popdef([fp_Cache])[]dnl
 275 ])# FP_CHECK_ALIGNMENT
 276
 277
 278 # FP_LEADING_UNDERSCORE
 279 # ---------------------
 280 # Test for determining whether symbol names have a leading underscore. We assume
 281 # that they _haven't_ if anything goes wrong. Sets the output variable
 282 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 283 #
 284 # Some nlist implementations seem to try to be compatible by ignoring a leading
 285 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 286 # checking for *no* leading underscore first. Sigh.  --SDM
 287 #
 288 # Similarly on OpenBSD, but this test doesn't help. -- dons
 289 AC_DEFUN([FP_LEADING_UNDERSCORE],
 290 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 291 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 292 # Hack!: nlist() under Digital UNIX insist on there being an _,
 293 # but symbol table listings shows none. What is going on here?!?
 294 #
 295 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 296 # the underscoredness of that "platform"
 297 case $HostPlatform in
 298 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 299   case $build in
 300     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 301     *) fptools_cv_leading_underscore=no ;;
 302   esac ;;
 303 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 304 *cygwin32) fptools_cv_leading_underscore=yes;;
 305 *mingw32) fptools_cv_leading_underscore=yes;;
 306
 307     # HACK: Apple doesn't seem to provide nlist in the 64-bit-libraries
 308 x86_64-apple-darwin*) fptools_cv_leading_underscore=yes;;
 309
 310 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 311 #include <nlist.h>
 312 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 313 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 314 #endif
 315
 316 int main(argc, argv)
 317 int argc;
 318 char **argv;
 319 {
 320 #ifdef HAVE_NLIST_H
 321     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 322         exit(1);
 323     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 324         exit(0);
 325 #endif
 326     exit(1);
 327 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 328 ;;
 329 esac]);
 330 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 331 if test x"$fptools_cv_leading_underscore" = xyes; then
 332    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 333 fi])# FP_LEADING_UNDERSCORE
 334
 335
 336 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 337 # ----------------------------------------------------------------------------------
 338 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 339 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 340 AC_DEFUN([FP_COMPARE_VERSIONS],
 341 [fp_version1=$1; fp_version2=$3
 342 fp_save_IFS=$IFS; IFS='.'
 343 while test x"$fp_version1" != x || test x"$fp_version2" != x
 344 do
 345
 346   set dummy $fp_version1; shift
 347   fp_num1=""
 348   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 349   test x"$fp_num1" = x && fp_num1="0"
 350   fp_version1="[$]*"
 351
 352   set dummy $fp_version2; shift
 353   fp_num2=""
 354   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 355   test x"$fp_num2" = x && fp_num2="0"
 356   fp_version2="[$]*"
 357
 358   test "$fp_num1" = "$fp_num2" || break;
 359 done
 360 IFS=$fp_save_IFS
 361 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 362 ])# FP_COMPARE_VERSIONS
 363
 364
 365 dnl
 366 dnl Check for GreenCard and version.
 367 dnl
 368 AC_DEFUN([FPTOOLS_GREENCARD],
 369 [
 370 AC_PATH_PROG(GreenCardCmd,greencard)
 371 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 372 changequote(, )dnl
 373 [if test x"$GreenCardCmd" != x; then
 374    fptools_cv_greencard_version="`$GreenCardCmd --version |
 375                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 376 else
 377    fptools_cv_greencard_version=""
 378 fi
 379 changequote([, ])dnl
 380 ])
 381 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 382   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 383 GreenCardVersion=$fptools_cv_greencard_version
 384 AC_SUBST(GreenCardVersion)
 385 ])
 386
 387 dnl
 388 dnl Check for Happy and version.  If we're building GHC, then we need
 389 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 390 dnl for a happy source tree and point the build system at that instead.
 391 dnl
 392 AC_DEFUN([FPTOOLS_HAPPY],
 393 [AC_PATH_PROG(HappyCmd,happy,)
 394 # Happy is passed to Cabal, so we need a native path
 395 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 396    test "${OSTYPE}"      != "msys"                  && \
 397    test "${HappyCmd}"    != ""
 398 then
 399     # Canonicalise to <drive>:/path/to/gcc
 400     HappyCmd=`cygpath -m "${HappyCmd}"`
 401     AC_MSG_NOTICE([normalized happy command to $HappyCmd])
 402 fi
 403
 404 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 405 changequote(, )dnl
 406 [if test x"$HappyCmd" != x; then
 407    fptools_cv_happy_version=`"$HappyCmd" -v |
 408                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'` ;
 409 else
 410    fptools_cv_happy_version="";
 411 fi;
 412 changequote([, ])dnl
 413 ])
 414 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
 415 then
 416     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.16],
 417       [AC_MSG_ERROR([Happy version 1.16 or later is required to compile GHC.])])[]
 418 fi
 419 HappyVersion=$fptools_cv_happy_version;
 420 AC_SUBST(HappyVersion)
 421 ])
 422
 423 dnl
 424 dnl Check for Alex and version.  If we're building GHC, then we need
 425 dnl at least Alex version 2.0.1.
 426 dnl
 427 AC_DEFUN([FPTOOLS_ALEX],
 428 [
 429 AC_PATH_PROG(AlexCmd,alex,)
 430 # Alex is passed to Cabal, so we need a native path
 431 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 432    test "${OSTYPE}"      != "msys"                  && \
 433    test "${AlexCmd}"     != ""
 434 then
 435     # Canonicalise to <drive>:/path/to/gcc
 436     AlexCmd=`cygpath -m "${AlexCmd}"`
 437 fi
 438
 439 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 440 changequote(, )dnl
 441 [if test x"$AlexCmd" != x; then
 442    fptools_cv_alex_version=`"$AlexCmd" -v |
 443                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'` ;
 444 else
 445    fptools_cv_alex_version="";
 446 fi;
 447 changequote([, ])dnl
 448 ])
 449 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
 450 then
 451     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.1.0],
 452       [AC_MSG_ERROR([Alex version 2.1.0 or later is required to compile GHC.])])[]
 453 fi
 454 AlexVersion=$fptools_cv_alex_version;
 455 AC_SUBST(AlexVersion)
 456 ])
 457
 458
 459 # FP_PROG_LD_X
 460 # ------------
 461 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 462 # variable's value is empty.
 463 AC_DEFUN([FP_PROG_LD_X],
 464 [
 465 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 466 [echo 'foo() {}' > conftest.c
 467 ${CC-cc} -c conftest.c
 468 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
 469    fp_cv_ld_x=yes
 470 else
 471    fp_cv_ld_x=no
 472 fi
 473 rm -rf conftest*])
 474 if test "$fp_cv_ld_x" = yes; then
 475   LdXFlag=-x
 476 else
 477   LdXFlag=
 478 fi
 479 AC_SUBST([LdXFlag])
 480 ])# FP_PROG_LD_X
 481
 482
 483 # FP_PROG_LD_BUILD_ID
 484 # ------------
 485
 486 # Sets the output variable LdHasBuildId to YES if ld supports
 487 # --build-id, or NO otherwise.
 488 AC_DEFUN([FP_PROG_LD_BUILD_ID],
 489 [
 490 AC_CACHE_CHECK([whether ld understands --build-id], [fp_cv_ld_build_id],
 491 [echo 'foo() {}' > conftest.c
 492 ${CC-cc} -c conftest.c
 493 if ${LdCmd} -r --build-id=none -o conftest2.o conftest.o > /dev/null 2>&1; then
 494    fp_cv_ld_build_id=yes
 495 else
 496    fp_cv_ld_build_id=no
 497 fi
 498 rm -rf conftest*])
 499 if test "$fp_cv_ld_build_id" = yes; then
 500   LdHasBuildId=YES
 501 else
 502   LdHasBuildId=NO
 503 fi
 504 AC_SUBST([LdHasBuildId])
 505 ])# FP_PROG_LD_BUILD_ID
 506
 507
 508 # FP_PROG_LD_IS_GNU
 509 # -----------------
 510 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 511 # GNU ld or not.
 512 AC_DEFUN([FP_PROG_LD_IS_GNU],
 513 [
 514 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 515 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 516   fp_cv_gnu_ld=yes
 517 else
 518   fp_cv_gnu_ld=no
 519 fi])
 520 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 521 ])# FP_PROG_LD_IS_GNU
 522
 523
 524 # FP_PROG_AR
 525 # ----------
 526 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 527 # version of it. Exits if no ar can be found
 528 AC_DEFUN([FP_PROG_AR],
 529 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 530 if test -z "$fp_prog_ar_raw"; then
 531   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 532 fi
 533 fp_prog_ar="$fp_prog_ar_raw"
 534 case $HostPlatform in
 535   *mingw32) if test x${OSTYPE} != xmsys; then
 536               fp_prog_ar="`cygpath -w "${fp_prog_ar_raw}" | sed -e 's@\\\\@/@g'`"
 537               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 538             fi
 539             ;;
 540 esac
 541 ])# FP_PROG_AR
 542
 543
 544 # FP_PROG_AR_IS_GNU
 545 # -----------------
 546 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 547 AC_DEFUN([FP_PROG_AR_IS_GNU],
 548 [AC_REQUIRE([FP_PROG_AR])
 549 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 550 [if "$fp_prog_ar_raw" --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 551   fp_cv_prog_ar_is_gnu=yes
 552 else
 553   fp_cv_prog_ar_is_gnu=no
 554 fi])
 555 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 556 AC_SUBST([ArIsGNUAr], [`echo $fp_prog_ar_is_gnu | tr 'a-z' 'A-Z'`])
 557 ])# FP_PROG_AR_IS_GNU
 558
 559
 560 # FP_PROG_AR_SUPPORTS_ATFILE
 561 # -----------------
 562 # Sets fp_prog_ar_supports_atfile to yes or no, depending on whether
 563 # or not it supports the @file syntax
 564 AC_DEFUN([FP_PROG_AR_SUPPORTS_ATFILE],
 565 [AC_REQUIRE([FP_PROG_AR])
 566  AC_REQUIRE([FP_PROG_AR_ARGS])
 567 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports @file], [fp_cv_prog_ar_supports_atfile],
 568 [
 569 rm -f conftest*
 570 touch conftest.file
 571 echo conftest.file  > conftest.atfile
 572 echo conftest.file >> conftest.atfile
 573 "$fp_prog_ar_raw" $fp_prog_ar_args conftest.a @conftest.atfile > /dev/null 2>&1
 574 fp_prog_ar_supports_atfile_tmp=`"$fp_prog_ar_raw" t conftest.a 2> /dev/null | grep -c conftest.file`
 575 rm -f conftest*
 576 if test "$fp_prog_ar_supports_atfile_tmp" -eq 2
 577 then
 578   fp_cv_prog_ar_supports_atfile=yes
 579 else
 580   fp_cv_prog_ar_supports_atfile=no
 581 fi])
 582 fp_prog_ar_supports_atfile=$fp_cv_prog_ar_supports_atfile
 583 AC_SUBST([ArSupportsAtFile], [`echo $fp_prog_ar_supports_atfile | tr 'a-z' 'A-Z'`])
 584 ])# FP_PROG_AR_SUPPORTS_ATFILE
 585
 586 # FP_PROG_AR_ARGS
 587 # ---------------
 588 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 589 # to a non-Cygwin invocation of ar including these arguments.
 590 AC_DEFUN([FP_PROG_AR_ARGS],
 591 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 592 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 593 [
 594 # GNU ar needs special treatment: it appears to have problems with
 595 # object files with the same name if you use the 's' modifier, but
 596 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 597 if test $fp_prog_ar_is_gnu = yes; then
 598   fp_cv_prog_ar_args="q"
 599 else
 600   touch conftest.dummy
 601   for fp_var in clqsZ clqs cqs clq cq ; do
 602      rm -f conftest.a
 603      if "$fp_prog_ar_raw" $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 604         fp_cv_prog_ar_args=$fp_var
 605         break
 606      fi
 607   done
 608   rm -f conftest*
 609   if test -z "$fp_cv_prog_ar_args"; then
 610     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 611   fi
 612 fi])
 613 fp_prog_ar_args=$fp_cv_prog_ar_args
 614 AC_SUBST([ArCmd], ["$fp_prog_ar"])
 615 AC_SUBST([ArArgs], ["$fp_prog_ar_args"])
 616
 617 ])# FP_PROG_AR_ARGS
 618
 619
 620 # FP_PROG_AR_NEEDS_RANLIB
 621 # -----------------------
 622 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 623 # to ":" otherwise.
 624 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 625 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 626 AC_REQUIRE([FP_PROG_AR_ARGS])
 627 AC_REQUIRE([AC_PROG_CC])
 628 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 629 [if test $fp_prog_ar_is_gnu = yes; then
 630   fp_cv_prog_ar_needs_ranlib=no
 631 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
 632   # It's quite tedious to check for Apple's crazy timestamps in .a files,
 633   # so we hardcode it.
 634   fp_cv_prog_ar_needs_ranlib=yes
 635 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 636   fp_cv_prog_ar_needs_ranlib=no
 637 else
 638   fp_cv_prog_ar_needs_ranlib=yes
 639 fi])
 640 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 641    AC_PROG_RANLIB
 642 else
 643   RANLIB=":"
 644   AC_SUBST([RANLIB])
 645 fi
 646 ])# FP_PROG_AR_NEEDS_RANLIB
 647
 648
 649 dnl
 650 dnl AC_SHEBANG_PERL - can we she-bang perl?
 651 dnl
 652 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
 653 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 654 [echo "#!$PerlCmd"'
 655 exit $1;
 656 ' > conftest
 657 chmod u+x conftest
 658 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 659 if test $? -ne 69; then
 660    fptools_cv_shebang_perl=yes
 661 else
 662    fptools_cv_shebang_perl=no
 663 fi
 664 rm -f conftest
 665 ])])
 666
 667
 668 # FP_GCC_VERSION
 669 # -----------
 670 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 671 # output variable GccVersion.
 672 AC_DEFUN([FP_GCC_VERSION],
 673 [AC_REQUIRE([AC_PROG_CC])
 674 if test -z "$GCC"
 675 then
 676   AC_MSG_ERROR([gcc is required])
 677 fi
 678 GccLT34=
 679 AC_CACHE_CHECK([version of gcc], [fp_cv_gcc_version],
 680 [
 681     fp_cv_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
 682     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.0],
 683                         [AC_MSG_ERROR([Need at least gcc version 3.0 (3.4+ recommended)])])
 684     # See #2770: gcc 2.95 doesn't work any more, apparently.  There probably
 685     # isn't a very good reason for that, but for now just make configure
 686     # fail.
 687     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.4], GccLT34=YES)
 688 ])
 689 AC_SUBST([GccVersion], [$fp_cv_gcc_version])
 690 AC_SUBST(GccLT34)
 691 ])# FP_GCC_VERSION
 692
 693 dnl Small feature test for perl version. Assumes PerlCmd
 694 dnl contains path to perl binary.
 695 dnl
 696 dnl (Perl versions prior to v5.6 does not contain the string "v5";
 697 dnl instead they display version strings such as "version 5.005".)
 698 dnl
 699 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
 700 [$PerlCmd -v >conftest.out 2>&1
 701    if grep "v5" conftest.out >/dev/null 2>&1; then
 702       :
 703    else
 704       AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
 705    fi
 706 rm -fr conftest*
 707 ])
 708
 709
 710 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 711 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 712 # -----------------------------------------------------
 713 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 714 # of PROG-TO-CHECK-FOR when found.
 715 AC_DEFUN([FP_CHECK_PROG],
 716 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 717 )# FP_CHECK_PROC
 718
 719
 720 # FP_PROG_FIND
 721 # ------------
 722 # Find a non-WinDoze version of the "find" utility.
 723 AC_DEFUN([FP_PROG_FIND],
 724 [AC_PATH_PROGS([fp_prog_find], [gfind find], find)
 725 echo foo > conftest.txt
 726 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 727 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 728   # OK, looks like a real "find".
 729   case $HostPlatform in
 730     *mingw32)
 731       if test x${OSTYPE} != xmsys
 732       then
 733             fp_prog_find="`cygpath --mixed ${fp_prog_find}`"
 734         AC_MSG_NOTICE([normalized find command to $fp_prog_find])
 735       fi ;;
 736     *) ;;
 737   esac
 738   FindCmd="$fp_prog_find"
 739 else
 740   # Found a poor WinDoze version of "find", ignore it.
 741   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 742   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 743 fi
 744 rm -f conftest.txt conftest.out
 745 AC_SUBST([FindCmd])[]dnl
 746 ])# FP_PROG_FIND
 747
 748
 749 # FP_PROG_SORT
 750 # ------------
 751 # Find a Unix-like sort
 752 AC_DEFUN([FP_PROG_SORT],
 753 [AC_PATH_PROG([fp_prog_sort], [sort])
 754 echo conwip > conftest.txt
 755 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
 756 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
 757   # The goods
 758   SortCmd="$fp_prog_sort"
 759 else
 760   # Summink else..pick next one.
 761   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
 762   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
 763 fi
 764 rm -f conftest.txt conftest.out
 765 AC_SUBST([SortCmd])[]dnl
 766 ])# FP_PROG_SORT
 767
 768 dnl
 769 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 770 dnl values of the second argument to the result of running
 771 dnl the commands given by the third. It does not cache its
 772 dnl result, so it is suitable for checks which should be
 773 dnl run every time.
 774 dnl
 775 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
 776 [AC_MSG_CHECKING([$1])
 777  $3
 778  AC_MSG_RESULT([$][$2])
 779 ])
 780
 781 dnl
 782 dnl FPTOOLS_GHC_VERSION(version)
 783 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 784 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 785 dnl
 786 dnl Test for version of installed ghc.  Uses $GHC.
 787 dnl [original version pinched from c2hs]
 788 dnl
 789 AC_DEFUN([FPTOOLS_GHC_VERSION],
 790 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 791 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 792   cat conftestghc >&AS_MESSAGE_LOG_FD
 793 #Useless Use Of cat award...
 794   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 795   rm -fr conftest*
 796   if test "[$]fptools_version_of_ghc" = ""
 797   then
 798     fptools_version_of_ghc='unknown'
 799   fi
 800 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 801 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 802 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 803 #
 804 if test "[$]fptools_version_of_ghc[_pl]" = ""
 805 then
 806   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 807   fptools_version_of_ghc[_pl]="0"
 808 else
 809   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 810 fi
 811 #
 812 ifelse($#, [1], [dnl
 813 [$1]="[$]fptools_version_of_ghc[_all]"
 814 ], $#, [2], [dnl
 815 [$1]="[$]fptools_version_of_ghc[_major]"
 816 [$2]="[$]fptools_version_of_ghc[_minor]"
 817 ], $#, [3], [dnl
 818 [$1]="[$]fptools_version_of_ghc[_major]"
 819 [$2]="[$]fptools_version_of_ghc[_minor]"
 820 [$3]="[$]fptools_version_of_ghc[_pl]"
 821 ], $#, [4], [dnl
 822 [$1]="[$]fptools_version_of_ghc[_all]"
 823 [$2]="[$]fptools_version_of_ghc[_major]"
 824 [$3]="[$]fptools_version_of_ghc[_minor]"
 825 [$4]="[$]fptools_version_of_ghc[_pl]"
 826 ])
 827 ])
 828 ])dnl
 829
 830
 831 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 832 # ---------------------------------------------------------------------------------
 833 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 834 # additional flexibility of specifying the PROLOGUE and BODY.
 835 AC_DEFUN([FP_CHECK_FUNC],
 836 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 837 AC_CACHE_CHECK([for $1], fp_func,
 838 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 839                 [AS_VAR_SET(fp_func, yes)],
 840                 [AS_VAR_SET(fp_func, no)])])
 841 AS_IF([test AS_VAR_GET(fp_func) = yes],
 842       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 843                 [Define to 1 if you have the `]$1[' function.]) $4],
 844       [$5])dnl
 845 AS_VAR_POPDEF([fp_func])dnl
 846 ])# FP_CHECK_FUNC
 847
 848
 849 # FP_GEN_DOCBOOK_XML
 850 # ------------------
 851 # Generates a DocBook XML V4.5 document in conftest.xml.
 852 #
 853 # It took a lot of experimentation to find a document that will cause
 854 # xsltproc to fail with an error code when the relevant
 855 # stylesheets/DTDs are not found.  I couldn't make xsltproc fail with
 856 # a single-file document, it seems a multi-file document is needed.
 857 # -- SDM 2009-06-03
 858 #
 859 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 860 [rm -f conftest.xml conftest-book.xml
 861 cat > conftest.xml << EOF
 862 <?xml version="1.0" encoding="iso-8859-1"?>
 863 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.5//EN"
 864    "http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd" [[
 865 <!ENTITY conftest-book SYSTEM "conftest-book.xml">
 866 ]]>
 867 <book id="test">
 868 &conftest-book;
 869 </book>
 870 EOF
 871 cat >conftest-book.xml << EOF
 872 <?xml version="1.0" encoding="iso-8859-1"?>
 873   <title>A DocBook &ldquo;Test Document&rdquo;</title>
 874   <chapter id="id-one">
 875     <title>A Chapter Title</title>
 876     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 877   </chapter>
 878   <chapter id="id-two">
 879     <title>Another Chapter Title</title>
 880     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 881   </chapter>
 882 EOF
 883 ]) # FP_GEN_DOCBOOK_XML
 884
 885
 886 # FP_PROG_DBLATEX
 887 # ----------------
 888 # Sets the output variable DblatexCmd to the full path of dblatex,
 889 # which we use for building PDF and PS docs.
 890 # DblatexCmd is empty if dblatex could not be found.
 891 AC_DEFUN([FP_PROG_DBLATEX],
 892 [AC_PATH_PROG([DblatexCmd], [dblatex])
 893 if test -z "$DblatexCmd"; then
 894   AC_MSG_WARN([cannot find dblatex in your PATH, you will not be able to build the PDF and PS documentation])
 895 fi
 896 ])# FP_PROG_DBLATEX
 897
 898
 899 # FP_PROG_XSLTPROC
 900 # ----------------
 901 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 902 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 903 AC_DEFUN([FP_PROG_XSLTPROC],
 904 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 905 if test -z "$XsltprocCmd"; then
 906   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the HTML documentation])
 907 fi
 908 ])# FP_PROG_XSLTPROC
 909
 910
 911 # FP_DOCBOOK_XSL
 912 # ----------------------------
 913 # Check that we can process a DocBook XML document to HTML using xsltproc.
 914 AC_DEFUN([FP_DOCBOOK_XSL],
 915 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 916 if test -n "$XsltprocCmd"; then
 917   AC_CACHE_CHECK([for DocBook XSL stylesheet], fp_cv_dir_docbook_xsl,
 918   [FP_GEN_DOCBOOK_XML
 919   fp_cv_dir_docbook_xsl=no
 920   if $XsltprocCmd --nonet http://docbook.sourceforge.net/release/xsl/current/html/chunk.xsl conftest.xml > /dev/null 2>&1; then
 921      fp_cv_dir_docbook_xsl=yes
 922   fi
 923   rm -rf conftest*])
 924 fi
 925 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 926   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 927   HAVE_DOCBOOK_XSL=NO
 928 else
 929   HAVE_DOCBOOK_XSL=YES
 930 fi
 931 AC_SUBST([HAVE_DOCBOOK_XSL])
 932 ])# FP_DOCBOOK_XSL
 933
 934
 935 # FP_PROG_XMLLINT
 936 # ----------------
 937 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 938 # xmllint. XmllintCmd is empty if xmllint could not be found.
 939 AC_DEFUN([FP_PROG_XMLLINT],
 940 [AC_PATH_PROG([XmllintCmd], [xmllint])
 941 if test -z "$XmllintCmd"; then
 942   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 943 fi
 944 ])# FP_PROG_XMLLINT
 945
 946
 947 # FP_CHECK_DOCBOOK_DTD
 948 # --------------------
 949 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 950 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 951 if test -n "$XmllintCmd"; then
 952   AC_MSG_CHECKING([for DocBook DTD])
 953   FP_GEN_DOCBOOK_XML
 954   if $XmllintCmd --nonet --valid --noout conftest.xml ; then
 955     AC_MSG_RESULT([ok])
 956   else
 957     AC_MSG_RESULT([failed])
 958     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.5, you will not be able to validate your documentation])
 959     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 960   fi
 961   rm -rf conftest*
 962 fi
 963 ])# FP_CHECK_DOCBOOK_DTD
 964
 965
 966 # FP_GEN_FO
 967 # ------------------
 968 # Generates a formatting objects document in conftest.fo.
 969 AC_DEFUN([FP_GEN_FO],
 970 [rm -f conftest.fo
 971 cat > conftest.fo << EOF
 972 <?xml version="1.0"?>
 973 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 974   <fo:layout-master-set>
 975     <fo:simple-page-master master-name="blank">
 976       <fo:region-body/>
 977     </fo:simple-page-master>
 978   </fo:layout-master-set>
 979   <fo:page-sequence master-reference="blank">
 980     <fo:flow flow-name="xsl-region-body">
 981       <fo:block>
 982         Test!
 983       </fo:block>
 984     </fo:flow>
 985   </fo:page-sequence>
 986 </fo:root>
 987 EOF
 988 ]) # FP_GEN_FO
 989
 990
 991 # FP_PROG_FOP
 992 # -----------
 993 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 994 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 995 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 996 AC_DEFUN([FP_PROG_FOP],
 997 [AC_PATH_PROGS([FopCmd1], [fop fop.sh])
 998 if test -n "$FopCmd1"; then
 999   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
1000     [FP_GEN_FO
1001     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
1002       fp_cv_fop_usability=yes
1003     else
1004       fp_cv_fop_usability=no
1005     fi
1006     rm -rf conftest*])
1007   if test x"$fp_cv_fop_usability" = xyes; then
1008      FopCmd=$FopCmd1
1009   fi
1010 fi
1011 if test -z "$FopCmd"; then
1012   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
1013   FopCmd=$FopCmd2
1014 fi
1015 AC_SUBST([FopCmd])
1016 ])# FP_PROG_FOP
1017
1018
1019 # FP_PROG_HSTAGS
1020 # ----------------
1021 # Sets the output variable HstagsCmd to the full Haskell tags program path.
1022 # HstagsCmd is empty if no such program could be found.
1023 AC_DEFUN([FP_PROG_HSTAGS],
1024 [AC_PATH_PROG([HstagsCmd], [hasktags])
1025 if test -z "$HstagsCmd"; then
1026   AC_MSG_WARN([cannot find hasktags in your PATH, you will not be able to build the tags])
1027 fi
1028 ])# FP_PROG_HSTAGS
1029
1030
1031 # FP_PROG_GHC_PKG
1032 # ----------------
1033 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
1034 # WithGhc. Sets the output variable GhcPkgCmd.
1035 AC_DEFUN([FP_PROG_GHC_PKG],
1036 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
1037 [
1038 # If we are told to use ghc-stage2, then we're using an in-tree
1039 # compiler. In this case, we just want ghc-pkg, not ghc-pkg-stage2,
1040 # so we sed off -stage[0-9]$. However, if we are told to use
1041 # ghc-6.12.1 then we want to use ghc-pkg-6.12.1, so we keep any
1042 # other suffix.
1043 fp_ghc_pkg_guess=`echo $WithGhc | sed -e 's/-stage@<:@0-9@:>@$//' -e 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
1044 if "$fp_ghc_pkg_guess" list > /dev/null 2>&1; then
1045   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
1046 else
1047   AC_MSG_ERROR([Cannot find matching ghc-pkg])
1048 fi])
1049 GhcPkgCmd=$fp_cv_matching_ghc_pkg
1050 AC_SUBST([GhcPkgCmd])
1051 ])# FP_PROG_GHC_PKG
1052
1053
1054 # FP_GCC_EXTRA_FLAGS
1055 # ------------------
1056 # Determine which extra flags we need to pass gcc when we invoke it
1057 # to compile .hc code.
1058 #
1059 # -fwrapv is needed for gcc to emit well-behaved code in the presence of
1060 # integer wrap around. (Trac #952)
1061 #
1062 AC_DEFUN([FP_GCC_EXTRA_FLAGS],
1063 [AC_REQUIRE([FP_GCC_VERSION])
1064 AC_CACHE_CHECK([for extra options to pass gcc when compiling via C], [fp_cv_gcc_extra_opts],
1065 [fp_cv_gcc_extra_opts=
1066  FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.4],
1067   [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fwrapv"],
1068   [])
1069 ])
1070 AC_SUBST([GccExtraViaCOpts],$fp_cv_gcc_extra_opts)
1071 ])
1072
1073
1074 # FP_SETUP_PROJECT_VERSION
1075 # ---------------------
1076 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
1077 [
1078 if test "$RELEASE" = "NO"; then
1079     AC_MSG_CHECKING([for GHC version date])
1080     if test -f VERSION_DATE; then
1081         PACKAGE_VERSION=${PACKAGE_VERSION}.`cat VERSION_DATE`
1082         AC_MSG_RESULT(given $PACKAGE_VERSION)
1083     elif test -d .git; then
1084         changequote(, )dnl
1085         ver_date=`git log -n 1 --date=short --pretty=format:%ci | cut -d ' ' -f 1 | tr -d -`
1086         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
1087         changequote([, ])dnl
1088                 AC_MSG_ERROR([failed to detect version date: check that git is in your path])
1089         fi
1090         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
1091         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
1092     elif test -d _darcs; then
1093         # TODO: Remove this branch after conversion to Git
1094         changequote(, )dnl
1095         ver_date=`darcs changes --quiet --no-summary --xml | head -500 | grep 'date=' | sed "s/^.*date='\([0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]\).*$/\1/g" | ${SortCmd} -n | tail -1`
1096         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
1097         changequote([, ])dnl
1098                 AC_MSG_ERROR([failed to detect version date: check that darcs is in your path])
1099         fi
1100         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
1101         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
1102     elif test -f VERSION; then
1103         PACKAGE_VERSION=`cat VERSION`
1104         AC_MSG_RESULT(given $PACKAGE_VERSION)
1105     else
1106         AC_MSG_WARN([cannot determine snapshot version: no .git or _darcs directory and no VERSION file])
1107     fi
1108 fi
1109
1110 # Some renamings
1111 AC_SUBST([ProjectName], [$PACKAGE_NAME])
1112 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
1113
1114 # Split PACKAGE_VERSION into (possibly empty) parts
1115 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1116 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1117 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1118 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1119
1120 # Calculate project version as an integer, using 2 digits for minor version
1121 case $VERSION_MINOR in
1122   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
1123   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
1124   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
1125 esac
1126 AC_SUBST([ProjectVersionInt])
1127
1128 # The project patchlevel is zero unless stated otherwise
1129 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
1130
1131 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
1132 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
1133
1134 AC_SUBST([ProjectPatchLevel])
1135 ])# FP_SETUP_PROJECT_VERSION
1136
1137
1138 # Check for a working timer_create().  We need a pretty detailed check
1139 # here, because there exist partially-working implementations of
1140 # timer_create() in certain versions of Linux (see bug #1933).
1141 #
1142 AC_DEFUN([FP_CHECK_TIMER_CREATE],
1143   [AC_CACHE_CHECK([for a working timer_create(CLOCK_REALTIME)],
1144     [fptools_cv_timer_create_works],
1145     [AC_TRY_RUN([
1146 #include <stdio.h>
1147 #ifdef HAVE_STDLIB_H
1148 #include <stdlib.h>
1149 #endif
1150 #ifdef HAVE_TIME_H
1151 #include <time.h>
1152 #endif
1153 #ifdef HAVE_SIGNAL_H
1154 #include <signal.h>
1155 #endif
1156 #ifdef HAVE_UNISTD_H
1157 #include <unistd.h>
1158 #endif
1159
1160 static volatile int tock = 0;
1161 static void handler(int i)
1162 {
1163    tock = 1;
1164 }
1165
1166 static void timeout(int i)
1167 {
1168   // timer_settime() has been known to hang, so just in case
1169   // we install a 1-second timeout (see #2257)
1170   exit(99);
1171 }
1172
1173 int main(int argc, char *argv[])
1174 {
1175
1176     struct sigevent ev;
1177     timer_t timer;
1178     struct itimerspec it;
1179     struct sigaction action;
1180     int m,n,count = 0;
1181
1182     ev.sigev_notify = SIGEV_SIGNAL;
1183     ev.sigev_signo  = SIGVTALRM;
1184
1185     action.sa_handler = handler;
1186     action.sa_flags = 0;
1187     sigemptyset(&action.sa_mask);
1188     if (sigaction(SIGVTALRM, &action, NULL) == -1) {
1189         fprintf(stderr,"SIGVTALRM problem\n");
1190         exit(3);
1191     }
1192
1193     action.sa_handler = timeout;
1194     action.sa_flags = 0;
1195     sigemptyset(&action.sa_mask);
1196     if (sigaction(SIGALRM, &action, NULL) == -1) {
1197       fprintf(stderr,"SIGALRM problem\n");
1198       exit(3);
1199     }
1200     alarm(1);
1201
1202     if (timer_create(CLOCK_PROCESS_CPUTIME_ID, &ev, &timer) != 0) {
1203         fprintf(stderr,"No CLOCK_PROCESS_CPUTIME_ID timer\n");
1204        exit(1);
1205     }
1206
1207     it.it_value.tv_sec = 0;
1208     it.it_value.tv_nsec = 1;
1209     it.it_interval = it.it_value;
1210     if (timer_settime(timer, 0, &it, NULL) != 0) {
1211         fprintf(stderr,"settime problem\n");
1212         exit(4);
1213     }
1214
1215     tock = 0;
1216
1217     for(n = 3; n < 20000; n++){
1218         for(m = 2; m <= n/2; m++){
1219             if (!(n%m)) count++;
1220             if (tock) goto out;
1221         }
1222     }
1223 out:
1224
1225     if (!tock) {
1226         fprintf(stderr,"no CLOCK_PROCESS_CPUTIME_ID signal\n");
1227         exit(5);
1228     }
1229
1230     timer_delete(timer);
1231
1232     if (timer_create(CLOCK_REALTIME, &ev, &timer) != 0) {
1233         fprintf(stderr,"No CLOCK_REALTIME timer\n");
1234         exit(2);
1235     }
1236
1237     it.it_value.tv_sec = 0;
1238     it.it_value.tv_nsec = 1000000;
1239     it.it_interval = it.it_value;
1240     if (timer_settime(timer, 0, &it, NULL) != 0) {
1241         fprintf(stderr,"settime problem\n");
1242         exit(4);
1243     }
1244
1245     tock = 0;
1246
1247     usleep(3000);
1248
1249     if (!tock) {
1250         fprintf(stderr,"no CLOCK_REALTIME signal\n");
1251         exit(5);
1252     }
1253
1254     timer_delete(timer);
1255
1256     exit(0);
1257 }
1258      ],
1259      [fptools_cv_timer_create_works=yes],
1260      [fptools_cv_timer_create_works=no])
1261   ])
1262 case $fptools_cv_timer_create_works in
1263     yes) AC_DEFINE([USE_TIMER_CREATE], 1,
1264                    [Define to 1 if we can use timer_create(CLOCK_PROCESS_CPUTIME_ID,...)]);;
1265 esac
1266 ])
1267
1268 # FP_ICONV
1269 # -------------
1270 AC_DEFUN([FP_ICONV],
1271 [
1272   dnl--------------------------------------------------------------------
1273   dnl * Deal with arguments telling us iconv is somewhere odd
1274   dnl--------------------------------------------------------------------
1275
1276   dnl Note: ICONV_LIB_DIRS and ICONV_INCLUDE_DIRS are not predefined
1277   dnl to the empty string to allow them to be overridden from the
1278   dnl environment.
1279
1280   AC_ARG_WITH([iconv-includes],
1281     [AC_HELP_STRING([--with-iconv-includes],
1282       [directory containing iconv.h])],
1283       [ICONV_INCLUDE_DIRS=$withval])
1284
1285   AC_ARG_WITH([iconv-libraries],
1286     [AC_HELP_STRING([--with-iconv-libraries],
1287       [directory containing iconv library])],
1288       [ICONV_LIB_DIRS=$withval])
1289
1290   AC_SUBST(ICONV_INCLUDE_DIRS)
1291   AC_SUBST(ICONV_LIB_DIRS)
1292 ])# FP_ICONV
1293
1294 # FP_GMP
1295 # -------------
1296 AC_DEFUN([FP_GMP],
1297 [
1298   dnl--------------------------------------------------------------------
1299   dnl * Deal with arguments telling us gmp is somewhere odd
1300   dnl--------------------------------------------------------------------
1301
1302   AC_ARG_WITH([gmp-includes],
1303     [AC_HELP_STRING([--with-gmp-includes],
1304       [directory containing gmp.h])],
1305       [GMP_INCLUDE_DIRS=$withval])
1306
1307   AC_ARG_WITH([gmp-libraries],
1308     [AC_HELP_STRING([--with-gmp-libraries],
1309       [directory containing gmp library])],
1310       [GMP_LIB_DIRS=$withval])
1311
1312   AC_SUBST(GMP_INCLUDE_DIRS)
1313   AC_SUBST(GMP_LIB_DIRS)
1314 ])# FP_GMP
1315
1316 # FP_CHECK_MACOSX_DEPLOYMENT_TARGET
1317 # ---------------------------------
1318 AC_DEFUN([FP_CHECK_MACOSX_DEPLOYMENT_TARGET],
1319 [
1320 if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple"; then
1321   AC_MSG_CHECKING([Mac OS X deployment target])
1322   case $FP_MACOSX_DEPLOYMENT_TARGET in
1323     none)  ;;
1324     10.4)  MACOSX_DEPLOYMENT_VERSION=10.4
1325            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1326            ;;
1327     10.4u) MACOSX_DEPLOYMENT_VERSION=10.4
1328            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1329            ;;
1330     *)     MACOSX_DEPLOYMENT_VERSION=$FP_MACOSX_DEPLOYMENT_TARGET
1331            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX${FP_MACOSX_DEPLOYMENT_TARGET}.sdk
1332            ;;
1333   esac
1334   if test "x$FP_MACOSX_DEPLOYMENT_TARGET" = "xnone"; then
1335     AC_MSG_RESULT(none)
1336   else
1337     if test ! -d $MACOSX_DEPLOYMENT_SDK; then
1338       AC_MSG_ERROR([Unknown deployment target $FP_MACOSX_DEPLOYMENT_TARGET])
1339     fi
1340     AC_MSG_RESULT([${MACOSX_DEPLOYMENT_VERSION} (${MACOSX_DEPLOYMENT_SDK})])
1341   fi
1342 fi
1343 ])
1344
1345 # --------------------------------------------------------------
1346 # Calculate absolute path to build tree
1347 # --------------------------------------------------------------
1348
1349 AC_DEFUN([FP_INTREE_GHC_PWD],[
1350 AC_MSG_NOTICE(Building in-tree ghc-pwd)
1351     dnl This would be
1352     dnl     make -C utils/ghc-pwd clean && make -C utils/ghc-pwd
1353     dnl except we don't want to have to know what make is called. Sigh.
1354     rm -rf utils/ghc-pwd/dist-boot
1355     mkdir  utils/ghc-pwd/dist-boot
1356     if ! "$WithGhc" -v0 -no-user-package-conf -hidir utils/ghc-pwd/dist-boot -odir utils/ghc-pwd/dist-boot -stubdir utils/ghc-pwd/dist-boot --make utils/ghc-pwd/Main.hs -o utils/ghc-pwd/dist-boot/ghc-pwd
1357     then
1358         AC_MSG_ERROR([Building ghc-pwd failed])
1359     fi
1360
1361     GHC_PWD=utils/ghc-pwd/dist-boot/ghc-pwd
1362 ])
1363
1364 AC_DEFUN([FP_BINDIST_GHC_PWD],[
1365     GHC_PWD=utils/ghc-pwd/dist/build/tmp/ghc-pwd
1366 ])
1367
1368 AC_DEFUN([FP_FIND_ROOT],[
1369 AC_MSG_CHECKING(for path to top of build tree)
1370     hardtop=`$GHC_PWD`
1371
1372     dnl Remove common automounter nonsense
1373     hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|'`
1374
1375     if ! test -d "$hardtop"; then
1376         AC_MSG_ERROR([cannot determine current directory])
1377     fi
1378
1379     dnl We don't support building in directories with spaces.
1380     case "$hardtop" in
1381     *' '*)
1382         AC_MSG_ERROR([
1383         The build system does not support building in a directory
1384         containing space characters.
1385         Suggestion: move the build tree somewhere else.])
1386         ;;
1387     esac
1388
1389     AC_SUBST(hardtop)
1390
1391     AC_MSG_RESULT($hardtop)
1392 ])
1393
1394 # GHC_CONVERT_CPU(cpu, target_var)
1395 # --------------------------------
1396 # converts cpu from gnu to ghc naming, and assigns the result to $target_var
1397 AC_DEFUN([GHC_CONVERT_CPU],[
1398 case "$1" in
1399   alpha*)
1400     $2="alpha"
1401     ;;
1402   arm*)
1403     $2="arm"
1404     ;;
1405   hppa1.1*)
1406     $2="hppa1_1"
1407     ;;
1408   hppa*)
1409     $2="hppa"
1410     ;;
1411   i386|i486|i586|i686)
1412     $2="i386"
1413     ;;
1414   ia64)
1415     $2="ia64"
1416     ;;
1417   m68k*)
1418     $2="m68k"
1419     ;;
1420   mipseb*)
1421     $2="mipseb"
1422     ;;
1423   mipsel*)
1424     $2="mipsel"
1425     ;;
1426   mips*)
1427     $2="mips"
1428     ;;
1429   powerpc64*)
1430     $2="powerpc64"
1431     ;;
1432   powerpc*)
1433     $2="powerpc"
1434     ;;
1435   rs6000)
1436     $2="rs6000"
1437     ;;
1438   s390*)
1439     $2="s390"
1440     ;;
1441   sparc64*)
1442     $2="sparc64"
1443     ;;
1444   sparc*)
1445     $2="sparc"
1446     ;;
1447   vax)
1448     $2="vax"
1449     ;;
1450   x86_64)
1451     $2="x86_64"
1452     ;;
1453   *)
1454     echo "Unknown CPU $1"
1455     exit 1
1456     ;;
1457   esac
1458 ])
1459
1460 # GHC_CONVERT_VENDOR(vendor, target_var)
1461 # --------------------------------
1462 # converts vendor from gnu to ghc naming, and assigns the result to $target_var
1463 AC_DEFUN([GHC_CONVERT_VENDOR],[
1464   case "$1" in
1465   pc|gentoo) # like i686-pc-linux-gnu and i686-gentoo-freebsd8
1466     $2="unknown"
1467     ;;
1468   *)
1469     #pass thru by default
1470     $2="$1"
1471     ;;
1472   esac
1473 ])
1474
1475 # GHC_CONVERT_OS(os, target_var)
1476 # --------------------------------
1477 # converts os from gnu to ghc naming, and assigns the result to $target_var
1478 AC_DEFUN([GHC_CONVERT_OS],[
1479 case "$1" in
1480   linux-*|linux)
1481     $2="linux"
1482     ;;
1483   # As far as I'm aware, none of these have relevant variants
1484   freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
1485     $2="$1"
1486     ;;
1487   freebsd8) # like i686-gentoo-freebsd8
1488     $2="freebsd"
1489     ;;
1490   *)
1491     echo "Unknown OS $1"
1492     exit 1
1493     ;;
1494   esac
1495 ])
1496
1497 # BOOTSTRAPPING_GHC_INFO_FIELD
1498 # --------------------------------
1499 # If the bootstrapping compiler is >= 7.1, then set the variable
1500 # $1 to the value of the ghc --info field $2. Otherwise, set it to
1501 # $3.
1502 AC_DEFUN([BOOTSTRAPPING_GHC_INFO_FIELD],[
1503 if test $GhcCanonVersion -ge 701
1504 then
1505     $1=`"$WithGhc" --info | grep "^ ,(\"$2\"," | sed -e 's/.*","//' -e 's/")$//'`
1506 else
1507     $1=$3
1508 fi
1509 AC_SUBST($1)
1510 ])
1511
1512 # LIBRARY_VERSION(lib)
1513 # --------------------------------
1514 # Gets the version number of a library.
1515 # If $1 is ghc-prim, then we define LIBRARY_ghc_prim_VERSION as 1.2.3
1516 AC_DEFUN([LIBRARY_VERSION],[
1517 LIBRARY_[]translit([$1], [-], [_])[]_VERSION=`grep -i "^version:" libraries/$1/$1.cabal | sed "s/.* //"`
1518 AC_SUBST(LIBRARY_[]translit([$1], [-], [_])[]_VERSION)
1519 ])
1520
1521 # LocalWords:  fi