aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FP_EVAL_STDERR(COMMAND)
   8 # -----------------------
   9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  10 # into the file conftest.err and the exit status in the variable fp_status.
  11 AC_DEFUN([FP_EVAL_STDERR],
  12 [{ (eval $1) 2>conftest.er1
  13   fp_status=$?
  14   grep -v '^ *+' conftest.er1 >conftest.err
  15   rm -f conftest.er1
  16   (exit $fp_status); }[]dnl
  17 ])# FP_EVAL_STDERR
  18
  19
  20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
  21 # ---------------------------------------------------------------------
  22 # Check to see whether the compiler for the current language supports a
  23 # particular option.
  24 #
  25 # Implementation note: When given an unkown option, GCC issues an warning on
  26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
  27 # to check stderr *and* the exit value.
  28 #
  29 # Used by ghc.
  30 AC_DEFUN(FP_CHECK_FLAG,
  31 [AC_LANG_COMPILER_REQUIRE()dnl
  32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
  33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
  34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
  35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
  36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
  37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
  38 fp_save_flags="$fp_Flags"
  39 fp_Flags="$fp_Flags $1"
  40 fp_Cache=no
  41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  42   test -s conftest.err || fp_Cache=yes
  43 fi
  44 fp_Flags="$fp_save_flags"
  45 rm -f conftest.err conftest.$ac_ext])
  46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
  47 m4_popdef([fp_Cache])[]dnl
  48 m4_popdef([fp_Flags])[]dnl
  49 ])# FP_CHECK_FLAG
  50
  51
  52 # FP_PROG_CONTEXT_DIFF
  53 # --------------------
  54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  55 #
  56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  57 #
  58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  61 [echo foo > conftest1
  62 echo foo > conftest2
  63 fp_cv_context_diff=no
  64 for fp_var in '-C 1' '-c1'
  65 do
  66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  67     fp_cv_context_diff="diff $fp_var"
  68     break
  69   fi
  70 done])
  71 if test x"$fp_cv_context_diff" = xno; then
  72    AC_MSG_ERROR([cannot figure out how to do context diffs])
  73 fi
  74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  75 ])# FP_PROG_CONTEXT_DIFF
  76
  77
  78 # FP_DECL_ALTZONE
  79 # ---------------
  80 # Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
  81 #
  82 # Used by base package.
  83 AC_DEFUN([FP_DECL_ALTZONE],
  84 [AC_REQUIRE([AC_HEADER_TIME])dnl
  85 AC_CHECK_HEADERS([sys/time.h])
  86 AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
  87 # include <sys/time.h>
  88 # include <time.h>
  89 #else
  90 # if HAVE_SYS_TIME_H
  91 #  include <sys/time.h>
  92 # else
  93 #  include <time.h>
  94 # endif
  95 #endif])
  96 ])# FP_DECL_ALTZONE
  97
  98
  99 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
 100 # --------------------------------------------------------
 101 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
 102 # compilation. Execute IF-FAILS when unable to determine the value. Works for
 103 # cross-compilation, too.
 104 #
 105 # Implementation note: We are lazy and use an internal autoconf macro, but it
 106 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
 107 # little risk.
 108 AC_DEFUN([FP_COMPUTE_INT],
 109 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
 110 ])# FP_COMPUTE_INT
 111
 112
 113 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
 114 # ------------------------------------------------------------------
 115 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
 116 # given type. Defines ALIGNMENT_TYPE.
 117 AC_DEFUN([FP_CHECK_ALIGNMENT],
 118 [AS_LITERAL_IF([$1], [],
 119                [AC_FATAL([$0: requires literal arguments])])[]dnl
 120 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 121 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 122 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 123 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 124   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 125                  [fp_Cache],
 126                  [AC_INCLUDES_DEFAULT([$3])],
 127                  [AC_MSG_ERROR([cannot compute alignment ($1)
 128 See `config.log' for more details.], [77])])
 129 else
 130   fp_Cache=0
 131 fi])[]dnl
 132 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 133 m4_popdef([fp_Cache])[]dnl
 134 ])# FP_CHECK_ALIGNMENT
 135
 136
 137 # FP_LEADING_UNDERSCORE
 138 # ---------------------
 139 # Test for determining whether symbol names have a leading underscore. We assume
 140 # that they _haven't_ if anything goes wrong. Sets the output variable
 141 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 142 #
 143 # Some nlist implementations seem to try to be compatible by ignoring a leading
 144 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 145 # checking for *no* leading underscore first. Sigh.  --SDM
 146 #
 147 # Similarly on OpenBSD, but this test doesn't help. -- dons
 148 AC_DEFUN([FP_LEADING_UNDERSCORE],
 149 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 150 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 151 # Hack!: nlist() under Digital UNIX insist on there being an _,
 152 # but symbol table listings shows none. What is going on here?!?
 153 #
 154 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 155 # the underscoredness of that "platform"
 156 case $HostPlatform in
 157 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 158   case $build in
 159     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 160     *) fptools_cv_leading_underscore=no ;;
 161   esac ;;
 162 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 163 *cygwin32) fptools_cv_leading_underscore=yes;;
 164 *mingw32) fptools_cv_leading_underscore=yes;;
 165 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 166 #include <nlist.h>
 167 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 168 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 169 #endif
 170
 171 int main(argc, argv)
 172 int argc;
 173 char **argv;
 174 {
 175 #ifdef HAVE_NLIST_H
 176     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 177         exit(1);
 178     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 179         exit(0);
 180 #endif
 181     exit(1);
 182 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 183 ;;
 184 esac]);
 185 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 186 if test x"$fptools_cv_leading_underscore" = xyes; then
 187    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 188 fi])# FP_LEADING_UNDERSCORE
 189
 190
 191 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 192 # ----------------------------------------------------------------------------------
 193 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 194 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 195 AC_DEFUN([FP_COMPARE_VERSIONS],
 196 [fp_version1=$1; fp_version2=$3
 197 fp_save_IFS=$IFS; IFS='.'
 198 while test x"$fp_version1" != x || test x"$fp_version2" != x
 199 do
 200
 201   set dummy $fp_version1; shift
 202   fp_num1=""
 203   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 204   test x"$fp_num1" = x && fp_num1="0"
 205   fp_version1="[$]*"
 206
 207   set dummy $fp_version2; shift
 208   fp_num2=""
 209   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 210   test x"$fp_num2" = x && fp_num2="0"
 211   fp_version2="[$]*"
 212
 213   test "$fp_num1" = "$fp_num2" || break;
 214 done
 215 IFS=$fp_save_IFS
 216 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 217 ])# FP_COMPARE_VERSIONS
 218
 219
 220 dnl
 221 dnl Check for GreenCard and version.
 222 dnl
 223 AC_DEFUN(FPTOOLS_GREENCARD,
 224 [
 225 AC_PATH_PROG(GreenCardCmd,greencard)
 226 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 227 changequote(, )dnl
 228 [if test x"$GreenCardCmd" != x; then
 229    fptools_cv_greencard_version="`$GreenCardCmd --version |
 230                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 231 else
 232    fptools_cv_greencard_version=""
 233 fi
 234 changequote([, ])dnl
 235 ])
 236 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 237   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 238 GreenCardVersion=$fptools_cv_greencard_version
 239 AC_SUBST(GreenCardVersion)
 240 ])
 241
 242 dnl
 243 dnl Check for Happy and version.  If we're building GHC, then we need
 244 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 245 dnl for a happy source tree and point the build system at that instead.
 246 dnl
 247 AC_DEFUN(FPTOOLS_HAPPY,
 248 [
 249 if test -d $srcdir/happy; then
 250    SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
 251 fi
 252 if test x"$UseSrcTreeHappy" = xYES; then
 253   HappyCmd=$SrcTreeHappyCmd
 254 else
 255   AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
 256 fi
 257 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 258 changequote(, )dnl
 259 [if test x"$HappyCmd" = x"$SrcTreeHappyCmd" -a -e $srcdir/happy/mk/version.mk; then
 260    fptools_cv_happy_version=`grep '^ProjectVersion[     ]*=' $srcdir/happy/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 261 elif test x"$HappyCmd" != x; then
 262    fptools_cv_happy_version="`$HappyCmd -v |
 263                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 264 else
 265    fptools_cv_happy_version="";
 266 fi;
 267 changequote([, ])dnl
 268 ])
 269 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
 270   FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.14],
 271   [AC_MSG_ERROR([Happy version 1.14 or later is required to compile GHC.])])[]dnl
 272 fi
 273 HappyVersion=$fptools_cv_happy_version;
 274 AC_SUBST(HappyVersion)
 275 ])
 276
 277 dnl
 278 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 279 dnl for a haddock source tree and point the build system at that instead.
 280 dnl
 281 AC_DEFUN(FPTOOLS_HADDOCK,
 282 [
 283 if test -d $srcdir/haddock; then
 284    SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
 285 fi
 286 if test x"$UseSrcTreeHaddock" = xYES; then
 287   HaddockCmd=$SrcTreeHaddockCmd
 288 else
 289   AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
 290 fi
 291 dnl Darn, I forgot to make Haddock print out its version number when
 292 dnl invoked with -v.  We could try generating some HTML and grepping
 293 dnl through that to find the version number, but I think we'll make
 294 dnl do without it for now.
 295 ])
 296
 297 dnl
 298 dnl Check for Alex and version.  If we're building GHC, then we need
 299 dnl at least Alex version 2.0.  If there's no installed Alex, we look
 300 dnl for a alex source tree and point the build system at that instead.
 301 dnl
 302 AC_DEFUN(FPTOOLS_ALEX,
 303 [
 304 if test -d $srcdir/alex; then
 305    SrcTreeAlexCmd=$hardtop/alex/src/alex-inplace
 306 fi
 307 if test x"$UseSrcTreeAlex" = xYES; then
 308   AlexCmd=$SrcTreeAlexCmd
 309 else
 310   AC_PATH_PROG(AlexCmd,alex,$SrcTreeAlexCmd)
 311 fi
 312 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 313 changequote(, )dnl
 314 [if test x"$AlexCmd" = x"$SrcTreeAlexCmd"; then
 315    fptools_cv_alex_version=`grep '^ProjectVersion[      ]*=' $srcdir/alex/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 316 elif test x"$AlexCmd" != x; then
 317    fptools_cv_alex_version="`$AlexCmd -v |
 318                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 319 else
 320    fptools_cv_alex_version="";
 321 fi;
 322 changequote([, ])dnl
 323 ])
 324 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Lexer.hs; then
 325   FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
 326   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
 327 fi
 328 AlexVersion=$fptools_cv_alex_version;
 329 AC_SUBST(AlexVersion)
 330 ])
 331
 332
 333 # FP_PROG_LD
 334 # ----------
 335 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 336 # of ld. Exits if no ld can be found
 337 AC_DEFUN([FP_PROG_LD],
 338 [AC_PATH_PROG([fp_prog_ld_raw], [ld])
 339 if test -z "$fp_prog_ld_raw"; then
 340   AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 341 fi
 342 LdCmd=$fp_prog_ld_raw
 343 case $HostPlatform in
 344   *mingw32) if test x${OSTYPE} != xmsys; then
 345               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 346               AC_MSG_NOTICE([normalized ld command to $LdCmd])
 347             fi
 348             ;;
 349 esac
 350 AC_SUBST([LdCmd])
 351 ])# FP_PROG_LD
 352
 353
 354 # FP_PROG_LD_X
 355 # ------------
 356 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 357 # variable's value is empty.
 358 AC_DEFUN([FP_PROG_LD_X],
 359 [AC_REQUIRE([FP_PROG_LD])
 360 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 361 [echo 'foo() {}' > conftest.c
 362 ${CC-cc} -c conftest.c
 363 if ${LdCmd} -r -x -o conftest2.o conftest.o; then
 364    fp_cv_ld_x=yes
 365 else
 366    fp_cv_ld_x=no
 367 fi
 368 rm -rf conftest*])
 369 if test "$fp_cv_ld_x" = yes; then
 370   LdXFlag=-x
 371 else
 372   LdXFlag=
 373 fi
 374 AC_SUBST([LdXFlag])
 375 ])# FP_PROG_LD_X
 376
 377
 378 # FP_PROG_LD_IS_GNU
 379 # -----------------
 380 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 381 # GNU ld or not.
 382 AC_DEFUN([FP_PROG_LD_IS_GNU],
 383 [AC_REQUIRE([FP_PROG_LD])
 384 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 385 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 386   fp_cv_gnu_ld=yes
 387 else
 388   fp_cv_gnu_ld=no
 389 fi])
 390 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 391 ])# FP_PROG_LD_IS_GNU
 392
 393
 394 # FP_PROG_AR
 395 # ----------
 396 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 397 # version of it. Exits if no ar can be found
 398 AC_DEFUN([FP_PROG_AR],
 399 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 400 if test -z "$fp_prog_ar_raw"; then
 401   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 402 fi
 403 fp_prog_ar=$fp_prog_ar_raw
 404 case $HostPlatform in
 405   *mingw32) if test x${OSTYPE} != xmsys; then
 406               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 407               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 408             fi
 409             ;;
 410 esac
 411 ])# FP_PROG_AR
 412
 413
 414 # FP_PROG_AR_IS_GNU
 415 # -----------------
 416 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 417 AC_DEFUN([FP_PROG_AR_IS_GNU],
 418 [AC_REQUIRE([FP_PROG_AR])
 419 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 420 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 421   fp_cv_prog_ar_is_gnu=yes
 422 else
 423   fp_cv_prog_ar_is_gnu=no
 424 fi])
 425 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 426 ])# FP_PROG_AR_IS_GNU
 427
 428
 429 # FP_PROG_AR_ARGS
 430 # ---------------
 431 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 432 # to a non-Cygwin invocation of ar including these arguments.
 433 AC_DEFUN([FP_PROG_AR_ARGS],
 434 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 435 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 436 [
 437 # GNU ar needs special treatment: it appears to have problems with
 438 # object files with the same name if you use the 's' modifier, but
 439 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 440 if test $fp_prog_ar_is_gnu = yes; then
 441   fp_cv_prog_ar_args="q"
 442 else
 443   touch conftest.dummy
 444   for fp_var in clqsZ clqs cqs clq cq ; do
 445      rm -f conftest.a
 446      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 447         fp_cv_prog_ar_args=$fp_var
 448         break
 449      fi
 450   done
 451   rm -f conftest*
 452   if test -z "$fp_cv_prog_ar_args"; then
 453     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 454   fi
 455 fi])
 456 fp_prog_ar_args=$fp_cv_prog_ar_args
 457 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 458
 459 ])# FP_PROG_AR_ARGS
 460
 461
 462 # FP_PROG_AR_NEEDS_RANLIB
 463 # -----------------------
 464 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 465 # to ":" otherwise.
 466 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 467 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 468 AC_REQUIRE([FP_PROG_AR_ARGS])
 469 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 470 [if test $fp_prog_ar_is_gnu = yes; then
 471   fp_cv_prog_ar_needs_ranlib=no
 472 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 473   fp_cv_prog_ar_needs_ranlib=no
 474 else
 475   fp_cv_prog_ar_needs_ranlib=yes
 476 fi])
 477 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 478    AC_PROG_RANLIB
 479 else
 480   RANLIB=":"
 481   AC_SUBST([RANLIB])
 482 fi
 483 ])# FP_PROG_AR_NEEDS_RANLIB
 484
 485
 486 # FP_PROG_AR_SUPPORTS_INPUT
 487 # -------------------------
 488 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 489 # whether ar supports -input flag is supported or not.
 490 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 491 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 492 AC_REQUIRE([FP_PROG_AR_ARGS])
 493 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 494 [fp_cv_prog_ar_supports_input=no
 495 if test $fp_prog_ar_is_gnu = no; then
 496   rm -f conftest*
 497   touch conftest.lst
 498   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 499     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 500   fi
 501   rm -f conftest*
 502 fi])
 503 if test $fp_cv_prog_ar_supports_input = yes; then
 504     ArSupportsInput="-input"
 505 else
 506     ArSupportsInput=""
 507 fi
 508 AC_SUBST([ArSupportsInput])
 509 ])# FP_PROG_AR_SUPPORTS_INPUT
 510
 511
 512 dnl
 513 dnl AC_SHEBANG_PERL - can we she-bang perl?
 514 dnl
 515 AC_DEFUN(FPTOOLS_SHEBANG_PERL,
 516 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 517 [echo "#!$PerlCmd"'
 518 exit $1;
 519 ' > conftest
 520 chmod u+x conftest
 521 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 522 if test $? -ne 69; then
 523    fptools_cv_shebang_perl=yes
 524 else
 525    fptools_cv_shebang_perl=no
 526 fi
 527 rm -f conftest
 528 ])])
 529
 530
 531 # FP_HAVE_GCC
 532 # -----------
 533 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 534 # output variables HaveGcc and GccVersion.
 535 AC_DEFUN([FP_HAVE_GCC],
 536 [AC_REQUIRE([AC_PROG_CC])
 537 AC_CACHE_CHECK([whether your gcc is OK], [fp_cv_have_gcc],
 538 [if test -z "$GCC"; then
 539   fp_cv_have_gcc='no'
 540   AC_MSG_WARN([You would be better off with gcc, perhaps it is already installed, but not in your PATH?])
 541 else
 542   fp_cv_have_gcc='yes'
 543   gcc_version_str="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9]][[0-9]]*\)\.\([[0-9]][[0-9]]*\).*/\1\.\2/g' `"
 544   FP_COMPARE_VERSIONS([$gcc_version_str], [-lt], [2.0],
 545     [AC_MSG_ERROR([Need at least gcc version 2.0 (2.95.3 recommend)])])
 546 fi])
 547 AC_SUBST([HaveGcc], [`echo $fp_cv_have_gcc | sed 'y/yesno/YESNO/'`])
 548 AC_SUBST([GccVersion], [`gcc --version | grep mingw | cut -f 3 -d ' '`])
 549 ])# FP_HAVE_GCC
 550
 551 AC_DEFUN([FP_MINGW_GCC],
 552 [
 553   case $HostOS_CPP in
 554     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
 555              if $CC -v 2>&1 | grep mingw >/dev/null; then
 556                 AC_MSG_RESULT([yes])
 557              else
 558                 AC_MSG_RESULT([no])
 559                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
 560              fi;;
 561     *) ;;
 562   esac
 563 ])
 564
 565 dnl Small feature test for perl version. Assumes PerlCmd
 566 dnl contains path to perl binary
 567 dnl
 568 AC_DEFUN(FPTOOLS_CHECK_PERL_VERSION,
 569 [$PerlCmd -v >conftest.out 2>&1
 570 if grep "version 5" conftest.out >/dev/null 2>&1; then
 571    :
 572 else
 573    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 574       :
 575    else
 576       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 577          :
 578       else
 579          if grep "version 6" conftest.out >/dev/null 2>&1; then
 580             :
 581          else
 582             echo "Your version of perl probably won't work."
 583          fi
 584       fi
 585    fi
 586 fi
 587 rm -fr conftest*
 588 ])
 589
 590
 591 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 592 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 593 # -----------------------------------------------------
 594 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 595 # of PROG-TO-CHECK-FOR when found.
 596 AC_DEFUN([FP_CHECK_PROG],
 597 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 598 )# FP_CHECK_PROC
 599
 600
 601 # FP_PROG_FIND
 602 # ------------
 603 # Find a non-WinDoze version of the "find" utility.
 604 AC_DEFUN([FP_PROG_FIND],
 605 [AC_PATH_PROG([fp_prog_find], [find])
 606 echo foo > conftest.txt
 607 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 608 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 609   # OK, looks like a real "find".
 610   FindCmd="$fp_prog_find"
 611 else
 612   # Found a poor WinDoze version of "find", ignore it.
 613   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 614   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 615 fi
 616 rm -f conftest.txt conftest.out
 617 AC_SUBST([FindCmd])[]dnl
 618 ])# FP_PROG_FIND
 619
 620
 621 dnl
 622 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 623 dnl values of the second argument to the result of running
 624 dnl the commands given by the third. It does not cache its
 625 dnl result, so it is suitable for checks which should be
 626 dnl run every time.
 627 dnl
 628 AC_DEFUN(FPTOOLS_NOCACHE_CHECK,
 629 [AC_MSG_CHECKING([$1])
 630  $3
 631  AC_MSG_RESULT([$][$2])
 632 ])
 633
 634 dnl
 635 dnl FPTOOLS_GHC_VERSION(version)
 636 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 637 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 638 dnl
 639 dnl Test for version of installed ghc.  Uses $GHC.
 640 dnl [original version pinched from c2hs]
 641 dnl
 642 AC_DEFUN(FPTOOLS_GHC_VERSION,
 643 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 644 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 645   cat conftestghc >&AS_MESSAGE_LOG_FD
 646 #Useless Use Of cat award...
 647   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 648   rm -fr conftest*
 649   if test "[$]fptools_version_of_ghc" = ""
 650   then
 651     fptools_version_of_ghc='unknown'
 652   fi
 653 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 654 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 655 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 656 #
 657 if test "[$]fptools_version_of_ghc[_pl]" = ""
 658 then
 659   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 660   fptools_version_of_ghc[_pl]="0"
 661 else
 662   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 663 fi
 664 #
 665 ifelse($#, [1], [dnl
 666 [$1]="[$]fptools_version_of_ghc[_all]"
 667 ], $#, [2], [dnl
 668 [$1]="[$]fptools_version_of_ghc[_major]"
 669 [$2]="[$]fptools_version_of_ghc[_minor]"
 670 ], $#, [3], [dnl
 671 [$1]="[$]fptools_version_of_ghc[_major]"
 672 [$2]="[$]fptools_version_of_ghc[_minor]"
 673 [$3]="[$]fptools_version_of_ghc[_pl]"
 674 ], $#, [4], [dnl
 675 [$1]="[$]fptools_version_of_ghc[_all]"
 676 [$2]="[$]fptools_version_of_ghc[_major]"
 677 [$3]="[$]fptools_version_of_ghc[_minor]"
 678 [$4]="[$]fptools_version_of_ghc[_pl]"
 679 ])
 680 ])
 681 ])dnl
 682
 683
 684 dnl ** Map an arithmetic C type to a Haskell type.
 685 dnl    Based on autconf's AC_CHECK_SIZEOF.
 686
 687 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
 688 AC_DEFUN(FPTOOLS_CHECK_HTYPE,
 689 [changequote(<<, >>)dnl
 690 dnl The name to #define.
 691 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
 692 dnl The cache variable name.
 693 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
 694 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
 695 changequote([, ])dnl
 696 AC_MSG_CHECKING(Haskell type for $1)
 697 AC_CACHE_VAL(AC_CV_NAME,
 698 [AC_CV_NAME_supported=yes
 699 fp_check_htype_save_cppflags="$CPPFLAGS"
 700 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 701 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdio.h>
 702 #include <stddef.h>
 703
 704 #if HAVE_SYS_TYPES_H
 705 # include <sys/types.h>
 706 #endif
 707
 708 #if HAVE_UNISTD_H
 709 # include <unistd.h>
 710 #endif
 711
 712 #if HAVE_SYS_STAT_H
 713 # include <sys/stat.h>
 714 #endif
 715
 716 #if HAVE_FCNTL_H
 717 # include <fcntl.h>
 718 #endif
 719
 720 #if HAVE_SIGNAL_H
 721 # include <signal.h>
 722 #endif
 723
 724 #if HAVE_TIME_H
 725 # include <time.h>
 726 #endif
 727
 728 #if HAVE_TERMIOS_H
 729 # include <termios.h>
 730 #endif
 731
 732 #if HAVE_STRING_H
 733 # include <string.h>
 734 #endif
 735
 736 #if HAVE_CTYPE_H
 737 # include <ctype.h>
 738 #endif
 739
 740 #if defined(HAVE_GL_GL_H)
 741 # include <GL/gl.h>
 742 #elif defined(HAVE_OPENGL_GL_H)
 743 # include <OpenGL/gl.h>
 744 #endif
 745
 746 #if defined(HAVE_AL_ALC_H)
 747 # include <AL/alc.h>
 748 #elif defined(HAVE_OPENAL_ALC_H)
 749 # include <OpenAL/alc.h>
 750 #endif
 751
 752 #if HAVE_SYS_RESOURCE_H
 753 # include <sys/resource.h>
 754 #endif
 755
 756 typedef $1 testing;
 757
 758 main() {
 759   FILE *f=fopen("conftestval", "w");
 760   if (!f) exit(1);
 761   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
 762     fprintf(f, "%s%d\n",
 763            ((testing)(-1) < (testing)0) ? "Int" : "Word",
 764            sizeof(testing)*8);
 765   } else {
 766     fprintf(f,"%s\n",
 767            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
 768            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
 769   }
 770   fclose(f);
 771   exit(0);
 772 }]])],[AC_CV_NAME=`cat conftestval`],
 773 [ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], [AC_CV_NAME=$2])],
 774 [ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], [AC_CV_NAME=$3])])]) dnl
 775 CPPFLAGS="$fp_check_htype_save_cppflags"
 776 if test "$AC_CV_NAME_supported" = yes; then
 777   AC_MSG_RESULT($AC_CV_NAME)
 778   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
 779 else
 780   AC_MSG_RESULT([not supported])
 781 fi
 782 undefine([AC_TYPE_NAME])dnl
 783 undefine([AC_CV_NAME])dnl
 784 undefine([AC_CV_NAME_supported])dnl
 785 ])
 786
 787
 788 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 789 # ---------------------------------------------------------------------------------
 790 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 791 # additional flexibility of specifying the PROLOGUE and BODY.
 792 AC_DEFUN([FP_CHECK_FUNC],
 793 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 794 AC_CACHE_CHECK([for $1], fp_func,
 795 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 796                 [AS_VAR_SET(fp_func, yes)],
 797                 [AS_VAR_SET(fp_func, no)])])
 798 AS_IF([test AS_VAR_GET(fp_func) = yes],
 799       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 800                 [Define to 1 if you have the `]$1[' function.]) $4],
 801       [$5])dnl
 802 AS_VAR_POPDEF([fp_func])dnl
 803 ])# FP_CHECK_FUNC
 804
 805
 806 # FP_GEN_DOCBOOK_XML
 807 # ------------------
 808 # Generates a DocBook XML V4.2 document in conftest.xml.
 809 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 810 [rm -f conftest.xml
 811 cat > conftest.xml << EOF
 812 <?xml version="1.0" encoding="iso-8859-1"?>
 813 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 814    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 815 <book id="test">
 816   <title>A DocBook Test Document</title>
 817   <chapter id="id-one">
 818     <title>A Chapter Title</title>
 819     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 820   </chapter>
 821   <chapter id="id-two">
 822     <title>Another Chapter Title</title>
 823     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 824   </chapter>
 825 </book>
 826 EOF
 827 ]) # FP_GEN_DOCBOOK_XML
 828
 829
 830 # FP_PROG_XSLTPROC
 831 # ----------------
 832 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 833 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 834 AC_DEFUN([FP_PROG_XSLTPROC],
 835 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 836 if test -z "$XsltprocCmd"; then
 837   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 838 fi
 839 ])# FP_PROG_XSLTPROC
 840
 841
 842 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 843 # ----------------------------
 844 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 845 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 846 # will be empty if none could be found.
 847 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 848 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 849 if test -n "$XsltprocCmd"; then
 850   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 851   [FP_GEN_DOCBOOK_XML
 852   fp_cv_dir_docbook_xsl=no
 853   for fp_var in $1; do
 854      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 855         fp_cv_dir_docbook_xsl=$fp_var
 856         break
 857      fi
 858   done
 859   rm -rf conftest*])
 860 fi
 861 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 862   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 863   DIR_DOCBOOK_XSL=
 864 else
 865   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 866 fi
 867 AC_SUBST([DIR_DOCBOOK_XSL])
 868 ])# FP_DIR_DOCBOOK_XSL
 869
 870
 871 # FP_PROG_XMLLINT
 872 # ----------------
 873 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 874 # xmllint. XmllintCmd is empty if xmllint could not be found.
 875 AC_DEFUN([FP_PROG_XMLLINT],
 876 [AC_PATH_PROG([XmllintCmd], [xmllint])
 877 if test -z "$XmllintCmd"; then
 878   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 879 fi
 880 ])# FP_PROG_XMLLINT
 881
 882
 883 # FP_CHECK_DOCBOOK_DTD
 884 # --------------------
 885 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 886 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 887 if test -n "$XmllintCmd"; then
 888   AC_MSG_CHECKING([for DocBook DTD])
 889   FP_GEN_DOCBOOK_XML
 890   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 891     AC_MSG_RESULT([ok])
 892   else
 893     AC_MSG_RESULT([failed])
 894     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 895     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 896   fi
 897   rm -rf conftest*
 898 fi
 899 ])# FP_CHECK_DOCBOOK_DTD
 900
 901
 902 # FP_GEN_FO
 903 # ------------------
 904 # Generates a formatting objects document in conftest.fo.
 905 AC_DEFUN([FP_GEN_FO],
 906 [rm -f conftest.fo
 907 cat > conftest.fo << EOF
 908 <?xml version="1.0"?>
 909 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 910   <fo:layout-master-set>
 911     <fo:simple-page-master master-name="blank">
 912       <fo:region-body/>
 913     </fo:simple-page-master>
 914   </fo:layout-master-set>
 915   <fo:page-sequence master-reference="blank">
 916     <fo:flow flow-name="xsl-region-body">
 917       <fo:block>
 918         Test!
 919       </fo:block>
 920     </fo:flow>
 921   </fo:page-sequence>
 922 </fo:root>
 923 EOF
 924 ]) # FP_GEN_FO
 925
 926
 927 # FP_PROG_FOP
 928 # -----------
 929 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 930 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 931 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 932 AC_DEFUN([FP_PROG_FOP],
 933 [AC_PATH_PROGS([FopCmd1], [fop])
 934 if test -n "$FopCmd1"; then
 935   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 936     [FP_GEN_FO
 937     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 938       fp_cv_fop_usability=yes
 939     else
 940       fp_cv_fop_usability=no
 941     fi
 942     rm -rf conftest*])
 943   if test x"$fp_cv_fop_usability" = xyes; then
 944      FopCmd=$FopCmd1
 945   fi
 946 fi
 947 if test -z "$FopCmd"; then
 948   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 949   FopCmd=$FopCmd2
 950 fi
 951 AC_SUBST([FopCmd])
 952 ])# FP_PROG_FOP
 953
 954
 955 # FP_PROG_FO_PROCESSOR
 956 # --------------------
 957 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
 958 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
 959 # PdfxmltexCmd.
 960 AC_DEFUN([FP_PROG_FO_PROCESSOR],
 961 [AC_REQUIRE([FP_PROG_FOP])
 962 AC_PATH_PROG([XmltexCmd], [xmltex])
 963 AC_PATH_PROG([DvipsCmd], [dvips])
 964 if test -z "$FopCmd"; then
 965   if test -z "$XmltexCmd"; then
 966     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
 967   else
 968     if test -z "$DvipsCmd"; then
 969       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
 970     fi
 971   fi
 972   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
 973   if test -z "$PdfxmltexCmd"; then
 974     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
 975   fi
 976 elif test -z "$XmltexCmd"; then
 977   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
 978 fi
 979 ])# FP_PROG_FO_PROCESSOR
 980
 981
 982 # FP_PROG_GHC_PKG
 983 # ----------------
 984 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
 985 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
 986 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
 987 AC_DEFUN([FP_PROG_GHC_PKG],
 988 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
 989 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
 990 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
 991   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 992 else
 993   fp_cv_matching_ghc_pkg=no
 994 fi])
 995 if test x"$fp_cv_matching_ghc_pkg" = xno; then
 996   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
 997 else
 998   GhcPkgCmd=$fp_cv_matching_ghc_pkg
 999 fi])# FP_PROG_GHC_PKG
1000
1001 # LocalWords:  fi