aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FP_EVAL_STDERR(COMMAND)
   8 # -----------------------
   9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  10 # into the file conftest.err and the exit status in the variable fp_status.
  11 AC_DEFUN([FP_EVAL_STDERR],
  12 [{ (eval $1) 2>conftest.er1
  13   fp_status=$?
  14   grep -v '^ *+' conftest.er1 >conftest.err
  15   rm -f conftest.er1
  16   (exit $fp_status); }[]dnl
  17 ])# FP_EVAL_STDERR
  18
  19
  20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
  21 # ---------------------------------------------------------------------
  22 # Check to see whether the compiler for the current language supports a
  23 # particular option.
  24 #
  25 # Implementation note: When given an unkown option, GCC issues an warning on
  26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
  27 # to check stderr *and* the exit value.
  28 #
  29 # Used by ghc.
  30 AC_DEFUN(FP_CHECK_FLAG,
  31 [AC_LANG_COMPILER_REQUIRE()dnl
  32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
  33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
  34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
  35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
  36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
  37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
  38 fp_save_flags="$fp_Flags"
  39 fp_Flags="$fp_Flags $1"
  40 fp_Cache=no
  41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  42   test -s conftest.err || fp_Cache=yes
  43 fi
  44 fp_Flags="$fp_save_flags"
  45 rm -f conftest.err conftest.$ac_ext])
  46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
  47 m4_popdef([fp_Cache])[]dnl
  48 m4_popdef([fp_Flags])[]dnl
  49 ])# FP_CHECK_FLAG
  50
  51
  52 # FP_PROG_CONTEXT_DIFF
  53 # --------------------
  54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  55 #
  56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  57 #
  58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  61 [echo foo > conftest1
  62 echo foo > conftest2
  63 fp_cv_context_diff=no
  64 for fp_var in '-C 1' '-c1'
  65 do
  66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  67     fp_cv_context_diff="diff $fp_var"
  68     break
  69   fi
  70 done])
  71 if test x"$fp_cv_context_diff" = xno; then
  72    AC_MSG_ERROR([cannot figure out how to do context diffs])
  73 fi
  74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  75 ])# FP_PROG_CONTEXT_DIFF
  76
  77
  78 # FP_DECL_ALTZONE
  79 # ---------------
  80 # Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
  81 #
  82 # Used by base package.
  83 AC_DEFUN([FP_DECL_ALTZONE],
  84 [AC_REQUIRE([AC_HEADER_TIME])dnl
  85 AC_CHECK_HEADERS([sys/time.h])
  86 AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
  87 # include <sys/time.h>
  88 # include <time.h>
  89 #else
  90 # if HAVE_SYS_TIME_H
  91 #  include <sys/time.h>
  92 # else
  93 #  include <time.h>
  94 # endif
  95 #endif])
  96 ])# FP_DECL_ALTZONE
  97
  98
  99 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
 100 # --------------------------------------------------------
 101 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
 102 # compilation. Execute IF-FAILS when unable to determine the value. Works for
 103 # cross-compilation, too.
 104 #
 105 # Implementation note: We are lazy and use an internal autoconf macro, but it
 106 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
 107 # little risk.
 108 AC_DEFUN([FP_COMPUTE_INT],
 109 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
 110 ])# FP_COMPUTE_INT
 111
 112
 113 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
 114 # ------------------------------------------------------------------
 115 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
 116 # given type. Defines ALIGNMENT_TYPE.
 117 AC_DEFUN([FP_CHECK_ALIGNMENT],
 118 [AS_LITERAL_IF([$1], [],
 119                [AC_FATAL([$0: requires literal arguments])])[]dnl
 120 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 121 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 122 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 123 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 124   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 125                  [fp_Cache],
 126                  [AC_INCLUDES_DEFAULT([$3])],
 127                  [AC_MSG_ERROR([cannot compute alignment ($1)
 128 See `config.log' for more details.], [77])])
 129 else
 130   fp_Cache=0
 131 fi])[]dnl
 132 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 133 m4_popdef([fp_Cache])[]dnl
 134 ])# FP_CHECK_ALIGNMENT
 135
 136
 137 # FP_LEADING_UNDERSCORE
 138 # ---------------------
 139 # Test for determining whether symbol names have a leading underscore. We assume
 140 # that they _haven't_ if anything goes wrong. Sets the output variable
 141 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 142 #
 143 # Some nlist implementations seem to try to be compatible by ignoring a leading
 144 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 145 # checking for *no* leading underscore first. Sigh.  --SDM
 146 #
 147 # Similarly on OpenBSD, but this test doesn't help. -- dons
 148 AC_DEFUN([FP_LEADING_UNDERSCORE],
 149 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 150 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 151 # Hack!: nlist() under Digital UNIX insist on there being an _,
 152 # but symbol table listings shows none. What is going on here?!?
 153 #
 154 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 155 # the underscoredness of that "platform"
 156 case $HostPlatform in
 157 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 158   case $build in
 159     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 160     *) fptools_cv_leading_underscore=no ;;
 161   esac ;;
 162 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 163 *cygwin32) fptools_cv_leading_underscore=yes;;
 164 *mingw32) fptools_cv_leading_underscore=yes;;
 165 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 166 #include <nlist.h>
 167 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 168 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 169 #endif
 170
 171 int main(argc, argv)
 172 int argc;
 173 char **argv;
 174 {
 175 #ifdef HAVE_NLIST_H
 176     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 177         exit(1);
 178     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 179         exit(0);
 180 #endif
 181     exit(1);
 182 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 183 ;;
 184 esac]);
 185 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 186 if test x"$fptools_cv_leading_underscore" = xyes; then
 187    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 188 fi])# FP_LEADING_UNDERSCORE
 189
 190
 191 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 192 # ----------------------------------------------------------------------------------
 193 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 194 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 195 AC_DEFUN([FP_COMPARE_VERSIONS],
 196 [fp_version1=$1; fp_version2=$3
 197 fp_save_IFS=$IFS; IFS='.'
 198 while test x"$fp_version1" != x || test x"$fp_version2" != x
 199 do
 200
 201   set dummy $fp_version1; shift
 202   fp_num1=""
 203   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 204   test x"$fp_num1" = x && fp_num1="0"
 205   fp_version1="[$]*"
 206
 207   set dummy $fp_version2; shift
 208   fp_num2=""
 209   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 210   test x"$fp_num2" = x && fp_num2="0"
 211   fp_version2="[$]*"
 212
 213   test "$fp_num1" = "$fp_num2" || break;
 214 done
 215 IFS=$fp_save_IFS
 216 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 217 ])# FP_COMPARE_VERSIONS
 218
 219
 220 dnl
 221 dnl Check for GreenCard and version.
 222 dnl
 223 AC_DEFUN(FPTOOLS_GREENCARD,
 224 [
 225 AC_PATH_PROG(GreenCardCmd,greencard)
 226 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 227 changequote(, )dnl
 228 [if test x"$GreenCardCmd" != x; then
 229    fptools_cv_greencard_version="`$GreenCardCmd --version |
 230                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 231 else
 232    fptools_cv_greencard_version=""
 233 fi
 234 changequote([, ])dnl
 235 ])
 236 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 237   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 238 GreenCardVersion=$fptools_cv_greencard_version
 239 AC_SUBST(GreenCardVersion)
 240 ])
 241
 242 dnl
 243 dnl Check for Happy and version.  If we're building GHC, then we need
 244 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 245 dnl for a happy source tree and point the build system at that instead.
 246 dnl
 247 AC_DEFUN(FPTOOLS_HAPPY,
 248 [
 249 if test -d $srcdir/happy; then
 250    SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
 251 fi
 252 if test x"$UseSrcTreeHappy" = xYES; then
 253   HappyCmd=$SrcTreeHappyCmd
 254 else
 255   AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
 256 fi
 257 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 258 changequote(, )dnl
 259 [if test x"$HappyCmd" = x"$SrcTreeHappyCmd" -a -e $srcdir/happy/mk/version.mk; then
 260    fptools_cv_happy_version=`grep '^ProjectVersion[     ]*=' $srcdir/happy/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 261 elif test x"$HappyCmd" != x; then
 262    fptools_cv_happy_version="`$HappyCmd -v |
 263                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 264 else
 265    fptools_cv_happy_version="";
 266 fi;
 267 changequote([, ])dnl
 268 ])
 269 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
 270   FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.14],
 271   [AC_MSG_ERROR([Happy version 1.14 or later is required to compile GHC.])])[]dnl
 272 fi
 273 HappyVersion=$fptools_cv_happy_version;
 274 AC_SUBST(HappyVersion)
 275 ])
 276
 277 dnl
 278 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 279 dnl for a haddock source tree and point the build system at that instead.
 280 dnl
 281 AC_DEFUN(FPTOOLS_HADDOCK,
 282 [
 283 if test -d $srcdir/haddock; then
 284    SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
 285 fi
 286 if test x"$UseSrcTreeHaddock" = xYES; then
 287   HaddockCmd=$SrcTreeHaddockCmd
 288 else
 289   AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
 290 fi
 291 dnl Darn, I forgot to make Haddock print out its version number when
 292 dnl invoked with -v.  We could try generating some HTML and grepping
 293 dnl through that to find the version number, but I think we'll make
 294 dnl do without it for now.
 295 ])
 296
 297 dnl
 298 dnl Check for Alex and version.  If we're building GHC, then we need
 299 dnl at least Alex version 2.0.  If there's no installed Alex, we look
 300 dnl for a alex source tree and point the build system at that instead.
 301 dnl
 302 AC_DEFUN(FPTOOLS_ALEX,
 303 [
 304 if test -d $srcdir/alex; then
 305    SrcTreeAlexCmd=$hardtop/alex/src/alex-inplace
 306 fi
 307 if test x"$UseSrcTreeAlex" = xYES; then
 308   AlexCmd=$SrcTreeAlexCmd
 309 else
 310   AC_PATH_PROG(AlexCmd,alex,$SrcTreeAlexCmd)
 311 fi
 312 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 313 changequote(, )dnl
 314 [if test x"$AlexCmd" = x"$SrcTreeAlexCmd"; then
 315    fptools_cv_alex_version=`grep '^ProjectVersion[      ]*=' $srcdir/alex/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 316 elif test x"$AlexCmd" != x; then
 317    fptools_cv_alex_version="`$AlexCmd -v |
 318                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 319 else
 320    fptools_cv_alex_version="";
 321 fi;
 322 changequote([, ])dnl
 323 ])
 324 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Lexer.hs; then
 325   FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
 326   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
 327 fi
 328 AlexVersion=$fptools_cv_alex_version;
 329 AC_SUBST(AlexVersion)
 330 ])
 331
 332
 333 dnl
 334 dnl Check whether ld supports -x
 335 dnl
 336 AC_DEFUN(FPTOOLS_LD_X,
 337 [AC_CACHE_CHECK([whether ld understands -x], fptools_cv_ld_x,
 338 [
 339 echo 'foo() {}' > conftest.c
 340 ${CC-cc} -c conftest.c
 341 if ${LdCmd} -r -x -o foo.o conftest.o; then
 342    fptools_cv_ld_x=yes
 343 else
 344    fptools_cv_ld_x=no
 345 fi
 346 rm -rf conftest.c conftest.o foo.o
 347 ])
 348 if test "$fptools_cv_ld_x" = yes; then
 349         LdXFlag=-x
 350 else
 351         LdXFlag=
 352 fi
 353 AC_SUBST(LdXFlag)
 354 ])
 355
 356
 357 # FP_PROG_AR
 358 # ----------
 359 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 360 # version of it. Exits if no ar can be found
 361 AC_DEFUN([FP_PROG_AR],
 362 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 363 if test -z "$fp_prog_ar_raw"; then
 364   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 365 fi
 366 fp_prog_ar=$fp_prog_ar_raw
 367 case $HostPlatform in
 368   *mingw32) if test x${OSTYPE} != xmsys; then
 369               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 370               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 371             fi
 372             ;;
 373 esac
 374 ])# FP_PROG_AR
 375
 376
 377 # FP_PROG_AR_IS_GNU
 378 # -----------------
 379 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 380 AC_DEFUN([FP_PROG_AR_IS_GNU],
 381 [AC_REQUIRE([FP_PROG_AR])
 382 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 383 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 384   fp_cv_prog_ar_is_gnu=yes
 385 else
 386   fp_cv_prog_ar_is_gnu=no
 387 fi])
 388 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 389 ])# FP_PROG_AR_IS_GNU
 390
 391
 392 # FP_PROG_AR_ARGS
 393 # ---------------
 394 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 395 # to a non-Cygwin invocation of ar including these arguments.
 396 AC_DEFUN([FP_PROG_AR_ARGS],
 397 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 398 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 399 [
 400 # GNU ar needs special treatment: it appears to have problems with
 401 # object files with the same name if you use the 's' modifier, but
 402 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 403 if test $fp_prog_ar_is_gnu = yes; then
 404   fp_cv_prog_ar_args="q"
 405 else
 406   touch conftest.dummy
 407   for fp_var in clqsZ clqs cqs clq cq ; do
 408      rm -f conftest.a
 409      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 410         fp_cv_prog_ar_args=$fp_var
 411         break
 412      fi
 413   done
 414   rm -f conftest*
 415   if test -z "$fp_cv_prog_ar_args"; then
 416     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 417   fi
 418 fi])
 419 fp_prog_ar_args=$fp_cv_prog_ar_args
 420 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 421
 422 ])# FP_PROG_AR_ARGS
 423
 424
 425 # FP_PROG_AR_NEEDS_RANLIB
 426 # -----------------------
 427 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 428 # to ":" otherwise.
 429 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 430 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 431 AC_REQUIRE([FP_PROG_AR_ARGS])
 432 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 433 [if test $fp_prog_ar_is_gnu = yes; then
 434   fp_cv_prog_ar_needs_ranlib=no
 435 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 436   fp_cv_prog_ar_needs_ranlib=no
 437 else
 438   fp_cv_prog_ar_needs_ranlib=yes
 439 fi])
 440 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 441    AC_PROG_RANLIB
 442 else
 443   RANLIB=":"
 444   AC_SUBST([RANLIB])
 445 fi
 446 ])# FP_PROG_AR_NEEDS_RANLIB
 447
 448
 449 # FP_PROG_AR_SUPPORTS_INPUT
 450 # -------------------------
 451 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 452 # whether ar supports -input flag is supported or not.
 453 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 454 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 455 AC_REQUIRE([FP_PROG_AR_ARGS])
 456 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 457 [fp_cv_prog_ar_supports_input=no
 458 if test $fp_prog_ar_is_gnu = no; then
 459   rm -f conftest*
 460   touch conftest.lst
 461   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 462     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 463   fi
 464   rm -f conftest*
 465 fi])
 466 if test $fp_cv_prog_ar_supports_input = yes; then
 467     ArSupportsInput="-input"
 468 else
 469     ArSupportsInput=""
 470 fi
 471 AC_SUBST([ArSupportsInput])
 472 ])# FP_PROG_AR_SUPPORTS_INPUT
 473
 474
 475 dnl
 476 dnl AC_SHEBANG_PERL - can we she-bang perl?
 477 dnl
 478 AC_DEFUN(FPTOOLS_SHEBANG_PERL,
 479 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 480 [echo "#!$PerlCmd"'
 481 exit $1;
 482 ' > conftest
 483 chmod u+x conftest
 484 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 485 if test $? -ne 69; then
 486    fptools_cv_shebang_perl=yes
 487 else
 488    fptools_cv_shebang_perl=no
 489 fi
 490 rm -f conftest
 491 ])])
 492
 493 dnl
 494 dnl Extra testing of the result AC_PROG_CC, testing the gcc version no.
 495 dnl *Must* be called after AC_PROG_CC
 496 dnl
 497 AC_DEFUN(FPTOOLS_HAVE_GCC,
 498 [AC_CACHE_CHECK([whether you have an ok gcc], fptools_cv_have_gcc,
 499 [if test -z "$GCC"; then
 500     echo ''
 501     echo "You would be better off with gcc"
 502     echo "Perhaps it is already installed, but not in your PATH?"
 503     fptools_cv_have_gcc='no'
 504 else
 505 changequote(, )dnl
 506     gcc_version_str="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [^0-9]*\([0-9][0-9]*\)\.\([0-9][0-9]*\).*/\1\.\2/g' `"
 507 changequote([, ])dnl
 508     fptools_cv_have_gcc='yes'
 509     FP_COMPARE_VERSIONS([$gcc_version_str], [-lt], [2.0],
 510         [fptools_cv_have_gcc='no'
 511         echo ""
 512         echo "your gcc version appears to be ..."
 513         $CC --version
 514         echo "gcc prior to 2.0 and have never worked with ghc."
 515         echo "we recommend 2.95.3, although versions back to 2.7.2 should be ok."
 516         AC_MSG_ERROR([gcc 1.X has never been supported])])
 517 fi
 518 ])
 519 HaveGcc=`echo $fptools_cv_have_gcc | sed 'y/yesno/YESNO/'`
 520 AC_SUBST(HaveGcc)
 521 GccVersion=`gcc --version | grep mingw | cut -f 3 -d ' '`
 522 AC_SUBST(GccVersion)
 523 ])
 524
 525 dnl
 526 dnl Some OSs (Mandrake Linux, in particular) configure GCC with
 527 dnl -momit-leaf-frame-pointer on by default.  If this is the case, we
 528 dnl need to turn it off for mangling to work.  The test is currently a bit
 529 dnl crude, using only the version number of gcc.
 530 dnl
 531 AC_DEFUN([FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR],
 532 [AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fptools_cv_gcc_needs_no_omit_lfptr],
 533 [FP_COMPARE_VERSIONS([$gcc_version_str], [-ge], [3.2],
 534   [fptools_cv_gcc_needs_no_omit_lfptr=yes],
 535   [fptools_cv_gcc_needs_no_omit_lfptr=no])])
 536 if test "$fptools_cv_gcc_needs_no_omit_lfptr" = "yes"; then
 537    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
 538 fi])# FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR
 539
 540
 541 dnl Small feature test for perl version. Assumes PerlCmd
 542 dnl contains path to perl binary
 543 dnl
 544 AC_DEFUN(FPTOOLS_CHECK_PERL_VERSION,
 545 [$PerlCmd -v >conftest.out 2>&1
 546 if grep "version 5" conftest.out >/dev/null 2>&1; then
 547    :
 548 else
 549    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 550       :
 551    else
 552       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 553          :
 554       else
 555          if grep "version 6" conftest.out >/dev/null 2>&1; then
 556             :
 557          else
 558             echo "Your version of perl probably won't work."
 559          fi
 560       fi
 561    fi
 562 fi
 563 rm -fr conftest*
 564 ])
 565
 566
 567 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 568 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 569 # -----------------------------------------------------
 570 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 571 # of PROG-TO-CHECK-FOR when found.
 572 AC_DEFUN([FP_CHECK_PROG],
 573 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 574 )# FP_CHECK_PROC
 575
 576
 577 # FP_PROG_FIND
 578 # ------------
 579 # Find a non-WinDoze version of the "find" utility.
 580 AC_DEFUN([FP_PROG_FIND],
 581 [AC_PATH_PROG([fp_prog_find], [find])
 582 echo foo > conftest.txt
 583 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 584 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 585   # OK, looks like a real "find".
 586   FindCmd="$fp_prog_find"
 587 else
 588   # Found a poor WinDoze version of "find", ignore it.
 589   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 590   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 591 fi
 592 rm -f conftest.txt conftest.out
 593 AC_SUBST([FindCmd])[]dnl
 594 ])# FP_PROG_FIND
 595
 596
 597 dnl
 598 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 599 dnl values of the second argument to the result of running
 600 dnl the commands given by the third. It does not cache its
 601 dnl result, so it is suitable for checks which should be
 602 dnl run every time.
 603 dnl
 604 AC_DEFUN(FPTOOLS_NOCACHE_CHECK,
 605 [AC_MSG_CHECKING([$1])
 606  $3
 607  AC_MSG_RESULT([$][$2])
 608 ])
 609
 610 dnl
 611 dnl FPTOOLS_GHC_VERSION(version)
 612 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 613 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 614 dnl
 615 dnl Test for version of installed ghc.  Uses $GHC.
 616 dnl [original version pinched from c2hs]
 617 dnl
 618 AC_DEFUN(FPTOOLS_GHC_VERSION,
 619 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 620 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 621   cat conftestghc >&AS_MESSAGE_LOG_FD
 622 #Useless Use Of cat award...
 623   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 624   rm -fr conftest*
 625   if test "[$]fptools_version_of_ghc" = ""
 626   then
 627     fptools_version_of_ghc='unknown'
 628   fi
 629 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 630 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 631 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 632 #
 633 if test "[$]fptools_version_of_ghc[_pl]" = ""
 634 then
 635   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 636   fptools_version_of_ghc[_pl]="0"
 637 else
 638   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 639 fi
 640 #
 641 ifelse($#, [1], [dnl
 642 [$1]="[$]fptools_version_of_ghc[_all]"
 643 ], $#, [2], [dnl
 644 [$1]="[$]fptools_version_of_ghc[_major]"
 645 [$2]="[$]fptools_version_of_ghc[_minor]"
 646 ], $#, [3], [dnl
 647 [$1]="[$]fptools_version_of_ghc[_major]"
 648 [$2]="[$]fptools_version_of_ghc[_minor]"
 649 [$3]="[$]fptools_version_of_ghc[_pl]"
 650 ], $#, [4], [dnl
 651 [$1]="[$]fptools_version_of_ghc[_all]"
 652 [$2]="[$]fptools_version_of_ghc[_major]"
 653 [$3]="[$]fptools_version_of_ghc[_minor]"
 654 [$4]="[$]fptools_version_of_ghc[_pl]"
 655 ])
 656 ])
 657 ])dnl
 658
 659
 660 dnl ** Map an arithmetic C type to a Haskell type.
 661 dnl    Based on autconf's AC_CHECK_SIZEOF.
 662
 663 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
 664 AC_DEFUN(FPTOOLS_CHECK_HTYPE,
 665 [changequote(<<, >>)dnl
 666 dnl The name to #define.
 667 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
 668 dnl The cache variable name.
 669 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
 670 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
 671 changequote([, ])dnl
 672 AC_MSG_CHECKING(Haskell type for $1)
 673 AC_CACHE_VAL(AC_CV_NAME,
 674 [AC_CV_NAME_supported=yes
 675 fp_check_htype_save_cppflags="$CPPFLAGS"
 676 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 677 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdio.h>
 678 #include <stddef.h>
 679
 680 #if HAVE_SYS_TYPES_H
 681 # include <sys/types.h>
 682 #endif
 683
 684 #if HAVE_UNISTD_H
 685 # include <unistd.h>
 686 #endif
 687
 688 #if HAVE_SYS_STAT_H
 689 # include <sys/stat.h>
 690 #endif
 691
 692 #if HAVE_FCNTL_H
 693 # include <fcntl.h>
 694 #endif
 695
 696 #if HAVE_SIGNAL_H
 697 # include <signal.h>
 698 #endif
 699
 700 #if HAVE_TIME_H
 701 # include <time.h>
 702 #endif
 703
 704 #if HAVE_TERMIOS_H
 705 # include <termios.h>
 706 #endif
 707
 708 #if HAVE_STRING_H
 709 # include <string.h>
 710 #endif
 711
 712 #if HAVE_CTYPE_H
 713 # include <ctype.h>
 714 #endif
 715
 716 #if defined(HAVE_GL_GL_H)
 717 # include <GL/gl.h>
 718 #elif defined(HAVE_OPENGL_GL_H)
 719 # include <OpenGL/gl.h>
 720 #endif
 721
 722 #if defined(HAVE_AL_ALC_H)
 723 # include <AL/alc.h>
 724 #elif defined(HAVE_OPENAL_ALC_H)
 725 # include <OpenAL/alc.h>
 726 #endif
 727
 728 #if HAVE_SYS_RESOURCE_H
 729 # include <sys/resource.h>
 730 #endif
 731
 732 typedef $1 testing;
 733
 734 main() {
 735   FILE *f=fopen("conftestval", "w");
 736   if (!f) exit(1);
 737   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
 738     fprintf(f, "%s%d\n",
 739            ((testing)(-1) < (testing)0) ? "Int" : "Word",
 740            sizeof(testing)*8);
 741   } else {
 742     fprintf(f,"%s\n",
 743            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
 744            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
 745   }
 746   fclose(f);
 747   exit(0);
 748 }]])],[AC_CV_NAME=`cat conftestval`],
 749 [ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], [AC_CV_NAME=$2])],
 750 [ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], [AC_CV_NAME=$3])])]) dnl
 751 CPPFLAGS="$fp_check_htype_save_cppflags"
 752 if test "$AC_CV_NAME_supported" = yes; then
 753   AC_MSG_RESULT($AC_CV_NAME)
 754   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
 755 else
 756   AC_MSG_RESULT([not supported])
 757 fi
 758 undefine([AC_TYPE_NAME])dnl
 759 undefine([AC_CV_NAME])dnl
 760 undefine([AC_CV_NAME_supported])dnl
 761 ])
 762
 763
 764 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 765 # ---------------------------------------------------------------------------------
 766 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 767 # additional flexibility of specifying the PROLOGUE and BODY.
 768 AC_DEFUN([FP_CHECK_FUNC],
 769 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 770 AC_CACHE_CHECK([for $1], fp_func,
 771 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 772                 [AS_VAR_SET(fp_func, yes)],
 773                 [AS_VAR_SET(fp_func, no)])])
 774 AS_IF([test AS_VAR_GET(fp_func) = yes],
 775       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 776                 [Define to 1 if you have the `]$1[' function.]) $4],
 777       [$5])dnl
 778 AS_VAR_POPDEF([fp_func])dnl
 779 ])# FP_CHECK_FUNC
 780
 781
 782 # FP_GEN_DOCBOOK_XML
 783 # ------------------
 784 # Generates a DocBook XML V4.2 document in conftest.xml.
 785 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 786 [rm -f conftest.xml
 787 cat > conftest.xml << EOF
 788 <?xml version="1.0" encoding="iso-8859-1"?>
 789 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 790    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 791 <book id="test">
 792   <title>A DocBook Test Document</title>
 793   <chapter id="id-one">
 794     <title>A Chapter Title</title>
 795     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 796   </chapter>
 797   <chapter id="id-two">
 798     <title>Another Chapter Title</title>
 799     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 800   </chapter>
 801 </book>
 802 EOF
 803 ]) # FP_GEN_DOCBOOK_XML
 804
 805
 806 # FP_PROG_XSLTPROC
 807 # ----------------
 808 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 809 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 810 AC_DEFUN([FP_PROG_XSLTPROC],
 811 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 812 if test -z "$XsltprocCmd"; then
 813   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 814 fi
 815 ])# FP_PROG_XSLTPROC
 816
 817
 818 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 819 # ----------------------------
 820 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 821 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 822 # will be empty if none could be found.
 823 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 824 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 825 if test -n "$XsltprocCmd"; then
 826   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 827   [FP_GEN_DOCBOOK_XML
 828   fp_cv_dir_docbook_xsl=no
 829   for fp_var in $1; do
 830      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 831         fp_cv_dir_docbook_xsl=$fp_var
 832         break
 833      fi
 834   done
 835   rm -rf conftest*])
 836 fi
 837 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 838   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 839   DIR_DOCBOOK_XSL=
 840 else
 841   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 842 fi
 843 AC_SUBST([DIR_DOCBOOK_XSL])
 844 ])# FP_DIR_DOCBOOK_XSL
 845
 846
 847 # FP_PROG_XMLLINT
 848 # ----------------
 849 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 850 # xmllint. XmllintCmd is empty if xmllint could not be found.
 851 AC_DEFUN([FP_PROG_XMLLINT],
 852 [AC_PATH_PROG([XmllintCmd], [xmllint])
 853 if test -z "$XmllintCmd"; then
 854   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 855 fi
 856 ])# FP_PROG_XMLLINT
 857
 858
 859 # FP_CHECK_DOCBOOK_DTD
 860 # --------------------
 861 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 862 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 863 if test -n "$XmllintCmd"; then
 864   AC_MSG_CHECKING([for DocBook DTD])
 865   FP_GEN_DOCBOOK_XML
 866   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 867     AC_MSG_RESULT([ok])
 868   else
 869     AC_MSG_RESULT([failed])
 870     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 871     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 872   fi
 873   rm -rf conftest*
 874 fi
 875 ])# FP_CHECK_DOCBOOK_DTD
 876
 877
 878 # FP_GEN_FO
 879 # ------------------
 880 # Generates a formatting objects document in conftest.fo.
 881 AC_DEFUN([FP_GEN_FO],
 882 [rm -f conftest.fo
 883 cat > conftest.fo << EOF
 884 <?xml version="1.0"?>
 885 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 886   <fo:layout-master-set>
 887     <fo:simple-page-master master-name="blank">
 888       <fo:region-body/>
 889     </fo:simple-page-master>
 890   </fo:layout-master-set>
 891   <fo:page-sequence master-reference="blank">
 892     <fo:flow flow-name="xsl-region-body">
 893       <fo:block>
 894         Test!
 895       </fo:block>
 896     </fo:flow>
 897   </fo:page-sequence>
 898 </fo:root>
 899 EOF
 900 ]) # FP_GEN_FO
 901
 902
 903 # FP_PROG_FOP
 904 # -----------
 905 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 906 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 907 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 908 AC_DEFUN([FP_PROG_FOP],
 909 [AC_PATH_PROGS([FopCmd1], [fop])
 910 if test -n "$FopCmd1"; then
 911   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 912     [FP_GEN_FO
 913     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 914       fp_cv_fop_usability=yes
 915     else
 916       fp_cv_fop_usability=no
 917     fi
 918     rm -rf conftest*])
 919   if test x"$fp_cv_fop_usability" = xyes; then
 920      FopCmd=$FopCmd1
 921   fi
 922 fi
 923 if test -z "$FopCmd"; then
 924   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 925   FopCmd=$FopCmd2
 926 fi
 927 AC_SUBST([FopCmd])
 928 ])# FP_PROG_FOP
 929
 930
 931 # FP_PROG_FO_PROCESSOR
 932 # --------------------
 933 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
 934 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
 935 # PdfxmltexCmd.
 936 AC_DEFUN([FP_PROG_FO_PROCESSOR],
 937 [AC_REQUIRE([FP_PROG_FOP])
 938 AC_PATH_PROG([XmltexCmd], [xmltex])
 939 AC_PATH_PROG([DvipsCmd], [dvips])
 940 if test -z "$FopCmd"; then
 941   if test -z "$XmltexCmd"; then
 942     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
 943   else
 944     if test -z "$DvipsCmd"; then
 945       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
 946     fi
 947   fi
 948   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
 949   if test -z "$PdfxmltexCmd"; then
 950     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
 951   fi
 952 elif test -z "$XmltexCmd"; then
 953   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
 954 fi
 955 ])# FP_PROG_FO_PROCESSOR
 956
 957
 958 # FP_PROG_GHC_PKG
 959 # ----------------
 960 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
 961 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
 962 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
 963 AC_DEFUN([FP_PROG_GHC_PKG],
 964 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
 965 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
 966 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
 967   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 968 else
 969   fp_cv_matching_ghc_pkg=no
 970 fi])
 971 if test x"$fp_cv_matching_ghc_pkg" = xno; then
 972   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
 973 else
 974   GhcPkgCmd=$fp_cv_matching_ghc_pkg
 975 fi])# FP_PROG_GHC_PKG
 976
 977
 978 # FP_CHECK_WIN32
 979 # --------------
 980 # If Windows is the target platform (e.g. MinGW/MSYS or Cygwin with
 981 # -mno-cygwin), the variable "is_win32" is set to "yes", otherwise (e.g. *nix
 982 # systems or plain Cygwin) it is set to "no".
 983 AC_DEFUN([FP_CHECK_WIN32],
 984 [AC_CACHE_CHECK([for Windows environment], [fp_cv_is_win32],
 985   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 986 #if !_WIN32
 987    syntax error;
 988 #endif
 989 ])], [fp_cv_is_win32=yes], [fp_cv_is_win32=no])])
 990 is_win32="$fp_cv_is_win32"[]dnl
 991 ])# FP_CHECK_WIN32
 992
 993
 994 # FP_PATH_X
 995 # ---------
 996 # Same as AC_PATH_X, but works even for broken Cygwins which try to include the
 997 # non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
 998 AC_DEFUN([FP_PATH_X],
 999 [AC_REQUIRE([FP_CHECK_WIN32])
1000 if test x"$is_win32" = xyes; then
1001   no_x=yes
1002 else
1003   AC_PATH_X
1004 fi
1005 ])# FP_PATH_X
1006
1007
1008 # FP_PATH_XTRA
1009 # ------------
1010 # Same as AC_PATH_XTRA, but works even for broken Cygwins which try to include
1011 # the non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
1012 AC_DEFUN([FP_PATH_XTRA],
1013 [AC_REQUIRE([FP_CHECK_WIN32])
1014 if test x"$is_win32" = xyes; then
1015   no_x=yes
1016 else
1017   AC_PATH_XTRA
1018 fi
1019 ])# FP_PATH_XTRA
1020
1021
1022 # FP_CHECK_GL_HELPER(LIBNAME, LIBS, INCLUDES, FUNCTION-BODY)
1023 # ----------------------------------------------------------
1024 # Try each library in LIBS to successfully link INCLUDES plus FUNCTION-BODY,
1025 # setting LIBNAME_CFLAGS and LIBNAME_LIBS to the corresponding values. Sets
1026 # no_LIBNAME to "yes" if no suitable library was found. (LIBNAME_CFLAGS0
1027 # contains the value of LIBNAME_CFLAGS without CPPFLAGS, and LIBNAME_LIBS0
1028 # contains the value of LIBNAME_LIBS without LDFLAGS, but these are only
1029 # used internally.)
1030 AC_DEFUN([FP_CHECK_GL_HELPER],
1031 [AC_CACHE_CHECK([for $1 library], [fp_cv_check_$1_lib],
1032   [fp_cv_check_$1_lib="no"
1033   fp_save_CPPFLAGS="$CPPFLAGS"
1034   CPPFLAGS="$CPPFLAGS ${$1_CFLAGS}"
1035   fp_save_LIBS="$LIBS"
1036   for fp_try_lib in $2; do
1037     # transform "-lfoo" to "foo.lib" when using cl
1038     if test x"$CC" = xcl; then
1039       fp_try_lib=`echo $fp_try_lib | sed -e 's/^-l//' -e 's/$/.lib/'`
1040     fi
1041     LIBS="$fp_try_lib ${$1_LIBS} $fp_save_LIBS"
1042     AC_LINK_IFELSE([AC_LANG_PROGRAM([$3], [$4])], [fp_cv_check_$1_lib="$fp_try_lib ${$1_LIBS}"; break])
1043   done
1044   LIBS="$fp_save_LIBS"
1045   CPPFLAGS="$fp_save_CPPFLAGS"])
1046
1047   if test x"$fp_cv_check_$1_lib" = xno; then
1048     no_$1=yes
1049     $1_CFLAGS=
1050     $1_LIBS=
1051   else
1052     $1_CFLAGS0="${$1_CFLAGS}"
1053     $1_CFLAGS="$CPPFLAGS ${$1_CFLAGS0}"
1054     $1_LIBS0="$fp_cv_check_$1_lib"
1055     $1_LIBS="$LDFLAGS ${$1_LIBS0}"
1056   fi
1057 ])# FP_CHECK_GL_HELPER
1058
1059
1060 # FP_CHECK_GL
1061 # -----------
1062 AC_DEFUN([FP_CHECK_GL],
1063 [AC_REQUIRE([FP_PATH_X])
1064 AC_REQUIRE([AC_CANONICAL_TARGET])
1065
1066 AC_ARG_ENABLE([hopengl],
1067   [AC_HELP_STRING([--enable-hopengl],
1068     [build a Haskell binding for OpenGL (GL/GLU). On Mac OS X, use
1069      --enable-hopengl=x11 to use X11 instead of the "native" libraries.
1070      (default=no)])],
1071   [enable_opengl=$enableval], [enable_opengl=no])
1072
1073 if test x"$enable_opengl" = xno; then
1074    no_GL=yes
1075 else
1076   use_quartz_opengl=no
1077   case $target_os in
1078   darwin*)
1079     if test x"$enable_opengl" != xx11; then
1080       AC_DEFINE([USE_QUARTZ_OPENGL], [1],
1081                 [Define to 1 if native OpenGL should be used on Mac OS X])
1082       use_quartz_opengl=yes
1083     fi
1084     ;;
1085   esac
1086
1087   if test x"$use_quartz_opengl" != xyes; then
1088     AC_CHECK_LIB([m], [atan], [GL_LIBS="-lm $GL_LIBS"])
1089
1090     if test x"$no_x" != xyes; then
1091       test -n "$x_includes" && GL_CFLAGS="-I$x_includes $GL_CFLAGS"
1092       test -n "$x_libraries" && GL_LIBS="-L$x_libraries -lX11 $GL_LIBS"
1093     fi
1094
1095     FP_CHECK_GL_HELPER([GL], [-lGL -lopengl32], [@%:@include <GL/gl.h>], [glEnd()])
1096
1097     if test x"$no_GL" != xyes; then
1098       # Ugly: To get wglGetProcAddress on Windows, we have to link with
1099       # opengl32.dll, too, even when we are using Cygwin with X11.
1100       case "$GL_LIBS" in
1101         *-lopengl32*|*opengl32.lib*) ;;
1102         *) fp_save_LIBS="$LIBS"
1103            LIBS="$LIBS -lopengl32"
1104            AC_LINK_IFELSE([AC_LANG_PROGRAM([[@%:@include <GL/gl.h>]], [[glEnd()]])],
1105              [GL_LIBS="$GL_LIBS -lopengl32"; GL_LIBS0="$GL_LIBS0 -lopengl32"])
1106            LIBS="$fp_save_LIBS"
1107            ;;
1108       esac
1109     fi
1110   fi
1111 fi
1112
1113 AC_SUBST([GL_CFLAGS])
1114 AC_SUBST([GL_LIBS])
1115 ])# FP_CHECK_GL
1116
1117
1118 # FP_CHECK_GLU
1119 # ------------
1120 AC_DEFUN([FP_CHECK_GLU],
1121 [AC_REQUIRE([FP_CHECK_GL])dnl
1122 GLU_CFLAGS="$GL_CFLAGS0"
1123 GLU_LIBS="$GL_LIBS0"
1124
1125 if test x"$enable_opengl" = xno; then
1126    no_GLU=yes
1127 elif test x"$use_quartz_opengl" != xyes; then
1128   FP_CHECK_GL_HELPER([GLU], [-lglu32 -lGLU], [@%:@include <GL/glu.h>], [gluNewQuadric()])
1129 fi
1130
1131 AC_SUBST([GLU_CFLAGS])
1132 AC_SUBST([GLU_LIBS])
1133 ])# FP_CHECK_GLU
1134
1135
1136 # FP_CHECK_GLUT
1137 # -------------
1138 AC_DEFUN([FP_CHECK_GLUT],
1139 [AC_REQUIRE([FP_CHECK_GLU])
1140 FP_PATH_XTRA
1141
1142 if test x"$enable_opengl" = xno; then
1143    no_GLUT=yes
1144 elif test x"$use_quartz_opengl" != xyes; then
1145   GLUT_CFLAGS="$GLU_CFLAGS0"
1146   GLUT_LIBS="$GLU_LIBS0"
1147
1148   if test x"$no_x" != xyes; then
1149     GLUT_LIBS="$X_PRE_LIBS -lXmu -lXi $X_EXTRA_LIBS $GLUT_LIBS"
1150   fi
1151
1152   AC_CHECK_HEADERS([windows.h GL/glut.h])
1153   # Note 1: On Cygwin with X11, GL/GLU functions use the "normal" calling
1154   # convention, but GLUT functions use stdcall. To get this right, it is
1155   # necessary to include <windows.h> first.
1156   # Note 2: MinGW/MSYS comes without a GLUT header, so we use Cygwin's one in
1157   # that case.
1158   FP_CHECK_GL_HELPER([GLUT], [-lglut32 -lglut], [
1159 #if HAVE_WINDOWS_H
1160 #include <windows.h>
1161 #endif
1162 #if HAVE_GL_GLUT_H
1163 #include <GL/glut.h>
1164 #else
1165 #include "glut_local.h"
1166 #endif
1167     ], [glutMainLoop()])
1168 fi
1169
1170 AC_SUBST([GLUT_CFLAGS])
1171 AC_SUBST([GLUT_LIBS])
1172 ])# FP_CHECK_GLUT
1173
1174 # LocalWords:  fi