aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
   8 # ----------------------------------
   9 # Little endian Arm on Linux with some ABIs has big endian word order
  10 # in doubles. Define FLOAT_WORDS_BIGENDIAN if this is the case.
  11 AC_DEFUN([FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN],
  12   [AC_CACHE_CHECK([whether float word order is big endian], [fptools_cv_float_word_order_bigendian],
  13     [AC_COMPILE_IFELSE(
  14       [AC_LANG_PROGRAM(
  15         [#include <endian.h>],
  16         [#if defined(__FLOAT_WORD_ORDER) && __FLOAT_WORD_ORDER == BIG_ENDIAN
  17              return 0;
  18          #else
  19              not float word order big endian
  20          #endif]
  21       )],
  22       [fptools_cv_float_word_order_bigendian=yes],
  23       [fptools_cv_float_word_order_bigendian=no])
  24     ])
  25   case $fptools_cv_float_word_order_bigendian in
  26       yes)
  27           AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
  28           [Define to 1 if your processor stores words of floats with
  29            the most significant byte first]) ;;
  30   esac
  31 ])
  32
  33
  34 # FP_EVAL_STDERR(COMMAND)
  35 # -----------------------
  36 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  37 # into the file conftest.err and the exit status in the variable fp_status.
  38 AC_DEFUN([FP_EVAL_STDERR],
  39 [{ (eval $1) 2>conftest.er1
  40   fp_status=$?
  41   grep -v '^ *+' conftest.er1 >conftest.err
  42   rm -f conftest.er1
  43   (exit $fp_status); }[]dnl
  44 ])# FP_EVAL_STDERR
  45
  46
  47 # FP_PROG_CONTEXT_DIFF
  48 # --------------------
  49 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  50 #
  51 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  52 #
  53 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  54 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  55 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  56 [echo foo > conftest1
  57 echo foo > conftest2
  58 fp_cv_context_diff=no
  59 for fp_var in '-U 1' '-u1' '-C 1' '-c1'
  60 do
  61   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  62     fp_cv_context_diff="diff $fp_var"
  63     break
  64   fi
  65 done])
  66 if test x"$fp_cv_context_diff" = xno; then
  67    AC_MSG_ERROR([cannot figure out how to do context diffs])
  68 fi
  69 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  70 ])# FP_PROG_CONTEXT_DIFF
  71
  72
  73 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
  74 # --------------------------------------------------------
  75 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
  76 # compilation. Execute IF-FAILS when unable to determine the value. Works for
  77 # cross-compilation, too.
  78 #
  79 # Implementation note: We are lazy and use an internal autoconf macro, but it
  80 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
  81 # little risk.
  82 AC_DEFUN([FP_COMPUTE_INT],
  83 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
  84 ])# FP_COMPUTE_INT
  85
  86
  87 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
  88 # ------------------------------------------------------------------
  89 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
  90 # given type. Defines ALIGNMENT_TYPE.
  91 AC_DEFUN([FP_CHECK_ALIGNMENT],
  92 [AS_LITERAL_IF([$1], [],
  93                [AC_FATAL([$0: requires literal arguments])])[]dnl
  94 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
  95 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
  96 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
  97 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
  98   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
  99                  [fp_Cache],
 100                  [AC_INCLUDES_DEFAULT([$3])],
 101                  [AC_MSG_ERROR([cannot compute alignment ($1)
 102 See `config.log' for more details.], [77])])
 103 else
 104   fp_Cache=0
 105 fi])[]dnl
 106 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 107 m4_popdef([fp_Cache])[]dnl
 108 ])# FP_CHECK_ALIGNMENT
 109
 110
 111 # FP_LEADING_UNDERSCORE
 112 # ---------------------
 113 # Test for determining whether symbol names have a leading underscore. We assume
 114 # that they _haven't_ if anything goes wrong. Sets the output variable
 115 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 116 #
 117 # Some nlist implementations seem to try to be compatible by ignoring a leading
 118 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 119 # checking for *no* leading underscore first. Sigh.  --SDM
 120 #
 121 # Similarly on OpenBSD, but this test doesn't help. -- dons
 122 AC_DEFUN([FP_LEADING_UNDERSCORE],
 123 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 124 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 125 # Hack!: nlist() under Digital UNIX insist on there being an _,
 126 # but symbol table listings shows none. What is going on here?!?
 127 #
 128 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 129 # the underscoredness of that "platform"
 130 case $HostPlatform in
 131 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 132   case $build in
 133     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 134     *) fptools_cv_leading_underscore=no ;;
 135   esac ;;
 136 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 137 *cygwin32) fptools_cv_leading_underscore=yes;;
 138 *mingw32) fptools_cv_leading_underscore=yes;;
 139
 140     # HACK: Apple doesn't seem to provide nlist in the 64-bit-libraries
 141 x86_64-apple-darwin*) fptools_cv_leading_underscore=yes;;
 142
 143 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 144 #include <nlist.h>
 145 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 146 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 147 #endif
 148
 149 int main(argc, argv)
 150 int argc;
 151 char **argv;
 152 {
 153 #ifdef HAVE_NLIST_H
 154     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 155         exit(1);
 156     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 157         exit(0);
 158 #endif
 159     exit(1);
 160 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 161 ;;
 162 esac]);
 163 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 164 if test x"$fptools_cv_leading_underscore" = xyes; then
 165    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 166 fi])# FP_LEADING_UNDERSCORE
 167
 168
 169 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 170 # ----------------------------------------------------------------------------------
 171 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 172 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 173 AC_DEFUN([FP_COMPARE_VERSIONS],
 174 [fp_version1=$1; fp_version2=$3
 175 fp_save_IFS=$IFS; IFS='.'
 176 while test x"$fp_version1" != x || test x"$fp_version2" != x
 177 do
 178
 179   set dummy $fp_version1; shift
 180   fp_num1=""
 181   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 182   test x"$fp_num1" = x && fp_num1="0"
 183   fp_version1="[$]*"
 184
 185   set dummy $fp_version2; shift
 186   fp_num2=""
 187   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 188   test x"$fp_num2" = x && fp_num2="0"
 189   fp_version2="[$]*"
 190
 191   test "$fp_num1" = "$fp_num2" || break;
 192 done
 193 IFS=$fp_save_IFS
 194 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 195 ])# FP_COMPARE_VERSIONS
 196
 197
 198 dnl
 199 dnl Check for GreenCard and version.
 200 dnl
 201 AC_DEFUN([FPTOOLS_GREENCARD],
 202 [
 203 AC_PATH_PROG(GreenCardCmd,greencard)
 204 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 205 changequote(, )dnl
 206 [if test x"$GreenCardCmd" != x; then
 207    fptools_cv_greencard_version="`$GreenCardCmd --version |
 208                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 209 else
 210    fptools_cv_greencard_version=""
 211 fi
 212 changequote([, ])dnl
 213 ])
 214 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 215   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 216 GreenCardVersion=$fptools_cv_greencard_version
 217 AC_SUBST(GreenCardVersion)
 218 ])
 219
 220 dnl
 221 dnl Check for Happy and version.  If we're building GHC, then we need
 222 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 223 dnl for a happy source tree and point the build system at that instead.
 224 dnl
 225 AC_DEFUN([FPTOOLS_HAPPY],
 226 [AC_PATH_PROG(HappyCmd,happy,)
 227 # Happy is passed to Cabal, so we need a native path
 228 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 229    test "${OSTYPE}"      != "msys"                  && \
 230    test "${HappyCmd}"    != ""
 231 then
 232     # Canonicalise to <drive>:/path/to/gcc
 233     HappyCmd=`cygpath -m ${HappyCmd}`
 234     AC_MSG_NOTICE([normalized happy command to $HappyCmd])
 235 fi
 236
 237 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 238 changequote(, )dnl
 239 [if test x"$HappyCmd" != x; then
 240    fptools_cv_happy_version=`"$HappyCmd" -v |
 241                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'` ;
 242 else
 243    fptools_cv_happy_version="";
 244 fi;
 245 changequote([, ])dnl
 246 ])
 247 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
 248 then
 249     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.16],
 250       [AC_MSG_ERROR([Happy version 1.16 or later is required to compile GHC.])])[]
 251 fi
 252 HappyVersion=$fptools_cv_happy_version;
 253 AC_SUBST(HappyVersion)
 254 ])
 255
 256 dnl
 257 dnl Check for Alex and version.  If we're building GHC, then we need
 258 dnl at least Alex version 2.0.1.
 259 dnl
 260 AC_DEFUN([FPTOOLS_ALEX],
 261 [
 262 AC_PATH_PROG(AlexCmd,alex,)
 263 # Alex is passed to Cabal, so we need a native path
 264 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 265    test "${OSTYPE}"      != "msys"                  && \
 266    test "${AlexCmd}"     != ""
 267 then
 268     # Canonicalise to <drive>:/path/to/gcc
 269     AlexCmd=`cygpath -m ${AlexCmd}`
 270 fi
 271
 272 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 273 changequote(, )dnl
 274 [if test x"$AlexCmd" != x; then
 275    fptools_cv_alex_version=`"$AlexCmd" -v |
 276                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'` ;
 277 else
 278    fptools_cv_alex_version="";
 279 fi;
 280 changequote([, ])dnl
 281 ])
 282 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
 283 then
 284     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.1.0],
 285       [AC_MSG_ERROR([Alex version 2.1.0 or later is required to compile GHC.])])[]
 286 fi
 287 AlexVersion=$fptools_cv_alex_version;
 288 AC_SUBST(AlexVersion)
 289 ])
 290
 291
 292
 293 # FP_PROG_LD
 294 # ----------
 295 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 296 # of ld. Exits if no ld can be found
 297 AC_DEFUN([FP_PROG_LD],
 298 [
 299 if test -z "$1"
 300 then
 301   AC_PATH_PROG([fp_prog_ld_raw], [ld])
 302   if test -z "$fp_prog_ld_raw"; then
 303     AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 304   fi
 305   LdCmd=$fp_prog_ld_raw
 306   case $HostPlatform in
 307     *mingw32) if test x${OSTYPE} != xmsys; then
 308               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 309                 AC_MSG_NOTICE([normalized ld command to $LdCmd])
 310               fi
 311             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
 312             # the generation of relocatable object files with large amounts
 313             # of relocations correctly. (cf. HSbase.o splittage-hack)
 314             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
 315             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
 316                                   [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
 317               ;;
 318   esac
 319 else
 320   LdCmd="$1"
 321 fi
 322 AC_SUBST([LdCmd])
 323 ])# FP_PROG_LD
 324
 325
 326 # FP_PROG_LD_X
 327 # ------------
 328 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 329 # variable's value is empty.
 330 AC_DEFUN([FP_PROG_LD_X],
 331 [AC_REQUIRE([FP_PROG_LD])
 332 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 333 [echo 'foo() {}' > conftest.c
 334 ${CC-cc} -c conftest.c
 335 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
 336    fp_cv_ld_x=yes
 337 else
 338    fp_cv_ld_x=no
 339 fi
 340 rm -rf conftest*])
 341 if test "$fp_cv_ld_x" = yes; then
 342   LdXFlag=-x
 343 else
 344   LdXFlag=
 345 fi
 346 AC_SUBST([LdXFlag])
 347 ])# FP_PROG_LD_X
 348
 349
 350 # FP_PROG_LD_IS_GNU
 351 # -----------------
 352 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 353 # GNU ld or not.
 354 AC_DEFUN([FP_PROG_LD_IS_GNU],
 355 [AC_REQUIRE([FP_PROG_LD])
 356 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 357 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 358   fp_cv_gnu_ld=yes
 359 else
 360   fp_cv_gnu_ld=no
 361 fi])
 362 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 363 ])# FP_PROG_LD_IS_GNU
 364
 365
 366 # FP_PROG_AR
 367 # ----------
 368 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 369 # version of it. Exits if no ar can be found
 370 AC_DEFUN([FP_PROG_AR],
 371 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 372 if test -z "$fp_prog_ar_raw"; then
 373   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 374 fi
 375 fp_prog_ar=$fp_prog_ar_raw
 376 case $HostPlatform in
 377   *mingw32) if test x${OSTYPE} != xmsys; then
 378               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 379               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 380             fi
 381             ;;
 382 esac
 383 ])# FP_PROG_AR
 384
 385
 386 # FP_PROG_AR_IS_GNU
 387 # -----------------
 388 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 389 AC_DEFUN([FP_PROG_AR_IS_GNU],
 390 [AC_REQUIRE([FP_PROG_AR])
 391 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 392 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 393   fp_cv_prog_ar_is_gnu=yes
 394 else
 395   fp_cv_prog_ar_is_gnu=no
 396 fi])
 397 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 398 ])# FP_PROG_AR_IS_GNU
 399
 400
 401 # FP_PROG_AR_ARGS
 402 # ---------------
 403 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 404 # to a non-Cygwin invocation of ar including these arguments.
 405 AC_DEFUN([FP_PROG_AR_ARGS],
 406 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 407 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 408 [
 409 # GNU ar needs special treatment: it appears to have problems with
 410 # object files with the same name if you use the 's' modifier, but
 411 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 412 if test $fp_prog_ar_is_gnu = yes; then
 413   fp_cv_prog_ar_args="q"
 414 else
 415   touch conftest.dummy
 416   for fp_var in clqsZ clqs cqs clq cq ; do
 417      rm -f conftest.a
 418      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 419         fp_cv_prog_ar_args=$fp_var
 420         break
 421      fi
 422   done
 423   rm -f conftest*
 424   if test -z "$fp_cv_prog_ar_args"; then
 425     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 426   fi
 427 fi])
 428 fp_prog_ar_args=$fp_cv_prog_ar_args
 429 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 430
 431 ])# FP_PROG_AR_ARGS
 432
 433
 434 # FP_PROG_AR_NEEDS_RANLIB
 435 # -----------------------
 436 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 437 # to ":" otherwise.
 438 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 439 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 440 AC_REQUIRE([FP_PROG_AR_ARGS])
 441 AC_REQUIRE([AC_PROG_CC])
 442 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 443 [if test $fp_prog_ar_is_gnu = yes; then
 444   fp_cv_prog_ar_needs_ranlib=no
 445 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
 446   # It's quite tedious to check for Apple's crazy timestamps in .a files,
 447   # so we hardcode it.
 448   fp_cv_prog_ar_needs_ranlib=yes
 449 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 450   fp_cv_prog_ar_needs_ranlib=no
 451 else
 452   fp_cv_prog_ar_needs_ranlib=yes
 453 fi])
 454 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 455    AC_PROG_RANLIB
 456 else
 457   RANLIB=":"
 458   AC_SUBST([RANLIB])
 459 fi
 460 ])# FP_PROG_AR_NEEDS_RANLIB
 461
 462
 463 # FP_PROG_AR_SUPPORTS_INPUT
 464 # -------------------------
 465 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 466 # whether ar supports -input flag is supported or not.
 467 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 468 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 469 AC_REQUIRE([FP_PROG_AR_ARGS])
 470 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 471 [fp_cv_prog_ar_supports_input=no
 472 if test $fp_prog_ar_is_gnu = no; then
 473   rm -f conftest*
 474   touch conftest.lst
 475   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 476     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 477   fi
 478   rm -f conftest*
 479 fi])
 480 if test $fp_cv_prog_ar_supports_input = yes; then
 481     ArSupportsInput="-input"
 482 else
 483     ArSupportsInput=""
 484 fi
 485 AC_SUBST([ArSupportsInput])
 486 ])# FP_PROG_AR_SUPPORTS_INPUT
 487
 488
 489 dnl
 490 dnl AC_SHEBANG_PERL - can we she-bang perl?
 491 dnl
 492 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
 493 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 494 [echo "#!$PerlCmd"'
 495 exit $1;
 496 ' > conftest
 497 chmod u+x conftest
 498 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 499 if test $? -ne 69; then
 500    fptools_cv_shebang_perl=yes
 501 else
 502    fptools_cv_shebang_perl=no
 503 fi
 504 rm -f conftest
 505 ])])
 506
 507
 508 # FP_HAVE_GCC
 509 # -----------
 510 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 511 # output variables HaveGcc and GccVersion.
 512 AC_DEFUN([FP_HAVE_GCC],
 513 [AC_REQUIRE([AC_PROG_CC])
 514 if test -z "$GCC"; then
 515    fp_have_gcc=NO
 516 else
 517    fp_have_gcc=YES
 518 fi
 519 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
 520   AC_MSG_ERROR([gcc is required])
 521 fi
 522 GccLT34=
 523 AC_CACHE_CHECK([version of gcc], [fp_cv_gcc_version],
 524 [if test "$fp_have_gcc" = "YES"; then
 525    fp_cv_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
 526    FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.0],
 527      [AC_MSG_ERROR([Need at least gcc version 3.0 (3.4+ recommended)])])
 528    # See #2770: gcc 2.95 doesn't work any more, apparently.  There probably
 529    # isn't a very good reason for that, but for now just make configure
 530    # fail.
 531    FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.4], GccLT34=YES)
 532  else
 533    fp_cv_gcc_version="not-installed"
 534  fi
 535 ])
 536 AC_SUBST([HaveGcc], [$fp_have_gcc])
 537 AC_SUBST([GccVersion], [$fp_cv_gcc_version])
 538 AC_SUBST(GccLT34)
 539 ])# FP_HAVE_GCC
 540
 541 dnl Small feature test for perl version. Assumes PerlCmd
 542 dnl contains path to perl binary.
 543 dnl
 544 dnl (Perl versions prior to v5.6 does not contain the string "v5";
 545 dnl instead they display version strings such as "version 5.005".)
 546 dnl
 547 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
 548 [$PerlCmd -v >conftest.out 2>&1
 549    if grep "v5" conftest.out >/dev/null 2>&1; then
 550       :
 551    else
 552       AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
 553    fi
 554 rm -fr conftest*
 555 ])
 556
 557
 558 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 559 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 560 # -----------------------------------------------------
 561 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 562 # of PROG-TO-CHECK-FOR when found.
 563 AC_DEFUN([FP_CHECK_PROG],
 564 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 565 )# FP_CHECK_PROC
 566
 567
 568 # FP_PROG_FIND
 569 # ------------
 570 # Find a non-WinDoze version of the "find" utility.
 571 AC_DEFUN([FP_PROG_FIND],
 572 [AC_PATH_PROGS([fp_prog_find], [gfind find], find)
 573 echo foo > conftest.txt
 574 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 575 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 576   # OK, looks like a real "find".
 577   case $HostPlatform in
 578     *mingw32)
 579       if test x${OSTYPE} != xmsys
 580       then
 581             fp_prog_find="`cygpath --mixed ${fp_prog_find}`"
 582         AC_MSG_NOTICE([normalized find command to $fp_prog_find])
 583       fi ;;
 584     *) ;;
 585   esac
 586   FindCmd="$fp_prog_find"
 587 else
 588   # Found a poor WinDoze version of "find", ignore it.
 589   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 590   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 591 fi
 592 rm -f conftest.txt conftest.out
 593 AC_SUBST([FindCmd])[]dnl
 594 ])# FP_PROG_FIND
 595
 596
 597 # FP_PROG_SORT
 598 # ------------
 599 # Find a Unix-like sort
 600 AC_DEFUN([FP_PROG_SORT],
 601 [AC_PATH_PROG([fp_prog_sort], [sort])
 602 echo conwip > conftest.txt
 603 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
 604 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
 605   # The goods
 606   SortCmd="$fp_prog_sort"
 607 else
 608   # Summink else..pick next one.
 609   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
 610   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
 611 fi
 612 rm -f conftest.txt conftest.out
 613 AC_SUBST([SortCmd])[]dnl
 614 ])# FP_PROG_SORT
 615
 616 dnl
 617 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 618 dnl values of the second argument to the result of running
 619 dnl the commands given by the third. It does not cache its
 620 dnl result, so it is suitable for checks which should be
 621 dnl run every time.
 622 dnl
 623 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
 624 [AC_MSG_CHECKING([$1])
 625  $3
 626  AC_MSG_RESULT([$][$2])
 627 ])
 628
 629 dnl
 630 dnl FPTOOLS_GHC_VERSION(version)
 631 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 632 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 633 dnl
 634 dnl Test for version of installed ghc.  Uses $GHC.
 635 dnl [original version pinched from c2hs]
 636 dnl
 637 AC_DEFUN([FPTOOLS_GHC_VERSION],
 638 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 639 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 640   cat conftestghc >&AS_MESSAGE_LOG_FD
 641 #Useless Use Of cat award...
 642   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 643   rm -fr conftest*
 644   if test "[$]fptools_version_of_ghc" = ""
 645   then
 646     fptools_version_of_ghc='unknown'
 647   fi
 648 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 649 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 650 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 651 #
 652 if test "[$]fptools_version_of_ghc[_pl]" = ""
 653 then
 654   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 655   fptools_version_of_ghc[_pl]="0"
 656 else
 657   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 658 fi
 659 #
 660 ifelse($#, [1], [dnl
 661 [$1]="[$]fptools_version_of_ghc[_all]"
 662 ], $#, [2], [dnl
 663 [$1]="[$]fptools_version_of_ghc[_major]"
 664 [$2]="[$]fptools_version_of_ghc[_minor]"
 665 ], $#, [3], [dnl
 666 [$1]="[$]fptools_version_of_ghc[_major]"
 667 [$2]="[$]fptools_version_of_ghc[_minor]"
 668 [$3]="[$]fptools_version_of_ghc[_pl]"
 669 ], $#, [4], [dnl
 670 [$1]="[$]fptools_version_of_ghc[_all]"
 671 [$2]="[$]fptools_version_of_ghc[_major]"
 672 [$3]="[$]fptools_version_of_ghc[_minor]"
 673 [$4]="[$]fptools_version_of_ghc[_pl]"
 674 ])
 675 ])
 676 ])dnl
 677
 678
 679 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 680 # ---------------------------------------------------------------------------------
 681 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 682 # additional flexibility of specifying the PROLOGUE and BODY.
 683 AC_DEFUN([FP_CHECK_FUNC],
 684 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 685 AC_CACHE_CHECK([for $1], fp_func,
 686 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 687                 [AS_VAR_SET(fp_func, yes)],
 688                 [AS_VAR_SET(fp_func, no)])])
 689 AS_IF([test AS_VAR_GET(fp_func) = yes],
 690       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 691                 [Define to 1 if you have the `]$1[' function.]) $4],
 692       [$5])dnl
 693 AS_VAR_POPDEF([fp_func])dnl
 694 ])# FP_CHECK_FUNC
 695
 696
 697 # FP_GEN_DOCBOOK_XML
 698 # ------------------
 699 # Generates a DocBook XML V4.2 document in conftest.xml.
 700 #
 701 # It took a lot of experimentation to find a document that will cause
 702 # xsltproc to fail with an error code when the relevant
 703 # stylesheets/DTDs are not found.  I couldn't make xsltproc fail with
 704 # a single-file document, it seems a multi-file document is needed.
 705 # -- SDM 2009-06-03
 706 #
 707 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 708 [rm -f conftest.xml conftest-book.xml
 709 cat > conftest.xml << EOF
 710 <?xml version="1.0" encoding="iso-8859-1"?>
 711 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 712    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd" [[
 713 <!ENTITY conftest-book SYSTEM "conftest-book.xml">
 714 ]]>
 715 <book id="test">
 716 &conftest-book;
 717 </book>
 718 EOF
 719 cat >conftest-book.xml << EOF
 720 <?xml version="1.0" encoding="iso-8859-1"?>
 721   <title>A DocBook &ldquo;Test Document&rdquo;</title>
 722   <chapter id="id-one">
 723     <title>A Chapter Title</title>
 724     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 725   </chapter>
 726   <chapter id="id-two">
 727     <title>Another Chapter Title</title>
 728     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 729   </chapter>
 730 EOF
 731 ]) # FP_GEN_DOCBOOK_XML
 732
 733
 734 # FP_PROG_DBLATEX
 735 # ----------------
 736 # Sets the output variable DblatexCmd to the full path of dblatex,
 737 # which we use for building PDF and PS docs.
 738 # DblatexCmd is empty if dblatex could not be found.
 739 AC_DEFUN([FP_PROG_DBLATEX],
 740 [AC_PATH_PROG([DblatexCmd], [dblatex])
 741 if test -z "$DblatexCmd"; then
 742   AC_MSG_WARN([cannot find dblatex in your PATH, you will not be able to build the PDF and PS documentation])
 743 fi
 744 ])# FP_PROG_DBLATEX
 745
 746
 747 # FP_PROG_XSLTPROC
 748 # ----------------
 749 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 750 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 751 AC_DEFUN([FP_PROG_XSLTPROC],
 752 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 753 if test -z "$XsltprocCmd"; then
 754   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the HTML documentation])
 755 fi
 756 ])# FP_PROG_XSLTPROC
 757
 758
 759 # FP_DOCBOOK_XSL
 760 # ----------------------------
 761 # Check that we can process a DocBook XML document to HTML using xsltproc.
 762 AC_DEFUN([FP_DOCBOOK_XSL],
 763 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 764 if test -n "$XsltprocCmd"; then
 765   AC_CACHE_CHECK([for DocBook XSL stylesheet], fp_cv_dir_docbook_xsl,
 766   [FP_GEN_DOCBOOK_XML
 767   fp_cv_dir_docbook_xsl=no
 768   if $XsltprocCmd --nonet http://docbook.sourceforge.net/release/xsl/current/html/chunk.xsl conftest.xml > /dev/null 2>&1; then
 769      fp_cv_dir_docbook_xsl=yes
 770   fi
 771   rm -rf conftest*])
 772 fi
 773 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 774   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 775   HAVE_DOCBOOK_XSL=NO
 776 else
 777   HAVE_DOCBOOK_XSL=YES
 778 fi
 779 AC_SUBST([HAVE_DOCBOOK_XSL])
 780 ])# FP_DOCBOOK_XSL
 781
 782
 783 # FP_PROG_XMLLINT
 784 # ----------------
 785 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 786 # xmllint. XmllintCmd is empty if xmllint could not be found.
 787 AC_DEFUN([FP_PROG_XMLLINT],
 788 [AC_PATH_PROG([XmllintCmd], [xmllint])
 789 if test -z "$XmllintCmd"; then
 790   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 791 fi
 792 ])# FP_PROG_XMLLINT
 793
 794
 795 # FP_CHECK_DOCBOOK_DTD
 796 # --------------------
 797 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 798 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 799 if test -n "$XmllintCmd"; then
 800   AC_MSG_CHECKING([for DocBook DTD])
 801   FP_GEN_DOCBOOK_XML
 802   if $XmllintCmd --nonet --valid --noout conftest.xml ; then
 803     AC_MSG_RESULT([ok])
 804   else
 805     AC_MSG_RESULT([failed])
 806     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 807     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 808   fi
 809   rm -rf conftest*
 810 fi
 811 ])# FP_CHECK_DOCBOOK_DTD
 812
 813
 814 # FP_GEN_FO
 815 # ------------------
 816 # Generates a formatting objects document in conftest.fo.
 817 AC_DEFUN([FP_GEN_FO],
 818 [rm -f conftest.fo
 819 cat > conftest.fo << EOF
 820 <?xml version="1.0"?>
 821 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 822   <fo:layout-master-set>
 823     <fo:simple-page-master master-name="blank">
 824       <fo:region-body/>
 825     </fo:simple-page-master>
 826   </fo:layout-master-set>
 827   <fo:page-sequence master-reference="blank">
 828     <fo:flow flow-name="xsl-region-body">
 829       <fo:block>
 830         Test!
 831       </fo:block>
 832     </fo:flow>
 833   </fo:page-sequence>
 834 </fo:root>
 835 EOF
 836 ]) # FP_GEN_FO
 837
 838
 839 # FP_PROG_FOP
 840 # -----------
 841 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 842 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 843 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 844 AC_DEFUN([FP_PROG_FOP],
 845 [AC_PATH_PROGS([FopCmd1], [fop fop.sh])
 846 if test -n "$FopCmd1"; then
 847   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 848     [FP_GEN_FO
 849     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 850       fp_cv_fop_usability=yes
 851     else
 852       fp_cv_fop_usability=no
 853     fi
 854     rm -rf conftest*])
 855   if test x"$fp_cv_fop_usability" = xyes; then
 856      FopCmd=$FopCmd1
 857   fi
 858 fi
 859 if test -z "$FopCmd"; then
 860   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 861   FopCmd=$FopCmd2
 862 fi
 863 AC_SUBST([FopCmd])
 864 ])# FP_PROG_FOP
 865
 866
 867 # FP_PROG_HSTAGS
 868 # ----------------
 869 # Sets the output variable HstagsCmd to the full Haskell tags program path.
 870 # HstagsCmd is empty if no such program could be found.
 871 AC_DEFUN([FP_PROG_HSTAGS],
 872 [AC_PATH_PROG([HstagsCmd], [hasktags])
 873 if test -z "$HstagsCmd"; then
 874   AC_MSG_WARN([cannot find hasktags in your PATH, you will not be able to build the tags])
 875 fi
 876 ])# FP_PROG_HSTAGS
 877
 878
 879 # FP_PROG_GHC_PKG
 880 # ----------------
 881 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
 882 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
 883 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
 884 AC_DEFUN([FP_PROG_GHC_PKG],
 885 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
 886 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
 887 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
 888   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 889 elif "$fp_ghc_pkg_guess" list > /dev/null 2>&1; then
 890   # from 6.10, ghc-pkg doesn't support the old -l syntax any more
 891   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 892 else
 893   fp_cv_matching_ghc_pkg=no
 894 fi])
 895 if test x"$fp_cv_matching_ghc_pkg" = xno; then
 896   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
 897 else
 898   GhcPkgCmd=$fp_cv_matching_ghc_pkg
 899 fi])# FP_PROG_GHC_PKG
 900
 901
 902 # FP_GCC_EXTRA_FLAGS
 903 # ------------------
 904 # Determine which extra flags we need to pass gcc when we invoke it
 905 # to compile .hc code.
 906 #
 907 # Some OSs (Mandrake Linux, in particular) configure GCC with
 908 # -momit-leaf-frame-pointer on by default. If this is the case, we
 909 # need to turn it off for mangling to work. The test is currently a
 910 # bit crude, using only the version number of gcc.
 911 #
 912 # -fwrapv is needed for gcc to emit well-behaved code in the presence of
 913 # integer wrap around. (Trac #952)
 914 #
 915 # -fno-unit-at-a-time or -fno-toplevel-reoder is necessary to avoid gcc
 916 # reordering things in the module and confusing the manger and/or splitter.
 917 # (eg. Trac #1427)
 918 #
 919 AC_DEFUN([FP_GCC_EXTRA_FLAGS],
 920 [AC_REQUIRE([FP_HAVE_GCC])
 921 AC_CACHE_CHECK([for extra options to pass gcc when compiling via C], [fp_cv_gcc_extra_opts],
 922 [fp_cv_gcc_extra_opts=
 923  FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.4],
 924   [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fwrapv"],
 925   [])
 926  case $TargetPlatform in
 927   i386-*|x86_64-*)
 928      FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.2],
 929       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -mno-omit-leaf-frame-pointer"],
 930       [])
 931     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.4],
 932      [FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [4.2],
 933        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
 934        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-unit-at-a-time"]
 935      )],
 936      [])
 937   ;;
 938   sparc-*-solaris2)
 939     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [4.2],
 940       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
 941       [])
 942   ;;
 943  esac
 944 ])
 945 AC_SUBST([GccExtraViaCOpts],$fp_cv_gcc_extra_opts)
 946 ])
 947
 948
 949 # FP_SETUP_PROJECT_VERSION
 950 # ---------------------
 951 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
 952 [
 953 if test "$RELEASE" = "NO"; then
 954     AC_MSG_CHECKING([for GHC version date])
 955     if test -f VERSION_DATE; then
 956         PACKAGE_VERSION=${PACKAGE_VERSION}.`cat VERSION_DATE`
 957         AC_MSG_RESULT(given $PACKAGE_VERSION)
 958     elif test -d .git; then
 959         changequote(, )dnl
 960         ver_date=`git log -n 1 --date=short --pretty=format:%ci | sed "s/^.*\([0-9][0-9][0-9][0-9]\)-\([0-9][0-9]\)-\([0-9][0-9]\).*$/\1\2\3/"`
 961         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
 962         changequote([, ])dnl
 963                 AC_MSG_ERROR([failed to detect version date: check that git is in your path])
 964         fi
 965         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
 966         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
 967     elif test -d _darcs; then
 968         # TODO: Remove this branch after conversion to Git
 969         changequote(, )dnl
 970         ver_date=`darcs changes --quiet --no-summary --xml | head -500 | grep 'date=' | sed "s/^.*date='\([0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]\).*$/\1/g" | ${SortCmd} -n | tail -1`
 971         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
 972         changequote([, ])dnl
 973                 AC_MSG_ERROR([failed to detect version date: check that darcs is in your path])
 974         fi
 975         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
 976         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
 977     elif test -f VERSION; then
 978         PACKAGE_VERSION=`cat VERSION`
 979         AC_MSG_RESULT(given $PACKAGE_VERSION)
 980     else
 981         AC_MSG_WARN([cannot determine snapshot version: no .git or _darcs directory and no VERSION file])
 982     fi
 983 fi
 984
 985 # Some renamings
 986 AC_SUBST([ProjectName], [$PACKAGE_NAME])
 987 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
 988
 989 # Split PACKAGE_VERSION into (possibly empty) parts
 990 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
 991 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
 992 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
 993 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
 994
 995 # Calculate project version as an integer, using 2 digits for minor version
 996 case $VERSION_MINOR in
 997   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
 998   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
 999   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
1000 esac
1001 AC_SUBST([ProjectVersionInt])
1002
1003 # The project patchlevel is zero unless stated otherwise
1004 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
1005
1006 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
1007 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
1008
1009 AC_SUBST([ProjectPatchLevel])
1010 ])# FP_SETUP_PROJECT_VERSION
1011
1012
1013 # Check for a working timer_create().  We need a pretty detailed check
1014 # here, because there exist partially-working implementations of
1015 # timer_create() in certain versions of Linux (see bug #1933).
1016 #
1017 AC_DEFUN([FP_CHECK_TIMER_CREATE],
1018   [AC_CACHE_CHECK([for a working timer_create(CLOCK_REALTIME)],
1019     [fptools_cv_timer_create_works],
1020     [AC_TRY_RUN([
1021 #include <stdio.h>
1022 #ifdef HAVE_STDLIB_H
1023 #include <stdlib.h>
1024 #endif
1025 #ifdef HAVE_TIME_H
1026 #include <time.h>
1027 #endif
1028 #ifdef HAVE_SIGNAL_H
1029 #include <signal.h>
1030 #endif
1031 #ifdef HAVE_UNISTD_H
1032 #include <unistd.h>
1033 #endif
1034
1035 static volatile int tock = 0;
1036 static void handler(int i)
1037 {
1038    tock = 1;
1039 }
1040
1041 static void timeout(int i)
1042 {
1043   // timer_settime() has been known to hang, so just in case
1044   // we install a 1-second timeout (see #2257)
1045   exit(99);
1046 }
1047
1048 int main(int argc, char *argv[])
1049 {
1050
1051     struct sigevent ev;
1052     timer_t timer;
1053     struct itimerspec it;
1054     struct sigaction action;
1055     int m,n,count = 0;
1056
1057     ev.sigev_notify = SIGEV_SIGNAL;
1058     ev.sigev_signo  = SIGVTALRM;
1059
1060     action.sa_handler = handler;
1061     action.sa_flags = 0;
1062     sigemptyset(&action.sa_mask);
1063     if (sigaction(SIGVTALRM, &action, NULL) == -1) {
1064         fprintf(stderr,"SIGVTALRM problem\n");
1065         exit(3);
1066     }
1067
1068     action.sa_handler = timeout;
1069     action.sa_flags = 0;
1070     sigemptyset(&action.sa_mask);
1071     if (sigaction(SIGALRM, &action, NULL) == -1) {
1072       fprintf(stderr,"SIGALRM problem\n");
1073       exit(3);
1074     }
1075     alarm(1);
1076
1077     if (timer_create(CLOCK_PROCESS_CPUTIME_ID, &ev, &timer) != 0) {
1078         fprintf(stderr,"No CLOCK_PROCESS_CPUTIME_ID timer\n");
1079        exit(1);
1080     }
1081
1082     it.it_value.tv_sec = 0;
1083     it.it_value.tv_nsec = 1;
1084     it.it_interval = it.it_value;
1085     if (timer_settime(timer, 0, &it, NULL) != 0) {
1086         fprintf(stderr,"settime problem\n");
1087         exit(4);
1088     }
1089
1090     tock = 0;
1091
1092     for(n = 3; n < 20000; n++){
1093         for(m = 2; m <= n/2; m++){
1094             if (!(n%m)) count++;
1095             if (tock) goto out;
1096         }
1097     }
1098 out:
1099
1100     if (!tock) {
1101         fprintf(stderr,"no CLOCK_PROCESS_CPUTIME_ID signal\n");
1102         exit(5);
1103     }
1104
1105     timer_delete(timer);
1106
1107     if (timer_create(CLOCK_REALTIME, &ev, &timer) != 0) {
1108         fprintf(stderr,"No CLOCK_REALTIME timer\n");
1109         exit(2);
1110     }
1111
1112     it.it_value.tv_sec = 0;
1113     it.it_value.tv_nsec = 1000000;
1114     it.it_interval = it.it_value;
1115     if (timer_settime(timer, 0, &it, NULL) != 0) {
1116         fprintf(stderr,"settime problem\n");
1117         exit(4);
1118     }
1119
1120     tock = 0;
1121
1122     usleep(3000);
1123
1124     if (!tock) {
1125         fprintf(stderr,"no CLOCK_REALTIME signal\n");
1126         exit(5);
1127     }
1128
1129     timer_delete(timer);
1130
1131     exit(0);
1132 }
1133      ],
1134      [fptools_cv_timer_create_works=yes],
1135      [fptools_cv_timer_create_works=no])
1136   ])
1137 case $fptools_cv_timer_create_works in
1138     yes) AC_DEFINE([USE_TIMER_CREATE], 1,
1139                    [Define to 1 if we can use timer_create(CLOCK_PROCESS_CPUTIME_ID,...)]);;
1140 esac
1141 ])
1142
1143 # FP_ARG_GMP
1144 # -------------
1145 AC_DEFUN([FP_ARG_GMP],
1146 [
1147 AC_ARG_WITH([gmp-includes],
1148   [AC_HELP_STRING([--with-gmp-includes],
1149     [directory containing gmp.h])],
1150     [gmp_includes=$withval],
1151     [gmp_includes=NONE])
1152
1153 AC_ARG_WITH([gmp-libraries],
1154   [AC_HELP_STRING([--with-gmp-libraries],
1155     [directory containing gmp library])],
1156     [gmp_libraries=$withval],
1157     [gmp_libraries=NONE])
1158 ])# FP_ARG_GMP
1159
1160 AC_DEFUN([CHECK_GMP],
1161 [AC_REQUIRE([AC_PROG_CPP])
1162 AC_REQUIRE([AC_PROG_CC])
1163 ])
1164
1165 # FP_CHECK_MACOSX_DEPLOYMENT_TARGET
1166 # ---------------------------------
1167 AC_DEFUN([FP_CHECK_MACOSX_DEPLOYMENT_TARGET],
1168 [
1169 if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple"; then
1170   AC_MSG_CHECKING([Mac OS X deployment target])
1171   case $FP_MACOSX_DEPLOYMENT_TARGET in
1172     none)  ;;
1173     10.4)  MACOSX_DEPLOYMENT_VERSION=10.4
1174            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1175            ;;
1176     10.4u) MACOSX_DEPLOYMENT_VERSION=10.4
1177            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1178            ;;
1179     *)     MACOSX_DEPLOYMENT_VERSION=$FP_MACOSX_DEPLOYMENT_TARGET
1180            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX${FP_MACOSX_DEPLOYMENT_TARGET}.sdk
1181            ;;
1182   esac
1183   if test "x$FP_MACOSX_DEPLOYMENT_TARGET" = "xnone"; then
1184     AC_MSG_RESULT(none)
1185   else
1186     if test ! -d $MACOSX_DEPLOYMENT_SDK; then
1187       AC_MSG_ERROR([Unknown deployment target $FP_MACOSX_DEPLOYMENT_TARGET])
1188     fi
1189     AC_MSG_RESULT([${MACOSX_DEPLOYMENT_VERSION} (${MACOSX_DEPLOYMENT_SDK})])
1190   fi
1191 fi
1192 ])
1193
1194 # --------------------------------------------------------------
1195 # Calculate absolute path to build tree
1196 # --------------------------------------------------------------
1197
1198 AC_DEFUN([FP_FIND_ROOT],[
1199 AC_MSG_CHECKING(for path to top of build tree)
1200
1201 dnl This would be
1202 dnl     make -C utils/ghc-pwd clean && make -C utils/ghc-pwd
1203 dnl except we don't want to have to know what make is called. Sigh.
1204 if test ! -f utils/ghc-pwd/ghc-pwd && test ! -f utils/ghc-pwd/ghc-pwd.exe; then
1205   cd utils/ghc-pwd
1206   rm -f *.o
1207   rm -f *.hi
1208   rm -f ghc-pwd
1209   rm -f ghc-pwd.exe
1210   $WithGhc -v0 --make ghc-pwd -o ghc-pwd
1211   cd ../..
1212 fi
1213
1214 hardtop=`utils/ghc-pwd/ghc-pwd`
1215
1216 if ! test -d "$hardtop"; then
1217   AC_MSG_ERROR([cannot determine current directory])
1218 fi
1219
1220 dnl Remove common automounter nonsense
1221 dnl
1222 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|'`
1223
1224 AC_SUBST(hardtop)
1225
1226 AC_MSG_RESULT(${hardtop})
1227
1228 # We don't support building in directories with spaces.
1229 case "$hardtop" in
1230   *' '*) AC_MSG_ERROR([
1231    The build system does not support building in a directory containing
1232    space characters.  Suggestion: move the build tree somewhere else.])
1233  ;;
1234 esac
1235 ])
1236
1237 # LocalWords:  fi