aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
   8 # ----------------------------------
   9 # Little endian Arm on Linux with some ABIs has big endian word order
  10 # in doubles. Define FLOAT_WORDS_BIGENDIAN if this is the case.
  11 AC_DEFUN([FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN],
  12   [AC_CACHE_CHECK([whether float word order is big endian], [fptools_cv_float_word_order_bigendian],
  13     [AC_COMPILE_IFELSE(
  14       [AC_LANG_PROGRAM(
  15         [#include <endian.h>],
  16         [#if defined(__FLOAT_WORD_ORDER) && __FLOAT_WORD_ORDER == BIG_ENDIAN
  17              return 0;
  18          #else
  19              not float word order big endian
  20          #endif]
  21       )],
  22       [fptools_cv_float_word_order_bigendian=yes],
  23       [fptools_cv_float_word_order_bigendian=no])
  24     ])
  25   case $fptools_cv_float_word_order_bigendian in
  26       yes)
  27           AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
  28           [Define to 1 if your processor stores words of floats with
  29            the most significant byte first]) ;;
  30   esac
  31 ])
  32
  33
  34 # FP_EVAL_STDERR(COMMAND)
  35 # -----------------------
  36 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  37 # into the file conftest.err and the exit status in the variable fp_status.
  38 AC_DEFUN([FP_EVAL_STDERR],
  39 [{ (eval $1) 2>conftest.er1
  40   fp_status=$?
  41   grep -v '^ *+' conftest.er1 >conftest.err
  42   rm -f conftest.er1
  43   (exit $fp_status); }[]dnl
  44 ])# FP_EVAL_STDERR
  45
  46
  47 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
  48 # ---------------------------------------------------------------------
  49 # Check to see whether the compiler for the current language supports a
  50 # particular option.
  51 #
  52 # Implementation note: When given an unkown option, GCC issues an warning on
  53 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
  54 # to check stderr *and* the exit value.
  55 #
  56 # Used by ghc.
  57 AC_DEFUN([FP_CHECK_FLAG],
  58 [AC_LANG_COMPILER_REQUIRE()dnl
  59 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
  60              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
  61              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
  62 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
  63 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
  64 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
  65 fp_save_flags="$fp_Flags"
  66 fp_Flags="$fp_Flags $1"
  67 fp_Cache=no
  68 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  69   test -s conftest.err || fp_Cache=yes
  70 fi
  71 fp_Flags="$fp_save_flags"
  72 rm -f conftest.err conftest.$ac_ext])
  73 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
  74 m4_popdef([fp_Cache])[]dnl
  75 m4_popdef([fp_Flags])[]dnl
  76 ])# FP_CHECK_FLAG
  77
  78
  79 # FP_PROG_CONTEXT_DIFF
  80 # --------------------
  81 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  82 #
  83 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  84 #
  85 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  86 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  87 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  88 [echo foo > conftest1
  89 echo foo > conftest2
  90 fp_cv_context_diff=no
  91 for fp_var in '-C 1' '-c1'
  92 do
  93   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  94     fp_cv_context_diff="diff $fp_var"
  95     break
  96   fi
  97 done])
  98 if test x"$fp_cv_context_diff" = xno; then
  99    AC_MSG_ERROR([cannot figure out how to do context diffs])
 100 fi
 101 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
 102 ])# FP_PROG_CONTEXT_DIFF
 103
 104
 105 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
 106 # --------------------------------------------------------
 107 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
 108 # compilation. Execute IF-FAILS when unable to determine the value. Works for
 109 # cross-compilation, too.
 110 #
 111 # Implementation note: We are lazy and use an internal autoconf macro, but it
 112 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
 113 # little risk.
 114 AC_DEFUN([FP_COMPUTE_INT],
 115 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
 116 ])# FP_COMPUTE_INT
 117
 118
 119 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
 120 # ------------------------------------------------------------------
 121 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
 122 # given type. Defines ALIGNMENT_TYPE.
 123 AC_DEFUN([FP_CHECK_ALIGNMENT],
 124 [AS_LITERAL_IF([$1], [],
 125                [AC_FATAL([$0: requires literal arguments])])[]dnl
 126 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 127 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 128 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 129 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 130   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 131                  [fp_Cache],
 132                  [AC_INCLUDES_DEFAULT([$3])],
 133                  [AC_MSG_ERROR([cannot compute alignment ($1)
 134 See `config.log' for more details.], [77])])
 135 else
 136   fp_Cache=0
 137 fi])[]dnl
 138 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 139 m4_popdef([fp_Cache])[]dnl
 140 ])# FP_CHECK_ALIGNMENT
 141
 142
 143 # FP_LEADING_UNDERSCORE
 144 # ---------------------
 145 # Test for determining whether symbol names have a leading underscore. We assume
 146 # that they _haven't_ if anything goes wrong. Sets the output variable
 147 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 148 #
 149 # Some nlist implementations seem to try to be compatible by ignoring a leading
 150 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 151 # checking for *no* leading underscore first. Sigh.  --SDM
 152 #
 153 # Similarly on OpenBSD, but this test doesn't help. -- dons
 154 AC_DEFUN([FP_LEADING_UNDERSCORE],
 155 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 156 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 157 # Hack!: nlist() under Digital UNIX insist on there being an _,
 158 # but symbol table listings shows none. What is going on here?!?
 159 #
 160 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 161 # the underscoredness of that "platform"
 162 case $HostPlatform in
 163 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 164   case $build in
 165     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 166     *) fptools_cv_leading_underscore=no ;;
 167   esac ;;
 168 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 169 *cygwin32) fptools_cv_leading_underscore=yes;;
 170 *mingw32) fptools_cv_leading_underscore=yes;;
 171
 172     # HACK: Apple doesn't seem to provide nlist in the 64-bit-libraries
 173 x86_64-apple-darwin*) fptools_cv_leading_underscore=yes;;
 174
 175 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 176 #include <nlist.h>
 177 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 178 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 179 #endif
 180
 181 int main(argc, argv)
 182 int argc;
 183 char **argv;
 184 {
 185 #ifdef HAVE_NLIST_H
 186     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 187         exit(1);
 188     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 189         exit(0);
 190 #endif
 191     exit(1);
 192 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 193 ;;
 194 esac]);
 195 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 196 if test x"$fptools_cv_leading_underscore" = xyes; then
 197    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 198 fi])# FP_LEADING_UNDERSCORE
 199
 200
 201 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 202 # ----------------------------------------------------------------------------------
 203 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 204 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 205 AC_DEFUN([FP_COMPARE_VERSIONS],
 206 [fp_version1=$1; fp_version2=$3
 207 fp_save_IFS=$IFS; IFS='.'
 208 while test x"$fp_version1" != x || test x"$fp_version2" != x
 209 do
 210
 211   set dummy $fp_version1; shift
 212   fp_num1=""
 213   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 214   test x"$fp_num1" = x && fp_num1="0"
 215   fp_version1="[$]*"
 216
 217   set dummy $fp_version2; shift
 218   fp_num2=""
 219   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 220   test x"$fp_num2" = x && fp_num2="0"
 221   fp_version2="[$]*"
 222
 223   test "$fp_num1" = "$fp_num2" || break;
 224 done
 225 IFS=$fp_save_IFS
 226 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 227 ])# FP_COMPARE_VERSIONS
 228
 229
 230 dnl
 231 dnl Check for GreenCard and version.
 232 dnl
 233 AC_DEFUN([FPTOOLS_GREENCARD],
 234 [
 235 AC_PATH_PROG(GreenCardCmd,greencard)
 236 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 237 changequote(, )dnl
 238 [if test x"$GreenCardCmd" != x; then
 239    fptools_cv_greencard_version="`$GreenCardCmd --version |
 240                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 241 else
 242    fptools_cv_greencard_version=""
 243 fi
 244 changequote([, ])dnl
 245 ])
 246 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 247   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 248 GreenCardVersion=$fptools_cv_greencard_version
 249 AC_SUBST(GreenCardVersion)
 250 ])
 251
 252 dnl
 253 dnl Check for Happy and version.  If we're building GHC, then we need
 254 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 255 dnl for a happy source tree and point the build system at that instead.
 256 dnl
 257 AC_DEFUN([FPTOOLS_HAPPY],
 258 [AC_PATH_PROG(HappyCmd,happy,)
 259 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 260 changequote(, )dnl
 261 [if test x"$HappyCmd" != x; then
 262    fptools_cv_happy_version="`$HappyCmd -v |
 263                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 264 else
 265    fptools_cv_happy_version="";
 266 fi;
 267 changequote([, ])dnl
 268 ])
 269 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/main/ParsePkgConf.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
 270 then
 271     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
 272       [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
 273 fi
 274 HappyVersion=$fptools_cv_happy_version;
 275 AC_SUBST(HappyVersion)
 276 ])
 277
 278 dnl
 279 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 280 dnl for a haddock source tree and point the build system at that instead.
 281 dnl
 282 AC_DEFUN([FPTOOLS_HADDOCK],
 283 [AC_PATH_PROG(HaddockCmd,haddock,)
 284 dnl Darn, I forgot to make Haddock print out its version number when
 285 dnl invoked with -v.  We could try generating some HTML and grepping
 286 dnl through that to find the version number, but I think we'll make
 287 dnl do without it for now.
 288 ])
 289
 290 dnl
 291 dnl Check for Alex and version.  If we're building GHC, then we need
 292 dnl at least Alex version 2.0.1.
 293 dnl
 294 AC_DEFUN([FPTOOLS_ALEX],
 295 [
 296 AC_PATH_PROG(AlexCmd,alex,)
 297 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 298 changequote(, )dnl
 299 [if test x"$AlexCmd" != x; then
 300    fptools_cv_alex_version="`$AlexCmd -v |
 301                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 302 else
 303    fptools_cv_alex_version="";
 304 fi;
 305 changequote([, ])dnl
 306 ])
 307 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
 308 then
 309     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0.1],
 310       [AC_MSG_ERROR([Alex version 2.0.1 or later is required to compile GHC.])])[]dnl
 311 fi
 312 AlexVersion=$fptools_cv_alex_version;
 313 AC_SUBST(AlexVersion)
 314 ])
 315
 316
 317 # FP_PROG_LD
 318 # ----------
 319 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 320 # of ld. Exits if no ld can be found
 321 AC_DEFUN([FP_PROG_LD],
 322 [AC_PATH_PROG([fp_prog_ld_raw], [ld])
 323 if test -z "$fp_prog_ld_raw"; then
 324   AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 325 fi
 326 LdCmd=$fp_prog_ld_raw
 327 case $HostPlatform in
 328   *mingw32) if test x${OSTYPE} != xmsys; then
 329               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 330               AC_MSG_NOTICE([normalized ld command to $LdCmd])
 331             fi
 332             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
 333             # the generation of relocatable object files with large amounts
 334             # of relocations correctly. (cf. HSbase.o splittage-hack)
 335             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
 336             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
 337                                 [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
 338             ;;
 339 esac
 340 AC_SUBST([LdCmd])
 341 ])# FP_PROG_LD
 342
 343
 344 # FP_PROG_LD_X
 345 # ------------
 346 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 347 # variable's value is empty.
 348 AC_DEFUN([FP_PROG_LD_X],
 349 [AC_REQUIRE([FP_PROG_LD])
 350 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 351 [echo 'foo() {}' > conftest.c
 352 ${CC-cc} -c conftest.c
 353 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
 354    fp_cv_ld_x=yes
 355 else
 356    fp_cv_ld_x=no
 357 fi
 358 rm -rf conftest*])
 359 if test "$fp_cv_ld_x" = yes; then
 360   LdXFlag=-x
 361 else
 362   LdXFlag=
 363 fi
 364 AC_SUBST([LdXFlag])
 365 ])# FP_PROG_LD_X
 366
 367
 368 # FP_PROG_LD_IS_GNU
 369 # -----------------
 370 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 371 # GNU ld or not.
 372 AC_DEFUN([FP_PROG_LD_IS_GNU],
 373 [AC_REQUIRE([FP_PROG_LD])
 374 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 375 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 376   fp_cv_gnu_ld=yes
 377 else
 378   fp_cv_gnu_ld=no
 379 fi])
 380 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 381 ])# FP_PROG_LD_IS_GNU
 382
 383
 384 # FP_PROG_AR
 385 # ----------
 386 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 387 # version of it. Exits if no ar can be found
 388 AC_DEFUN([FP_PROG_AR],
 389 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 390 if test -z "$fp_prog_ar_raw"; then
 391   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 392 fi
 393 fp_prog_ar=$fp_prog_ar_raw
 394 case $HostPlatform in
 395   *mingw32) if test x${OSTYPE} != xmsys; then
 396               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 397               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 398             fi
 399             ;;
 400 esac
 401 ])# FP_PROG_AR
 402
 403
 404 # FP_PROG_AR_IS_GNU
 405 # -----------------
 406 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 407 AC_DEFUN([FP_PROG_AR_IS_GNU],
 408 [AC_REQUIRE([FP_PROG_AR])
 409 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 410 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 411   fp_cv_prog_ar_is_gnu=yes
 412 else
 413   fp_cv_prog_ar_is_gnu=no
 414 fi])
 415 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 416 ])# FP_PROG_AR_IS_GNU
 417
 418
 419 # FP_PROG_AR_ARGS
 420 # ---------------
 421 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 422 # to a non-Cygwin invocation of ar including these arguments.
 423 AC_DEFUN([FP_PROG_AR_ARGS],
 424 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 425 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 426 [
 427 # GNU ar needs special treatment: it appears to have problems with
 428 # object files with the same name if you use the 's' modifier, but
 429 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 430 if test $fp_prog_ar_is_gnu = yes; then
 431   fp_cv_prog_ar_args="q"
 432 else
 433   touch conftest.dummy
 434   for fp_var in clqsZ clqs cqs clq cq ; do
 435      rm -f conftest.a
 436      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 437         fp_cv_prog_ar_args=$fp_var
 438         break
 439      fi
 440   done
 441   rm -f conftest*
 442   if test -z "$fp_cv_prog_ar_args"; then
 443     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 444   fi
 445 fi])
 446 fp_prog_ar_args=$fp_cv_prog_ar_args
 447 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 448
 449 ])# FP_PROG_AR_ARGS
 450
 451
 452 # FP_PROG_AR_NEEDS_RANLIB
 453 # -----------------------
 454 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 455 # to ":" otherwise.
 456 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 457 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 458 AC_REQUIRE([FP_PROG_AR_ARGS])
 459 AC_REQUIRE([AC_PROG_CC])
 460 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 461 [if test $fp_prog_ar_is_gnu = yes; then
 462   fp_cv_prog_ar_needs_ranlib=no
 463 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
 464   # It's quite tedious to check for Apple's crazy timestamps in .a files,
 465   # so we hardcode it.
 466   fp_cv_prog_ar_needs_ranlib=yes
 467 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 468   fp_cv_prog_ar_needs_ranlib=no
 469 else
 470   fp_cv_prog_ar_needs_ranlib=yes
 471 fi])
 472 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 473    AC_PROG_RANLIB
 474 else
 475   RANLIB=":"
 476   AC_SUBST([RANLIB])
 477 fi
 478 ])# FP_PROG_AR_NEEDS_RANLIB
 479
 480
 481 # FP_PROG_AR_SUPPORTS_INPUT
 482 # -------------------------
 483 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 484 # whether ar supports -input flag is supported or not.
 485 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 486 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 487 AC_REQUIRE([FP_PROG_AR_ARGS])
 488 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 489 [fp_cv_prog_ar_supports_input=no
 490 if test $fp_prog_ar_is_gnu = no; then
 491   rm -f conftest*
 492   touch conftest.lst
 493   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 494     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 495   fi
 496   rm -f conftest*
 497 fi])
 498 if test $fp_cv_prog_ar_supports_input = yes; then
 499     ArSupportsInput="-input"
 500 else
 501     ArSupportsInput=""
 502 fi
 503 AC_SUBST([ArSupportsInput])
 504 ])# FP_PROG_AR_SUPPORTS_INPUT
 505
 506
 507 dnl
 508 dnl AC_SHEBANG_PERL - can we she-bang perl?
 509 dnl
 510 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
 511 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 512 [echo "#!$PerlCmd"'
 513 exit $1;
 514 ' > conftest
 515 chmod u+x conftest
 516 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 517 if test $? -ne 69; then
 518    fptools_cv_shebang_perl=yes
 519 else
 520    fptools_cv_shebang_perl=no
 521 fi
 522 rm -f conftest
 523 ])])
 524
 525
 526 # FP_HAVE_GCC
 527 # -----------
 528 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 529 # output variables HaveGcc and GccVersion.
 530 AC_DEFUN([FP_HAVE_GCC],
 531 [AC_REQUIRE([AC_PROG_CC])
 532 if test -z "$GCC"; then
 533    fp_have_gcc=NO
 534 else
 535    fp_have_gcc=YES
 536 fi
 537 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
 538   AC_MSG_ERROR([gcc is required])
 539 fi
 540 AC_CACHE_CHECK([version of gcc], [fp_gcc_version],
 541 [if test "$fp_have_gcc" = "YES"; then
 542    fp_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
 543    FP_COMPARE_VERSIONS([$fp_gcc_version], [-lt], [2.0],
 544      [AC_MSG_ERROR([Need at least gcc version 2.0 (3.4+ recommended)])])
 545  else
 546    fp_gcc_version="not-installed"
 547  fi
 548 ])
 549 AC_SUBST([HaveGcc], [$fp_have_gcc])
 550 AC_SUBST([GccVersion], [$fp_gcc_version])
 551 ])# FP_HAVE_GCC
 552
 553 AC_DEFUN([FP_MINGW_GCC],
 554 [
 555   case $HostOS_CPP in
 556     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
 557              if $CC -v 2>&1 | grep mingw >/dev/null; then
 558                 AC_MSG_RESULT([yes])
 559              else
 560                 AC_MSG_RESULT([no])
 561                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
 562              fi;;
 563     *) ;;
 564   esac
 565 ])
 566
 567 dnl Small feature test for perl version. Assumes PerlCmd
 568 dnl contains path to perl binary
 569 dnl
 570 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
 571 [$PerlCmd -v >conftest.out 2>&1
 572    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 573       :
 574    else
 575       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 576          :
 577       else
 578          if grep "version 6" conftest.out >/dev/null 2>&1; then
 579             :
 580          else
 581             AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
 582          fi
 583       fi
 584    fi
 585 rm -fr conftest*
 586 ])
 587
 588
 589 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 590 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 591 # -----------------------------------------------------
 592 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 593 # of PROG-TO-CHECK-FOR when found.
 594 AC_DEFUN([FP_CHECK_PROG],
 595 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 596 )# FP_CHECK_PROC
 597
 598
 599 # FP_PROG_FIND
 600 # ------------
 601 # Find a non-WinDoze version of the "find" utility.
 602 AC_DEFUN([FP_PROG_FIND],
 603 [AC_PATH_PROG([fp_prog_find], [find])
 604 echo foo > conftest.txt
 605 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 606 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 607   # OK, looks like a real "find".
 608   FindCmd="$fp_prog_find"
 609 else
 610   # Found a poor WinDoze version of "find", ignore it.
 611   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 612   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 613 fi
 614 rm -f conftest.txt conftest.out
 615 AC_SUBST([FindCmd])[]dnl
 616 ])# FP_PROG_FIND
 617
 618
 619 # FP_PROG_SORT
 620 # ------------
 621 # Find a Unix-like sort
 622 AC_DEFUN([FP_PROG_SORT],
 623 [AC_PATH_PROG([fp_prog_sort], [sort])
 624 echo conwip > conftest.txt
 625 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
 626 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
 627   # The goods
 628   SortCmd="$fp_prog_sort"
 629 else
 630   # Summink else..pick next one.
 631   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
 632   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
 633 fi
 634 rm -f conftest.txt conftest.out
 635 AC_SUBST([SortCmd])[]dnl
 636 ])# FP_PROG_SORT
 637
 638 dnl
 639 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 640 dnl values of the second argument to the result of running
 641 dnl the commands given by the third. It does not cache its
 642 dnl result, so it is suitable for checks which should be
 643 dnl run every time.
 644 dnl
 645 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
 646 [AC_MSG_CHECKING([$1])
 647  $3
 648  AC_MSG_RESULT([$][$2])
 649 ])
 650
 651 dnl
 652 dnl FPTOOLS_GHC_VERSION(version)
 653 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 654 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 655 dnl
 656 dnl Test for version of installed ghc.  Uses $GHC.
 657 dnl [original version pinched from c2hs]
 658 dnl
 659 AC_DEFUN([FPTOOLS_GHC_VERSION],
 660 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 661 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 662   cat conftestghc >&AS_MESSAGE_LOG_FD
 663 #Useless Use Of cat award...
 664   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 665   rm -fr conftest*
 666   if test "[$]fptools_version_of_ghc" = ""
 667   then
 668     fptools_version_of_ghc='unknown'
 669   fi
 670 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 671 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 672 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 673 #
 674 if test "[$]fptools_version_of_ghc[_pl]" = ""
 675 then
 676   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 677   fptools_version_of_ghc[_pl]="0"
 678 else
 679   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 680 fi
 681 #
 682 ifelse($#, [1], [dnl
 683 [$1]="[$]fptools_version_of_ghc[_all]"
 684 ], $#, [2], [dnl
 685 [$1]="[$]fptools_version_of_ghc[_major]"
 686 [$2]="[$]fptools_version_of_ghc[_minor]"
 687 ], $#, [3], [dnl
 688 [$1]="[$]fptools_version_of_ghc[_major]"
 689 [$2]="[$]fptools_version_of_ghc[_minor]"
 690 [$3]="[$]fptools_version_of_ghc[_pl]"
 691 ], $#, [4], [dnl
 692 [$1]="[$]fptools_version_of_ghc[_all]"
 693 [$2]="[$]fptools_version_of_ghc[_major]"
 694 [$3]="[$]fptools_version_of_ghc[_minor]"
 695 [$4]="[$]fptools_version_of_ghc[_pl]"
 696 ])
 697 ])
 698 ])dnl
 699
 700
 701 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 702 # ---------------------------------------------------------------------------------
 703 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 704 # additional flexibility of specifying the PROLOGUE and BODY.
 705 AC_DEFUN([FP_CHECK_FUNC],
 706 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 707 AC_CACHE_CHECK([for $1], fp_func,
 708 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 709                 [AS_VAR_SET(fp_func, yes)],
 710                 [AS_VAR_SET(fp_func, no)])])
 711 AS_IF([test AS_VAR_GET(fp_func) = yes],
 712       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 713                 [Define to 1 if you have the `]$1[' function.]) $4],
 714       [$5])dnl
 715 AS_VAR_POPDEF([fp_func])dnl
 716 ])# FP_CHECK_FUNC
 717
 718
 719 # FP_GEN_DOCBOOK_XML
 720 # ------------------
 721 # Generates a DocBook XML V4.2 document in conftest.xml.
 722 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 723 [rm -f conftest.xml
 724 cat > conftest.xml << EOF
 725 <?xml version="1.0" encoding="iso-8859-1"?>
 726 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 727    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 728 <book id="test">
 729   <title>A DocBook Test Document</title>
 730   <chapter id="id-one">
 731     <title>A Chapter Title</title>
 732     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 733   </chapter>
 734   <chapter id="id-two">
 735     <title>Another Chapter Title</title>
 736     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 737   </chapter>
 738 </book>
 739 EOF
 740 ]) # FP_GEN_DOCBOOK_XML
 741
 742
 743 # FP_PROG_XSLTPROC
 744 # ----------------
 745 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 746 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 747 AC_DEFUN([FP_PROG_XSLTPROC],
 748 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 749 if test -z "$XsltprocCmd"; then
 750   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 751 fi
 752 ])# FP_PROG_XSLTPROC
 753
 754
 755 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 756 # ----------------------------
 757 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 758 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 759 # will be empty if none could be found.
 760 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 761 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 762 if test -n "$XsltprocCmd"; then
 763   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 764   [FP_GEN_DOCBOOK_XML
 765   fp_cv_dir_docbook_xsl=no
 766   for fp_var in $1; do
 767      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 768         fp_cv_dir_docbook_xsl=$fp_var
 769         break
 770      fi
 771   done
 772   rm -rf conftest*])
 773 fi
 774 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 775   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 776   DIR_DOCBOOK_XSL=
 777 else
 778   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 779 fi
 780 AC_SUBST([DIR_DOCBOOK_XSL])
 781 ])# FP_DIR_DOCBOOK_XSL
 782
 783
 784 # FP_PROG_XMLLINT
 785 # ----------------
 786 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 787 # xmllint. XmllintCmd is empty if xmllint could not be found.
 788 AC_DEFUN([FP_PROG_XMLLINT],
 789 [AC_PATH_PROG([XmllintCmd], [xmllint])
 790 if test -z "$XmllintCmd"; then
 791   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 792 fi
 793 ])# FP_PROG_XMLLINT
 794
 795
 796 # FP_CHECK_DOCBOOK_DTD
 797 # --------------------
 798 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 799 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 800 if test -n "$XmllintCmd"; then
 801   AC_MSG_CHECKING([for DocBook DTD])
 802   FP_GEN_DOCBOOK_XML
 803   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 804     AC_MSG_RESULT([ok])
 805   else
 806     AC_MSG_RESULT([failed])
 807     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 808     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 809   fi
 810   rm -rf conftest*
 811 fi
 812 ])# FP_CHECK_DOCBOOK_DTD
 813
 814
 815 # FP_GEN_FO
 816 # ------------------
 817 # Generates a formatting objects document in conftest.fo.
 818 AC_DEFUN([FP_GEN_FO],
 819 [rm -f conftest.fo
 820 cat > conftest.fo << EOF
 821 <?xml version="1.0"?>
 822 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 823   <fo:layout-master-set>
 824     <fo:simple-page-master master-name="blank">
 825       <fo:region-body/>
 826     </fo:simple-page-master>
 827   </fo:layout-master-set>
 828   <fo:page-sequence master-reference="blank">
 829     <fo:flow flow-name="xsl-region-body">
 830       <fo:block>
 831         Test!
 832       </fo:block>
 833     </fo:flow>
 834   </fo:page-sequence>
 835 </fo:root>
 836 EOF
 837 ]) # FP_GEN_FO
 838
 839
 840 # FP_PROG_FOP
 841 # -----------
 842 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 843 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 844 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 845 AC_DEFUN([FP_PROG_FOP],
 846 [AC_PATH_PROGS([FopCmd1], [fop fop.sh])
 847 if test -n "$FopCmd1"; then
 848   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 849     [FP_GEN_FO
 850     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 851       fp_cv_fop_usability=yes
 852     else
 853       fp_cv_fop_usability=no
 854     fi
 855     rm -rf conftest*])
 856   if test x"$fp_cv_fop_usability" = xyes; then
 857      FopCmd=$FopCmd1
 858   fi
 859 fi
 860 if test -z "$FopCmd"; then
 861   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 862   FopCmd=$FopCmd2
 863 fi
 864 AC_SUBST([FopCmd])
 865 ])# FP_PROG_FOP
 866
 867
 868 # FP_PROG_FO_PROCESSOR
 869 # --------------------
 870 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
 871 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
 872 # PdfxmltexCmd.
 873 AC_DEFUN([FP_PROG_FO_PROCESSOR],
 874 [AC_REQUIRE([FP_PROG_FOP])
 875 AC_PATH_PROG([XmltexCmd], [xmltex])
 876 AC_PATH_PROG([DvipsCmd], [dvips])
 877 if test -z "$FopCmd"; then
 878   if test -z "$XmltexCmd"; then
 879     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
 880   else
 881     if test -z "$DvipsCmd"; then
 882       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
 883     fi
 884   fi
 885   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
 886   if test -z "$PdfxmltexCmd"; then
 887     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
 888   fi
 889 elif test -z "$XmltexCmd"; then
 890   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
 891 fi
 892 ])# FP_PROG_FO_PROCESSOR
 893
 894
 895 # FP_PROG_GHC_PKG
 896 # ----------------
 897 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
 898 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
 899 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
 900 AC_DEFUN([FP_PROG_GHC_PKG],
 901 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
 902 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
 903 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
 904   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 905 else
 906   fp_cv_matching_ghc_pkg=no
 907 fi])
 908 if test x"$fp_cv_matching_ghc_pkg" = xno; then
 909   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
 910 else
 911   GhcPkgCmd=$fp_cv_matching_ghc_pkg
 912 fi])# FP_PROG_GHC_PKG
 913
 914
 915 # FP_GHC_HAS_READLINE
 916 # -------------------
 917 AC_DEFUN([FP_GHC_HAS_READLINE],
 918 [AC_REQUIRE([FP_PROG_GHC_PKG])
 919 AC_CACHE_CHECK([whether ghc has readline package], [fp_cv_ghc_has_readline],
 920 [if "${GhcPkgCmd-ghc-pkg}" --show-package readline >/dev/null 2>&1; then
 921   fp_cv_ghc_has_readline=yes
 922 else
 923   fp_cv_ghc_has_readline=no
 924  fi])
 925 AC_SUBST([GhcHasReadline], [`echo $fp_cv_ghc_has_readline | sed 'y/yesno/YESNO/'`])
 926 ])# FP_GHC_HAS_READLINE
 927
 928
 929 # FP_GCC_NEEDS_NO_OMIT_LFPTR
 930 # --------------------------
 931 # Some OSs (Mandrake Linux, in particular) configure GCC with
 932 # -momit-leaf-frame-pointer on by default. If this is the case, we need to turn
 933 # it off for mangling to work. The test is currently a bit crude, using only the
 934 # version number of gcc. Defines HAVE_GCC_MNO_OMIT_LFPTR.
 935 AC_DEFUN([FP_GCC_NEEDS_NO_OMIT_LFPTR],
 936 [AC_REQUIRE([FP_HAVE_GCC])
 937 AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fp_cv_gcc_needs_no_omit_lfptr],
 938 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.2],
 939   [fp_cv_gcc_needs_no_omit_lfptr=yes],
 940   [fp_cv_gcc_needs_no_omit_lfptr=no])])
 941 if test "$fp_cv_gcc_needs_no_omit_lfptr" = "yes"; then
 942    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
 943 fi])# FP_GCC_NEEDS_NO_OMIT_LFPTR
 944
 945 # FP_GCC_HAS_NO_UNIT_AT_A_TIME
 946 # --------------------------
 947 AC_DEFUN([FP_GCC_HAS_NO_UNIT_AT_A_TIME],
 948 [AC_REQUIRE([FP_HAVE_GCC])
 949 AC_CACHE_CHECK([whether gcc has -fno-unit-at-a-time], [fp_cv_gcc_has_no_unit_at_a_time],
 950 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
 951   [fp_cv_gcc_has_no_unit_at_a_time=yes],
 952   [fp_cv_gcc_has_no_unit_at_a_time=no])])
 953 if test "$fp_cv_gcc_has_no_unit_at_a_time" = "yes"; then
 954    AC_DEFINE([HAVE_GCC_HAS_NO_UNIT_AT_A_TIME], [1], [Define to 1 if gcc supports -fno-unit-at-a-time.])
 955 fi])
 956
 957 # FP_SETUP_PROJECT_VERSION
 958 # ---------------------
 959 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
 960 [# Some renamings
 961 AC_SUBST([ProjectName], [$PACKAGE_NAME])
 962 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
 963
 964 # Split PACKAGE_VERSION into (possibly empty) parts
 965 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
 966 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
 967 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
 968 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
 969
 970 # Calculate project version as an integer, using 2 digits for minor version
 971 case $VERSION_MINOR in
 972   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
 973   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
 974   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
 975 esac
 976 AC_SUBST([ProjectVersionInt])
 977
 978 # The project patchlevel is zero unless stated otherwise
 979 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
 980
 981 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
 982 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
 983
 984 AC_SUBST([ProjectPatchLevel])
 985 ])# FP_SETUP_PROJECT_VERSION
 986
 987 # LocalWords:  fi