aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FP_EVAL_STDERR(COMMAND)
   8 # ------------------------
   9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  10 # into the file conftest.err and the exit status in the variable fp_status.
  11 AC_DEFUN([FP_EVAL_STDERR],
  12 [{ (eval $1) 2>conftest.er1
  13   fp_status=$?
  14   grep -v '^ *+' conftest.er1 >conftest.err
  15   rm -f conftest.er1
  16   (exit $fp_status); }[]dnl
  17 ])# FP_EVAL_STDERR
  18
  19
  20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
  21 # -----------------------------------------------------------------------
  22 # Check to see whether the compiler for the current language supports a
  23 # particular option.
  24 #
  25 # Implementation note: When given an unkown option, GCC issues an warning on
  26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
  27 # to check stderr *and* the exit value.
  28 #
  29 # Used by ghc.
  30 AC_DEFUN(FP_CHECK_FLAG,
  31 [AC_LANG_COMPILER_REQUIRE()dnl
  32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
  33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
  34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
  35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
  36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
  37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
  38 fp_save_flags="$fp_Flags"
  39 fp_Flags="$fp_Flags $1"
  40 fp_Cache=no
  41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  42   test -s conftest.err || fp_Cache=yes
  43 fi
  44 fp_Flags="$fp_save_flags"
  45 rm -f conftest.err conftest.$ac_ext])
  46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
  47 m4_popdef([fp_Cache])[]dnl
  48 m4_popdef([fp_Flags])[]dnl
  49 ])# FP_CHECK_FLAG
  50
  51
  52 # FP_PROG_CONTEXT_DIFF
  53 # --------------------
  54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  55 #
  56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  57 #
  58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  61 [echo foo > conftest1
  62 echo foo > conftest2
  63 fp_cv_context_diff=no
  64 for fp_var in '-C 1' '-c1'
  65 do
  66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  67     fp_cv_context_diff="diff $fp_var"
  68     break
  69   fi
  70 done])
  71 if test x"$fp_cv_context_diff" = xno; then
  72    AC_MSG_ERROR([cannot figure out how to do context diffs])
  73 fi
  74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  75 ])# FP_PROG_CONTEXT_DIFF
  76
  77
  78 # FP_DECL_ALTZONE
  79 # -------------------
  80 # Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
  81 #
  82 # Used by base package.
  83 AC_DEFUN([FP_DECL_ALTZONE],
  84 [AC_REQUIRE([AC_HEADER_TIME])dnl
  85 AC_CHECK_HEADERS([sys/time.h])
  86 AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
  87 # include <sys/time.h>
  88 # include <time.h>
  89 #else
  90 # if HAVE_SYS_TIME_H
  91 #  include <sys/time.h>
  92 # else
  93 #  include <time.h>
  94 # endif
  95 #endif])
  96 ])# FP_DECL_ALTZONE
  97
  98
  99 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
 100 # ---------------------------------------------------------
 101 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
 102 # compilation. Execute IF-FAILS when unable to determine the value. Works for
 103 # cross-compilation, too.
 104 #
 105 # Implementation note: We are lazy and use an internal autoconf macro, but it
 106 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
 107 # little risk.
 108 AC_DEFUN([FP_COMPUTE_INT],
 109 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
 110 ])# FP_COMPUTE_INT
 111
 112
 113 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
 114 # ------------------------------------------------------------------
 115 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
 116 # given type. Defines ALIGNMENT_TYPE.
 117 AC_DEFUN([FP_CHECK_ALIGNMENT],
 118 [AS_LITERAL_IF([$1], [],
 119                [AC_FATAL([$0: requires literal arguments])])[]dnl
 120 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 121 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 122 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 123 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 124   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 125                  [fp_Cache],
 126                  [AC_INCLUDES_DEFAULT([$3])],
 127                  [AC_MSG_ERROR([cannot compute alignment ($1)
 128 See `config.log' for more details.], [77])])
 129 else
 130   fp_Cache=0
 131 fi])[]dnl
 132 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 133 m4_popdef([fp_Cache])[]dnl
 134 ])# FP_CHECK_ALIGNMENT
 135
 136
 137 # FP_CHECK_CONST(EXPRESSION, [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = -1])
 138 # ---------------------------------------------------------------------------------
 139 # Defines CONST_EXPRESSION to the value of the compile-time EXPRESSION, using
 140 # INCLUDES. If the value cannot be determined, use VALUE-IF-FAIL.
 141 AC_DEFUN([FP_CHECK_CONST],
 142 [AS_VAR_PUSHDEF([fp_Cache], [fp_cv_const_$1])[]dnl
 143 AC_CACHE_CHECK([value of $1], fp_Cache,
 144 [FP_COMPUTE_INT([$1], fp_check_const_result, [AC_INCLUDES_DEFAULT([$2])],
 145                 [fp_check_const_result=m4_default([$3], ['-1'])])
 146 AS_VAR_SET(fp_Cache, [$fp_check_const_result])])[]dnl
 147 AC_DEFINE_UNQUOTED(AS_TR_CPP([CONST_$1]), AS_VAR_GET(fp_Cache), [The value of $1.])[]dnl
 148 AS_VAR_POPDEF([fp_Cache])[]dnl
 149 ])# FP_CHECK_CONST
 150
 151
 152 # FP_CHECK_CONSTS_TEMPLATE(EXPRESSION...)
 153 # ----------------------------------
 154 # autoheader helper for FP_CHECK_CONSTS
 155 m4_define([FP_CHECK_CONSTS_TEMPLATE],
 156 [AC_FOREACH([fp_Const], [$1],
 157   [AH_TEMPLATE(AS_TR_CPP(CONST_[]fp_Const),
 158                [The value of ]fp_Const[.])])[]dnl
 159 ])# FP_CHECK_CONSTS_TEMPLATE
 160
 161
 162 # FP_CHECK_CONSTS(EXPRESSION..., [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = -1])
 163 # -------------------------------------------------------------------------------------
 164 # List version of FP_CHECK_CONST
 165 AC_DEFUN(FP_CHECK_CONSTS,
 166 [FP_CHECK_CONSTS_TEMPLATE([$1])dnl
 167 for fp_const_name in $1
 168 do
 169 FP_CHECK_CONST([$fp_const_name], [$2], [$3])
 170 done
 171 ])# FP_CHECK_CONSTS
 172
 173
 174 dnl ** check for leading underscores in symbol names
 175 dnl
 176 dnl Test for determining whether symbol names have a leading
 177 dnl underscore.
 178 dnl
 179 dnl We assume that they _haven't_ if anything goes wrong.
 180 dnl
 181 dnl Some nlist implementations seem to try to be compatible by ignoring
 182 dnl a leading underscore sometimes (eg. FreeBSD).  We therefore have
 183 dnl to work around this by checking for *no* leading underscore first.
 184 dnl Sigh.  --SDM
 185 dnl
 186 dnl Similarly on OpenBSD, but this test doesn't help. -- dons
 187 dnl
 188 AC_DEFUN(FPTOOLS_UNDERSCORE,
 189 [AC_CHECK_LIB(elf, nlist, LIBS="-lelf $LIBS")dnl
 190 AC_CACHE_CHECK([leading underscore in symbol names], fptools_cv_lead_uscore,
 191
 192 dnl
 193 dnl Hack!: nlist() under Digital UNIX insist on there being an _,
 194 dnl but symbol table listings shows none. What is going on here?!?
 195 dnl
 196 dnl Another hack: cygwin doesn't come with nlist.h , so we hardwire
 197 dnl the underscoredness of that "platform"
 198 changequote(<<, >>)dnl
 199 <<
 200 case $HostPlatform in
 201 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 202     case $build in
 203         i386-*2\.[[0-9]] | i386-*3\.[[0-3]] ) fptools_cv_lead_uscore='yes' ;;
 204         *)      fptools_cv_lead_uscore='no' ;;
 205     esac ;;
 206 alpha-dec-osf*) fptools_cv_lead_uscore='no';;
 207 *cygwin32) fptools_cv_lead_uscore='yes';;
 208 *mingw32) fptools_cv_lead_uscore='yes';;
 209 *) >>
 210 changequote([, ])dnl
 211 AC_TRY_RUN([#ifdef HAVE_NLIST_H
 212 #include <nlist.h>
 213 changequote(<<, >>)dnl
 214 <<
 215 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 216 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 217 #endif
 218
 219 main(argc, argv)
 220 int argc;
 221 char **argv;
 222 {
 223 #ifdef HAVE_NLIST_H
 224     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 225         exit(1);
 226     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 227         exit(0);>>
 228 changequote([, ])dnl
 229 #endif
 230     exit(1);
 231 }], fptools_cv_lead_uscore=yes, fptools_cv_lead_uscore=no, fptools_cv_lead_uscore=NO)
 232 ;;
 233 esac);
 234 LeadingUnderscore=`echo $fptools_cv_lead_uscore | sed 'y/yesno/YESNO/'`
 235 AC_SUBST(LeadingUnderscore)
 236 case $LeadingUnderscore in
 237 YES) AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.]);;
 238 esac
 239 ])
 240
 241
 242 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 243 # ----------------------------------------------------------------------------------
 244 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 245 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 246 AC_DEFUN([FP_COMPARE_VERSIONS],
 247 [fp_version1=$1; fp_version2=$3
 248 fp_save_IFS=$IFS; IFS='.'
 249 while test x"$fp_version1" != x || test x"$fp_version2" != x
 250 do
 251
 252   set dummy $fp_version1; shift
 253   fp_num1=""
 254   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 255   test x"$fp_num1" = x && fp_num1="0"
 256   fp_version1="[$]*"
 257
 258   set dummy $fp_version2; shift
 259   fp_num2=""
 260   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 261   test x"$fp_num2" = x && fp_num2="0"
 262   fp_version2="[$]*"
 263
 264   test "$fp_num1" = "$fp_num2" || break;
 265 done
 266 IFS=$fp_save_IFS
 267 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 268 ])# FP_COMPARE_VERSIONS
 269
 270
 271 dnl
 272 dnl Check for GreenCard and version.
 273 dnl
 274 AC_DEFUN(FPTOOLS_GREENCARD,
 275 [
 276 AC_PATH_PROG(GreenCardCmd,greencard)
 277 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 278 changequote(, )dnl
 279 [if test x"$GreenCardCmd" != x; then
 280    fptools_cv_greencard_version="`$GreenCardCmd --version |
 281                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 282 else
 283    fptools_cv_greencard_version=""
 284 fi
 285 changequote([, ])dnl
 286 ])
 287 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 288   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 289 GreenCardVersion=$fptools_cv_greencard_version
 290 AC_SUBST(GreenCardVersion)
 291 ])
 292
 293 dnl
 294 dnl Check for Happy and version.  If we're building GHC, then we need
 295 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 296 dnl for a happy source tree and point the build system at that instead.
 297 dnl
 298 AC_DEFUN(FPTOOLS_HAPPY,
 299 [
 300 if test -d $srcdir/happy; then
 301    SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
 302 fi
 303 if test x"$UseSrcTreeHappy" = xYES; then
 304   HappyCmd=$SrcTreeHappyCmd
 305 else
 306   AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
 307 fi
 308 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 309 changequote(, )dnl
 310 [if test x"$HappyCmd" = x"$SrcTreeHappyCmd" -a -e $srcdir/happy/mk/version.mk; then
 311    fptools_cv_happy_version=`grep '^ProjectVersion[     ]*=' $srcdir/happy/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 312 elif test x"$HappyCmd" != x; then
 313    fptools_cv_happy_version="`$HappyCmd -v |
 314                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 315 else
 316    fptools_cv_happy_version="";
 317 fi;
 318 changequote([, ])dnl
 319 ])
 320 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
 321   FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.14],
 322   [AC_MSG_ERROR([Happy version 1.14 or later is required to compile GHC.])])[]dnl
 323 fi
 324 HappyVersion=$fptools_cv_happy_version;
 325 AC_SUBST(HappyVersion)
 326 ])
 327
 328 dnl
 329 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 330 dnl for a haddock source tree and point the build system at that instead.
 331 dnl
 332 AC_DEFUN(FPTOOLS_HADDOCK,
 333 [
 334 if test -d $srcdir/haddock; then
 335    SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
 336 fi
 337 if test x"$UseSrcTreeHaddock" = xYES; then
 338   HaddockCmd=$SrcTreeHaddockCmd
 339 else
 340   AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
 341 fi
 342 dnl Darn, I forgot to make Haddock print out its version number when
 343 dnl invoked with -v.  We could try generating some HTML and grepping
 344 dnl through that to find the version number, but I think we'll make
 345 dnl do without it for now.
 346 ])
 347
 348 dnl
 349 dnl Check for Alex and version.  If we're building GHC, then we need
 350 dnl at least Alex version 2.0.  If there's no installed Alex, we look
 351 dnl for a alex source tree and point the build system at that instead.
 352 dnl
 353 AC_DEFUN(FPTOOLS_ALEX,
 354 [
 355 if test -d $srcdir/alex; then
 356    SrcTreeAlexCmd=$hardtop/alex/src/alex-inplace
 357 fi
 358 if test x"$UseSrcTreeAlex" = xYES; then
 359   AlexCmd=$SrcTreeAlexCmd
 360 else
 361   AC_PATH_PROG(AlexCmd,alex,$SrcTreeAlexCmd)
 362 fi
 363 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 364 changequote(, )dnl
 365 [if test x"$AlexCmd" = x"$SrcTreeAlexCmd"; then
 366    fptools_cv_alex_version=`grep '^ProjectVersion[      ]*=' $srcdir/alex/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 367 elif test x"$AlexCmd" != x; then
 368    fptools_cv_alex_version="`$AlexCmd -v |
 369                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 370 else
 371    fptools_cv_alex_version="";
 372 fi;
 373 changequote([, ])dnl
 374 ])
 375 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Lexer.hs; then
 376   FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
 377   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
 378 fi
 379 AlexVersion=$fptools_cv_alex_version;
 380 AC_SUBST(AlexVersion)
 381 ])
 382
 383
 384 dnl
 385 dnl Check whether ld supports -x
 386 dnl
 387 AC_DEFUN(FPTOOLS_LD_X,
 388 [AC_CACHE_CHECK([whether ld understands -x], fptools_cv_ld_x,
 389 [
 390 echo 'foo() {}' > conftest.c
 391 ${CC-cc} -c conftest.c
 392 if ${LdCmd} -r -x -o foo.o conftest.o; then
 393    fptools_cv_ld_x=yes
 394 else
 395    fptools_cv_ld_x=no
 396 fi
 397 rm -rf conftest.c conftest.o foo.o
 398 ])
 399 if test "$fptools_cv_ld_x" = yes; then
 400         LdXFlag=-x
 401 else
 402         LdXFlag=
 403 fi
 404 AC_SUBST(LdXFlag)
 405 ])
 406
 407
 408 # FP_PROG_AR
 409 # ----------
 410 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 411 # version of it. Exits if no ar can be found
 412 AC_DEFUN([FP_PROG_AR],
 413 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 414 if test -z "$fp_prog_ar_raw"; then
 415   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 416 fi
 417 fp_prog_ar=$fp_prog_ar_raw
 418 case $HostPlatform in
 419   *mingw32) if test x${OSTYPE} != xmsys; then
 420               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 421               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 422             fi
 423             ;;
 424 esac
 425 ])# FP_PROG_AR
 426
 427
 428 # FP_PROG_AR_IS_GNU
 429 # -----------------
 430 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 431 AC_DEFUN([FP_PROG_AR_IS_GNU],
 432 [AC_REQUIRE([FP_PROG_AR])
 433 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 434 [if $fp_prog_ar_raw --version | grep "GNU" > /dev/null 2> /dev/null; then
 435   fp_cv_prog_ar_is_gnu=yes
 436 else
 437   fp_cv_prog_ar_is_gnu=no
 438 fi])
 439 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 440 ])# FP_PROG_AR_IS_GNU
 441
 442
 443 # FP_PROG_AR_ARGS
 444 # ---------------
 445 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 446 # to a non-Cygwin invocation of ar including these arguments.
 447 AC_DEFUN([FP_PROG_AR_ARGS],
 448 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 449 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 450 [
 451 # GNU ar needs special treatment: it appears to have problems with
 452 # object files with the same name if you use the 's' modifier, but
 453 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 454 if test $fp_prog_ar_is_gnu = yes; then
 455   fp_cv_prog_ar_args="q"
 456 else
 457   touch conftest.dummy
 458   for fp_var in clqsZ clqs cqs clq cq ; do
 459      rm -f conftest.a
 460      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 461         fp_cv_prog_ar_args=$fp_var
 462         break
 463      fi
 464   done
 465   rm -f conftest*
 466   if test -z "$fp_cv_prog_ar_args"; then
 467     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 468   fi
 469 fi])
 470 fp_prog_ar_args=$fp_cv_prog_ar_args
 471 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 472
 473 ])# FP_PROG_AR_ARGS
 474
 475
 476 # FP_PROG_AR_NEEDS_RANLIB
 477 # -----------------------
 478 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 479 # to ":" otherwise.
 480 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 481 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 482 AC_REQUIRE([FP_PROG_AR_ARGS])
 483 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 484 [if test $fp_prog_ar_is_gnu = yes; then
 485   fp_cv_prog_ar_needs_ranlib=no
 486 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 487   fp_cv_prog_ar_needs_ranlib=no
 488 else
 489   fp_cv_prog_ar_needs_ranlib=yes
 490 fi])
 491 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 492    AC_PROG_RANLIB
 493 else
 494   RANLIB=":"
 495   AC_SUBST([RANLIB])
 496 fi
 497 ])# FP_PROG_AR_NEEDS_RANLIB
 498
 499
 500 # FP_PROG_AR_SUPPORTS_INPUT
 501 # -------------------------
 502 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 503 # whether ar supports -input flag is supported or not.
 504 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 505 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 506 AC_REQUIRE([FP_PROG_AR_ARGS])
 507 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 508 [fp_cv_prog_ar_supports_input=no
 509 if test $fp_prog_ar_is_gnu = no; then
 510   rm -f conftest*
 511   touch conftest.lst
 512   if $fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst > /dev/null 2> /dev/null; then
 513     fp_cv_prog_ar_supports_input=yes
 514   fi
 515   rm -f conftest*
 516 fi])
 517 if test $fp_cv_prog_ar_supports_input = yes; then
 518     ArSupportsInput="-input"
 519 else
 520     ArSupportsInput=""
 521 fi
 522 AC_SUBST([ArSupportsInput])
 523 ])# FP_PROG_AR_SUPPORTS_INPUT
 524
 525
 526 dnl
 527 dnl AC_SHEBANG_PERL - can we she-bang perl?
 528 dnl
 529 AC_DEFUN(FPTOOLS_SHEBANG_PERL,
 530 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 531 [echo "#!$PerlCmd"'
 532 exit $1;
 533 ' > conftest
 534 chmod u+x conftest
 535 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 536 if test $? -ne 69; then
 537    fptools_cv_shebang_perl=yes
 538 else
 539    fptools_cv_shebang_perl=no
 540 fi
 541 rm -f conftest
 542 ])])
 543
 544 dnl
 545 dnl Extra testing of the result AC_PROG_CC, testing the gcc version no.
 546 dnl *Must* be called after AC_PROG_CC
 547 dnl
 548 AC_DEFUN(FPTOOLS_HAVE_GCC,
 549 [AC_CACHE_CHECK([whether you have an ok gcc], fptools_cv_have_gcc,
 550 [if test -z "$GCC"; then
 551     echo ''
 552     echo "You would be better off with gcc"
 553     echo "Perhaps it is already installed, but not in your PATH?"
 554     fptools_cv_have_gcc='no'
 555 else
 556 changequote(, )dnl
 557     gcc_version_str="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [^0-9]*\([0-9][0-9]*\)\.\([0-9][0-9]*\).*/\1\.\2/g' `"
 558 changequote([, ])dnl
 559     fptools_cv_have_gcc='yes'
 560     FP_COMPARE_VERSIONS([$gcc_version_str], [-lt], [2.0],
 561         [fptools_cv_have_gcc='no'
 562         echo ""
 563         echo "your gcc version appears to be ..."
 564         $CC --version
 565         echo "gcc prior to 2.0 and have never worked with ghc."
 566         echo "we recommend 2.95.3, although versions back to 2.7.2 should be ok."
 567         AC_MSG_ERROR([gcc 1.X has never been supported])])
 568 fi
 569 ])
 570 HaveGcc=`echo $fptools_cv_have_gcc | sed 'y/yesno/YESNO/'`
 571 AC_SUBST(HaveGcc)
 572 ])
 573
 574 dnl
 575 dnl Some OSs (Mandrake Linux, in particular) configure GCC with
 576 dnl -momit-leaf-frame-pointer on by default.  If this is the case, we
 577 dnl need to turn it off for mangling to work.  The test is currently a bit
 578 dnl crude, using only the version number of gcc.
 579 dnl
 580 AC_DEFUN([FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR],
 581 [AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fptools_cv_gcc_needs_no_omit_lfptr],
 582 [FP_COMPARE_VERSIONS([$gcc_version_str], [-ge], [3.2],
 583   [fptools_cv_gcc_needs_no_omit_lfptr=yes],
 584   [fptools_cv_gcc_needs_no_omit_lfptr=no])])
 585 if test "$fptools_cv_gcc_needs_no_omit_lfptr" = "yes"; then
 586    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
 587 fi])# FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR
 588
 589
 590 dnl Small feature test for perl version. Assumes PerlCmd
 591 dnl contains path to perl binary
 592 dnl
 593 AC_DEFUN(FPTOOLS_CHECK_PERL_VERSION,
 594 [$PerlCmd -v >conftest.out 2>&1
 595 if grep "version 5" conftest.out >/dev/null 2>&1; then
 596    :
 597 else
 598    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 599       :
 600    else
 601       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 602          :
 603       else
 604          if grep "version 6" conftest.out >/dev/null 2>&1; then
 605             :
 606          else
 607             echo "Your version of perl probably won't work."
 608          fi
 609       fi
 610    fi
 611 fi
 612 rm -fr conftest*
 613 ])
 614
 615
 616 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 617 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 618 # -----------------------------------------------------
 619 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 620 # of PROG-TO-CHECK-FOR when found.
 621 AC_DEFUN([FP_CHECK_PROG],
 622 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 623 )# FP_CHECK_PROC
 624
 625
 626 # FP_PROG_FIND
 627 # ------------
 628 # Find a non-WinDoze version of the "find" utility.
 629 AC_DEFUN([FP_PROG_FIND],
 630 [AC_PATH_PROG([fp_prog_find], [find])
 631 echo foo > conftest.txt
 632 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 633 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 634   # OK, looks like a real "find".
 635   FindCmd="$fp_prog_find"
 636 else
 637   # Found a poor WinDoze version of "find", ignore it.
 638   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 639   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 640 fi
 641 rm -f conftest.txt conftest.out
 642 AC_SUBST([FindCmd])[]dnl
 643 ])# FP_PROG_FIND
 644
 645
 646 dnl
 647 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 648 dnl values of the second argument to the result of running
 649 dnl the commands given by the third. It does not cache its
 650 dnl result, so it is suitable for checks which should be
 651 dnl run every time.
 652 dnl
 653 AC_DEFUN(FPTOOLS_NOCACHE_CHECK,
 654 [AC_MSG_CHECKING([$1])
 655  $3
 656  AC_MSG_RESULT([$][$2])
 657 ])
 658
 659 dnl
 660 dnl FPTOOLS_GHC_VERSION(version)
 661 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 662 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 663 dnl
 664 dnl Test for version of installed ghc.  Uses $GHC.
 665 dnl [original version pinched from c2hs]
 666 dnl
 667 AC_DEFUN(FPTOOLS_GHC_VERSION,
 668 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 669 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 670   cat conftestghc >&AC_FD_CC
 671 #Useless Use Of cat award...
 672   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 673   rm -fr conftest*
 674   if test "[$]fptools_version_of_ghc" = ""
 675   then
 676     fptools_version_of_ghc='unknown'
 677   fi
 678 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 679 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 680 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 681 #
 682 if test "[$]fptools_version_of_ghc[_pl]" = ""
 683 then
 684   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 685   fptools_version_of_ghc[_pl]="0"
 686 else
 687   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 688 fi
 689 #
 690 ifelse($#, [1], [dnl
 691 [$1]="[$]fptools_version_of_ghc[_all]"
 692 ], $#, [2], [dnl
 693 [$1]="[$]fptools_version_of_ghc[_major]"
 694 [$2]="[$]fptools_version_of_ghc[_minor]"
 695 ], $#, [3], [dnl
 696 [$1]="[$]fptools_version_of_ghc[_major]"
 697 [$2]="[$]fptools_version_of_ghc[_minor]"
 698 [$3]="[$]fptools_version_of_ghc[_pl]"
 699 ], $#, [4], [dnl
 700 [$1]="[$]fptools_version_of_ghc[_all]"
 701 [$2]="[$]fptools_version_of_ghc[_major]"
 702 [$3]="[$]fptools_version_of_ghc[_minor]"
 703 [$4]="[$]fptools_version_of_ghc[_pl]"
 704 ])
 705 ])
 706 ])dnl
 707
 708
 709 dnl ** Map an arithmetic C type to a Haskell type.
 710 dnl    Based on autconf's AC_CHECK_SIZEOF.
 711
 712 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
 713 AC_DEFUN(FPTOOLS_CHECK_HTYPE,
 714 [changequote(<<, >>)dnl
 715 dnl The name to #define.
 716 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
 717 dnl The cache variable name.
 718 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
 719 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
 720 changequote([, ])dnl
 721 AC_MSG_CHECKING(Haskell type for $1)
 722 AC_CACHE_VAL(AC_CV_NAME,
 723 [AC_CV_NAME_supported=yes
 724 fp_check_htype_save_cppflags="$CPPFLAGS"
 725 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 726 AC_TRY_RUN([#include <stdio.h>
 727 #include <stddef.h>
 728
 729 #if HAVE_SYS_TYPES_H
 730 # include <sys/types.h>
 731 #endif
 732
 733 #if HAVE_UNISTD_H
 734 # include <unistd.h>
 735 #endif
 736
 737 #if HAVE_SYS_STAT_H
 738 # include <sys/stat.h>
 739 #endif
 740
 741 #if HAVE_FCNTL_H
 742 # include <fcntl.h>
 743 #endif
 744
 745 #if HAVE_SIGNAL_H
 746 # include <signal.h>
 747 #endif
 748
 749 #if HAVE_TIME_H
 750 # include <time.h>
 751 #endif
 752
 753 #if HAVE_TERMIOS_H
 754 # include <termios.h>
 755 #endif
 756
 757 #if HAVE_STRING_H
 758 # include <string.h>
 759 #endif
 760
 761 #if HAVE_CTYPE_H
 762 # include <ctype.h>
 763 #endif
 764
 765 #if defined(HAVE_GL_GL_H)
 766 # include <GL/gl.h>
 767 #elif defined(HAVE_OPENGL_GL_H)
 768 # include <OpenGL/gl.h>
 769 #endif
 770
 771 #if defined(HAVE_AL_ALC_H)
 772 # include <AL/alc.h>
 773 #elif defined(HAVE_OPENAL_ALC_H)
 774 # include <OpenAL/alc.h>
 775 #endif
 776
 777 #if HAVE_SYS_RESOURCE_H
 778 # include <sys/resource.h>
 779 #endif
 780
 781 typedef $1 testing;
 782
 783 main() {
 784   FILE *f=fopen("conftestval", "w");
 785   if (!f) exit(1);
 786   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
 787     fprintf(f, "%s%d\n",
 788            ((testing)(-1) < (testing)0) ? "Int" : "Word",
 789            sizeof(testing)*8);
 790   } else {
 791     fprintf(f,"%s\n",
 792            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
 793            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
 794   }
 795   fclose(f);
 796   exit(0);
 797 }],AC_CV_NAME=`cat conftestval`,
 798 ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], AC_CV_NAME=$2),
 799 ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], AC_CV_NAME=$3))]) dnl
 800 CPPFLAGS="$fp_check_htype_save_cppflags"
 801 if test "$AC_CV_NAME_supported" = yes; then
 802   AC_MSG_RESULT($AC_CV_NAME)
 803   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
 804 else
 805   AC_MSG_RESULT([not supported])
 806 fi
 807 undefine([AC_TYPE_NAME])dnl
 808 undefine([AC_CV_NAME])dnl
 809 undefine([AC_CV_NAME_supported])dnl
 810 ])
 811
 812
 813 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 814 # ---------------------------------------------------------------------------------
 815 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 816 # additional flexibility of specifying the PROLOGUE and BODY.
 817 AC_DEFUN([FP_CHECK_FUNC],
 818 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 819 AC_CACHE_CHECK([for $1], fp_func,
 820 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 821                 [AS_VAR_SET(fp_func, yes)],
 822                 [AS_VAR_SET(fp_func, no)])])
 823 AS_IF([test AS_VAR_GET(fp_func) = yes],
 824       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 825                 [Define to 1 if you have the `]$1[' function.]) $4],
 826       [$5])dnl
 827 AS_VAR_POPDEF([fp_func])dnl
 828 ])# FP_CHECK_FUNC
 829
 830
 831 dnl ** Check which CATALOG file we have to use with DocBook SGML.
 832 dnl
 833 dnl FPTOOLS_DOCBOOK_CATALOG(VARIABLE, JADE, STYLESHEET, CATALOGS-TO-CHECK-FOR)
 834 dnl
 835 dnl If any of the catalogs given in CATALOGS-TO-CHECK-FOR works on this
 836 dnl platform, let VARIABLE refer to this catalog; otherwise, VARIABLE
 837 dnl is set to "no".  JADE is the jade executable and STYLESHEET
 838 dnl a DocBook style sheet.
 839 dnl
 840 AC_DEFUN(FPTOOLS_DOCBOOK_CATALOG,
 841 [AC_CACHE_CHECK([for DocBook CATALOG], fptools_cv_sgml_catalog,
 842 [
 843 cat > conftest.sgml << EOF
 844 <!DOCTYPE Article PUBLIC "-//OASIS//DTD DocBook V3.1//EN">
 845 <Article>
 846 <ArtHeader>
 847 <Title>Test</Title>
 848 <Author><OtherName>Test</OtherName></Author>
 849 <Address>Test</Address>
 850 <PubDate>Test</PubDate>
 851 </ArtHeader>
 852 <Sect1><Title>Test</Title>
 853 <Para>
 854 Test.
 855 </Para>
 856 </Sect1>
 857 </Article>
 858 EOF
 859 fptools_cv_sgml_catalog=no
 860 if test -z "$SGML_CATALOG_FILES" ; then
 861  for fptools_catalog in $4; do
 862    ac_try="$2 -t rtf -d $3#print -c $fptools_catalog conftest.sgml"
 863    if AC_TRY_EVAL(ac_try); then
 864      fptools_cv_sgml_catalog=[$]fptools_catalog
 865      break
 866    fi
 867  done
 868 else
 869 # If the env var SGML_CATALOG_FILES is defined, assume things are cool.
 870   fptools_cv_sgml_catalog="yes"
 871 fi
 872 ])
 873 rm -rf conftest*
 874 if test $fptools_cv_sgml_catalog != "no"; then
 875   $1=$fptools_cv_sgml_catalog
 876 fi
 877 ])
 878
 879
 880 # FP_CHECK_WIN32
 881 # --------------
 882 # If Windows is the target platform (e.g. MinGW/MSYS or Cygwin with
 883 # -mno-cygwin), the variable "is_win32" is set to "yes", otherwise (e.g. *nix
 884 # systems or plain Cygwin) it is set to "no".
 885 AC_DEFUN([FP_CHECK_WIN32],
 886 [AC_CACHE_CHECK([for Windows environment], [fp_cv_is_win32],
 887   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 888 #if !_WIN32
 889    syntax error;
 890 #endif
 891 ])], [fp_cv_is_win32=yes], [fp_cv_is_win32=no])])
 892 is_win32="$fp_cv_is_win32"[]dnl
 893 ])# FP_CHECK_WIN32
 894
 895
 896 # FP_PATH_X
 897 # ---------
 898 # Same as AC_PATH_X, but works even for broken Cygwins which try to include the
 899 # non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
 900 AC_DEFUN([FP_PATH_X],
 901 [AC_REQUIRE([FP_CHECK_WIN32])
 902 if test x"$is_win32" = xyes; then
 903   no_x=yes
 904 else
 905   AC_PATH_X
 906 fi
 907 ])# FP_PATH_X
 908
 909
 910 # FP_PATH_XTRA
 911 # ------------
 912 # Same as AC_PATH_XTRA, but works even for broken Cygwins which try to include
 913 # the non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
 914 AC_DEFUN([FP_PATH_XTRA],
 915 [AC_REQUIRE([FP_CHECK_WIN32])
 916 if test x"$is_win32" = xyes; then
 917   no_x=yes
 918 else
 919   AC_PATH_XTRA
 920 fi
 921 ])# FP_PATH_XTRA
 922
 923
 924 # FP_CHECK_GL_HELPER(LIBNAME, LIBS, INCLUDES, FUNCTION-BODY)
 925 # ----------------------------------------------------------
 926 # Try each library in LIBS to successfully link INCLUDES plus FUNCTION-BODY,
 927 # setting LIBNAME_CFLAGS and LIBNAME_LIBS to the corresponding values. Sets
 928 # no_LIBNAME to "yes" if no suitable library was found. (LIBNAME_CFLAGS0
 929 # contains the value of LIBNAME_CFLAGS without CPPFLAGS, and LIBNAME_LIBS0
 930 # contains the value of LIBNAME_LIBS without LDFLAGS, but these are only
 931 # used internally.)
 932 AC_DEFUN([FP_CHECK_GL_HELPER],
 933 [AC_CACHE_CHECK([for $1 library], [fp_cv_check_$1_lib],
 934   [fp_cv_check_$1_lib="no"
 935   fp_save_CPPFLAGS="$CPPFLAGS"
 936   CPPFLAGS="$CPPFLAGS ${$1_CFLAGS}"
 937   fp_save_LIBS="$LIBS"
 938   for fp_try_lib in $2; do
 939     # transform "-lfoo" to "foo.lib" when using cl
 940     if test x"$CC" = xcl; then
 941       fp_try_lib=`echo $fp_try_lib | sed -e 's/^-l//' -e 's/$/.lib/'`
 942     fi
 943     LIBS="$fp_try_lib ${$1_LIBS} $fp_save_LIBS"
 944     AC_TRY_LINK([$3], [$4], [fp_cv_check_$1_lib="$fp_try_lib ${$1_LIBS}"; break])
 945   done
 946   LIBS="$fp_save_LIBS"
 947   CPPFLAGS="$fp_save_CPPFLAGS"])
 948
 949   if test x"$fp_cv_check_$1_lib" = xno; then
 950     no_$1=yes
 951     $1_CFLAGS=
 952     $1_LIBS=
 953   else
 954     $1_CFLAGS0="${$1_CFLAGS}"
 955     $1_CFLAGS="$CPPFLAGS ${$1_CFLAGS0}"
 956     $1_LIBS0="$fp_cv_check_$1_lib"
 957     $1_LIBS="$LDFLAGS ${$1_LIBS0}"
 958   fi
 959 ])# FP_CHECK_GL_HELPER
 960
 961
 962 # FP_CHECK_GL
 963 # -----------
 964 AC_DEFUN([FP_CHECK_GL],
 965 [AC_REQUIRE([FP_PATH_X])
 966 AC_REQUIRE([AC_CANONICAL_SYSTEM])
 967
 968 AC_ARG_ENABLE([hopengl],
 969   [AC_HELP_STRING([--enable-hopengl],
 970     [build a Haskell binding for OpenGL (GL/GLU). On Mac OS X, use
 971      --enable-hopengl=x11 to use X11 instead of the "native" libraries.
 972      (default=no)])],
 973   [enable_opengl=$enableval], [enable_opengl=no])
 974
 975 if test x"$enable_opengl" = xno; then
 976    no_GL=yes
 977 else
 978   use_quartz_opengl=no
 979   case $target_os in
 980   darwin*)
 981     if test x"$enable_opengl" != xx11; then
 982       AC_DEFINE([USE_QUARTZ_OPENGL], [1],
 983                 [Define to 1 if native OpenGL should be used on Mac OS X])
 984       use_quartz_opengl=yes
 985     fi
 986     ;;
 987   esac
 988
 989   if test x"$use_quartz_opengl" != xyes; then
 990     AC_CHECK_LIB([m], [atan], [GL_LIBS="-lm $GL_LIBS"])
 991
 992     if test x"$no_x" != xyes; then
 993       test -n "$x_includes" && GL_CFLAGS="-I$x_includes $GL_CFLAGS"
 994       test -n "$x_libraries" && GL_LIBS="-L$x_libraries -lX11 $GL_LIBS"
 995     fi
 996
 997     FP_CHECK_GL_HELPER([GL], [-lGL -lopengl32], [@%:@include <GL/gl.h>], [glEnd()])
 998
 999     if test x"$no_GL" != xyes; then
1000       # Ugly: To get wglGetProcAddress on Windows, we have to link with
1001       # opengl32.dll, too, even when we are using Cygwin with X11.
1002       case "$GL_LIBS" in
1003         *-lopengl32*|*opengl32.lib*) ;;
1004         *) fp_save_LIBS="$LIBS"
1005            LIBS="$LIBS -lopengl32"
1006            AC_TRY_LINK([@%:@include <GL/gl.h>], [glEnd()],
1007              [GL_LIBS="$GL_LIBS -lopengl32"; GL_LIBS0="$GL_LIBS0 -lopengl32"])
1008            LIBS="$fp_save_LIBS"
1009            ;;
1010       esac
1011     fi
1012   fi
1013 fi
1014
1015 AC_SUBST([GL_CFLAGS])
1016 AC_SUBST([GL_LIBS])
1017 ])# FP_CHECK_GL
1018
1019
1020 # FP_CHECK_GLU
1021 # ------------
1022 AC_DEFUN([FP_CHECK_GLU],
1023 [AC_REQUIRE([FP_CHECK_GL])dnl
1024 GLU_CFLAGS="$GL_CFLAGS0"
1025 GLU_LIBS="$GL_LIBS0"
1026
1027 if test x"$enable_opengl" = xno; then
1028    no_GLU=yes
1029 elif test x"$use_quartz_opengl" != xyes; then
1030   FP_CHECK_GL_HELPER([GLU], [-lglu32 -lGLU], [@%:@include <GL/glu.h>], [gluNewQuadric()])
1031 fi
1032
1033 AC_SUBST([GLU_CFLAGS])
1034 AC_SUBST([GLU_LIBS])
1035 ])# FP_CHECK_GLU
1036
1037
1038 # FP_CHECK_GLUT
1039 # -------------
1040 AC_DEFUN([FP_CHECK_GLUT],
1041 [AC_REQUIRE([FP_CHECK_GLU])
1042 FP_PATH_XTRA
1043
1044 if test x"$enable_opengl" = xno; then
1045    no_GLUT=yes
1046 elif test x"$use_quartz_opengl" != xyes; then
1047   GLUT_CFLAGS="$GLU_CFLAGS0"
1048   GLUT_LIBS="$GLU_LIBS0"
1049
1050   if test x"$no_x" != xyes; then
1051     GLUT_LIBS="$X_PRE_LIBS -lXmu -lXi $X_EXTRA_LIBS $GLUT_LIBS"
1052   fi
1053
1054   AC_CHECK_HEADERS([windows.h GL/glut.h])
1055   # Note 1: On Cygwin with X11, GL/GLU functions use the "normal" calling
1056   # convention, but GLUT functions use stdcall. To get this right, it is
1057   # necessary to include <windows.h> first.
1058   # Note 2: MinGW/MSYS comes without a GLUT header, so we use Cygwin's one in
1059   # that case.
1060   FP_CHECK_GL_HELPER([GLUT], [-lglut32 -lglut], [
1061 #if HAVE_WINDOWS_H
1062 #include <windows.h>
1063 #endif
1064 #if HAVE_GL_GLUT_H
1065 #include <GL/glut.h>
1066 #else
1067 #include "glut_local.h"
1068 #endif
1069     ], [glutMainLoop()])
1070 fi
1071
1072 AC_SUBST([GLUT_CFLAGS])
1073 AC_SUBST([GLUT_LIBS])
1074 ])# FP_CHECK_GLUT
1075
1076
1077 dnl @synopsis FP_EMPTY_STRUCTS
1078 dnl
1079 dnl Check whether empty structs is accepted by CC.
1080 dnl
1081 AC_DEFUN(FP_EMPTY_STRUCTS,
1082 [AC_CACHE_CHECK(empty struct support, fptools_cv_empty_structs,
1083 [AC_TRY_COMPILE([
1084 typedef struct { /*empty*/ } StgFoo;
1085 ],
1086 [int i;],
1087 fptools_cv_empty_structs=yes,
1088 fptools_cv_empty_structs=no)])
1089 if test "$fptools_cv_empty_structs" = yes; then
1090 AC_DEFINE([SUPPORTS_EMPTY_STRUCTS], [1], [Define to 1 if C compiler supports declaration of empty structure types.])
1091 fi
1092 ])
1093
1094 # LocalWords:  fi