aclocal.m4

   1 dnl $Id: aclocal.m4,v 1.121 2003/07/30 09:21:12 wolfgang Exp $
   2 dnl
   3 dnl Extra autoconf macros for the Glasgow fptools
   4 dnl
   5 dnl To be a good autoconf citizen, names of local macros have
   6 dnl prefixed with FPTOOLS_ to ensure we don't clash
   7 dnl with any pre-supplied autoconf ones.
   8
   9 dnl
  10 dnl Is timezone around? (in a header file)
  11 dnl
  12 AC_DEFUN(FPTOOLS_HAVE_TIMEZONE,
  13 [AC_CACHE_CHECK([timezone], fptools_cv_have_timezone,
  14 [AC_TRY_COMPILE([#if TIME_WITH_SYS_TIME
  15 # include <sys/time.h>
  16 # include <time.h>
  17 #else
  18 # if HAVE_SYS_TIME_H
  19 #  include <sys/time.h>
  20 # else
  21 #  include <time.h>
  22 # endif
  23 #endif
  24 ], [return timezone;],
  25 fptools_cv_have_timezone=yes, fptools_cv_have_timezone=no)])
  26 if test "$fptools_cv_have_timezone" = yes; then
  27   AC_DEFINE(HAVE_TIMEZONE)
  28 fi
  29 ])
  30
  31 dnl
  32 dnl Has timezone the type time_t or long (HP-UX 10.20 apparently
  33 dnl has `long'..)
  34 dnl
  35 AC_DEFUN(FPTOOLS_TYPE_TIMEZONE,
  36 [AC_CACHE_CHECK([type of timezone], fptools_cv_type_timezone,
  37 [AC_TRY_COMPILE([#if TIME_WITH_SYS_TIME
  38 # include <sys/time.h>
  39 # include <time.h>
  40 #else
  41 # if HAVE_SYS_TIME_H
  42 #  include <sys/time.h>
  43 # else
  44 #  include <time.h>
  45 # endif
  46 #endif
  47
  48 extern time_t timezone;
  49 ],
  50 [int i;], fptools_cv_type_timezone=time_t, fptools_cv_type_timezone=long)])
  51 AC_DEFINE_UNQUOTED(TYPE_TIMEZONE, $fptools_cv_type_timezone)
  52 ])
  53
  54 dnl *** Is altzone available? ***
  55 dnl
  56 AC_DEFUN(FPTOOLS_ALTZONE,
  57 [AC_CACHE_CHECK([altzone], fptools_cv_altzone,
  58 [AC_TRY_LINK([#if TIME_WITH_SYS_TIME
  59 # include <sys/time.h>
  60 # include <time.h>
  61 #else
  62 # if HAVE_SYS_TIME_H
  63 #  include <sys/time.h>
  64 # else
  65 #  include <time.h>
  66 # endif
  67 #endif
  68 ], [return altzone;],
  69 fptools_cv_altzone=yes, fptools_cv_altzone=no)])
  70 if test "$fptools_cv_altzone" = yes; then
  71   AC_DEFINE(HAVE_ALTZONE)
  72 fi
  73 ])
  74
  75
  76 dnl *** Does libc contain GNU regex? ***
  77 dnl
  78 AC_DEFUN(FPTOOLS_REGEX_IN_LIBC,
  79 [AC_CACHE_CHECK([for GNU regex in libc], fptools_cv_have_regex,
  80 [AC_TRY_LINK([#if HAVE_UNISTD_H
  81 #include <unistd.h>
  82 #endif
  83 #include <regex.h>
  84 ],[ struct re_pattern_buffer patbuf;
  85     re_compile_pattern("",0,&patbuf);
  86     re_search_2 (&patbuf, "", 0, "",0, 0,0,0,0); ],
  87 fptools_cv_have_regex=yes, fptools_cv_have_regex=no)])
  88 if test "$fptools_cv_have_regex" = yes; then
  89         HaveGNURegex=YES
  90 else
  91         HaveGNURegex=NO
  92 fi
  93 AC_SUBST(HaveGNURegex)
  94 ])
  95
  96
  97 dnl ** check for leading underscores in symbol names
  98 dnl
  99 dnl Test for determining whether symbol names have a leading
 100 dnl underscore.
 101 dnl
 102 dnl We assume that they _haven't_ if anything goes wrong.
 103 dnl
 104 dnl Some nlist implementations seem to try to be compatible by ignoring
 105 dnl a leading underscore sometimes (eg. FreeBSD).  We therefore have
 106 dnl to work around this by checking for *no* leading underscore first.
 107 dnl Sigh.  --SDM
 108 dnl
 109 AC_DEFUN(FPTOOLS_UNDERSCORE,
 110 [AC_CHECK_LIB(elf, nlist, LIBS="-lelf $LIBS")dnl
 111 AC_CACHE_CHECK([leading underscore in symbol names], fptools_cv_lead_uscore,
 112
 113 dnl
 114 dnl Hack!: nlist() under Digital UNIX insist on there being an _,
 115 dnl but symbol table listings shows none. What is going on here?!?
 116 dnl
 117 dnl Another hack: cygwin doesn't come with nlist.h , so we hardwire
 118 dnl the underscoredness of that "platform"
 119 changequote(<<, >>)dnl
 120 <<
 121 case $HostPlatform in
 122 alpha-dec-osf*) fptools_cv_lead_uscore='no';;
 123 *cygwin32) fptools_cv_lead_uscore='yes';;
 124 *mingw32) fptools_cv_lead_uscore='yes';;
 125 *) >>
 126 changequote([, ])dnl
 127 AC_TRY_RUN([#ifdef HAVE_NLIST_H
 128 #include <nlist.h>
 129 changequote(<<, >>)dnl
 130 <<
 131 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 132 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 133 #endif
 134
 135 main(argc, argv)
 136 int argc;
 137 char **argv;
 138 {
 139 #ifdef HAVE_NLIST_H
 140     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 141         exit(1);
 142     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 143         exit(0);>>
 144 changequote([, ])dnl
 145 #endif
 146     exit(1);
 147 }], fptools_cv_lead_uscore=yes, fptools_cv_lead_uscore=no, fptools_cv_lead_uscore=NO)
 148 ;;
 149 esac);
 150 LeadingUnderscore=`echo $fptools_cv_lead_uscore | sed 'y/yesno/YESNO/'`
 151 AC_SUBST(LeadingUnderscore)
 152 case $LeadingUnderscore in
 153 YES) AC_DEFINE(LEADING_UNDERSCORE);;
 154 esac
 155 ])
 156
 157 dnl
 158 dnl FPTOOLS_PROG_CHECK_VERSION(VERSIONSTR1, TEST, VERSIONSTR2,
 159 dnl                            ACTION-IF-TRUE [, ACTION-IF-FALSE])
 160 dnl
 161 dnl compare versions field-wise (separator is '.')
 162 dnl TEST is one of {-lt,-le,-eq,-ge,-gt}
 163 dnl
 164 dnl quite shell-independant and SUSv2 compliant code
 165 dnl
 166 dnl NOTE: the loop could be unrolled within autoconf, but the
 167 dnl       macro code would be a) longer and b) harder to debug... ;)
 168 dnl
 169 AC_DEFUN(FPTOOLS_PROG_CHECK_VERSION,
 170 [if ( IFS=".";
 171       a="[$1]";  b="[$3]";
 172       while test -n "$a$b"
 173       do
 174               set -- [$]a;  h1="[$]1";  shift 2>/dev/null;  a="[$]*"
 175               set -- [$]b;  h2="[$]1";  shift 2>/dev/null;  b="[$]*"
 176               test -n "[$]h1" || h1=0;  test -n "[$]h2" || h2=0
 177               test [$]{h1} -eq [$]{h2} || break
 178       done
 179       test [$]{h1} [$2] [$]{h2}
 180     )
 181 then ifelse([$4],,[:],[
 182   $4])
 183 ifelse([$5],,,
 184 [else
 185   $5])
 186 fi
 187 ])])dnl
 188
 189
 190 dnl
 191 dnl Check for Greencard and version.
 192 dnl
 193 AC_DEFUN(FPTOOLS_GREENCARD,
 194 [
 195 AC_PATH_PROG(GreencardCmd,greencard)
 196 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 197 changequote(, )dnl
 198 [if test x"$GreencardCmd" != x; then
 199    fptools_cv_greencard_version="`$GreencardCmd --version |
 200                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 201 else
 202    fptools_cv_greencard_version=""
 203 fi
 204 changequote([, ])dnl
 205 ])
 206 FPTOOLS_PROG_CHECK_VERSION([$fptools_cv_greencard_version],-lt,$1,
 207   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])dnl
 208 GreencardVersion=$fptools_cv_greencard_version
 209 AC_SUBST(GreencardVersion)
 210 ])
 211
 212 dnl
 213 dnl Check for Happy and version.  If we're building GHC, then we need
 214 dnl at least Happy version 1.13.  If there's no installed Happy, we look
 215 dnl for a happy source tree and point the build system at that instead.
 216 dnl
 217 AC_DEFUN(FPTOOLS_HAPPY,
 218 [
 219 if test -d $srcdir/happy; then
 220    SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
 221 fi
 222 if test x"$UseSrcTreeHappy" = xYES; then
 223   HappyCmd=$SrcTreeHappyCmd
 224 else
 225   AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
 226 fi
 227 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 228 changequote(, )dnl
 229 [if test x"$HappyCmd" = x"$SrcTreeHappyCmd"; then
 230    fptools_cv_happy_version=`grep '^ProjectVersion[     ]*=' $srcdir/happy/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 231 elif test x"$HappyCmd" != x; then
 232    fptools_cv_happy_version="`$HappyCmd -v |
 233                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 234 else
 235    fptools_cv_happy_version="";
 236 fi;
 237 changequote([, ])dnl
 238 ])
 239 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
 240   FPTOOLS_PROG_CHECK_VERSION([$fptools_cv_happy_version],-lt,[1.13],
 241   [AC_MSG_ERROR([Happy version 1.13 or later is required to compile GHC.])])dnl
 242 fi
 243 HappyVersion=$fptools_cv_happy_version;
 244 AC_SUBST(HappyVersion)
 245 ])
 246
 247 dnl
 248 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 249 dnl for a haddock source tree and point the build system at that instead.
 250 dnl
 251 AC_DEFUN(FPTOOLS_HADDOCK,
 252 [
 253 if test -d $srcdir/haddock; then
 254    SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
 255 fi
 256 if test x"$UseSrcTreeHaddock" = xYES; then
 257   HaddockCmd=$SrcTreeHaddockCmd
 258 else
 259   AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
 260 fi
 261 dnl Darn, I forgot to make Haddock print out its version number when
 262 dnl invoked with -v.  We could try generating some HTML and grepping
 263 dnl through that to find the version number, but I think we'll make
 264 dnl do without it for now.
 265 ])
 266
 267 dnl
 268 dnl What's the best way of doing context diffs?
 269 dnl
 270 dnl (NB: NeXTStep thinks diff'ing a file against itself is "trouble")
 271 dnl
 272 AC_DEFUN(FPTOOLS_PROG_DIFF,
 273 [AC_CACHE_CHECK([for ok way to do context diffs], fptools_cv_context_diffs,
 274 [echo foo > conftest1
 275 echo foo > conftest2
 276 if diff -C 1 conftest1 conftest2 > /dev/null 2>&1 ; then
 277     fptools_cv_context_diffs='diff -C 1'
 278 else
 279     if diff -c1 conftest1 conftest2 > /dev/null 2>&1 ; then
 280         fptools_cv_context_diffs='diff -c1'
 281     else
 282         echo "Can't figure out how to do context diffs."
 283         echo "Neither \`diff -C 1' nor \`diff -c1' works."
 284         exit 1
 285     fi
 286 fi
 287 rm -f conftest1 conftest2
 288 ])
 289 ContextDiffCmd=$fptools_cv_context_diffs
 290 AC_SUBST(ContextDiffCmd)
 291 ])
 292
 293 dnl
 294 dnl Check whether ld supports -x
 295 dnl
 296 AC_DEFUN(FPTOOLS_LD_X,
 297 [AC_CACHE_CHECK([whether ld understands -x], fptools_cv_ld_x,
 298 [
 299 echo 'foo() {}' > conftest.c
 300 ${CC-cc} -c conftest.c
 301 if ${LdCmd} -r -x -o foo.o conftest.o; then
 302    fptools_cv_ld_x=yes
 303 else
 304    fptools_cv_ld_x=no
 305 fi
 306 rm -rf conftest.c conftest.o foo.o
 307 ])
 308 if test "$fptools_cv_ld_x" = yes; then
 309         LdXFlag=-x
 310 else
 311         LdXFlag=
 312 fi
 313 AC_SUBST(LdXFlag)
 314 ])
 315
 316 dnl
 317 dnl Finding the Right Yacc
 318 dnl
 319 AC_DEFUN(FPTOOLS_PROG_YACCY,
 320 [AC_PROG_YACC
 321 if test "$YACC" = "yacc"; then
 322    AC_CACHE_CHECK([if it is an OK yacc], ac_cv_prog_yacc,
 323    [AC_CHECK_PROG(WhatCmd, what, what, :)
 324     $WhatCmd $YACC > conftest.out
 325     if egrep 'y1\.c 1\..*SMI' conftest.out >/dev/null 2>&1; then
 326         echo "I don't trust your $YaccCmd; it looks like an old Sun yacc"
 327         if test -f /usr/lang/yacc; then
 328            echo "I'm going to use /usr/lang/yacc instead"
 329            ac_cv_prog_yacc=/usr/lang/yacc
 330         else
 331            echo "I'm assuming the worst...no parser generator at all"
 332            ac_cv_prog_yacc=:
 333         fi
 334     elif egrep 'y1\.c.*Revision: 4\.2\.6\.3.*DEC' conftest.out >/dev/null 2>&1; then
 335         echo "I don't trust your $YaccCmd; it looks like a lame DEC yacc"
 336         echo "I'm assuming the worst...no parser generator at all"
 337         ac_cv_prog_yacc=:
 338     else
 339         ac_cv_prog_yacc=$YACC
 340     fi
 341     rm -fr conftest*
 342 ])
 343 else
 344     ac_cv_prog_yacc=$YACC
 345 fi
 346 YaccCmd=$ac_cv_prog_yacc
 347 AC_SUBST(YaccCmd)
 348 ])
 349
 350 dnl *** Checking for ar and its arguments + whether we need ranlib.
 351 dnl
 352 dnl ArCmd, ArSupportsInput and RANLIB are AC_SUBST'ed
 353 dnl On Digital UNIX, we test for the -Z (compress) and
 354 dnl -input (take list of files from external file) flags.
 355 dnl
 356 AC_DEFUN(FPTOOLS_PROG_AR_AND_RANLIB,
 357 [AC_PATH_PROG(ArCmdRaw,ar)
 358 if test -z "$ArCmdRaw"; then
 359     echo "You don't seem to have ar in your PATH...I have no idea how to make a library"
 360     exit 1;
 361 fi
 362 dnl GNU ar needs special treatment: it appears to have problems with
 363 dnl object files with the same name if you use the 's' modifier, but
 364 dnl simple 'ar q' works fine, and doesn't need a separate ranlib.
 365 if $ArCmdRaw --version | grep 'GNU' >/dev/null 2>/dev/null; then
 366     ArCmdArgs='q'
 367     NeedRanLib=''
 368 elif $ArCmdRaw clqsZ conftest.a >/dev/null 2>/dev/null; then
 369     ArCmdArgs="clqsZ"
 370     NeedRanLib=''
 371 elif $ArCmdRaw clqs conftest.a >/dev/null 2>/dev/null; then
 372     ArCmdArgs="clqs"
 373     NeedRanLib=''
 374 elif $ArCmdRaw cqs conftest.a >/dev/null 2>/dev/null; then
 375     ArCmdArgs="cqs"
 376     NeedRanLib=''
 377 elif $ArCmdRaw clq conftest.a >/dev/null 2>/dev/null; then
 378     ArCmdArgs="clq"
 379     NeedRanLib='YES'
 380 elif $ArCmdRaw cq conftest.a >/dev/null 2>/dev/null; then
 381     ArCmdArgs="cq"
 382     NeedRanLib='YES'
 383 elif $ArCmdRaw cq conftest.a 2>&1 | grep 'no archive members specified' >/dev/null 2>/dev/null; then
 384     ArCmdArgs="cq"
 385     NeedRanLib='YES'
 386 else
 387     echo "I can't figure out how to use your $ArCmd"
 388     exit 1
 389 fi
 390 rm -rf conftest*
 391 case $HostPlatform in
 392  *mingw32)
 393           ArCmd="`cygpath -w ${ArCmdRaw} | sed -e 's@\\\\@/@g' ` ${ArCmdArgs}"
 394           ;;
 395  *) ArCmd="${ArCmdRaw} ${ArCmdArgs}"
 396     ;;
 397 esac
 398 test -n "$ArCmd" && test -n "$verbose" && echo "        setting ArCmd to $ArCmd"
 399 AC_SUBST(ArCmd)
 400 if $ArCmd conftest.a -input /dev/null >/dev/null 2>/dev/null; then
 401     ArSupportsInput='-input'
 402 else
 403     ArSupportsInput=''
 404 fi
 405 rm -rf conftest*
 406 test -n "$ArSupportsInput" && test -n "$verbose" && echo "        setting ArSupportsInput to $ArSupportsInput"
 407 AC_SUBST(ArSupportsInput)
 408 if test -z "$NeedRanLib"; then
 409     RANLIB=':'
 410     test -n "$verbose" && echo "        setting RANLIB to $RANLIB"
 411     AC_SUBST(RANLIB)
 412 else
 413     AC_PROG_RANLIB
 414 fi
 415 ])
 416
 417 dnl
 418 dnl AC_SHEBANG_PERL - can we she-bang perl?
 419 dnl
 420 AC_DEFUN(FPTOOLS_SHEBANG_PERL,
 421 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 422 [echo "#!$PerlCmd"'
 423 exit $1;
 424 ' > conftest
 425 chmod u+x conftest
 426 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 427 if test $? -ne 69; then
 428    fptools_cv_shebang_perl=yes
 429 else
 430    fptools_cv_shebang_perl=no
 431 fi
 432 rm -f conftest
 433 ])])
 434
 435 dnl
 436 dnl Extra testing of the result AC_PROG_CC, testing the gcc version no.
 437 dnl *Must* be called after AC_PROG_CC
 438 dnl
 439 AC_DEFUN(FPTOOLS_HAVE_GCC,
 440 [AC_CACHE_CHECK([whether you have an ok gcc], fptools_cv_have_gcc,
 441 [if test -z "$GCC"; then
 442     echo ''
 443     echo "You would be better off with gcc"
 444     echo "Perhaps it is already installed, but not in your PATH?"
 445     fptools_cv_have_gcc='no'
 446 else
 447 changequote(, )dnl
 448     gcc_version_str="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [^0-9]*\([0-9][0-9]*\)\.\([0-9][0-9]*\).*/\1\.\2/g' `"
 449 changequote([, ])dnl
 450     fptools_cv_have_gcc='yes'
 451     FPTOOLS_PROG_CHECK_VERSION($gcc_version_str, -lt, "2.0",
 452         fptools_cv_have_gcc='no'
 453         echo ""
 454         echo "your gcc version appears to be ..."
 455         $CC --version
 456         echo "gcc prior to 2.0 and have never worked with ghc."
 457         echo "we recommend 2.95.3, although versions back to 2.7.2 should be ok."
 458         AC_MSG_ERROR([gcc 1.X has never been supported])
 459     )
 460 fi
 461 ])
 462 HaveGcc=`echo $fptools_cv_have_gcc | sed 'y/yesno/YESNO/'`
 463 AC_SUBST(HaveGcc)
 464 ])
 465
 466 dnl
 467 dnl Some OSs (Mandrake Linux, in particular) configure GCC with
 468 dnl -momit-leaf-frame-pointer on by default.  If this is the case, we
 469 dnl need to turn it off for mangling to work.  The test is currently a bit
 470 dnl crude, using only the version number of gcc.
 471 dnl
 472 AC_DEFUN(FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR,
 473 [AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], fptools_cv_gcc_needs_no_omit_lfptr,
 474 [
 475  fptools_cv_gcc_needs_no_omit_lfptr='no'
 476  FPTOOLS_PROG_CHECK_VERSION($gcc_version_str, -ge, "3.2",
 477      fptools_cv_gcc_needs_no_omit_lfptr='yes')
 478 ])
 479 if test "$fptools_cv_gcc_needs_no_omit_lfptr" = "yes"; then
 480    AC_DEFINE(HAVE_GCC_MNO_OMIT_LFPTR)
 481 fi
 482 ])
 483
 484 dnl Small feature test for perl version. Assumes PerlCmd
 485 dnl contains path to perl binary
 486 dnl
 487 AC_DEFUN(FPTOOLS_CHECK_PERL_VERSION,
 488 [$PerlCmd -v >conftest.out 2>&1
 489 if grep "version 5" conftest.out >/dev/null 2>&1; then
 490    :
 491 else
 492    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 493       :
 494    else
 495       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 496          :
 497       else
 498          if grep "version 6" conftest.out >/dev/null 2>&1; then
 499             :
 500          else
 501             echo "Your version of perl probably won't work."
 502          fi
 503       fi
 504    fi
 505 fi
 506 rm -fr conftest*
 507 ])
 508
 509 dnl
 510 dnl Getting at the right version of 'find'
 511 dnl (i.e., not the MS util on a Win32 box).
 512 dnl
 513 AC_DEFUN(FPTOOLS_FIND_FIND,
 514 [
 515 AC_PATH_PROG(Find2Cmd, find)
 516 $Find2Cmd --version > conftest.out 2>&1
 517 if grep "FIND: Parameter format" conftest.out >/dev/null 2>&1 ; then
 518    # Encountered MS' find utility, which is not what we're after.
 519    #
 520    # HACK - AC_CHECK_PROG is useful here in that does let you reject
 521    # an (absolute) entry in the path (Find2Cmd). It is not so useful
 522    # in that it doesn't let you (AFAIU) set VARIABLE equal to the
 523    # absolute path eventually found. So, hack around this by inspecting
 524    # what variables hold the abs. path & use them directly.
 525    AC_CHECK_PROG(FindCmd,find,`echo $ac_dir/$ac_word`,find,,$Find2Cmd)
 526 else
 527 FindCmd=$Find2Cmd
 528 AC_SUBST(FindCmd)
 529 fi
 530 ])
 531
 532 dnl
 533 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 534 dnl values of the second argument to the result of running
 535 dnl the commands given by the third. It does not cache its
 536 dnl result, so it is suitable for checks which should be
 537 dnl run every time.
 538 dnl
 539 AC_DEFUN(FPTOOLS_NOCACHE_CHECK,
 540 [AC_MSG_CHECKING([$1])
 541  $3
 542  AC_MSG_RESULT([$][$2])
 543 ])
 544
 545 dnl
 546 dnl FPTOOLS_GHC_VERSION(version)
 547 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 548 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 549 dnl
 550 dnl Test for version of installed ghc.  Uses $GHC.
 551 dnl [original version pinched from c2hs]
 552 dnl
 553 AC_DEFUN(FPTOOLS_GHC_VERSION,
 554 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 555 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 556   cat conftestghc >&AC_FD_CC
 557 #Useless Use Of cat award...
 558   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 559   rm -fr conftest*
 560   if test "[$]fptools_version_of_ghc" = ""
 561   then
 562     fptools_version_of_ghc='unknown'
 563   fi
 564 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 565 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 566 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 567 #
 568 if test "[$]fptools_version_of_ghc[_pl]" = ""
 569 then
 570   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 571   fptools_version_of_ghc[_pl]="0"
 572 else
 573   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 574 fi
 575 #
 576 ifelse($#, [1], [dnl
 577 [$1]="[$]fptools_version_of_ghc[_all]"
 578 ], $#, [2], [dnl
 579 [$1]="[$]fptools_version_of_ghc[_major]"
 580 [$2]="[$]fptools_version_of_ghc[_minor]"
 581 ], $#, [3], [dnl
 582 [$1]="[$]fptools_version_of_ghc[_major]"
 583 [$2]="[$]fptools_version_of_ghc[_minor]"
 584 [$3]="[$]fptools_version_of_ghc[_pl]"
 585 ], $#, [4], [dnl
 586 [$1]="[$]fptools_version_of_ghc[_all]"
 587 [$2]="[$]fptools_version_of_ghc[_major]"
 588 [$3]="[$]fptools_version_of_ghc[_minor]"
 589 [$4]="[$]fptools_version_of_ghc[_pl]"
 590 ])
 591 ])
 592 ])dnl
 593
 594
 595 dnl ** figure out the alignment restriction of a type
 596 dnl    (required SIZEOF test but AC_CHECK_SIZEOF doesn't call PROVIDE
 597 dnl     so we can't call REQUIRE)
 598
 599 dnl FPTOOLS_CHECK_ALIGNMENT(TYPE)
 600 AC_DEFUN(FPTOOLS_CHECK_ALIGNMENT,
 601 [changequote(<<, >>)dnl
 602 dnl The name to #define.
 603 define(<<AC_TYPE_NAME>>, translit(alignment_$1, [a-z *], [A-Z_P]))dnl
 604 dnl The cache variable name.
 605 define(<<AC_CV_NAME>>, translit(ac_cv_alignment_$1, [ *], [_p]))dnl
 606 dnl The name of the corresponding size.
 607 define(<<AC_CV_SIZEOF_NAME>>, translit(ac_cv_sizeof_$1, [ *], [_p]))dnl
 608 changequote([, ])dnl
 609 AC_MSG_CHECKING(alignment of $1)
 610 AC_CACHE_VAL(AC_CV_NAME,
 611 [AC_TRY_RUN([
 612 #include <stdio.h>
 613 #if HAVE_STDDEF_H
 614 #include <stddef.h>
 615 #endif
 616 #ifndef offsetof
 617 #define offsetof(ty,field) ((size_t)((char *)&((ty *)0)->field - (char *)(ty *)0))
 618 #endif
 619 int
 620 main()
 621 {
 622   FILE *f=fopen("conftestval", "w");
 623   if (!f) exit(1);
 624   fprintf(f, "%d", offsetof(struct { char c; $1 ty;},ty));
 625   exit(0);
 626 }],
 627 AC_CV_NAME=`cat conftestval`,
 628 AC_CV_NAME=$AC_CV_SIZEOF_NAME,
 629 AC_CV_NAME=$AC_CV_SIZEOF_NAME)])
 630 AC_MSG_RESULT($AC_CV_NAME)
 631 AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME)
 632 AC_PROVIDE($AC_TYPE_NAME)
 633 undefine([AC_TYPE_NAME])dnl
 634 undefine([AC_CV_NAME])dnl
 635 undefine([AC_CV_SIZEOF_NAME])dnl
 636 ])
 637
 638 dnl ** Map an arithmetic C type to a Haskell type.
 639 dnl    Based on autconf's AC_CHECK_SIZEOF.
 640
 641 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
 642 AC_DEFUN(FPTOOLS_CHECK_HTYPE,
 643 [changequote(<<, >>)dnl
 644 dnl The name to #define.
 645 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
 646 dnl The cache variable name.
 647 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
 648 changequote([, ])dnl
 649 AC_MSG_CHECKING(Haskell type for $1)
 650 AC_CACHE_VAL(AC_CV_NAME,
 651 [AC_TRY_RUN([#include <stdio.h>
 652 #include <stddef.h>
 653
 654 #ifdef HAVE_SYS_TYPES_H
 655 # include <sys/types.h>
 656 #endif
 657
 658 #ifdef HAVE_UNISTD_H
 659 # include <unistd.h>
 660 #endif
 661
 662 #ifdef HAVE_SYS_STAT_H
 663 # include <sys/stat.h>
 664 #endif
 665
 666 #ifdef HAVE_FCNTL_H
 667 # include <fcntl.h>
 668 #endif
 669
 670 #ifdef HAVE_SIGNAL_H
 671 # include <signal.h>
 672 #endif
 673
 674 #ifdef HAVE_TIME_H
 675 # include <time.h>
 676 #endif
 677
 678 #ifdef HAVE_TERMIOS_H
 679 # include <termios.h>
 680 #endif
 681
 682 #ifdef HAVE_STRING_H
 683 # include <string.h>
 684 #endif
 685
 686 #ifdef HAVE_CTYPE_H
 687 # include <ctype.h>
 688 #endif
 689
 690 #ifdef HAVE_GL_GL_H
 691 # include <GL/gl.h>
 692 #endif
 693
 694 #ifdef HAVE_OPENGL_GL_H
 695 # include <OpenGL/gl.h>
 696 #endif
 697
 698 #ifdef HAVE_SYS_RESOURCE_H
 699 # include <sys/resource.h>
 700 #endif
 701
 702 typedef $1 testing;
 703
 704 main() {
 705   FILE *f=fopen("conftestval", "w");
 706   if (!f) exit(1);
 707   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
 708     fprintf(f, "%s%d\n",
 709            ((testing)(-1) < (testing)0) ? "Int" : "Word",
 710            sizeof(testing)*8);
 711   } else {
 712     fprintf(f,"%s\n",
 713            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
 714            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
 715   }
 716   fclose(f);
 717   exit(0);
 718 }], AC_CV_NAME=`cat conftestval`,
 719 ifelse([$2], , AC_CV_NAME=NotReallyAType,      AC_CV_NAME=$2),
 720 ifelse([$3], , AC_CV_NAME=NotReallyATypeCross, AC_CV_NAME=$3))]) dnl
 721 AC_MSG_RESULT($AC_CV_NAME)
 722 AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME)
 723 undefine([AC_TYPE_NAME])dnl
 724 undefine([AC_CV_NAME])dnl
 725 ])
 726
 727 dnl ** figure out whether C compiler supports 'long long's
 728 dnl    (Closely based on Andreas Zeller's macro for testing
 729 dnl     for this under C++)
 730 dnl
 731 dnl    If the C compiler supports `long long' types,
 732 dnl    define `HAVE_LONG_LONG'.
 733 dnl
 734 AC_DEFUN(FPTOOLS_C_LONG_LONG,
 735 [
 736 AC_REQUIRE([AC_PROG_CC])
 737 AC_MSG_CHECKING(whether ${CC} supports long long types)
 738 AC_CACHE_VAL(fptools_cv_have_long_long,
 739 [
 740 AC_LANG_SAVE
 741 AC_LANG_C
 742 AC_TRY_COMPILE(,[long long a;],
 743 fptools_cv_have_long_long=yes,
 744 fptools_cv_have_long_long=no)
 745 AC_LANG_RESTORE
 746 ])
 747 AC_MSG_RESULT($fptools_cv_have_long_long)
 748 if test "$fptools_cv_have_long_long" = yes; then
 749 AC_DEFINE(HAVE_LONG_LONG)
 750 fi
 751 ])
 752
 753 dnl ** Obtain the value of a C constant.
 754 dnl    The value will be `(-1)' if the constant is undefined.
 755 dnl
 756 dnl    This is set up so that the argument can be a shell variable.
 757 dnl
 758 AC_DEFUN(FPTOOLS_CHECK_CCONST,
 759 [
 760 eval "cv_name=ac_cv_cconst_$1"
 761 AC_MSG_CHECKING(value of $1)
 762 AC_CACHE_VAL($cv_name,
 763 [AC_TRY_RUN([#include <stdio.h>
 764 #include <errno.h>
 765 main()
 766 {
 767   FILE *f=fopen("conftestval", "w");
 768   if (!f) exit(1);
 769   fprintf(f, "%d\n", $1);
 770   exit(0);
 771 }],
 772 eval "$cv_name=`cat conftestval`",
 773 eval "$cv_name=-1",
 774 eval "$cv_name=-1")])dnl
 775 eval "fptools_check_cconst_result=`echo '$'{$cv_name}`"
 776 AC_MSG_RESULT($fptools_check_cconst_result)
 777 AC_DEFINE_UNQUOTED(CCONST_$1, $fptools_check_cconst_result)
 778 unset fptools_check_cconst_result
 779 ])
 780
 781 dnl ** Invoke AC_CHECK_CCONST on each argument (which have to separate with
 782 dnl    spaces)
 783 dnl
 784 AC_DEFUN(FPTOOLS_CHECK_CCONSTS,
 785 [for ac_const_name in $1
 786 do
 787 FPTOOLS_CHECK_CCONST($ac_const_name)dnl
 788 done
 789 ])
 790
 791
 792 dnl *** Can we open files in binary mode? ***
 793 dnl
 794 AC_DEFUN(FPTOOLS_O_BINARY,
 795 [
 796 AC_REQUIRE([AC_PROG_CC])
 797 AC_MSG_CHECKING(whether we can open files in binary mode)
 798 AC_CACHE_VAL(fptools_cv_have_o_binary,
 799 [
 800 AC_LANG_SAVE
 801 AC_LANG_C
 802 AC_TRY_COMPILE(
 803 [#ifdef HAVE_FCNTL_H
 804 #include <fcntl.h>
 805 #endif],
 806 [int x = O_BINARY;],
 807 fptools_cv_have_o_binary=yes,
 808 fptools_cv_have_o_binary=no)
 809 AC_LANG_RESTORE
 810 ])
 811 AC_MSG_RESULT($fptools_cv_have_o_binary)
 812 if test "$fptools_cv_have_o_binary" = yes; then
 813 AC_DEFINE(HAVE_O_BINARY)
 814 fi
 815 ])
 816
 817 dnl *** Helper function **
 818 dnl
 819 AC_DEFUN(FPTOOLS_IN_SCOPE,
 820 [AC_TRY_LINK([extern char* $1;],[return (int)&$2], $3=yes, $3=no)
 821 ])
 822
 823
 824 dnl Based on AC_TRY_LINK - run iftrue if links cleanly with no warning
 825
 826 dnl FPTOOLS_TRY_LINK_NOWARN(flags,main?,iftrue,iffalse)
 827
 828 AC_DEFUN(FPTOOLS_TRY_LINK_NOWARN,
 829 [
 830 ac_save_LIBS="$LIBS"
 831 LIBS=[$1];
 832 cat > conftest.$ac_ext <<EOF
 833 dnl This sometimes fails to find confdefs.h, for some reason.
 834 dnl [#]line __oline__ "[$]0"
 835 [#]line __oline__ "configure"
 836 #include "confdefs.h"
 837 [$2]
 838 int t() { return 0; }
 839 EOF
 840 if AC_TRY_EVAL(ac_link); then
 841   ifelse([$3], , :, [
 842     LIBS="$ac_save_LIBS"
 843     rm -rf conftest*
 844     $3])
 845   ifelse([$4], , , [else
 846     LIBS="$ac_save_LIBS"
 847     rm -rf conftest*
 848     $4
 849 ])dnl
 850 fi
 851 rm -f conftest*
 852 ]
 853 )
 854
 855 dnl Loosely based on AC_CHECK_LIB in acgeneral.m4 in autoconf distribution
 856
 857 dnl FPTOOLS_CHECK_FLAG_NOWARN(NAME, FLAG, CODE, iftrue, iffalse)
 858
 859 AC_DEFUN(FPTOOLS_CHECK_FLAG_NOWARN,
 860 [AC_MSG_CHECKING([for $1])
 861  AC_CACHE_VAL(ac_cv_flag_$1,
 862    [FPTOOLS_TRY_LINK_NOWARN("$2", [main() { $3; exit(0); } ],
 863      eval "ac_cv_flag_$1=yes",
 864      eval "ac_cv_flag_$1=no"
 865    )]
 866  )
 867 if eval "test \"`echo '$ac_cv_flag_'$1`\" = yes"; then
 868   AC_MSG_RESULT(yes)
 869   LIBS="$2 $LIBS"
 870   $4
 871 else
 872   AC_MSG_RESULT(no)
 873   $5
 874 fi
 875 ])
 876
 877 dnl FPTOOLS_CHECK_LIB_NOWARN(LIBRARY, FUNCTION)
 878
 879 AC_DEFUN(FPTOOLS_CHECK_LIB_NOWARN,
 880 [FPTOOLS_CHECK_FLAG_NOWARN([function_$2],[],[extern char $2(); $2();],
 881 [changequote(, )dnl
 882   ac_tr_lib=HAVE_LIB`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 883  changequote([, ])dnl
 884  AC_DEFINE_UNQUOTED($ac_tr_lib)
 885 ],
 886 [FPTOOLS_CHECK_FLAG_NOWARN([library_$1],[-l$1],[extern char $2(); $2();],
 887 [changequote(, )dnl
 888   ac_tr_lib=HAVE_LIB`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 889  changequote([, ])dnl
 890  AC_DEFINE_UNQUOTED($ac_tr_lib)
 891 ],
 892 []
 893 )])]
 894 )
 895
 896 dnl check for prototypes
 897 dnl
 898 AC_DEFUN([AC_C_PROTOTYPES],
 899 [AC_CACHE_CHECK([prototypes], ac_cv_prototypes,
 900 [AC_TRY_COMPILE([
 901 void foo(int);
 902 void foo(i)
 903 int i; {
 904 return;
 905 }
 906 ],
 907 [int i;],
 908 ac_cv_prototypes=yes,
 909 ac_cv_prototypes=no)])
 910 if test "$ac_cv_prototypes" = yes; then
 911 AC_DEFINE([HAVE_PROTOTYPES])
 912 fi
 913 ])
 914
 915 dnl ** Check which CATALOG file we have to use with DocBook SGML.
 916 dnl
 917 dnl FPTOOLS_DOCBOOK_CATALOG(VARIABLE, JADE, STYLESHEET, CATALOGS-TO-CHECK-FOR)
 918 dnl
 919 dnl If any of the catalogs given in CATALOGS-TO-CHECK-FOR works on this
 920 dnl platform, let VARIABLE refer to this catalog; otherwise, VARIABLE
 921 dnl is set to "no".  JADE is the jade executable and STYLESHEET
 922 dnl a DocBook style sheet.
 923 dnl
 924 AC_DEFUN(FPTOOLS_DOCBOOK_CATALOG,
 925 [AC_CACHE_CHECK([for DocBook CATALOG], fptools_cv_sgml_catalog,
 926 [
 927 cat > conftest.sgml << EOF
 928 <!DOCTYPE Article PUBLIC "-//OASIS//DTD DocBook V3.1//EN">
 929 <Article>
 930 <ArtHeader>
 931 <Title>Test</Title>
 932 <Author><OtherName>Test</OtherName></Author>
 933 <Address>Test</Address>
 934 <PubDate>Test</PubDate>
 935 </ArtHeader>
 936 <Sect1><Title>Test</Title>
 937 <Para>
 938 Test.
 939 </Para>
 940 </Sect1>
 941 </Article>
 942 EOF
 943 fptools_cv_sgml_catalog=no
 944 if test -z "$SGML_CATALOG_FILES" ; then
 945  for fptools_catalog in $4; do
 946    ac_try="$2 -t rtf -d $3#print -c $fptools_catalog conftest.sgml"
 947    if AC_TRY_EVAL(ac_try); then
 948      fptools_cv_sgml_catalog=[$]fptools_catalog
 949      break
 950    fi
 951  done
 952 else
 953 # If the env var SGML_CATALOG_FILES is defined, assume things are cool.
 954   fptools_cv_sgml_catalog="yes"
 955 fi
 956 ])
 957 rm -rf conftest*
 958 if test $fptools_cv_sgml_catalog != "no"; then
 959   $1=$fptools_cv_sgml_catalog
 960 fi
 961 ])
 962
 963 dnl ######################################################################
 964 dnl FPTOOLS_SEARCH_LIBS(INCLUDES, FUNCTION, SEARCH-LIBS [, ACTION-IF-FOUND
 965 dnl                     [, ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
 966 dnl Search for a library defining FUNC, if it's not already available.
 967 dnl This is almost the same as AC_SEARCH_LIBS, but the INCLUDES can be
 968 dnl specified.
 969 dnl ######################################################################
 970
 971 AC_DEFUN(FPTOOLS_SEARCH_LIBS,
 972 [AC_PREREQ([2.13])
 973 AC_CACHE_CHECK([for library containing $2], [ac_cv_search_$2],
 974 [ac_func_search_save_LIBS="$LIBS"
 975 ac_cv_search_$2="no"
 976 AC_TRY_LINK([$1], [$2()], [ac_cv_search_$2="none required"])
 977 test "$ac_cv_search_$2" = "no" && for i in $3; do
 978 LIBS="-l$i $6 $ac_func_search_save_LIBS"
 979 AC_TRY_LINK([$1], [$2()],
 980 [ac_cv_search_$2="-l$i"
 981 break])
 982 done
 983 LIBS="$ac_func_search_save_LIBS"])
 984 if test "$ac_cv_search_$2" != "no"; then
 985   test "$ac_cv_search_$2" = "none required" || LIBS="$ac_cv_search_$2 $LIBS"
 986   $4
 987 else :
 988   $5
 989 fi])
 990
 991 dnl ####################### -*- Mode: M4 -*- ###########################
 992 dnl Copyright (C) 98, 1999 Matthew D. Langston <langston@SLAC.Stanford.EDU>
 993 dnl
 994 dnl This file is free software; you can redistribute it and/or modify it
 995 dnl under the terms of the GNU General Public License as published by
 996 dnl the Free Software Foundation; either version 2 of the License, or
 997 dnl (at your option) any later version.
 998 dnl
 999 dnl This file is distributed in the hope that it will be useful, but
1000 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
1001 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
1002 dnl General Public License for more details.
1003 dnl
1004 dnl You should have received a copy of the GNU General Public License
1005 dnl along with this file; if not, write to:
1006 dnl
1007 dnl   Free Software Foundation, Inc.
1008 dnl   Suite 330
1009 dnl   59 Temple Place
1010 dnl   Boston, MA 02111-1307, USA.
1011 dnl ####################################################################
1012
1013
1014 dnl @synopsis FPTOOLS_CHECK_LIBM
1015 dnl
1016 dnl Search for math library (typically -lm).
1017 dnl
1018 dnl The variable LIBM (which is not an output variable by default) is
1019 dnl set to a value which is suitable for use in a Makefile (for example,
1020 dnl in make's LOADLIBES macro) provided you AC_SUBST it first.
1021 dnl
1022 dnl @author Matthew D. Langston <langston@SLAC.Stanford.EDU>
1023
1024 # FPTOOLS_CHECK_LIBM - check for math library
1025 AC_DEFUN(FPTOOLS_CHECK_LIBM,
1026 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
1027 LIBM=
1028 case "$host" in
1029 *-*-beos*)
1030   # These system don't have libm
1031   ;;
1032 *-ncr-sysv4.3*)
1033   AC_CHECK_LIB(mw, _mwvalidcheckl, LIBM="-lmw")
1034   AC_CHECK_LIB(m, main, LIBM="$LIBM -lm")
1035   ;;
1036 *)
1037   AC_CHECK_LIB(m, main, LIBM="-lm")
1038   ;;
1039 esac
1040 ])
1041
1042 dnl ######################################################################
1043 dnl Note: Caching has been completely rewritten, but is still no perfect yet.
1044 dnl ######################################################################
1045
1046 dnl ########################### -*- Mode: M4 -*- #######################
1047 dnl Copyright (C) 98, 1999 Matthew D. Langston <langston@SLAC.Stanford.EDU>
1048 dnl
1049 dnl This file is free software; you can redistribute it and/or modify it
1050 dnl under the terms of the GNU General Public License as published by
1051 dnl the Free Software Foundation; either version 2 of the License, or
1052 dnl (at your option) any later version.
1053 dnl
1054 dnl This file is distributed in the hope that it will be useful, but
1055 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
1056 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
1057 dnl General Public License for more details.
1058 dnl
1059 dnl You should have received a copy of the GNU General Public License
1060 dnl along with this file; if not, write to:
1061 dnl
1062 dnl   Free Software Foundation, Inc.
1063 dnl   Suite 330
1064 dnl   59 Temple Place
1065 dnl   Boston, MA 02111-1307, USA.
1066 dnl ####################################################################
1067
1068 dnl @synopsis FPTOOLS_HAVE_OPENGL
1069 dnl
1070 dnl Search for OpenGL.  We search first for Mesa (a GPL'ed version of
1071 dnl OpenGL) before a vendor's version of OpenGL if we were specifically
1072 dnl asked to with `--with-Mesa=yes' or `--with-Mesa'.
1073 dnl
1074 dnl The four "standard" OpenGL libraries are searched for: "-lGL",
1075 dnl "-lGLU", "-lGLX" (or "-lMesaGL", "-lMesaGLU" as the case may be) and
1076 dnl "-lglut".
1077 dnl
1078 dnl All of the libraries that are found (since "-lglut" or "-lGLX" might
1079 dnl be missing) are added to the shell output variable "GL_LIBS", along
1080 dnl with any other libraries that are necessary to successfully link an
1081 dnl OpenGL application (e.g. the X11 libraries).  Care has been taken to
1082 dnl make sure that all of the libraries in "GL_LIBS" are listed in the
1083 dnl proper order.
1084 dnl
1085 dnl Additionally, the shell output variable "GL_CFLAGS" is set to any
1086 dnl flags (e.g. "-I" flags) that are necessary to successfully compile
1087 dnl an OpenGL application.
1088 dnl
1089 dnl The following shell variable (which are not output variables) are
1090 dnl also set to either "yes" or "no" (depending on which libraries were
1091 dnl found) to help you determine exactly what was found.
1092 dnl
1093 dnl   have_GL
1094 dnl   have_GLU
1095 dnl   have_GLX
1096 dnl   have_glut
1097 dnl
1098 dnl A complete little toy "Automake `make distcheck'" package of how to
1099 dnl use this macro is available at:
1100 dnl
1101 dnl   ftp://ftp.slac.stanford.edu/users/langston/autoconf/ac_opengl-0.01.tar.gz
1102 dnl
1103 dnl Please note that as the ac_opengl macro and the toy example evolves,
1104 dnl the version number increases, so you may have to adjust the above
1105 dnl URL accordingly.
1106 dnl
1107 dnl @author Matthew D. Langston <langston@SLAC.Stanford.EDU>
1108
1109 AC_DEFUN(FPTOOLS_HAVE_OPENGL,
1110 [
1111   AC_REQUIRE([AC_PROG_CC])
1112   AC_REQUIRE([AC_PATH_X])
1113   AC_REQUIRE([AC_PATH_XTRA])
1114   AC_REQUIRE([FPTOOLS_CHECK_LIBM])
1115
1116 dnl Check for Mesa first if we were asked to.
1117   AC_ARG_ENABLE(Mesa,
1118 [  --enable-mesa
1119         Prefer Mesa over a vendor's native OpenGL library (default=no)
1120 ],
1121                 use_Mesa=$enableval,
1122                 use_Mesa=no)
1123
1124   if test x"$use_Mesa" = xyes; then
1125      GL_search_list="MesaGL  GL  opengl32"
1126     GLU_search_list="MesaGLU GLU glu32"
1127     GLX_search_list="MesaGLX GLX"
1128   else
1129      GL_search_list="GL  opengl32 MesaGL"
1130     GLU_search_list="GLU glu32    MesaGLU"
1131     GLX_search_list="GLX          MesaGLX"
1132   fi
1133
1134   AC_LANG_SAVE
1135   AC_LANG_C
1136
1137 dnl If we are running under X11 then add in the appropriate libraries.
1138   if test x"$no_x" != xyes; then
1139 dnl Add everything we need to compile and link X programs to GL_CFLAGS
1140 dnl and GL_X_LIBS/GLUT_X_LIBS.
1141     GL_CFLAGS="$CPPFLAGS $X_CFLAGS"
1142     GL_X_LIBS="$X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS $LIBM"
1143     GLUT_X_LIBS="$X_LIBS $X_PRE_LIBS -lXmu -lXt -lXi -lXext -lX11 $X_EXTRA_LIBS $LIBM"
1144   fi
1145   GL_save_CPPFLAGS="$CPPFLAGS"
1146   CPPFLAGS="$GL_CFLAGS"
1147
1148   GL_save_LIBS="$LIBS"
1149   LIBS="$GL_X_LIBS"
1150
1151   FPTOOLS_SEARCH_LIBS([#include <GL/gl.h>],   glEnd,         $GL_search_list,  have_GL=yes,   have_GL=no)
1152   FPTOOLS_SEARCH_LIBS([#include <GL/glu.h>],  gluNewQuadric, $GLU_search_list, have_GLU=yes,  have_GLU=no)
1153   FPTOOLS_SEARCH_LIBS([#include <GL/glx.h>],  glXWaitX,      $GLX_search_list, have_GLX=yes,  have_GLX=no)
1154
1155   if test -n "$LIBS"; then
1156     GL_LIBS="$LDFLAGS $LIBS"
1157   else
1158     GL_LIBS="$LDFLAGS"
1159     GL_CFLAGS=
1160   fi
1161
1162   LIBS="$GLUT_X_LIBS"
1163
1164   FPTOOLS_SEARCH_LIBS([#include <GL/glut.h>], glutMainLoop,  glut32 glut,      have_glut=yes, have_glut=no)
1165
1166   if test -n "$LIBS"; then
1167     GLUT_LIBS="$LDFLAGS $LIBS"
1168   fi
1169
1170   AC_CACHE_CHECK([OpenGL flags], mdl_cv_gl_cflags, [mdl_cv_gl_cflags="$GL_CFLAGS"])
1171   GL_CFLAGS="$mdl_cv_gl_cflags"
1172   AC_SUBST(GL_CFLAGS)
1173   AC_CACHE_CHECK([OpenGL libs],  mdl_cv_gl_libs,   [mdl_cv_gl_libs="$GL_LIBS"])
1174   GL_LIBS="$mdl_cv_gl_libs"
1175   AC_SUBST(GL_LIBS)
1176   AC_CACHE_CHECK([GLUT libs],  mdl_cv_glut_libs,   [mdl_cv_glut_libs="$GLUT_LIBS"])
1177   GLUT_LIBS="$mdl_cv_glut_libs"
1178   AC_SUBST(GLUT_LIBS)
1179
1180 dnl Reset GL_X_LIBS/GLUT_X_LIBS regardless, since they were just temporary variables
1181 dnl and we don't want to be global namespace polluters.
1182   GL_X_LIBS=
1183   GLUT_X_LIBS=
1184
1185   LIBS="$GL_save_LIBS"
1186   CPPFLAGS="$GL_save_CPPFLAGS"
1187
1188   AC_LANG_RESTORE
1189 ])
1190
1191 # LocalWords:  fi
1192
1193 dnl
1194 dnl acspecific.m4's defn of AC_PROG_LEX is a bit too permissive, as it
1195 dnl defaults to 'lex' if 'flex' isn't found (without checking whether
1196 dnl 'lex' is actually present along the user's PATH).
1197 dnl
1198 AC_DEFUN(AC_PROG_LEX_STRICT,
1199 [AC_CHECK_PROG(LEX, flex, flex)
1200 if test -z "$LEX"
1201 then
1202   AC_CHECK_PROG(LEX,lex,lex)
1203   test -z "$LEX" && AC_MSG_ERROR(['lex' or 'flex' is required to compile GHC.])
1204 fi
1205 ])
1206
1207 dnl
1208 dnl Check to see whether CC (gcc) supports a particular option.
1209 dnl
1210 AC_DEFUN(FPTOOLS_CC_FLAG,
1211 [
1212 AC_CACHE_CHECK([whether $CC accepts $1], [ac_cv_cc_$2],
1213 [save_CFLAGS="$CFLAGS"
1214  CFLAGS="$CFLAGS $1"
1215  AC_LANG_C
1216  AC_TRY_COMPILE(,[int main(){return(0);}],
1217                  [ac_cv_cc_$2=yes],
1218                  [ac_cv_cc_$2=no])
1219  CFLAGS="$save_CFLAGS"
1220 ])
1221 if test "$ac_cv_cc_$2"x = "yesx"; then
1222   $2=$1;
1223 else
1224   $2="";
1225 fi;
1226 ])
1227
1228 dnl
1229 dnl Check to see whether 'struct msghdr' contains msg_control
1230 dnl
1231 AC_DEFUN(FPTOOLS_MSGHDR_MSG_CONTROL,
1232 [AC_CACHE_CHECK([for msg_control in struct msghdr], fptools_cv_struct_msghdr_msg_control,
1233 [AC_TRY_COMPILE([#include <sys/types.h>
1234 #include <sys/uio.h>
1235 #include <sys/socket.h>], [struct msghdr m; m.msg_control;],
1236 fptools_cv_struct_msghdr_msg_control=yes, fptools_cv_struct_msghdr_msg_control=no)])
1237 if test $fptools_cv_struct_msghdr_msg_control = yes; then
1238   AC_DEFINE(HAVE_MSGHDR_MSG_CONTROL)
1239 fi
1240 AC_SUBST(HAVE_MSGHDR_MSG_CONTROL)dnl
1241 ])
1242
1243 dnl
1244 dnl Check to see whether 'struct msghdr' contains msg_accrights
1245 dnl
1246 AC_DEFUN(FPTOOLS_MSGHDR_MSG_ACCRIGHTS,
1247 [AC_CACHE_CHECK([for msg_accrights in struct msghdr], fptools_cv_struct_msghdr_msg_accrights,
1248 [AC_TRY_COMPILE([#include <sys/types.h>
1249 #include <sys/uio.h>
1250 #include <sys/socket.h>], [struct msghdr m; m.msg_accrights;],
1251 fptools_cv_struct_msghdr_msg_accrights=yes, fptools_cv_struct_msghdr_msg_accrights=no)])
1252 if test $fptools_cv_struct_msghdr_msg_accrights = yes; then
1253   AC_DEFINE(HAVE_MSGHDR_MSG_ACCRIGHTS)
1254 fi
1255 AC_SUBST(HAVE_MSGHDR_MSG_ACCRIGHTS)dnl
1256 ])
1257