compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[StdIdInfo]{Standard unfoldings}
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9         * data constructors
  10         * record selectors
  11         * method and superclass selectors
  12         * primitive operations
  13
  14 \begin{code}
  15 module MkId (
  16         mkDictFunId, mkDefaultMethodId,
  17         mkDictSelId,
  18
  19         mkDataConIds,
  20         mkRecordSelId,
  21         mkPrimOpId, mkFCallId,
  22
  23         mkReboxingAlt, wrapNewTypeBody, unwrapNewTypeBody,
  24         mkUnpackCase, mkProductBox,
  25
  26         -- And some particular Ids; see below for why they are wired in
  27         wiredInIds, ghcPrimIds,
  28         unsafeCoerceId, realWorldPrimId, voidArgId, nullAddrId, seqId,
  29         lazyId, lazyIdUnfolding, lazyIdKey,
  30
  31         mkRuntimeErrorApp,
  32         rEC_CON_ERROR_ID, iRREFUT_PAT_ERROR_ID, rUNTIME_ERROR_ID,
  33         nON_EXHAUSTIVE_GUARDS_ERROR_ID, nO_METHOD_BINDING_ERROR_ID,
  34         pAT_ERROR_ID, eRROR_ID,
  35
  36         unsafeCoerceName
  37     ) where
  38
  39 #include "HsVersions.h"
  40
  41
  42 import BasicTypes       ( Arity, StrictnessMark(..), isMarkedUnboxed, isMarkedStrict )
  43 import Rules            ( mkSpecInfo )
  44 import TysPrim          ( openAlphaTyVars, alphaTyVar, alphaTy,
  45                           realWorldStatePrimTy, addrPrimTy
  46                         )
  47 import TysWiredIn       ( charTy, mkListTy )
  48 import PrelRules        ( primOpRules )
  49 import Type             ( TyThing(..), mkForAllTy, tyVarsOfTypes, newTyConInstRhs, coreEqType,
  50                           PredType(..),
  51                           mkTopTvSubst, substTyVar )
  52 import TcGadt           ( gadtRefine, refineType, emptyRefinement )
  53 import HsBinds          ( ExprCoFn(..), isIdCoercion )
  54 import Coercion         ( mkSymCoercion, mkUnsafeCoercion,
  55                           splitNewTypeRepCo_maybe, isEqPred )
  56 import TcType           ( Type, ThetaType, mkDictTy, mkPredTys, mkPredTy,
  57                           mkTyConApp, mkTyVarTys, mkClassPred, isPredTy,
  58                           mkFunTys, mkFunTy, mkSigmaTy, tcSplitSigmaTy, tcEqType,
  59                           isUnLiftedType, mkForAllTys, mkTyVarTy, tyVarsOfType,
  60                           tcSplitFunTys, tcSplitForAllTys, dataConsStupidTheta
  61                         )
  62 import CoreUtils        ( exprType, dataConOrigInstPat )
  63 import CoreUnfold       ( mkTopUnfolding, mkCompulsoryUnfolding )
  64 import Literal          ( nullAddrLit, mkStringLit )
  65 import TyCon            ( TyCon, isNewTyCon, tyConDataCons, FieldLabel,
  66                           tyConStupidTheta, isProductTyCon, isDataTyCon, isRecursiveTyCon,
  67                           newTyConCo, tyConArity )
  68 import Class            ( Class, classTyCon, classSelIds )
  69 import Var              ( Id, TyVar, Var, setIdType, mkCoVar, mkWildCoVar )
  70 import VarSet           ( isEmptyVarSet, subVarSet, varSetElems )
  71 import Name             ( mkFCallName, mkWiredInName, Name, BuiltInSyntax(..),
  72                           mkSysTvName )
  73 import OccName          ( mkOccNameFS, varName )
  74 import PrimOp           ( PrimOp, primOpSig, primOpOcc, primOpTag )
  75 import ForeignCall      ( ForeignCall )
  76 import DataCon          ( DataCon, DataConIds(..), dataConTyCon, dataConUnivTyVars,
  77                           dataConFieldLabels, dataConRepArity, dataConResTys,
  78                           dataConRepArgTys, dataConRepType, dataConFullSig,
  79                           dataConSig, dataConStrictMarks, dataConExStricts,
  80                           splitProductType, isVanillaDataCon, dataConFieldType,
  81                           dataConInstOrigArgTys, deepSplitProductType
  82                         )
  83 import Id               ( idType, mkGlobalId, mkVanillaGlobal, mkSysLocal,
  84                           mkTemplateLocals, mkTemplateLocalsNum, mkExportedLocalId,
  85                           mkTemplateLocal, idName, mkWildId
  86                         )
  87 import IdInfo           ( IdInfo, noCafIdInfo,  setUnfoldingInfo,
  88                           setArityInfo, setSpecInfo, setCafInfo,
  89                           setAllStrictnessInfo, vanillaIdInfo,
  90                           GlobalIdDetails(..), CafInfo(..)
  91                         )
  92 import NewDemand        ( mkStrictSig, DmdResult(..),
  93                           mkTopDmdType, topDmd, evalDmd, lazyDmd, retCPR,
  94                           Demand(..), Demands(..) )
  95 import DmdAnal          ( dmdAnalTopRhs )
  96 import CoreSyn
  97 import Unique           ( mkBuiltinUnique, mkPrimOpIdUnique )
  98 import Maybes
  99 import PrelNames
 100 import Util             ( dropList, isSingleton )
 101 import Outputable
 102 import FastString
 103 import ListSetOps       ( assoc, minusList )
 104 \end{code}
 105
 106 %************************************************************************
 107 %*                                                                      *
 108 \subsection{Wired in Ids}
 109 %*                                                                      *
 110 %************************************************************************
 111
 112 \begin{code}
 113 wiredInIds
 114   = [   -- These error-y things are wired in because we don't yet have
 115         -- a way to express in an interface file that the result type variable
 116         -- is 'open'; that is can be unified with an unboxed type
 117         --
 118         -- [The interface file format now carry such information, but there's
 119         -- no way yet of expressing at the definition site for these
 120         -- error-reporting functions that they have an 'open'
 121         -- result type. -- sof 1/99]
 122
 123     eRROR_ID,   -- This one isn't used anywhere else in the compiler
 124                 -- But we still need it in wiredInIds so that when GHC
 125                 -- compiles a program that mentions 'error' we don't
 126                 -- import its type from the interface file; we just get
 127                 -- the Id defined here.  Which has an 'open-tyvar' type.
 128
 129     rUNTIME_ERROR_ID,
 130     iRREFUT_PAT_ERROR_ID,
 131     nON_EXHAUSTIVE_GUARDS_ERROR_ID,
 132     nO_METHOD_BINDING_ERROR_ID,
 133     pAT_ERROR_ID,
 134     rEC_CON_ERROR_ID,
 135
 136     lazyId
 137     ] ++ ghcPrimIds
 138
 139 -- These Ids are exported from GHC.Prim
 140 ghcPrimIds
 141   = [   -- These can't be defined in Haskell, but they have
 142         -- perfectly reasonable unfoldings in Core
 143     realWorldPrimId,
 144     unsafeCoerceId,
 145     nullAddrId,
 146     seqId
 147     ]
 148 \end{code}
 149
 150 %************************************************************************
 151 %*                                                                      *
 152 \subsection{Data constructors}
 153 %*                                                                      *
 154 %************************************************************************
 155
 156 The wrapper for a constructor is an ordinary top-level binding that evaluates
 157 any strict args, unboxes any args that are going to be flattened, and calls
 158 the worker.
 159
 160 We're going to build a constructor that looks like:
 161
 162         data (Data a, C b) =>  T a b = T1 !a !Int b
 163
 164         T1 = /\ a b ->
 165              \d1::Data a, d2::C b ->
 166              \p q r -> case p of { p ->
 167                        case q of { q ->
 168                        Con T1 [a,b] [p,q,r]}}
 169
 170 Notice that
 171
 172 * d2 is thrown away --- a context in a data decl is used to make sure
 173   one *could* construct dictionaries at the site the constructor
 174   is used, but the dictionary isn't actually used.
 175
 176 * We have to check that we can construct Data dictionaries for
 177   the types a and Int.  Once we've done that we can throw d1 away too.
 178
 179 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 180   all that matters is that the arguments are evaluated.  "seq" is
 181   very careful to preserve evaluation order, which we don't need
 182   to be here.
 183
 184   You might think that we could simply give constructors some strictness
 185   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 186   But we don't do that because in the case of primops and functions strictness
 187   is a *property* not a *requirement*.  In the case of constructors we need to
 188   do something active to evaluate the argument.
 189
 190   Making an explicit case expression allows the simplifier to eliminate
 191   it in the (common) case where the constructor arg is already evaluated.
 192
 193
 194 \begin{code}
 195 mkDataConIds :: Name -> Name -> DataCon -> DataConIds
 196 mkDataConIds wrap_name wkr_name data_con
 197   | isNewTyCon tycon
 198   = NewDC nt_wrap_id
 199
 200   | any isMarkedStrict all_strict_marks         -- Algebraic, needs wrapper
 201     || not (null eq_spec)
 202   = AlgDC (Just alg_wrap_id) wrk_id
 203
 204   | otherwise                                   -- Algebraic, no wrapper
 205   = AlgDC Nothing wrk_id
 206   where
 207     (univ_tvs, ex_tvs, eq_spec, theta, orig_arg_tys) = dataConFullSig data_con
 208     tycon = dataConTyCon data_con
 209
 210         ----------- Wrapper --------------
 211         -- We used to include the stupid theta in the wrapper's args
 212         -- but now we don't.  Instead the type checker just injects these
 213         -- extra constraints where necessary.
 214     wrap_tvs = (univ_tvs `minusList` map fst eq_spec) ++ ex_tvs
 215     subst          = mkTopTvSubst eq_spec
 216     dict_tys       = mkPredTys theta
 217     result_ty_args = map (substTyVar subst) univ_tvs
 218     result_ty      = mkTyConApp tycon result_ty_args
 219     wrap_ty        = mkForAllTys wrap_tvs $ mkFunTys dict_tys $
 220                      mkFunTys orig_arg_tys $ result_ty
 221         -- NB: watch out here if you allow user-written equality
 222         --     constraints in data constructor signatures
 223
 224         ----------- Worker (algebraic data types only) --------------
 225         -- The *worker* for the data constructor is the function that
 226         -- takes the representation arguments and builds the constructor.
 227     wrk_id = mkGlobalId (DataConWorkId data_con) wkr_name
 228                         (dataConRepType data_con) wkr_info
 229
 230     wkr_arity = dataConRepArity data_con
 231     wkr_info  = noCafIdInfo
 232                 `setArityInfo`          wkr_arity
 233                 `setAllStrictnessInfo`  Just wkr_sig
 234                 `setUnfoldingInfo`      evaldUnfolding  -- Record that it's evaluated,
 235                                                         -- even if arity = 0
 236
 237     wkr_sig = mkStrictSig (mkTopDmdType (replicate wkr_arity topDmd) cpr_info)
 238         -- Notice that we do *not* say the worker is strict
 239         -- even if the data constructor is declared strict
 240         --      e.g.    data T = MkT !(Int,Int)
 241         -- Why?  Because the *wrapper* is strict (and its unfolding has case
 242         -- expresssions that do the evals) but the *worker* itself is not.
 243         -- If we pretend it is strict then when we see
 244         --      case x of y -> $wMkT y
 245         -- the simplifier thinks that y is "sure to be evaluated" (because
 246         --  $wMkT is strict) and drops the case.  No, $wMkT is not strict.
 247         --
 248         -- When the simplifer sees a pattern
 249         --      case e of MkT x -> ...
 250         -- it uses the dataConRepStrictness of MkT to mark x as evaluated;
 251         -- but that's fine... dataConRepStrictness comes from the data con
 252         -- not from the worker Id.
 253
 254     cpr_info | isProductTyCon tycon &&
 255                isDataTyCon tycon    &&
 256                wkr_arity > 0        &&
 257                wkr_arity <= mAX_CPR_SIZE        = retCPR
 258              | otherwise                        = TopRes
 259         -- RetCPR is only true for products that are real data types;
 260         -- that is, not unboxed tuples or [non-recursive] newtypes
 261
 262         ----------- Wrappers for newtypes --------------
 263     nt_wrap_id   = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty nt_wrap_info
 264     nt_wrap_info = noCafIdInfo          -- The NoCaf-ness is set by noCafIdInfo
 265                   `setArityInfo` 1      -- Arity 1
 266                   `setUnfoldingInfo`     newtype_unf
 267     newtype_unf  = ASSERT( isVanillaDataCon data_con &&
 268                            isSingleton orig_arg_tys )
 269                    -- No existentials on a newtype, but it can have a context
 270                    -- e.g.      newtype Eq a => T a = MkT (...)
 271                    mkCompulsoryUnfolding $
 272                    mkLams wrap_tvs $ Lam id_arg1 $
 273                    wrapNewTypeBody tycon result_ty_args
 274                        (Var id_arg1)
 275
 276     id_arg1 = mkTemplateLocal 1 (head orig_arg_tys)
 277
 278         ----------- Wrappers for algebraic data types --------------
 279     alg_wrap_id = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty alg_wrap_info
 280     alg_wrap_info = noCafIdInfo         -- The NoCaf-ness is set by noCafIdInfo
 281                     `setArityInfo`         alg_arity
 282                         -- It's important to specify the arity, so that partial
 283                         -- applications are treated as values
 284                     `setUnfoldingInfo`     alg_unf
 285                     `setAllStrictnessInfo` Just wrap_sig
 286
 287     all_strict_marks = dataConExStricts data_con ++ dataConStrictMarks data_con
 288     wrap_sig = mkStrictSig (mkTopDmdType arg_dmds cpr_info)
 289     arg_dmds = map mk_dmd all_strict_marks
 290     mk_dmd str | isMarkedStrict str = evalDmd
 291                | otherwise          = lazyDmd
 292         -- The Cpr info can be important inside INLINE rhss, where the
 293         -- wrapper constructor isn't inlined.
 294         -- And the argument strictness can be important too; we
 295         -- may not inline a contructor when it is partially applied.
 296         -- For example:
 297         --      data W = C !Int !Int !Int
 298         --      ...(let w = C x in ...(w p q)...)...
 299         -- we want to see that w is strict in its two arguments
 300
 301     alg_unf = mkTopUnfolding $ Note InlineMe $
 302               mkLams wrap_tvs $
 303               mkLams dict_args $ mkLams id_args $
 304               foldr mk_case con_app
 305                     (zip (dict_args ++ id_args) all_strict_marks)
 306                     i3 []
 307
 308     con_app i rep_ids = Var wrk_id `mkTyApps`  result_ty_args
 309                                    `mkVarApps` ex_tvs
 310                                    `mkTyApps`  map snd eq_spec
 311                                    `mkVarApps` reverse rep_ids
 312
 313     (dict_args,i2) = mkLocals 1  dict_tys
 314     (id_args,i3)   = mkLocals i2 orig_arg_tys
 315     alg_arity      = i3-1
 316
 317     mk_case
 318            :: (Id, StrictnessMark)      -- Arg, strictness
 319            -> (Int -> [Id] -> CoreExpr) -- Body
 320            -> Int                       -- Next rep arg id
 321            -> [Id]                      -- Rep args so far, reversed
 322            -> CoreExpr
 323     mk_case (arg,strict) body i rep_args
 324           = case strict of
 325                 NotMarkedStrict -> body i (arg:rep_args)
 326                 MarkedStrict
 327                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 328                    | otherwise ->
 329                         Case (Var arg) arg result_ty [(DEFAULT,[], body i (arg:rep_args))]
 330
 331                 MarkedUnboxed
 332                    -> unboxProduct i (Var arg) (idType arg) the_body result_ty
 333                       where
 334                         the_body i con_args = body i (reverse con_args ++ rep_args)
 335
 336 mAX_CPR_SIZE :: Arity
 337 mAX_CPR_SIZE = 10
 338 -- We do not treat very big tuples as CPR-ish:
 339 --      a) for a start we get into trouble because there aren't
 340 --         "enough" unboxed tuple types (a tiresome restriction,
 341 --         but hard to fix),
 342 --      b) more importantly, big unboxed tuples get returned mainly
 343 --         on the stack, and are often then allocated in the heap
 344 --         by the caller.  So doing CPR for them may in fact make
 345 --         things worse.
 346
 347 mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 348                where
 349                  n = length tys
 350 \end{code}
 351
 352
 353 %************************************************************************
 354 %*                                                                      *
 355 \subsection{Record selectors}
 356 %*                                                                      *
 357 %************************************************************************
 358
 359 We're going to build a record selector unfolding that looks like this:
 360
 361         data T a b c = T1 { ..., op :: a, ...}
 362                      | T2 { ..., op :: a, ...}
 363                      | T3
 364
 365         sel = /\ a b c -> \ d -> case d of
 366                                     T1 ... x ... -> x
 367                                     T2 ... x ... -> x
 368                                     other        -> error "..."
 369
 370 Similarly for newtypes
 371
 372         newtype N a = MkN { unN :: a->a }
 373
 374         unN :: N a -> a -> a
 375         unN n = coerce (a->a) n
 376
 377 We need to take a little care if the field has a polymorphic type:
 378
 379         data R = R { f :: forall a. a->a }
 380
 381 Then we want
 382
 383         f :: forall a. R -> a -> a
 384         f = /\ a \ r = case r of
 385                           R f -> f a
 386
 387 (not f :: R -> forall a. a->a, which gives the type inference mechanism
 388 problems at call sites)
 389
 390 Similarly for (recursive) newtypes
 391
 392         newtype N = MkN { unN :: forall a. a->a }
 393
 394         unN :: forall b. N -> b -> b
 395         unN = /\b -> \n:N -> (coerce (forall a. a->a) n)
 396
 397
 398 Note [Naughty record selectors]
 399 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 400 A "naughty" field is one for which we can't define a record
 401 selector, because an existential type variable would escape.  For example:
 402         data T = forall a. MkT { x,y::a }
 403 We obviously can't define
 404         x (MkT v _) = v
 405 Nevertheless we *do* put a RecordSelId into the type environment
 406 so that if the user tries to use 'x' as a selector we can bleat
 407 helpfully, rather than saying unhelpfully that 'x' is not in scope.
 408 Hence the sel_naughty flag, to identify record selectors that don't really exist.
 409
 410 In general, a field is naughty if its type mentions a type variable that
 411 isn't in the result type of the constructor.
 412
 413 Note [GADT record selectors]
 414 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 415 For GADTs, we require that all constructors with a common field 'f' have the same
 416 result type (modulo alpha conversion).  [Checked in TcTyClsDecls.checkValidTyCon]
 417 E.g.
 418         data T where
 419           T1 { f :: a } :: T [a]
 420           T2 { f :: a, y :: b  } :: T [a]
 421 and now the selector takes that type as its argument:
 422         f :: forall a. T [a] -> a
 423         f t = case t of
 424                 T1 { f = v } -> v
 425                 T2 { f = v } -> v
 426 Note the forall'd tyvars of the selector are just the free tyvars
 427 of the result type; there may be other tyvars in the constructor's
 428 type (e.g. 'b' in T2).
 429
 430 \begin{code}
 431
 432 -- Steps for handling "naughty" vs "non-naughty" selectors:
 433 --  1. Determine naughtiness by comparing field type vs result type
 434 --  2. Install naughty ones with selector_ty of type _|_ and fill in mzero for info
 435 --  3. If it's not naughty, do the normal plan.
 436
 437 mkRecordSelId :: TyCon -> FieldLabel -> Id
 438 mkRecordSelId tycon field_label
 439         -- Assumes that all fields with the same field label have the same type
 440   | is_naughty = naughty_id
 441   | otherwise  = sel_id
 442   where
 443     is_naughty = not (tyVarsOfType field_ty `subVarSet` res_tv_set)
 444     sel_id_details = RecordSelId tycon field_label is_naughty
 445
 446     -- Escapist case here for naughty construcotrs
 447     -- We give it no IdInfo, and a type of forall a.a (never looked at)
 448     naughty_id = mkGlobalId sel_id_details field_label forall_a_a noCafIdInfo
 449     forall_a_a = mkForAllTy alphaTyVar (mkTyVarTy alphaTyVar)
 450
 451     -- Normal case starts here
 452     sel_id = mkGlobalId sel_id_details field_label selector_ty info
 453     data_cons         = tyConDataCons tycon
 454     data_cons_w_field = filter has_field data_cons      -- Can't be empty!
 455     has_field con     = field_label `elem` dataConFieldLabels con
 456
 457     con1        = head data_cons_w_field
 458     res_tys     = dataConResTys con1
 459     res_tv_set  = tyVarsOfTypes res_tys
 460     res_tvs     = varSetElems res_tv_set
 461     data_ty     = mkTyConApp tycon res_tys
 462     field_ty    = dataConFieldType con1 field_label
 463
 464         -- *Very* tiresomely, the selectors are (unnecessarily!) overloaded over
 465         -- just the dictionaries in the types of the constructors that contain
 466         -- the relevant field.  [The Report says that pattern matching on a
 467         -- constructor gives the same constraints as applying it.]  Urgh.
 468         --
 469         -- However, not all data cons have all constraints (because of
 470         -- BuildTyCl.mkDataConStupidTheta).  So we need to find all the data cons
 471         -- involved in the pattern match and take the union of their constraints.
 472     stupid_dict_tys = mkPredTys (dataConsStupidTheta data_cons_w_field)
 473     n_stupid_dicts  = length stupid_dict_tys
 474
 475     (field_tyvars,pre_field_theta,field_tau) = tcSplitSigmaTy field_ty
 476
 477     field_theta  = filter (not . isEqPred) pre_field_theta
 478     field_dict_tys                       = mkPredTys field_theta
 479     n_field_dict_tys                     = length field_dict_tys
 480         -- If the field has a universally quantified type we have to
 481         -- be a bit careful.  Suppose we have
 482         --      data R = R { op :: forall a. Foo a => a -> a }
 483         -- Then we can't give op the type
 484         --      op :: R -> forall a. Foo a => a -> a
 485         -- because the typechecker doesn't understand foralls to the
 486         -- right of an arrow.  The "right" type to give it is
 487         --      op :: forall a. Foo a => R -> a -> a
 488         -- But then we must generate the right unfolding too:
 489         --      op = /\a -> \dfoo -> \ r ->
 490         --           case r of
 491         --              R op -> op a dfoo
 492         -- Note that this is exactly the type we'd infer from a user defn
 493         --      op (R op) = op
 494
 495     selector_ty :: Type
 496     selector_ty  = mkForAllTys res_tvs $ mkForAllTys field_tyvars $
 497                    mkFunTys stupid_dict_tys  $  mkFunTys field_dict_tys $
 498                    mkFunTy data_ty field_tau
 499
 500     arity = 1 + n_stupid_dicts + n_field_dict_tys
 501
 502     (strict_sig, rhs_w_str) = dmdAnalTopRhs sel_rhs
 503         -- Use the demand analyser to work out strictness.
 504         -- With all this unpackery it's not easy!
 505
 506     info = noCafIdInfo
 507            `setCafInfo`           caf_info
 508            `setArityInfo`         arity
 509            `setUnfoldingInfo`     mkTopUnfolding rhs_w_str
 510            `setAllStrictnessInfo` Just strict_sig
 511
 512         -- Allocate Ids.  We do it a funny way round because field_dict_tys is
 513         -- almost always empty.  Also note that we use max_dict_tys
 514         -- rather than n_dict_tys, because the latter gives an infinite loop:
 515         -- n_dict tys depends on the_alts, which depens on arg_ids, which depends
 516         -- on arity, which depends on n_dict tys.  Sigh!  Mega sigh!
 517     stupid_dict_ids  = mkTemplateLocalsNum 1 stupid_dict_tys
 518     max_stupid_dicts = length (tyConStupidTheta tycon)
 519     field_dict_base  = max_stupid_dicts + 1
 520     field_dict_ids   = mkTemplateLocalsNum field_dict_base field_dict_tys
 521     dict_id_base     = field_dict_base + n_field_dict_tys
 522     data_id          = mkTemplateLocal dict_id_base data_ty
 523     arg_base         = dict_id_base + 1
 524
 525     the_alts :: [CoreAlt]
 526     the_alts   = map mk_alt data_cons_w_field   -- Already sorted by data-con
 527     no_default = length data_cons == length data_cons_w_field   -- No default needed
 528
 529     default_alt | no_default = []
 530                 | otherwise  = [(DEFAULT, [], error_expr)]
 531
 532         -- The default branch may have CAF refs, because it calls recSelError etc.
 533     caf_info    | no_default = NoCafRefs
 534                 | otherwise  = MayHaveCafRefs
 535
 536     sel_rhs = mkLams res_tvs $ mkLams field_tyvars $
 537               mkLams stupid_dict_ids $ mkLams field_dict_ids $
 538               Lam data_id     $ mk_result sel_body
 539
 540         -- NB: A newtype always has a vanilla DataCon; no existentials etc
 541         --     res_tys will simply be the dataConUnivTyVars
 542     sel_body | isNewTyCon tycon = unwrapNewTypeBody tycon res_tys (Var data_id)
 543              | otherwise        = Case (Var data_id) data_id field_ty (default_alt ++ the_alts)
 544
 545     mk_result poly_result = mkVarApps (mkVarApps poly_result field_tyvars) field_dict_ids
 546         -- We pull the field lambdas to the top, so we need to
 547         -- apply them in the body.  For example:
 548         --      data T = MkT { foo :: forall a. a->a }
 549         --
 550         --      foo :: forall a. T -> a -> a
 551         --      foo = /\a. \t:T. case t of { MkT f -> f a }
 552
 553     mk_alt data_con
 554       =   ASSERT2( res_ty `tcEqType` field_ty, ppr data_con $$ ppr res_ty $$ ppr field_ty )
 555           mkReboxingAlt rebox_uniqs data_con (ex_tvs ++ co_tvs ++ arg_vs) rhs
 556       where
 557            -- get pattern binders with types appropriately instantiated
 558         arg_uniqs = map mkBuiltinUnique [arg_base..]
 559         (ex_tvs, co_tvs, arg_vs) = dataConOrigInstPat arg_uniqs data_con res_tys
 560
 561         rebox_base  = arg_base + length ex_tvs + length co_tvs + length arg_vs
 562         rebox_uniqs = map mkBuiltinUnique [rebox_base..]
 563
 564         -- data T :: *->* where T1 { fld :: Maybe b } -> T [b]
 565         --      Hence T1 :: forall a b. (a=[b]) => b -> T a
 566         -- fld :: forall b. T [b] -> Maybe b
 567         -- fld = /\b.\(t:T[b]). case t of
 568         --              T1 b' (c : [b]=[b']) (x:Maybe b')
 569         --                      -> x `cast` Maybe (sym (right c))
 570
 571         Succeeded refinement = gadtRefine emptyRefinement ex_tvs co_tvs
 572         (co_fn, res_ty) = refineType refinement (idType the_arg_id)
 573                 -- Generate the refinement for b'=b,
 574                 -- and apply to (Maybe b'), to get (Maybe b)
 575
 576         rhs = case co_fn of
 577                 ExprCoFn co -> Cast (Var the_arg_id) co
 578                 id_co       -> ASSERT(isIdCoercion id_co) Var the_arg_id
 579
 580         field_vs    = filter (not . isPredTy . idType) arg_vs
 581         the_arg_id  = assoc "mkRecordSelId:mk_alt" (field_lbls `zip` field_vs) field_label
 582         field_lbls  = dataConFieldLabels data_con
 583
 584     error_expr = mkRuntimeErrorApp rEC_SEL_ERROR_ID field_ty full_msg
 585     full_msg   = showSDoc (sep [text "No match in record selector", ppr sel_id])
 586
 587 -- unbox a product type...
 588 -- we will recurse into newtypes, casting along the way, and unbox at the
 589 -- first product data constructor we find. e.g.
 590 --
 591 --   data PairInt = PairInt Int Int
 592 --   newtype S = MkS PairInt
 593 --   newtype T = MkT S
 594 --
 595 -- If we have e = MkT (MkS (PairInt 0 1)) and some body expecting a list of
 596 -- ids, we get (modulo int passing)
 597 --
 598 --   case (e `cast` (sym CoT)) `cast` (sym CoS) of
 599 --     PairInt a b -> body [a,b]
 600 --
 601 -- The Ints passed around are just for creating fresh locals
 602 unboxProduct :: Int -> CoreExpr -> Type -> (Int -> [Id] -> CoreExpr) -> Type -> CoreExpr
 603 unboxProduct i arg arg_ty body res_ty
 604   = result
 605   where
 606     result = mkUnpackCase the_id arg arg_ty con_args boxing_con rhs
 607     (_tycon, _tycon_args, boxing_con, tys) = deepSplitProductType "unboxProduct" arg_ty
 608     ([the_id], i') = mkLocals i [arg_ty]
 609     (con_args, i'') = mkLocals i' tys
 610     rhs = body i'' con_args
 611
 612 mkUnpackCase ::  Id -> CoreExpr -> Type -> [Id] -> DataCon -> CoreExpr -> CoreExpr
 613 -- (mkUnpackCase x e args Con body)
 614 --      returns
 615 -- case (e `cast` ...) of bndr { Con args -> body }
 616 --
 617 -- the type of the bndr passed in is irrelevent
 618 mkUnpackCase bndr arg arg_ty unpk_args boxing_con body
 619   = Case cast_arg (setIdType bndr bndr_ty) (exprType body) [(DataAlt boxing_con, unpk_args, body)]
 620   where
 621   (cast_arg, bndr_ty) = go (idType bndr) arg
 622   go ty arg
 623     | res@(tycon, tycon_args, _, _)  <- splitProductType "mkUnpackCase" ty
 624     , isNewTyCon tycon && not (isRecursiveTyCon tycon)
 625     = go (newTyConInstRhs tycon tycon_args)
 626          (unwrapNewTypeBody tycon tycon_args arg)
 627     | otherwise = (arg, ty)
 628
 629 -- ...and the dual
 630 reboxProduct :: [Unique]     -- uniques to create new local binders
 631              -> Type         -- type of product to box
 632              -> ([Unique],   -- remaining uniques
 633                  CoreExpr,   -- boxed product
 634                  [Id])       -- Ids being boxed into product
 635 reboxProduct us ty
 636   = let
 637         (_tycon, _tycon_args, _pack_con, con_arg_tys) = deepSplitProductType "reboxProduct" ty
 638
 639         us' = dropList con_arg_tys us
 640
 641         arg_ids  = zipWith (mkSysLocal FSLIT("rb")) us con_arg_tys
 642
 643         bind_rhs = mkProductBox arg_ids ty
 644
 645     in
 646       (us', bind_rhs, arg_ids)
 647
 648 mkProductBox :: [Id] -> Type -> CoreExpr
 649 mkProductBox arg_ids ty
 650   = result_expr
 651   where
 652     (tycon, tycon_args, pack_con, _con_arg_tys) = splitProductType "mkProductBox" ty
 653
 654     result_expr
 655       | isNewTyCon tycon && not (isRecursiveTyCon tycon)
 656       = wrap (mkProductBox arg_ids (newTyConInstRhs tycon tycon_args))
 657       | otherwise = mkConApp pack_con (map Type tycon_args ++ map Var arg_ids)
 658
 659     wrap expr = wrapNewTypeBody tycon tycon_args expr
 660
 661
 662 -- (mkReboxingAlt us con xs rhs) basically constructs the case
 663 -- alternative  (con, xs, rhs)
 664 -- but it does the reboxing necessary to construct the *source*
 665 -- arguments, xs, from the representation arguments ys.
 666 -- For example:
 667 --      data T = MkT !(Int,Int) Bool
 668 --
 669 -- mkReboxingAlt MkT [x,b] r
 670 --      = (DataAlt MkT, [y::Int,z::Int,b], let x = (y,z) in r)
 671 --
 672 -- mkDataAlt should really be in DataCon, but it can't because
 673 -- it manipulates CoreSyn.
 674
 675 mkReboxingAlt
 676   :: [Unique]           -- Uniques for the new Ids
 677   -> DataCon
 678   -> [Var]              -- Source-level args, including existential dicts
 679   -> CoreExpr           -- RHS
 680   -> CoreAlt
 681
 682 mkReboxingAlt us con args rhs
 683   | not (any isMarkedUnboxed stricts)
 684   = (DataAlt con, args, rhs)
 685
 686   | otherwise
 687   = let
 688         (binds, args') = go args stricts us
 689     in
 690     (DataAlt con, args', mkLets binds rhs)
 691
 692   where
 693     stricts = dataConExStricts con ++ dataConStrictMarks con
 694
 695     go [] stricts us = ([], [])
 696
 697         -- Type variable case
 698     go (arg:args) stricts us
 699       | isTyVar arg
 700       = let (binds, args') = go args stricts us
 701         in  (binds, arg:args')
 702
 703         -- Term variable case
 704     go (arg:args) (str:stricts) us
 705       | isMarkedUnboxed str
 706       =
 707         let (binds, unpacked_args')        = go args stricts us'
 708             (us', bind_rhs, unpacked_args) = reboxProduct us (idType arg)
 709         in
 710             (NonRec arg bind_rhs : binds, unpacked_args ++ unpacked_args')
 711       | otherwise
 712       = let (binds, args') = go args stricts us
 713         in  (binds, arg:args')
 714 \end{code}
 715
 716
 717 %************************************************************************
 718 %*                                                                      *
 719 \subsection{Dictionary selectors}
 720 %*                                                                      *
 721 %************************************************************************
 722
 723 Selecting a field for a dictionary.  If there is just one field, then
 724 there's nothing to do.
 725
 726 Dictionary selectors may get nested forall-types.  Thus:
 727
 728         class Foo a where
 729           op :: forall b. Ord b => a -> b -> b
 730
 731 Then the top-level type for op is
 732
 733         op :: forall a. Foo a =>
 734               forall b. Ord b =>
 735               a -> b -> b
 736
 737 This is unlike ordinary record selectors, which have all the for-alls
 738 at the outside.  When dealing with classes it's very convenient to
 739 recover the original type signature from the class op selector.
 740
 741 \begin{code}
 742 mkDictSelId :: Name -> Class -> Id
 743 mkDictSelId name clas
 744   = mkGlobalId (ClassOpId clas) name sel_ty info
 745   where
 746     sel_ty = mkForAllTys tyvars (mkFunTy (idType dict_id) (idType the_arg_id))
 747         -- We can't just say (exprType rhs), because that would give a type
 748         --      C a -> C a
 749         -- for a single-op class (after all, the selector is the identity)
 750         -- But it's type must expose the representation of the dictionary
 751         -- to gat (say)         C a -> (a -> a)
 752
 753     info = noCafIdInfo
 754                 `setArityInfo`          1
 755                 `setUnfoldingInfo`      mkTopUnfolding rhs
 756                 `setAllStrictnessInfo`  Just strict_sig
 757
 758         -- We no longer use 'must-inline' on record selectors.  They'll
 759         -- inline like crazy if they scrutinise a constructor
 760
 761         -- The strictness signature is of the form U(AAAVAAAA) -> T
 762         -- where the V depends on which item we are selecting
 763         -- It's worth giving one, so that absence info etc is generated
 764         -- even if the selector isn't inlined
 765     strict_sig = mkStrictSig (mkTopDmdType [arg_dmd] TopRes)
 766     arg_dmd | isNewTyCon tycon = evalDmd
 767             | otherwise        = Eval (Prod [ if the_arg_id == id then evalDmd else Abs
 768                                             | id <- arg_ids ])
 769
 770     tycon      = classTyCon clas
 771     [data_con] = tyConDataCons tycon
 772     tyvars     = dataConUnivTyVars data_con
 773     arg_tys    = ASSERT( isVanillaDataCon data_con ) dataConRepArgTys data_con
 774     the_arg_id = assoc "MkId.mkDictSelId" (map idName (classSelIds clas) `zip` arg_ids) name
 775
 776     pred              = mkClassPred clas (mkTyVarTys tyvars)
 777     (dict_id:arg_ids) = mkTemplateLocals (mkPredTy pred : arg_tys)
 778
 779     rhs = mkLams tyvars (Lam dict_id rhs_body)
 780     rhs_body | isNewTyCon tycon = unwrapNewTypeBody tycon (map mkTyVarTy tyvars) (Var dict_id)
 781              | otherwise        = Case (Var dict_id) dict_id (idType the_arg_id)
 782                                        [(DataAlt data_con, arg_ids, Var the_arg_id)]
 783
 784 wrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 785 -- The wrapper for the data constructor for a newtype looks like this:
 786 --      newtype T a = MkT (a,Int)
 787 --      MkT :: forall a. (a,Int) -> T a
 788 --      MkT = /\a. \(x:(a,Int)). x `cast` CoT a
 789 -- where CoT is the coercion TyCon assoicated with the newtype
 790 --
 791 -- The call (wrapNewTypeBody T [a] e) returns the
 792 -- body of the wrapper, namely
 793 --      e `cast` CoT [a]
 794 --
 795 -- If a coercion constructor is prodivided in the newtype, then we use
 796 -- it, otherwise the wrap/unwrap are both no-ops
 797 --
 798 wrapNewTypeBody tycon args result_expr
 799   | Just co_con <- newTyConCo tycon
 800   = Cast result_expr (mkTyConApp co_con args)
 801   | otherwise
 802   = result_expr
 803
 804 unwrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 805 unwrapNewTypeBody tycon args result_expr
 806   | Just co_con <- newTyConCo tycon
 807   = Cast result_expr (mkSymCoercion (mkTyConApp co_con args))
 808   | otherwise
 809   = result_expr
 810
 811
 812 \end{code}
 813
 814
 815 %************************************************************************
 816 %*                                                                      *
 817 \subsection{Primitive operations
 818 %*                                                                      *
 819 %************************************************************************
 820
 821 \begin{code}
 822 mkPrimOpId :: PrimOp -> Id
 823 mkPrimOpId prim_op
 824   = id
 825   where
 826     (tyvars,arg_tys,res_ty, arity, strict_sig) = primOpSig prim_op
 827     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 828     name = mkWiredInName gHC_PRIM (primOpOcc prim_op)
 829                          (mkPrimOpIdUnique (primOpTag prim_op))
 830                          Nothing (AnId id) UserSyntax
 831     id   = mkGlobalId (PrimOpId prim_op) name ty info
 832
 833     info = noCafIdInfo
 834            `setSpecInfo`          mkSpecInfo (primOpRules prim_op name)
 835            `setArityInfo`         arity
 836            `setAllStrictnessInfo` Just strict_sig
 837
 838 -- For each ccall we manufacture a separate CCallOpId, giving it
 839 -- a fresh unique, a type that is correct for this particular ccall,
 840 -- and a CCall structure that gives the correct details about calling
 841 -- convention etc.
 842 --
 843 -- The *name* of this Id is a local name whose OccName gives the full
 844 -- details of the ccall, type and all.  This means that the interface
 845 -- file reader can reconstruct a suitable Id
 846
 847 mkFCallId :: Unique -> ForeignCall -> Type -> Id
 848 mkFCallId uniq fcall ty
 849   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 850         -- A CCallOpId should have no free type variables;
 851         -- when doing substitutions won't substitute over it
 852     mkGlobalId (FCallId fcall) name ty info
 853   where
 854     occ_str = showSDoc (braces (ppr fcall <+> ppr ty))
 855         -- The "occurrence name" of a ccall is the full info about the
 856         -- ccall; it is encoded, but may have embedded spaces etc!
 857
 858     name = mkFCallName uniq occ_str
 859
 860     info = noCafIdInfo
 861            `setArityInfo`               arity
 862            `setAllStrictnessInfo`       Just strict_sig
 863
 864     (_, tau)     = tcSplitForAllTys ty
 865     (arg_tys, _) = tcSplitFunTys tau
 866     arity        = length arg_tys
 867     strict_sig   = mkStrictSig (mkTopDmdType (replicate arity evalDmd) TopRes)
 868 \end{code}
 869
 870
 871 %************************************************************************
 872 %*                                                                      *
 873 \subsection{DictFuns and default methods}
 874 %*                                                                      *
 875 %************************************************************************
 876
 877 Important notes about dict funs and default methods
 878 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 879 Dict funs and default methods are *not* ImplicitIds.  Their definition
 880 involves user-written code, so we can't figure out their strictness etc
 881 based on fixed info, as we can for constructors and record selectors (say).
 882
 883 We build them as LocalIds, but with External Names.  This ensures that
 884 they are taken to account by free-variable finding and dependency
 885 analysis (e.g. CoreFVs.exprFreeVars).
 886
 887 Why shouldn't they be bound as GlobalIds?  Because, in particular, if
 888 they are globals, the specialiser floats dict uses above their defns,
 889 which prevents good simplifications happening.  Also the strictness
 890 analyser treats a occurrence of a GlobalId as imported and assumes it
 891 contains strictness in its IdInfo, which isn't true if the thing is
 892 bound in the same module as the occurrence.
 893
 894 It's OK for dfuns to be LocalIds, because we form the instance-env to
 895 pass on to the next module (md_insts) in CoreTidy, afer tidying
 896 and globalising the top-level Ids.
 897
 898 BUT make sure they are *exported* LocalIds (mkExportedLocalId) so
 899 that they aren't discarded by the occurrence analyser.
 900
 901 \begin{code}
 902 mkDefaultMethodId dm_name ty = mkExportedLocalId dm_name ty
 903
 904 mkDictFunId :: Name             -- Name to use for the dict fun;
 905             -> [TyVar]
 906             -> ThetaType
 907             -> Class
 908             -> [Type]
 909             -> Id
 910
 911 mkDictFunId dfun_name inst_tyvars dfun_theta clas inst_tys
 912   = mkExportedLocalId dfun_name dfun_ty
 913   where
 914     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
 915
 916 {-  1 dec 99: disable the Mark Jones optimisation for the sake
 917     of compatibility with Hugs.
 918     See `types/InstEnv' for a discussion related to this.
 919
 920     (class_tyvars, sc_theta, _, _) = classBigSig clas
 921     not_const (clas, tys) = not (isEmptyVarSet (tyVarsOfTypes tys))
 922     sc_theta' = substClasses (zipTopTvSubst class_tyvars inst_tys) sc_theta
 923     dfun_theta = case inst_decl_theta of
 924                    []    -> []  -- If inst_decl_theta is empty, then we don't
 925                                 -- want to have any dict arguments, so that we can
 926                                 -- expose the constant methods.
 927
 928                    other -> nub (inst_decl_theta ++ filter not_const sc_theta')
 929                                 -- Otherwise we pass the superclass dictionaries to
 930                                 -- the dictionary function; the Mark Jones optimisation.
 931                                 --
 932                                 -- NOTE the "nub".  I got caught by this one:
 933                                 --   class Monad m => MonadT t m where ...
 934                                 --   instance Monad m => MonadT (EnvT env) m where ...
 935                                 -- Here, the inst_decl_theta has (Monad m); but so
 936                                 -- does the sc_theta'!
 937                                 --
 938                                 -- NOTE the "not_const".  I got caught by this one too:
 939                                 --   class Foo a => Baz a b where ...
 940                                 --   instance Wob b => Baz T b where..
 941                                 -- Now sc_theta' has Foo T
 942 -}
 943 \end{code}
 944
 945
 946 %************************************************************************
 947 %*                                                                      *
 948 \subsection{Un-definable}
 949 %*                                                                      *
 950 %************************************************************************
 951
 952 These Ids can't be defined in Haskell.  They could be defined in
 953 unfoldings in the wired-in GHC.Prim interface file, but we'd have to
 954 ensure that they were definitely, definitely inlined, because there is
 955 no curried identifier for them.  That's what mkCompulsoryUnfolding
 956 does.  If we had a way to get a compulsory unfolding from an interface
 957 file, we could do that, but we don't right now.
 958
 959 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
 960 just gets expanded into a type coercion wherever it occurs.  Hence we
 961 add it as a built-in Id with an unfolding here.
 962
 963 The type variables we use here are "open" type variables: this means
 964 they can unify with both unlifted and lifted types.  Hence we provide
 965 another gun with which to shoot yourself in the foot.
 966
 967 \begin{code}
 968 mkWiredInIdName mod fs uniq id
 969  = mkWiredInName mod (mkOccNameFS varName fs) uniq Nothing (AnId id) UserSyntax
 970
 971 unsafeCoerceName = mkWiredInIdName gHC_PRIM FSLIT("unsafeCoerce#") unsafeCoerceIdKey  unsafeCoerceId
 972 nullAddrName     = mkWiredInIdName gHC_PRIM FSLIT("nullAddr#")     nullAddrIdKey      nullAddrId
 973 seqName          = mkWiredInIdName gHC_PRIM FSLIT("seq")           seqIdKey           seqId
 974 realWorldName    = mkWiredInIdName gHC_PRIM FSLIT("realWorld#")    realWorldPrimIdKey realWorldPrimId
 975 lazyIdName       = mkWiredInIdName gHC_BASE FSLIT("lazy")         lazyIdKey           lazyId
 976
 977 errorName                = mkWiredInIdName gHC_ERR FSLIT("error")            errorIdKey eRROR_ID
 978 recSelErrorName          = mkWiredInIdName gHC_ERR FSLIT("recSelError")     recSelErrorIdKey rEC_SEL_ERROR_ID
 979 runtimeErrorName         = mkWiredInIdName gHC_ERR FSLIT("runtimeError")    runtimeErrorIdKey rUNTIME_ERROR_ID
 980 irrefutPatErrorName      = mkWiredInIdName gHC_ERR FSLIT("irrefutPatError") irrefutPatErrorIdKey iRREFUT_PAT_ERROR_ID
 981 recConErrorName          = mkWiredInIdName gHC_ERR FSLIT("recConError")     recConErrorIdKey rEC_CON_ERROR_ID
 982 patErrorName             = mkWiredInIdName gHC_ERR FSLIT("patError")         patErrorIdKey pAT_ERROR_ID
 983 noMethodBindingErrorName = mkWiredInIdName gHC_ERR FSLIT("noMethodBindingError")
 984                                            noMethodBindingErrorIdKey nO_METHOD_BINDING_ERROR_ID
 985 nonExhaustiveGuardsErrorName
 986   = mkWiredInIdName gHC_ERR FSLIT("nonExhaustiveGuardsError")
 987                     nonExhaustiveGuardsErrorIdKey nON_EXHAUSTIVE_GUARDS_ERROR_ID
 988 \end{code}
 989
 990 \begin{code}
 991 -- unsafeCoerce# :: forall a b. a -> b
 992 unsafeCoerceId
 993   = pcMiscPrelId unsafeCoerceName ty info
 994   where
 995     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 996
 997
 998     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
 999                       (mkFunTy openAlphaTy openBetaTy)
1000     [x] = mkTemplateLocals [openAlphaTy]
1001     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
1002 --       Note (Coerce openBetaTy openAlphaTy) (Var x)
1003          Cast (Var x) (mkUnsafeCoercion openAlphaTy openBetaTy)
1004
1005 -- nullAddr# :: Addr#
1006 -- The reason is is here is because we don't provide
1007 -- a way to write this literal in Haskell.
1008 nullAddrId
1009   = pcMiscPrelId nullAddrName addrPrimTy info
1010   where
1011     info = noCafIdInfo `setUnfoldingInfo`
1012            mkCompulsoryUnfolding (Lit nullAddrLit)
1013
1014 seqId
1015   = pcMiscPrelId seqName ty info
1016   where
1017     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
1018
1019
1020     ty  = mkForAllTys [alphaTyVar,openBetaTyVar]
1021                       (mkFunTy alphaTy (mkFunTy openBetaTy openBetaTy))
1022     [x,y] = mkTemplateLocals [alphaTy, openBetaTy]
1023     rhs = mkLams [alphaTyVar,openBetaTyVar,x,y] (Case (Var x) x openBetaTy [(DEFAULT, [], Var y)])
1024
1025 -- lazy :: forall a?. a? -> a?   (i.e. works for unboxed types too)
1026 -- Used to lazify pseq:         pseq a b = a `seq` lazy b
1027 --
1028 -- Also, no strictness: by being a built-in Id, all the info about lazyId comes from here,
1029 -- not from GHC.Base.hi.   This is important, because the strictness
1030 -- analyser will spot it as strict!
1031 --
1032 -- Also no unfolding in lazyId: it gets "inlined" by a HACK in the worker/wrapper pass
1033 --      (see WorkWrap.wwExpr)
1034 -- We could use inline phases to do this, but that would be vulnerable to changes in
1035 -- phase numbering....we must inline precisely after strictness analysis.
1036 lazyId
1037   = pcMiscPrelId lazyIdName ty info
1038   where
1039     info = noCafIdInfo
1040     ty  = mkForAllTys [alphaTyVar] (mkFunTy alphaTy alphaTy)
1041
1042 lazyIdUnfolding :: CoreExpr     -- Used to expand 'lazyId' after strictness anal
1043 lazyIdUnfolding = mkLams [openAlphaTyVar,x] (Var x)
1044                 where
1045                   [x] = mkTemplateLocals [openAlphaTy]
1046 \end{code}
1047
1048 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
1049 nasty as-is, change it back to a literal (@Literal@).
1050
1051 voidArgId is a Local Id used simply as an argument in functions
1052 where we just want an arg to avoid having a thunk of unlifted type.
1053 E.g.
1054         x = \ void :: State# RealWorld -> (# p, q #)
1055
1056 This comes up in strictness analysis
1057
1058 \begin{code}
1059 realWorldPrimId -- :: State# RealWorld
1060   = pcMiscPrelId realWorldName realWorldStatePrimTy
1061                  (noCafIdInfo `setUnfoldingInfo` evaldUnfolding)
1062         -- The evaldUnfolding makes it look that realWorld# is evaluated
1063         -- which in turn makes Simplify.interestingArg return True,
1064         -- which in turn makes INLINE things applied to realWorld# likely
1065         -- to be inlined
1066
1067 voidArgId       -- :: State# RealWorld
1068   = mkSysLocal FSLIT("void") voidArgIdKey realWorldStatePrimTy
1069 \end{code}
1070
1071
1072 %************************************************************************
1073 %*                                                                      *
1074 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
1075 %*                                                                      *
1076 %************************************************************************
1077
1078 GHC randomly injects these into the code.
1079
1080 @patError@ is just a version of @error@ for pattern-matching
1081 failures.  It knows various ``codes'' which expand to longer
1082 strings---this saves space!
1083
1084 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
1085 well shouldn't be yanked on, but if one is, then you will get a
1086 friendly message from @absentErr@ (rather than a totally random
1087 crash).
1088
1089 @parError@ is a special version of @error@ which the compiler does
1090 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
1091 templates, but we don't ever expect to generate code for it.
1092
1093 \begin{code}
1094 mkRuntimeErrorApp
1095         :: Id           -- Should be of type (forall a. Addr# -> a)
1096                         --      where Addr# points to a UTF8 encoded string
1097         -> Type         -- The type to instantiate 'a'
1098         -> String       -- The string to print
1099         -> CoreExpr
1100
1101 mkRuntimeErrorApp err_id res_ty err_msg
1102   = mkApps (Var err_id) [Type res_ty, err_string]
1103   where
1104     err_string = Lit (mkStringLit err_msg)
1105
1106 rEC_SEL_ERROR_ID                = mkRuntimeErrorId recSelErrorName
1107 rUNTIME_ERROR_ID                = mkRuntimeErrorId runtimeErrorName
1108 iRREFUT_PAT_ERROR_ID            = mkRuntimeErrorId irrefutPatErrorName
1109 rEC_CON_ERROR_ID                = mkRuntimeErrorId recConErrorName
1110 pAT_ERROR_ID                    = mkRuntimeErrorId patErrorName
1111 nO_METHOD_BINDING_ERROR_ID      = mkRuntimeErrorId noMethodBindingErrorName
1112 nON_EXHAUSTIVE_GUARDS_ERROR_ID  = mkRuntimeErrorId nonExhaustiveGuardsErrorName
1113
1114 -- The runtime error Ids take a UTF8-encoded string as argument
1115 mkRuntimeErrorId name = pc_bottoming_Id name runtimeErrorTy
1116 runtimeErrorTy        = mkSigmaTy [openAlphaTyVar] [] (mkFunTy addrPrimTy openAlphaTy)
1117 \end{code}
1118
1119 \begin{code}
1120 eRROR_ID = pc_bottoming_Id errorName errorTy
1121
1122 errorTy  :: Type
1123 errorTy  = mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkListTy charTy] openAlphaTy)
1124     -- Notice the openAlphaTyVar.  It says that "error" can be applied
1125     -- to unboxed as well as boxed types.  This is OK because it never
1126     -- returns, so the return type is irrelevant.
1127 \end{code}
1128
1129
1130 %************************************************************************
1131 %*                                                                      *
1132 \subsection{Utilities}
1133 %*                                                                      *
1134 %************************************************************************
1135
1136 \begin{code}
1137 pcMiscPrelId :: Name -> Type -> IdInfo -> Id
1138 pcMiscPrelId name ty info
1139   = mkVanillaGlobal name ty info
1140     -- We lie and say the thing is imported; otherwise, we get into
1141     -- a mess with dependency analysis; e.g., core2stg may heave in
1142     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
1143     -- being compiled, then it's just a matter of luck if the definition
1144     -- will be in "the right place" to be in scope.
1145
1146 pc_bottoming_Id name ty
1147  = pcMiscPrelId name ty bottoming_info
1148  where
1149     bottoming_info = vanillaIdInfo `setAllStrictnessInfo` Just strict_sig
1150         -- Do *not* mark them as NoCafRefs, because they can indeed have
1151         -- CAF refs.  For example, pAT_ERROR_ID calls GHC.Err.untangle,
1152         -- which has some CAFs
1153         -- In due course we may arrange that these error-y things are
1154         -- regarded by the GC as permanently live, in which case we
1155         -- can give them NoCaf info.  As it is, any function that calls
1156         -- any pc_bottoming_Id will itself have CafRefs, which bloats
1157         -- SRTs.
1158
1159     strict_sig     = mkStrictSig (mkTopDmdType [evalDmd] BotRes)
1160         -- These "bottom" out, no matter what their arguments
1161
1162 (openAlphaTyVar:openBetaTyVar:_) = openAlphaTyVars
1163 openAlphaTy  = mkTyVarTy openAlphaTyVar
1164 openBetaTy   = mkTyVarTy openBetaTyVar
1165 \end{code}
1166