aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
   8 # ----------------------------------
   9 # Little endian Arm on Linux with some ABIs has big endian word order
  10 # in doubles. Define FLOAT_WORDS_BIGENDIAN if this is the case.
  11 AC_DEFUN([FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN],
  12   [AC_CACHE_CHECK([whether float word order is big endian], [fptools_cv_float_word_order_bigendian],
  13     [AC_COMPILE_IFELSE(
  14       [AC_LANG_PROGRAM(
  15         [#include <endian.h>],
  16         [#if defined(__FLOAT_WORD_ORDER) && __FLOAT_WORD_ORDER == BIG_ENDIAN
  17              return 0;
  18          #else
  19              not float word order big endian
  20          #endif]
  21       )],
  22       [fptools_cv_float_word_order_bigendian=yes],
  23       [fptools_cv_float_word_order_bigendian=no])
  24     ])
  25   case $fptools_cv_float_word_order_bigendian in
  26       yes)
  27           AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
  28           [Define to 1 if your processor stores words of floats with
  29            the most significant byte first]) ;;
  30   esac
  31 ])
  32
  33
  34 # FP_EVAL_STDERR(COMMAND)
  35 # -----------------------
  36 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  37 # into the file conftest.err and the exit status in the variable fp_status.
  38 AC_DEFUN([FP_EVAL_STDERR],
  39 [{ (eval $1) 2>conftest.er1
  40   fp_status=$?
  41   grep -v '^ *+' conftest.er1 >conftest.err
  42   rm -f conftest.er1
  43   (exit $fp_status); }[]dnl
  44 ])# FP_EVAL_STDERR
  45
  46
  47 # FP_PROG_CONTEXT_DIFF
  48 # --------------------
  49 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  50 #
  51 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  52 #
  53 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  54 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  55 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  56 [echo foo > conftest1
  57 echo foo > conftest2
  58 fp_cv_context_diff=no
  59 for fp_var in '-U 1' '-u1' '-C 1' '-c1'
  60 do
  61   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  62     fp_cv_context_diff="diff $fp_var"
  63     break
  64   fi
  65 done])
  66 if test x"$fp_cv_context_diff" = xno; then
  67    AC_MSG_ERROR([cannot figure out how to do context diffs])
  68 fi
  69 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  70 ])# FP_PROG_CONTEXT_DIFF
  71
  72
  73 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
  74 # --------------------------------------------------------
  75 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
  76 # compilation. Execute IF-FAILS when unable to determine the value. Works for
  77 # cross-compilation, too.
  78 #
  79 # Implementation note: We are lazy and use an internal autoconf macro, but it
  80 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
  81 # little risk.
  82 AC_DEFUN([FP_COMPUTE_INT],
  83 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
  84 ])# FP_COMPUTE_INT
  85
  86
  87 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
  88 # ------------------------------------------------------------------
  89 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
  90 # given type. Defines ALIGNMENT_TYPE.
  91 AC_DEFUN([FP_CHECK_ALIGNMENT],
  92 [AS_LITERAL_IF([$1], [],
  93                [AC_FATAL([$0: requires literal arguments])])[]dnl
  94 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
  95 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
  96 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
  97 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
  98   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
  99                  [fp_Cache],
 100                  [AC_INCLUDES_DEFAULT([$3])],
 101                  [AC_MSG_ERROR([cannot compute alignment ($1)
 102 See `config.log' for more details.], [77])])
 103 else
 104   fp_Cache=0
 105 fi])[]dnl
 106 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 107 m4_popdef([fp_Cache])[]dnl
 108 ])# FP_CHECK_ALIGNMENT
 109
 110
 111 # FP_LEADING_UNDERSCORE
 112 # ---------------------
 113 # Test for determining whether symbol names have a leading underscore. We assume
 114 # that they _haven't_ if anything goes wrong. Sets the output variable
 115 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 116 #
 117 # Some nlist implementations seem to try to be compatible by ignoring a leading
 118 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 119 # checking for *no* leading underscore first. Sigh.  --SDM
 120 #
 121 # Similarly on OpenBSD, but this test doesn't help. -- dons
 122 AC_DEFUN([FP_LEADING_UNDERSCORE],
 123 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 124 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 125 # Hack!: nlist() under Digital UNIX insist on there being an _,
 126 # but symbol table listings shows none. What is going on here?!?
 127 #
 128 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 129 # the underscoredness of that "platform"
 130 case $HostPlatform in
 131 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 132   case $build in
 133     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 134     *) fptools_cv_leading_underscore=no ;;
 135   esac ;;
 136 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 137 *cygwin32) fptools_cv_leading_underscore=yes;;
 138 *mingw32) fptools_cv_leading_underscore=yes;;
 139
 140     # HACK: Apple doesn't seem to provide nlist in the 64-bit-libraries
 141 x86_64-apple-darwin*) fptools_cv_leading_underscore=yes;;
 142
 143 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 144 #include <nlist.h>
 145 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 146 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 147 #endif
 148
 149 int main(argc, argv)
 150 int argc;
 151 char **argv;
 152 {
 153 #ifdef HAVE_NLIST_H
 154     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 155         exit(1);
 156     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 157         exit(0);
 158 #endif
 159     exit(1);
 160 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 161 ;;
 162 esac]);
 163 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 164 if test x"$fptools_cv_leading_underscore" = xyes; then
 165    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 166 fi])# FP_LEADING_UNDERSCORE
 167
 168
 169 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 170 # ----------------------------------------------------------------------------------
 171 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 172 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 173 AC_DEFUN([FP_COMPARE_VERSIONS],
 174 [fp_version1=$1; fp_version2=$3
 175 fp_save_IFS=$IFS; IFS='.'
 176 while test x"$fp_version1" != x || test x"$fp_version2" != x
 177 do
 178
 179   set dummy $fp_version1; shift
 180   fp_num1=""
 181   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 182   test x"$fp_num1" = x && fp_num1="0"
 183   fp_version1="[$]*"
 184
 185   set dummy $fp_version2; shift
 186   fp_num2=""
 187   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 188   test x"$fp_num2" = x && fp_num2="0"
 189   fp_version2="[$]*"
 190
 191   test "$fp_num1" = "$fp_num2" || break;
 192 done
 193 IFS=$fp_save_IFS
 194 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 195 ])# FP_COMPARE_VERSIONS
 196
 197
 198 dnl
 199 dnl Check for GreenCard and version.
 200 dnl
 201 AC_DEFUN([FPTOOLS_GREENCARD],
 202 [
 203 AC_PATH_PROG(GreenCardCmd,greencard)
 204 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 205 changequote(, )dnl
 206 [if test x"$GreenCardCmd" != x; then
 207    fptools_cv_greencard_version="`$GreenCardCmd --version |
 208                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 209 else
 210    fptools_cv_greencard_version=""
 211 fi
 212 changequote([, ])dnl
 213 ])
 214 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 215   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 216 GreenCardVersion=$fptools_cv_greencard_version
 217 AC_SUBST(GreenCardVersion)
 218 ])
 219
 220 dnl
 221 dnl Check for Happy and version.  If we're building GHC, then we need
 222 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 223 dnl for a happy source tree and point the build system at that instead.
 224 dnl
 225 AC_DEFUN([FPTOOLS_HAPPY],
 226 [AC_PATH_PROG(HappyCmd,happy,)
 227 # Happy is passed to Cabal, so we need a native path
 228 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 229    test "${OSTYPE}"      != "msys"                  && \
 230    test "${HappyCmd}"    != ""
 231 then
 232     # Canonicalise to <drive>:/path/to/gcc
 233     HappyCmd=`cygpath -m ${HappyCmd}`
 234     AC_MSG_NOTICE([normalized happy command to $HappyCmd])
 235 fi
 236
 237 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 238 changequote(, )dnl
 239 [if test x"$HappyCmd" != x; then
 240    fptools_cv_happy_version=`"$HappyCmd" -v |
 241                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'` ;
 242 else
 243    fptools_cv_happy_version="";
 244 fi;
 245 changequote([, ])dnl
 246 ])
 247 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
 248 then
 249     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.16],
 250       [AC_MSG_ERROR([Happy version 1.16 or later is required to compile GHC.])])[]
 251 fi
 252 HappyVersion=$fptools_cv_happy_version;
 253 AC_SUBST(HappyVersion)
 254 ])
 255
 256 dnl
 257 dnl Check for Alex and version.  If we're building GHC, then we need
 258 dnl at least Alex version 2.0.1.
 259 dnl
 260 AC_DEFUN([FPTOOLS_ALEX],
 261 [
 262 AC_PATH_PROG(AlexCmd,alex,)
 263 # Alex is passed to Cabal, so we need a native path
 264 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 265    test "${OSTYPE}"      != "msys"                  && \
 266    test "${AlexCmd}"     != ""
 267 then
 268     # Canonicalise to <drive>:/path/to/gcc
 269     AlexCmd=`cygpath -m ${AlexCmd}`
 270 fi
 271
 272 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 273 changequote(, )dnl
 274 [if test x"$AlexCmd" != x; then
 275    fptools_cv_alex_version=`"$AlexCmd" -v |
 276                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'` ;
 277 else
 278    fptools_cv_alex_version="";
 279 fi;
 280 changequote([, ])dnl
 281 ])
 282 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
 283 then
 284     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.1.0],
 285       [AC_MSG_ERROR([Alex version 2.1.0 or later is required to compile GHC.])])[]
 286 fi
 287 AlexVersion=$fptools_cv_alex_version;
 288 AC_SUBST(AlexVersion)
 289 ])
 290
 291
 292
 293 # FP_PROG_LD
 294 # ----------
 295 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 296 # of ld. Exits if no ld can be found
 297 AC_DEFUN([FP_PROG_LD],
 298 [
 299 if test -z "$1"
 300 then
 301   AC_PATH_PROG([fp_prog_ld_raw], [ld])
 302   if test -z "$fp_prog_ld_raw"; then
 303     AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 304   fi
 305   LdCmd=$fp_prog_ld_raw
 306   case $HostPlatform in
 307     *mingw32) if test x${OSTYPE} != xmsys; then
 308               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 309                 AC_MSG_NOTICE([normalized ld command to $LdCmd])
 310               fi
 311             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
 312             # the generation of relocatable object files with large amounts
 313             # of relocations correctly. (cf. HSbase.o splittage-hack)
 314             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
 315             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
 316                                   [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
 317               ;;
 318   esac
 319 else
 320   LdCmd="$1"
 321 fi
 322 AC_SUBST([LdCmd])
 323 ])# FP_PROG_LD
 324
 325
 326 # FP_PROG_LD_X
 327 # ------------
 328 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 329 # variable's value is empty.
 330 AC_DEFUN([FP_PROG_LD_X],
 331 [AC_REQUIRE([FP_PROG_LD])
 332 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 333 [echo 'foo() {}' > conftest.c
 334 ${CC-cc} -c conftest.c
 335 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
 336    fp_cv_ld_x=yes
 337 else
 338    fp_cv_ld_x=no
 339 fi
 340 rm -rf conftest*])
 341 if test "$fp_cv_ld_x" = yes; then
 342   LdXFlag=-x
 343 else
 344   LdXFlag=
 345 fi
 346 AC_SUBST([LdXFlag])
 347 ])# FP_PROG_LD_X
 348
 349
 350 # FP_PROG_LD_IS_GNU
 351 # -----------------
 352 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 353 # GNU ld or not.
 354 AC_DEFUN([FP_PROG_LD_IS_GNU],
 355 [AC_REQUIRE([FP_PROG_LD])
 356 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 357 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 358   fp_cv_gnu_ld=yes
 359 else
 360   fp_cv_gnu_ld=no
 361 fi])
 362 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 363 ])# FP_PROG_LD_IS_GNU
 364
 365
 366 # FP_PROG_AR
 367 # ----------
 368 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 369 # version of it. Exits if no ar can be found
 370 AC_DEFUN([FP_PROG_AR],
 371 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 372 if test -z "$fp_prog_ar_raw"; then
 373   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 374 fi
 375 fp_prog_ar=$fp_prog_ar_raw
 376 case $HostPlatform in
 377   *mingw32) if test x${OSTYPE} != xmsys; then
 378               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 379               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 380             fi
 381             ;;
 382 esac
 383 ])# FP_PROG_AR
 384
 385
 386 # FP_PROG_AR_IS_GNU
 387 # -----------------
 388 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 389 AC_DEFUN([FP_PROG_AR_IS_GNU],
 390 [AC_REQUIRE([FP_PROG_AR])
 391 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 392 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 393   fp_cv_prog_ar_is_gnu=yes
 394 else
 395   fp_cv_prog_ar_is_gnu=no
 396 fi])
 397 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 398 ])# FP_PROG_AR_IS_GNU
 399
 400
 401 # FP_PROG_AR_ARGS
 402 # ---------------
 403 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 404 # to a non-Cygwin invocation of ar including these arguments.
 405 AC_DEFUN([FP_PROG_AR_ARGS],
 406 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 407 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 408 [
 409 # GNU ar needs special treatment: it appears to have problems with
 410 # object files with the same name if you use the 's' modifier, but
 411 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 412 if test $fp_prog_ar_is_gnu = yes; then
 413   fp_cv_prog_ar_args="q"
 414 else
 415   touch conftest.dummy
 416   for fp_var in clqsZ clqs cqs clq cq ; do
 417      rm -f conftest.a
 418      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 419         fp_cv_prog_ar_args=$fp_var
 420         break
 421      fi
 422   done
 423   rm -f conftest*
 424   if test -z "$fp_cv_prog_ar_args"; then
 425     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 426   fi
 427 fi])
 428 fp_prog_ar_args=$fp_cv_prog_ar_args
 429 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 430
 431 ])# FP_PROG_AR_ARGS
 432
 433
 434 # FP_PROG_AR_NEEDS_RANLIB
 435 # -----------------------
 436 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 437 # to ":" otherwise.
 438 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 439 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 440 AC_REQUIRE([FP_PROG_AR_ARGS])
 441 AC_REQUIRE([AC_PROG_CC])
 442 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 443 [if test $fp_prog_ar_is_gnu = yes; then
 444   fp_cv_prog_ar_needs_ranlib=no
 445 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
 446   # It's quite tedious to check for Apple's crazy timestamps in .a files,
 447   # so we hardcode it.
 448   fp_cv_prog_ar_needs_ranlib=yes
 449 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 450   fp_cv_prog_ar_needs_ranlib=no
 451 else
 452   fp_cv_prog_ar_needs_ranlib=yes
 453 fi])
 454 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 455    AC_PROG_RANLIB
 456 else
 457   RANLIB=":"
 458   AC_SUBST([RANLIB])
 459 fi
 460 ])# FP_PROG_AR_NEEDS_RANLIB
 461
 462
 463 # FP_PROG_AR_SUPPORTS_INPUT
 464 # -------------------------
 465 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 466 # whether ar supports -input flag is supported or not.
 467 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 468 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 469 AC_REQUIRE([FP_PROG_AR_ARGS])
 470 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 471 [fp_cv_prog_ar_supports_input=no
 472 if test $fp_prog_ar_is_gnu = no; then
 473   rm -f conftest*
 474   touch conftest.lst
 475   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 476     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 477   fi
 478   rm -f conftest*
 479 fi])
 480 if test $fp_cv_prog_ar_supports_input = yes; then
 481     ArSupportsInput="-input"
 482 else
 483     ArSupportsInput=""
 484 fi
 485 AC_SUBST([ArSupportsInput])
 486 ])# FP_PROG_AR_SUPPORTS_INPUT
 487
 488
 489 dnl
 490 dnl AC_SHEBANG_PERL - can we she-bang perl?
 491 dnl
 492 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
 493 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 494 [echo "#!$PerlCmd"'
 495 exit $1;
 496 ' > conftest
 497 chmod u+x conftest
 498 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 499 if test $? -ne 69; then
 500    fptools_cv_shebang_perl=yes
 501 else
 502    fptools_cv_shebang_perl=no
 503 fi
 504 rm -f conftest
 505 ])])
 506
 507
 508 # FP_HAVE_GCC
 509 # -----------
 510 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 511 # output variables HaveGcc and GccVersion.
 512 AC_DEFUN([FP_HAVE_GCC],
 513 [AC_REQUIRE([AC_PROG_CC])
 514 if test -z "$GCC"; then
 515    fp_have_gcc=NO
 516 else
 517    fp_have_gcc=YES
 518 fi
 519 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
 520   AC_MSG_ERROR([gcc is required])
 521 fi
 522 GccLT34=
 523 AC_CACHE_CHECK([version of gcc], [fp_cv_gcc_version],
 524 [if test "$fp_have_gcc" = "YES"; then
 525    fp_cv_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
 526    FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.0],
 527      [AC_MSG_ERROR([Need at least gcc version 3.0 (3.4+ recommended)])])
 528    # See #2770: gcc 2.95 doesn't work any more, apparently.  There probably
 529    # isn't a very good reason for that, but for now just make configure
 530    # fail.
 531    FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.4], GccLT34=YES)
 532  else
 533    fp_cv_gcc_version="not-installed"
 534  fi
 535 ])
 536 AC_SUBST([HaveGcc], [$fp_have_gcc])
 537 AC_SUBST([GccVersion], [$fp_cv_gcc_version])
 538 AC_SUBST(GccLT34)
 539 ])# FP_HAVE_GCC
 540
 541 AC_DEFUN([FP_MINGW_GCC],
 542 [
 543   case $HostOS_CPP in
 544     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
 545              if $CC -v 2>&1 | grep mingw >/dev/null; then
 546                 AC_MSG_RESULT([yes])
 547              else
 548                 AC_MSG_RESULT([no])
 549                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
 550              fi;;
 551     *) ;;
 552   esac
 553 ])
 554
 555 dnl Small feature test for perl version. Assumes PerlCmd
 556 dnl contains path to perl binary.
 557 dnl
 558 dnl (Perl versions prior to v5.6 does not contain the string "v5";
 559 dnl instead they display version strings such as "version 5.005".)
 560 dnl
 561 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
 562 [$PerlCmd -v >conftest.out 2>&1
 563    if grep "v5" conftest.out >/dev/null 2>&1; then
 564       :
 565    else
 566       AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
 567    fi
 568 rm -fr conftest*
 569 ])
 570
 571
 572 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 573 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 574 # -----------------------------------------------------
 575 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 576 # of PROG-TO-CHECK-FOR when found.
 577 AC_DEFUN([FP_CHECK_PROG],
 578 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 579 )# FP_CHECK_PROC
 580
 581
 582 # FP_PROG_FIND
 583 # ------------
 584 # Find a non-WinDoze version of the "find" utility.
 585 AC_DEFUN([FP_PROG_FIND],
 586 [AC_PATH_PROGS([fp_prog_find], [gfind find], find)
 587 echo foo > conftest.txt
 588 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 589 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 590   # OK, looks like a real "find".
 591   case $HostPlatform in
 592     *mingw32)
 593       if test x${OSTYPE} != xmsys
 594       then
 595             fp_prog_find="`cygpath --mixed ${fp_prog_find}`"
 596         AC_MSG_NOTICE([normalized find command to $fp_prog_find])
 597       fi ;;
 598     *) ;;
 599   esac
 600   FindCmd="$fp_prog_find"
 601 else
 602   # Found a poor WinDoze version of "find", ignore it.
 603   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 604   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 605 fi
 606 rm -f conftest.txt conftest.out
 607 AC_SUBST([FindCmd])[]dnl
 608 ])# FP_PROG_FIND
 609
 610
 611 # FP_PROG_SORT
 612 # ------------
 613 # Find a Unix-like sort
 614 AC_DEFUN([FP_PROG_SORT],
 615 [AC_PATH_PROG([fp_prog_sort], [sort])
 616 echo conwip > conftest.txt
 617 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
 618 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
 619   # The goods
 620   SortCmd="$fp_prog_sort"
 621 else
 622   # Summink else..pick next one.
 623   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
 624   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
 625 fi
 626 rm -f conftest.txt conftest.out
 627 AC_SUBST([SortCmd])[]dnl
 628 ])# FP_PROG_SORT
 629
 630 dnl
 631 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 632 dnl values of the second argument to the result of running
 633 dnl the commands given by the third. It does not cache its
 634 dnl result, so it is suitable for checks which should be
 635 dnl run every time.
 636 dnl
 637 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
 638 [AC_MSG_CHECKING([$1])
 639  $3
 640  AC_MSG_RESULT([$][$2])
 641 ])
 642
 643 dnl
 644 dnl FPTOOLS_GHC_VERSION(version)
 645 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 646 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 647 dnl
 648 dnl Test for version of installed ghc.  Uses $GHC.
 649 dnl [original version pinched from c2hs]
 650 dnl
 651 AC_DEFUN([FPTOOLS_GHC_VERSION],
 652 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 653 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 654   cat conftestghc >&AS_MESSAGE_LOG_FD
 655 #Useless Use Of cat award...
 656   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 657   rm -fr conftest*
 658   if test "[$]fptools_version_of_ghc" = ""
 659   then
 660     fptools_version_of_ghc='unknown'
 661   fi
 662 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 663 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 664 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 665 #
 666 if test "[$]fptools_version_of_ghc[_pl]" = ""
 667 then
 668   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 669   fptools_version_of_ghc[_pl]="0"
 670 else
 671   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 672 fi
 673 #
 674 ifelse($#, [1], [dnl
 675 [$1]="[$]fptools_version_of_ghc[_all]"
 676 ], $#, [2], [dnl
 677 [$1]="[$]fptools_version_of_ghc[_major]"
 678 [$2]="[$]fptools_version_of_ghc[_minor]"
 679 ], $#, [3], [dnl
 680 [$1]="[$]fptools_version_of_ghc[_major]"
 681 [$2]="[$]fptools_version_of_ghc[_minor]"
 682 [$3]="[$]fptools_version_of_ghc[_pl]"
 683 ], $#, [4], [dnl
 684 [$1]="[$]fptools_version_of_ghc[_all]"
 685 [$2]="[$]fptools_version_of_ghc[_major]"
 686 [$3]="[$]fptools_version_of_ghc[_minor]"
 687 [$4]="[$]fptools_version_of_ghc[_pl]"
 688 ])
 689 ])
 690 ])dnl
 691
 692
 693 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 694 # ---------------------------------------------------------------------------------
 695 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 696 # additional flexibility of specifying the PROLOGUE and BODY.
 697 AC_DEFUN([FP_CHECK_FUNC],
 698 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 699 AC_CACHE_CHECK([for $1], fp_func,
 700 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 701                 [AS_VAR_SET(fp_func, yes)],
 702                 [AS_VAR_SET(fp_func, no)])])
 703 AS_IF([test AS_VAR_GET(fp_func) = yes],
 704       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 705                 [Define to 1 if you have the `]$1[' function.]) $4],
 706       [$5])dnl
 707 AS_VAR_POPDEF([fp_func])dnl
 708 ])# FP_CHECK_FUNC
 709
 710
 711 # FP_GEN_DOCBOOK_XML
 712 # ------------------
 713 # Generates a DocBook XML V4.2 document in conftest.xml.
 714 #
 715 # It took a lot of experimentation to find a document that will cause
 716 # xsltproc to fail with an error code when the relevant
 717 # stylesheets/DTDs are not found.  I couldn't make xsltproc fail with
 718 # a single-file document, it seems a multi-file document is needed.
 719 # -- SDM 2009-06-03
 720 #
 721 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 722 [rm -f conftest.xml conftest-book.xml
 723 cat > conftest.xml << EOF
 724 <?xml version="1.0" encoding="iso-8859-1"?>
 725 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 726    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd" [[
 727 <!ENTITY conftest-book SYSTEM "conftest-book.xml">
 728 ]]>
 729 <book id="test">
 730 &conftest-book;
 731 </book>
 732 EOF
 733 cat >conftest-book.xml << EOF
 734 <?xml version="1.0" encoding="iso-8859-1"?>
 735   <title>A DocBook &ldquo;Test Document&rdquo;</title>
 736   <chapter id="id-one">
 737     <title>A Chapter Title</title>
 738     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 739   </chapter>
 740   <chapter id="id-two">
 741     <title>Another Chapter Title</title>
 742     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 743   </chapter>
 744 EOF
 745 ]) # FP_GEN_DOCBOOK_XML
 746
 747
 748 # FP_PROG_DBLATEX
 749 # ----------------
 750 # Sets the output variable DblatexCmd to the full path of dblatex,
 751 # which we use for building PDF and PS docs.
 752 # DblatexCmd is empty if dblatex could not be found.
 753 AC_DEFUN([FP_PROG_DBLATEX],
 754 [AC_PATH_PROG([DblatexCmd], [dblatex])
 755 if test -z "$DblatexCmd"; then
 756   AC_MSG_WARN([cannot find dblatex in your PATH, you will not be able to build the PDF and PS documentation])
 757 fi
 758 ])# FP_PROG_DBLATEX
 759
 760
 761 # FP_PROG_XSLTPROC
 762 # ----------------
 763 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 764 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 765 AC_DEFUN([FP_PROG_XSLTPROC],
 766 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 767 if test -z "$XsltprocCmd"; then
 768   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the HTML documentation])
 769 fi
 770 ])# FP_PROG_XSLTPROC
 771
 772
 773 # FP_DOCBOOK_XSL
 774 # ----------------------------
 775 # Check that we can process a DocBook XML document to HTML using xsltproc.
 776 AC_DEFUN([FP_DOCBOOK_XSL],
 777 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 778 if test -n "$XsltprocCmd"; then
 779   AC_CACHE_CHECK([for DocBook XSL stylesheet], fp_cv_dir_docbook_xsl,
 780   [FP_GEN_DOCBOOK_XML
 781   fp_cv_dir_docbook_xsl=no
 782   if $XsltprocCmd --nonet http://docbook.sourceforge.net/release/xsl/current/html/chunk.xsl conftest.xml > /dev/null 2>&1; then
 783      fp_cv_dir_docbook_xsl=yes
 784   fi
 785   rm -rf conftest*])
 786 fi
 787 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 788   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 789   HAVE_DOCBOOK_XSL=NO
 790 else
 791   HAVE_DOCBOOK_XSL=YES
 792 fi
 793 AC_SUBST([HAVE_DOCBOOK_XSL])
 794 ])# FP_DOCBOOK_XSL
 795
 796
 797 # FP_PROG_XMLLINT
 798 # ----------------
 799 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 800 # xmllint. XmllintCmd is empty if xmllint could not be found.
 801 AC_DEFUN([FP_PROG_XMLLINT],
 802 [AC_PATH_PROG([XmllintCmd], [xmllint])
 803 if test -z "$XmllintCmd"; then
 804   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 805 fi
 806 ])# FP_PROG_XMLLINT
 807
 808
 809 # FP_CHECK_DOCBOOK_DTD
 810 # --------------------
 811 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 812 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 813 if test -n "$XmllintCmd"; then
 814   AC_MSG_CHECKING([for DocBook DTD])
 815   FP_GEN_DOCBOOK_XML
 816   if $XmllintCmd --nonet --valid --noout conftest.xml ; then
 817     AC_MSG_RESULT([ok])
 818   else
 819     AC_MSG_RESULT([failed])
 820     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 821     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 822   fi
 823   rm -rf conftest*
 824 fi
 825 ])# FP_CHECK_DOCBOOK_DTD
 826
 827
 828 # FP_GEN_FO
 829 # ------------------
 830 # Generates a formatting objects document in conftest.fo.
 831 AC_DEFUN([FP_GEN_FO],
 832 [rm -f conftest.fo
 833 cat > conftest.fo << EOF
 834 <?xml version="1.0"?>
 835 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 836   <fo:layout-master-set>
 837     <fo:simple-page-master master-name="blank">
 838       <fo:region-body/>
 839     </fo:simple-page-master>
 840   </fo:layout-master-set>
 841   <fo:page-sequence master-reference="blank">
 842     <fo:flow flow-name="xsl-region-body">
 843       <fo:block>
 844         Test!
 845       </fo:block>
 846     </fo:flow>
 847   </fo:page-sequence>
 848 </fo:root>
 849 EOF
 850 ]) # FP_GEN_FO
 851
 852
 853 # FP_PROG_FOP
 854 # -----------
 855 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 856 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 857 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 858 AC_DEFUN([FP_PROG_FOP],
 859 [AC_PATH_PROGS([FopCmd1], [fop fop.sh])
 860 if test -n "$FopCmd1"; then
 861   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 862     [FP_GEN_FO
 863     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 864       fp_cv_fop_usability=yes
 865     else
 866       fp_cv_fop_usability=no
 867     fi
 868     rm -rf conftest*])
 869   if test x"$fp_cv_fop_usability" = xyes; then
 870      FopCmd=$FopCmd1
 871   fi
 872 fi
 873 if test -z "$FopCmd"; then
 874   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 875   FopCmd=$FopCmd2
 876 fi
 877 AC_SUBST([FopCmd])
 878 ])# FP_PROG_FOP
 879
 880
 881 # FP_PROG_HSTAGS
 882 # ----------------
 883 # Sets the output variable HstagsCmd to the full Haskell tags program path.
 884 # HstagsCmd is empty if no such program could be found.
 885 AC_DEFUN([FP_PROG_HSTAGS],
 886 [AC_PATH_PROG([HstagsCmd], [hasktags])
 887 if test -z "$HstagsCmd"; then
 888   AC_MSG_WARN([cannot find hasktags in your PATH, you will not be able to build the tags])
 889 fi
 890 ])# FP_PROG_HSTAGS
 891
 892
 893 # FP_PROG_GHC_PKG
 894 # ----------------
 895 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
 896 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
 897 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
 898 AC_DEFUN([FP_PROG_GHC_PKG],
 899 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
 900 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
 901 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
 902   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 903 elif "$fp_ghc_pkg_guess" list > /dev/null 2>&1; then
 904   # from 6.10, ghc-pkg doesn't support the old -l syntax any more
 905   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 906 else
 907   fp_cv_matching_ghc_pkg=no
 908 fi])
 909 if test x"$fp_cv_matching_ghc_pkg" = xno; then
 910   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
 911 else
 912   GhcPkgCmd=$fp_cv_matching_ghc_pkg
 913 fi])# FP_PROG_GHC_PKG
 914
 915
 916 # FP_GCC_EXTRA_FLAGS
 917 # ------------------
 918 # Determine which extra flags we need to pass gcc when we invoke it
 919 # to compile .hc code.
 920 #
 921 # Some OSs (Mandrake Linux, in particular) configure GCC with
 922 # -momit-leaf-frame-pointer on by default. If this is the case, we
 923 # need to turn it off for mangling to work. The test is currently a
 924 # bit crude, using only the version number of gcc.
 925 #
 926 # -fwrapv is needed for gcc to emit well-behaved code in the presence of
 927 # integer wrap around. (Trac #952)
 928 #
 929 # -fno-unit-at-a-time or -fno-toplevel-reoder is necessary to avoid gcc
 930 # reordering things in the module and confusing the manger and/or splitter.
 931 # (eg. Trac #1427)
 932 #
 933 AC_DEFUN([FP_GCC_EXTRA_FLAGS],
 934 [AC_REQUIRE([FP_HAVE_GCC])
 935 AC_CACHE_CHECK([for extra options to pass gcc when compiling via C], [fp_cv_gcc_extra_opts],
 936 [fp_cv_gcc_extra_opts=
 937  FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.4],
 938   [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fwrapv"],
 939   [])
 940  case $TargetPlatform in
 941   i386-*|x86_64-*)
 942      FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.2],
 943       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -mno-omit-leaf-frame-pointer"],
 944       [])
 945     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.4],
 946      [FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [4.2],
 947        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
 948        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-unit-at-a-time"]
 949      )],
 950      [])
 951   ;;
 952   sparc-*-solaris2)
 953     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [4.2],
 954       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
 955       [])
 956   ;;
 957  esac
 958 ])
 959 AC_SUBST([GccExtraViaCOpts],$fp_cv_gcc_extra_opts)
 960 ])
 961
 962
 963 # FP_SETUP_PROJECT_VERSION
 964 # ---------------------
 965 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
 966 [
 967 if test "$RELEASE" = "NO"; then
 968     AC_MSG_CHECKING([for GHC version date])
 969     if test -f VERSION_DATE; then
 970         PACKAGE_VERSION=${PACKAGE_VERSION}.`cat VERSION_DATE`
 971         AC_MSG_RESULT(given $PACKAGE_VERSION)
 972     elif test -d .git; then
 973         changequote(, )dnl
 974         ver_date=`git log -n 1 --date=short --pretty=format:%ci | sed "s/^.*\([0-9][0-9][0-9][0-9]\)-\([0-9][0-9]\)-\([0-9][0-9]\).*$/\1\2\3/"`
 975         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
 976         changequote([, ])dnl
 977                 AC_MSG_ERROR([failed to detect version date: check that git is in your path])
 978         fi
 979         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
 980         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
 981     elif test -d _darcs; then
 982         # TODO: Remove this branch after conversion to Git
 983         changequote(, )dnl
 984         ver_date=`darcs changes --quiet --no-summary --xml | head -500 | grep 'date=' | sed "s/^.*date='\([0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]\).*$/\1/g" | ${SortCmd} -n | tail -1`
 985         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
 986         changequote([, ])dnl
 987                 AC_MSG_ERROR([failed to detect version date: check that darcs is in your path])
 988         fi
 989         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
 990         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
 991     elif test -f VERSION; then
 992         PACKAGE_VERSION=`cat VERSION`
 993         AC_MSG_RESULT(given $PACKAGE_VERSION)
 994     else
 995         AC_MSG_WARN([cannot determine snapshot version: no .git or _darcs directory and no VERSION file])
 996     fi
 997 fi
 998
 999 # Some renamings
1000 AC_SUBST([ProjectName], [$PACKAGE_NAME])
1001 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
1002
1003 # Split PACKAGE_VERSION into (possibly empty) parts
1004 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1005 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1006 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1007 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1008
1009 # Calculate project version as an integer, using 2 digits for minor version
1010 case $VERSION_MINOR in
1011   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
1012   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
1013   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
1014 esac
1015 AC_SUBST([ProjectVersionInt])
1016
1017 # The project patchlevel is zero unless stated otherwise
1018 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
1019
1020 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
1021 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
1022
1023 AC_SUBST([ProjectPatchLevel])
1024 ])# FP_SETUP_PROJECT_VERSION
1025
1026
1027 # Check for a working timer_create().  We need a pretty detailed check
1028 # here, because there exist partially-working implementations of
1029 # timer_create() in certain versions of Linux (see bug #1933).
1030 #
1031 AC_DEFUN([FP_CHECK_TIMER_CREATE],
1032   [AC_CACHE_CHECK([for a working timer_create(CLOCK_REALTIME)],
1033     [fptools_cv_timer_create_works],
1034     [AC_TRY_RUN([
1035 #include <stdio.h>
1036 #ifdef HAVE_STDLIB_H
1037 #include <stdlib.h>
1038 #endif
1039 #ifdef HAVE_TIME_H
1040 #include <time.h>
1041 #endif
1042 #ifdef HAVE_SIGNAL_H
1043 #include <signal.h>
1044 #endif
1045 #ifdef HAVE_UNISTD_H
1046 #include <unistd.h>
1047 #endif
1048
1049 static volatile int tock = 0;
1050 static void handler(int i)
1051 {
1052    tock = 1;
1053 }
1054
1055 static void timeout(int i)
1056 {
1057   // timer_settime() has been known to hang, so just in case
1058   // we install a 1-second timeout (see #2257)
1059   exit(99);
1060 }
1061
1062 int main(int argc, char *argv[])
1063 {
1064
1065     struct sigevent ev;
1066     timer_t timer;
1067     struct itimerspec it;
1068     struct sigaction action;
1069     int m,n,count = 0;
1070
1071     ev.sigev_notify = SIGEV_SIGNAL;
1072     ev.sigev_signo  = SIGVTALRM;
1073
1074     action.sa_handler = handler;
1075     action.sa_flags = 0;
1076     sigemptyset(&action.sa_mask);
1077     if (sigaction(SIGVTALRM, &action, NULL) == -1) {
1078         fprintf(stderr,"SIGVTALRM problem\n");
1079         exit(3);
1080     }
1081
1082     action.sa_handler = timeout;
1083     action.sa_flags = 0;
1084     sigemptyset(&action.sa_mask);
1085     if (sigaction(SIGALRM, &action, NULL) == -1) {
1086       fprintf(stderr,"SIGALRM problem\n");
1087       exit(3);
1088     }
1089     alarm(1);
1090
1091     if (timer_create(CLOCK_PROCESS_CPUTIME_ID, &ev, &timer) != 0) {
1092         fprintf(stderr,"No CLOCK_PROCESS_CPUTIME_ID timer\n");
1093        exit(1);
1094     }
1095
1096     it.it_value.tv_sec = 0;
1097     it.it_value.tv_nsec = 1;
1098     it.it_interval = it.it_value;
1099     if (timer_settime(timer, 0, &it, NULL) != 0) {
1100         fprintf(stderr,"settime problem\n");
1101         exit(4);
1102     }
1103
1104     tock = 0;
1105
1106     for(n = 3; n < 20000; n++){
1107         for(m = 2; m <= n/2; m++){
1108             if (!(n%m)) count++;
1109             if (tock) goto out;
1110         }
1111     }
1112 out:
1113
1114     if (!tock) {
1115         fprintf(stderr,"no CLOCK_PROCESS_CPUTIME_ID signal\n");
1116         exit(5);
1117     }
1118
1119     timer_delete(timer);
1120
1121     if (timer_create(CLOCK_REALTIME, &ev, &timer) != 0) {
1122         fprintf(stderr,"No CLOCK_REALTIME timer\n");
1123         exit(2);
1124     }
1125
1126     it.it_value.tv_sec = 0;
1127     it.it_value.tv_nsec = 1000000;
1128     it.it_interval = it.it_value;
1129     if (timer_settime(timer, 0, &it, NULL) != 0) {
1130         fprintf(stderr,"settime problem\n");
1131         exit(4);
1132     }
1133
1134     tock = 0;
1135
1136     usleep(3000);
1137
1138     if (!tock) {
1139         fprintf(stderr,"no CLOCK_REALTIME signal\n");
1140         exit(5);
1141     }
1142
1143     timer_delete(timer);
1144
1145     exit(0);
1146 }
1147      ],
1148      [fptools_cv_timer_create_works=yes],
1149      [fptools_cv_timer_create_works=no])
1150   ])
1151 case $fptools_cv_timer_create_works in
1152     yes) AC_DEFINE([USE_TIMER_CREATE], 1,
1153                    [Define to 1 if we can use timer_create(CLOCK_PROCESS_CPUTIME_ID,...)]);;
1154 esac
1155 ])
1156
1157 # FP_ARG_GMP
1158 # -------------
1159 AC_DEFUN([FP_ARG_GMP],
1160 [
1161 AC_ARG_WITH([gmp-includes],
1162   [AC_HELP_STRING([--with-gmp-includes],
1163     [directory containing gmp.h])],
1164     [gmp_includes=$withval],
1165     [gmp_includes=NONE])
1166
1167 AC_ARG_WITH([gmp-libraries],
1168   [AC_HELP_STRING([--with-gmp-libraries],
1169     [directory containing gmp library])],
1170     [gmp_libraries=$withval],
1171     [gmp_libraries=NONE])
1172 ])# FP_ARG_GMP
1173
1174 AC_DEFUN([CHECK_GMP],
1175 [AC_REQUIRE([AC_PROG_CPP])
1176 AC_REQUIRE([AC_PROG_CC])
1177 ])
1178
1179 # FP_CHECK_MACOSX_DEPLOYMENT_TARGET
1180 # ---------------------------------
1181 AC_DEFUN([FP_CHECK_MACOSX_DEPLOYMENT_TARGET],
1182 [
1183 if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple"; then
1184   AC_MSG_CHECKING([Mac OS X deployment target])
1185   case $FP_MACOSX_DEPLOYMENT_TARGET in
1186     none)  ;;
1187     10.4)  MACOSX_DEPLOYMENT_VERSION=10.4
1188            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1189            ;;
1190     10.4u) MACOSX_DEPLOYMENT_VERSION=10.4
1191            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1192            ;;
1193     *)     MACOSX_DEPLOYMENT_VERSION=$FP_MACOSX_DEPLOYMENT_TARGET
1194            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX${FP_MACOSX_DEPLOYMENT_TARGET}.sdk
1195            ;;
1196   esac
1197   if test "x$FP_MACOSX_DEPLOYMENT_TARGET" = "xnone"; then
1198     AC_MSG_RESULT(none)
1199   else
1200     if test ! -d $MACOSX_DEPLOYMENT_SDK; then
1201       AC_MSG_ERROR([Unknown deployment target $FP_MACOSX_DEPLOYMENT_TARGET])
1202     fi
1203     AC_MSG_RESULT([${MACOSX_DEPLOYMENT_VERSION} (${MACOSX_DEPLOYMENT_SDK})])
1204   fi
1205 fi
1206 ])
1207
1208 # --------------------------------------------------------------
1209 # Calculate absolute path to build tree
1210 # --------------------------------------------------------------
1211
1212 AC_DEFUN([FP_FIND_ROOT],[
1213 AC_MSG_CHECKING(for path to top of build tree)
1214
1215 dnl This would be
1216 dnl     make -C utils/ghc-pwd clean && make -C utils/ghc-pwd
1217 dnl except we don't want to have to know what make is called. Sigh.
1218 if test ! -f utils/ghc-pwd/ghc-pwd && test ! -f utils/ghc-pwd/ghc-pwd.exe; then
1219   cd utils/ghc-pwd
1220   rm -f *.o
1221   rm -f *.hi
1222   rm -f ghc-pwd
1223   rm -f ghc-pwd.exe
1224   $WithGhc -v0 --make ghc-pwd -o ghc-pwd
1225   cd ../..
1226 fi
1227
1228 hardtop=`utils/ghc-pwd/ghc-pwd`
1229
1230 if ! test -d "$hardtop"; then
1231   AC_MSG_ERROR([cannot determine current directory])
1232 fi
1233
1234 dnl Remove common automounter nonsense
1235 dnl
1236 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|'`
1237
1238 AC_SUBST(hardtop)
1239
1240 AC_MSG_RESULT(${hardtop})
1241
1242 # We don't support building in directories with spaces.
1243 case "$hardtop" in
1244   *' '*) AC_MSG_ERROR([
1245    The build system does not support building in a directory containing
1246    space characters.  Suggestion: move the build tree somewhere else.])
1247  ;;
1248 esac
1249 ])
1250
1251 # LocalWords:  fi