aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FP_EVAL_STDERR(COMMAND)
   8 # -----------------------
   9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  10 # into the file conftest.err and the exit status in the variable fp_status.
  11 AC_DEFUN([FP_EVAL_STDERR],
  12 [{ (eval $1) 2>conftest.er1
  13   fp_status=$?
  14   grep -v '^ *+' conftest.er1 >conftest.err
  15   rm -f conftest.er1
  16   (exit $fp_status); }[]dnl
  17 ])# FP_EVAL_STDERR
  18
  19
  20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
  21 # ---------------------------------------------------------------------
  22 # Check to see whether the compiler for the current language supports a
  23 # particular option.
  24 #
  25 # Implementation note: When given an unkown option, GCC issues an warning on
  26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
  27 # to check stderr *and* the exit value.
  28 #
  29 # Used by ghc.
  30 AC_DEFUN([FP_CHECK_FLAG],
  31 [AC_LANG_COMPILER_REQUIRE()dnl
  32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
  33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
  34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
  35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
  36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
  37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
  38 fp_save_flags="$fp_Flags"
  39 fp_Flags="$fp_Flags $1"
  40 fp_Cache=no
  41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  42   test -s conftest.err || fp_Cache=yes
  43 fi
  44 fp_Flags="$fp_save_flags"
  45 rm -f conftest.err conftest.$ac_ext])
  46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
  47 m4_popdef([fp_Cache])[]dnl
  48 m4_popdef([fp_Flags])[]dnl
  49 ])# FP_CHECK_FLAG
  50
  51
  52 # FP_PROG_CONTEXT_DIFF
  53 # --------------------
  54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  55 #
  56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  57 #
  58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  61 [echo foo > conftest1
  62 echo foo > conftest2
  63 fp_cv_context_diff=no
  64 for fp_var in '-C 1' '-c1'
  65 do
  66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  67     fp_cv_context_diff="diff $fp_var"
  68     break
  69   fi
  70 done])
  71 if test x"$fp_cv_context_diff" = xno; then
  72    AC_MSG_ERROR([cannot figure out how to do context diffs])
  73 fi
  74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  75 ])# FP_PROG_CONTEXT_DIFF
  76
  77
  78 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
  79 # --------------------------------------------------------
  80 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
  81 # compilation. Execute IF-FAILS when unable to determine the value. Works for
  82 # cross-compilation, too.
  83 #
  84 # Implementation note: We are lazy and use an internal autoconf macro, but it
  85 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
  86 # little risk.
  87 AC_DEFUN([FP_COMPUTE_INT],
  88 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
  89 ])# FP_COMPUTE_INT
  90
  91
  92 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
  93 # ------------------------------------------------------------------
  94 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
  95 # given type. Defines ALIGNMENT_TYPE.
  96 AC_DEFUN([FP_CHECK_ALIGNMENT],
  97 [AS_LITERAL_IF([$1], [],
  98                [AC_FATAL([$0: requires literal arguments])])[]dnl
  99 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 100 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 101 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 102 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 103   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 104                  [fp_Cache],
 105                  [AC_INCLUDES_DEFAULT([$3])],
 106                  [AC_MSG_ERROR([cannot compute alignment ($1)
 107 See `config.log' for more details.], [77])])
 108 else
 109   fp_Cache=0
 110 fi])[]dnl
 111 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 112 m4_popdef([fp_Cache])[]dnl
 113 ])# FP_CHECK_ALIGNMENT
 114
 115
 116 # FP_LEADING_UNDERSCORE
 117 # ---------------------
 118 # Test for determining whether symbol names have a leading underscore. We assume
 119 # that they _haven't_ if anything goes wrong. Sets the output variable
 120 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 121 #
 122 # Some nlist implementations seem to try to be compatible by ignoring a leading
 123 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 124 # checking for *no* leading underscore first. Sigh.  --SDM
 125 #
 126 # Similarly on OpenBSD, but this test doesn't help. -- dons
 127 AC_DEFUN([FP_LEADING_UNDERSCORE],
 128 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 129 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 130 # Hack!: nlist() under Digital UNIX insist on there being an _,
 131 # but symbol table listings shows none. What is going on here?!?
 132 #
 133 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 134 # the underscoredness of that "platform"
 135 case $HostPlatform in
 136 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 137   case $build in
 138     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 139     *) fptools_cv_leading_underscore=no ;;
 140   esac ;;
 141 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 142 *cygwin32) fptools_cv_leading_underscore=yes;;
 143 *mingw32) fptools_cv_leading_underscore=yes;;
 144 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 145 #include <nlist.h>
 146 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 147 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 148 #endif
 149
 150 int main(argc, argv)
 151 int argc;
 152 char **argv;
 153 {
 154 #ifdef HAVE_NLIST_H
 155     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 156         exit(1);
 157     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 158         exit(0);
 159 #endif
 160     exit(1);
 161 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 162 ;;
 163 esac]);
 164 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 165 if test x"$fptools_cv_leading_underscore" = xyes; then
 166    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 167 fi])# FP_LEADING_UNDERSCORE
 168
 169
 170 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 171 # ----------------------------------------------------------------------------------
 172 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 173 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 174 AC_DEFUN([FP_COMPARE_VERSIONS],
 175 [fp_version1=$1; fp_version2=$3
 176 fp_save_IFS=$IFS; IFS='.'
 177 while test x"$fp_version1" != x || test x"$fp_version2" != x
 178 do
 179
 180   set dummy $fp_version1; shift
 181   fp_num1=""
 182   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 183   test x"$fp_num1" = x && fp_num1="0"
 184   fp_version1="[$]*"
 185
 186   set dummy $fp_version2; shift
 187   fp_num2=""
 188   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 189   test x"$fp_num2" = x && fp_num2="0"
 190   fp_version2="[$]*"
 191
 192   test "$fp_num1" = "$fp_num2" || break;
 193 done
 194 IFS=$fp_save_IFS
 195 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 196 ])# FP_COMPARE_VERSIONS
 197
 198
 199 dnl
 200 dnl Check for GreenCard and version.
 201 dnl
 202 AC_DEFUN([FPTOOLS_GREENCARD],
 203 [
 204 AC_PATH_PROG(GreenCardCmd,greencard)
 205 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 206 changequote(, )dnl
 207 [if test x"$GreenCardCmd" != x; then
 208    fptools_cv_greencard_version="`$GreenCardCmd --version |
 209                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 210 else
 211    fptools_cv_greencard_version=""
 212 fi
 213 changequote([, ])dnl
 214 ])
 215 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 216   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 217 GreenCardVersion=$fptools_cv_greencard_version
 218 AC_SUBST(GreenCardVersion)
 219 ])
 220
 221 dnl
 222 dnl Check for Happy and version.  If we're building GHC, then we need
 223 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 224 dnl for a happy source tree and point the build system at that instead.
 225 dnl
 226 AC_DEFUN([FPTOOLS_HAPPY],
 227 [AC_PATH_PROG(HappyCmd,happy,)
 228 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 229 changequote(, )dnl
 230 [if test x"$HappyCmd" != x; then
 231    fptools_cv_happy_version="`$HappyCmd -v |
 232                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 233 else
 234    fptools_cv_happy_version="";
 235 fi;
 236 changequote([, ])dnl
 237 ])
 238 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/main/ParsePkgConf.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
 239 then
 240     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
 241       [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
 242 fi
 243 HappyVersion=$fptools_cv_happy_version;
 244 AC_SUBST(HappyVersion)
 245 ])
 246
 247 dnl
 248 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 249 dnl for a haddock source tree and point the build system at that instead.
 250 dnl
 251 AC_DEFUN([FPTOOLS_HADDOCK],
 252 [AC_PATH_PROG(HaddockCmd,haddock,)
 253 dnl Darn, I forgot to make Haddock print out its version number when
 254 dnl invoked with -v.  We could try generating some HTML and grepping
 255 dnl through that to find the version number, but I think we'll make
 256 dnl do without it for now.
 257 ])
 258
 259 dnl
 260 dnl Check for Alex and version.  If we're building GHC, then we need
 261 dnl at least Alex version 2.0.1.
 262 dnl
 263 AC_DEFUN([FPTOOLS_ALEX],
 264 [
 265 AC_PATH_PROG(AlexCmd,alex,)
 266 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 267 changequote(, )dnl
 268 [if test x"$AlexCmd" != x; then
 269    fptools_cv_alex_version="`$AlexCmd -v |
 270                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 271 else
 272    fptools_cv_alex_version="";
 273 fi;
 274 changequote([, ])dnl
 275 ])
 276 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
 277 then
 278     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0.1],
 279       [AC_MSG_ERROR([Alex version 2.0.1 or later is required to compile GHC.])])[]dnl
 280 fi
 281 AlexVersion=$fptools_cv_alex_version;
 282 AC_SUBST(AlexVersion)
 283 ])
 284
 285
 286 # FP_PROG_LD
 287 # ----------
 288 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 289 # of ld. Exits if no ld can be found
 290 AC_DEFUN([FP_PROG_LD],
 291 [AC_PATH_PROG([fp_prog_ld_raw], [ld])
 292 if test -z "$fp_prog_ld_raw"; then
 293   AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 294 fi
 295 LdCmd=$fp_prog_ld_raw
 296 case $HostPlatform in
 297   *mingw32) if test x${OSTYPE} != xmsys; then
 298               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 299               AC_MSG_NOTICE([normalized ld command to $LdCmd])
 300             fi
 301             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
 302             # the generation of relocatable object files with large amounts
 303             # of relocations correctly. (cf. HSbase.o splittage-hack)
 304             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
 305             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
 306                                 [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
 307             ;;
 308 esac
 309 AC_SUBST([LdCmd])
 310 ])# FP_PROG_LD
 311
 312
 313 # FP_PROG_LD_X
 314 # ------------
 315 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 316 # variable's value is empty.
 317 AC_DEFUN([FP_PROG_LD_X],
 318 [AC_REQUIRE([FP_PROG_LD])
 319 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 320 [echo 'foo() {}' > conftest.c
 321 ${CC-cc} -c conftest.c
 322 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
 323    fp_cv_ld_x=yes
 324 else
 325    fp_cv_ld_x=no
 326 fi
 327 rm -rf conftest*])
 328 if test "$fp_cv_ld_x" = yes; then
 329   LdXFlag=-x
 330 else
 331   LdXFlag=
 332 fi
 333 AC_SUBST([LdXFlag])
 334 ])# FP_PROG_LD_X
 335
 336
 337 # FP_PROG_LD_IS_GNU
 338 # -----------------
 339 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 340 # GNU ld or not.
 341 AC_DEFUN([FP_PROG_LD_IS_GNU],
 342 [AC_REQUIRE([FP_PROG_LD])
 343 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 344 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 345   fp_cv_gnu_ld=yes
 346 else
 347   fp_cv_gnu_ld=no
 348 fi])
 349 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 350 ])# FP_PROG_LD_IS_GNU
 351
 352
 353 # FP_PROG_AR
 354 # ----------
 355 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 356 # version of it. Exits if no ar can be found
 357 AC_DEFUN([FP_PROG_AR],
 358 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 359 if test -z "$fp_prog_ar_raw"; then
 360   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 361 fi
 362 fp_prog_ar=$fp_prog_ar_raw
 363 case $HostPlatform in
 364   *mingw32) if test x${OSTYPE} != xmsys; then
 365               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 366               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 367             fi
 368             ;;
 369 esac
 370 ])# FP_PROG_AR
 371
 372
 373 # FP_PROG_AR_IS_GNU
 374 # -----------------
 375 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 376 AC_DEFUN([FP_PROG_AR_IS_GNU],
 377 [AC_REQUIRE([FP_PROG_AR])
 378 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 379 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 380   fp_cv_prog_ar_is_gnu=yes
 381 else
 382   fp_cv_prog_ar_is_gnu=no
 383 fi])
 384 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 385 ])# FP_PROG_AR_IS_GNU
 386
 387
 388 # FP_PROG_AR_ARGS
 389 # ---------------
 390 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 391 # to a non-Cygwin invocation of ar including these arguments.
 392 AC_DEFUN([FP_PROG_AR_ARGS],
 393 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 394 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 395 [
 396 # GNU ar needs special treatment: it appears to have problems with
 397 # object files with the same name if you use the 's' modifier, but
 398 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 399 if test $fp_prog_ar_is_gnu = yes; then
 400   fp_cv_prog_ar_args="q"
 401 else
 402   touch conftest.dummy
 403   for fp_var in clqsZ clqs cqs clq cq ; do
 404      rm -f conftest.a
 405      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 406         fp_cv_prog_ar_args=$fp_var
 407         break
 408      fi
 409   done
 410   rm -f conftest*
 411   if test -z "$fp_cv_prog_ar_args"; then
 412     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 413   fi
 414 fi])
 415 fp_prog_ar_args=$fp_cv_prog_ar_args
 416 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 417
 418 ])# FP_PROG_AR_ARGS
 419
 420
 421 # FP_PROG_AR_NEEDS_RANLIB
 422 # -----------------------
 423 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 424 # to ":" otherwise.
 425 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 426 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 427 AC_REQUIRE([FP_PROG_AR_ARGS])
 428 AC_REQUIRE([AC_PROG_CC])
 429 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 430 [if test $fp_prog_ar_is_gnu = yes; then
 431   fp_cv_prog_ar_needs_ranlib=no
 432 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
 433   # It's quite tedious to check for Apple's crazy timestamps in .a files,
 434   # so we hardcode it.
 435   fp_cv_prog_ar_needs_ranlib=yes
 436 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 437   fp_cv_prog_ar_needs_ranlib=no
 438 else
 439   fp_cv_prog_ar_needs_ranlib=yes
 440 fi])
 441 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 442    AC_PROG_RANLIB
 443 else
 444   RANLIB=":"
 445   AC_SUBST([RANLIB])
 446 fi
 447 ])# FP_PROG_AR_NEEDS_RANLIB
 448
 449
 450 # FP_PROG_AR_SUPPORTS_INPUT
 451 # -------------------------
 452 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 453 # whether ar supports -input flag is supported or not.
 454 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 455 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 456 AC_REQUIRE([FP_PROG_AR_ARGS])
 457 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 458 [fp_cv_prog_ar_supports_input=no
 459 if test $fp_prog_ar_is_gnu = no; then
 460   rm -f conftest*
 461   touch conftest.lst
 462   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 463     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 464   fi
 465   rm -f conftest*
 466 fi])
 467 if test $fp_cv_prog_ar_supports_input = yes; then
 468     ArSupportsInput="-input"
 469 else
 470     ArSupportsInput=""
 471 fi
 472 AC_SUBST([ArSupportsInput])
 473 ])# FP_PROG_AR_SUPPORTS_INPUT
 474
 475
 476 dnl
 477 dnl AC_SHEBANG_PERL - can we she-bang perl?
 478 dnl
 479 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
 480 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 481 [echo "#!$PerlCmd"'
 482 exit $1;
 483 ' > conftest
 484 chmod u+x conftest
 485 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 486 if test $? -ne 69; then
 487    fptools_cv_shebang_perl=yes
 488 else
 489    fptools_cv_shebang_perl=no
 490 fi
 491 rm -f conftest
 492 ])])
 493
 494
 495 # FP_HAVE_GCC
 496 # -----------
 497 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 498 # output variables HaveGcc and GccVersion.
 499 AC_DEFUN([FP_HAVE_GCC],
 500 [AC_REQUIRE([AC_PROG_CC])
 501 if test -z "$GCC"; then
 502    fp_have_gcc=NO
 503 else
 504    fp_have_gcc=YES
 505 fi
 506 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
 507   AC_MSG_ERROR([gcc is required])
 508 fi
 509 AC_CACHE_CHECK([version of gcc], [fp_gcc_version],
 510 [if test "$fp_have_gcc" = "YES"; then
 511    fp_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
 512    FP_COMPARE_VERSIONS([$fp_gcc_version], [-lt], [2.0],
 513      [AC_MSG_ERROR([Need at least gcc version 2.0 (3.4+ recommended)])])
 514  else
 515    fp_gcc_version="not-installed"
 516  fi
 517 ])
 518 AC_SUBST([HaveGcc], [$fp_have_gcc])
 519 AC_SUBST([GccVersion], [$fp_gcc_version])
 520 ])# FP_HAVE_GCC
 521
 522 AC_DEFUN([FP_MINGW_GCC],
 523 [
 524   case $HostOS_CPP in
 525     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
 526              if $CC -v 2>&1 | grep mingw >/dev/null; then
 527                 AC_MSG_RESULT([yes])
 528              else
 529                 AC_MSG_RESULT([no])
 530                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
 531              fi;;
 532     *) ;;
 533   esac
 534 ])
 535
 536 dnl Small feature test for perl version. Assumes PerlCmd
 537 dnl contains path to perl binary
 538 dnl
 539 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
 540 [$PerlCmd -v >conftest.out 2>&1
 541    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 542       :
 543    else
 544       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 545          :
 546       else
 547          if grep "version 6" conftest.out >/dev/null 2>&1; then
 548             :
 549          else
 550             AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
 551          fi
 552       fi
 553    fi
 554 rm -fr conftest*
 555 ])
 556
 557
 558 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 559 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 560 # -----------------------------------------------------
 561 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 562 # of PROG-TO-CHECK-FOR when found.
 563 AC_DEFUN([FP_CHECK_PROG],
 564 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 565 )# FP_CHECK_PROC
 566
 567
 568 # FP_PROG_FIND
 569 # ------------
 570 # Find a non-WinDoze version of the "find" utility.
 571 AC_DEFUN([FP_PROG_FIND],
 572 [AC_PATH_PROG([fp_prog_find], [find])
 573 echo foo > conftest.txt
 574 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 575 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 576   # OK, looks like a real "find".
 577   FindCmd="$fp_prog_find"
 578 else
 579   # Found a poor WinDoze version of "find", ignore it.
 580   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 581   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 582 fi
 583 rm -f conftest.txt conftest.out
 584 AC_SUBST([FindCmd])[]dnl
 585 ])# FP_PROG_FIND
 586
 587
 588 # FP_PROG_SORT
 589 # ------------
 590 # Find a Unix-like sort
 591 AC_DEFUN([FP_PROG_SORT],
 592 [AC_PATH_PROG([fp_prog_sort], [sort])
 593 echo conwip > conftest.txt
 594 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
 595 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
 596   # The goods
 597   SortCmd="$fp_prog_sort"
 598 else
 599   # Summink else..pick next one.
 600   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
 601   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
 602 fi
 603 rm -f conftest.txt conftest.out
 604 AC_SUBST([SortCmd])[]dnl
 605 ])# FP_PROG_SORT
 606
 607 dnl
 608 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 609 dnl values of the second argument to the result of running
 610 dnl the commands given by the third. It does not cache its
 611 dnl result, so it is suitable for checks which should be
 612 dnl run every time.
 613 dnl
 614 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
 615 [AC_MSG_CHECKING([$1])
 616  $3
 617  AC_MSG_RESULT([$][$2])
 618 ])
 619
 620 dnl
 621 dnl FPTOOLS_GHC_VERSION(version)
 622 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 623 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 624 dnl
 625 dnl Test for version of installed ghc.  Uses $GHC.
 626 dnl [original version pinched from c2hs]
 627 dnl
 628 AC_DEFUN([FPTOOLS_GHC_VERSION],
 629 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 630 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 631   cat conftestghc >&AS_MESSAGE_LOG_FD
 632 #Useless Use Of cat award...
 633   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 634   rm -fr conftest*
 635   if test "[$]fptools_version_of_ghc" = ""
 636   then
 637     fptools_version_of_ghc='unknown'
 638   fi
 639 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 640 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 641 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 642 #
 643 if test "[$]fptools_version_of_ghc[_pl]" = ""
 644 then
 645   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 646   fptools_version_of_ghc[_pl]="0"
 647 else
 648   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 649 fi
 650 #
 651 ifelse($#, [1], [dnl
 652 [$1]="[$]fptools_version_of_ghc[_all]"
 653 ], $#, [2], [dnl
 654 [$1]="[$]fptools_version_of_ghc[_major]"
 655 [$2]="[$]fptools_version_of_ghc[_minor]"
 656 ], $#, [3], [dnl
 657 [$1]="[$]fptools_version_of_ghc[_major]"
 658 [$2]="[$]fptools_version_of_ghc[_minor]"
 659 [$3]="[$]fptools_version_of_ghc[_pl]"
 660 ], $#, [4], [dnl
 661 [$1]="[$]fptools_version_of_ghc[_all]"
 662 [$2]="[$]fptools_version_of_ghc[_major]"
 663 [$3]="[$]fptools_version_of_ghc[_minor]"
 664 [$4]="[$]fptools_version_of_ghc[_pl]"
 665 ])
 666 ])
 667 ])dnl
 668
 669
 670 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 671 # ---------------------------------------------------------------------------------
 672 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 673 # additional flexibility of specifying the PROLOGUE and BODY.
 674 AC_DEFUN([FP_CHECK_FUNC],
 675 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 676 AC_CACHE_CHECK([for $1], fp_func,
 677 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 678                 [AS_VAR_SET(fp_func, yes)],
 679                 [AS_VAR_SET(fp_func, no)])])
 680 AS_IF([test AS_VAR_GET(fp_func) = yes],
 681       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 682                 [Define to 1 if you have the `]$1[' function.]) $4],
 683       [$5])dnl
 684 AS_VAR_POPDEF([fp_func])dnl
 685 ])# FP_CHECK_FUNC
 686
 687
 688 # FP_GEN_DOCBOOK_XML
 689 # ------------------
 690 # Generates a DocBook XML V4.2 document in conftest.xml.
 691 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 692 [rm -f conftest.xml
 693 cat > conftest.xml << EOF
 694 <?xml version="1.0" encoding="iso-8859-1"?>
 695 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 696    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 697 <book id="test">
 698   <title>A DocBook Test Document</title>
 699   <chapter id="id-one">
 700     <title>A Chapter Title</title>
 701     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 702   </chapter>
 703   <chapter id="id-two">
 704     <title>Another Chapter Title</title>
 705     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 706   </chapter>
 707 </book>
 708 EOF
 709 ]) # FP_GEN_DOCBOOK_XML
 710
 711
 712 # FP_PROG_XSLTPROC
 713 # ----------------
 714 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 715 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 716 AC_DEFUN([FP_PROG_XSLTPROC],
 717 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 718 if test -z "$XsltprocCmd"; then
 719   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 720 fi
 721 ])# FP_PROG_XSLTPROC
 722
 723
 724 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 725 # ----------------------------
 726 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 727 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 728 # will be empty if none could be found.
 729 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 730 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 731 if test -n "$XsltprocCmd"; then
 732   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 733   [FP_GEN_DOCBOOK_XML
 734   fp_cv_dir_docbook_xsl=no
 735   for fp_var in $1; do
 736      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 737         fp_cv_dir_docbook_xsl=$fp_var
 738         break
 739      fi
 740   done
 741   rm -rf conftest*])
 742 fi
 743 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 744   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 745   DIR_DOCBOOK_XSL=
 746 else
 747   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 748 fi
 749 AC_SUBST([DIR_DOCBOOK_XSL])
 750 ])# FP_DIR_DOCBOOK_XSL
 751
 752
 753 # FP_PROG_XMLLINT
 754 # ----------------
 755 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 756 # xmllint. XmllintCmd is empty if xmllint could not be found.
 757 AC_DEFUN([FP_PROG_XMLLINT],
 758 [AC_PATH_PROG([XmllintCmd], [xmllint])
 759 if test -z "$XmllintCmd"; then
 760   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 761 fi
 762 ])# FP_PROG_XMLLINT
 763
 764
 765 # FP_CHECK_DOCBOOK_DTD
 766 # --------------------
 767 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 768 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 769 if test -n "$XmllintCmd"; then
 770   AC_MSG_CHECKING([for DocBook DTD])
 771   FP_GEN_DOCBOOK_XML
 772   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 773     AC_MSG_RESULT([ok])
 774   else
 775     AC_MSG_RESULT([failed])
 776     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 777     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 778   fi
 779   rm -rf conftest*
 780 fi
 781 ])# FP_CHECK_DOCBOOK_DTD
 782
 783
 784 # FP_GEN_FO
 785 # ------------------
 786 # Generates a formatting objects document in conftest.fo.
 787 AC_DEFUN([FP_GEN_FO],
 788 [rm -f conftest.fo
 789 cat > conftest.fo << EOF
 790 <?xml version="1.0"?>
 791 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 792   <fo:layout-master-set>
 793     <fo:simple-page-master master-name="blank">
 794       <fo:region-body/>
 795     </fo:simple-page-master>
 796   </fo:layout-master-set>
 797   <fo:page-sequence master-reference="blank">
 798     <fo:flow flow-name="xsl-region-body">
 799       <fo:block>
 800         Test!
 801       </fo:block>
 802     </fo:flow>
 803   </fo:page-sequence>
 804 </fo:root>
 805 EOF
 806 ]) # FP_GEN_FO
 807
 808
 809 # FP_PROG_FOP
 810 # -----------
 811 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 812 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 813 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 814 AC_DEFUN([FP_PROG_FOP],
 815 [AC_PATH_PROGS([FopCmd1], [fop])
 816 if test -n "$FopCmd1"; then
 817   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 818     [FP_GEN_FO
 819     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 820       fp_cv_fop_usability=yes
 821     else
 822       fp_cv_fop_usability=no
 823     fi
 824     rm -rf conftest*])
 825   if test x"$fp_cv_fop_usability" = xyes; then
 826      FopCmd=$FopCmd1
 827   fi
 828 fi
 829 if test -z "$FopCmd"; then
 830   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 831   FopCmd=$FopCmd2
 832 fi
 833 AC_SUBST([FopCmd])
 834 ])# FP_PROG_FOP
 835
 836
 837 # FP_PROG_FO_PROCESSOR
 838 # --------------------
 839 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
 840 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
 841 # PdfxmltexCmd.
 842 AC_DEFUN([FP_PROG_FO_PROCESSOR],
 843 [AC_REQUIRE([FP_PROG_FOP])
 844 AC_PATH_PROG([XmltexCmd], [xmltex])
 845 AC_PATH_PROG([DvipsCmd], [dvips])
 846 if test -z "$FopCmd"; then
 847   if test -z "$XmltexCmd"; then
 848     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
 849   else
 850     if test -z "$DvipsCmd"; then
 851       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
 852     fi
 853   fi
 854   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
 855   if test -z "$PdfxmltexCmd"; then
 856     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
 857   fi
 858 elif test -z "$XmltexCmd"; then
 859   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
 860 fi
 861 ])# FP_PROG_FO_PROCESSOR
 862
 863
 864 # FP_PROG_GHC_PKG
 865 # ----------------
 866 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
 867 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
 868 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
 869 AC_DEFUN([FP_PROG_GHC_PKG],
 870 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
 871 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
 872 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
 873   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 874 else
 875   fp_cv_matching_ghc_pkg=no
 876 fi])
 877 if test x"$fp_cv_matching_ghc_pkg" = xno; then
 878   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
 879 else
 880   GhcPkgCmd=$fp_cv_matching_ghc_pkg
 881 fi])# FP_PROG_GHC_PKG
 882
 883
 884 # FP_GHC_HAS_READLINE
 885 # -------------------
 886 AC_DEFUN([FP_GHC_HAS_READLINE],
 887 [AC_REQUIRE([FP_PROG_GHC_PKG])
 888 AC_CACHE_CHECK([whether ghc has readline package], [fp_cv_ghc_has_readline],
 889 [if "${GhcPkgCmd-ghc-pkg}" --show-package readline >/dev/null 2>&1; then
 890   fp_cv_ghc_has_readline=yes
 891 else
 892   fp_cv_ghc_has_readline=no
 893  fi])
 894 AC_SUBST([GhcHasReadline], [`echo $fp_cv_ghc_has_readline | sed 'y/yesno/YESNO/'`])
 895 ])# FP_GHC_HAS_READLINE
 896
 897
 898 # FP_GCC_NEEDS_NO_OMIT_LFPTR
 899 # --------------------------
 900 # Some OSs (Mandrake Linux, in particular) configure GCC with
 901 # -momit-leaf-frame-pointer on by default. If this is the case, we need to turn
 902 # it off for mangling to work. The test is currently a bit crude, using only the
 903 # version number of gcc. Defines HAVE_GCC_MNO_OMIT_LFPTR.
 904 AC_DEFUN([FP_GCC_NEEDS_NO_OMIT_LFPTR],
 905 [AC_REQUIRE([FP_HAVE_GCC])
 906 AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fp_cv_gcc_needs_no_omit_lfptr],
 907 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.2],
 908   [fp_cv_gcc_needs_no_omit_lfptr=yes],
 909   [fp_cv_gcc_needs_no_omit_lfptr=no])])
 910 if test "$fp_cv_gcc_needs_no_omit_lfptr" = "yes"; then
 911    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
 912 fi])# FP_GCC_NEEDS_NO_OMIT_LFPTR
 913
 914 # FP_GCC_HAS_NO_UNIT_AT_A_TIME
 915 # --------------------------
 916 AC_DEFUN([FP_GCC_HAS_NO_UNIT_AT_A_TIME],
 917 [AC_REQUIRE([FP_HAVE_GCC])
 918 AC_CACHE_CHECK([whether gcc has -fno-unit-at-a-time], [fp_cv_gcc_has_no_unit_at_a_time],
 919 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
 920   [fp_cv_gcc_has_no_unit_at_a_time=yes],
 921   [fp_cv_gcc_has_no_unit_at_a_time=no])])
 922 if test "$fp_cv_gcc_has_no_unit_at_a_time" = "yes"; then
 923    AC_DEFINE([HAVE_GCC_HAS_NO_UNIT_AT_A_TIME], [1], [Define to 1 if gcc supports -fno-unit-at-a-time.])
 924 fi])
 925
 926 # FP_SETUP_PROJECT_VERSION
 927 # ---------------------
 928 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
 929 [# Some renamings
 930 AC_SUBST([ProjectName], [$PACKAGE_NAME])
 931 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
 932
 933 # Split PACKAGE_VERSION into (possibly empty) parts
 934 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
 935 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
 936 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
 937 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
 938
 939 # Calculate project version as an integer, using 2 digits for minor version
 940 case $VERSION_MINOR in
 941   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
 942   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
 943   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
 944 esac
 945 AC_SUBST([ProjectVersionInt])
 946
 947 # The project patchlevel is zero unless stated otherwise
 948 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
 949
 950 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
 951 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
 952
 953 AC_SUBST([ProjectPatchLevel])
 954 ])# FP_SETUP_PROJECT_VERSION
 955
 956 # LocalWords:  fi