compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1998
   4 %
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9         * data constructors
  10         * record selectors
  11         * method and superclass selectors
  12         * primitive operations
  13
  14 \begin{code}
  15 module MkId (
  16         mkDictFunId, mkDefaultMethodId,
  17         mkDictSelId,
  18
  19         mkDataConIds,
  20         mkRecordSelId,
  21         mkPrimOpId, mkFCallId, mkTickBoxOpId, mkBreakPointOpId,
  22
  23         mkReboxingAlt, wrapNewTypeBody, unwrapNewTypeBody,
  24         mkUnpackCase, mkProductBox,
  25
  26         -- And some particular Ids; see below for why they are wired in
  27         wiredInIds, ghcPrimIds,
  28         unsafeCoerceId, realWorldPrimId, voidArgId, nullAddrId, seqId,
  29         lazyId, lazyIdUnfolding, lazyIdKey,
  30
  31         mkRuntimeErrorApp,
  32         rEC_CON_ERROR_ID, iRREFUT_PAT_ERROR_ID, rUNTIME_ERROR_ID,
  33         nON_EXHAUSTIVE_GUARDS_ERROR_ID, nO_METHOD_BINDING_ERROR_ID,
  34         pAT_ERROR_ID, eRROR_ID,
  35
  36         unsafeCoerceName
  37     ) where
  38
  39 #include "HsVersions.h"
  40
  41 import Rules
  42 import TysPrim
  43 import TysWiredIn
  44 import PrelRules
  45 import Type
  46 import TcGadt
  47 import Coercion
  48 import TcType
  49 import CoreUtils
  50 import CoreUnfold
  51 import Literal
  52 import TyCon
  53 import Class
  54 import VarSet
  55 import Name
  56 import OccName
  57 import PrimOp
  58 import ForeignCall
  59 import DataCon
  60 import Id
  61 import Var              ( Var, TyVar)
  62 import IdInfo
  63 import NewDemand
  64 import DmdAnal
  65 import CoreSyn
  66 import Unique
  67 import Maybes
  68 import PrelNames
  69 import BasicTypes       hiding ( SuccessFlag(..) )
  70 import Util
  71 import Outputable
  72 import FastString
  73 import ListSetOps
  74 import Module
  75 \end{code}
  76
  77 %************************************************************************
  78 %*                                                                      *
  79 \subsection{Wired in Ids}
  80 %*                                                                      *
  81 %************************************************************************
  82
  83 \begin{code}
  84 wiredInIds
  85   = [   -- These error-y things are wired in because we don't yet have
  86         -- a way to express in an interface file that the result type variable
  87         -- is 'open'; that is can be unified with an unboxed type
  88         --
  89         -- [The interface file format now carry such information, but there's
  90         -- no way yet of expressing at the definition site for these
  91         -- error-reporting functions that they have an 'open'
  92         -- result type. -- sof 1/99]
  93
  94     eRROR_ID,   -- This one isn't used anywhere else in the compiler
  95                 -- But we still need it in wiredInIds so that when GHC
  96                 -- compiles a program that mentions 'error' we don't
  97                 -- import its type from the interface file; we just get
  98                 -- the Id defined here.  Which has an 'open-tyvar' type.
  99
 100     rUNTIME_ERROR_ID,
 101     iRREFUT_PAT_ERROR_ID,
 102     nON_EXHAUSTIVE_GUARDS_ERROR_ID,
 103     nO_METHOD_BINDING_ERROR_ID,
 104     pAT_ERROR_ID,
 105     rEC_CON_ERROR_ID,
 106
 107     lazyId
 108     ] ++ ghcPrimIds
 109
 110 -- These Ids are exported from GHC.Prim
 111 ghcPrimIds
 112   = [   -- These can't be defined in Haskell, but they have
 113         -- perfectly reasonable unfoldings in Core
 114     realWorldPrimId,
 115     unsafeCoerceId,
 116     nullAddrId,
 117     seqId
 118     ]
 119 \end{code}
 120
 121 %************************************************************************
 122 %*                                                                      *
 123 \subsection{Data constructors}
 124 %*                                                                      *
 125 %************************************************************************
 126
 127 The wrapper for a constructor is an ordinary top-level binding that evaluates
 128 any strict args, unboxes any args that are going to be flattened, and calls
 129 the worker.
 130
 131 We're going to build a constructor that looks like:
 132
 133         data (Data a, C b) =>  T a b = T1 !a !Int b
 134
 135         T1 = /\ a b ->
 136              \d1::Data a, d2::C b ->
 137              \p q r -> case p of { p ->
 138                        case q of { q ->
 139                        Con T1 [a,b] [p,q,r]}}
 140
 141 Notice that
 142
 143 * d2 is thrown away --- a context in a data decl is used to make sure
 144   one *could* construct dictionaries at the site the constructor
 145   is used, but the dictionary isn't actually used.
 146
 147 * We have to check that we can construct Data dictionaries for
 148   the types a and Int.  Once we've done that we can throw d1 away too.
 149
 150 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 151   all that matters is that the arguments are evaluated.  "seq" is
 152   very careful to preserve evaluation order, which we don't need
 153   to be here.
 154
 155   You might think that we could simply give constructors some strictness
 156   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 157   But we don't do that because in the case of primops and functions strictness
 158   is a *property* not a *requirement*.  In the case of constructors we need to
 159   do something active to evaluate the argument.
 160
 161   Making an explicit case expression allows the simplifier to eliminate
 162   it in the (common) case where the constructor arg is already evaluated.
 163
 164 Note [Wrappers for data instance tycons]
 165 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 166 In the case of data instances, the wrapper also applies the coercion turning
 167 the representation type into the family instance type to cast the result of
 168 the wrapper.  For example, consider the declarations
 169
 170   data family Map k :: * -> *
 171   data instance Map (a, b) v = MapPair (Map a (Pair b v))
 172
 173 The tycon to which the datacon MapPair belongs gets a unique internal
 174 name of the form :R123Map, and we call it the representation tycon.
 175 In contrast, Map is the family tycon (accessible via
 176 tyConFamInst_maybe). A coercion allows you to move between
 177 representation and family type.  It is accessible from :R123Map via
 178 tyConFamilyCoercion_maybe and has kind
 179
 180   Co123Map a b v :: {Map (a, b) v :=: :R123Map a b v}
 181
 182 The wrapper and worker of MapPair get the types
 183
 184         -- Wrapper
 185   $WMapPair :: forall a b v. Map a (Map a b v) -> Map (a, b) v
 186   $WMapPair a b v = MapPair a b v `cast` sym (Co123Map a b v)
 187
 188         -- Worker
 189   MapPair :: forall a b v. Map a (Map a b v) -> :R123Map a b v
 190
 191 This coercion is conditionally applied by wrapFamInstBody.
 192
 193 It's a bit more complicated if the data instance is a GADT as well!
 194
 195    data instance T [a] where
 196         T1 :: forall b. b -> T [Maybe b]
 197 Hence
 198    Co7T a :: T [a] ~ :R7T a
 199
 200 Now we want
 201
 202         -- Wrapper
 203   $WT1 :: forall b. b -> T [Maybe b]
 204   $WT1 b v = T1 (Maybe b) b (Maybe b) v
 205                         `cast` sym (Co7T (Maybe b))
 206
 207         -- Worker
 208   T1 :: forall c b. (c ~ Maybe b) => b -> :R7T c
 209
 210 \begin{code}
 211 mkDataConIds :: Name -> Name -> DataCon -> DataConIds
 212 mkDataConIds wrap_name wkr_name data_con
 213   | isNewTyCon tycon                    -- Newtype, only has a worker
 214   , not (isFamInstTyCon tycon)          -- unless it's a family instancex
 215   = DCIds Nothing nt_work_id
 216
 217   | any isMarkedStrict all_strict_marks      -- Algebraic, needs wrapper
 218     || not (null eq_spec)                    -- NB: LoadIface.ifaceDeclSubBndrs
 219     || isFamInstTyCon tycon                  --     depends on this test
 220   = DCIds (Just alg_wrap_id) wrk_id
 221
 222   | otherwise                                -- Algebraic, no wrapper
 223   = DCIds Nothing wrk_id
 224   where
 225     (univ_tvs, ex_tvs, eq_spec,
 226      theta, orig_arg_tys, res_ty) = dataConFullSig data_con
 227     tycon = dataConTyCon data_con       -- The representation TyCon (not family)
 228
 229         ----------- Worker (algebraic data types only) --------------
 230         -- The *worker* for the data constructor is the function that
 231         -- takes the representation arguments and builds the constructor.
 232     wrk_id = mkGlobalId (DataConWorkId data_con) wkr_name
 233                         (dataConRepType data_con) wkr_info
 234
 235     wkr_arity = dataConRepArity data_con
 236     wkr_info  = noCafIdInfo
 237                 `setArityInfo`          wkr_arity
 238                 `setAllStrictnessInfo`  Just wkr_sig
 239                 `setUnfoldingInfo`      evaldUnfolding  -- Record that it's evaluated,
 240                                                         -- even if arity = 0
 241
 242     wkr_sig = mkStrictSig (mkTopDmdType (replicate wkr_arity topDmd) cpr_info)
 243         --      Note [Data-con worker strictness]
 244         -- Notice that we do *not* say the worker is strict
 245         -- even if the data constructor is declared strict
 246         --      e.g.    data T = MkT !(Int,Int)
 247         -- Why?  Because the *wrapper* is strict (and its unfolding has case
 248         -- expresssions that do the evals) but the *worker* itself is not.
 249         -- If we pretend it is strict then when we see
 250         --      case x of y -> $wMkT y
 251         -- the simplifier thinks that y is "sure to be evaluated" (because
 252         --  $wMkT is strict) and drops the case.  No, $wMkT is not strict.
 253         --
 254         -- When the simplifer sees a pattern
 255         --      case e of MkT x -> ...
 256         -- it uses the dataConRepStrictness of MkT to mark x as evaluated;
 257         -- but that's fine... dataConRepStrictness comes from the data con
 258         -- not from the worker Id.
 259
 260     cpr_info | isProductTyCon tycon &&
 261                isDataTyCon tycon    &&
 262                wkr_arity > 0        &&
 263                wkr_arity <= mAX_CPR_SIZE        = retCPR
 264              | otherwise                        = TopRes
 265         -- RetCPR is only true for products that are real data types;
 266         -- that is, not unboxed tuples or [non-recursive] newtypes
 267
 268         ----------- Workers for newtypes --------------
 269     nt_work_id   = mkGlobalId (DataConWrapId data_con) wkr_name wrap_ty nt_work_info
 270     nt_work_info = noCafIdInfo          -- The NoCaf-ness is set by noCafIdInfo
 271                   `setArityInfo` 1      -- Arity 1
 272                   `setUnfoldingInfo`     newtype_unf
 273     newtype_unf  = ASSERT( isVanillaDataCon data_con &&
 274                            isSingleton orig_arg_tys )
 275                    -- No existentials on a newtype, but it can have a context
 276                    -- e.g.      newtype Eq a => T a = MkT (...)
 277                    mkCompulsoryUnfolding $
 278                    mkLams wrap_tvs $ Lam id_arg1 $
 279                    wrapNewTypeBody tycon res_ty_args
 280                        (Var id_arg1)
 281
 282     id_arg1 = mkTemplateLocal 1 (head orig_arg_tys)
 283
 284         ----------- Wrapper --------------
 285         -- We used to include the stupid theta in the wrapper's args
 286         -- but now we don't.  Instead the type checker just injects these
 287         -- extra constraints where necessary.
 288     wrap_tvs    = (univ_tvs `minusList` map fst eq_spec) ++ ex_tvs
 289     res_ty_args = substTyVars (mkTopTvSubst eq_spec) univ_tvs
 290     dict_tys = mkPredTys theta
 291     wrap_ty  = mkForAllTys wrap_tvs $ mkFunTys dict_tys $
 292                mkFunTys orig_arg_tys $ res_ty
 293         -- NB: watch out here if you allow user-written equality
 294         --     constraints in data constructor signatures
 295
 296         ----------- Wrappers for algebraic data types --------------
 297     alg_wrap_id = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty alg_wrap_info
 298     alg_wrap_info = noCafIdInfo         -- The NoCaf-ness is set by noCafIdInfo
 299                     `setArityInfo`         wrap_arity
 300                         -- It's important to specify the arity, so that partial
 301                         -- applications are treated as values
 302                     `setUnfoldingInfo`     wrap_unf
 303                     `setAllStrictnessInfo` Just wrap_sig
 304
 305     all_strict_marks = dataConExStricts data_con ++ dataConStrictMarks data_con
 306     wrap_sig = mkStrictSig (mkTopDmdType arg_dmds cpr_info)
 307     arg_dmds = map mk_dmd all_strict_marks
 308     mk_dmd str | isMarkedStrict str = evalDmd
 309                | otherwise          = lazyDmd
 310         -- The Cpr info can be important inside INLINE rhss, where the
 311         -- wrapper constructor isn't inlined.
 312         -- And the argument strictness can be important too; we
 313         -- may not inline a contructor when it is partially applied.
 314         -- For example:
 315         --      data W = C !Int !Int !Int
 316         --      ...(let w = C x in ...(w p q)...)...
 317         -- we want to see that w is strict in its two arguments
 318
 319     wrap_unf = mkTopUnfolding $ Note InlineMe $
 320               mkLams wrap_tvs $
 321               mkLams dict_args $ mkLams id_args $
 322               foldr mk_case con_app
 323                     (zip (dict_args ++ id_args) all_strict_marks)
 324                     i3 []
 325
 326     con_app _ rep_ids = wrapFamInstBody tycon res_ty_args $
 327                           Var wrk_id `mkTyApps`  res_ty_args
 328                                      `mkVarApps` ex_tvs
 329                                      `mkTyApps`  map snd eq_spec        -- Equality evidence
 330                                      `mkVarApps` reverse rep_ids
 331
 332     (dict_args,i2) = mkLocals 1  dict_tys
 333     (id_args,i3)   = mkLocals i2 orig_arg_tys
 334     wrap_arity     = i3-1
 335
 336     mk_case
 337            :: (Id, StrictnessMark)      -- Arg, strictness
 338            -> (Int -> [Id] -> CoreExpr) -- Body
 339            -> Int                       -- Next rep arg id
 340            -> [Id]                      -- Rep args so far, reversed
 341            -> CoreExpr
 342     mk_case (arg,strict) body i rep_args
 343           = case strict of
 344                 NotMarkedStrict -> body i (arg:rep_args)
 345                 MarkedStrict
 346                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 347                    | otherwise ->
 348                         Case (Var arg) arg res_ty [(DEFAULT,[], body i (arg:rep_args))]
 349
 350                 MarkedUnboxed
 351                    -> unboxProduct i (Var arg) (idType arg) the_body
 352                       where
 353                         the_body i con_args = body i (reverse con_args ++ rep_args)
 354
 355 mAX_CPR_SIZE :: Arity
 356 mAX_CPR_SIZE = 10
 357 -- We do not treat very big tuples as CPR-ish:
 358 --      a) for a start we get into trouble because there aren't
 359 --         "enough" unboxed tuple types (a tiresome restriction,
 360 --         but hard to fix),
 361 --      b) more importantly, big unboxed tuples get returned mainly
 362 --         on the stack, and are often then allocated in the heap
 363 --         by the caller.  So doing CPR for them may in fact make
 364 --         things worse.
 365
 366 mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 367                where
 368                  n = length tys
 369 \end{code}
 370
 371
 372 %************************************************************************
 373 %*                                                                      *
 374 \subsection{Record selectors}
 375 %*                                                                      *
 376 %************************************************************************
 377
 378 We're going to build a record selector unfolding that looks like this:
 379
 380         data T a b c = T1 { ..., op :: a, ...}
 381                      | T2 { ..., op :: a, ...}
 382                      | T3
 383
 384         sel = /\ a b c -> \ d -> case d of
 385                                     T1 ... x ... -> x
 386                                     T2 ... x ... -> x
 387                                     other        -> error "..."
 388
 389 Similarly for newtypes
 390
 391         newtype N a = MkN { unN :: a->a }
 392
 393         unN :: N a -> a -> a
 394         unN n = coerce (a->a) n
 395
 396 We need to take a little care if the field has a polymorphic type:
 397
 398         data R = R { f :: forall a. a->a }
 399
 400 Then we want
 401
 402         f :: forall a. R -> a -> a
 403         f = /\ a \ r = case r of
 404                           R f -> f a
 405
 406 (not f :: R -> forall a. a->a, which gives the type inference mechanism
 407 problems at call sites)
 408
 409 Similarly for (recursive) newtypes
 410
 411         newtype N = MkN { unN :: forall a. a->a }
 412
 413         unN :: forall b. N -> b -> b
 414         unN = /\b -> \n:N -> (coerce (forall a. a->a) n)
 415
 416
 417 Note [Naughty record selectors]
 418 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 419 A "naughty" field is one for which we can't define a record
 420 selector, because an existential type variable would escape.  For example:
 421         data T = forall a. MkT { x,y::a }
 422 We obviously can't define
 423         x (MkT v _) = v
 424 Nevertheless we *do* put a RecordSelId into the type environment
 425 so that if the user tries to use 'x' as a selector we can bleat
 426 helpfully, rather than saying unhelpfully that 'x' is not in scope.
 427 Hence the sel_naughty flag, to identify record selectors that don't really exist.
 428
 429 In general, a field is naughty if its type mentions a type variable that
 430 isn't in the result type of the constructor.
 431
 432 Note [GADT record selectors]
 433 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 434 For GADTs, we require that all constructors with a common field 'f' have the same
 435 result type (modulo alpha conversion).  [Checked in TcTyClsDecls.checkValidTyCon]
 436 E.g.
 437         data T where
 438           T1 { f :: a } :: T [a]
 439           T2 { f :: a, y :: b  } :: T [a]
 440 and now the selector takes that type as its argument:
 441         f :: forall a. T [a] -> a
 442         f t = case t of
 443                 T1 { f = v } -> v
 444                 T2 { f = v } -> v
 445 Note the forall'd tyvars of the selector are just the free tyvars
 446 of the result type; there may be other tyvars in the constructor's
 447 type (e.g. 'b' in T2).
 448
 449 Note [Selector running example]
 450 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 451 It's OK to combine GADTs and type families.  Here's a running example:
 452
 453         data instance T [a] where
 454           T1 { fld :: b } :: T [Maybe b]
 455
 456 The representation type looks like this
 457         data :R7T a where
 458           T1 { fld :: b } :: :R7T (Maybe b)
 459
 460 and there's coercion from the family type to the representation type
 461         :CoR7T a :: T [a] ~ :R7T a
 462
 463 The selector we want for fld looks like this:
 464
 465         fld :: forall b. T [Maybe b] -> b
 466         fld = /\b. \(d::T [Maybe b]).
 467               case d `cast` :CoR7T (Maybe b) of
 468                 T1 (x::b) -> x
 469
 470 The scrutinee of the case has type :R7T (Maybe b), which can be
 471 gotten by appying the eq_spec to the univ_tvs of the data con.
 472
 473 \begin{code}
 474 mkRecordSelId :: TyCon -> FieldLabel -> Id
 475 mkRecordSelId tycon field_label
 476         -- Assumes that all fields with the same field label have the same type
 477   | is_naughty = naughty_id
 478   | otherwise  = sel_id
 479   where
 480     is_naughty = not (tyVarsOfType field_ty `subVarSet` data_tv_set)
 481     sel_id_details = RecordSelId { sel_tycon = tycon, sel_label = field_label, sel_naughty = is_naughty }
 482         -- For a data type family, the tycon is the *instance* TyCon
 483
 484     -- Escapist case here for naughty constructors
 485     -- We give it no IdInfo, and a type of forall a.a (never looked at)
 486     naughty_id = mkGlobalId sel_id_details field_label forall_a_a noCafIdInfo
 487     forall_a_a = mkForAllTy alphaTyVar (mkTyVarTy alphaTyVar)
 488
 489     -- Normal case starts here
 490     sel_id = mkGlobalId sel_id_details field_label selector_ty info
 491     data_cons         = tyConDataCons tycon
 492     data_cons_w_field = filter has_field data_cons      -- Can't be empty!
 493     has_field con     = field_label `elem` dataConFieldLabels con
 494
 495     con1        = head data_cons_w_field
 496     (univ_tvs, _, eq_spec, _, _, data_ty) = dataConFullSig con1
 497         -- For a data type family, the data_ty (and hence selector_ty) mentions
 498         -- only the family TyCon, not the instance TyCon
 499     data_tv_set = tyVarsOfType data_ty
 500     data_tvs    = varSetElems data_tv_set
 501     field_ty    = dataConFieldType con1 field_label
 502
 503         -- *Very* tiresomely, the selectors are (unnecessarily!) overloaded over
 504         -- just the dictionaries in the types of the constructors that contain
 505         -- the relevant field.  [The Report says that pattern matching on a
 506         -- constructor gives the same constraints as applying it.]  Urgh.
 507         --
 508         -- However, not all data cons have all constraints (because of
 509         -- BuildTyCl.mkDataConStupidTheta).  So we need to find all the data cons
 510         -- involved in the pattern match and take the union of their constraints.
 511     stupid_dict_tys = mkPredTys (dataConsStupidTheta data_cons_w_field)
 512     n_stupid_dicts  = length stupid_dict_tys
 513
 514     (field_tyvars,pre_field_theta,field_tau) = tcSplitSigmaTy field_ty
 515     field_theta       = filter (not . isEqPred) pre_field_theta
 516     field_dict_tys    = mkPredTys field_theta
 517     n_field_dict_tys  = length field_dict_tys
 518         -- If the field has a universally quantified type we have to
 519         -- be a bit careful.  Suppose we have
 520         --      data R = R { op :: forall a. Foo a => a -> a }
 521         -- Then we can't give op the type
 522         --      op :: R -> forall a. Foo a => a -> a
 523         -- because the typechecker doesn't understand foralls to the
 524         -- right of an arrow.  The "right" type to give it is
 525         --      op :: forall a. Foo a => R -> a -> a
 526         -- But then we must generate the right unfolding too:
 527         --      op = /\a -> \dfoo -> \ r ->
 528         --           case r of
 529         --              R op -> op a dfoo
 530         -- Note that this is exactly the type we'd infer from a user defn
 531         --      op (R op) = op
 532
 533     selector_ty :: Type
 534     selector_ty  = mkForAllTys data_tvs $ mkForAllTys field_tyvars $
 535                    mkFunTys stupid_dict_tys  $  mkFunTys field_dict_tys $
 536                    mkFunTy data_ty field_tau
 537
 538     arity = 1 + n_stupid_dicts + n_field_dict_tys
 539
 540     (strict_sig, rhs_w_str) = dmdAnalTopRhs sel_rhs
 541         -- Use the demand analyser to work out strictness.
 542         -- With all this unpackery it's not easy!
 543
 544     info = noCafIdInfo
 545            `setCafInfo`           caf_info
 546            `setArityInfo`         arity
 547            `setUnfoldingInfo`     mkTopUnfolding rhs_w_str
 548            `setAllStrictnessInfo` Just strict_sig
 549
 550         -- Allocate Ids.  We do it a funny way round because field_dict_tys is
 551         -- almost always empty.  Also note that we use max_dict_tys
 552         -- rather than n_dict_tys, because the latter gives an infinite loop:
 553         -- n_dict tys depends on the_alts, which depens on arg_ids, which depends
 554         -- on arity, which depends on n_dict tys.  Sigh!  Mega sigh!
 555     stupid_dict_ids  = mkTemplateLocalsNum 1 stupid_dict_tys
 556     max_stupid_dicts = length (tyConStupidTheta tycon)
 557     field_dict_base  = max_stupid_dicts + 1
 558     field_dict_ids   = mkTemplateLocalsNum field_dict_base field_dict_tys
 559     dict_id_base     = field_dict_base + n_field_dict_tys
 560     data_id          = mkTemplateLocal dict_id_base data_ty
 561     scrut_id         = mkTemplateLocal (dict_id_base+1) scrut_ty
 562     arg_base         = dict_id_base + 2
 563
 564     the_alts :: [CoreAlt]
 565     the_alts   = map mk_alt data_cons_w_field   -- Already sorted by data-con
 566     no_default = length data_cons == length data_cons_w_field   -- No default needed
 567
 568     default_alt | no_default = []
 569                 | otherwise  = [(DEFAULT, [], error_expr)]
 570
 571         -- The default branch may have CAF refs, because it calls recSelError etc.
 572     caf_info    | no_default = NoCafRefs
 573                 | otherwise  = MayHaveCafRefs
 574
 575     sel_rhs = mkLams data_tvs $ mkLams field_tyvars $
 576               mkLams stupid_dict_ids $ mkLams field_dict_ids $
 577               Lam data_id $ mk_result sel_body
 578
 579     scrut_ty_args = substTyVars (mkTopTvSubst eq_spec) univ_tvs
 580     scrut_ty      = mkTyConApp tycon scrut_ty_args
 581     scrut = unwrapFamInstScrut tycon scrut_ty_args (Var data_id)
 582         -- First coerce from the type family to the representation type
 583
 584         -- NB: A newtype always has a vanilla DataCon; no existentials etc
 585         --     data_tys will simply be the dataConUnivTyVars
 586     sel_body | isNewTyCon tycon = unwrapNewTypeBody tycon scrut_ty_args scrut
 587              | otherwise        = Case scrut scrut_id field_ty (default_alt ++ the_alts)
 588
 589     mk_result poly_result = mkVarApps (mkVarApps poly_result field_tyvars) field_dict_ids
 590         -- We pull the field lambdas to the top, so we need to
 591         -- apply them in the body.  For example:
 592         --      data T = MkT { foo :: forall a. a->a }
 593         --
 594         --      foo :: forall a. T -> a -> a
 595         --      foo = /\a. \t:T. case t of { MkT f -> f a }
 596
 597     mk_alt data_con
 598       =   ASSERT2( data_ty `tcEqType` field_ty, ppr data_con $$ ppr data_ty $$ ppr field_ty )
 599           mkReboxingAlt rebox_uniqs data_con (ex_tvs ++ co_tvs ++ arg_vs) rhs
 600       where
 601            -- get pattern binders with types appropriately instantiated
 602         arg_uniqs = map mkBuiltinUnique [arg_base..]
 603         (ex_tvs, co_tvs, arg_vs) = dataConOrigInstPat arg_uniqs data_con scrut_ty_args
 604
 605         rebox_base  = arg_base + length ex_tvs + length co_tvs + length arg_vs
 606         rebox_uniqs = map mkBuiltinUnique [rebox_base..]
 607
 608         -- data T :: *->* where T1 { fld :: Maybe b } -> T [b]
 609         --      Hence T1 :: forall a b. (a=[b]) => b -> T a
 610         -- fld :: forall b. T [b] -> Maybe b
 611         -- fld = /\b.\(t:T[b]). case t of
 612         --              T1 b' (c : [b]=[b']) (x:Maybe b')
 613         --                      -> x `cast` Maybe (sym (right c))
 614
 615
 616                 -- Generate the refinement for b'=b,
 617                 -- and apply to (Maybe b'), to get (Maybe b)
 618         Succeeded refinement = gadtRefine emptyRefinement ex_tvs co_tvs
 619         the_arg_id_ty = idType the_arg_id
 620         (rhs, data_ty) = case refineType refinement the_arg_id_ty of
 621                           Just (co, data_ty) -> (Cast (Var the_arg_id) co, data_ty)
 622                           Nothing            -> (Var the_arg_id, the_arg_id_ty)
 623
 624         field_vs    = filter (not . isPredTy . idType) arg_vs
 625         the_arg_id  = assoc "mkRecordSelId:mk_alt" (field_lbls `zip` field_vs) field_label
 626         field_lbls  = dataConFieldLabels data_con
 627
 628     error_expr = mkRuntimeErrorApp rEC_SEL_ERROR_ID field_ty full_msg
 629     full_msg   = showSDoc (sep [text "No match in record selector", ppr sel_id])
 630
 631 -- unbox a product type...
 632 -- we will recurse into newtypes, casting along the way, and unbox at the
 633 -- first product data constructor we find. e.g.
 634 --
 635 --   data PairInt = PairInt Int Int
 636 --   newtype S = MkS PairInt
 637 --   newtype T = MkT S
 638 --
 639 -- If we have e = MkT (MkS (PairInt 0 1)) and some body expecting a list of
 640 -- ids, we get (modulo int passing)
 641 --
 642 --   case (e `cast` CoT) `cast` CoS of
 643 --     PairInt a b -> body [a,b]
 644 --
 645 -- The Ints passed around are just for creating fresh locals
 646 unboxProduct :: Int -> CoreExpr -> Type -> (Int -> [Id] -> CoreExpr) -> CoreExpr
 647 unboxProduct i arg arg_ty body
 648   = result
 649   where
 650     result = mkUnpackCase the_id arg con_args boxing_con rhs
 651     (_tycon, _tycon_args, boxing_con, tys) = deepSplitProductType "unboxProduct" arg_ty
 652     ([the_id], i') = mkLocals i [arg_ty]
 653     (con_args, i'') = mkLocals i' tys
 654     rhs = body i'' con_args
 655
 656 mkUnpackCase ::  Id -> CoreExpr -> [Id] -> DataCon -> CoreExpr -> CoreExpr
 657 -- (mkUnpackCase x e args Con body)
 658 --      returns
 659 -- case (e `cast` ...) of bndr { Con args -> body }
 660 --
 661 -- the type of the bndr passed in is irrelevent
 662 mkUnpackCase bndr arg unpk_args boxing_con body
 663   = Case cast_arg (setIdType bndr bndr_ty) (exprType body) [(DataAlt boxing_con, unpk_args, body)]
 664   where
 665   (cast_arg, bndr_ty) = go (idType bndr) arg
 666   go ty arg
 667     | (tycon, tycon_args, _, _)  <- splitProductType "mkUnpackCase" ty
 668     , isNewTyCon tycon && not (isRecursiveTyCon tycon)
 669     = go (newTyConInstRhs tycon tycon_args)
 670          (unwrapNewTypeBody tycon tycon_args arg)
 671     | otherwise = (arg, ty)
 672
 673 -- ...and the dual
 674 reboxProduct :: [Unique]     -- uniques to create new local binders
 675              -> Type         -- type of product to box
 676              -> ([Unique],   -- remaining uniques
 677                  CoreExpr,   -- boxed product
 678                  [Id])       -- Ids being boxed into product
 679 reboxProduct us ty
 680   = let
 681         (_tycon, _tycon_args, _pack_con, con_arg_tys) = deepSplitProductType "reboxProduct" ty
 682
 683         us' = dropList con_arg_tys us
 684
 685         arg_ids  = zipWith (mkSysLocal FSLIT("rb")) us con_arg_tys
 686
 687         bind_rhs = mkProductBox arg_ids ty
 688
 689     in
 690       (us', bind_rhs, arg_ids)
 691
 692 mkProductBox :: [Id] -> Type -> CoreExpr
 693 mkProductBox arg_ids ty
 694   = result_expr
 695   where
 696     (tycon, tycon_args, pack_con, _con_arg_tys) = splitProductType "mkProductBox" ty
 697
 698     result_expr
 699       | isNewTyCon tycon && not (isRecursiveTyCon tycon)
 700       = wrap (mkProductBox arg_ids (newTyConInstRhs tycon tycon_args))
 701       | otherwise = mkConApp pack_con (map Type tycon_args ++ map Var arg_ids)
 702
 703     wrap expr = wrapNewTypeBody tycon tycon_args expr
 704
 705
 706 -- (mkReboxingAlt us con xs rhs) basically constructs the case
 707 -- alternative  (con, xs, rhs)
 708 -- but it does the reboxing necessary to construct the *source*
 709 -- arguments, xs, from the representation arguments ys.
 710 -- For example:
 711 --      data T = MkT !(Int,Int) Bool
 712 --
 713 -- mkReboxingAlt MkT [x,b] r
 714 --      = (DataAlt MkT, [y::Int,z::Int,b], let x = (y,z) in r)
 715 --
 716 -- mkDataAlt should really be in DataCon, but it can't because
 717 -- it manipulates CoreSyn.
 718
 719 mkReboxingAlt
 720   :: [Unique]           -- Uniques for the new Ids
 721   -> DataCon
 722   -> [Var]              -- Source-level args, including existential dicts
 723   -> CoreExpr           -- RHS
 724   -> CoreAlt
 725
 726 mkReboxingAlt us con args rhs
 727   | not (any isMarkedUnboxed stricts)
 728   = (DataAlt con, args, rhs)
 729
 730   | otherwise
 731   = let
 732         (binds, args') = go args stricts us
 733     in
 734     (DataAlt con, args', mkLets binds rhs)
 735
 736   where
 737     stricts = dataConExStricts con ++ dataConStrictMarks con
 738
 739     go [] _stricts _us = ([], [])
 740
 741         -- Type variable case
 742     go (arg:args) stricts us
 743       | isTyVar arg
 744       = let (binds, args') = go args stricts us
 745         in  (binds, arg:args')
 746
 747         -- Term variable case
 748     go (arg:args) (str:stricts) us
 749       | isMarkedUnboxed str
 750       =
 751         let (binds, unpacked_args')        = go args stricts us'
 752             (us', bind_rhs, unpacked_args) = reboxProduct us (idType arg)
 753         in
 754             (NonRec arg bind_rhs : binds, unpacked_args ++ unpacked_args')
 755       | otherwise
 756       = let (binds, args') = go args stricts us
 757         in  (binds, arg:args')
 758 \end{code}
 759
 760
 761 %************************************************************************
 762 %*                                                                      *
 763 \subsection{Dictionary selectors}
 764 %*                                                                      *
 765 %************************************************************************
 766
 767 Selecting a field for a dictionary.  If there is just one field, then
 768 there's nothing to do.
 769
 770 Dictionary selectors may get nested forall-types.  Thus:
 771
 772         class Foo a where
 773           op :: forall b. Ord b => a -> b -> b
 774
 775 Then the top-level type for op is
 776
 777         op :: forall a. Foo a =>
 778               forall b. Ord b =>
 779               a -> b -> b
 780
 781 This is unlike ordinary record selectors, which have all the for-alls
 782 at the outside.  When dealing with classes it's very convenient to
 783 recover the original type signature from the class op selector.
 784
 785 \begin{code}
 786 mkDictSelId :: Name -> Class -> Id
 787 mkDictSelId name clas
 788   = mkGlobalId (ClassOpId clas) name sel_ty info
 789   where
 790     sel_ty = mkForAllTys tyvars (mkFunTy (idType dict_id) (idType the_arg_id))
 791         -- We can't just say (exprType rhs), because that would give a type
 792         --      C a -> C a
 793         -- for a single-op class (after all, the selector is the identity)
 794         -- But it's type must expose the representation of the dictionary
 795         -- to gat (say)         C a -> (a -> a)
 796
 797     info = noCafIdInfo
 798                 `setArityInfo`          1
 799                 `setUnfoldingInfo`      mkTopUnfolding rhs
 800                 `setAllStrictnessInfo`  Just strict_sig
 801
 802         -- We no longer use 'must-inline' on record selectors.  They'll
 803         -- inline like crazy if they scrutinise a constructor
 804
 805         -- The strictness signature is of the form U(AAAVAAAA) -> T
 806         -- where the V depends on which item we are selecting
 807         -- It's worth giving one, so that absence info etc is generated
 808         -- even if the selector isn't inlined
 809     strict_sig = mkStrictSig (mkTopDmdType [arg_dmd] TopRes)
 810     arg_dmd | isNewTyCon tycon = evalDmd
 811             | otherwise        = Eval (Prod [ if the_arg_id == id then evalDmd else Abs
 812                                             | id <- arg_ids ])
 813
 814     tycon      = classTyCon clas
 815     [data_con] = tyConDataCons tycon
 816     tyvars     = dataConUnivTyVars data_con
 817     arg_tys    = ASSERT( isVanillaDataCon data_con ) dataConRepArgTys data_con
 818     the_arg_id = assoc "MkId.mkDictSelId" (map idName (classSelIds clas) `zip` arg_ids) name
 819
 820     pred              = mkClassPred clas (mkTyVarTys tyvars)
 821     (dict_id:arg_ids) = mkTemplateLocals (mkPredTy pred : arg_tys)
 822
 823     rhs = mkLams tyvars (Lam dict_id rhs_body)
 824     rhs_body | isNewTyCon tycon = unwrapNewTypeBody tycon (map mkTyVarTy tyvars) (Var dict_id)
 825              | otherwise        = Case (Var dict_id) dict_id (idType the_arg_id)
 826                                        [(DataAlt data_con, arg_ids, Var the_arg_id)]
 827 \end{code}
 828
 829
 830 %************************************************************************
 831 %*                                                                      *
 832         Wrapping and unwrapping newtypes and type families
 833 %*                                                                      *
 834 %************************************************************************
 835
 836 \begin{code}
 837 wrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 838 -- The wrapper for the data constructor for a newtype looks like this:
 839 --      newtype T a = MkT (a,Int)
 840 --      MkT :: forall a. (a,Int) -> T a
 841 --      MkT = /\a. \(x:(a,Int)). x `cast` sym (CoT a)
 842 -- where CoT is the coercion TyCon assoicated with the newtype
 843 --
 844 -- The call (wrapNewTypeBody T [a] e) returns the
 845 -- body of the wrapper, namely
 846 --      e `cast` (CoT [a])
 847 --
 848 -- If a coercion constructor is provided in the newtype, then we use
 849 -- it, otherwise the wrap/unwrap are both no-ops
 850 --
 851 -- If the we are dealing with a newtype *instance*, we have a second coercion
 852 -- identifying the family instance with the constructor of the newtype
 853 -- instance.  This coercion is applied in any case (ie, composed with the
 854 -- coercion constructor of the newtype or applied by itself).
 855
 856 wrapNewTypeBody tycon args result_expr
 857   = wrapFamInstBody tycon args inner
 858   where
 859     inner
 860       | Just co_con <- newTyConCo_maybe tycon
 861       = mkCoerce (mkSymCoercion (mkTyConApp co_con args)) result_expr
 862       | otherwise
 863       = result_expr
 864
 865 -- When unwrapping, we do *not* apply any family coercion, because this will
 866 -- be done via a CoPat by the type checker.  We have to do it this way as
 867 -- computing the right type arguments for the coercion requires more than just
 868 -- a spliting operation (cf, TcPat.tcConPat).
 869
 870 unwrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 871 unwrapNewTypeBody tycon args result_expr
 872   | Just co_con <- newTyConCo_maybe tycon
 873   = mkCoerce (mkTyConApp co_con args) result_expr
 874   | otherwise
 875   = result_expr
 876
 877 -- If the type constructor is a representation type of a data instance, wrap
 878 -- the expression into a cast adjusting the expression type, which is an
 879 -- instance of the representation type, to the corresponding instance of the
 880 -- family instance type.
 881 -- See Note [Wrappers for data instance tycons]
 882 wrapFamInstBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 883 wrapFamInstBody tycon args body
 884   | Just co_con <- tyConFamilyCoercion_maybe tycon
 885   = mkCoerce (mkSymCoercion (mkTyConApp co_con args)) body
 886   | otherwise
 887   = body
 888
 889 unwrapFamInstScrut :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 890 unwrapFamInstScrut tycon args scrut
 891   | Just co_con <- tyConFamilyCoercion_maybe tycon
 892   = mkCoerce (mkTyConApp co_con args) scrut
 893   | otherwise
 894   = scrut
 895 \end{code}
 896
 897
 898 %************************************************************************
 899 %*                                                                      *
 900 \subsection{Primitive operations
 901 %*                                                                      *
 902 %************************************************************************
 903
 904 \begin{code}
 905 mkPrimOpId :: PrimOp -> Id
 906 mkPrimOpId prim_op
 907   = id
 908   where
 909     (tyvars,arg_tys,res_ty, arity, strict_sig) = primOpSig prim_op
 910     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 911     name = mkWiredInName gHC_PRIM (primOpOcc prim_op)
 912                          (mkPrimOpIdUnique (primOpTag prim_op))
 913                          (AnId id) UserSyntax
 914     id   = mkGlobalId (PrimOpId prim_op) name ty info
 915
 916     info = noCafIdInfo
 917            `setSpecInfo`          mkSpecInfo (primOpRules prim_op name)
 918            `setArityInfo`         arity
 919            `setAllStrictnessInfo` Just strict_sig
 920
 921 -- For each ccall we manufacture a separate CCallOpId, giving it
 922 -- a fresh unique, a type that is correct for this particular ccall,
 923 -- and a CCall structure that gives the correct details about calling
 924 -- convention etc.
 925 --
 926 -- The *name* of this Id is a local name whose OccName gives the full
 927 -- details of the ccall, type and all.  This means that the interface
 928 -- file reader can reconstruct a suitable Id
 929
 930 mkFCallId :: Unique -> ForeignCall -> Type -> Id
 931 mkFCallId uniq fcall ty
 932   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 933         -- A CCallOpId should have no free type variables;
 934         -- when doing substitutions won't substitute over it
 935     mkGlobalId (FCallId fcall) name ty info
 936   where
 937     occ_str = showSDoc (braces (ppr fcall <+> ppr ty))
 938         -- The "occurrence name" of a ccall is the full info about the
 939         -- ccall; it is encoded, but may have embedded spaces etc!
 940
 941     name = mkFCallName uniq occ_str
 942
 943     info = noCafIdInfo
 944            `setArityInfo`               arity
 945            `setAllStrictnessInfo`       Just strict_sig
 946
 947     (_, tau)     = tcSplitForAllTys ty
 948     (arg_tys, _) = tcSplitFunTys tau
 949     arity        = length arg_tys
 950     strict_sig   = mkStrictSig (mkTopDmdType (replicate arity evalDmd) TopRes)
 951
 952 -- Tick boxes and breakpoints are both represented as TickBoxOpIds,
 953 -- except for the type:
 954 --
 955 --    a plain HPC tick box has type (State# RealWorld)
 956 --    a breakpoint Id has type forall a.a
 957 --
 958 -- The breakpoint Id will be applied to a list of arbitrary free variables,
 959 -- which is why it needs a polymorphic type.
 960
 961 mkTickBoxOpId :: Unique -> Module -> TickBoxId -> Id
 962 mkTickBoxOpId uniq mod ix = mkTickBox' uniq mod ix realWorldStatePrimTy
 963
 964 mkBreakPointOpId :: Unique -> Module -> TickBoxId -> Id
 965 mkBreakPointOpId uniq mod ix = mkTickBox' uniq mod ix ty
 966  where ty = mkSigmaTy [openAlphaTyVar] [] openAlphaTy
 967
 968 mkTickBox' uniq mod ix ty = mkGlobalId (TickBoxOpId tickbox) name ty info
 969   where
 970     tickbox = TickBox mod ix
 971     occ_str = showSDoc (braces (ppr tickbox))
 972     name    = mkTickBoxOpName uniq occ_str
 973     info    = noCafIdInfo
 974 \end{code}
 975
 976
 977 %************************************************************************
 978 %*                                                                      *
 979 \subsection{DictFuns and default methods}
 980 %*                                                                      *
 981 %************************************************************************
 982
 983 Important notes about dict funs and default methods
 984 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 985 Dict funs and default methods are *not* ImplicitIds.  Their definition
 986 involves user-written code, so we can't figure out their strictness etc
 987 based on fixed info, as we can for constructors and record selectors (say).
 988
 989 We build them as LocalIds, but with External Names.  This ensures that
 990 they are taken to account by free-variable finding and dependency
 991 analysis (e.g. CoreFVs.exprFreeVars).
 992
 993 Why shouldn't they be bound as GlobalIds?  Because, in particular, if
 994 they are globals, the specialiser floats dict uses above their defns,
 995 which prevents good simplifications happening.  Also the strictness
 996 analyser treats a occurrence of a GlobalId as imported and assumes it
 997 contains strictness in its IdInfo, which isn't true if the thing is
 998 bound in the same module as the occurrence.
 999
1000 It's OK for dfuns to be LocalIds, because we form the instance-env to
1001 pass on to the next module (md_insts) in CoreTidy, afer tidying
1002 and globalising the top-level Ids.
1003
1004 BUT make sure they are *exported* LocalIds (mkExportedLocalId) so
1005 that they aren't discarded by the occurrence analyser.
1006
1007 \begin{code}
1008 mkDefaultMethodId dm_name ty = mkExportedLocalId dm_name ty
1009
1010 mkDictFunId :: Name             -- Name to use for the dict fun;
1011             -> [TyVar]
1012             -> ThetaType
1013             -> Class
1014             -> [Type]
1015             -> Id
1016
1017 mkDictFunId dfun_name inst_tyvars dfun_theta clas inst_tys
1018   = mkExportedLocalId dfun_name dfun_ty
1019   where
1020     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
1021
1022 {-  1 dec 99: disable the Mark Jones optimisation for the sake
1023     of compatibility with Hugs.
1024     See `types/InstEnv' for a discussion related to this.
1025
1026     (class_tyvars, sc_theta, _, _) = classBigSig clas
1027     not_const (clas, tys) = not (isEmptyVarSet (tyVarsOfTypes tys))
1028     sc_theta' = substClasses (zipTopTvSubst class_tyvars inst_tys) sc_theta
1029     dfun_theta = case inst_decl_theta of
1030                    []    -> []  -- If inst_decl_theta is empty, then we don't
1031                                 -- want to have any dict arguments, so that we can
1032                                 -- expose the constant methods.
1033
1034                    other -> nub (inst_decl_theta ++ filter not_const sc_theta')
1035                                 -- Otherwise we pass the superclass dictionaries to
1036                                 -- the dictionary function; the Mark Jones optimisation.
1037                                 --
1038                                 -- NOTE the "nub".  I got caught by this one:
1039                                 --   class Monad m => MonadT t m where ...
1040                                 --   instance Monad m => MonadT (EnvT env) m where ...
1041                                 -- Here, the inst_decl_theta has (Monad m); but so
1042                                 -- does the sc_theta'!
1043                                 --
1044                                 -- NOTE the "not_const".  I got caught by this one too:
1045                                 --   class Foo a => Baz a b where ...
1046                                 --   instance Wob b => Baz T b where..
1047                                 -- Now sc_theta' has Foo T
1048 -}
1049 \end{code}
1050
1051
1052 %************************************************************************
1053 %*                                                                      *
1054 \subsection{Un-definable}
1055 %*                                                                      *
1056 %************************************************************************
1057
1058 These Ids can't be defined in Haskell.  They could be defined in
1059 unfoldings in the wired-in GHC.Prim interface file, but we'd have to
1060 ensure that they were definitely, definitely inlined, because there is
1061 no curried identifier for them.  That's what mkCompulsoryUnfolding
1062 does.  If we had a way to get a compulsory unfolding from an interface
1063 file, we could do that, but we don't right now.
1064
1065 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
1066 just gets expanded into a type coercion wherever it occurs.  Hence we
1067 add it as a built-in Id with an unfolding here.
1068
1069 The type variables we use here are "open" type variables: this means
1070 they can unify with both unlifted and lifted types.  Hence we provide
1071 another gun with which to shoot yourself in the foot.
1072
1073 \begin{code}
1074 mkWiredInIdName mod fs uniq id
1075  = mkWiredInName mod (mkOccNameFS varName fs) uniq (AnId id) UserSyntax
1076
1077 unsafeCoerceName = mkWiredInIdName gHC_PRIM FSLIT("unsafeCoerce#") unsafeCoerceIdKey  unsafeCoerceId
1078 nullAddrName     = mkWiredInIdName gHC_PRIM FSLIT("nullAddr#")     nullAddrIdKey      nullAddrId
1079 seqName          = mkWiredInIdName gHC_PRIM FSLIT("seq")           seqIdKey           seqId
1080 realWorldName    = mkWiredInIdName gHC_PRIM FSLIT("realWorld#")    realWorldPrimIdKey realWorldPrimId
1081 lazyIdName       = mkWiredInIdName gHC_BASE FSLIT("lazy")         lazyIdKey           lazyId
1082
1083 errorName                = mkWiredInIdName gHC_ERR FSLIT("error")            errorIdKey eRROR_ID
1084 recSelErrorName          = mkWiredInIdName gHC_ERR FSLIT("recSelError")     recSelErrorIdKey rEC_SEL_ERROR_ID
1085 runtimeErrorName         = mkWiredInIdName gHC_ERR FSLIT("runtimeError")    runtimeErrorIdKey rUNTIME_ERROR_ID
1086 irrefutPatErrorName      = mkWiredInIdName gHC_ERR FSLIT("irrefutPatError") irrefutPatErrorIdKey iRREFUT_PAT_ERROR_ID
1087 recConErrorName          = mkWiredInIdName gHC_ERR FSLIT("recConError")     recConErrorIdKey rEC_CON_ERROR_ID
1088 patErrorName             = mkWiredInIdName gHC_ERR FSLIT("patError")         patErrorIdKey pAT_ERROR_ID
1089 noMethodBindingErrorName = mkWiredInIdName gHC_ERR FSLIT("noMethodBindingError")
1090                                            noMethodBindingErrorIdKey nO_METHOD_BINDING_ERROR_ID
1091 nonExhaustiveGuardsErrorName
1092   = mkWiredInIdName gHC_ERR FSLIT("nonExhaustiveGuardsError")
1093                     nonExhaustiveGuardsErrorIdKey nON_EXHAUSTIVE_GUARDS_ERROR_ID
1094 \end{code}
1095
1096 \begin{code}
1097 -- unsafeCoerce# :: forall a b. a -> b
1098 unsafeCoerceId
1099   = pcMiscPrelId unsafeCoerceName ty info
1100   where
1101     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
1102
1103
1104     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
1105                       (mkFunTy openAlphaTy openBetaTy)
1106     [x] = mkTemplateLocals [openAlphaTy]
1107     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
1108           Cast (Var x) (mkUnsafeCoercion openAlphaTy openBetaTy)
1109
1110 -- nullAddr# :: Addr#
1111 -- The reason is is here is because we don't provide
1112 -- a way to write this literal in Haskell.
1113 nullAddrId
1114   = pcMiscPrelId nullAddrName addrPrimTy info
1115   where
1116     info = noCafIdInfo `setUnfoldingInfo`
1117            mkCompulsoryUnfolding (Lit nullAddrLit)
1118
1119 seqId
1120   = pcMiscPrelId seqName ty info
1121   where
1122     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
1123
1124
1125     ty  = mkForAllTys [alphaTyVar,openBetaTyVar]
1126                       (mkFunTy alphaTy (mkFunTy openBetaTy openBetaTy))
1127     [x,y] = mkTemplateLocals [alphaTy, openBetaTy]
1128     rhs = mkLams [alphaTyVar,openBetaTyVar,x,y] (Case (Var x) x openBetaTy [(DEFAULT, [], Var y)])
1129
1130 -- lazy :: forall a?. a? -> a?   (i.e. works for unboxed types too)
1131 -- Used to lazify pseq:         pseq a b = a `seq` lazy b
1132 --
1133 -- Also, no strictness: by being a built-in Id, all the info about lazyId comes from here,
1134 -- not from GHC.Base.hi.   This is important, because the strictness
1135 -- analyser will spot it as strict!
1136 --
1137 -- Also no unfolding in lazyId: it gets "inlined" by a HACK in the worker/wrapperpass
1138 --      (see WorkWrap.wwExpr)
1139 -- We could use inline phases to do this, but that would be vulnerable to changes in
1140 -- phase numbering....we must inline precisely after strictness analysis.
1141 lazyId
1142   = pcMiscPrelId lazyIdName ty info
1143   where
1144     info = noCafIdInfo
1145     ty  = mkForAllTys [alphaTyVar] (mkFunTy alphaTy alphaTy)
1146
1147 lazyIdUnfolding :: CoreExpr     -- Used to expand 'lazyId' after strictness anal
1148 lazyIdUnfolding = mkLams [openAlphaTyVar,x] (Var x)
1149                 where
1150                   [x] = mkTemplateLocals [openAlphaTy]
1151 \end{code}
1152
1153 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
1154 nasty as-is, change it back to a literal (@Literal@).
1155
1156 voidArgId is a Local Id used simply as an argument in functions
1157 where we just want an arg to avoid having a thunk of unlifted type.
1158 E.g.
1159         x = \ void :: State# RealWorld -> (# p, q #)
1160
1161 This comes up in strictness analysis
1162
1163 \begin{code}
1164 realWorldPrimId -- :: State# RealWorld
1165   = pcMiscPrelId realWorldName realWorldStatePrimTy
1166                  (noCafIdInfo `setUnfoldingInfo` evaldUnfolding)
1167         -- The evaldUnfolding makes it look that realWorld# is evaluated
1168         -- which in turn makes Simplify.interestingArg return True,
1169         -- which in turn makes INLINE things applied to realWorld# likely
1170         -- to be inlined
1171
1172 voidArgId       -- :: State# RealWorld
1173   = mkSysLocal FSLIT("void") voidArgIdKey realWorldStatePrimTy
1174 \end{code}
1175
1176
1177 %************************************************************************
1178 %*                                                                      *
1179 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
1180 %*                                                                      *
1181 %************************************************************************
1182
1183 GHC randomly injects these into the code.
1184
1185 @patError@ is just a version of @error@ for pattern-matching
1186 failures.  It knows various ``codes'' which expand to longer
1187 strings---this saves space!
1188
1189 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
1190 well shouldn't be yanked on, but if one is, then you will get a
1191 friendly message from @absentErr@ (rather than a totally random
1192 crash).
1193
1194 @parError@ is a special version of @error@ which the compiler does
1195 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
1196 templates, but we don't ever expect to generate code for it.
1197
1198 \begin{code}
1199 mkRuntimeErrorApp
1200         :: Id           -- Should be of type (forall a. Addr# -> a)
1201                         --      where Addr# points to a UTF8 encoded string
1202         -> Type         -- The type to instantiate 'a'
1203         -> String       -- The string to print
1204         -> CoreExpr
1205
1206 mkRuntimeErrorApp err_id res_ty err_msg
1207   = mkApps (Var err_id) [Type res_ty, err_string]
1208   where
1209     err_string = Lit (mkStringLit err_msg)
1210
1211 rEC_SEL_ERROR_ID                = mkRuntimeErrorId recSelErrorName
1212 rUNTIME_ERROR_ID                = mkRuntimeErrorId runtimeErrorName
1213 iRREFUT_PAT_ERROR_ID            = mkRuntimeErrorId irrefutPatErrorName
1214 rEC_CON_ERROR_ID                = mkRuntimeErrorId recConErrorName
1215 pAT_ERROR_ID                    = mkRuntimeErrorId patErrorName
1216 nO_METHOD_BINDING_ERROR_ID      = mkRuntimeErrorId noMethodBindingErrorName
1217 nON_EXHAUSTIVE_GUARDS_ERROR_ID  = mkRuntimeErrorId nonExhaustiveGuardsErrorName
1218
1219 -- The runtime error Ids take a UTF8-encoded string as argument
1220 mkRuntimeErrorId name = pc_bottoming_Id name runtimeErrorTy
1221 runtimeErrorTy        = mkSigmaTy [openAlphaTyVar] [] (mkFunTy addrPrimTy openAlphaTy)
1222 \end{code}
1223
1224 \begin{code}
1225 eRROR_ID = pc_bottoming_Id errorName errorTy
1226
1227 errorTy  :: Type
1228 errorTy  = mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkListTy charTy] openAlphaTy)
1229     -- Notice the openAlphaTyVar.  It says that "error" can be applied
1230     -- to unboxed as well as boxed types.  This is OK because it never
1231     -- returns, so the return type is irrelevant.
1232 \end{code}
1233
1234
1235 %************************************************************************
1236 %*                                                                      *
1237 \subsection{Utilities}
1238 %*                                                                      *
1239 %************************************************************************
1240
1241 \begin{code}
1242 pcMiscPrelId :: Name -> Type -> IdInfo -> Id
1243 pcMiscPrelId name ty info
1244   = mkVanillaGlobal name ty info
1245     -- We lie and say the thing is imported; otherwise, we get into
1246     -- a mess with dependency analysis; e.g., core2stg may heave in
1247     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
1248     -- being compiled, then it's just a matter of luck if the definition
1249     -- will be in "the right place" to be in scope.
1250
1251 pc_bottoming_Id name ty
1252  = pcMiscPrelId name ty bottoming_info
1253  where
1254     bottoming_info = vanillaIdInfo `setAllStrictnessInfo` Just strict_sig
1255         -- Do *not* mark them as NoCafRefs, because they can indeed have
1256         -- CAF refs.  For example, pAT_ERROR_ID calls GHC.Err.untangle,
1257         -- which has some CAFs
1258         -- In due course we may arrange that these error-y things are
1259         -- regarded by the GC as permanently live, in which case we
1260         -- can give them NoCaf info.  As it is, any function that calls
1261         -- any pc_bottoming_Id will itself have CafRefs, which bloats
1262         -- SRTs.
1263
1264     strict_sig     = mkStrictSig (mkTopDmdType [evalDmd] BotRes)
1265         -- These "bottom" out, no matter what their arguments
1266 \end{code}
1267