aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
   8 # ----------------------------------
   9 # Little endian Arm on Linux with some ABIs has big endian word order
  10 # in doubles. Define FLOAT_WORDS_BIGENDIAN if this is the case.
  11 AC_DEFUN([FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN],
  12   [AC_CACHE_CHECK([whether float word order is big endian], [fptools_cv_float_word_order_bigendian],
  13     [AC_COMPILE_IFELSE(
  14       [AC_LANG_PROGRAM(
  15         [#include <endian.h>],
  16         [#if defined(__FLOAT_WORD_ORDER) && __FLOAT_WORD_ORDER == BIG_ENDIAN
  17              return 0;
  18          #else
  19              not float word order big endian
  20          #endif]
  21       )],
  22       [fptools_cv_float_word_order_bigendian=yes],
  23       [fptools_cv_float_word_order_bigendian=no])
  24     ])
  25   case $fptools_cv_float_word_order_bigendian in
  26       yes)
  27           AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
  28           [Define to 1 if your processor stores words of floats with
  29            the most significant byte first]) ;;
  30   esac
  31 ])
  32
  33
  34 # FP_EVAL_STDERR(COMMAND)
  35 # -----------------------
  36 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  37 # into the file conftest.err and the exit status in the variable fp_status.
  38 AC_DEFUN([FP_EVAL_STDERR],
  39 [{ (eval $1) 2>conftest.er1
  40   fp_status=$?
  41   grep -v '^ *+' conftest.er1 >conftest.err
  42   rm -f conftest.er1
  43   (exit $fp_status); }[]dnl
  44 ])# FP_EVAL_STDERR
  45
  46
  47 # FP_PROG_CONTEXT_DIFF
  48 # --------------------
  49 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  50 #
  51 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  52 #
  53 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  54 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  55 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  56 [echo foo > conftest1
  57 echo foo > conftest2
  58 fp_cv_context_diff=no
  59 for fp_var in '-U 1' '-u1' '-C 1' '-c1'
  60 do
  61   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  62     fp_cv_context_diff="diff $fp_var"
  63     break
  64   fi
  65 done])
  66 if test x"$fp_cv_context_diff" = xno; then
  67    AC_MSG_ERROR([cannot figure out how to do context diffs])
  68 fi
  69 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  70 ])# FP_PROG_CONTEXT_DIFF
  71
  72
  73 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
  74 # --------------------------------------------------------
  75 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
  76 # compilation. Execute IF-FAILS when unable to determine the value. Works for
  77 # cross-compilation, too.
  78 #
  79 # Implementation note: We are lazy and use an internal autoconf macro, but it
  80 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
  81 # little risk.
  82 AC_DEFUN([FP_COMPUTE_INT],
  83 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
  84 ])# FP_COMPUTE_INT
  85
  86
  87 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
  88 # ------------------------------------------------------------------
  89 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
  90 # given type. Defines ALIGNMENT_TYPE.
  91 AC_DEFUN([FP_CHECK_ALIGNMENT],
  92 [AS_LITERAL_IF([$1], [],
  93                [AC_FATAL([$0: requires literal arguments])])[]dnl
  94 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
  95 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
  96 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
  97 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
  98   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
  99                  [fp_Cache],
 100                  [AC_INCLUDES_DEFAULT([$3])],
 101                  [AC_MSG_ERROR([cannot compute alignment ($1)
 102 See `config.log' for more details.], [77])])
 103 else
 104   fp_Cache=0
 105 fi])[]dnl
 106 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 107 m4_popdef([fp_Cache])[]dnl
 108 ])# FP_CHECK_ALIGNMENT
 109
 110
 111 # FP_LEADING_UNDERSCORE
 112 # ---------------------
 113 # Test for determining whether symbol names have a leading underscore. We assume
 114 # that they _haven't_ if anything goes wrong. Sets the output variable
 115 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 116 #
 117 # Some nlist implementations seem to try to be compatible by ignoring a leading
 118 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 119 # checking for *no* leading underscore first. Sigh.  --SDM
 120 #
 121 # Similarly on OpenBSD, but this test doesn't help. -- dons
 122 AC_DEFUN([FP_LEADING_UNDERSCORE],
 123 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 124 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 125 # Hack!: nlist() under Digital UNIX insist on there being an _,
 126 # but symbol table listings shows none. What is going on here?!?
 127 #
 128 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 129 # the underscoredness of that "platform"
 130 case $HostPlatform in
 131 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 132   case $build in
 133     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 134     *) fptools_cv_leading_underscore=no ;;
 135   esac ;;
 136 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 137 *cygwin32) fptools_cv_leading_underscore=yes;;
 138 *mingw32) fptools_cv_leading_underscore=yes;;
 139
 140     # HACK: Apple doesn't seem to provide nlist in the 64-bit-libraries
 141 x86_64-apple-darwin*) fptools_cv_leading_underscore=yes;;
 142
 143 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 144 #include <nlist.h>
 145 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 146 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 147 #endif
 148
 149 int main(argc, argv)
 150 int argc;
 151 char **argv;
 152 {
 153 #ifdef HAVE_NLIST_H
 154     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 155         exit(1);
 156     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 157         exit(0);
 158 #endif
 159     exit(1);
 160 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 161 ;;
 162 esac]);
 163 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 164 if test x"$fptools_cv_leading_underscore" = xyes; then
 165    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 166 fi])# FP_LEADING_UNDERSCORE
 167
 168
 169 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 170 # ----------------------------------------------------------------------------------
 171 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 172 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 173 AC_DEFUN([FP_COMPARE_VERSIONS],
 174 [fp_version1=$1; fp_version2=$3
 175 fp_save_IFS=$IFS; IFS='.'
 176 while test x"$fp_version1" != x || test x"$fp_version2" != x
 177 do
 178
 179   set dummy $fp_version1; shift
 180   fp_num1=""
 181   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 182   test x"$fp_num1" = x && fp_num1="0"
 183   fp_version1="[$]*"
 184
 185   set dummy $fp_version2; shift
 186   fp_num2=""
 187   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 188   test x"$fp_num2" = x && fp_num2="0"
 189   fp_version2="[$]*"
 190
 191   test "$fp_num1" = "$fp_num2" || break;
 192 done
 193 IFS=$fp_save_IFS
 194 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 195 ])# FP_COMPARE_VERSIONS
 196
 197
 198 dnl
 199 dnl Check for GreenCard and version.
 200 dnl
 201 AC_DEFUN([FPTOOLS_GREENCARD],
 202 [
 203 AC_PATH_PROG(GreenCardCmd,greencard)
 204 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 205 changequote(, )dnl
 206 [if test x"$GreenCardCmd" != x; then
 207    fptools_cv_greencard_version="`$GreenCardCmd --version |
 208                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 209 else
 210    fptools_cv_greencard_version=""
 211 fi
 212 changequote([, ])dnl
 213 ])
 214 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 215   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 216 GreenCardVersion=$fptools_cv_greencard_version
 217 AC_SUBST(GreenCardVersion)
 218 ])
 219
 220 dnl
 221 dnl Check for Happy and version.  If we're building GHC, then we need
 222 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 223 dnl for a happy source tree and point the build system at that instead.
 224 dnl
 225 AC_DEFUN([FPTOOLS_HAPPY],
 226 [AC_PATH_PROG(HappyCmd,happy,)
 227 # Happy is passed to Cabal, so we need a native path
 228 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 229    test "${OSTYPE}"      != "msys"                  && \
 230    test "${HappyCmd}"    != ""
 231 then
 232     # Canonicalise to <drive>:/path/to/gcc
 233     HappyCmd=`cygpath -m ${HappyCmd}`
 234     AC_MSG_NOTICE([normalized happy command to $HappyCmd])
 235 fi
 236
 237 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 238 changequote(, )dnl
 239 [if test x"$HappyCmd" != x; then
 240    fptools_cv_happy_version="`$HappyCmd -v |
 241                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 242 else
 243    fptools_cv_happy_version="";
 244 fi;
 245 changequote([, ])dnl
 246 ])
 247 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/main/ParsePkgConf.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
 248 then
 249     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
 250       [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
 251 fi
 252 HappyVersion=$fptools_cv_happy_version;
 253 AC_SUBST(HappyVersion)
 254 ])
 255
 256 dnl
 257 dnl Check for Alex and version.  If we're building GHC, then we need
 258 dnl at least Alex version 2.0.1.
 259 dnl
 260 AC_DEFUN([FPTOOLS_ALEX],
 261 [
 262 AC_PATH_PROG(AlexCmd,alex,)
 263 # Alex is passed to Cabal, so we need a native path
 264 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 265    test "${OSTYPE}"      != "msys"                  && \
 266    test "${AlexCmd}"     != ""
 267 then
 268     # Canonicalise to <drive>:/path/to/gcc
 269     AlexCmd=`cygpath -m ${AlexCmd}`
 270 fi
 271
 272 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 273 changequote(, )dnl
 274 [if test x"$AlexCmd" != x; then
 275    fptools_cv_alex_version="`$AlexCmd -v |
 276                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 277 else
 278    fptools_cv_alex_version="";
 279 fi;
 280 changequote([, ])dnl
 281 ])
 282 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
 283 then
 284     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.1.0],
 285       [AC_MSG_ERROR([Alex version 2.1.0 or later is required to compile GHC.])])[]dnl
 286 fi
 287 AlexVersion=$fptools_cv_alex_version;
 288 AC_SUBST(AlexVersion)
 289 ])
 290
 291
 292 dnl
 293 dnl Check for windres and version.
 294 dnl 2.15.91 works
 295 dnl 2.17.50 doesn't work
 296 dnl 2.18.50 works
 297 dnl
 298 AC_DEFUN([FPTOOLS_WINDRES],
 299 [
 300 if test "x$HostPlatform"  = "xi386-unknown-mingw32"
 301 then
 302     AC_PATH_PROG(WindResCmd,windres,)
 303     # Alex is passed to Cabal, so we need a native path
 304     if test "${OSTYPE}"      != "msys"                  && \
 305        test "${WindResCmd}"  != ""
 306     then
 307         # Canonicalise to <drive>:/path/to/gcc
 308         WindResCmd=`cygpath -m ${WindResCmd}`
 309     fi
 310
 311     AC_CACHE_CHECK([for version of windres], fptools_cv_windres_version,
 312     changequote(, )dnl
 313     [
 314         if test x"$WindResCmd" != x
 315         then
 316             fptools_cv_windres_version="`$WindResCmd --version |
 317                           grep 'GNU windres' |
 318               sed -e 's/GNU windres[^0-9]* \([0-9\.]*\).*/\1/g'`" ;
 319         else
 320             fptools_cv_windres_version="";
 321         fi
 322         changequote([, ])dnl
 323     ])
 324     FP_COMPARE_VERSIONS([$fptools_cv_windres_version],[-eq],[2.17.50],
 325       [AC_MSG_ERROR([Your windres version isn't compatible with GHC. 2.15.91 and 2.18.50 are known to work.])])[]dnl
 326     indResVersion=$fptools_cv_windres_version;
 327     AC_SUBST(WindResVersion)
 328 fi
 329 ])
 330
 331
 332 # FP_PROG_LD
 333 # ----------
 334 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 335 # of ld. Exits if no ld can be found
 336 AC_DEFUN([FP_PROG_LD],
 337 [
 338 if test -z "$1"
 339 then
 340   AC_PATH_PROG([fp_prog_ld_raw], [ld])
 341   if test -z "$fp_prog_ld_raw"; then
 342     AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 343   fi
 344   LdCmd=$fp_prog_ld_raw
 345   case $HostPlatform in
 346     *mingw32) if test x${OSTYPE} != xmsys; then
 347               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 348                 AC_MSG_NOTICE([normalized ld command to $LdCmd])
 349               fi
 350             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
 351             # the generation of relocatable object files with large amounts
 352             # of relocations correctly. (cf. HSbase.o splittage-hack)
 353             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
 354             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
 355                                   [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
 356               ;;
 357   esac
 358 else
 359   LdCmd="$1"
 360 fi
 361 AC_SUBST([LdCmd])
 362 ])# FP_PROG_LD
 363
 364
 365 # FP_PROG_LD_X
 366 # ------------
 367 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 368 # variable's value is empty.
 369 AC_DEFUN([FP_PROG_LD_X],
 370 [AC_REQUIRE([FP_PROG_LD])
 371 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 372 [echo 'foo() {}' > conftest.c
 373 ${CC-cc} -c conftest.c
 374 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
 375    fp_cv_ld_x=yes
 376 else
 377    fp_cv_ld_x=no
 378 fi
 379 rm -rf conftest*])
 380 if test "$fp_cv_ld_x" = yes; then
 381   LdXFlag=-x
 382 else
 383   LdXFlag=
 384 fi
 385 AC_SUBST([LdXFlag])
 386 ])# FP_PROG_LD_X
 387
 388
 389 # FP_PROG_LD_IS_GNU
 390 # -----------------
 391 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 392 # GNU ld or not.
 393 AC_DEFUN([FP_PROG_LD_IS_GNU],
 394 [AC_REQUIRE([FP_PROG_LD])
 395 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 396 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 397   fp_cv_gnu_ld=yes
 398 else
 399   fp_cv_gnu_ld=no
 400 fi])
 401 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 402 ])# FP_PROG_LD_IS_GNU
 403
 404
 405 # FP_PROG_AR
 406 # ----------
 407 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 408 # version of it. Exits if no ar can be found
 409 AC_DEFUN([FP_PROG_AR],
 410 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 411 if test -z "$fp_prog_ar_raw"; then
 412   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 413 fi
 414 fp_prog_ar=$fp_prog_ar_raw
 415 case $HostPlatform in
 416   *mingw32) if test x${OSTYPE} != xmsys; then
 417               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 418               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 419             fi
 420             ;;
 421 esac
 422 ])# FP_PROG_AR
 423
 424
 425 # FP_PROG_AR_IS_GNU
 426 # -----------------
 427 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 428 AC_DEFUN([FP_PROG_AR_IS_GNU],
 429 [AC_REQUIRE([FP_PROG_AR])
 430 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 431 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 432   fp_cv_prog_ar_is_gnu=yes
 433 else
 434   fp_cv_prog_ar_is_gnu=no
 435 fi])
 436 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 437 ])# FP_PROG_AR_IS_GNU
 438
 439
 440 # FP_PROG_AR_ARGS
 441 # ---------------
 442 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 443 # to a non-Cygwin invocation of ar including these arguments.
 444 AC_DEFUN([FP_PROG_AR_ARGS],
 445 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 446 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 447 [
 448 # GNU ar needs special treatment: it appears to have problems with
 449 # object files with the same name if you use the 's' modifier, but
 450 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 451 if test $fp_prog_ar_is_gnu = yes; then
 452   fp_cv_prog_ar_args="q"
 453 else
 454   touch conftest.dummy
 455   for fp_var in clqsZ clqs cqs clq cq ; do
 456      rm -f conftest.a
 457      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 458         fp_cv_prog_ar_args=$fp_var
 459         break
 460      fi
 461   done
 462   rm -f conftest*
 463   if test -z "$fp_cv_prog_ar_args"; then
 464     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 465   fi
 466 fi])
 467 fp_prog_ar_args=$fp_cv_prog_ar_args
 468 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 469
 470 ])# FP_PROG_AR_ARGS
 471
 472
 473 # FP_PROG_AR_NEEDS_RANLIB
 474 # -----------------------
 475 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 476 # to ":" otherwise.
 477 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 478 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 479 AC_REQUIRE([FP_PROG_AR_ARGS])
 480 AC_REQUIRE([AC_PROG_CC])
 481 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 482 [if test $fp_prog_ar_is_gnu = yes; then
 483   fp_cv_prog_ar_needs_ranlib=no
 484 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
 485   # It's quite tedious to check for Apple's crazy timestamps in .a files,
 486   # so we hardcode it.
 487   fp_cv_prog_ar_needs_ranlib=yes
 488 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 489   fp_cv_prog_ar_needs_ranlib=no
 490 else
 491   fp_cv_prog_ar_needs_ranlib=yes
 492 fi])
 493 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 494    AC_PROG_RANLIB
 495 else
 496   RANLIB=":"
 497   AC_SUBST([RANLIB])
 498 fi
 499 ])# FP_PROG_AR_NEEDS_RANLIB
 500
 501
 502 # FP_PROG_AR_SUPPORTS_INPUT
 503 # -------------------------
 504 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 505 # whether ar supports -input flag is supported or not.
 506 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 507 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 508 AC_REQUIRE([FP_PROG_AR_ARGS])
 509 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 510 [fp_cv_prog_ar_supports_input=no
 511 if test $fp_prog_ar_is_gnu = no; then
 512   rm -f conftest*
 513   touch conftest.lst
 514   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 515     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 516   fi
 517   rm -f conftest*
 518 fi])
 519 if test $fp_cv_prog_ar_supports_input = yes; then
 520     ArSupportsInput="-input"
 521 else
 522     ArSupportsInput=""
 523 fi
 524 AC_SUBST([ArSupportsInput])
 525 ])# FP_PROG_AR_SUPPORTS_INPUT
 526
 527
 528 dnl
 529 dnl AC_SHEBANG_PERL - can we she-bang perl?
 530 dnl
 531 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
 532 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 533 [echo "#!$PerlCmd"'
 534 exit $1;
 535 ' > conftest
 536 chmod u+x conftest
 537 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 538 if test $? -ne 69; then
 539    fptools_cv_shebang_perl=yes
 540 else
 541    fptools_cv_shebang_perl=no
 542 fi
 543 rm -f conftest
 544 ])])
 545
 546
 547 # FP_HAVE_GCC
 548 # -----------
 549 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 550 # output variables HaveGcc and GccVersion.
 551 AC_DEFUN([FP_HAVE_GCC],
 552 [AC_REQUIRE([AC_PROG_CC])
 553 if test -z "$GCC"; then
 554    fp_have_gcc=NO
 555 else
 556    fp_have_gcc=YES
 557 fi
 558 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
 559   AC_MSG_ERROR([gcc is required])
 560 fi
 561 AC_CACHE_CHECK([version of gcc], [fp_gcc_version],
 562 [if test "$fp_have_gcc" = "YES"; then
 563    fp_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
 564    FP_COMPARE_VERSIONS([$fp_gcc_version], [-lt], [2.0],
 565      [AC_MSG_ERROR([Need at least gcc version 2.0 (3.4+ recommended)])])
 566  else
 567    fp_gcc_version="not-installed"
 568  fi
 569 ])
 570 AC_SUBST([HaveGcc], [$fp_have_gcc])
 571 AC_SUBST([GccVersion], [$fp_gcc_version])
 572 ])# FP_HAVE_GCC
 573
 574 AC_DEFUN([FP_MINGW_GCC],
 575 [
 576   case $HostOS_CPP in
 577     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
 578              if $CC -v 2>&1 | grep mingw >/dev/null; then
 579                 AC_MSG_RESULT([yes])
 580              else
 581                 AC_MSG_RESULT([no])
 582                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
 583              fi;;
 584     *) ;;
 585   esac
 586 ])
 587
 588 dnl Small feature test for perl version. Assumes PerlCmd
 589 dnl contains path to perl binary.
 590 dnl
 591 dnl (Perl versions prior to v5.6 does not contain the string "v5";
 592 dnl instead they display version strings such as "version 5.005".)
 593 dnl
 594 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
 595 [$PerlCmd -v >conftest.out 2>&1
 596    if grep "v5" conftest.out >/dev/null 2>&1; then
 597       :
 598    else
 599       AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
 600    fi
 601 rm -fr conftest*
 602 ])
 603
 604
 605 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 606 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 607 # -----------------------------------------------------
 608 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 609 # of PROG-TO-CHECK-FOR when found.
 610 AC_DEFUN([FP_CHECK_PROG],
 611 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 612 )# FP_CHECK_PROC
 613
 614
 615 # FP_PROG_FIND
 616 # ------------
 617 # Find a non-WinDoze version of the "find" utility.
 618 AC_DEFUN([FP_PROG_FIND],
 619 [AC_PATH_PROGS([fp_prog_find], [gfind find], find)
 620 echo foo > conftest.txt
 621 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 622 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 623   # OK, looks like a real "find".
 624   case $HostPlatform in
 625     *mingw32)
 626       if test x${OSTYPE} != xmsys
 627       then
 628             fp_prog_find="`cygpath --mixed ${fp_prog_find}`"
 629         AC_MSG_NOTICE([normalized find command to $fp_prog_find])
 630       fi ;;
 631     *) ;;
 632   esac
 633   FindCmd="$fp_prog_find"
 634 else
 635   # Found a poor WinDoze version of "find", ignore it.
 636   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 637   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 638 fi
 639 rm -f conftest.txt conftest.out
 640 AC_SUBST([FindCmd])[]dnl
 641 ])# FP_PROG_FIND
 642
 643
 644 # FP_PROG_SORT
 645 # ------------
 646 # Find a Unix-like sort
 647 AC_DEFUN([FP_PROG_SORT],
 648 [AC_PATH_PROG([fp_prog_sort], [sort])
 649 echo conwip > conftest.txt
 650 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
 651 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
 652   # The goods
 653   SortCmd="$fp_prog_sort"
 654 else
 655   # Summink else..pick next one.
 656   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
 657   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
 658 fi
 659 rm -f conftest.txt conftest.out
 660 AC_SUBST([SortCmd])[]dnl
 661 ])# FP_PROG_SORT
 662
 663 dnl
 664 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 665 dnl values of the second argument to the result of running
 666 dnl the commands given by the third. It does not cache its
 667 dnl result, so it is suitable for checks which should be
 668 dnl run every time.
 669 dnl
 670 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
 671 [AC_MSG_CHECKING([$1])
 672  $3
 673  AC_MSG_RESULT([$][$2])
 674 ])
 675
 676 dnl
 677 dnl FPTOOLS_GHC_VERSION(version)
 678 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 679 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 680 dnl
 681 dnl Test for version of installed ghc.  Uses $GHC.
 682 dnl [original version pinched from c2hs]
 683 dnl
 684 AC_DEFUN([FPTOOLS_GHC_VERSION],
 685 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 686 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 687   cat conftestghc >&AS_MESSAGE_LOG_FD
 688 #Useless Use Of cat award...
 689   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 690   rm -fr conftest*
 691   if test "[$]fptools_version_of_ghc" = ""
 692   then
 693     fptools_version_of_ghc='unknown'
 694   fi
 695 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 696 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 697 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 698 #
 699 if test "[$]fptools_version_of_ghc[_pl]" = ""
 700 then
 701   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 702   fptools_version_of_ghc[_pl]="0"
 703 else
 704   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 705 fi
 706 #
 707 ifelse($#, [1], [dnl
 708 [$1]="[$]fptools_version_of_ghc[_all]"
 709 ], $#, [2], [dnl
 710 [$1]="[$]fptools_version_of_ghc[_major]"
 711 [$2]="[$]fptools_version_of_ghc[_minor]"
 712 ], $#, [3], [dnl
 713 [$1]="[$]fptools_version_of_ghc[_major]"
 714 [$2]="[$]fptools_version_of_ghc[_minor]"
 715 [$3]="[$]fptools_version_of_ghc[_pl]"
 716 ], $#, [4], [dnl
 717 [$1]="[$]fptools_version_of_ghc[_all]"
 718 [$2]="[$]fptools_version_of_ghc[_major]"
 719 [$3]="[$]fptools_version_of_ghc[_minor]"
 720 [$4]="[$]fptools_version_of_ghc[_pl]"
 721 ])
 722 ])
 723 ])dnl
 724
 725
 726 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 727 # ---------------------------------------------------------------------------------
 728 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 729 # additional flexibility of specifying the PROLOGUE and BODY.
 730 AC_DEFUN([FP_CHECK_FUNC],
 731 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 732 AC_CACHE_CHECK([for $1], fp_func,
 733 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 734                 [AS_VAR_SET(fp_func, yes)],
 735                 [AS_VAR_SET(fp_func, no)])])
 736 AS_IF([test AS_VAR_GET(fp_func) = yes],
 737       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 738                 [Define to 1 if you have the `]$1[' function.]) $4],
 739       [$5])dnl
 740 AS_VAR_POPDEF([fp_func])dnl
 741 ])# FP_CHECK_FUNC
 742
 743
 744 # FP_GEN_DOCBOOK_XML
 745 # ------------------
 746 # Generates a DocBook XML V4.2 document in conftest.xml.
 747 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 748 [rm -f conftest.xml
 749 cat > conftest.xml << EOF
 750 <?xml version="1.0" encoding="iso-8859-1"?>
 751 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 752    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 753 <book id="test">
 754   <title>A DocBook Test Document</title>
 755   <chapter id="id-one">
 756     <title>A Chapter Title</title>
 757     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 758   </chapter>
 759   <chapter id="id-two">
 760     <title>Another Chapter Title</title>
 761     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 762   </chapter>
 763 </book>
 764 EOF
 765 ]) # FP_GEN_DOCBOOK_XML
 766
 767
 768 # FP_PROG_XSLTPROC
 769 # ----------------
 770 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 771 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 772 AC_DEFUN([FP_PROG_XSLTPROC],
 773 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 774 if test -z "$XsltprocCmd"; then
 775   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 776 fi
 777 ])# FP_PROG_XSLTPROC
 778
 779
 780 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 781 # ----------------------------
 782 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 783 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 784 # will be empty if none could be found.
 785 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 786 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 787 if test -n "$XsltprocCmd"; then
 788   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 789   [FP_GEN_DOCBOOK_XML
 790   fp_cv_dir_docbook_xsl=no
 791   for fp_var in $1; do
 792      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 793         fp_cv_dir_docbook_xsl=$fp_var
 794         break
 795      fi
 796   done
 797   rm -rf conftest*])
 798 fi
 799 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 800   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 801   DIR_DOCBOOK_XSL=
 802 else
 803   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 804 fi
 805 AC_SUBST([DIR_DOCBOOK_XSL])
 806 ])# FP_DIR_DOCBOOK_XSL
 807
 808
 809 # FP_PROG_XMLLINT
 810 # ----------------
 811 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 812 # xmllint. XmllintCmd is empty if xmllint could not be found.
 813 AC_DEFUN([FP_PROG_XMLLINT],
 814 [AC_PATH_PROG([XmllintCmd], [xmllint])
 815 if test -z "$XmllintCmd"; then
 816   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 817 fi
 818 ])# FP_PROG_XMLLINT
 819
 820
 821 # FP_CHECK_DOCBOOK_DTD
 822 # --------------------
 823 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 824 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 825 if test -n "$XmllintCmd"; then
 826   AC_MSG_CHECKING([for DocBook DTD])
 827   FP_GEN_DOCBOOK_XML
 828   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 829     AC_MSG_RESULT([ok])
 830   else
 831     AC_MSG_RESULT([failed])
 832     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 833     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 834   fi
 835   rm -rf conftest*
 836 fi
 837 ])# FP_CHECK_DOCBOOK_DTD
 838
 839
 840 # FP_GEN_FO
 841 # ------------------
 842 # Generates a formatting objects document in conftest.fo.
 843 AC_DEFUN([FP_GEN_FO],
 844 [rm -f conftest.fo
 845 cat > conftest.fo << EOF
 846 <?xml version="1.0"?>
 847 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 848   <fo:layout-master-set>
 849     <fo:simple-page-master master-name="blank">
 850       <fo:region-body/>
 851     </fo:simple-page-master>
 852   </fo:layout-master-set>
 853   <fo:page-sequence master-reference="blank">
 854     <fo:flow flow-name="xsl-region-body">
 855       <fo:block>
 856         Test!
 857       </fo:block>
 858     </fo:flow>
 859   </fo:page-sequence>
 860 </fo:root>
 861 EOF
 862 ]) # FP_GEN_FO
 863
 864
 865 # FP_PROG_FOP
 866 # -----------
 867 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 868 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 869 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 870 AC_DEFUN([FP_PROG_FOP],
 871 [AC_PATH_PROGS([FopCmd1], [fop fop.sh])
 872 if test -n "$FopCmd1"; then
 873   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 874     [FP_GEN_FO
 875     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 876       fp_cv_fop_usability=yes
 877     else
 878       fp_cv_fop_usability=no
 879     fi
 880     rm -rf conftest*])
 881   if test x"$fp_cv_fop_usability" = xyes; then
 882      FopCmd=$FopCmd1
 883   fi
 884 fi
 885 if test -z "$FopCmd"; then
 886   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 887   FopCmd=$FopCmd2
 888 fi
 889 AC_SUBST([FopCmd])
 890 ])# FP_PROG_FOP
 891
 892
 893 # FP_PROG_FO_PROCESSOR
 894 # --------------------
 895 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
 896 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
 897 # PdfxmltexCmd.
 898 AC_DEFUN([FP_PROG_FO_PROCESSOR],
 899 [AC_REQUIRE([FP_PROG_FOP])
 900 AC_PATH_PROG([XmltexCmd], [xmltex])
 901 AC_PATH_PROG([DvipsCmd], [dvips])
 902 if test -z "$FopCmd"; then
 903   if test -z "$XmltexCmd"; then
 904     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
 905   else
 906     if test -z "$DvipsCmd"; then
 907       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
 908     fi
 909   fi
 910   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
 911   if test -z "$PdfxmltexCmd"; then
 912     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
 913   fi
 914 elif test -z "$XmltexCmd"; then
 915   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
 916 fi
 917 ])# FP_PROG_FO_PROCESSOR
 918
 919
 920 # FP_PROG_GHC_PKG
 921 # ----------------
 922 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
 923 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
 924 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
 925 AC_DEFUN([FP_PROG_GHC_PKG],
 926 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
 927 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
 928 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
 929   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 930 else
 931   fp_cv_matching_ghc_pkg=no
 932 fi])
 933 if test x"$fp_cv_matching_ghc_pkg" = xno; then
 934   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
 935 else
 936   GhcPkgCmd=$fp_cv_matching_ghc_pkg
 937 fi])# FP_PROG_GHC_PKG
 938
 939
 940 # FP_GHC_HAS_EDITLINE
 941 # -------------------
 942 AC_DEFUN([FP_GHC_HAS_EDITLINE],
 943 [AC_REQUIRE([FP_PROG_GHC_PKG])
 944 AC_CACHE_CHECK([whether ghc has editline package], [fp_cv_ghc_has_editline],
 945 [if "${GhcPkgCmd-ghc-pkg}" --show-package editline >/dev/null 2>&1; then
 946   fp_cv_ghc_has_editline=yes
 947 else
 948   fp_cv_ghc_has_editline=no
 949  fi])
 950 AC_SUBST([GhcHasEditline], [`echo $fp_cv_ghc_has_editline | sed 'y/yesno/YESNO/'`])
 951 ])# FP_GHC_HAS_EDITLINE
 952
 953
 954 # FP_GCC_EXTRA_FLAGS
 955 # ------------------
 956 # Determine which extra flags we need to pass gcc when we invoke it
 957 # to compile .hc code.
 958 #
 959 # Some OSs (Mandrake Linux, in particular) configure GCC with
 960 # -momit-leaf-frame-pointer on by default. If this is the case, we
 961 # need to turn it off for mangling to work. The test is currently a
 962 # bit crude, using only the version number of gcc.
 963 #
 964 # -fwrapv is needed for gcc to emit well-behaved code in the presence of
 965 # integer wrap around. (Trac #952)
 966 #
 967 # -fno-unit-at-a-time or -fno-toplevel-reoder is necessary to avoid gcc
 968 # reordering things in the module and confusing the manger and/or splitter.
 969 # (eg. Trac #1427)
 970 #
 971 AC_DEFUN([FP_GCC_EXTRA_FLAGS],
 972 [AC_REQUIRE([FP_HAVE_GCC])
 973 AC_CACHE_CHECK([for extra options to pass gcc when compiling via C], [fp_cv_gcc_extra_opts],
 974 [fp_cv_gcc_extra_opts=
 975  FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
 976   [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fwrapv"],
 977   [])
 978  case $TargetPlatform in
 979   i386-*|x86_64-*)
 980      FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.2],
 981       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -mno-omit-leaf-frame-pointer"],
 982       [])
 983     FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
 984      [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [4.2],
 985        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
 986        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-unit-at-a-time"]
 987      )],
 988      [])
 989   ;;
 990   sparc-*-solaris2)
 991     FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [4.2],
 992       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
 993       [])
 994   ;;
 995  esac
 996 ])
 997 AC_SUBST([GccExtraViaCOpts],$fp_cv_gcc_extra_opts)
 998 ])
 999
1000
1001 # FP_SETUP_PROJECT_VERSION
1002 # ---------------------
1003 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
1004 [
1005 if test "$RELEASE" = "NO"; then
1006     AC_MSG_CHECKING([for GHC version date])
1007     if test -f VERSION_DATE; then
1008         PACKAGE_VERSION=${PACKAGE_VERSION}.`cat VERSION_DATE`
1009         AC_MSG_RESULT(given $PACKAGE_VERSION)
1010     elif test -d .git; then
1011         changequote(, )dnl
1012         ver_date=`git log -n 1 --date=short --pretty=format:%ci | sed "s/^.*\([0-9][0-9][0-9][0-9]\)-\([0-9][0-9]\)-\([0-9][0-9]\).*$/\1\2\3/"`
1013         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
1014         changequote([, ])dnl
1015                 AC_MSG_ERROR([failed to detect version date: check that git is in your path])
1016         fi
1017         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
1018         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
1019     elif test -d _darcs; then
1020         # TODO: Remove this branch after conversion to Git
1021         changequote(, )dnl
1022         ver_date=`darcs changes --quiet --no-summary --xml | head -500 | grep 'date=' | sed "s/^.*date='\([0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]\).*$/\1/g" | sort -n | tail -1`
1023         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
1024         changequote([, ])dnl
1025                 AC_MSG_ERROR([failed to detect version date: check that darcs is in your path])
1026         fi
1027         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
1028         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
1029     elif test -f VERSION; then
1030         PACKAGE_VERSION=`cat VERSION`
1031         AC_MSG_RESULT(given $PACKAGE_VERSION)
1032     else
1033         AC_MSG_WARN([cannot determine snapshot version: no .git or _darcs directory and no VERSION file])
1034     fi
1035 fi
1036
1037 # Some renamings
1038 AC_SUBST([ProjectName], [$PACKAGE_NAME])
1039 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
1040
1041 # Split PACKAGE_VERSION into (possibly empty) parts
1042 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1043 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1044 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1045 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1046
1047 # Calculate project version as an integer, using 2 digits for minor version
1048 case $VERSION_MINOR in
1049   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
1050   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
1051   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
1052 esac
1053 AC_SUBST([ProjectVersionInt])
1054
1055 # The project patchlevel is zero unless stated otherwise
1056 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
1057
1058 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
1059 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
1060
1061 AC_SUBST([ProjectPatchLevel])
1062 ])# FP_SETUP_PROJECT_VERSION
1063
1064
1065 # Check for a working timer_create().  We need a pretty detailed check
1066 # here, because there exist partially-working implementations of
1067 # timer_create() in certain versions of Linux (see bug #1933).
1068 #
1069 AC_DEFUN([FP_CHECK_TIMER_CREATE],
1070   [AC_CACHE_CHECK([for a working timer_create(CLOCK_REALTIME)],
1071     [fptools_cv_timer_create_works],
1072     [AC_TRY_RUN([
1073 #include <stdio.h>
1074 #ifdef HAVE_STDLIB_H
1075 #include <stdlib.h>
1076 #endif
1077 #ifdef HAVE_TIME_H
1078 #include <time.h>
1079 #endif
1080 #ifdef HAVE_SIGNAL_H
1081 #include <signal.h>
1082 #endif
1083 #ifdef HAVE_UNISTD_H
1084 #include <unistd.h>
1085 #endif
1086
1087 static volatile int tock = 0;
1088 static void handler(int i)
1089 {
1090    tock = 1;
1091 }
1092
1093 static void timeout(int i)
1094 {
1095   // timer_settime() has been known to hang, so just in case
1096   // we install a 1-second timeout (see #2257)
1097   exit(99);
1098 }
1099
1100 int main(int argc, char *argv[])
1101 {
1102
1103     struct sigevent ev;
1104     timer_t timer;
1105     struct itimerspec it;
1106     struct sigaction action;
1107     int m,n,count = 0;
1108
1109     ev.sigev_notify = SIGEV_SIGNAL;
1110     ev.sigev_signo  = SIGVTALRM;
1111
1112     action.sa_handler = handler;
1113     action.sa_flags = 0;
1114     sigemptyset(&action.sa_mask);
1115     if (sigaction(SIGVTALRM, &action, NULL) == -1) {
1116         fprintf(stderr,"SIGVTALRM problem\n");
1117         exit(3);
1118     }
1119
1120     action.sa_handler = timeout;
1121     action.sa_flags = 0;
1122     sigemptyset(&action.sa_mask);
1123     if (sigaction(SIGALRM, &action, NULL) == -1) {
1124       fprintf(stderr,"SIGALRM problem\n");
1125       exit(3);
1126     }
1127     alarm(1);
1128
1129     if (timer_create(CLOCK_PROCESS_CPUTIME_ID, &ev, &timer) != 0) {
1130         fprintf(stderr,"No CLOCK_PROCESS_CPUTIME_ID timer\n");
1131        exit(1);
1132     }
1133
1134     it.it_value.tv_sec = 0;
1135     it.it_value.tv_nsec = 1;
1136     it.it_interval = it.it_value;
1137     if (timer_settime(timer, 0, &it, NULL) != 0) {
1138         fprintf(stderr,"settime problem\n");
1139         exit(4);
1140     }
1141
1142     tock = 0;
1143
1144     for(n = 3; n < 20000; n++){
1145         for(m = 2; m <= n/2; m++){
1146             if (!(n%m)) count++;
1147             if (tock) goto out;
1148         }
1149     }
1150 out:
1151
1152     if (!tock) {
1153         fprintf(stderr,"no CLOCK_PROCESS_CPUTIME_ID signal\n");
1154         exit(5);
1155     }
1156
1157     timer_delete(timer);
1158
1159     if (timer_create(CLOCK_REALTIME, &ev, &timer) != 0) {
1160         fprintf(stderr,"No CLOCK_REALTIME timer\n");
1161         exit(2);
1162     }
1163
1164     it.it_value.tv_sec = 0;
1165     it.it_value.tv_nsec = 1000000;
1166     it.it_interval = it.it_value;
1167     if (timer_settime(timer, 0, &it, NULL) != 0) {
1168         fprintf(stderr,"settime problem\n");
1169         exit(4);
1170     }
1171
1172     tock = 0;
1173
1174     usleep(3000);
1175
1176     if (!tock) {
1177         fprintf(stderr,"no CLOCK_REALTIME signal\n");
1178         exit(5);
1179     }
1180
1181     timer_delete(timer);
1182
1183     exit(0);
1184 }
1185      ],
1186      [fptools_cv_timer_create_works=yes],
1187      [fptools_cv_timer_create_works=no])
1188   ])
1189 case $fptools_cv_timer_create_works in
1190     yes) AC_DEFINE([USE_TIMER_CREATE], 1,
1191                    [Define to 1 if we can use timer_create(CLOCK_PROCESS_CPUTIME_ID,...)]);;
1192 esac
1193 ])
1194
1195 # FP_ARG_GMP
1196 # -------------
1197 AC_DEFUN([FP_ARG_GMP],
1198 [
1199 AC_ARG_WITH([gmp-includes],
1200   [AC_HELP_STRING([--with-gmp-includes],
1201     [directory containing gmp.h])],
1202     [gmp_includes=$withval],
1203     [gmp_includes=NONE])
1204
1205 AC_ARG_WITH([gmp-libraries],
1206   [AC_HELP_STRING([--with-gmp-libraries],
1207     [directory containing gmp library])],
1208     [gmp_libraries=$withval],
1209     [gmp_libraries=NONE])
1210 ])# FP_ARG_GMP
1211
1212 AC_DEFUN([CHECK_GMP],
1213 [AC_REQUIRE([AC_PROG_CPP])
1214 AC_REQUIRE([AC_PROG_CC])
1215 ])
1216
1217 # FP_CHECK_MACOSX_DEPLOYMENT_TARGET
1218 # ---------------------------------
1219 AC_DEFUN([FP_CHECK_MACOSX_DEPLOYMENT_TARGET],
1220 [
1221 if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple"; then
1222   AC_MSG_CHECKING([Mac OS X deployment target])
1223   case $FP_MACOSX_DEPLOYMENT_TARGET in
1224     none)  ;;
1225     10.4)  MACOSX_DEPLOYMENT_VERSION=10.4
1226            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1227            ;;
1228     10.4u) MACOSX_DEPLOYMENT_VERSION=10.4
1229            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1230            ;;
1231     *)     MACOSX_DEPLOYMENT_VERSION=$FP_MACOSX_DEPLOYMENT_TARGET
1232            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX${FP_MACOSX_DEPLOYMENT_TARGET}.sdk
1233            ;;
1234   esac
1235   if test "x$FP_MACOSX_DEPLOYMENT_TARGET" = "xnone"; then
1236     AC_MSG_RESULT(none)
1237   else
1238     if test ! -d $MACOSX_DEPLOYMENT_SDK; then
1239       AC_MSG_ERROR([Unknown deployment target $FP_MACOSX_DEPLOYMENT_TARGET])
1240     fi
1241     AC_MSG_RESULT([${MACOSX_DEPLOYMENT_VERSION} (${MACOSX_DEPLOYMENT_SDK})])
1242   fi
1243 fi
1244 ])
1245
1246 # --------------------------------------------------------------
1247 # Calculate absolute path to build tree
1248 # --------------------------------------------------------------
1249
1250 AC_DEFUN([FP_FIND_ROOT],[
1251 AC_MSG_CHECKING(for path to top of build tree)
1252
1253 dnl This would be
1254 dnl     make -C utils/pwd clean && make -C utils/pwd
1255 dnl except we don't want to have to know what make is called. Sigh.
1256 if test ! -f utils/pwd/pwd && test ! -f utils/pwd/pwd.exe; then
1257   cd utils/pwd
1258   rm -f *.o
1259   rm -f *.hi
1260   rm -f pwd
1261   rm -f pwd.exe
1262   $WithGhc -v0 --make pwd -o pwd
1263   cd ../..
1264 fi
1265
1266 hardtop=`utils/pwd/pwd forwardslash`
1267
1268 if ! test -d "$hardtop"; then
1269   AC_MSG_ERROR([cannot determine current directory])
1270 fi
1271
1272 dnl Remove common automounter nonsense
1273 dnl
1274 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|'`
1275
1276 AC_SUBST(hardtop)
1277
1278 AC_MSG_RESULT(${hardtop})
1279
1280 # We don't support building in directories with spaces.
1281 case "$hardtop" in
1282   *' '*) AC_MSG_ERROR([
1283    The build system does not support building in a directory containing
1284    space characters.  Suggestion: move the build tree somewhere else.])
1285  ;;
1286 esac
1287 ])
1288
1289 # LocalWords:  fi