compiler/basicTypes/DataCon.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DataCon]{@DataCon@: Data Constructors}
   5
   6 \begin{code}
   7 module DataCon (
   8         DataCon, DataConIds(..),
   9         ConTag, fIRST_TAG,
  10         mkDataCon,
  11         dataConRepType, dataConSig, dataConFullSig,
  12         dataConName, dataConTag, dataConTyCon, dataConUserType,
  13         dataConUnivTyVars, dataConExTyVars, dataConAllTyVars, dataConResTys,
  14         dataConEqSpec, dataConTheta, dataConStupidTheta,
  15         dataConInstArgTys, dataConOrigArgTys,
  16         dataConInstOrigArgTys, dataConRepArgTys,
  17         dataConFieldLabels, dataConFieldType,
  18         dataConStrictMarks, dataConExStricts,
  19         dataConSourceArity, dataConRepArity,
  20         dataConIsInfix,
  21         dataConWorkId, dataConWrapId, dataConWrapId_maybe, dataConImplicitIds,
  22         dataConRepStrictness,
  23         isNullarySrcDataCon, isNullaryRepDataCon, isTupleCon, isUnboxedTupleCon,
  24         isVanillaDataCon, classDataCon,
  25
  26         splitProductType_maybe, splitProductType,
  27     ) where
  28
  29 #include "HsVersions.h"
  30
  31 import Type             ( Type, ThetaType,
  32                           substTyWith, substTyVar, mkTopTvSubst,
  33                           mkForAllTys, mkFunTys, mkTyConApp, mkTyVarTy, mkTyVarTys,
  34                           splitTyConApp_maybe,
  35                           mkPredTys, isStrictPred, pprType
  36                         )
  37 import Coercion         ( isEqPred, mkEqPred )
  38 import TyCon            ( TyCon, FieldLabel, tyConDataCons,
  39                           isProductTyCon, isTupleTyCon, isUnboxedTupleTyCon,
  40                           isNewTyCon )
  41 import Class            ( Class, classTyCon )
  42 import Name             ( Name, NamedThing(..), nameUnique )
  43 import Var              ( TyVar, Id )
  44 import BasicTypes       ( Arity, StrictnessMark(..) )
  45 import Outputable
  46 import Unique           ( Unique, Uniquable(..) )
  47 import ListSetOps       ( assoc, minusList )
  48 import Util             ( zipEqual, zipWithEqual )
  49 import List             ( partition )
  50 import Maybes           ( expectJust )
  51 \end{code}
  52
  53
  54 Data constructor representation
  55 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  56 Consider the following Haskell data type declaration
  57
  58         data T = T !Int ![Int]
  59
  60 Using the strictness annotations, GHC will represent this as
  61
  62         data T = T Int# [Int]
  63
  64 That is, the Int has been unboxed.  Furthermore, the Haskell source construction
  65
  66         T e1 e2
  67
  68 is translated to
  69
  70         case e1 of { I# x ->
  71         case e2 of { r ->
  72         T x r }}
  73
  74 That is, the first argument is unboxed, and the second is evaluated.  Finally,
  75 pattern matching is translated too:
  76
  77         case e of { T a b -> ... }
  78
  79 becomes
  80
  81         case e of { T a' b -> let a = I# a' in ... }
  82
  83 To keep ourselves sane, we name the different versions of the data constructor
  84 differently, as follows.
  85
  86
  87 Note [Data Constructor Naming]
  88 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  89 Each data constructor C has two, and possibly three, Names associated with it:
  90
  91                              OccName    Name space      Used for
  92   ---------------------------------------------------------------------------
  93   * The "source data con"       C       DataName        The DataCon itself
  94   * The "real data con"         C       VarName         Its worker Id
  95   * The "wrapper data con"      $WC     VarName         Wrapper Id (optional)
  96
  97 Each of these three has a distinct Unique.  The "source data con" name
  98 appears in the output of the renamer, and names the Haskell-source
  99 data constructor.  The type checker translates it into either the wrapper Id
 100 (if it exists) or worker Id (otherwise).
 101
 102 The data con has one or two Ids associated with it:
 103
 104   The "worker Id", is the actual data constructor.
 105         Its type may be different to the Haskell source constructor
 106         because:
 107                 - useless dict args are dropped
 108                 - strict args may be flattened
 109         The worker is very like a primop, in that it has no binding.
 110
 111         Newtypes have no worker Id
 112
 113
 114   The "wrapper Id", $WC, whose type is exactly what it looks like
 115         in the source program. It is an ordinary function,
 116         and it gets a top-level binding like any other function.
 117
 118         The wrapper Id isn't generated for a data type if the worker
 119         and wrapper are identical.  It's always generated for a newtype.
 120
 121
 122
 123 A note about the stupid context
 124 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 125 Data types can have a context:
 126
 127         data (Eq a, Ord b) => T a b = T1 a b | T2 a
 128
 129 and that makes the constructors have a context too
 130 (notice that T2's context is "thinned"):
 131
 132         T1 :: (Eq a, Ord b) => a -> b -> T a b
 133         T2 :: (Eq a) => a -> T a b
 134
 135 Furthermore, this context pops up when pattern matching
 136 (though GHC hasn't implemented this, but it is in H98, and
 137 I've fixed GHC so that it now does):
 138
 139         f (T2 x) = x
 140 gets inferred type
 141         f :: Eq a => T a b -> a
 142
 143 I say the context is "stupid" because the dictionaries passed
 144 are immediately discarded -- they do nothing and have no benefit.
 145 It's a flaw in the language.
 146
 147         Up to now [March 2002] I have put this stupid context into the
 148         type of the "wrapper" constructors functions, T1 and T2, but
 149         that turned out to be jolly inconvenient for generics, and
 150         record update, and other functions that build values of type T
 151         (because they don't have suitable dictionaries available).
 152
 153         So now I've taken the stupid context out.  I simply deal with
 154         it separately in the type checker on occurrences of a
 155         constructor, either in an expression or in a pattern.
 156
 157         [May 2003: actually I think this decision could evasily be
 158         reversed now, and probably should be.  Generics could be
 159         disabled for types with a stupid context; record updates now
 160         (H98) needs the context too; etc.  It's an unforced change, so
 161         I'm leaving it for now --- but it does seem odd that the
 162         wrapper doesn't include the stupid context.]
 163
 164 [July 04] With the advent of generalised data types, it's less obvious
 165 what the "stupid context" is.  Consider
 166         C :: forall a. Ord a => a -> a -> T (Foo a)
 167 Does the C constructor in Core contain the Ord dictionary?  Yes, it must:
 168
 169         f :: T b -> Ordering
 170         f = /\b. \x:T b.
 171             case x of
 172                 C a (d:Ord a) (p:a) (q:a) -> compare d p q
 173
 174 Note that (Foo a) might not be an instance of Ord.
 175
 176 %************************************************************************
 177 %*                                                                      *
 178 \subsection{Data constructors}
 179 %*                                                                      *
 180 %************************************************************************
 181
 182 \begin{code}
 183 data DataCon
 184   = MkData {
 185         dcName    :: Name,      -- This is the name of the *source data con*
 186                                 -- (see "Note [Data Constructor Naming]" above)
 187         dcUnique :: Unique,     -- Cached from Name
 188         dcTag    :: ConTag,
 189
 190         -- Running example:
 191         --
 192         --      *** As declared by the user
 193         --  data T a where
 194         --    MkT :: forall x y. (Ord x) => x -> y -> T (x,y)
 195
 196         --      *** As represented internally
 197         --  data T a where
 198         --    MkT :: forall a. forall x y. (a:=:(x,y), Ord x) => x -> y -> T a
 199         --
 200         -- The next six fields express the type of the constructor, in pieces
 201         -- e.g.
 202         --
 203         --      dcUnivTyVars  = [a]
 204         --      dcExTyVars    = [x,y]
 205         --      dcEqSpec      = [a:=:(x,y)]
 206         --      dcTheta       = [Ord x]
 207         --      dcOrigArgTys  = [a,List b]
 208         --      dcTyCon       = T
 209
 210         dcVanilla :: Bool,      -- True <=> This is a vanilla Haskell 98 data constructor
 211                                 --          Its type is of form
 212                                 --              forall a1..an . t1 -> ... tm -> T a1..an
 213                                 --          No existentials, no coercions, nothing.
 214                                 -- That is: dcExTyVars = dcEqSpec = dcTheta = []
 215                 -- NB 1: newtypes always have a vanilla data con
 216                 -- NB 2: a vanilla constructor can still be declared in GADT-style
 217                 --       syntax, provided its type looks like the above.
 218                 --       The declaration format is held in the TyCon (algTcGadtSyntax)
 219
 220         dcUnivTyVars :: [TyVar],        -- Universally-quantified type vars
 221         dcExTyVars   :: [TyVar],        -- Existentially-quantified type vars
 222                 -- In general, the dcUnivTyVars are NOT NECESSARILY THE SAME AS THE TYVARS
 223                 -- FOR THE PARENT TyCon. With GADTs the data con might not even have
 224                 -- the same number of type variables.
 225                 -- [This is a change (Oct05): previously, vanilla datacons guaranteed to
 226                 --  have the same type variables as their parent TyCon, but that seems ugly.]
 227
 228         dcEqSpec :: [(TyVar,Type)],     -- Equalities derived from the result type,
 229                                         -- *as written by the programmer*
 230                 -- This field allows us to move conveniently between the two ways
 231                 -- of representing a GADT constructor's type:
 232                 --      MkT :: forall a b. (a :=: [b]) => b -> T a
 233                 --      MkT :: forall b. b -> T [b]
 234                 -- Each equality is of the form (a :=: ty), where 'a' is one of
 235                 -- the universally quantified type variables
 236
 237         dcTheta  :: ThetaType,          -- The context of the constructor
 238                 -- In GADT form, this is *exactly* what the programmer writes, even if
 239                 -- the context constrains only universally quantified variables
 240                 --      MkT :: forall a. Eq a => a -> T a
 241                 -- It may contain user-written equality predicates too
 242
 243         dcStupidTheta :: ThetaType,     -- The context of the data type declaration
 244                                         --      data Eq a => T a = ...
 245                                         -- or, rather, a "thinned" version thereof
 246                 -- "Thinned", because the Report says
 247                 -- to eliminate any constraints that don't mention
 248                 -- tyvars free in the arg types for this constructor
 249                 --
 250                 -- INVARIANT: the free tyvars of dcStupidTheta are a subset of dcUnivTyVars
 251                 -- Reason: dcStupidTeta is gotten by thinning the stupid theta from the tycon
 252                 --
 253                 -- "Stupid", because the dictionaries aren't used for anything.
 254                 -- Indeed, [as of March 02] they are no longer in the type of
 255                 -- the wrapper Id, because that makes it harder to use the wrap-id
 256                 -- to rebuild values after record selection or in generics.
 257
 258         dcOrigArgTys :: [Type],         -- Original argument types
 259                                         -- (before unboxing and flattening of strict fields)
 260
 261         -- Result type of constructor is T t1..tn
 262         dcTyCon  :: TyCon,              -- Result tycon, T
 263
 264         -- Now the strictness annotations and field labels of the constructor
 265         dcStrictMarks :: [StrictnessMark],
 266                 -- Strictness annotations as decided by the compiler.
 267                 -- Does *not* include the existential dictionaries
 268                 -- length = dataConSourceArity dataCon
 269
 270         dcFields  :: [FieldLabel],
 271                 -- Field labels for this constructor, in the
 272                 -- same order as the argument types;
 273                 -- length = 0 (if not a record) or dataConSourceArity.
 274
 275         -- Constructor representation
 276         dcRepArgTys :: [Type],          -- Final, representation argument types,
 277                                         -- after unboxing and flattening,
 278                                         -- and *including* existential dictionaries
 279
 280         dcRepStrictness :: [StrictnessMark],    -- One for each *representation* argument
 281
 282         dcRepType   :: Type,    -- Type of the constructor
 283                                 --      forall a x y. (a:=:(x,y), Ord x) => x -> y -> MkT a
 284                                 -- (this is *not* of the constructor wrapper Id:
 285                                 --  see Note [Data con representation] below)
 286         -- Notice that the existential type parameters come *second*.
 287         -- Reason: in a case expression we may find:
 288         --      case (e :: T t) of { MkT b (d:Ord b) (x:t) (xs:[b]) -> ... }
 289         -- It's convenient to apply the rep-type of MkT to 't', to get
 290         --      forall b. Ord b => ...
 291         -- and use that to check the pattern.  Mind you, this is really only
 292         -- use in CoreLint.
 293
 294
 295         -- Finally, the curried worker function that corresponds to the constructor
 296         -- It doesn't have an unfolding; the code generator saturates these Ids
 297         -- and allocates a real constructor when it finds one.
 298         --
 299         -- An entirely separate wrapper function is built in TcTyDecls
 300         dcIds :: DataConIds,
 301
 302         dcInfix :: Bool         -- True <=> declared infix
 303                                 -- Used for Template Haskell and 'deriving' only
 304                                 -- The actual fixity is stored elsewhere
 305   }
 306
 307 data DataConIds
 308   = NewDC Id                    -- Newtypes have only a wrapper, but no worker
 309   | AlgDC (Maybe Id) Id         -- Algebraic data types always have a worker, and
 310                                 -- may or may not have a wrapper, depending on whether
 311                                 -- the wrapper does anything.
 312
 313         -- _Neither_ the worker _nor_ the wrapper take the dcStupidTheta dicts as arguments
 314
 315         -- The wrapper takes dcOrigArgTys as its arguments
 316         -- The worker takes dcRepArgTys as its arguments
 317         -- If the worker is absent, dcRepArgTys is the same as dcOrigArgTys
 318
 319         -- The 'Nothing' case of AlgDC is important
 320         -- Not only is this efficient,
 321         -- but it also ensures that the wrapper is replaced
 322         -- by the worker (becuase it *is* the wroker)
 323         -- even when there are no args. E.g. in
 324         --              f (:) x
 325         -- the (:) *is* the worker.
 326         -- This is really important in rule matching,
 327         -- (We could match on the wrappers,
 328         -- but that makes it less likely that rules will match
 329         -- when we bring bits of unfoldings together.)
 330
 331 type ConTag = Int
 332
 333 fIRST_TAG :: ConTag
 334 fIRST_TAG =  1  -- Tags allocated from here for real constructors
 335 \end{code}
 336
 337 Note [Data con representation]
 338 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 339 The dcRepType field contains the type of the representation of a contructor
 340 This may differ from the type of the contructor *Id* (built
 341 by MkId.mkDataConId) for two reasons:
 342         a) the constructor Id may be overloaded, but the dictionary isn't stored
 343            e.g.    data Eq a => T a = MkT a a
 344
 345         b) the constructor may store an unboxed version of a strict field.
 346
 347 Here's an example illustrating both:
 348         data Ord a => T a = MkT Int! a
 349 Here
 350         T :: Ord a => Int -> a -> T a
 351 but the rep type is
 352         Trep :: Int# -> a -> T a
 353 Actually, the unboxed part isn't implemented yet!
 354
 355
 356 %************************************************************************
 357 %*                                                                      *
 358 \subsection{Instances}
 359 %*                                                                      *
 360 %************************************************************************
 361
 362 \begin{code}
 363 instance Eq DataCon where
 364     a == b = getUnique a == getUnique b
 365     a /= b = getUnique a /= getUnique b
 366
 367 instance Ord DataCon where
 368     a <= b = getUnique a <= getUnique b
 369     a <  b = getUnique a <  getUnique b
 370     a >= b = getUnique a >= getUnique b
 371     a >  b = getUnique a > getUnique b
 372     compare a b = getUnique a `compare` getUnique b
 373
 374 instance Uniquable DataCon where
 375     getUnique = dcUnique
 376
 377 instance NamedThing DataCon where
 378     getName = dcName
 379
 380 instance Outputable DataCon where
 381     ppr con = ppr (dataConName con)
 382
 383 instance Show DataCon where
 384     showsPrec p con = showsPrecSDoc p (ppr con)
 385 \end{code}
 386
 387
 388 %************************************************************************
 389 %*                                                                      *
 390 \subsection{Construction}
 391 %*                                                                      *
 392 %************************************************************************
 393
 394 \begin{code}
 395 mkDataCon :: Name
 396           -> Bool       -- Declared infix
 397           -> [StrictnessMark] -> [FieldLabel]
 398           -> [TyVar] -> [TyVar]
 399           -> [(TyVar,Type)] -> ThetaType
 400           -> [Type] -> TyCon
 401           -> ThetaType -> DataConIds
 402           -> DataCon
 403   -- Can get the tag from the TyCon
 404
 405 mkDataCon name declared_infix
 406           arg_stricts   -- Must match orig_arg_tys 1-1
 407           fields
 408           univ_tvs ex_tvs
 409           eq_spec theta
 410           orig_arg_tys tycon
 411           stupid_theta ids
 412   = con
 413   where
 414     is_vanilla = null ex_tvs && null eq_spec && null theta
 415     con = ASSERT( is_vanilla || not (isNewTyCon tycon) )
 416                 -- Invariant: newtypes have a vanilla data-con
 417           MkData {dcName = name, dcUnique = nameUnique name,
 418                   dcVanilla = is_vanilla, dcInfix = declared_infix,
 419                   dcUnivTyVars = univ_tvs, dcExTyVars = ex_tvs,
 420                   dcEqSpec = eq_spec,
 421                   dcStupidTheta = stupid_theta, dcTheta = theta,
 422                   dcOrigArgTys = orig_arg_tys, dcTyCon = tycon,
 423                   dcRepArgTys = rep_arg_tys,
 424                   dcStrictMarks = arg_stricts, dcRepStrictness = rep_arg_stricts,
 425                   dcFields = fields, dcTag = tag, dcRepType = ty,
 426                   dcIds = ids }
 427
 428         -- Strictness marks for source-args
 429         --      *after unboxing choices*,
 430         -- but  *including existential dictionaries*
 431         --
 432         -- The 'arg_stricts' passed to mkDataCon are simply those for the
 433         -- source-language arguments.  We add extra ones for the
 434         -- dictionary arguments right here.
 435     (more_eq_preds, dict_preds) = partition isEqPred theta
 436     dict_tys     = mkPredTys theta
 437     real_arg_tys = dict_tys                      ++ orig_arg_tys
 438     real_stricts = map mk_dict_strict_mark dict_preds ++ arg_stricts
 439
 440         -- Representation arguments and demands
 441         -- To do: eliminate duplication with MkId
 442     (rep_arg_stricts, rep_arg_tys) = computeRep real_stricts real_arg_tys
 443
 444     tag = assoc "mkDataCon" (tyConDataCons tycon `zip` [fIRST_TAG..]) con
 445     ty  = mkForAllTys univ_tvs $ mkForAllTys ex_tvs $
 446           mkFunTys (mkPredTys (eqSpecPreds eq_spec)) $
 447                 -- NB:  the dict args are already in rep_arg_tys
 448                 --      because they might be flattened..
 449                 --      but the equality predicates are not
 450           mkFunTys rep_arg_tys $
 451           mkTyConApp tycon (mkTyVarTys univ_tvs)
 452
 453 eqSpecPreds :: [(TyVar,Type)] -> ThetaType
 454 eqSpecPreds spec = [ mkEqPred (mkTyVarTy tv, ty) | (tv,ty) <- spec ]
 455
 456 mk_dict_strict_mark pred | isStrictPred pred = MarkedStrict
 457                          | otherwise         = NotMarkedStrict
 458 \end{code}
 459
 460 \begin{code}
 461 dataConName :: DataCon -> Name
 462 dataConName = dcName
 463
 464 dataConTag :: DataCon -> ConTag
 465 dataConTag  = dcTag
 466
 467 dataConTyCon :: DataCon -> TyCon
 468 dataConTyCon = dcTyCon
 469
 470 dataConRepType :: DataCon -> Type
 471 dataConRepType = dcRepType
 472
 473 dataConIsInfix :: DataCon -> Bool
 474 dataConIsInfix = dcInfix
 475
 476 dataConUnivTyVars :: DataCon -> [TyVar]
 477 dataConUnivTyVars = dcUnivTyVars
 478
 479 dataConExTyVars :: DataCon -> [TyVar]
 480 dataConExTyVars = dcExTyVars
 481
 482 dataConAllTyVars :: DataCon -> [TyVar]
 483 dataConAllTyVars (MkData { dcUnivTyVars = univ_tvs, dcExTyVars = ex_tvs })
 484   = univ_tvs ++ ex_tvs
 485
 486 dataConEqSpec :: DataCon -> [(TyVar,Type)]
 487 dataConEqSpec = dcEqSpec
 488
 489 dataConTheta :: DataCon -> ThetaType
 490 dataConTheta = dcTheta
 491
 492 dataConWorkId :: DataCon -> Id
 493 dataConWorkId dc = case dcIds dc of
 494                         AlgDC _ wrk_id -> wrk_id
 495                         NewDC _ -> pprPanic "dataConWorkId" (ppr dc)
 496
 497 dataConWrapId_maybe :: DataCon -> Maybe Id
 498 -- Returns Nothing if there is no wrapper for an algebraic data con
 499 --                 and also for a newtype (whose constructor is inlined compulsorily)
 500 dataConWrapId_maybe dc = case dcIds dc of
 501                                 AlgDC mb_wrap _ -> mb_wrap
 502                                 NewDC wrap      -> Nothing
 503
 504 dataConWrapId :: DataCon -> Id
 505 -- Returns an Id which looks like the Haskell-source constructor
 506 dataConWrapId dc = case dcIds dc of
 507                         AlgDC (Just wrap) _   -> wrap
 508                         AlgDC Nothing     wrk -> wrk        -- worker=wrapper
 509                         NewDC wrap            -> wrap
 510
 511 dataConImplicitIds :: DataCon -> [Id]
 512 dataConImplicitIds dc = case dcIds dc of
 513                           AlgDC (Just wrap) work -> [wrap,work]
 514                           AlgDC Nothing     work -> [work]
 515                           NewDC wrap             -> [wrap]
 516
 517 dataConFieldLabels :: DataCon -> [FieldLabel]
 518 dataConFieldLabels = dcFields
 519
 520 dataConFieldType :: DataCon -> FieldLabel -> Type
 521 dataConFieldType con label = expectJust "unexpected label" $
 522     lookup label (dcFields con `zip` dcOrigArgTys con)
 523
 524 dataConStrictMarks :: DataCon -> [StrictnessMark]
 525 dataConStrictMarks = dcStrictMarks
 526
 527 dataConExStricts :: DataCon -> [StrictnessMark]
 528 -- Strictness of *existential* arguments only
 529 -- Usually empty, so we don't bother to cache this
 530 dataConExStricts dc = map mk_dict_strict_mark (dcTheta dc)
 531
 532 dataConSourceArity :: DataCon -> Arity
 533         -- Source-level arity of the data constructor
 534 dataConSourceArity dc = length (dcOrigArgTys dc)
 535
 536 -- dataConRepArity gives the number of actual fields in the
 537 -- {\em representation} of the data constructor.  This may be more than appear
 538 -- in the source code; the extra ones are the existentially quantified
 539 -- dictionaries
 540 dataConRepArity (MkData {dcRepArgTys = arg_tys}) = length arg_tys
 541
 542 isNullarySrcDataCon, isNullaryRepDataCon :: DataCon -> Bool
 543 isNullarySrcDataCon dc = null (dcOrigArgTys dc)
 544 isNullaryRepDataCon dc = null (dcRepArgTys dc)
 545
 546 dataConRepStrictness :: DataCon -> [StrictnessMark]
 547         -- Give the demands on the arguments of a
 548         -- Core constructor application (Con dc args)
 549 dataConRepStrictness dc = dcRepStrictness dc
 550
 551 dataConSig :: DataCon -> ([TyVar], ThetaType, [Type])
 552 dataConSig (MkData {dcUnivTyVars = univ_tvs, dcExTyVars = ex_tvs, dcEqSpec = eq_spec,
 553                     dcTheta  = theta, dcOrigArgTys = arg_tys, dcTyCon = tycon})
 554   = (univ_tvs ++ ex_tvs, eqSpecPreds eq_spec ++ theta, arg_tys)
 555
 556 dataConFullSig :: DataCon
 557                -> ([TyVar], [TyVar], [(TyVar,Type)], ThetaType, [Type])
 558 dataConFullSig (MkData {dcUnivTyVars = univ_tvs, dcExTyVars = ex_tvs, dcEqSpec = eq_spec,
 559                         dcTheta  = theta, dcOrigArgTys = arg_tys, dcTyCon = tycon})
 560   = (univ_tvs, ex_tvs, eq_spec, theta, arg_tys)
 561
 562 dataConStupidTheta :: DataCon -> ThetaType
 563 dataConStupidTheta dc = dcStupidTheta dc
 564
 565 dataConResTys :: DataCon -> [Type]
 566 dataConResTys dc = [substTyVar env tv | tv <- dcUnivTyVars dc]
 567   where
 568     env = mkTopTvSubst (dcEqSpec dc)
 569
 570 dataConUserType :: DataCon -> Type
 571 -- The user-declared type of the data constructor
 572 -- in the nice-to-read form
 573 --      T :: forall a. a -> T [a]
 574 -- rather than
 575 --      T :: forall b. forall a. (a=[b]) => a -> T b
 576 dataConUserType  (MkData { dcUnivTyVars = univ_tvs,
 577                            dcExTyVars = ex_tvs, dcEqSpec = eq_spec,
 578                            dcTheta = theta, dcOrigArgTys = arg_tys,
 579                            dcTyCon = tycon })
 580   = mkForAllTys ((univ_tvs `minusList` map fst eq_spec) ++ ex_tvs) $
 581     mkFunTys (mkPredTys theta) $
 582     mkFunTys arg_tys $
 583     mkTyConApp tycon (map (substTyVar subst) univ_tvs)
 584   where
 585     subst = mkTopTvSubst eq_spec
 586
 587 dataConInstArgTys :: DataCon
 588                   -> [Type]     -- Instantiated at these types
 589                                 -- NB: these INCLUDE the existentially quantified arg types
 590                   -> [Type]     -- Needs arguments of these types
 591                                 -- NB: these INCLUDE the existentially quantified dict args
 592                                 --     but EXCLUDE the data-decl context which is discarded
 593                                 -- It's all post-flattening etc; this is a representation type
 594 dataConInstArgTys (MkData {dcRepArgTys = arg_tys,
 595                            dcUnivTyVars = univ_tvs,
 596                            dcExTyVars = ex_tvs}) inst_tys
 597  = ASSERT( length tyvars == length inst_tys )
 598    map (substTyWith tyvars inst_tys) arg_tys
 599  where
 600    tyvars = univ_tvs ++ ex_tvs
 601
 602 -- And the same deal for the original arg tys
 603 dataConInstOrigArgTys :: DataCon -> [Type] -> [Type]
 604 dataConInstOrigArgTys (MkData {dcOrigArgTys = arg_tys,
 605                                dcUnivTyVars = univ_tvs,
 606                                dcExTyVars = ex_tvs}) inst_tys
 607  = ASSERT( length tyvars == length inst_tys )
 608    map (substTyWith tyvars inst_tys) arg_tys
 609  where
 610    tyvars = univ_tvs ++ ex_tvs
 611 \end{code}
 612
 613 These two functions get the real argument types of the constructor,
 614 without substituting for any type variables.
 615
 616 dataConOrigArgTys returns the arg types of the wrapper, excluding all dictionary args.
 617
 618 dataConRepArgTys retuns the arg types of the worker, including all dictionaries, and
 619 after any flattening has been done.
 620
 621 \begin{code}
 622 dataConOrigArgTys :: DataCon -> [Type]
 623 dataConOrigArgTys dc = dcOrigArgTys dc
 624
 625 dataConRepArgTys :: DataCon -> [Type]
 626 dataConRepArgTys dc = dcRepArgTys dc
 627 \end{code}
 628
 629
 630 \begin{code}
 631 isTupleCon :: DataCon -> Bool
 632 isTupleCon (MkData {dcTyCon = tc}) = isTupleTyCon tc
 633
 634 isUnboxedTupleCon :: DataCon -> Bool
 635 isUnboxedTupleCon (MkData {dcTyCon = tc}) = isUnboxedTupleTyCon tc
 636
 637 isVanillaDataCon :: DataCon -> Bool
 638 isVanillaDataCon dc = dcVanilla dc
 639 \end{code}
 640
 641
 642 \begin{code}
 643 classDataCon :: Class -> DataCon
 644 classDataCon clas = case tyConDataCons (classTyCon clas) of
 645                       (dict_constr:no_more) -> ASSERT( null no_more ) dict_constr
 646 \end{code}
 647
 648 %************************************************************************
 649 %*                                                                      *
 650 \subsection{Splitting products}
 651 %*                                                                      *
 652 %************************************************************************
 653
 654 \begin{code}
 655 splitProductType_maybe
 656         :: Type                         -- A product type, perhaps
 657         -> Maybe (TyCon,                -- The type constructor
 658                   [Type],               -- Type args of the tycon
 659                   DataCon,              -- The data constructor
 660                   [Type])               -- Its *representation* arg types
 661
 662         -- Returns (Just ...) for any
 663         --      concrete (i.e. constructors visible)
 664         --      single-constructor
 665         --      not existentially quantified
 666         -- type whether a data type or a new type
 667         --
 668         -- Rejecing existentials is conservative.  Maybe some things
 669         -- could be made to work with them, but I'm not going to sweat
 670         -- it through till someone finds it's important.
 671
 672 splitProductType_maybe ty
 673   = case splitTyConApp_maybe ty of
 674         Just (tycon,ty_args)
 675            | isProductTyCon tycon       -- Includes check for non-existential,
 676                                         -- and for constructors visible
 677            -> Just (tycon, ty_args, data_con, dataConInstArgTys data_con ty_args)
 678            where
 679               data_con = head (tyConDataCons tycon)
 680         other -> Nothing
 681
 682 splitProductType str ty
 683   = case splitProductType_maybe ty of
 684         Just stuff -> stuff
 685         Nothing    -> pprPanic (str ++ ": not a product") (pprType ty)
 686
 687
 688 computeRep :: [StrictnessMark]          -- Original arg strictness
 689            -> [Type]                    -- and types
 690            -> ([StrictnessMark],        -- Representation arg strictness
 691                [Type])                  -- And type
 692
 693 computeRep stricts tys
 694   = unzip $ concat $ zipWithEqual "computeRep" unbox stricts tys
 695   where
 696     unbox NotMarkedStrict ty = [(NotMarkedStrict, ty)]
 697     unbox MarkedStrict    ty = [(MarkedStrict,    ty)]
 698     unbox MarkedUnboxed   ty = zipEqual "computeRep" (dataConRepStrictness arg_dc) arg_tys
 699                              where
 700                                (_, _, arg_dc, arg_tys) = splitProductType "unbox_strict_arg_ty" ty
 701 \end{code}