aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FP_EVAL_STDERR(COMMAND)
   8 # -----------------------
   9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  10 # into the file conftest.err and the exit status in the variable fp_status.
  11 AC_DEFUN([FP_EVAL_STDERR],
  12 [{ (eval $1) 2>conftest.er1
  13   fp_status=$?
  14   grep -v '^ *+' conftest.er1 >conftest.err
  15   rm -f conftest.er1
  16   (exit $fp_status); }[]dnl
  17 ])# FP_EVAL_STDERR
  18
  19
  20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
  21 # ---------------------------------------------------------------------
  22 # Check to see whether the compiler for the current language supports a
  23 # particular option.
  24 #
  25 # Implementation note: When given an unkown option, GCC issues an warning on
  26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
  27 # to check stderr *and* the exit value.
  28 #
  29 # Used by ghc.
  30 AC_DEFUN([FP_CHECK_FLAG],
  31 [AC_LANG_COMPILER_REQUIRE()dnl
  32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
  33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
  34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
  35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
  36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
  37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
  38 fp_save_flags="$fp_Flags"
  39 fp_Flags="$fp_Flags $1"
  40 fp_Cache=no
  41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  42   test -s conftest.err || fp_Cache=yes
  43 fi
  44 fp_Flags="$fp_save_flags"
  45 rm -f conftest.err conftest.$ac_ext])
  46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
  47 m4_popdef([fp_Cache])[]dnl
  48 m4_popdef([fp_Flags])[]dnl
  49 ])# FP_CHECK_FLAG
  50
  51
  52 # FP_PROG_CONTEXT_DIFF
  53 # --------------------
  54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  55 #
  56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  57 #
  58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  61 [echo foo > conftest1
  62 echo foo > conftest2
  63 fp_cv_context_diff=no
  64 for fp_var in '-C 1' '-c1'
  65 do
  66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  67     fp_cv_context_diff="diff $fp_var"
  68     break
  69   fi
  70 done])
  71 if test x"$fp_cv_context_diff" = xno; then
  72    AC_MSG_ERROR([cannot figure out how to do context diffs])
  73 fi
  74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  75 ])# FP_PROG_CONTEXT_DIFF
  76
  77
  78 # FP_DECL_ALTZONE
  79 # ---------------
  80 # Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
  81 #
  82 # Used by base package.
  83 AC_DEFUN([FP_DECL_ALTZONE],
  84 [AC_REQUIRE([AC_HEADER_TIME])dnl
  85 AC_CHECK_HEADERS([sys/time.h])
  86 AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
  87 # include <sys/time.h>
  88 # include <time.h>
  89 #else
  90 # if HAVE_SYS_TIME_H
  91 #  include <sys/time.h>
  92 # else
  93 #  include <time.h>
  94 # endif
  95 #endif])
  96 ])# FP_DECL_ALTZONE
  97
  98
  99 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
 100 # --------------------------------------------------------
 101 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
 102 # compilation. Execute IF-FAILS when unable to determine the value. Works for
 103 # cross-compilation, too.
 104 #
 105 # Implementation note: We are lazy and use an internal autoconf macro, but it
 106 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
 107 # little risk.
 108 AC_DEFUN([FP_COMPUTE_INT],
 109 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
 110 ])# FP_COMPUTE_INT
 111
 112
 113 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
 114 # ------------------------------------------------------------------
 115 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
 116 # given type. Defines ALIGNMENT_TYPE.
 117 AC_DEFUN([FP_CHECK_ALIGNMENT],
 118 [AS_LITERAL_IF([$1], [],
 119                [AC_FATAL([$0: requires literal arguments])])[]dnl
 120 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 121 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 122 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 123 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 124   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 125                  [fp_Cache],
 126                  [AC_INCLUDES_DEFAULT([$3])],
 127                  [AC_MSG_ERROR([cannot compute alignment ($1)
 128 See `config.log' for more details.], [77])])
 129 else
 130   fp_Cache=0
 131 fi])[]dnl
 132 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 133 m4_popdef([fp_Cache])[]dnl
 134 ])# FP_CHECK_ALIGNMENT
 135
 136
 137 # FP_LEADING_UNDERSCORE
 138 # ---------------------
 139 # Test for determining whether symbol names have a leading underscore. We assume
 140 # that they _haven't_ if anything goes wrong. Sets the output variable
 141 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 142 #
 143 # Some nlist implementations seem to try to be compatible by ignoring a leading
 144 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 145 # checking for *no* leading underscore first. Sigh.  --SDM
 146 #
 147 # Similarly on OpenBSD, but this test doesn't help. -- dons
 148 AC_DEFUN([FP_LEADING_UNDERSCORE],
 149 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 150 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 151 # Hack!: nlist() under Digital UNIX insist on there being an _,
 152 # but symbol table listings shows none. What is going on here?!?
 153 #
 154 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 155 # the underscoredness of that "platform"
 156 case $HostPlatform in
 157 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 158   case $build in
 159     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 160     *) fptools_cv_leading_underscore=no ;;
 161   esac ;;
 162 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 163 *cygwin32) fptools_cv_leading_underscore=yes;;
 164 *mingw32) fptools_cv_leading_underscore=yes;;
 165 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 166 #include <nlist.h>
 167 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 168 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 169 #endif
 170
 171 int main(argc, argv)
 172 int argc;
 173 char **argv;
 174 {
 175 #ifdef HAVE_NLIST_H
 176     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 177         exit(1);
 178     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 179         exit(0);
 180 #endif
 181     exit(1);
 182 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 183 ;;
 184 esac]);
 185 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 186 if test x"$fptools_cv_leading_underscore" = xyes; then
 187    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 188 fi])# FP_LEADING_UNDERSCORE
 189
 190
 191 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 192 # ----------------------------------------------------------------------------------
 193 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 194 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 195 AC_DEFUN([FP_COMPARE_VERSIONS],
 196 [fp_version1=$1; fp_version2=$3
 197 fp_save_IFS=$IFS; IFS='.'
 198 while test x"$fp_version1" != x || test x"$fp_version2" != x
 199 do
 200
 201   set dummy $fp_version1; shift
 202   fp_num1=""
 203   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 204   test x"$fp_num1" = x && fp_num1="0"
 205   fp_version1="[$]*"
 206
 207   set dummy $fp_version2; shift
 208   fp_num2=""
 209   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 210   test x"$fp_num2" = x && fp_num2="0"
 211   fp_version2="[$]*"
 212
 213   test "$fp_num1" = "$fp_num2" || break;
 214 done
 215 IFS=$fp_save_IFS
 216 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 217 ])# FP_COMPARE_VERSIONS
 218
 219
 220 dnl
 221 dnl Check for GreenCard and version.
 222 dnl
 223 AC_DEFUN([FPTOOLS_GREENCARD],
 224 [
 225 AC_PATH_PROG(GreenCardCmd,greencard)
 226 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 227 changequote(, )dnl
 228 [if test x"$GreenCardCmd" != x; then
 229    fptools_cv_greencard_version="`$GreenCardCmd --version |
 230                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 231 else
 232    fptools_cv_greencard_version=""
 233 fi
 234 changequote([, ])dnl
 235 ])
 236 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 237   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 238 GreenCardVersion=$fptools_cv_greencard_version
 239 AC_SUBST(GreenCardVersion)
 240 ])
 241
 242 dnl
 243 dnl Check for Happy and version.  If we're building GHC, then we need
 244 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 245 dnl for a happy source tree and point the build system at that instead.
 246 dnl
 247 AC_DEFUN([FPTOOLS_HAPPY],
 248 [
 249 if test -d $srcdir/happy; then
 250    SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
 251 else
 252    SrcTreeHappyCmd=""
 253 fi
 254 if test x"$UseSrcTreeHappy" = xYES; then
 255   if test x"$SrcTreeHappyCmd" != x; then
 256      HappyCmd=$SrcTreeHappyCmd
 257   else
 258      AC_MSG_ERROR([--enable-src-tree-happy given, but happy not found in source tree])
 259   fi
 260 else
 261   AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
 262 fi
 263 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 264 changequote(, )dnl
 265 [if test x"$HappyCmd" = x"$SrcTreeHappyCmd" -a -e $srcdir/happy/mk/version.mk; then
 266    fptools_cv_happy_version=`grep '^ProjectVersion[     ]*=' $srcdir/happy/mk/version.mk | sed 's/[^0-9]*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 267 elif test x"$HappyCmd" != x; then
 268    fptools_cv_happy_version="`$HappyCmd -v |
 269                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 270 else
 271    fptools_cv_happy_version="";
 272 fi;
 273 changequote([, ])dnl
 274 ])
 275 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
 276   FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
 277   [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
 278 fi
 279 HappyVersion=$fptools_cv_happy_version;
 280 AC_SUBST(HappyVersion)
 281 ])
 282
 283 dnl
 284 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 285 dnl for a haddock source tree and point the build system at that instead.
 286 dnl
 287 AC_DEFUN([FPTOOLS_HADDOCK],
 288 [
 289 if test -d $srcdir/haddock; then
 290    SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
 291 else
 292    SrcTreeHaddockCmd=""
 293 fi
 294 if test x"$UseSrcTreeHaddock" = xYES; then
 295   if test x"$SrcTreeHaddockCmd" != x; then
 296      HaddockCmd=$SrcTreeHaddockCmd
 297   else
 298      AC_MSG_ERROR([--enable-src-tree-haddock given, but haddock not found in source tree])
 299   fi
 300 else
 301   AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
 302 fi
 303 dnl Darn, I forgot to make Haddock print out its version number when
 304 dnl invoked with -v.  We could try generating some HTML and grepping
 305 dnl through that to find the version number, but I think we'll make
 306 dnl do without it for now.
 307 ])
 308
 309 dnl
 310 dnl Check for Alex and version.  If we're building GHC, then we need
 311 dnl at least Alex version 2.0.  If there's no installed Alex, we look
 312 dnl for a alex source tree and point the build system at that instead.
 313 dnl
 314 AC_DEFUN([FPTOOLS_ALEX],
 315 [
 316 if test -d $srcdir/alex; then
 317    SrcTreeAlexCmd=$hardtop/alex/src/alex-inplace
 318 else
 319    SrcTreeAlexCmd=""
 320 fi
 321 if test x"$UseSrcTreeAlex" = xYES; then
 322   if test x"$SrcTreeAlexCmd" != x; then
 323      AlexCmd=$SrcTreeAlexCmd
 324   else
 325      AC_MSG_ERROR([--enable-src-tree-alex given, but alex not found in source tree])
 326   fi
 327 else
 328   AC_PATH_PROG(AlexCmd,alex,$SrcTreeAlexCmd)
 329 fi
 330 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 331 changequote(, )dnl
 332 [if test x"$AlexCmd" = x"$SrcTreeAlexCmd"; then
 333    fptools_cv_alex_version=`grep '^ProjectVersion[      ]*=' $srcdir/alex/mk/version.mk | sed 's/[^0-9]*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 334 elif test x"$AlexCmd" != x; then
 335    fptools_cv_alex_version="`$AlexCmd -v |
 336                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 337 else
 338    fptools_cv_alex_version="";
 339 fi;
 340 changequote([, ])dnl
 341 ])
 342 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Lexer.hs; then
 343   FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
 344   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
 345 fi
 346 AlexVersion=$fptools_cv_alex_version;
 347 AC_SUBST(AlexVersion)
 348 ])
 349
 350
 351 # FP_PROG_LD
 352 # ----------
 353 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 354 # of ld. Exits if no ld can be found
 355 AC_DEFUN([FP_PROG_LD],
 356 [AC_PATH_PROG([fp_prog_ld_raw], [ld])
 357 if test -z "$fp_prog_ld_raw"; then
 358   AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 359 fi
 360 LdCmd=$fp_prog_ld_raw
 361 case $HostPlatform in
 362   *mingw32) if test x${OSTYPE} != xmsys; then
 363               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 364               AC_MSG_NOTICE([normalized ld command to $LdCmd])
 365             fi
 366             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
 367             # the generation of relocatable object files with large amounts
 368             # of relocations correctly. (cf. HSbase.o splittage-hack)
 369             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
 370             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
 371                                 [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
 372             ;;
 373 esac
 374 AC_SUBST([LdCmd])
 375 ])# FP_PROG_LD
 376
 377
 378 # FP_PROG_LD_X
 379 # ------------
 380 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 381 # variable's value is empty.
 382 AC_DEFUN([FP_PROG_LD_X],
 383 [AC_REQUIRE([FP_PROG_LD])
 384 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 385 [echo 'foo() {}' > conftest.c
 386 ${CC-cc} -c conftest.c
 387 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
 388    fp_cv_ld_x=yes
 389 else
 390    fp_cv_ld_x=no
 391 fi
 392 rm -rf conftest*])
 393 if test "$fp_cv_ld_x" = yes; then
 394   LdXFlag=-x
 395 else
 396   LdXFlag=
 397 fi
 398 AC_SUBST([LdXFlag])
 399 ])# FP_PROG_LD_X
 400
 401
 402 # FP_PROG_LD_IS_GNU
 403 # -----------------
 404 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 405 # GNU ld or not.
 406 AC_DEFUN([FP_PROG_LD_IS_GNU],
 407 [AC_REQUIRE([FP_PROG_LD])
 408 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 409 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 410   fp_cv_gnu_ld=yes
 411 else
 412   fp_cv_gnu_ld=no
 413 fi])
 414 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 415 ])# FP_PROG_LD_IS_GNU
 416
 417
 418 # FP_PROG_AR
 419 # ----------
 420 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 421 # version of it. Exits if no ar can be found
 422 AC_DEFUN([FP_PROG_AR],
 423 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 424 if test -z "$fp_prog_ar_raw"; then
 425   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 426 fi
 427 fp_prog_ar=$fp_prog_ar_raw
 428 case $HostPlatform in
 429   *mingw32) if test x${OSTYPE} != xmsys; then
 430               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 431               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 432             fi
 433             ;;
 434 esac
 435 ])# FP_PROG_AR
 436
 437
 438 # FP_PROG_AR_IS_GNU
 439 # -----------------
 440 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 441 AC_DEFUN([FP_PROG_AR_IS_GNU],
 442 [AC_REQUIRE([FP_PROG_AR])
 443 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 444 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 445   fp_cv_prog_ar_is_gnu=yes
 446 else
 447   fp_cv_prog_ar_is_gnu=no
 448 fi])
 449 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 450 ])# FP_PROG_AR_IS_GNU
 451
 452
 453 # FP_PROG_AR_ARGS
 454 # ---------------
 455 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 456 # to a non-Cygwin invocation of ar including these arguments.
 457 AC_DEFUN([FP_PROG_AR_ARGS],
 458 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 459 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 460 [
 461 # GNU ar needs special treatment: it appears to have problems with
 462 # object files with the same name if you use the 's' modifier, but
 463 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 464 if test $fp_prog_ar_is_gnu = yes; then
 465   fp_cv_prog_ar_args="q"
 466 else
 467   touch conftest.dummy
 468   for fp_var in clqsZ clqs cqs clq cq ; do
 469      rm -f conftest.a
 470      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 471         fp_cv_prog_ar_args=$fp_var
 472         break
 473      fi
 474   done
 475   rm -f conftest*
 476   if test -z "$fp_cv_prog_ar_args"; then
 477     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 478   fi
 479 fi])
 480 fp_prog_ar_args=$fp_cv_prog_ar_args
 481 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 482
 483 ])# FP_PROG_AR_ARGS
 484
 485
 486 # FP_PROG_AR_NEEDS_RANLIB
 487 # -----------------------
 488 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 489 # to ":" otherwise.
 490 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 491 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 492 AC_REQUIRE([FP_PROG_AR_ARGS])
 493 AC_REQUIRE([AC_PROG_CC])
 494 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 495 [if test $fp_prog_ar_is_gnu = yes; then
 496   fp_cv_prog_ar_needs_ranlib=no
 497 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
 498   # It's quite tedious to check for Apple's crazy timestamps in .a files,
 499   # so we hardcode it.
 500   fp_cv_prog_ar_needs_ranlib=yes
 501 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 502   fp_cv_prog_ar_needs_ranlib=no
 503 else
 504   fp_cv_prog_ar_needs_ranlib=yes
 505 fi])
 506 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 507    AC_PROG_RANLIB
 508 else
 509   RANLIB=":"
 510   AC_SUBST([RANLIB])
 511 fi
 512 ])# FP_PROG_AR_NEEDS_RANLIB
 513
 514
 515 # FP_PROG_AR_SUPPORTS_INPUT
 516 # -------------------------
 517 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 518 # whether ar supports -input flag is supported or not.
 519 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 520 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 521 AC_REQUIRE([FP_PROG_AR_ARGS])
 522 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 523 [fp_cv_prog_ar_supports_input=no
 524 if test $fp_prog_ar_is_gnu = no; then
 525   rm -f conftest*
 526   touch conftest.lst
 527   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 528     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 529   fi
 530   rm -f conftest*
 531 fi])
 532 if test $fp_cv_prog_ar_supports_input = yes; then
 533     ArSupportsInput="-input"
 534 else
 535     ArSupportsInput=""
 536 fi
 537 AC_SUBST([ArSupportsInput])
 538 ])# FP_PROG_AR_SUPPORTS_INPUT
 539
 540
 541 dnl
 542 dnl AC_SHEBANG_PERL - can we she-bang perl?
 543 dnl
 544 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
 545 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 546 [echo "#!$PerlCmd"'
 547 exit $1;
 548 ' > conftest
 549 chmod u+x conftest
 550 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 551 if test $? -ne 69; then
 552    fptools_cv_shebang_perl=yes
 553 else
 554    fptools_cv_shebang_perl=no
 555 fi
 556 rm -f conftest
 557 ])])
 558
 559
 560 # FP_HAVE_GCC
 561 # -----------
 562 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 563 # output variables HaveGcc and GccVersion.
 564 AC_DEFUN([FP_HAVE_GCC],
 565 [AC_REQUIRE([AC_PROG_CC])
 566 if test -z "$GCC"; then
 567    fp_have_gcc=NO
 568 else
 569    fp_have_gcc=YES
 570 fi
 571 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
 572   AC_MSG_ERROR([gcc is required])
 573 fi
 574 AC_CACHE_CHECK([version of gcc], [fp_gcc_version],
 575 [if test "$fp_have_gcc" = "YES"; then
 576    fp_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
 577    FP_COMPARE_VERSIONS([$fp_gcc_version], [-lt], [2.0],
 578      [AC_MSG_ERROR([Need at least gcc version 2.0 (3.4+ recommended)])])
 579  else
 580    fp_gcc_version="not-installed"
 581  fi
 582 ])
 583 AC_SUBST([HaveGcc], [$fp_have_gcc])
 584 AC_SUBST([GccVersion], [$fp_gcc_version])
 585 ])# FP_HAVE_GCC
 586
 587 AC_DEFUN([FP_MINGW_GCC],
 588 [
 589   case $HostOS_CPP in
 590     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
 591              if $CC -v 2>&1 | grep mingw >/dev/null; then
 592                 AC_MSG_RESULT([yes])
 593              else
 594                 AC_MSG_RESULT([no])
 595                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
 596              fi;;
 597     *) ;;
 598   esac
 599 ])
 600
 601 dnl Small feature test for perl version. Assumes PerlCmd
 602 dnl contains path to perl binary
 603 dnl
 604 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
 605 [$PerlCmd -v >conftest.out 2>&1
 606    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 607       :
 608    else
 609       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 610          :
 611       else
 612          if grep "version 6" conftest.out >/dev/null 2>&1; then
 613             :
 614          else
 615             AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
 616          fi
 617       fi
 618    fi
 619 rm -fr conftest*
 620 ])
 621
 622
 623 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 624 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 625 # -----------------------------------------------------
 626 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 627 # of PROG-TO-CHECK-FOR when found.
 628 AC_DEFUN([FP_CHECK_PROG],
 629 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 630 )# FP_CHECK_PROC
 631
 632
 633 # FP_PROG_FIND
 634 # ------------
 635 # Find a non-WinDoze version of the "find" utility.
 636 AC_DEFUN([FP_PROG_FIND],
 637 [AC_PATH_PROG([fp_prog_find], [find])
 638 echo foo > conftest.txt
 639 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 640 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 641   # OK, looks like a real "find".
 642   FindCmd="$fp_prog_find"
 643 else
 644   # Found a poor WinDoze version of "find", ignore it.
 645   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 646   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 647 fi
 648 rm -f conftest.txt conftest.out
 649 AC_SUBST([FindCmd])[]dnl
 650 ])# FP_PROG_FIND
 651
 652
 653 # FP_PROG_SORT
 654 # ------------
 655 # Find a Unix-like sort
 656 AC_DEFUN([FP_PROG_SORT],
 657 [AC_PATH_PROG([fp_prog_sort], [sort])
 658 echo conwip > conftest.txt
 659 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
 660 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
 661   # The goods
 662   SortCmd="$fp_prog_sort"
 663 else
 664   # Summink else..pick next one.
 665   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
 666   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
 667 fi
 668 rm -f conftest.txt conftest.out
 669 AC_SUBST([SortCmd])[]dnl
 670 ])# FP_PROG_SORT
 671
 672 dnl
 673 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 674 dnl values of the second argument to the result of running
 675 dnl the commands given by the third. It does not cache its
 676 dnl result, so it is suitable for checks which should be
 677 dnl run every time.
 678 dnl
 679 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
 680 [AC_MSG_CHECKING([$1])
 681  $3
 682  AC_MSG_RESULT([$][$2])
 683 ])
 684
 685 dnl
 686 dnl FPTOOLS_GHC_VERSION(version)
 687 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 688 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 689 dnl
 690 dnl Test for version of installed ghc.  Uses $GHC.
 691 dnl [original version pinched from c2hs]
 692 dnl
 693 AC_DEFUN([FPTOOLS_GHC_VERSION],
 694 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 695 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 696   cat conftestghc >&AS_MESSAGE_LOG_FD
 697 #Useless Use Of cat award...
 698   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 699   rm -fr conftest*
 700   if test "[$]fptools_version_of_ghc" = ""
 701   then
 702     fptools_version_of_ghc='unknown'
 703   fi
 704 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 705 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 706 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 707 #
 708 if test "[$]fptools_version_of_ghc[_pl]" = ""
 709 then
 710   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 711   fptools_version_of_ghc[_pl]="0"
 712 else
 713   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 714 fi
 715 #
 716 ifelse($#, [1], [dnl
 717 [$1]="[$]fptools_version_of_ghc[_all]"
 718 ], $#, [2], [dnl
 719 [$1]="[$]fptools_version_of_ghc[_major]"
 720 [$2]="[$]fptools_version_of_ghc[_minor]"
 721 ], $#, [3], [dnl
 722 [$1]="[$]fptools_version_of_ghc[_major]"
 723 [$2]="[$]fptools_version_of_ghc[_minor]"
 724 [$3]="[$]fptools_version_of_ghc[_pl]"
 725 ], $#, [4], [dnl
 726 [$1]="[$]fptools_version_of_ghc[_all]"
 727 [$2]="[$]fptools_version_of_ghc[_major]"
 728 [$3]="[$]fptools_version_of_ghc[_minor]"
 729 [$4]="[$]fptools_version_of_ghc[_pl]"
 730 ])
 731 ])
 732 ])dnl
 733
 734
 735 dnl ** Map an arithmetic C type to a Haskell type.
 736 dnl    Based on autconf's AC_CHECK_SIZEOF.
 737
 738 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
 739 AC_DEFUN([FPTOOLS_CHECK_HTYPE],
 740 [changequote(<<, >>)dnl
 741 dnl The name to #define.
 742 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
 743 dnl The cache variable name.
 744 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
 745 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
 746 changequote([, ])dnl
 747 AC_MSG_CHECKING(Haskell type for $1)
 748 AC_CACHE_VAL(AC_CV_NAME,
 749 [AC_CV_NAME_supported=yes
 750 fp_check_htype_save_cppflags="$CPPFLAGS"
 751 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 752 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdio.h>
 753 #include <stddef.h>
 754
 755 #if HAVE_SYS_TYPES_H
 756 # include <sys/types.h>
 757 #endif
 758
 759 #if HAVE_UNISTD_H
 760 # include <unistd.h>
 761 #endif
 762
 763 #if HAVE_SYS_STAT_H
 764 # include <sys/stat.h>
 765 #endif
 766
 767 #if HAVE_FCNTL_H
 768 # include <fcntl.h>
 769 #endif
 770
 771 #if HAVE_SIGNAL_H
 772 # include <signal.h>
 773 #endif
 774
 775 #if HAVE_TIME_H
 776 # include <time.h>
 777 #endif
 778
 779 #if HAVE_TERMIOS_H
 780 # include <termios.h>
 781 #endif
 782
 783 #if HAVE_STRING_H
 784 # include <string.h>
 785 #endif
 786
 787 #if HAVE_CTYPE_H
 788 # include <ctype.h>
 789 #endif
 790
 791 #if defined(HAVE_GL_GL_H)
 792 # include <GL/gl.h>
 793 #elif defined(HAVE_OPENGL_GL_H)
 794 # include <OpenGL/gl.h>
 795 #endif
 796
 797 #if defined(HAVE_AL_AL_H)
 798 # include <AL/al.h>
 799 #elif defined(HAVE_OPENAL_AL_H)
 800 # include <OpenAL/al.h>
 801 #endif
 802
 803 #if defined(HAVE_AL_ALC_H)
 804 # include <AL/alc.h>
 805 #elif defined(HAVE_OPENAL_ALC_H)
 806 # include <OpenAL/alc.h>
 807 #endif
 808
 809 #if HAVE_SYS_RESOURCE_H
 810 # include <sys/resource.h>
 811 #endif
 812
 813 typedef $1 testing;
 814
 815 main() {
 816   FILE *f=fopen("conftestval", "w");
 817   if (!f) exit(1);
 818   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
 819     fprintf(f, "%s%d\n",
 820            ((testing)(-1) < (testing)0) ? "Int" : "Word",
 821            sizeof(testing)*8);
 822   } else {
 823     fprintf(f,"%s\n",
 824            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
 825            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
 826   }
 827   fclose(f);
 828   exit(0);
 829 }]])],[AC_CV_NAME=`cat conftestval`],
 830 [ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], [AC_CV_NAME=$2])],
 831 [ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], [AC_CV_NAME=$3])])
 832 CPPFLAGS="$fp_check_htype_save_cppflags"]) dnl
 833 if test "$AC_CV_NAME_supported" = yes; then
 834   AC_MSG_RESULT($AC_CV_NAME)
 835   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
 836 else
 837   AC_MSG_RESULT([not supported])
 838 fi
 839 undefine([AC_TYPE_NAME])dnl
 840 undefine([AC_CV_NAME])dnl
 841 undefine([AC_CV_NAME_supported])dnl
 842 ])
 843
 844
 845 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 846 # ---------------------------------------------------------------------------------
 847 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 848 # additional flexibility of specifying the PROLOGUE and BODY.
 849 AC_DEFUN([FP_CHECK_FUNC],
 850 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 851 AC_CACHE_CHECK([for $1], fp_func,
 852 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 853                 [AS_VAR_SET(fp_func, yes)],
 854                 [AS_VAR_SET(fp_func, no)])])
 855 AS_IF([test AS_VAR_GET(fp_func) = yes],
 856       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 857                 [Define to 1 if you have the `]$1[' function.]) $4],
 858       [$5])dnl
 859 AS_VAR_POPDEF([fp_func])dnl
 860 ])# FP_CHECK_FUNC
 861
 862
 863 # FP_GEN_DOCBOOK_XML
 864 # ------------------
 865 # Generates a DocBook XML V4.2 document in conftest.xml.
 866 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 867 [rm -f conftest.xml
 868 cat > conftest.xml << EOF
 869 <?xml version="1.0" encoding="iso-8859-1"?>
 870 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 871    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 872 <book id="test">
 873   <title>A DocBook Test Document</title>
 874   <chapter id="id-one">
 875     <title>A Chapter Title</title>
 876     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 877   </chapter>
 878   <chapter id="id-two">
 879     <title>Another Chapter Title</title>
 880     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 881   </chapter>
 882 </book>
 883 EOF
 884 ]) # FP_GEN_DOCBOOK_XML
 885
 886
 887 # FP_PROG_XSLTPROC
 888 # ----------------
 889 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 890 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 891 AC_DEFUN([FP_PROG_XSLTPROC],
 892 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 893 if test -z "$XsltprocCmd"; then
 894   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 895 fi
 896 ])# FP_PROG_XSLTPROC
 897
 898
 899 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 900 # ----------------------------
 901 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 902 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 903 # will be empty if none could be found.
 904 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 905 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 906 if test -n "$XsltprocCmd"; then
 907   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 908   [FP_GEN_DOCBOOK_XML
 909   fp_cv_dir_docbook_xsl=no
 910   for fp_var in $1; do
 911      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 912         fp_cv_dir_docbook_xsl=$fp_var
 913         break
 914      fi
 915   done
 916   rm -rf conftest*])
 917 fi
 918 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 919   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 920   DIR_DOCBOOK_XSL=
 921 else
 922   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 923 fi
 924 AC_SUBST([DIR_DOCBOOK_XSL])
 925 ])# FP_DIR_DOCBOOK_XSL
 926
 927
 928 # FP_PROG_XMLLINT
 929 # ----------------
 930 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 931 # xmllint. XmllintCmd is empty if xmllint could not be found.
 932 AC_DEFUN([FP_PROG_XMLLINT],
 933 [AC_PATH_PROG([XmllintCmd], [xmllint])
 934 if test -z "$XmllintCmd"; then
 935   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 936 fi
 937 ])# FP_PROG_XMLLINT
 938
 939
 940 # FP_CHECK_DOCBOOK_DTD
 941 # --------------------
 942 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 943 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 944 if test -n "$XmllintCmd"; then
 945   AC_MSG_CHECKING([for DocBook DTD])
 946   FP_GEN_DOCBOOK_XML
 947   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 948     AC_MSG_RESULT([ok])
 949   else
 950     AC_MSG_RESULT([failed])
 951     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 952     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 953   fi
 954   rm -rf conftest*
 955 fi
 956 ])# FP_CHECK_DOCBOOK_DTD
 957
 958
 959 # FP_GEN_FO
 960 # ------------------
 961 # Generates a formatting objects document in conftest.fo.
 962 AC_DEFUN([FP_GEN_FO],
 963 [rm -f conftest.fo
 964 cat > conftest.fo << EOF
 965 <?xml version="1.0"?>
 966 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 967   <fo:layout-master-set>
 968     <fo:simple-page-master master-name="blank">
 969       <fo:region-body/>
 970     </fo:simple-page-master>
 971   </fo:layout-master-set>
 972   <fo:page-sequence master-reference="blank">
 973     <fo:flow flow-name="xsl-region-body">
 974       <fo:block>
 975         Test!
 976       </fo:block>
 977     </fo:flow>
 978   </fo:page-sequence>
 979 </fo:root>
 980 EOF
 981 ]) # FP_GEN_FO
 982
 983
 984 # FP_PROG_FOP
 985 # -----------
 986 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 987 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 988 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 989 AC_DEFUN([FP_PROG_FOP],
 990 [AC_PATH_PROGS([FopCmd1], [fop])
 991 if test -n "$FopCmd1"; then
 992   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 993     [FP_GEN_FO
 994     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 995       fp_cv_fop_usability=yes
 996     else
 997       fp_cv_fop_usability=no
 998     fi
 999     rm -rf conftest*])
1000   if test x"$fp_cv_fop_usability" = xyes; then
1001      FopCmd=$FopCmd1
1002   fi
1003 fi
1004 if test -z "$FopCmd"; then
1005   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
1006   FopCmd=$FopCmd2
1007 fi
1008 AC_SUBST([FopCmd])
1009 ])# FP_PROG_FOP
1010
1011
1012 # FP_PROG_FO_PROCESSOR
1013 # --------------------
1014 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
1015 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
1016 # PdfxmltexCmd.
1017 AC_DEFUN([FP_PROG_FO_PROCESSOR],
1018 [AC_REQUIRE([FP_PROG_FOP])
1019 AC_PATH_PROG([XmltexCmd], [xmltex])
1020 AC_PATH_PROG([DvipsCmd], [dvips])
1021 if test -z "$FopCmd"; then
1022   if test -z "$XmltexCmd"; then
1023     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
1024   else
1025     if test -z "$DvipsCmd"; then
1026       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
1027     fi
1028   fi
1029   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
1030   if test -z "$PdfxmltexCmd"; then
1031     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
1032   fi
1033 elif test -z "$XmltexCmd"; then
1034   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
1035 fi
1036 ])# FP_PROG_FO_PROCESSOR
1037
1038
1039 # FP_PROG_GHC_PKG
1040 # ----------------
1041 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
1042 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
1043 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
1044 AC_DEFUN([FP_PROG_GHC_PKG],
1045 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
1046 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
1047 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
1048   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
1049 else
1050   fp_cv_matching_ghc_pkg=no
1051 fi])
1052 if test x"$fp_cv_matching_ghc_pkg" = xno; then
1053   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
1054 else
1055   GhcPkgCmd=$fp_cv_matching_ghc_pkg
1056 fi])# FP_PROG_GHC_PKG
1057
1058 # LocalWords:  fi