aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FP_EVAL_STDERR(COMMAND)
   8 # -----------------------
   9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  10 # into the file conftest.err and the exit status in the variable fp_status.
  11 AC_DEFUN([FP_EVAL_STDERR],
  12 [{ (eval $1) 2>conftest.er1
  13   fp_status=$?
  14   grep -v '^ *+' conftest.er1 >conftest.err
  15   rm -f conftest.er1
  16   (exit $fp_status); }[]dnl
  17 ])# FP_EVAL_STDERR
  18
  19
  20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
  21 # ---------------------------------------------------------------------
  22 # Check to see whether the compiler for the current language supports a
  23 # particular option.
  24 #
  25 # Implementation note: When given an unkown option, GCC issues an warning on
  26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
  27 # to check stderr *and* the exit value.
  28 #
  29 # Used by ghc.
  30 AC_DEFUN([FP_CHECK_FLAG],
  31 [AC_LANG_COMPILER_REQUIRE()dnl
  32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
  33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
  34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
  35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
  36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
  37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
  38 fp_save_flags="$fp_Flags"
  39 fp_Flags="$fp_Flags $1"
  40 fp_Cache=no
  41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  42   test -s conftest.err || fp_Cache=yes
  43 fi
  44 fp_Flags="$fp_save_flags"
  45 rm -f conftest.err conftest.$ac_ext])
  46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
  47 m4_popdef([fp_Cache])[]dnl
  48 m4_popdef([fp_Flags])[]dnl
  49 ])# FP_CHECK_FLAG
  50
  51
  52 # FP_PROG_CONTEXT_DIFF
  53 # --------------------
  54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  55 #
  56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  57 #
  58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  61 [echo foo > conftest1
  62 echo foo > conftest2
  63 fp_cv_context_diff=no
  64 for fp_var in '-C 1' '-c1'
  65 do
  66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  67     fp_cv_context_diff="diff $fp_var"
  68     break
  69   fi
  70 done])
  71 if test x"$fp_cv_context_diff" = xno; then
  72    AC_MSG_ERROR([cannot figure out how to do context diffs])
  73 fi
  74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  75 ])# FP_PROG_CONTEXT_DIFF
  76
  77
  78 # FP_DECL_ALTZONE
  79 # ---------------
  80 # Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
  81 #
  82 # Used by base package.
  83 AC_DEFUN([FP_DECL_ALTZONE],
  84 [AC_REQUIRE([AC_HEADER_TIME])dnl
  85 AC_CHECK_HEADERS([sys/time.h])
  86 AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
  87 # include <sys/time.h>
  88 # include <time.h>
  89 #else
  90 # if HAVE_SYS_TIME_H
  91 #  include <sys/time.h>
  92 # else
  93 #  include <time.h>
  94 # endif
  95 #endif])
  96 ])# FP_DECL_ALTZONE
  97
  98
  99 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
 100 # --------------------------------------------------------
 101 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
 102 # compilation. Execute IF-FAILS when unable to determine the value. Works for
 103 # cross-compilation, too.
 104 #
 105 # Implementation note: We are lazy and use an internal autoconf macro, but it
 106 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
 107 # little risk.
 108 AC_DEFUN([FP_COMPUTE_INT],
 109 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
 110 ])# FP_COMPUTE_INT
 111
 112
 113 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
 114 # ------------------------------------------------------------------
 115 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
 116 # given type. Defines ALIGNMENT_TYPE.
 117 AC_DEFUN([FP_CHECK_ALIGNMENT],
 118 [AS_LITERAL_IF([$1], [],
 119                [AC_FATAL([$0: requires literal arguments])])[]dnl
 120 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 121 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 122 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 123 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 124   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 125                  [fp_Cache],
 126                  [AC_INCLUDES_DEFAULT([$3])],
 127                  [AC_MSG_ERROR([cannot compute alignment ($1)
 128 See `config.log' for more details.], [77])])
 129 else
 130   fp_Cache=0
 131 fi])[]dnl
 132 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 133 m4_popdef([fp_Cache])[]dnl
 134 ])# FP_CHECK_ALIGNMENT
 135
 136
 137 # FP_LEADING_UNDERSCORE
 138 # ---------------------
 139 # Test for determining whether symbol names have a leading underscore. We assume
 140 # that they _haven't_ if anything goes wrong. Sets the output variable
 141 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 142 #
 143 # Some nlist implementations seem to try to be compatible by ignoring a leading
 144 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 145 # checking for *no* leading underscore first. Sigh.  --SDM
 146 #
 147 # Similarly on OpenBSD, but this test doesn't help. -- dons
 148 AC_DEFUN([FP_LEADING_UNDERSCORE],
 149 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 150 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 151 # Hack!: nlist() under Digital UNIX insist on there being an _,
 152 # but symbol table listings shows none. What is going on here?!?
 153 #
 154 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 155 # the underscoredness of that "platform"
 156 case $HostPlatform in
 157 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 158   case $build in
 159     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 160     *) fptools_cv_leading_underscore=no ;;
 161   esac ;;
 162 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 163 *cygwin32) fptools_cv_leading_underscore=yes;;
 164 *mingw32) fptools_cv_leading_underscore=yes;;
 165 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 166 #include <nlist.h>
 167 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 168 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 169 #endif
 170
 171 int main(argc, argv)
 172 int argc;
 173 char **argv;
 174 {
 175 #ifdef HAVE_NLIST_H
 176     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 177         exit(1);
 178     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 179         exit(0);
 180 #endif
 181     exit(1);
 182 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 183 ;;
 184 esac]);
 185 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 186 if test x"$fptools_cv_leading_underscore" = xyes; then
 187    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 188 fi])# FP_LEADING_UNDERSCORE
 189
 190
 191 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 192 # ----------------------------------------------------------------------------------
 193 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 194 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 195 AC_DEFUN([FP_COMPARE_VERSIONS],
 196 [fp_version1=$1; fp_version2=$3
 197 fp_save_IFS=$IFS; IFS='.'
 198 while test x"$fp_version1" != x || test x"$fp_version2" != x
 199 do
 200
 201   set dummy $fp_version1; shift
 202   fp_num1=""
 203   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 204   test x"$fp_num1" = x && fp_num1="0"
 205   fp_version1="[$]*"
 206
 207   set dummy $fp_version2; shift
 208   fp_num2=""
 209   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 210   test x"$fp_num2" = x && fp_num2="0"
 211   fp_version2="[$]*"
 212
 213   test "$fp_num1" = "$fp_num2" || break;
 214 done
 215 IFS=$fp_save_IFS
 216 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 217 ])# FP_COMPARE_VERSIONS
 218
 219
 220 dnl
 221 dnl Check for GreenCard and version.
 222 dnl
 223 AC_DEFUN([FPTOOLS_GREENCARD],
 224 [
 225 AC_PATH_PROG(GreenCardCmd,greencard)
 226 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 227 changequote(, )dnl
 228 [if test x"$GreenCardCmd" != x; then
 229    fptools_cv_greencard_version="`$GreenCardCmd --version |
 230                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 231 else
 232    fptools_cv_greencard_version=""
 233 fi
 234 changequote([, ])dnl
 235 ])
 236 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 237   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 238 GreenCardVersion=$fptools_cv_greencard_version
 239 AC_SUBST(GreenCardVersion)
 240 ])
 241
 242 dnl
 243 dnl Check for Happy and version.  If we're building GHC, then we need
 244 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 245 dnl for a happy source tree and point the build system at that instead.
 246 dnl
 247 AC_DEFUN([FPTOOLS_HAPPY],
 248 [AC_PATH_PROG(HappyCmd,happy,)
 249 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 250 changequote(, )dnl
 251 [if test x"$HappyCmd" != x; then
 252    fptools_cv_happy_version="`$HappyCmd -v |
 253                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 254 else
 255    fptools_cv_happy_version="";
 256 fi;
 257 changequote([, ])dnl
 258 ])
 259 FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
 260   [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
 261 HappyVersion=$fptools_cv_happy_version;
 262 AC_SUBST(HappyVersion)
 263 ])
 264
 265 dnl
 266 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 267 dnl for a haddock source tree and point the build system at that instead.
 268 dnl
 269 AC_DEFUN([FPTOOLS_HADDOCK],
 270 [AC_PATH_PROG(HaddockCmd,haddock,)
 271 dnl Darn, I forgot to make Haddock print out its version number when
 272 dnl invoked with -v.  We could try generating some HTML and grepping
 273 dnl through that to find the version number, but I think we'll make
 274 dnl do without it for now.
 275 ])
 276
 277 dnl
 278 dnl Check for Alex and version.  If we're building GHC, then we need
 279 dnl at least Alex version 2.0.  If there's no installed Alex, we look
 280 dnl for a alex source tree and point the build system at that instead.
 281 dnl
 282 AC_DEFUN([FPTOOLS_ALEX],
 283 [
 284 AC_PATH_PROG(AlexCmd,alex,)
 285 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 286 changequote(, )dnl
 287 [if test x"$AlexCmd" != x; then
 288    fptools_cv_alex_version="`$AlexCmd -v |
 289                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 290 else
 291    fptools_cv_alex_version="";
 292 fi;
 293 changequote([, ])dnl
 294 ])
 295 FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
 296   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
 297 AlexVersion=$fptools_cv_alex_version;
 298 AC_SUBST(AlexVersion)
 299 ])
 300
 301
 302 # FP_PROG_LD
 303 # ----------
 304 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 305 # of ld. Exits if no ld can be found
 306 AC_DEFUN([FP_PROG_LD],
 307 [AC_PATH_PROG([fp_prog_ld_raw], [ld])
 308 if test -z "$fp_prog_ld_raw"; then
 309   AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 310 fi
 311 LdCmd=$fp_prog_ld_raw
 312 case $HostPlatform in
 313   *mingw32) if test x${OSTYPE} != xmsys; then
 314               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 315               AC_MSG_NOTICE([normalized ld command to $LdCmd])
 316             fi
 317             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
 318             # the generation of relocatable object files with large amounts
 319             # of relocations correctly. (cf. HSbase.o splittage-hack)
 320             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
 321             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
 322                                 [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
 323             ;;
 324 esac
 325 AC_SUBST([LdCmd])
 326 ])# FP_PROG_LD
 327
 328
 329 # FP_PROG_LD_X
 330 # ------------
 331 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 332 # variable's value is empty.
 333 AC_DEFUN([FP_PROG_LD_X],
 334 [AC_REQUIRE([FP_PROG_LD])
 335 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 336 [echo 'foo() {}' > conftest.c
 337 ${CC-cc} -c conftest.c
 338 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
 339    fp_cv_ld_x=yes
 340 else
 341    fp_cv_ld_x=no
 342 fi
 343 rm -rf conftest*])
 344 if test "$fp_cv_ld_x" = yes; then
 345   LdXFlag=-x
 346 else
 347   LdXFlag=
 348 fi
 349 AC_SUBST([LdXFlag])
 350 ])# FP_PROG_LD_X
 351
 352
 353 # FP_PROG_LD_IS_GNU
 354 # -----------------
 355 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 356 # GNU ld or not.
 357 AC_DEFUN([FP_PROG_LD_IS_GNU],
 358 [AC_REQUIRE([FP_PROG_LD])
 359 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 360 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 361   fp_cv_gnu_ld=yes
 362 else
 363   fp_cv_gnu_ld=no
 364 fi])
 365 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 366 ])# FP_PROG_LD_IS_GNU
 367
 368
 369 # FP_PROG_AR
 370 # ----------
 371 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 372 # version of it. Exits if no ar can be found
 373 AC_DEFUN([FP_PROG_AR],
 374 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 375 if test -z "$fp_prog_ar_raw"; then
 376   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 377 fi
 378 fp_prog_ar=$fp_prog_ar_raw
 379 case $HostPlatform in
 380   *mingw32) if test x${OSTYPE} != xmsys; then
 381               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 382               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 383             fi
 384             ;;
 385 esac
 386 ])# FP_PROG_AR
 387
 388
 389 # FP_PROG_AR_IS_GNU
 390 # -----------------
 391 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 392 AC_DEFUN([FP_PROG_AR_IS_GNU],
 393 [AC_REQUIRE([FP_PROG_AR])
 394 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 395 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 396   fp_cv_prog_ar_is_gnu=yes
 397 else
 398   fp_cv_prog_ar_is_gnu=no
 399 fi])
 400 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 401 ])# FP_PROG_AR_IS_GNU
 402
 403
 404 # FP_PROG_AR_ARGS
 405 # ---------------
 406 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 407 # to a non-Cygwin invocation of ar including these arguments.
 408 AC_DEFUN([FP_PROG_AR_ARGS],
 409 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 410 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 411 [
 412 # GNU ar needs special treatment: it appears to have problems with
 413 # object files with the same name if you use the 's' modifier, but
 414 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 415 if test $fp_prog_ar_is_gnu = yes; then
 416   fp_cv_prog_ar_args="q"
 417 else
 418   touch conftest.dummy
 419   for fp_var in clqsZ clqs cqs clq cq ; do
 420      rm -f conftest.a
 421      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 422         fp_cv_prog_ar_args=$fp_var
 423         break
 424      fi
 425   done
 426   rm -f conftest*
 427   if test -z "$fp_cv_prog_ar_args"; then
 428     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 429   fi
 430 fi])
 431 fp_prog_ar_args=$fp_cv_prog_ar_args
 432 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 433
 434 ])# FP_PROG_AR_ARGS
 435
 436
 437 # FP_PROG_AR_NEEDS_RANLIB
 438 # -----------------------
 439 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 440 # to ":" otherwise.
 441 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 442 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 443 AC_REQUIRE([FP_PROG_AR_ARGS])
 444 AC_REQUIRE([AC_PROG_CC])
 445 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 446 [if test $fp_prog_ar_is_gnu = yes; then
 447   fp_cv_prog_ar_needs_ranlib=no
 448 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
 449   # It's quite tedious to check for Apple's crazy timestamps in .a files,
 450   # so we hardcode it.
 451   fp_cv_prog_ar_needs_ranlib=yes
 452 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 453   fp_cv_prog_ar_needs_ranlib=no
 454 else
 455   fp_cv_prog_ar_needs_ranlib=yes
 456 fi])
 457 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 458    AC_PROG_RANLIB
 459 else
 460   RANLIB=":"
 461   AC_SUBST([RANLIB])
 462 fi
 463 ])# FP_PROG_AR_NEEDS_RANLIB
 464
 465
 466 # FP_PROG_AR_SUPPORTS_INPUT
 467 # -------------------------
 468 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 469 # whether ar supports -input flag is supported or not.
 470 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 471 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 472 AC_REQUIRE([FP_PROG_AR_ARGS])
 473 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 474 [fp_cv_prog_ar_supports_input=no
 475 if test $fp_prog_ar_is_gnu = no; then
 476   rm -f conftest*
 477   touch conftest.lst
 478   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 479     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 480   fi
 481   rm -f conftest*
 482 fi])
 483 if test $fp_cv_prog_ar_supports_input = yes; then
 484     ArSupportsInput="-input"
 485 else
 486     ArSupportsInput=""
 487 fi
 488 AC_SUBST([ArSupportsInput])
 489 ])# FP_PROG_AR_SUPPORTS_INPUT
 490
 491
 492 dnl
 493 dnl AC_SHEBANG_PERL - can we she-bang perl?
 494 dnl
 495 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
 496 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 497 [echo "#!$PerlCmd"'
 498 exit $1;
 499 ' > conftest
 500 chmod u+x conftest
 501 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 502 if test $? -ne 69; then
 503    fptools_cv_shebang_perl=yes
 504 else
 505    fptools_cv_shebang_perl=no
 506 fi
 507 rm -f conftest
 508 ])])
 509
 510
 511 # FP_HAVE_GCC
 512 # -----------
 513 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 514 # output variables HaveGcc and GccVersion.
 515 AC_DEFUN([FP_HAVE_GCC],
 516 [AC_REQUIRE([AC_PROG_CC])
 517 if test -z "$GCC"; then
 518    fp_have_gcc=NO
 519 else
 520    fp_have_gcc=YES
 521 fi
 522 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
 523   AC_MSG_ERROR([gcc is required])
 524 fi
 525 AC_CACHE_CHECK([version of gcc], [fp_gcc_version],
 526 [if test "$fp_have_gcc" = "YES"; then
 527    fp_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
 528    FP_COMPARE_VERSIONS([$fp_gcc_version], [-lt], [2.0],
 529      [AC_MSG_ERROR([Need at least gcc version 2.0 (3.4+ recommended)])])
 530  else
 531    fp_gcc_version="not-installed"
 532  fi
 533 ])
 534 AC_SUBST([HaveGcc], [$fp_have_gcc])
 535 AC_SUBST([GccVersion], [$fp_gcc_version])
 536 ])# FP_HAVE_GCC
 537
 538 AC_DEFUN([FP_MINGW_GCC],
 539 [
 540   case $HostOS_CPP in
 541     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
 542              if $CC -v 2>&1 | grep mingw >/dev/null; then
 543                 AC_MSG_RESULT([yes])
 544              else
 545                 AC_MSG_RESULT([no])
 546                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
 547              fi;;
 548     *) ;;
 549   esac
 550 ])
 551
 552 dnl Small feature test for perl version. Assumes PerlCmd
 553 dnl contains path to perl binary
 554 dnl
 555 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
 556 [$PerlCmd -v >conftest.out 2>&1
 557    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 558       :
 559    else
 560       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 561          :
 562       else
 563          if grep "version 6" conftest.out >/dev/null 2>&1; then
 564             :
 565          else
 566             AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
 567          fi
 568       fi
 569    fi
 570 rm -fr conftest*
 571 ])
 572
 573
 574 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 575 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 576 # -----------------------------------------------------
 577 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 578 # of PROG-TO-CHECK-FOR when found.
 579 AC_DEFUN([FP_CHECK_PROG],
 580 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 581 )# FP_CHECK_PROC
 582
 583
 584 # FP_PROG_FIND
 585 # ------------
 586 # Find a non-WinDoze version of the "find" utility.
 587 AC_DEFUN([FP_PROG_FIND],
 588 [AC_PATH_PROG([fp_prog_find], [find])
 589 echo foo > conftest.txt
 590 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 591 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 592   # OK, looks like a real "find".
 593   FindCmd="$fp_prog_find"
 594 else
 595   # Found a poor WinDoze version of "find", ignore it.
 596   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 597   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 598 fi
 599 rm -f conftest.txt conftest.out
 600 AC_SUBST([FindCmd])[]dnl
 601 ])# FP_PROG_FIND
 602
 603
 604 # FP_PROG_SORT
 605 # ------------
 606 # Find a Unix-like sort
 607 AC_DEFUN([FP_PROG_SORT],
 608 [AC_PATH_PROG([fp_prog_sort], [sort])
 609 echo conwip > conftest.txt
 610 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
 611 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
 612   # The goods
 613   SortCmd="$fp_prog_sort"
 614 else
 615   # Summink else..pick next one.
 616   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
 617   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
 618 fi
 619 rm -f conftest.txt conftest.out
 620 AC_SUBST([SortCmd])[]dnl
 621 ])# FP_PROG_SORT
 622
 623 dnl
 624 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 625 dnl values of the second argument to the result of running
 626 dnl the commands given by the third. It does not cache its
 627 dnl result, so it is suitable for checks which should be
 628 dnl run every time.
 629 dnl
 630 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
 631 [AC_MSG_CHECKING([$1])
 632  $3
 633  AC_MSG_RESULT([$][$2])
 634 ])
 635
 636 dnl
 637 dnl FPTOOLS_GHC_VERSION(version)
 638 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 639 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 640 dnl
 641 dnl Test for version of installed ghc.  Uses $GHC.
 642 dnl [original version pinched from c2hs]
 643 dnl
 644 AC_DEFUN([FPTOOLS_GHC_VERSION],
 645 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 646 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 647   cat conftestghc >&AS_MESSAGE_LOG_FD
 648 #Useless Use Of cat award...
 649   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 650   rm -fr conftest*
 651   if test "[$]fptools_version_of_ghc" = ""
 652   then
 653     fptools_version_of_ghc='unknown'
 654   fi
 655 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 656 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 657 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 658 #
 659 if test "[$]fptools_version_of_ghc[_pl]" = ""
 660 then
 661   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 662   fptools_version_of_ghc[_pl]="0"
 663 else
 664   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 665 fi
 666 #
 667 ifelse($#, [1], [dnl
 668 [$1]="[$]fptools_version_of_ghc[_all]"
 669 ], $#, [2], [dnl
 670 [$1]="[$]fptools_version_of_ghc[_major]"
 671 [$2]="[$]fptools_version_of_ghc[_minor]"
 672 ], $#, [3], [dnl
 673 [$1]="[$]fptools_version_of_ghc[_major]"
 674 [$2]="[$]fptools_version_of_ghc[_minor]"
 675 [$3]="[$]fptools_version_of_ghc[_pl]"
 676 ], $#, [4], [dnl
 677 [$1]="[$]fptools_version_of_ghc[_all]"
 678 [$2]="[$]fptools_version_of_ghc[_major]"
 679 [$3]="[$]fptools_version_of_ghc[_minor]"
 680 [$4]="[$]fptools_version_of_ghc[_pl]"
 681 ])
 682 ])
 683 ])dnl
 684
 685
 686 dnl ** Map an arithmetic C type to a Haskell type.
 687 dnl    Based on autconf's AC_CHECK_SIZEOF.
 688
 689 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
 690 AC_DEFUN([FPTOOLS_CHECK_HTYPE],
 691 [changequote(<<, >>)dnl
 692 dnl The name to #define.
 693 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
 694 dnl The cache variable name.
 695 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
 696 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
 697 changequote([, ])dnl
 698 AC_MSG_CHECKING(Haskell type for $1)
 699 AC_CACHE_VAL(AC_CV_NAME,
 700 [AC_CV_NAME_supported=yes
 701 fp_check_htype_save_cppflags="$CPPFLAGS"
 702 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 703 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdio.h>
 704 #include <stddef.h>
 705
 706 #if HAVE_SYS_TYPES_H
 707 # include <sys/types.h>
 708 #endif
 709
 710 #if HAVE_UNISTD_H
 711 # include <unistd.h>
 712 #endif
 713
 714 #if HAVE_SYS_STAT_H
 715 # include <sys/stat.h>
 716 #endif
 717
 718 #if HAVE_FCNTL_H
 719 # include <fcntl.h>
 720 #endif
 721
 722 #if HAVE_SIGNAL_H
 723 # include <signal.h>
 724 #endif
 725
 726 #if HAVE_TIME_H
 727 # include <time.h>
 728 #endif
 729
 730 #if HAVE_TERMIOS_H
 731 # include <termios.h>
 732 #endif
 733
 734 #if HAVE_STRING_H
 735 # include <string.h>
 736 #endif
 737
 738 #if HAVE_CTYPE_H
 739 # include <ctype.h>
 740 #endif
 741
 742 #if defined(HAVE_GL_GL_H)
 743 # include <GL/gl.h>
 744 #elif defined(HAVE_OPENGL_GL_H)
 745 # include <OpenGL/gl.h>
 746 #endif
 747
 748 #if defined(HAVE_AL_AL_H)
 749 # include <AL/al.h>
 750 #elif defined(HAVE_OPENAL_AL_H)
 751 # include <OpenAL/al.h>
 752 #endif
 753
 754 #if defined(HAVE_AL_ALC_H)
 755 # include <AL/alc.h>
 756 #elif defined(HAVE_OPENAL_ALC_H)
 757 # include <OpenAL/alc.h>
 758 #endif
 759
 760 #if HAVE_SYS_RESOURCE_H
 761 # include <sys/resource.h>
 762 #endif
 763
 764 typedef $1 testing;
 765
 766 main() {
 767   FILE *f=fopen("conftestval", "w");
 768   if (!f) exit(1);
 769   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
 770     fprintf(f, "%s%d\n",
 771            ((testing)(-1) < (testing)0) ? "Int" : "Word",
 772            sizeof(testing)*8);
 773   } else {
 774     fprintf(f,"%s\n",
 775            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
 776            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
 777   }
 778   fclose(f);
 779   exit(0);
 780 }]])],[AC_CV_NAME=`cat conftestval`],
 781 [ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], [AC_CV_NAME=$2])],
 782 [ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], [AC_CV_NAME=$3])])
 783 CPPFLAGS="$fp_check_htype_save_cppflags"]) dnl
 784 if test "$AC_CV_NAME_supported" = yes; then
 785   AC_MSG_RESULT($AC_CV_NAME)
 786   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
 787 else
 788   AC_MSG_RESULT([not supported])
 789 fi
 790 undefine([AC_TYPE_NAME])dnl
 791 undefine([AC_CV_NAME])dnl
 792 undefine([AC_CV_NAME_supported])dnl
 793 ])
 794
 795
 796 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 797 # ---------------------------------------------------------------------------------
 798 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 799 # additional flexibility of specifying the PROLOGUE and BODY.
 800 AC_DEFUN([FP_CHECK_FUNC],
 801 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 802 AC_CACHE_CHECK([for $1], fp_func,
 803 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 804                 [AS_VAR_SET(fp_func, yes)],
 805                 [AS_VAR_SET(fp_func, no)])])
 806 AS_IF([test AS_VAR_GET(fp_func) = yes],
 807       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 808                 [Define to 1 if you have the `]$1[' function.]) $4],
 809       [$5])dnl
 810 AS_VAR_POPDEF([fp_func])dnl
 811 ])# FP_CHECK_FUNC
 812
 813
 814 # FP_GEN_DOCBOOK_XML
 815 # ------------------
 816 # Generates a DocBook XML V4.2 document in conftest.xml.
 817 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 818 [rm -f conftest.xml
 819 cat > conftest.xml << EOF
 820 <?xml version="1.0" encoding="iso-8859-1"?>
 821 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 822    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 823 <book id="test">
 824   <title>A DocBook Test Document</title>
 825   <chapter id="id-one">
 826     <title>A Chapter Title</title>
 827     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 828   </chapter>
 829   <chapter id="id-two">
 830     <title>Another Chapter Title</title>
 831     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 832   </chapter>
 833 </book>
 834 EOF
 835 ]) # FP_GEN_DOCBOOK_XML
 836
 837
 838 # FP_PROG_XSLTPROC
 839 # ----------------
 840 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 841 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 842 AC_DEFUN([FP_PROG_XSLTPROC],
 843 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 844 if test -z "$XsltprocCmd"; then
 845   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 846 fi
 847 ])# FP_PROG_XSLTPROC
 848
 849
 850 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 851 # ----------------------------
 852 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 853 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 854 # will be empty if none could be found.
 855 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 856 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 857 if test -n "$XsltprocCmd"; then
 858   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 859   [FP_GEN_DOCBOOK_XML
 860   fp_cv_dir_docbook_xsl=no
 861   for fp_var in $1; do
 862      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 863         fp_cv_dir_docbook_xsl=$fp_var
 864         break
 865      fi
 866   done
 867   rm -rf conftest*])
 868 fi
 869 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 870   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 871   DIR_DOCBOOK_XSL=
 872 else
 873   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 874 fi
 875 AC_SUBST([DIR_DOCBOOK_XSL])
 876 ])# FP_DIR_DOCBOOK_XSL
 877
 878
 879 # FP_PROG_XMLLINT
 880 # ----------------
 881 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 882 # xmllint. XmllintCmd is empty if xmllint could not be found.
 883 AC_DEFUN([FP_PROG_XMLLINT],
 884 [AC_PATH_PROG([XmllintCmd], [xmllint])
 885 if test -z "$XmllintCmd"; then
 886   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 887 fi
 888 ])# FP_PROG_XMLLINT
 889
 890
 891 # FP_CHECK_DOCBOOK_DTD
 892 # --------------------
 893 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 894 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 895 if test -n "$XmllintCmd"; then
 896   AC_MSG_CHECKING([for DocBook DTD])
 897   FP_GEN_DOCBOOK_XML
 898   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 899     AC_MSG_RESULT([ok])
 900   else
 901     AC_MSG_RESULT([failed])
 902     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 903     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 904   fi
 905   rm -rf conftest*
 906 fi
 907 ])# FP_CHECK_DOCBOOK_DTD
 908
 909
 910 # FP_GEN_FO
 911 # ------------------
 912 # Generates a formatting objects document in conftest.fo.
 913 AC_DEFUN([FP_GEN_FO],
 914 [rm -f conftest.fo
 915 cat > conftest.fo << EOF
 916 <?xml version="1.0"?>
 917 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 918   <fo:layout-master-set>
 919     <fo:simple-page-master master-name="blank">
 920       <fo:region-body/>
 921     </fo:simple-page-master>
 922   </fo:layout-master-set>
 923   <fo:page-sequence master-reference="blank">
 924     <fo:flow flow-name="xsl-region-body">
 925       <fo:block>
 926         Test!
 927       </fo:block>
 928     </fo:flow>
 929   </fo:page-sequence>
 930 </fo:root>
 931 EOF
 932 ]) # FP_GEN_FO
 933
 934
 935 # FP_PROG_FOP
 936 # -----------
 937 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 938 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 939 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 940 AC_DEFUN([FP_PROG_FOP],
 941 [AC_PATH_PROGS([FopCmd1], [fop])
 942 if test -n "$FopCmd1"; then
 943   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 944     [FP_GEN_FO
 945     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 946       fp_cv_fop_usability=yes
 947     else
 948       fp_cv_fop_usability=no
 949     fi
 950     rm -rf conftest*])
 951   if test x"$fp_cv_fop_usability" = xyes; then
 952      FopCmd=$FopCmd1
 953   fi
 954 fi
 955 if test -z "$FopCmd"; then
 956   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 957   FopCmd=$FopCmd2
 958 fi
 959 AC_SUBST([FopCmd])
 960 ])# FP_PROG_FOP
 961
 962
 963 # FP_PROG_FO_PROCESSOR
 964 # --------------------
 965 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
 966 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
 967 # PdfxmltexCmd.
 968 AC_DEFUN([FP_PROG_FO_PROCESSOR],
 969 [AC_REQUIRE([FP_PROG_FOP])
 970 AC_PATH_PROG([XmltexCmd], [xmltex])
 971 AC_PATH_PROG([DvipsCmd], [dvips])
 972 if test -z "$FopCmd"; then
 973   if test -z "$XmltexCmd"; then
 974     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
 975   else
 976     if test -z "$DvipsCmd"; then
 977       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
 978     fi
 979   fi
 980   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
 981   if test -z "$PdfxmltexCmd"; then
 982     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
 983   fi
 984 elif test -z "$XmltexCmd"; then
 985   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
 986 fi
 987 ])# FP_PROG_FO_PROCESSOR
 988
 989
 990 # FP_PROG_GHC_PKG
 991 # ----------------
 992 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
 993 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
 994 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
 995 AC_DEFUN([FP_PROG_GHC_PKG],
 996 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
 997 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
 998 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
 999   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
1000 else
1001   fp_cv_matching_ghc_pkg=no
1002 fi])
1003 if test x"$fp_cv_matching_ghc_pkg" = xno; then
1004   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
1005 else
1006   GhcPkgCmd=$fp_cv_matching_ghc_pkg
1007 fi])# FP_PROG_GHC_PKG
1008
1009
1010 # FP_GHC_HAS_READLINE
1011 # -------------------
1012 AC_DEFUN([FP_GHC_HAS_READLINE],
1013 [AC_REQUIRE([FP_PROG_GHC_PKG])
1014 AC_CACHE_CHECK([whether ghc has readline package], [fp_cv_ghc_has_readline],
1015 [if "${GhcPkgCmd-ghc-pkg}" --show-package readline >/dev/null 2>&1; then
1016   fp_cv_ghc_has_readline=yes
1017 else
1018   fp_cv_ghc_has_readline=no
1019  fi])
1020 AC_SUBST([GhcHasReadline], [`echo $fp_cv_ghc_has_readline | sed 'y/yesno/YESNO/'`])
1021 ])# FP_GHC_HAS_READLINE
1022
1023
1024 # FP_GCC_NEEDS_NO_OMIT_LFPTR
1025 # --------------------------
1026 # Some OSs (Mandrake Linux, in particular) configure GCC with
1027 # -momit-leaf-frame-pointer on by default. If this is the case, we need to turn
1028 # it off for mangling to work. The test is currently a bit crude, using only the
1029 # version number of gcc. Defines HAVE_GCC_MNO_OMIT_LFPTR.
1030 AC_DEFUN([FP_GCC_NEEDS_NO_OMIT_LFPTR],
1031 [AC_REQUIRE([FP_HAVE_GCC])
1032 AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fp_cv_gcc_needs_no_omit_lfptr],
1033 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.2],
1034   [fp_cv_gcc_needs_no_omit_lfptr=yes],
1035   [fp_cv_gcc_needs_no_omit_lfptr=no])])
1036 if test "$fp_cv_gcc_needs_no_omit_lfptr" = "yes"; then
1037    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
1038 fi])# FP_GCC_NEEDS_NO_OMIT_LFPTR
1039
1040 # FP_GCC_HAS_NO_UNIT_AT_A_TIME
1041 # --------------------------
1042 AC_DEFUN([FP_GCC_HAS_NO_UNIT_AT_A_TIME],
1043 [AC_REQUIRE([FP_HAVE_GCC])
1044 AC_CACHE_CHECK([whether gcc has -fno-unit-at-a-time], [fp_cv_gcc_has_no_unit_at_a_time],
1045 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
1046   [fp_cv_gcc_has_no_unit_at_a_time=yes],
1047   [fp_cv_gcc_has_no_unit_at_a_time=no])])
1048 if test "$fp_cv_gcc_has_no_unit_at_a_time" = "yes"; then
1049    AC_DEFINE([HAVE_GCC_HAS_NO_UNIT_AT_A_TIME], [1], [Define to 1 if gcc supports -fno-unit-at-a-time.])
1050 fi])
1051
1052 # FP_SETUP_PROJECT_VERSION
1053 # ---------------------
1054 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
1055 [# Some renamings
1056 AC_SUBST([ProjectName], [$PACKAGE_NAME])
1057 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
1058
1059 # Split PACKAGE_VERSION into (possibly empty) parts
1060 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1061 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1062 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1063 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1064
1065 # Calculate project version as an integer, using 2 digits for minor version
1066 case $VERSION_MINOR in
1067   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
1068   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
1069   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
1070 esac
1071 AC_SUBST([ProjectVersionInt])
1072
1073 # The project patchlevel is zero unless stated otherwise
1074 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
1075
1076 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
1077 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
1078
1079 AC_SUBST([ProjectPatchLevel])
1080 ])# FP_SETUP_PROJECT_VERSION
1081
1082 # LocalWords:  fi