compiler/basicTypes/MkId.lhs

   1 \%
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1998
   4 %
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9         * data constructors
  10         * record selectors
  11         * method and superclass selectors
  12         * primitive operations
  13
  14 \begin{code}
  15 {-# OPTIONS -w #-}
  16 -- The above warning supression flag is a temporary kludge.
  17 -- While working on this module you are encouraged to remove it and fix
  18 -- any warnings in the module. See
  19 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  20 -- for details
  21
  22 module MkId (
  23         mkDictFunId, mkDefaultMethodId,
  24         mkDictSelId,
  25
  26         mkDataConIds,
  27         mkRecordSelId,
  28         mkPrimOpId, mkFCallId, mkTickBoxOpId, mkBreakPointOpId,
  29
  30         mkReboxingAlt, wrapNewTypeBody, unwrapNewTypeBody,
  31         wrapFamInstBody, unwrapFamInstScrut,
  32         mkUnpackCase, mkProductBox,
  33
  34         -- And some particular Ids; see below for why they are wired in
  35         wiredInIds, ghcPrimIds,
  36         unsafeCoerceId, realWorldPrimId, voidArgId, nullAddrId, seqId,
  37         lazyId, lazyIdUnfolding, lazyIdKey,
  38
  39         mkRuntimeErrorApp,
  40         rEC_CON_ERROR_ID, iRREFUT_PAT_ERROR_ID, rUNTIME_ERROR_ID,
  41         nON_EXHAUSTIVE_GUARDS_ERROR_ID, nO_METHOD_BINDING_ERROR_ID,
  42         pAT_ERROR_ID, eRROR_ID,
  43
  44         unsafeCoerceName
  45     ) where
  46
  47 #include "HsVersions.h"
  48
  49 import Rules
  50 import TysPrim
  51 import TysWiredIn
  52 import PrelRules
  53 import Type
  54 import TypeRep
  55 import TcGadt
  56 import Coercion
  57 import TcType
  58 import CoreUtils
  59 import CoreUnfold
  60 import Literal
  61 import TyCon
  62 import Class
  63 import VarSet
  64 import Name
  65 import OccName
  66 import PrimOp
  67 import ForeignCall
  68 import DataCon
  69 import Id
  70 import Var              ( Var, TyVar, mkCoVar)
  71 import IdInfo
  72 import NewDemand
  73 import DmdAnal
  74 import CoreSyn
  75 import Unique
  76 import Maybes
  77 import PrelNames
  78 import BasicTypes       hiding ( SuccessFlag(..) )
  79 import Util
  80 import Outputable
  81 import FastString
  82 import ListSetOps
  83 import Module
  84 \end{code}
  85
  86 %************************************************************************
  87 %*                                                                      *
  88 \subsection{Wired in Ids}
  89 %*                                                                      *
  90 %************************************************************************
  91
  92 \begin{code}
  93 wiredInIds
  94   = [   -- These error-y things are wired in because we don't yet have
  95         -- a way to express in an interface file that the result type variable
  96         -- is 'open'; that is can be unified with an unboxed type
  97         --
  98         -- [The interface file format now carry such information, but there's
  99         -- no way yet of expressing at the definition site for these
 100         -- error-reporting functions that they have an 'open'
 101         -- result type. -- sof 1/99]
 102
 103     eRROR_ID,   -- This one isn't used anywhere else in the compiler
 104                 -- But we still need it in wiredInIds so that when GHC
 105                 -- compiles a program that mentions 'error' we don't
 106                 -- import its type from the interface file; we just get
 107                 -- the Id defined here.  Which has an 'open-tyvar' type.
 108
 109     rUNTIME_ERROR_ID,
 110     iRREFUT_PAT_ERROR_ID,
 111     nON_EXHAUSTIVE_GUARDS_ERROR_ID,
 112     nO_METHOD_BINDING_ERROR_ID,
 113     pAT_ERROR_ID,
 114     rEC_CON_ERROR_ID,
 115
 116     lazyId
 117     ] ++ ghcPrimIds
 118
 119 -- These Ids are exported from GHC.Prim
 120 ghcPrimIds
 121   = [   -- These can't be defined in Haskell, but they have
 122         -- perfectly reasonable unfoldings in Core
 123     realWorldPrimId,
 124     unsafeCoerceId,
 125     nullAddrId,
 126     seqId
 127     ]
 128 \end{code}
 129
 130 %************************************************************************
 131 %*                                                                      *
 132 \subsection{Data constructors}
 133 %*                                                                      *
 134 %************************************************************************
 135
 136 The wrapper for a constructor is an ordinary top-level binding that evaluates
 137 any strict args, unboxes any args that are going to be flattened, and calls
 138 the worker.
 139
 140 We're going to build a constructor that looks like:
 141
 142         data (Data a, C b) =>  T a b = T1 !a !Int b
 143
 144         T1 = /\ a b ->
 145              \d1::Data a, d2::C b ->
 146              \p q r -> case p of { p ->
 147                        case q of { q ->
 148                        Con T1 [a,b] [p,q,r]}}
 149
 150 Notice that
 151
 152 * d2 is thrown away --- a context in a data decl is used to make sure
 153   one *could* construct dictionaries at the site the constructor
 154   is used, but the dictionary isn't actually used.
 155
 156 * We have to check that we can construct Data dictionaries for
 157   the types a and Int.  Once we've done that we can throw d1 away too.
 158
 159 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 160   all that matters is that the arguments are evaluated.  "seq" is
 161   very careful to preserve evaluation order, which we don't need
 162   to be here.
 163
 164   You might think that we could simply give constructors some strictness
 165   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 166   But we don't do that because in the case of primops and functions strictness
 167   is a *property* not a *requirement*.  In the case of constructors we need to
 168   do something active to evaluate the argument.
 169
 170   Making an explicit case expression allows the simplifier to eliminate
 171   it in the (common) case where the constructor arg is already evaluated.
 172
 173 Note [Wrappers for data instance tycons]
 174 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 175 In the case of data instances, the wrapper also applies the coercion turning
 176 the representation type into the family instance type to cast the result of
 177 the wrapper.  For example, consider the declarations
 178
 179   data family Map k :: * -> *
 180   data instance Map (a, b) v = MapPair (Map a (Pair b v))
 181
 182 The tycon to which the datacon MapPair belongs gets a unique internal
 183 name of the form :R123Map, and we call it the representation tycon.
 184 In contrast, Map is the family tycon (accessible via
 185 tyConFamInst_maybe). A coercion allows you to move between
 186 representation and family type.  It is accessible from :R123Map via
 187 tyConFamilyCoercion_maybe and has kind
 188
 189   Co123Map a b v :: {Map (a, b) v :=: :R123Map a b v}
 190
 191 The wrapper and worker of MapPair get the types
 192
 193         -- Wrapper
 194   $WMapPair :: forall a b v. Map a (Map a b v) -> Map (a, b) v
 195   $WMapPair a b v = MapPair a b v `cast` sym (Co123Map a b v)
 196
 197         -- Worker
 198   MapPair :: forall a b v. Map a (Map a b v) -> :R123Map a b v
 199
 200 This coercion is conditionally applied by wrapFamInstBody.
 201
 202 It's a bit more complicated if the data instance is a GADT as well!
 203
 204    data instance T [a] where
 205         T1 :: forall b. b -> T [Maybe b]
 206 Hence
 207    Co7T a :: T [a] ~ :R7T a
 208
 209 Now we want
 210
 211         -- Wrapper
 212   $WT1 :: forall b. b -> T [Maybe b]
 213   $WT1 b v = T1 (Maybe b) b (Maybe b) v
 214                         `cast` sym (Co7T (Maybe b))
 215
 216         -- Worker
 217   T1 :: forall c b. (c ~ Maybe b) => b -> :R7T c
 218
 219 \begin{code}
 220 mkDataConIds :: Name -> Name -> DataCon -> DataConIds
 221 mkDataConIds wrap_name wkr_name data_con
 222   | isNewTyCon tycon                    -- Newtype, only has a worker
 223   = DCIds Nothing nt_work_id
 224
 225   | any isMarkedStrict all_strict_marks      -- Algebraic, needs wrapper
 226     || not (null eq_spec)                    -- NB: LoadIface.ifaceDeclSubBndrs
 227     || isFamInstTyCon tycon                  --     depends on this test
 228   = DCIds (Just alg_wrap_id) wrk_id
 229
 230   | otherwise                                -- Algebraic, no wrapper
 231   = DCIds Nothing wrk_id
 232   where
 233     (univ_tvs, ex_tvs, eq_spec,
 234      eq_theta, dict_theta, orig_arg_tys, res_ty) = dataConFullSig data_con
 235     tycon = dataConTyCon data_con       -- The representation TyCon (not family)
 236
 237         ----------- Worker (algebraic data types only) --------------
 238         -- The *worker* for the data constructor is the function that
 239         -- takes the representation arguments and builds the constructor.
 240     wrk_id = mkGlobalId (DataConWorkId data_con) wkr_name
 241                         (dataConRepType data_con) wkr_info
 242
 243     wkr_arity = dataConRepArity data_con
 244     wkr_info  = noCafIdInfo
 245                 `setArityInfo`          wkr_arity
 246                 `setAllStrictnessInfo`  Just wkr_sig
 247                 `setUnfoldingInfo`      evaldUnfolding  -- Record that it's evaluated,
 248                                                         -- even if arity = 0
 249
 250     wkr_sig = mkStrictSig (mkTopDmdType (replicate wkr_arity topDmd) cpr_info)
 251         --      Note [Data-con worker strictness]
 252         -- Notice that we do *not* say the worker is strict
 253         -- even if the data constructor is declared strict
 254         --      e.g.    data T = MkT !(Int,Int)
 255         -- Why?  Because the *wrapper* is strict (and its unfolding has case
 256         -- expresssions that do the evals) but the *worker* itself is not.
 257         -- If we pretend it is strict then when we see
 258         --      case x of y -> $wMkT y
 259         -- the simplifier thinks that y is "sure to be evaluated" (because
 260         --  $wMkT is strict) and drops the case.  No, $wMkT is not strict.
 261         --
 262         -- When the simplifer sees a pattern
 263         --      case e of MkT x -> ...
 264         -- it uses the dataConRepStrictness of MkT to mark x as evaluated;
 265         -- but that's fine... dataConRepStrictness comes from the data con
 266         -- not from the worker Id.
 267
 268     cpr_info | isProductTyCon tycon &&
 269                isDataTyCon tycon    &&
 270                wkr_arity > 0        &&
 271                wkr_arity <= mAX_CPR_SIZE        = retCPR
 272              | otherwise                        = TopRes
 273         -- RetCPR is only true for products that are real data types;
 274         -- that is, not unboxed tuples or [non-recursive] newtypes
 275
 276         ----------- Workers for newtypes --------------
 277     nt_work_id   = mkGlobalId (DataConWrapId data_con) wkr_name wrap_ty nt_work_info
 278     nt_work_info = noCafIdInfo          -- The NoCaf-ness is set by noCafIdInfo
 279                   `setArityInfo` 1      -- Arity 1
 280                   `setUnfoldingInfo`     newtype_unf
 281     newtype_unf  = -- The assertion below is no longer correct:
 282                    --   there may be a dict theta rather than a singleton orig_arg_ty
 283                    -- ASSERT( isVanillaDataCon data_con &&
 284                    --      isSingleton orig_arg_tys )
 285                    --
 286                    -- No existentials on a newtype, but it can have a context
 287                    -- e.g.      newtype Eq a => T a = MkT (...)
 288                    mkCompulsoryUnfolding $
 289                    mkLams wrap_tvs $ Lam id_arg1 $
 290                    wrapNewTypeBody tycon res_ty_args
 291                        (Var id_arg1)
 292
 293     id_arg1 = mkTemplateLocal 1
 294                 (if null orig_arg_tys
 295                     then ASSERT(not (null $ dataConDictTheta data_con)) mkPredTy $ head (dataConDictTheta data_con)
 296                     else head orig_arg_tys
 297                 )
 298
 299         ----------- Wrapper --------------
 300         -- We used to include the stupid theta in the wrapper's args
 301         -- but now we don't.  Instead the type checker just injects these
 302         -- extra constraints where necessary.
 303     wrap_tvs    = (univ_tvs `minusList` map fst eq_spec) ++ ex_tvs
 304     res_ty_args = substTyVars (mkTopTvSubst eq_spec) univ_tvs
 305     eq_tys   = mkPredTys eq_theta
 306     dict_tys = mkPredTys dict_theta
 307     wrap_ty  = mkForAllTys wrap_tvs $ mkFunTys eq_tys $ mkFunTys dict_tys $
 308                mkFunTys orig_arg_tys $ res_ty
 309         -- NB: watch out here if you allow user-written equality
 310         --     constraints in data constructor signatures
 311
 312         ----------- Wrappers for algebraic data types --------------
 313     alg_wrap_id = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty alg_wrap_info
 314     alg_wrap_info = noCafIdInfo         -- The NoCaf-ness is set by noCafIdInfo
 315                     `setArityInfo`         wrap_arity
 316                         -- It's important to specify the arity, so that partial
 317                         -- applications are treated as values
 318                     `setUnfoldingInfo`     wrap_unf
 319                     `setAllStrictnessInfo` Just wrap_sig
 320
 321     all_strict_marks = dataConExStricts data_con ++ dataConStrictMarks data_con
 322     wrap_sig = mkStrictSig (mkTopDmdType arg_dmds cpr_info)
 323     arg_dmds = map mk_dmd all_strict_marks
 324     mk_dmd str | isMarkedStrict str = evalDmd
 325                | otherwise          = lazyDmd
 326         -- The Cpr info can be important inside INLINE rhss, where the
 327         -- wrapper constructor isn't inlined.
 328         -- And the argument strictness can be important too; we
 329         -- may not inline a contructor when it is partially applied.
 330         -- For example:
 331         --      data W = C !Int !Int !Int
 332         --      ...(let w = C x in ...(w p q)...)...
 333         -- we want to see that w is strict in its two arguments
 334
 335     wrap_unf = mkTopUnfolding $ Note InlineMe $
 336               mkLams wrap_tvs $
 337               mkLams eq_args $
 338               mkLams dict_args $ mkLams id_args $
 339               foldr mk_case con_app
 340                     (zip (dict_args ++ id_args) all_strict_marks)
 341                     i3 []
 342
 343     con_app _ rep_ids = wrapFamInstBody tycon res_ty_args $
 344                           Var wrk_id `mkTyApps`  res_ty_args
 345                                      `mkVarApps` ex_tvs
 346                                      `mkTyApps`  map snd eq_spec        -- Equality evidence
 347                                      `mkVarApps` eq_args
 348                                      `mkVarApps` reverse rep_ids
 349
 350     (dict_args,i2) = mkLocals 1  dict_tys
 351     (id_args,i3)   = mkLocals i2 orig_arg_tys
 352     wrap_arity     = i3-1
 353     (eq_args,_)    = mkCoVarLocals i3 eq_tys
 354
 355     mkCoVarLocals i []     = ([],i)
 356     mkCoVarLocals i (x:xs) = let (ys,j) = mkCoVarLocals (i+1) xs
 357                                  y      = mkCoVar (mkSysTvName (mkBuiltinUnique i) FSLIT("dc_co")) x
 358                              in (y:ys,j)
 359
 360     mk_case
 361            :: (Id, StrictnessMark)      -- Arg, strictness
 362            -> (Int -> [Id] -> CoreExpr) -- Body
 363            -> Int                       -- Next rep arg id
 364            -> [Id]                      -- Rep args so far, reversed
 365            -> CoreExpr
 366     mk_case (arg,strict) body i rep_args
 367           = case strict of
 368                 NotMarkedStrict -> body i (arg:rep_args)
 369                 MarkedStrict
 370                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 371                    | otherwise ->
 372                         Case (Var arg) arg res_ty [(DEFAULT,[], body i (arg:rep_args))]
 373
 374                 MarkedUnboxed
 375                    -> unboxProduct i (Var arg) (idType arg) the_body
 376                       where
 377                         the_body i con_args = body i (reverse con_args ++ rep_args)
 378
 379 mAX_CPR_SIZE :: Arity
 380 mAX_CPR_SIZE = 10
 381 -- We do not treat very big tuples as CPR-ish:
 382 --      a) for a start we get into trouble because there aren't
 383 --         "enough" unboxed tuple types (a tiresome restriction,
 384 --         but hard to fix),
 385 --      b) more importantly, big unboxed tuples get returned mainly
 386 --         on the stack, and are often then allocated in the heap
 387 --         by the caller.  So doing CPR for them may in fact make
 388 --         things worse.
 389
 390 mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 391                where
 392                  n = length tys
 393 \end{code}
 394
 395
 396 %************************************************************************
 397 %*                                                                      *
 398 \subsection{Record selectors}
 399 %*                                                                      *
 400 %************************************************************************
 401
 402 We're going to build a record selector unfolding that looks like this:
 403
 404         data T a b c = T1 { ..., op :: a, ...}
 405                      | T2 { ..., op :: a, ...}
 406                      | T3
 407
 408         sel = /\ a b c -> \ d -> case d of
 409                                     T1 ... x ... -> x
 410                                     T2 ... x ... -> x
 411                                     other        -> error "..."
 412
 413 Similarly for newtypes
 414
 415         newtype N a = MkN { unN :: a->a }
 416
 417         unN :: N a -> a -> a
 418         unN n = coerce (a->a) n
 419
 420 We need to take a little care if the field has a polymorphic type:
 421
 422         data R = R { f :: forall a. a->a }
 423
 424 Then we want
 425
 426         f :: forall a. R -> a -> a
 427         f = /\ a \ r = case r of
 428                           R f -> f a
 429
 430 (not f :: R -> forall a. a->a, which gives the type inference mechanism
 431 problems at call sites)
 432
 433 Similarly for (recursive) newtypes
 434
 435         newtype N = MkN { unN :: forall a. a->a }
 436
 437         unN :: forall b. N -> b -> b
 438         unN = /\b -> \n:N -> (coerce (forall a. a->a) n)
 439
 440
 441 Note [Naughty record selectors]
 442 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 443 A "naughty" field is one for which we can't define a record
 444 selector, because an existential type variable would escape.  For example:
 445         data T = forall a. MkT { x,y::a }
 446 We obviously can't define
 447         x (MkT v _) = v
 448 Nevertheless we *do* put a RecordSelId into the type environment
 449 so that if the user tries to use 'x' as a selector we can bleat
 450 helpfully, rather than saying unhelpfully that 'x' is not in scope.
 451 Hence the sel_naughty flag, to identify record selectors that don't really exist.
 452
 453 In general, a field is naughty if its type mentions a type variable that
 454 isn't in the result type of the constructor.
 455
 456 Note [GADT record selectors]
 457 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 458 For GADTs, we require that all constructors with a common field 'f' have the same
 459 result type (modulo alpha conversion).  [Checked in TcTyClsDecls.checkValidTyCon]
 460 E.g.
 461         data T where
 462           T1 { f :: a } :: T [a]
 463           T2 { f :: a, y :: b  } :: T [a]
 464 and now the selector takes that type as its argument:
 465         f :: forall a. T [a] -> a
 466         f t = case t of
 467                 T1 { f = v } -> v
 468                 T2 { f = v } -> v
 469 Note the forall'd tyvars of the selector are just the free tyvars
 470 of the result type; there may be other tyvars in the constructor's
 471 type (e.g. 'b' in T2).
 472
 473 Note [Selector running example]
 474 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 475 It's OK to combine GADTs and type families.  Here's a running example:
 476
 477         data instance T [a] where
 478           T1 { fld :: b } :: T [Maybe b]
 479
 480 The representation type looks like this
 481         data :R7T a where
 482           T1 { fld :: b } :: :R7T (Maybe b)
 483
 484 and there's coercion from the family type to the representation type
 485         :CoR7T a :: T [a] ~ :R7T a
 486
 487 The selector we want for fld looks like this:
 488
 489         fld :: forall b. T [Maybe b] -> b
 490         fld = /\b. \(d::T [Maybe b]).
 491               case d `cast` :CoR7T (Maybe b) of
 492                 T1 (x::b) -> x
 493
 494 The scrutinee of the case has type :R7T (Maybe b), which can be
 495 gotten by appying the eq_spec to the univ_tvs of the data con.
 496
 497 \begin{code}
 498 mkRecordSelId :: TyCon -> FieldLabel -> Id
 499 mkRecordSelId tycon field_label
 500         -- Assumes that all fields with the same field label have the same type
 501   = sel_id
 502   where
 503     -- Because this function gets called by implicitTyThings, we need to
 504     -- produce the OccName of the Id without doing any suspend type checks.
 505     -- (see the note [Tricky iface loop]).
 506     -- A suspended type-check is sometimes necessary to compute field_ty,
 507     -- so we need to make sure that we suspend anything that depends on field_ty.
 508
 509     -- the overall result
 510     sel_id = mkGlobalId sel_id_details field_label theType theInfo
 511
 512     -- check whether the type is naughty: this thunk does not get forced
 513     -- until the type is actually needed
 514     field_ty    = dataConFieldType con1 field_label
 515     is_naughty = not (tyVarsOfType field_ty `subVarSet` data_tv_set)
 516
 517     -- it's important that this doesn't force the if
 518     (theType, theInfo) = if is_naughty
 519                          -- Escapist case here for naughty constructors
 520                          -- We give it no IdInfo, and a type of forall a.a (never looked at)
 521                          then (forall_a_a, noCafIdInfo)
 522                          -- otherwise do the real case
 523                          else (selector_ty, info)
 524
 525     sel_id_details = RecordSelId { sel_tycon = tycon, sel_label = field_label, sel_naughty = is_naughty }
 526     -- For a data type family, the tycon is the *instance* TyCon
 527
 528     -- for naughty case
 529     forall_a_a = mkForAllTy alphaTyVar (mkTyVarTy alphaTyVar)
 530
 531     -- real case starts here:
 532     data_cons         = tyConDataCons tycon
 533     data_cons_w_field = filter has_field data_cons      -- Can't be empty!
 534     has_field con     = field_label `elem` dataConFieldLabels con
 535
 536     con1        = ASSERT( not (null data_cons_w_field) ) head data_cons_w_field
 537     (univ_tvs, _, eq_spec, _, _, _, data_ty) = dataConFullSig con1
 538         -- For a data type family, the data_ty (and hence selector_ty) mentions
 539         -- only the family TyCon, not the instance TyCon
 540     data_tv_set = tyVarsOfType data_ty
 541     data_tvs    = varSetElems data_tv_set
 542
 543         -- *Very* tiresomely, the selectors are (unnecessarily!) overloaded over
 544         -- just the dictionaries in the types of the constructors that contain
 545         -- the relevant field.  [The Report says that pattern matching on a
 546         -- constructor gives the same constraints as applying it.]  Urgh.
 547         --
 548         -- However, not all data cons have all constraints (because of
 549         -- BuildTyCl.mkDataConStupidTheta).  So we need to find all the data cons
 550         -- involved in the pattern match and take the union of their constraints.
 551     stupid_dict_tys = mkPredTys (dataConsStupidTheta data_cons_w_field)
 552     n_stupid_dicts  = length stupid_dict_tys
 553
 554     (field_tyvars,pre_field_theta,field_tau) = tcSplitSigmaTy field_ty
 555     field_theta       = filter (not . isEqPred) pre_field_theta
 556     field_dict_tys    = mkPredTys field_theta
 557     n_field_dict_tys  = length field_dict_tys
 558         -- If the field has a universally quantified type we have to
 559         -- be a bit careful.  Suppose we have
 560         --      data R = R { op :: forall a. Foo a => a -> a }
 561         -- Then we can't give op the type
 562         --      op :: R -> forall a. Foo a => a -> a
 563         -- because the typechecker doesn't understand foralls to the
 564         -- right of an arrow.  The "right" type to give it is
 565         --      op :: forall a. Foo a => R -> a -> a
 566         -- But then we must generate the right unfolding too:
 567         --      op = /\a -> \dfoo -> \ r ->
 568         --           case r of
 569         --              R op -> op a dfoo
 570         -- Note that this is exactly the type we'd infer from a user defn
 571         --      op (R op) = op
 572
 573     selector_ty :: Type
 574     selector_ty  = mkForAllTys data_tvs $ mkForAllTys field_tyvars $
 575                    mkFunTys stupid_dict_tys  $  mkFunTys field_dict_tys $
 576                    mkFunTy data_ty field_tau
 577
 578     arity = 1 + n_stupid_dicts + n_field_dict_tys
 579
 580     (strict_sig, rhs_w_str) = dmdAnalTopRhs sel_rhs
 581         -- Use the demand analyser to work out strictness.
 582         -- With all this unpackery it's not easy!
 583
 584     info = noCafIdInfo
 585            `setCafInfo`           caf_info
 586            `setArityInfo`         arity
 587            `setUnfoldingInfo`     mkTopUnfolding rhs_w_str
 588            `setAllStrictnessInfo` Just strict_sig
 589
 590         -- Allocate Ids.  We do it a funny way round because field_dict_tys is
 591         -- almost always empty.  Also note that we use max_dict_tys
 592         -- rather than n_dict_tys, because the latter gives an infinite loop:
 593         -- n_dict tys depends on the_alts, which depens on arg_ids, which depends
 594         -- on arity, which depends on n_dict tys.  Sigh!  Mega sigh!
 595     stupid_dict_ids  = mkTemplateLocalsNum 1 stupid_dict_tys
 596     max_stupid_dicts = length (tyConStupidTheta tycon)
 597     field_dict_base  = max_stupid_dicts + 1
 598     field_dict_ids   = mkTemplateLocalsNum field_dict_base field_dict_tys
 599     dict_id_base     = field_dict_base + n_field_dict_tys
 600     data_id          = mkTemplateLocal dict_id_base data_ty
 601     scrut_id         = mkTemplateLocal (dict_id_base+1) scrut_ty
 602     arg_base         = dict_id_base + 2
 603
 604     the_alts :: [CoreAlt]
 605     the_alts   = map mk_alt data_cons_w_field   -- Already sorted by data-con
 606     no_default = length data_cons == length data_cons_w_field   -- No default needed
 607
 608     default_alt | no_default = []
 609                 | otherwise  = [(DEFAULT, [], error_expr)]
 610
 611         -- The default branch may have CAF refs, because it calls recSelError etc.
 612     caf_info    | no_default = NoCafRefs
 613                 | otherwise  = MayHaveCafRefs
 614
 615     sel_rhs = mkLams data_tvs $ mkLams field_tyvars $
 616               mkLams stupid_dict_ids $ mkLams field_dict_ids $
 617               Lam data_id $ mk_result sel_body
 618
 619     scrut_ty_args = substTyVars (mkTopTvSubst eq_spec) univ_tvs
 620     scrut_ty      = mkTyConApp tycon scrut_ty_args
 621     scrut = unwrapFamInstScrut tycon scrut_ty_args (Var data_id)
 622         -- First coerce from the type family to the representation type
 623
 624         -- NB: A newtype always has a vanilla DataCon; no existentials etc
 625         --     data_tys will simply be the dataConUnivTyVars
 626     sel_body | isNewTyCon tycon = unwrapNewTypeBody tycon scrut_ty_args scrut
 627              | otherwise        = Case scrut scrut_id field_ty (default_alt ++ the_alts)
 628
 629     mk_result poly_result = mkVarApps (mkVarApps poly_result field_tyvars) field_dict_ids
 630         -- We pull the field lambdas to the top, so we need to
 631         -- apply them in the body.  For example:
 632         --      data T = MkT { foo :: forall a. a->a }
 633         --
 634         --      foo :: forall a. T -> a -> a
 635         --      foo = /\a. \t:T. case t of { MkT f -> f a }
 636
 637     mk_alt data_con
 638       =   ASSERT2( data_ty `tcEqType` field_ty, ppr data_con $$ ppr data_ty $$ ppr field_ty )
 639           mkReboxingAlt rebox_uniqs data_con (ex_tvs ++ co_tvs ++ arg_vs) rhs
 640       where
 641            -- get pattern binders with types appropriately instantiated
 642         arg_uniqs = map mkBuiltinUnique [arg_base..]
 643         (ex_tvs, co_tvs, arg_vs) = dataConOrigInstPat arg_uniqs data_con scrut_ty_args
 644
 645         rebox_base  = arg_base + length ex_tvs + length co_tvs + length arg_vs
 646         rebox_uniqs = map mkBuiltinUnique [rebox_base..]
 647
 648         -- data T :: *->* where T1 { fld :: Maybe b } -> T [b]
 649         --      Hence T1 :: forall a b. (a=[b]) => b -> T a
 650         -- fld :: forall b. T [b] -> Maybe b
 651         -- fld = /\b.\(t:T[b]). case t of
 652         --              T1 b' (c : [b]=[b']) (x:Maybe b')
 653         --                      -> x `cast` Maybe (sym (right c))
 654
 655
 656                 -- Generate the refinement for b'=b,
 657                 -- and apply to (Maybe b'), to get (Maybe b)
 658         Succeeded refinement = gadtRefine emptyRefinement ex_tvs co_tvs
 659         the_arg_id_ty = idType the_arg_id
 660         (rhs, data_ty) = case refineType refinement the_arg_id_ty of
 661                           Just (co, data_ty) -> (Cast (Var the_arg_id) co, data_ty)
 662                           Nothing            -> (Var the_arg_id, the_arg_id_ty)
 663
 664         field_vs    = filter (not . isPredTy . idType) arg_vs
 665         the_arg_id  = assoc "mkRecordSelId:mk_alt" (field_lbls `zip` field_vs) field_label
 666         field_lbls  = dataConFieldLabels data_con
 667
 668     error_expr = mkRuntimeErrorApp rEC_SEL_ERROR_ID field_ty full_msg
 669     full_msg   = showSDoc (sep [text "No match in record selector", ppr sel_id])
 670
 671 -- unbox a product type...
 672 -- we will recurse into newtypes, casting along the way, and unbox at the
 673 -- first product data constructor we find. e.g.
 674 --
 675 --   data PairInt = PairInt Int Int
 676 --   newtype S = MkS PairInt
 677 --   newtype T = MkT S
 678 --
 679 -- If we have e = MkT (MkS (PairInt 0 1)) and some body expecting a list of
 680 -- ids, we get (modulo int passing)
 681 --
 682 --   case (e `cast` CoT) `cast` CoS of
 683 --     PairInt a b -> body [a,b]
 684 --
 685 -- The Ints passed around are just for creating fresh locals
 686 unboxProduct :: Int -> CoreExpr -> Type -> (Int -> [Id] -> CoreExpr) -> CoreExpr
 687 unboxProduct i arg arg_ty body
 688   = result
 689   where
 690     result = mkUnpackCase the_id arg con_args boxing_con rhs
 691     (_tycon, _tycon_args, boxing_con, tys) = deepSplitProductType "unboxProduct" arg_ty
 692     ([the_id], i') = mkLocals i [arg_ty]
 693     (con_args, i'') = mkLocals i' tys
 694     rhs = body i'' con_args
 695
 696 mkUnpackCase ::  Id -> CoreExpr -> [Id] -> DataCon -> CoreExpr -> CoreExpr
 697 -- (mkUnpackCase x e args Con body)
 698 --      returns
 699 -- case (e `cast` ...) of bndr { Con args -> body }
 700 --
 701 -- the type of the bndr passed in is irrelevent
 702 mkUnpackCase bndr arg unpk_args boxing_con body
 703   = Case cast_arg (setIdType bndr bndr_ty) (exprType body) [(DataAlt boxing_con, unpk_args, body)]
 704   where
 705   (cast_arg, bndr_ty) = go (idType bndr) arg
 706   go ty arg
 707     | (tycon, tycon_args, _, _)  <- splitProductType "mkUnpackCase" ty
 708     , isNewTyCon tycon && not (isRecursiveTyCon tycon)
 709     = go (newTyConInstRhs tycon tycon_args)
 710          (unwrapNewTypeBody tycon tycon_args arg)
 711     | otherwise = (arg, ty)
 712
 713 -- ...and the dual
 714 reboxProduct :: [Unique]     -- uniques to create new local binders
 715              -> Type         -- type of product to box
 716              -> ([Unique],   -- remaining uniques
 717                  CoreExpr,   -- boxed product
 718                  [Id])       -- Ids being boxed into product
 719 reboxProduct us ty
 720   = let
 721         (_tycon, _tycon_args, _pack_con, con_arg_tys) = deepSplitProductType "reboxProduct" ty
 722
 723         us' = dropList con_arg_tys us
 724
 725         arg_ids  = zipWith (mkSysLocal FSLIT("rb")) us con_arg_tys
 726
 727         bind_rhs = mkProductBox arg_ids ty
 728
 729     in
 730       (us', bind_rhs, arg_ids)
 731
 732 mkProductBox :: [Id] -> Type -> CoreExpr
 733 mkProductBox arg_ids ty
 734   = result_expr
 735   where
 736     (tycon, tycon_args, pack_con, _con_arg_tys) = splitProductType "mkProductBox" ty
 737
 738     result_expr
 739       | isNewTyCon tycon && not (isRecursiveTyCon tycon)
 740       = wrap (mkProductBox arg_ids (newTyConInstRhs tycon tycon_args))
 741       | otherwise = mkConApp pack_con (map Type tycon_args ++ map Var arg_ids)
 742
 743     wrap expr = wrapNewTypeBody tycon tycon_args expr
 744
 745
 746 -- (mkReboxingAlt us con xs rhs) basically constructs the case
 747 -- alternative  (con, xs, rhs)
 748 -- but it does the reboxing necessary to construct the *source*
 749 -- arguments, xs, from the representation arguments ys.
 750 -- For example:
 751 --      data T = MkT !(Int,Int) Bool
 752 --
 753 -- mkReboxingAlt MkT [x,b] r
 754 --      = (DataAlt MkT, [y::Int,z::Int,b], let x = (y,z) in r)
 755 --
 756 -- mkDataAlt should really be in DataCon, but it can't because
 757 -- it manipulates CoreSyn.
 758
 759 mkReboxingAlt
 760   :: [Unique]           -- Uniques for the new Ids
 761   -> DataCon
 762   -> [Var]              -- Source-level args, including existential dicts
 763   -> CoreExpr           -- RHS
 764   -> CoreAlt
 765
 766 mkReboxingAlt us con args rhs
 767   | not (any isMarkedUnboxed stricts)
 768   = (DataAlt con, args, rhs)
 769
 770   | otherwise
 771   = let
 772         (binds, args') = go args stricts us
 773     in
 774     (DataAlt con, args', mkLets binds rhs)
 775
 776   where
 777     stricts = dataConExStricts con ++ dataConStrictMarks con
 778
 779     go [] _stricts _us = ([], [])
 780
 781         -- Type variable case
 782     go (arg:args) stricts us
 783       | isTyVar arg
 784       = let (binds, args') = go args stricts us
 785         in  (binds, arg:args')
 786
 787         -- Term variable case
 788     go (arg:args) (str:stricts) us
 789       | isMarkedUnboxed str
 790       =
 791         let (binds, unpacked_args')        = go args stricts us'
 792             (us', bind_rhs, unpacked_args) = reboxProduct us (idType arg)
 793         in
 794             (NonRec arg bind_rhs : binds, unpacked_args ++ unpacked_args')
 795       | otherwise
 796       = let (binds, args') = go args stricts us
 797         in  (binds, arg:args')
 798 \end{code}
 799
 800
 801 %************************************************************************
 802 %*                                                                      *
 803 \subsection{Dictionary selectors}
 804 %*                                                                      *
 805 %************************************************************************
 806
 807 Selecting a field for a dictionary.  If there is just one field, then
 808 there's nothing to do.
 809
 810 Dictionary selectors may get nested forall-types.  Thus:
 811
 812         class Foo a where
 813           op :: forall b. Ord b => a -> b -> b
 814
 815 Then the top-level type for op is
 816
 817         op :: forall a. Foo a =>
 818               forall b. Ord b =>
 819               a -> b -> b
 820
 821 This is unlike ordinary record selectors, which have all the for-alls
 822 at the outside.  When dealing with classes it's very convenient to
 823 recover the original type signature from the class op selector.
 824
 825 \begin{code}
 826 mkDictSelId :: Name -> Class -> Id
 827 mkDictSelId name clas
 828   = mkGlobalId (ClassOpId clas) name sel_ty info
 829   where
 830     sel_ty = mkForAllTys tyvars (mkFunTy (idType dict_id) (idType the_arg_id))
 831         -- We can't just say (exprType rhs), because that would give a type
 832         --      C a -> C a
 833         -- for a single-op class (after all, the selector is the identity)
 834         -- But it's type must expose the representation of the dictionary
 835         -- to get (say)         C a -> (a -> a)
 836
 837     info = noCafIdInfo
 838                 `setArityInfo`          1
 839                 `setUnfoldingInfo`      mkTopUnfolding rhs
 840                 `setAllStrictnessInfo`  Just strict_sig
 841
 842         -- We no longer use 'must-inline' on record selectors.  They'll
 843         -- inline like crazy if they scrutinise a constructor
 844
 845         -- The strictness signature is of the form U(AAAVAAAA) -> T
 846         -- where the V depends on which item we are selecting
 847         -- It's worth giving one, so that absence info etc is generated
 848         -- even if the selector isn't inlined
 849     strict_sig = mkStrictSig (mkTopDmdType [arg_dmd] TopRes)
 850     arg_dmd | isNewTyCon tycon = evalDmd
 851             | otherwise        = Eval (Prod [ if the_arg_id == id then evalDmd else Abs
 852                                             | id <- arg_ids ])
 853
 854     tycon      = classTyCon clas
 855     [data_con] = tyConDataCons tycon
 856     tyvars     = dataConUnivTyVars data_con
 857     arg_tys    = {- ASSERT( isVanillaDataCon data_con ) -} dataConRepArgTys data_con
 858     eq_theta   = dataConEqTheta data_con
 859     the_arg_id = assoc "MkId.mkDictSelId" (map idName (classSelIds clas) `zip` arg_ids) name
 860
 861     pred       = mkClassPred clas (mkTyVarTys tyvars)
 862     dict_id    = mkTemplateLocal     1 $ mkPredTy pred
 863     (eq_ids,n) = mkCoVarLocals 2 $ mkPredTys eq_theta
 864     arg_ids    = mkTemplateLocalsNum n arg_tys
 865
 866     mkCoVarLocals i []     = ([],i)
 867     mkCoVarLocals i (x:xs) = let (ys,j) = mkCoVarLocals (i+1) xs
 868                                  y      = mkCoVar (mkSysTvName (mkBuiltinUnique i) FSLIT("dc_co")) x
 869                              in (y:ys,j)
 870
 871     rhs = mkLams tyvars  (Lam dict_id   rhs_body)
 872     rhs_body | isNewTyCon tycon = unwrapNewTypeBody tycon (map mkTyVarTy tyvars) (Var dict_id)
 873              | otherwise        = Case (Var dict_id) dict_id (idType the_arg_id)
 874                                        [(DataAlt data_con, eq_ids ++ arg_ids, Var the_arg_id)]
 875 \end{code}
 876
 877
 878 %************************************************************************
 879 %*                                                                      *
 880         Wrapping and unwrapping newtypes and type families
 881 %*                                                                      *
 882 %************************************************************************
 883
 884 \begin{code}
 885 wrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 886 -- The wrapper for the data constructor for a newtype looks like this:
 887 --      newtype T a = MkT (a,Int)
 888 --      MkT :: forall a. (a,Int) -> T a
 889 --      MkT = /\a. \(x:(a,Int)). x `cast` sym (CoT a)
 890 -- where CoT is the coercion TyCon assoicated with the newtype
 891 --
 892 -- The call (wrapNewTypeBody T [a] e) returns the
 893 -- body of the wrapper, namely
 894 --      e `cast` (CoT [a])
 895 --
 896 -- If a coercion constructor is provided in the newtype, then we use
 897 -- it, otherwise the wrap/unwrap are both no-ops
 898 --
 899 -- If the we are dealing with a newtype *instance*, we have a second coercion
 900 -- identifying the family instance with the constructor of the newtype
 901 -- instance.  This coercion is applied in any case (ie, composed with the
 902 -- coercion constructor of the newtype or applied by itself).
 903
 904 wrapNewTypeBody tycon args result_expr
 905   = wrapFamInstBody tycon args inner
 906   where
 907     inner
 908       | Just co_con <- newTyConCo_maybe tycon
 909       = mkCoerce (mkSymCoercion (mkTyConApp co_con args)) result_expr
 910       | otherwise
 911       = result_expr
 912
 913 -- When unwrapping, we do *not* apply any family coercion, because this will
 914 -- be done via a CoPat by the type checker.  We have to do it this way as
 915 -- computing the right type arguments for the coercion requires more than just
 916 -- a spliting operation (cf, TcPat.tcConPat).
 917
 918 unwrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 919 unwrapNewTypeBody tycon args result_expr
 920   | Just co_con <- newTyConCo_maybe tycon
 921   = mkCoerce (mkTyConApp co_con args) result_expr
 922   | otherwise
 923   = result_expr
 924
 925 -- If the type constructor is a representation type of a data instance, wrap
 926 -- the expression into a cast adjusting the expression type, which is an
 927 -- instance of the representation type, to the corresponding instance of the
 928 -- family instance type.
 929 -- See Note [Wrappers for data instance tycons]
 930 wrapFamInstBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 931 wrapFamInstBody tycon args body
 932   | Just co_con <- tyConFamilyCoercion_maybe tycon
 933   = mkCoerce (mkSymCoercion (mkTyConApp co_con args)) body
 934   | otherwise
 935   = body
 936
 937 unwrapFamInstScrut :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 938 unwrapFamInstScrut tycon args scrut
 939   | Just co_con <- tyConFamilyCoercion_maybe tycon
 940   = mkCoerce (mkTyConApp co_con args) scrut
 941   | otherwise
 942   = scrut
 943 \end{code}
 944
 945
 946 %************************************************************************
 947 %*                                                                      *
 948 \subsection{Primitive operations
 949 %*                                                                      *
 950 %************************************************************************
 951
 952 \begin{code}
 953 mkPrimOpId :: PrimOp -> Id
 954 mkPrimOpId prim_op
 955   = id
 956   where
 957     (tyvars,arg_tys,res_ty, arity, strict_sig) = primOpSig prim_op
 958     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 959     name = mkWiredInName gHC_PRIM (primOpOcc prim_op)
 960                          (mkPrimOpIdUnique (primOpTag prim_op))
 961                          (AnId id) UserSyntax
 962     id   = mkGlobalId (PrimOpId prim_op) name ty info
 963
 964     info = noCafIdInfo
 965            `setSpecInfo`          mkSpecInfo (primOpRules prim_op name)
 966            `setArityInfo`         arity
 967            `setAllStrictnessInfo` Just strict_sig
 968
 969 -- For each ccall we manufacture a separate CCallOpId, giving it
 970 -- a fresh unique, a type that is correct for this particular ccall,
 971 -- and a CCall structure that gives the correct details about calling
 972 -- convention etc.
 973 --
 974 -- The *name* of this Id is a local name whose OccName gives the full
 975 -- details of the ccall, type and all.  This means that the interface
 976 -- file reader can reconstruct a suitable Id
 977
 978 mkFCallId :: Unique -> ForeignCall -> Type -> Id
 979 mkFCallId uniq fcall ty
 980   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 981         -- A CCallOpId should have no free type variables;
 982         -- when doing substitutions won't substitute over it
 983     mkGlobalId (FCallId fcall) name ty info
 984   where
 985     occ_str = showSDoc (braces (ppr fcall <+> ppr ty))
 986         -- The "occurrence name" of a ccall is the full info about the
 987         -- ccall; it is encoded, but may have embedded spaces etc!
 988
 989     name = mkFCallName uniq occ_str
 990
 991     info = noCafIdInfo
 992            `setArityInfo`               arity
 993            `setAllStrictnessInfo`       Just strict_sig
 994
 995     (_, tau)     = tcSplitForAllTys ty
 996     (arg_tys, _) = tcSplitFunTys tau
 997     arity        = length arg_tys
 998     strict_sig   = mkStrictSig (mkTopDmdType (replicate arity evalDmd) TopRes)
 999
1000 -- Tick boxes and breakpoints are both represented as TickBoxOpIds,
1001 -- except for the type:
1002 --
1003 --    a plain HPC tick box has type (State# RealWorld)
1004 --    a breakpoint Id has type forall a.a
1005 --
1006 -- The breakpoint Id will be applied to a list of arbitrary free variables,
1007 -- which is why it needs a polymorphic type.
1008
1009 mkTickBoxOpId :: Unique -> Module -> TickBoxId -> Id
1010 mkTickBoxOpId uniq mod ix = mkTickBox' uniq mod ix realWorldStatePrimTy
1011
1012 mkBreakPointOpId :: Unique -> Module -> TickBoxId -> Id
1013 mkBreakPointOpId uniq mod ix = mkTickBox' uniq mod ix ty
1014  where ty = mkSigmaTy [openAlphaTyVar] [] openAlphaTy
1015
1016 mkTickBox' uniq mod ix ty = mkGlobalId (TickBoxOpId tickbox) name ty info
1017   where
1018     tickbox = TickBox mod ix
1019     occ_str = showSDoc (braces (ppr tickbox))
1020     name    = mkTickBoxOpName uniq occ_str
1021     info    = noCafIdInfo
1022 \end{code}
1023
1024
1025 %************************************************************************
1026 %*                                                                      *
1027 \subsection{DictFuns and default methods}
1028 %*                                                                      *
1029 %************************************************************************
1030
1031 Important notes about dict funs and default methods
1032 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1033 Dict funs and default methods are *not* ImplicitIds.  Their definition
1034 involves user-written code, so we can't figure out their strictness etc
1035 based on fixed info, as we can for constructors and record selectors (say).
1036
1037 We build them as LocalIds, but with External Names.  This ensures that
1038 they are taken to account by free-variable finding and dependency
1039 analysis (e.g. CoreFVs.exprFreeVars).
1040
1041 Why shouldn't they be bound as GlobalIds?  Because, in particular, if
1042 they are globals, the specialiser floats dict uses above their defns,
1043 which prevents good simplifications happening.  Also the strictness
1044 analyser treats a occurrence of a GlobalId as imported and assumes it
1045 contains strictness in its IdInfo, which isn't true if the thing is
1046 bound in the same module as the occurrence.
1047
1048 It's OK for dfuns to be LocalIds, because we form the instance-env to
1049 pass on to the next module (md_insts) in CoreTidy, afer tidying
1050 and globalising the top-level Ids.
1051
1052 BUT make sure they are *exported* LocalIds (mkExportedLocalId) so
1053 that they aren't discarded by the occurrence analyser.
1054
1055 \begin{code}
1056 mkDefaultMethodId dm_name ty = mkExportedLocalId dm_name ty
1057
1058 mkDictFunId :: Name             -- Name to use for the dict fun;
1059             -> [TyVar]
1060             -> ThetaType
1061             -> Class
1062             -> [Type]
1063             -> Id
1064
1065 mkDictFunId dfun_name inst_tyvars dfun_theta clas inst_tys
1066   = mkExportedLocalId dfun_name dfun_ty
1067   where
1068     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
1069
1070 {-  1 dec 99: disable the Mark Jones optimisation for the sake
1071     of compatibility with Hugs.
1072     See `types/InstEnv' for a discussion related to this.
1073
1074     (class_tyvars, sc_theta, _, _) = classBigSig clas
1075     not_const (clas, tys) = not (isEmptyVarSet (tyVarsOfTypes tys))
1076     sc_theta' = substClasses (zipTopTvSubst class_tyvars inst_tys) sc_theta
1077     dfun_theta = case inst_decl_theta of
1078                    []    -> []  -- If inst_decl_theta is empty, then we don't
1079                                 -- want to have any dict arguments, so that we can
1080                                 -- expose the constant methods.
1081
1082                    other -> nub (inst_decl_theta ++ filter not_const sc_theta')
1083                                 -- Otherwise we pass the superclass dictionaries to
1084                                 -- the dictionary function; the Mark Jones optimisation.
1085                                 --
1086                                 -- NOTE the "nub".  I got caught by this one:
1087                                 --   class Monad m => MonadT t m where ...
1088                                 --   instance Monad m => MonadT (EnvT env) m where ...
1089                                 -- Here, the inst_decl_theta has (Monad m); but so
1090                                 -- does the sc_theta'!
1091                                 --
1092                                 -- NOTE the "not_const".  I got caught by this one too:
1093                                 --   class Foo a => Baz a b where ...
1094                                 --   instance Wob b => Baz T b where..
1095                                 -- Now sc_theta' has Foo T
1096 -}
1097 \end{code}
1098
1099
1100 %************************************************************************
1101 %*                                                                      *
1102 \subsection{Un-definable}
1103 %*                                                                      *
1104 %************************************************************************
1105
1106 These Ids can't be defined in Haskell.  They could be defined in
1107 unfoldings in the wired-in GHC.Prim interface file, but we'd have to
1108 ensure that they were definitely, definitely inlined, because there is
1109 no curried identifier for them.  That's what mkCompulsoryUnfolding
1110 does.  If we had a way to get a compulsory unfolding from an interface
1111 file, we could do that, but we don't right now.
1112
1113 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
1114 just gets expanded into a type coercion wherever it occurs.  Hence we
1115 add it as a built-in Id with an unfolding here.
1116
1117 The type variables we use here are "open" type variables: this means
1118 they can unify with both unlifted and lifted types.  Hence we provide
1119 another gun with which to shoot yourself in the foot.
1120
1121 \begin{code}
1122 mkWiredInIdName mod fs uniq id
1123  = mkWiredInName mod (mkOccNameFS varName fs) uniq (AnId id) UserSyntax
1124
1125 unsafeCoerceName = mkWiredInIdName gHC_PRIM FSLIT("unsafeCoerce#") unsafeCoerceIdKey  unsafeCoerceId
1126 nullAddrName     = mkWiredInIdName gHC_PRIM FSLIT("nullAddr#")     nullAddrIdKey      nullAddrId
1127 seqName          = mkWiredInIdName gHC_PRIM FSLIT("seq")           seqIdKey           seqId
1128 realWorldName    = mkWiredInIdName gHC_PRIM FSLIT("realWorld#")    realWorldPrimIdKey realWorldPrimId
1129 lazyIdName       = mkWiredInIdName gHC_BASE FSLIT("lazy")         lazyIdKey           lazyId
1130
1131 errorName                = mkWiredInIdName gHC_ERR FSLIT("error")            errorIdKey eRROR_ID
1132 recSelErrorName          = mkWiredInIdName gHC_ERR FSLIT("recSelError")     recSelErrorIdKey rEC_SEL_ERROR_ID
1133 runtimeErrorName         = mkWiredInIdName gHC_ERR FSLIT("runtimeError")    runtimeErrorIdKey rUNTIME_ERROR_ID
1134 irrefutPatErrorName      = mkWiredInIdName gHC_ERR FSLIT("irrefutPatError") irrefutPatErrorIdKey iRREFUT_PAT_ERROR_ID
1135 recConErrorName          = mkWiredInIdName gHC_ERR FSLIT("recConError")     recConErrorIdKey rEC_CON_ERROR_ID
1136 patErrorName             = mkWiredInIdName gHC_ERR FSLIT("patError")         patErrorIdKey pAT_ERROR_ID
1137 noMethodBindingErrorName = mkWiredInIdName gHC_ERR FSLIT("noMethodBindingError")
1138                                            noMethodBindingErrorIdKey nO_METHOD_BINDING_ERROR_ID
1139 nonExhaustiveGuardsErrorName
1140   = mkWiredInIdName gHC_ERR FSLIT("nonExhaustiveGuardsError")
1141                     nonExhaustiveGuardsErrorIdKey nON_EXHAUSTIVE_GUARDS_ERROR_ID
1142 \end{code}
1143
1144 \begin{code}
1145 -- unsafeCoerce# :: forall a b. a -> b
1146 unsafeCoerceId
1147   = pcMiscPrelId unsafeCoerceName ty info
1148   where
1149     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
1150
1151
1152     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
1153                       (mkFunTy openAlphaTy openBetaTy)
1154     [x] = mkTemplateLocals [openAlphaTy]
1155     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
1156           Cast (Var x) (mkUnsafeCoercion openAlphaTy openBetaTy)
1157
1158 -- nullAddr# :: Addr#
1159 -- The reason is is here is because we don't provide
1160 -- a way to write this literal in Haskell.
1161 nullAddrId
1162   = pcMiscPrelId nullAddrName addrPrimTy info
1163   where
1164     info = noCafIdInfo `setUnfoldingInfo`
1165            mkCompulsoryUnfolding (Lit nullAddrLit)
1166
1167 seqId
1168   = pcMiscPrelId seqName ty info
1169   where
1170     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
1171
1172
1173     ty  = mkForAllTys [alphaTyVar,openBetaTyVar]
1174                       (mkFunTy alphaTy (mkFunTy openBetaTy openBetaTy))
1175     [x,y] = mkTemplateLocals [alphaTy, openBetaTy]
1176     rhs = mkLams [alphaTyVar,openBetaTyVar,x,y] (Case (Var x) x openBetaTy [(DEFAULT, [], Var y)])
1177
1178 -- lazy :: forall a?. a? -> a?   (i.e. works for unboxed types too)
1179 -- Used to lazify pseq:         pseq a b = a `seq` lazy b
1180 --
1181 -- Also, no strictness: by being a built-in Id, all the info about lazyId comes from here,
1182 -- not from GHC.Base.hi.   This is important, because the strictness
1183 -- analyser will spot it as strict!
1184 --
1185 -- Also no unfolding in lazyId: it gets "inlined" by a HACK in the worker/wrapperpass
1186 --      (see WorkWrap.wwExpr)
1187 -- We could use inline phases to do this, but that would be vulnerable to changes in
1188 -- phase numbering....we must inline precisely after strictness analysis.
1189 lazyId
1190   = pcMiscPrelId lazyIdName ty info
1191   where
1192     info = noCafIdInfo
1193     ty  = mkForAllTys [alphaTyVar] (mkFunTy alphaTy alphaTy)
1194
1195 lazyIdUnfolding :: CoreExpr     -- Used to expand 'lazyId' after strictness anal
1196 lazyIdUnfolding = mkLams [openAlphaTyVar,x] (Var x)
1197                 where
1198                   [x] = mkTemplateLocals [openAlphaTy]
1199 \end{code}
1200
1201 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
1202 nasty as-is, change it back to a literal (@Literal@).
1203
1204 voidArgId is a Local Id used simply as an argument in functions
1205 where we just want an arg to avoid having a thunk of unlifted type.
1206 E.g.
1207         x = \ void :: State# RealWorld -> (# p, q #)
1208
1209 This comes up in strictness analysis
1210
1211 \begin{code}
1212 realWorldPrimId -- :: State# RealWorld
1213   = pcMiscPrelId realWorldName realWorldStatePrimTy
1214                  (noCafIdInfo `setUnfoldingInfo` evaldUnfolding)
1215         -- The evaldUnfolding makes it look that realWorld# is evaluated
1216         -- which in turn makes Simplify.interestingArg return True,
1217         -- which in turn makes INLINE things applied to realWorld# likely
1218         -- to be inlined
1219
1220 voidArgId       -- :: State# RealWorld
1221   = mkSysLocal FSLIT("void") voidArgIdKey realWorldStatePrimTy
1222 \end{code}
1223
1224
1225 %************************************************************************
1226 %*                                                                      *
1227 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
1228 %*                                                                      *
1229 %************************************************************************
1230
1231 GHC randomly injects these into the code.
1232
1233 @patError@ is just a version of @error@ for pattern-matching
1234 failures.  It knows various ``codes'' which expand to longer
1235 strings---this saves space!
1236
1237 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
1238 well shouldn't be yanked on, but if one is, then you will get a
1239 friendly message from @absentErr@ (rather than a totally random
1240 crash).
1241
1242 @parError@ is a special version of @error@ which the compiler does
1243 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
1244 templates, but we don't ever expect to generate code for it.
1245
1246 \begin{code}
1247 mkRuntimeErrorApp
1248         :: Id           -- Should be of type (forall a. Addr# -> a)
1249                         --      where Addr# points to a UTF8 encoded string
1250         -> Type         -- The type to instantiate 'a'
1251         -> String       -- The string to print
1252         -> CoreExpr
1253
1254 mkRuntimeErrorApp err_id res_ty err_msg
1255   = mkApps (Var err_id) [Type res_ty, err_string]
1256   where
1257     err_string = Lit (mkStringLit err_msg)
1258
1259 rEC_SEL_ERROR_ID                = mkRuntimeErrorId recSelErrorName
1260 rUNTIME_ERROR_ID                = mkRuntimeErrorId runtimeErrorName
1261 iRREFUT_PAT_ERROR_ID            = mkRuntimeErrorId irrefutPatErrorName
1262 rEC_CON_ERROR_ID                = mkRuntimeErrorId recConErrorName
1263 pAT_ERROR_ID                    = mkRuntimeErrorId patErrorName
1264 nO_METHOD_BINDING_ERROR_ID      = mkRuntimeErrorId noMethodBindingErrorName
1265 nON_EXHAUSTIVE_GUARDS_ERROR_ID  = mkRuntimeErrorId nonExhaustiveGuardsErrorName
1266
1267 -- The runtime error Ids take a UTF8-encoded string as argument
1268 mkRuntimeErrorId name = pc_bottoming_Id name runtimeErrorTy
1269 runtimeErrorTy        = mkSigmaTy [openAlphaTyVar] [] (mkFunTy addrPrimTy openAlphaTy)
1270 \end{code}
1271
1272 \begin{code}
1273 eRROR_ID = pc_bottoming_Id errorName errorTy
1274
1275 errorTy  :: Type
1276 errorTy  = mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkListTy charTy] openAlphaTy)
1277     -- Notice the openAlphaTyVar.  It says that "error" can be applied
1278     -- to unboxed as well as boxed types.  This is OK because it never
1279     -- returns, so the return type is irrelevant.
1280 \end{code}
1281
1282
1283 %************************************************************************
1284 %*                                                                      *
1285 \subsection{Utilities}
1286 %*                                                                      *
1287 %************************************************************************
1288
1289 \begin{code}
1290 pcMiscPrelId :: Name -> Type -> IdInfo -> Id
1291 pcMiscPrelId name ty info
1292   = mkVanillaGlobal name ty info
1293     -- We lie and say the thing is imported; otherwise, we get into
1294     -- a mess with dependency analysis; e.g., core2stg may heave in
1295     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
1296     -- being compiled, then it's just a matter of luck if the definition
1297     -- will be in "the right place" to be in scope.
1298
1299 pc_bottoming_Id name ty
1300  = pcMiscPrelId name ty bottoming_info
1301  where
1302     bottoming_info = vanillaIdInfo `setAllStrictnessInfo` Just strict_sig
1303         -- Do *not* mark them as NoCafRefs, because they can indeed have
1304         -- CAF refs.  For example, pAT_ERROR_ID calls GHC.Err.untangle,
1305         -- which has some CAFs
1306         -- In due course we may arrange that these error-y things are
1307         -- regarded by the GC as permanently live, in which case we
1308         -- can give them NoCaf info.  As it is, any function that calls
1309         -- any pc_bottoming_Id will itself have CafRefs, which bloats
1310         -- SRTs.
1311
1312     strict_sig     = mkStrictSig (mkTopDmdType [evalDmd] BotRes)
1313         -- These "bottom" out, no matter what their arguments
1314 \end{code}
1315